git.oblomov.eu Git - wine/blob - debugger/dbg.y

   1 %{
   2 /*
   3  * Parser for command lines in the Wine debugger
   4  *
   5  * Copyright 1993 Eric Youngdale
   6  * Copyright 1995 Morten Welinder
   7  * Copyright 2000 Eric Pouech
   8  */
   9
  10 #include "config.h"
  11
  12 #include <stdio.h>
  13 #include <stdlib.h>
  14 #include <string.h>
  15 #include <signal.h>
  16 #include <unistd.h>
  17
  18 #include "wine/exception.h"
  19 #include "debugger.h"
  20 #include "expr.h"
  21
  22 extern FILE * yyin;
  23
  24 static void issue_prompt(void);
  25 static void mode_command(int);
  26 int yylex(void);
  27 int yyerror(char *);
  28
  29 %}
  30
  31 %union
  32 {
  33     DBG_VALUE        value;
  34     char *           string;
  35     int              integer;
  36     struct list_id   listing;
  37     struct expr *    expression;
  38     struct datatype* type;
  39 }
  40
  41 %token tCONT tPASS tSTEP tLIST tNEXT tQUIT tHELP tBACKTRACE tINFO tWALK tUP tDOWN
  42 %token tENABLE tDISABLE tBREAK tWATCH tDELETE tSET tMODE tPRINT tEXAM tABORT tVM86
  43 %token tCLASS tMAPS tMODULE tSTACK tSEGMENTS tREGS tWND tQUEUE tLOCAL
  44 %token tPROCESS tTHREAD tMODREF tEOL
  45 %token tFRAME tSHARE tCOND tDISPLAY tUNDISPLAY tDISASSEMBLE
  46 %token tSTEPI tNEXTI tFINISH tSHOW tDIR tWHATIS
  47 %token <string> tPATH
  48 %token <string> tIDENTIFIER tSTRING tDEBUGSTR tINTVAR
  49 %token <integer> tNUM tFORMAT
  50 %token tSYMBOLFILE tRUN tATTACH tNOPROCESS
  51
  52 %token tCHAR tSHORT tINT tLONG tFLOAT tDOUBLE tUNSIGNED tSIGNED
  53 %token tSTRUCT tUNION tENUM
  54
  55 /* %left ',' */
  56 /* %left '=' OP_OR_EQUAL OP_XOR_EQUAL OP_AND_EQUAL OP_SHL_EQUAL \
  57          OP_SHR_EQUAL OP_PLUS_EQUAL OP_MINUS_EQUAL \
  58          OP_TIMES_EQUAL OP_DIVIDE_EQUAL OP_MODULO_EQUAL */
  59 /* %left OP_COND */ /* ... ? ... : ... */
  60 %left OP_LOR
  61 %left OP_LAND
  62 %left '|'
  63 %left '^'
  64 %left '&'
  65 %left OP_EQ OP_NE
  66 %left '<' '>' OP_LE OP_GE
  67 %left OP_SHL OP_SHR
  68 %left '+' '-'
  69 %left '*' '/' '%'
  70 %left OP_SIGN '!' '~' OP_DEREF /* OP_INC OP_DEC OP_ADDR */
  71 %left '.' '[' OP_DRF
  72 %nonassoc ':'
  73
  74 %type <expression> expr lval lvalue
  75 %type <type> type_cast type_expr
  76 %type <value> expr_addr lval_addr
  77 %type <integer> expr_value
  78 %type <string> pathname identifier
  79
  80 %type <listing> list_arg
  81
  82 %%
  83
  84 input: line                     { issue_prompt(); }
  85     | input line                { issue_prompt(); }
  86
  87 line: command
  88     | tEOL
  89     | error tEOL                { yyerrok; }
  90
  91 command:
  92       tQUIT tEOL                { return FALSE; }
  93     | tHELP tEOL                { DEBUG_Help(); }
  94     | tHELP tINFO tEOL          { DEBUG_HelpInfo(); }
  95     | tCONT tEOL                { DEBUG_CurrThread->dbg_exec_count = 1;
  96                                   DEBUG_CurrThread->dbg_exec_mode = EXEC_CONT; return TRUE; }
  97     | tPASS tEOL                { DEBUG_CurrThread->dbg_exec_count = 1;
  98                                   DEBUG_CurrThread->dbg_exec_mode = EXEC_PASS; return TRUE; }
  99     | tCONT tNUM tEOL           { DEBUG_CurrThread->dbg_exec_count = $2;
 100                                   DEBUG_CurrThread->dbg_exec_mode = EXEC_CONT; return TRUE; }
 101     | tSTEP tEOL                { DEBUG_CurrThread->dbg_exec_count = 1;
 102                                   DEBUG_CurrThread->dbg_exec_mode = EXEC_STEP_INSTR; return TRUE; }
 103     | tNEXT tEOL                { DEBUG_CurrThread->dbg_exec_count = 1;
 104                                   DEBUG_CurrThread->dbg_exec_mode = EXEC_STEP_OVER; return TRUE; }
 105     | tSTEP tNUM tEOL           { DEBUG_CurrThread->dbg_exec_count = $2;
 106                                   DEBUG_CurrThread->dbg_exec_mode = EXEC_STEP_INSTR; return TRUE; }
 107     | tNEXT tNUM tEOL           { DEBUG_CurrThread->dbg_exec_count = $2;
 108                                   DEBUG_CurrThread->dbg_exec_mode = EXEC_STEP_OVER; return TRUE; }
 109     | tSTEPI tEOL               { DEBUG_CurrThread->dbg_exec_count = 1;
 110                                   DEBUG_CurrThread->dbg_exec_mode = EXEC_STEPI_INSTR; return TRUE; }
 111     | tNEXTI tEOL               { DEBUG_CurrThread->dbg_exec_count = 1;
 112                                   DEBUG_CurrThread->dbg_exec_mode = EXEC_STEPI_OVER; return TRUE; }
 113     | tSTEPI tNUM tEOL          { DEBUG_CurrThread->dbg_exec_count = $2;
 114                                   DEBUG_CurrThread->dbg_exec_mode = EXEC_STEPI_INSTR; return TRUE; }
 115     | tNEXTI tNUM tEOL          { DEBUG_CurrThread->dbg_exec_count = $2;
 116                                   DEBUG_CurrThread->dbg_exec_mode = EXEC_STEPI_OVER; return TRUE; }
 117     | tABORT tEOL               { kill(getpid(), SIGABRT); }
 118     | tMODE tNUM tEOL           { mode_command($2); }
 119     | tMODE tVM86 tEOL          { DEBUG_CurrThread->dbg_mode = MODE_VM86; }
 120     | tENABLE tNUM tEOL         { DEBUG_EnableBreakpoint( $2, TRUE ); }
 121     | tDISABLE tNUM tEOL        { DEBUG_EnableBreakpoint( $2, FALSE ); }
 122     | tDELETE tBREAK tNUM tEOL  { DEBUG_DelBreakpoint( $3 ); }
 123     | tBACKTRACE tEOL           { DEBUG_BackTrace(DEBUG_CurrTid, TRUE); }
 124     | tBACKTRACE tNUM tEOL      { DEBUG_BackTrace($2, TRUE); }
 125     | tUP tEOL                  { DEBUG_SetFrame( curr_frame + 1 );  }
 126     | tUP tNUM tEOL             { DEBUG_SetFrame( curr_frame + $2 ); }
 127     | tDOWN tEOL                { DEBUG_SetFrame( curr_frame - 1 );  }
 128     | tDOWN tNUM tEOL           { DEBUG_SetFrame( curr_frame - $2 ); }
 129     | tFRAME tNUM tEOL          { DEBUG_SetFrame( $2 ); }
 130     | tFINISH tEOL              { DEBUG_CurrThread->dbg_exec_count = 0;
 131                                   DEBUG_CurrThread->dbg_exec_mode = EXEC_FINISH; return TRUE; }
 132     | tSHOW tDIR tEOL           { DEBUG_ShowDir(); }
 133     | tDIR pathname tEOL        { DEBUG_AddPath( $2 ); }
 134     | tDIR tEOL                 { DEBUG_NukePath(); }
 135     | tDISPLAY tEOL             { DEBUG_InfoDisplay(); }
 136     | tDISPLAY expr tEOL        { DEBUG_AddDisplay($2, 1, 0); }
 137     | tDISPLAY tFORMAT expr tEOL{ DEBUG_AddDisplay($3, $2 >> 8, $2 & 0xff); }
 138     | tDELETE tDISPLAY tNUM tEOL{ DEBUG_DelDisplay( $3 ); }
 139     | tDELETE tDISPLAY tEOL     { DEBUG_DelDisplay( -1 ); }
 140     | tUNDISPLAY tNUM tEOL      { DEBUG_DelDisplay( $2 ); }
 141     | tUNDISPLAY tEOL           { DEBUG_DelDisplay( -1 ); }
 142     | tCOND tNUM tEOL           { DEBUG_AddBPCondition($2, NULL); }
 143     | tCOND tNUM expr tEOL      { DEBUG_AddBPCondition($2, $3); }
 144     | tSYMBOLFILE pathname tEOL { DEBUG_ReadSymbolTable($2); }
 145     | tWHATIS expr_addr tEOL    { DEBUG_PrintType(&$2); DEBUG_FreeExprMem(); }
 146     | tATTACH tNUM tEOL         { if (DEBUG_Attach($2, FALSE)) return TRUE; }
 147     | list_command
 148     | disassemble_command
 149     | set_command
 150     | x_command
 151     | print_command
 152     | break_command
 153     | watch_command
 154     | info_command
 155     | walk_command
 156     | run_command
 157     | noprocess_state
 158
 159 set_command:
 160       tSET lval_addr '=' expr_value tEOL   { DEBUG_WriteMemory( &$2, $4 );
 161                                              DEBUG_FreeExprMem(); }
 162
 163 pathname:
 164       tIDENTIFIER              { $$ = $1; }
 165     | tPATH                    { $$ = $1; }
 166
 167 disassemble_command:
 168       tDISASSEMBLE tEOL              { DEBUG_Disassemble( NULL, NULL, 10 ); }
 169     | tDISASSEMBLE expr_addr tEOL    { DEBUG_Disassemble( & $2, NULL, 10 ); }
 170     | tDISASSEMBLE expr_addr ',' expr_addr tEOL { DEBUG_Disassemble( & $2, & $4, 0 ); }
 171
 172 list_command:
 173       tLIST tEOL               { DEBUG_List( NULL, NULL, 10 ); }
 174     | tLIST '-' tEOL           { DEBUG_List( NULL, NULL, -10 ); }
 175     | tLIST list_arg tEOL      { DEBUG_List( & $2, NULL, 10 ); }
 176     | tLIST ',' list_arg tEOL  { DEBUG_List( NULL, & $3, -10 ); }
 177     | tLIST list_arg ',' list_arg tEOL { DEBUG_List( & $2, & $4, 0 ); }
 178
 179 list_arg:
 180       tNUM                     { $$.sourcefile = NULL; $$.line = $1; }
 181     | pathname ':' tNUM        { $$.sourcefile = $1; $$.line = $3; }
 182     | tIDENTIFIER              { DEBUG_GetFuncInfo( & $$, NULL, $1); }
 183     | pathname ':' tIDENTIFIER { DEBUG_GetFuncInfo( & $$, $1, $3); }
 184     | '*' expr_addr            { DEBUG_FindNearestSymbol( & $2.addr, FALSE, NULL, 0, & $$ );
 185                                  DEBUG_FreeExprMem(); }
 186
 187 x_command:
 188       tEXAM expr_addr tEOL     { DEBUG_ExamineMemory( &$2, 1, 'x'); DEBUG_FreeExprMem(); }
 189     | tEXAM tFORMAT expr_addr tEOL  { DEBUG_ExamineMemory( &$3, $2>>8, $2&0xff );
 190                                       DEBUG_FreeExprMem(); }
 191
 192 print_command:
 193       tPRINT expr_addr tEOL    { DEBUG_Print( &$2, 1, 0, 0 ); DEBUG_FreeExprMem(); }
 194     | tPRINT tFORMAT expr_addr tEOL { DEBUG_Print( &$3, $2 >> 8, $2 & 0xff, 0 );
 195                                       DEBUG_FreeExprMem(); }
 196
 197 break_command:
 198       tBREAK '*' expr_addr tEOL{ DEBUG_AddBreakpoint( &$3, NULL ); DEBUG_FreeExprMem(); }
 199     | tBREAK identifier tEOL   { DEBUG_AddBreakpointFromId($2, -1); }
 200     | tBREAK identifier ':' tNUM tEOL  { DEBUG_AddBreakpointFromId($2, $4); }
 201     | tBREAK tNUM tEOL         { DEBUG_AddBreakpointFromLineno($2); }
 202     | tBREAK tEOL              { DEBUG_AddBreakpointFromLineno(-1); }
 203
 204 watch_command:
 205       tWATCH '*' expr_addr tEOL { DEBUG_AddWatchpoint( &$3, 1 ); DEBUG_FreeExprMem(); }
 206     | tWATCH identifier tEOL    { DEBUG_AddWatchpointFromId($2); }
 207
 208 info_command:
 209       tINFO tBREAK tEOL         { DEBUG_InfoBreakpoints(); }
 210     | tINFO tCLASS tSTRING tEOL { DEBUG_InfoClass( $3 ); }
 211     | tINFO tSHARE tEOL         { DEBUG_InfoShare(); }
 212     | tINFO tMODULE expr_value tEOL   { DEBUG_DumpModule( $3 ); DEBUG_FreeExprMem(); }
 213     | tINFO tQUEUE expr_value tEOL    { DEBUG_DumpQueue( $3 ); DEBUG_FreeExprMem(); }
 214     | tINFO tREGS tEOL          { DEBUG_InfoRegisters(); }
 215     | tINFO tSEGMENTS expr_value tEOL { DEBUG_InfoSegments( $3, 1 ); DEBUG_FreeExprMem(); }
 216     | tINFO tSEGMENTS tEOL      { DEBUG_InfoSegments( 0, -1 ); }
 217     | tINFO tSTACK tEOL         { DEBUG_InfoStack(); }
 218     | tINFO tMAPS tEOL          { DEBUG_InfoVirtual(); }
 219     | tINFO tWND expr_value tEOL{ DEBUG_InfoWindow( (HWND)$3 ); DEBUG_FreeExprMem(); }
 220     | tINFO tLOCAL tEOL         { DEBUG_InfoLocals(); }
 221     | tINFO tDISPLAY tEOL       { DEBUG_InfoDisplay(); }
 222
 223 walk_command:
 224       tWALK tCLASS tEOL         { DEBUG_WalkClasses(); }
 225     | tWALK tMODULE tEOL        { DEBUG_WalkModules(); }
 226     | tWALK tQUEUE tEOL         { DEBUG_WalkQueues(); }
 227     | tWALK tWND tEOL           { DEBUG_WalkWindows( 0, 0 ); }
 228     | tWALK tWND tNUM tEOL      { DEBUG_WalkWindows( (HWND)$3, 0 ); }
 229     | tWALK tPROCESS tEOL       { DEBUG_WalkProcess(); }
 230     | tWALK tTHREAD tEOL        { DEBUG_WalkThreads(); }
 231     | tWALK tMODREF expr_value tEOL   { DEBUG_WalkModref( $3 ); DEBUG_FreeExprMem(); }
 232
 233 run_command:
 234       tRUN tEOL                 { DEBUG_Run(NULL); }
 235     | tRUN tSTRING tEOL         { DEBUG_Run($2); }
 236
 237 noprocess_state:
 238       tNOPROCESS tEOL           {} /* <CR> shall not barf anything */
 239     | tNOPROCESS tSTRING tEOL   { DEBUG_Printf(DBG_CHN_MESG, "No process loaded, cannot execute '%s'\n", $2); }
 240
 241 type_cast:
 242       '(' type_expr ')'         { $$ = $2; }
 243
 244 type_expr:
 245       type_expr '*'             { $$ = DEBUG_FindOrMakePointerType($1); }
 246     |  tINT                     { $$ = DEBUG_TypeCast(DT_BASIC, "int"); }
 247     | tCHAR                     { $$ = DEBUG_TypeCast(DT_BASIC, "char"); }
 248     | tLONG tINT                { $$ = DEBUG_TypeCast(DT_BASIC, "long int"); }
 249     | tUNSIGNED tINT            { $$ = DEBUG_TypeCast(DT_BASIC, "unsigned int"); }
 250     | tLONG tUNSIGNED tINT      { $$ = DEBUG_TypeCast(DT_BASIC, "long unsigned int"); }
 251     | tLONG tLONG tINT          { $$ = DEBUG_TypeCast(DT_BASIC, "long long int"); }
 252     | tLONG tLONG tUNSIGNED tINT{ $$ = DEBUG_TypeCast(DT_BASIC, "long long unsigned int"); }
 253     | tSHORT tINT               { $$ = DEBUG_TypeCast(DT_BASIC, "short int"); }
 254     | tSHORT tUNSIGNED tINT     { $$ = DEBUG_TypeCast(DT_BASIC, "short unsigned int"); }
 255     | tSIGNED tCHAR             { $$ = DEBUG_TypeCast(DT_BASIC, "signed char"); }
 256     | tUNSIGNED tCHAR           { $$ = DEBUG_TypeCast(DT_BASIC, "unsigned char"); }
 257     | tFLOAT                    { $$ = DEBUG_TypeCast(DT_BASIC, "float"); }
 258     | tDOUBLE                   { $$ = DEBUG_TypeCast(DT_BASIC, "double"); }
 259     | tLONG tDOUBLE             { $$ = DEBUG_TypeCast(DT_BASIC, "long double"); }
 260     | tSTRUCT tIDENTIFIER       { $$ = DEBUG_TypeCast(DT_STRUCT, $2); }
 261     | tUNION tIDENTIFIER        { $$ = DEBUG_TypeCast(DT_STRUCT, $2); }
 262     | tENUM tIDENTIFIER         { $$ = DEBUG_TypeCast(DT_ENUM, $2); }
 263
 264 expr_addr:
 265       expr                      { $$ = DEBUG_EvalExpr($1); }
 266
 267 expr_value:
 268       expr                      { DBG_VALUE     value = DEBUG_EvalExpr($1);
 269                                   /* expr_value is typed as an integer */
 270                                   $$ = DEBUG_ReadMemory(&value); }
 271
 272 /*
 273  * The expr rule builds an expression tree.  When we are done, we call
 274  * EvalExpr to evaluate the value of the expression.  The advantage of
 275  * the two-step approach is that it is possible to save expressions for
 276  * use in 'display' commands, and in conditional watchpoints.
 277  */
 278 expr:
 279       tNUM                       { $$ = DEBUG_ConstExpr($1); }
 280     | tSTRING                    { $$ = DEBUG_StringExpr($1); }
 281     | tINTVAR                    { $$ = DEBUG_IntVarExpr($1); }
 282     | tIDENTIFIER                { $$ = DEBUG_SymbolExpr($1); }
 283     | expr OP_DRF tIDENTIFIER    { $$ = DEBUG_StructPExpr($1, $3); }
 284     | expr '.' tIDENTIFIER       { $$ = DEBUG_StructExpr($1, $3); }
 285     | tIDENTIFIER '(' ')'        { $$ = DEBUG_CallExpr($1, 0); }
 286     | tIDENTIFIER '(' expr ')'   { $$ = DEBUG_CallExpr($1, 1, $3); }
 287     | tIDENTIFIER '(' expr ',' expr ')'  { $$ = DEBUG_CallExpr($1, 2, $3, $5); }
 288     | tIDENTIFIER '(' expr ',' expr ',' expr ')'         { $$ = DEBUG_CallExpr($1, 3, $3, $5, $7); }
 289     | tIDENTIFIER '(' expr ',' expr ',' expr ',' expr ')'        { $$ = DEBUG_CallExpr($1, 4, $3, $5, $7, $9); }
 290     | tIDENTIFIER '(' expr ',' expr ',' expr ',' expr ',' expr ')'       { $$ = DEBUG_CallExpr($1, 5, $3, $5, $7, $9, $11); }
 291     | expr '[' expr ']'          { $$ = DEBUG_BinopExpr(EXP_OP_ARR, $1, $3); }
 292     | expr ':' expr              { $$ = DEBUG_BinopExpr(EXP_OP_SEG, $1, $3); }
 293     | expr OP_LOR expr           { $$ = DEBUG_BinopExpr(EXP_OP_LOR, $1, $3); }
 294     | expr OP_LAND expr          { $$ = DEBUG_BinopExpr(EXP_OP_LAND, $1, $3); }
 295     | expr '|' expr              { $$ = DEBUG_BinopExpr(EXP_OP_OR, $1, $3); }
 296     | expr '&' expr              { $$ = DEBUG_BinopExpr(EXP_OP_AND, $1, $3); }
 297     | expr '^' expr              { $$ = DEBUG_BinopExpr(EXP_OP_XOR, $1, $3); }
 298     | expr OP_EQ expr            { $$ = DEBUG_BinopExpr(EXP_OP_EQ, $1, $3); }
 299     | expr '>' expr              { $$ = DEBUG_BinopExpr(EXP_OP_GT, $1, $3); }
 300     | expr '<' expr              { $$ = DEBUG_BinopExpr(EXP_OP_LT, $1, $3); }
 301     | expr OP_GE expr            { $$ = DEBUG_BinopExpr(EXP_OP_GE, $1, $3); }
 302     | expr OP_LE expr            { $$ = DEBUG_BinopExpr(EXP_OP_LE, $1, $3); }
 303     | expr OP_NE expr            { $$ = DEBUG_BinopExpr(EXP_OP_NE, $1, $3); }
 304     | expr OP_SHL expr           { $$ = DEBUG_BinopExpr(EXP_OP_SHL, $1, $3); }
 305     | expr OP_SHR expr           { $$ = DEBUG_BinopExpr(EXP_OP_SHR, $1, $3); }
 306     | expr '+' expr              { $$ = DEBUG_BinopExpr(EXP_OP_ADD, $1, $3); }
 307     | expr '-' expr              { $$ = DEBUG_BinopExpr(EXP_OP_SUB, $1, $3); }
 308     | expr '*' expr              { $$ = DEBUG_BinopExpr(EXP_OP_MUL, $1, $3); }
 309     | expr '/' expr              { $$ = DEBUG_BinopExpr(EXP_OP_DIV, $1, $3); }
 310     | expr '%' expr              { $$ = DEBUG_BinopExpr(EXP_OP_REM, $1, $3); }
 311     | '-' expr %prec OP_SIGN     { $$ = DEBUG_UnopExpr(EXP_OP_NEG, $2); }
 312     | '+' expr %prec OP_SIGN     { $$ = $2; }
 313     | '!' expr                   { $$ = DEBUG_UnopExpr(EXP_OP_NOT, $2); }
 314     | '~' expr                   { $$ = DEBUG_UnopExpr(EXP_OP_LNOT, $2); }
 315     | '(' expr ')'               { $$ = $2; }
 316     | '*' expr %prec OP_DEREF    { $$ = DEBUG_UnopExpr(EXP_OP_DEREF, $2); }
 317     | '&' expr %prec OP_DEREF    { $$ = DEBUG_UnopExpr(EXP_OP_ADDR, $2); }
 318     | type_cast expr %prec OP_DEREF { $$ = DEBUG_TypeCastExpr($1, $2); }
 319
 320 /*
 321  * The lvalue rule builds an expression tree.  This is a limited form
 322  * of expression that is suitable to be used as an lvalue.
 323  */
 324 lval_addr:
 325     lval                         { $$ = DEBUG_EvalExpr($1); }
 326
 327 lval:
 328       lvalue                     { $$ = $1; }
 329     | '*' expr                   { $$ = DEBUG_UnopExpr(EXP_OP_FORCE_DEREF, $2); }
 330
 331 lvalue:
 332       tNUM                       { $$ = DEBUG_ConstExpr($1); }
 333     | tINTVAR                    { $$ = DEBUG_IntVarExpr($1); }
 334     | tIDENTIFIER                { $$ = DEBUG_SymbolExpr($1); }
 335     | lvalue OP_DRF tIDENTIFIER  { $$ = DEBUG_StructPExpr($1, $3); }
 336     | lvalue '.' tIDENTIFIER     { $$ = DEBUG_StructExpr($1, $3); }
 337     | lvalue '[' expr ']'        { $$ = DEBUG_BinopExpr(EXP_OP_ARR, $1, $3); }
 338
 339 identifier:
 340       tIDENTIFIER                { $$ = $1; }
 341     | identifier '.' tIDENTIFIER { char* ptr = DBG_alloc(strlen($1) + 1 + strlen($3)+ 1);
 342                                    sprintf(ptr, "%s.%s", $1, $3); $$ = DEBUG_MakeSymbol(ptr);
 343                                    DBG_free(ptr); }
 344
 345 %%
 346
 347 static void issue_prompt(void)
 348 {
 349 #ifdef DONT_USE_READLINE
 350    DEBUG_Printf(DBG_CHN_MESG, "Wine-dbg>");
 351 #endif
 352 }
 353
 354 static void mode_command(int newmode)
 355 {
 356     switch(newmode)
 357     {
 358     case 16: DEBUG_CurrThread->dbg_mode = MODE_16; break;
 359     case 32: DEBUG_CurrThread->dbg_mode = MODE_32; break;
 360     default: DEBUG_Printf(DBG_CHN_MESG,"Invalid mode (use 16, 32 or vm86)\n");
 361     }
 362 }
 363
 364 void DEBUG_Exit(DWORD ec)
 365 {
 366    ExitProcess(ec);
 367 }
 368
 369 static WINE_EXCEPTION_FILTER(wine_dbg_cmd)
 370 {
 371    DEBUG_Printf(DBG_CHN_MESG, "\nwine_dbg_cmd: ");
 372    switch (GetExceptionCode()) {
 373    case DEBUG_STATUS_INTERNAL_ERROR:
 374       DEBUG_Printf(DBG_CHN_MESG, "WineDbg internal error\n");
 375       break;
 376    case DEBUG_STATUS_NO_SYMBOL:
 377       DEBUG_Printf(DBG_CHN_MESG, "Undefined symbol\n");
 378       break;
 379    case DEBUG_STATUS_DIV_BY_ZERO:
 380       DEBUG_Printf(DBG_CHN_MESG, "Division by zero\n");
 381       break;
 382    case DEBUG_STATUS_BAD_TYPE:
 383       DEBUG_Printf(DBG_CHN_MESG, "No type or type mismatch\n");
 384       break;
 385    case DEBUG_STATUS_NO_FIELD:
 386       DEBUG_Printf(DBG_CHN_MESG, "No such field in structure or union\n");
 387       break;
 388    default:
 389       DEBUG_Printf(DBG_CHN_MESG, "Exception %lx\n", GetExceptionCode());
 390       break;
 391    }
 392
 393    return EXCEPTION_EXECUTE_HANDLER;
 394 }
 395
 396 /***********************************************************************
 397  *           DEBUG_Parser
 398  *
 399  * Debugger editline parser
 400  */
 401 BOOL    DEBUG_Parser(void)
 402 {
 403     BOOL        ret_ok;
 404     BOOL        ret = TRUE;
 405 #ifdef YYDEBUG
 406     yydebug = 0;
 407 #endif
 408     yyin = stdin;
 409
 410     ret_ok = FALSE;
 411     do {
 412        __TRY {
 413           issue_prompt();
 414           ret_ok = TRUE;
 415           if ((ret = yyparse())) {
 416              DEBUG_FlushSymbols();
 417           }
 418        } __EXCEPT(wine_dbg_cmd) {
 419           ret_ok = FALSE;
 420        }
 421        __ENDTRY;
 422
 423     } while (!ret_ok);
 424     return ret;
 425 }
 426
 427 int yyerror(char* s)
 428 {
 429    DEBUG_Printf(DBG_CHN_MESG, "%s\n", s);
 430    return 0;
 431 }