git.oblomov.eu Git - wine/blob - dlls/vbscript/parser.y

   1 /*
   2  * Copyright 2011 Jacek Caban for CodeWeavers
   3  *
   4  * This library is free software; you can redistribute it and/or
   5  * modify it under the terms of the GNU Lesser General Public
   6  * License as published by the Free Software Foundation; either
   7  * version 2.1 of the License, or (at your option) any later version.
   8  *
   9  * This library is distributed in the hope that it will be useful,
  10  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  11  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12  * Lesser General Public License for more details.
  13  *
  14  * You should have received a copy of the GNU Lesser General Public
  15  * License along with this library; if not, write to the Free Software
  16  * Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA
  17  */
  18
  19 %{
  20
  21 #include "vbscript.h"
  22 #include "parse.h"
  23
  24 #include "wine/debug.h"
  25
  26 WINE_DEFAULT_DEBUG_CHANNEL(vbscript);
  27
  28
  29 #define YYLEX_PARAM ctx
  30 #define YYPARSE_PARAM ctx
  31
  32 static int parser_error(const char*);
  33
  34  static void parse_complete(parser_ctx_t*,BOOL);
  35
  36 static void source_add_statement(parser_ctx_t*,statement_t*);
  37
  38 static void *new_expression(parser_ctx_t*,expression_type_t,size_t);
  39 static expression_t *new_bool_expression(parser_ctx_t*,VARIANT_BOOL);
  40 static expression_t *new_string_expression(parser_ctx_t*,const WCHAR*);
  41 static expression_t *new_long_expression(parser_ctx_t*,expression_type_t,LONG);
  42 static expression_t *new_double_expression(parser_ctx_t*,double);
  43 static expression_t *new_unary_expression(parser_ctx_t*,expression_type_t,expression_t*);
  44 static expression_t *new_binary_expression(parser_ctx_t*,expression_type_t,expression_t*,expression_t*);
  45
  46 static member_expression_t *new_member_expression(parser_ctx_t*,expression_t*,const WCHAR*);
  47
  48 static statement_t *new_call_statement(parser_ctx_t*,member_expression_t*);
  49 static statement_t *new_assign_statement(parser_ctx_t*,member_expression_t*,expression_t*);
  50 static statement_t *new_dim_statement(parser_ctx_t*,dim_decl_t*);
  51 static statement_t *new_if_statement(parser_ctx_t*,expression_t*,statement_t*,elseif_decl_t*,statement_t*);
  52 static statement_t *new_function_statement(parser_ctx_t*,function_decl_t*);
  53
  54 static dim_decl_t *new_dim_decl(parser_ctx_t*,const WCHAR*,dim_decl_t*);
  55 static elseif_decl_t *new_elseif_decl(parser_ctx_t*,expression_t*,statement_t*);
  56 static function_decl_t *new_function_decl(parser_ctx_t*,const WCHAR*,function_type_t,arg_decl_t*,statement_t*);
  57 static arg_decl_t *new_argument_decl(parser_ctx_t*,const WCHAR*,BOOL);
  58
  59 #define CHECK_ERROR if(((parser_ctx_t*)ctx)->hres != S_OK) YYABORT
  60
  61 %}
  62
  63 %pure_parser
  64 %start Program
  65
  66 %union {
  67     const WCHAR *string;
  68     statement_t *statement;
  69     expression_t *expression;
  70     member_expression_t *member;
  71     elseif_decl_t *elseif;
  72     dim_decl_t *dim_decl;
  73     function_decl_t *func_decl;
  74     arg_decl_t *arg_decl;
  75     LONG lng;
  76     BOOL bool;
  77     double dbl;
  78 }
  79
  80 %token tEOF tNL tREM tEMPTYBRACKETS
  81 %token tTRUE tFALSE
  82 %token tNOT tAND tOR tXOR tEQV tIMP tNEQ
  83 %token tIS tLTEQ tGTEQ tMOD
  84 %token tCALL tDIM tSUB tFUNCTION tPROPERTY tGET tLET
  85 %token tIF tELSE tELSEIF tEND tTHEN tEXIT
  86 %token tWHILE tWEND tDO tLOOP tUNTIL
  87 %token tBYREF tBYVAL
  88 %token tOPTION tEXPLICIT
  89 %token tSTOP
  90 %token tNOTHING tEMPTY tNULL
  91 %token tCLASS tSET tNEW tPUBLIC tPRIVATE tDEFAULT tME
  92 %token tERROR tNEXT tON tRESUME tGOTO
  93 %token <string> tIdentifier tString
  94 %token <lng> tLong tShort
  95 %token <dbl> tDouble
  96
  97 %type <statement> Statement StatementNl StatementsNl StatementsNl_opt IfStatement Else_opt
  98 %type <expression> Expression LiteralExpression PrimaryExpression EqualityExpression CallExpression
  99 %type <expression> ConcatExpression AdditiveExpression ModExpression IntdivExpression MultiplicativeExpression ExpExpression
 100 %type <expression> NotExpression UnaryExpression
 101 %type <member> MemberExpression
 102 %type <expression> Arguments_opt ArgumentList_opt ArgumentList
 103 %type <bool> OptionExplicit_opt
 104 %type <arg_decl> ArgumentsDecl_opt ArgumentDeclList ArgumentDecl
 105 %type <func_decl> FunctionDecl
 106 %type <elseif> ElseIfs_opt ElseIfs ElseIf
 107 %type <dim_decl> DimDeclList
 108
 109 %%
 110
 111 Program
 112     : OptionExplicit_opt SourceElements tEOF    { parse_complete(ctx, $1); }
 113
 114 OptionExplicit_opt
 115     : /* empty */                { $$ = FALSE; }
 116     | tOPTION tEXPLICIT tNL      { $$ = TRUE; }
 117
 118 SourceElements
 119     : /* empty */
 120     | SourceElements StatementNl    { source_add_statement(ctx, $2); }
 121
 122 StatementsNl_opt
 123     : /* empty */                           { $$ = NULL; }
 124     | StatementsNl                          { $$ = $1; }
 125
 126 StatementsNl
 127     : StatementNl                           { $$ = $1; }
 128     | StatementNl StatementsNl              { $1->next = $2; $$ = $1; }
 129
 130 StatementNl
 131     : Statement tNL                 { $$ = $1; }
 132
 133 Statement
 134     : MemberExpression ArgumentList_opt     { $1->args = $2; $$ = new_call_statement(ctx, $1); CHECK_ERROR; }
 135     | tCALL MemberExpression Arguments_opt  { $2->args = $3; $$ = new_call_statement(ctx, $2); CHECK_ERROR; }
 136     | MemberExpression Arguments_opt '=' Expression
 137                                             { $1->args = $2; $$ = new_assign_statement(ctx, $1, $4); CHECK_ERROR; }
 138     | tDIM DimDeclList                      { $$ = new_dim_statement(ctx, $2); CHECK_ERROR; }
 139     | IfStatement                           { $$ = $1; }
 140     | FunctionDecl                          { $$ = new_function_statement(ctx, $1); CHECK_ERROR; }
 141
 142 MemberExpression
 143     : tIdentifier                           { $$ = new_member_expression(ctx, NULL, $1); CHECK_ERROR; }
 144     | CallExpression '.' tIdentifier        { $$ = new_member_expression(ctx, $1, $3); CHECK_ERROR; }
 145
 146 DimDeclList /* FIXME: Support arrays */
 147     : tIdentifier                           { $$ = new_dim_decl(ctx, $1, NULL); CHECK_ERROR; }
 148     | tIdentifier ',' DimDeclList           { $$ = new_dim_decl(ctx, $1, $3); CHECK_ERROR; }
 149
 150 IfStatement
 151     : tIF Expression tTHEN tNL StatementsNl ElseIfs_opt Else_opt tEND tIF
 152                                             { $$ = new_if_statement(ctx, $2, $5, $6, $7); CHECK_ERROR; }
 153     /* FIXME: short if statement */
 154
 155 ElseIfs_opt
 156     : /* empty */                           { $$ = NULL; }
 157     | ElseIfs                               { $$ = $1; }
 158
 159 ElseIfs
 160     : ElseIf                                { $$ = $1; }
 161     | ElseIf ElseIfs                        { $1->next = $2; $$ = $1; }
 162
 163 ElseIf
 164     : tELSEIF Expression tTHEN tNL StatementsNl
 165                                             { $$ = new_elseif_decl(ctx, $2, $5); }
 166
 167 Else_opt
 168     : /* empty */                           { $$ = NULL; }
 169     | tELSE tNL StatementsNl                { $$ = $3; }
 170
 171 Arguments_opt
 172     : EmptyBrackets_opt             { $$ = NULL; }
 173     | '(' ArgumentList ')'          { $$ = $2; }
 174
 175 ArgumentList_opt
 176     : EmptyBrackets_opt             { $$ = NULL; }
 177     | ArgumentList                  { $$ = $1; }
 178
 179 ArgumentList
 180     : Expression                    { $$ = $1; }
 181     | Expression ',' ArgumentList   { $1->next = $3; $$ = $1; }
 182
 183 EmptyBrackets_opt
 184     : /* empty */
 185     | tEMPTYBRACKETS
 186
 187 Expression
 188     : NotExpression                 { $$ = $1; }
 189
 190 NotExpression
 191     : EqualityExpression            { $$ = $1; }
 192     | tNOT NotExpression            { $$ = new_unary_expression(ctx, EXPR_NOT, $2); CHECK_ERROR; }
 193
 194 EqualityExpression
 195     : ConcatExpression                          { $$ = $1; }
 196     | EqualityExpression '=' ConcatExpression   { $$ = new_binary_expression(ctx, EXPR_EQUAL, $1, $3); CHECK_ERROR; }
 197     | EqualityExpression tNEQ ConcatExpression  { $$ = new_binary_expression(ctx, EXPR_NEQUAL, $1, $3); CHECK_ERROR; }
 198
 199 ConcatExpression
 200     : AdditiveExpression                        { $$ = $1; }
 201     | ConcatExpression '&' AdditiveExpression   { $$ = new_binary_expression(ctx, EXPR_CONCAT, $1, $3); CHECK_ERROR; }
 202
 203 AdditiveExpression
 204     : ModExpression                             { $$ = $1; }
 205     | AdditiveExpression '+' ModExpression      { $$ = new_binary_expression(ctx, EXPR_ADD, $1, $3); CHECK_ERROR; }
 206     | AdditiveExpression '-' ModExpression      { $$ = new_binary_expression(ctx, EXPR_SUB, $1, $3); CHECK_ERROR; }
 207
 208 ModExpression
 209     : IntdivExpression                          { $$ = $1; }
 210     | ModExpression tMOD IntdivExpression       { $$ = new_binary_expression(ctx, EXPR_MOD, $1, $3); CHECK_ERROR; }
 211
 212 IntdivExpression
 213     : MultiplicativeExpression                  { $$ = $1; }
 214     | IntdivExpression '\\' MultiplicativeExpression
 215                                                 { $$ = new_binary_expression(ctx, EXPR_IDIV, $1, $3); CHECK_ERROR; }
 216
 217 MultiplicativeExpression
 218     : ExpExpression                             { $$ = $1; }
 219     | MultiplicativeExpression '*' ExpExpression
 220                                                 { $$ = new_binary_expression(ctx, EXPR_MUL, $1, $3); CHECK_ERROR; }
 221     | MultiplicativeExpression '/' ExpExpression
 222                                                 { $$ = new_binary_expression(ctx, EXPR_DIV, $1, $3); CHECK_ERROR; }
 223
 224 ExpExpression
 225     : UnaryExpression                           { $$ = $1; }
 226     | ExpExpression '^' UnaryExpression         { $$ = new_binary_expression(ctx, EXPR_EXP, $1, $3); CHECK_ERROR; }
 227
 228 UnaryExpression
 229     : LiteralExpression             { $$ = $1; }
 230     | CallExpression                { $$ = $1; }
 231     | '-' UnaryExpression           { $$ = new_unary_expression(ctx, EXPR_NEG, $2); CHECK_ERROR; }
 232
 233 CallExpression
 234     : PrimaryExpression                 { $$ = $1; }
 235     | MemberExpression Arguments_opt    { $1->args = $2; $$ = &$1->expr; }
 236
 237 LiteralExpression
 238     : tTRUE                         { $$ = new_bool_expression(ctx, VARIANT_TRUE); CHECK_ERROR; }
 239     | tFALSE                        { $$ = new_bool_expression(ctx, VARIANT_FALSE); CHECK_ERROR; }
 240     | tString                       { $$ = new_string_expression(ctx, $1); CHECK_ERROR; }
 241     | tShort                        { $$ = new_long_expression(ctx, EXPR_USHORT, $1); CHECK_ERROR; }
 242     | '0'                           { $$ = new_long_expression(ctx, EXPR_USHORT, 0); CHECK_ERROR; }
 243     | tLong                         { $$ = new_long_expression(ctx, EXPR_ULONG, $1); CHECK_ERROR; }
 244     | tDouble                       { $$ = new_double_expression(ctx, $1); CHECK_ERROR; }
 245     | tEMPTY                        { $$ = new_expression(ctx, EXPR_EMPTY, 0); CHECK_ERROR; }
 246     | tNULL                         { $$ = new_expression(ctx, EXPR_NULL, 0); CHECK_ERROR; }
 247
 248 PrimaryExpression
 249     : '(' Expression ')'            { $$ = $2; }
 250
 251 FunctionDecl
 252     : /* Storage_opt */ tSUB tIdentifier ArgumentsDecl_opt tNL StatementsNl_opt tEND tSUB
 253                                     { $$ = new_function_decl(ctx, $2, FUNC_SUB, $3, $5); CHECK_ERROR; }
 254
 255 ArgumentsDecl_opt
 256     : EmptyBrackets_opt                         { $$ = NULL; }
 257     | '(' ArgumentDeclList ')'                  { $$ = $2; }
 258
 259 ArgumentDeclList
 260     : ArgumentDecl                              { $$ = $1; }
 261     | ArgumentDecl ',' ArgumentDeclList         { $1->next = $3; $$ = $1; }
 262
 263 ArgumentDecl
 264     : tIdentifier                               { $$ = new_argument_decl(ctx, $1, TRUE); }
 265     | tBYREF tIdentifier                        { $$ = new_argument_decl(ctx, $2, TRUE); }
 266     | tBYVAL tIdentifier                        { $$ = new_argument_decl(ctx, $2, FALSE); }
 267
 268 %%
 269
 270 static int parser_error(const char *str)
 271 {
 272     return 0;
 273 }
 274
 275 static void source_add_statement(parser_ctx_t *ctx, statement_t *stat)
 276 {
 277     if(ctx->stats) {
 278         ctx->stats_tail->next = stat;
 279         ctx->stats_tail = stat;
 280     }else {
 281         ctx->stats = ctx->stats_tail = stat;
 282     }
 283 }
 284
 285 static void parse_complete(parser_ctx_t *ctx, BOOL option_explicit)
 286 {
 287     ctx->parse_complete = TRUE;
 288     ctx->option_explicit = option_explicit;
 289 }
 290
 291 static void *new_expression(parser_ctx_t *ctx, expression_type_t type, size_t size)
 292 {
 293     expression_t *expr;
 294
 295     expr = parser_alloc(ctx, size ? size : sizeof(*expr));
 296     if(expr) {
 297         expr->type = type;
 298         expr->next = NULL;
 299     }
 300
 301     return expr;
 302 }
 303
 304 static expression_t *new_bool_expression(parser_ctx_t *ctx, VARIANT_BOOL value)
 305 {
 306     bool_expression_t *expr;
 307
 308     expr = new_expression(ctx, EXPR_BOOL, sizeof(*expr));
 309     if(!expr)
 310         return NULL;
 311
 312     expr->value = value;
 313     return &expr->expr;
 314 }
 315
 316 static expression_t *new_string_expression(parser_ctx_t *ctx, const WCHAR *value)
 317 {
 318     string_expression_t *expr;
 319
 320     expr = new_expression(ctx, EXPR_STRING, sizeof(*expr));
 321     if(!expr)
 322         return NULL;
 323
 324     expr->value = value;
 325     return &expr->expr;
 326 }
 327
 328 static expression_t *new_long_expression(parser_ctx_t *ctx, expression_type_t type, LONG value)
 329 {
 330     int_expression_t *expr;
 331
 332     expr = new_expression(ctx, type, sizeof(*expr));
 333     if(!expr)
 334         return NULL;
 335
 336     expr->value = value;
 337     return &expr->expr;
 338 }
 339
 340 static expression_t *new_double_expression(parser_ctx_t *ctx, double value)
 341 {
 342     double_expression_t *expr;
 343
 344     expr = new_expression(ctx, EXPR_DOUBLE, sizeof(*expr));
 345     if(!expr)
 346         return NULL;
 347
 348     expr->value = value;
 349     return &expr->expr;
 350 }
 351
 352 static expression_t *new_unary_expression(parser_ctx_t *ctx, expression_type_t type, expression_t *subexpr)
 353 {
 354     unary_expression_t *expr;
 355
 356     expr = new_expression(ctx, type, sizeof(*expr));
 357     if(!expr)
 358         return NULL;
 359
 360     expr->subexpr = subexpr;
 361     return &expr->expr;
 362 }
 363
 364 static expression_t *new_binary_expression(parser_ctx_t *ctx, expression_type_t type, expression_t *left, expression_t *right)
 365 {
 366     binary_expression_t *expr;
 367
 368     expr = new_expression(ctx, type, sizeof(*expr));
 369     if(!expr)
 370         return NULL;
 371
 372     expr->left = left;
 373     expr->right = right;
 374     return &expr->expr;
 375 }
 376
 377 static member_expression_t *new_member_expression(parser_ctx_t *ctx, expression_t *obj_expr, const WCHAR *identifier)
 378 {
 379     member_expression_t *expr;
 380
 381     expr = new_expression(ctx, EXPR_MEMBER, sizeof(*expr));
 382     if(!expr)
 383         return NULL;
 384
 385     expr->obj_expr = obj_expr;
 386     expr->identifier = identifier;
 387     expr->args = NULL;
 388     return expr;
 389 }
 390
 391 static void *new_statement(parser_ctx_t *ctx, statement_type_t type, unsigned size)
 392 {
 393     statement_t *stat;
 394
 395     stat = parser_alloc(ctx, size);
 396     if(stat) {
 397         stat->type = type;
 398         stat->next = NULL;
 399     }
 400
 401     return stat;
 402 }
 403
 404 static statement_t *new_call_statement(parser_ctx_t *ctx, member_expression_t *expr)
 405 {
 406     call_statement_t *stat;
 407
 408     stat = new_statement(ctx, STAT_CALL, sizeof(*stat));
 409     if(!stat)
 410         return NULL;
 411
 412     stat->expr = expr;
 413     return &stat->stat;
 414 }
 415
 416 static statement_t *new_assign_statement(parser_ctx_t *ctx, member_expression_t *left, expression_t *right)
 417 {
 418     assign_statement_t *stat;
 419
 420     stat = new_statement(ctx, STAT_ASSIGN, sizeof(*stat));
 421     if(!stat)
 422         return NULL;
 423
 424     stat->member_expr = left;
 425     stat->value_expr = right;
 426     return &stat->stat;
 427 }
 428
 429 static dim_decl_t *new_dim_decl(parser_ctx_t *ctx, const WCHAR *name, dim_decl_t *next)
 430 {
 431     dim_decl_t *decl;
 432
 433     decl = parser_alloc(ctx, sizeof(*decl));
 434     if(!decl)
 435         return NULL;
 436
 437     decl->name = name;
 438     decl->next = next;
 439     return decl;
 440 }
 441
 442 static statement_t *new_dim_statement(parser_ctx_t *ctx, dim_decl_t *decls)
 443 {
 444     dim_statement_t *stat;
 445
 446     stat = new_statement(ctx, STAT_DIM, sizeof(*stat));
 447     if(!stat)
 448         return NULL;
 449
 450     stat->dim_decls = decls;
 451     return &stat->stat;
 452 }
 453
 454 static elseif_decl_t *new_elseif_decl(parser_ctx_t *ctx, expression_t *expr, statement_t *stat)
 455 {
 456     elseif_decl_t *decl;
 457
 458     decl = parser_alloc(ctx, sizeof(*decl));
 459     if(!decl)
 460         return NULL;
 461
 462     decl->expr = expr;
 463     decl->stat = stat;
 464     decl->next = NULL;
 465     return decl;
 466 }
 467
 468 static statement_t *new_if_statement(parser_ctx_t *ctx, expression_t *expr, statement_t *if_stat, elseif_decl_t *elseif_decl,
 469         statement_t *else_stat)
 470 {
 471     if_statement_t *stat;
 472
 473     stat = new_statement(ctx, STAT_IF, sizeof(*stat));
 474     if(!stat)
 475         return NULL;
 476
 477     stat->expr = expr;
 478     stat->if_stat = if_stat;
 479     stat->elseifs = elseif_decl;
 480     stat->else_stat = else_stat;
 481     return &stat->stat;
 482 }
 483
 484 static arg_decl_t *new_argument_decl(parser_ctx_t *ctx, const WCHAR *name, BOOL by_ref)
 485 {
 486     arg_decl_t *arg_decl;
 487
 488     arg_decl = parser_alloc(ctx, sizeof(*arg_decl));
 489     if(!arg_decl)
 490         return NULL;
 491
 492     arg_decl->name = name;
 493     arg_decl->by_ref = by_ref;
 494     arg_decl->next = NULL;
 495     return arg_decl;
 496 }
 497
 498 static function_decl_t *new_function_decl(parser_ctx_t *ctx, const WCHAR *name, function_type_t type,
 499         arg_decl_t *arg_decl, statement_t *body)
 500 {
 501     function_decl_t *decl;
 502
 503     decl = parser_alloc(ctx, sizeof(*decl));
 504     if(!decl)
 505         return NULL;
 506
 507     decl->name = name;
 508     decl->type = type;
 509     decl->args = arg_decl;
 510     decl->body = body;
 511     return decl;
 512 }
 513
 514 static statement_t *new_function_statement(parser_ctx_t *ctx, function_decl_t *decl)
 515 {
 516     function_statement_t *stat;
 517
 518     stat = new_statement(ctx, STAT_FUNC, sizeof(*stat));
 519     if(!stat)
 520         return NULL;
 521
 522     stat->func_decl = decl;
 523     return &stat->stat;
 524 }
 525
 526 void *parser_alloc(parser_ctx_t *ctx, size_t size)
 527 {
 528     void *ret;
 529
 530     ret = vbsheap_alloc(&ctx->heap, size);
 531     if(!ret)
 532         ctx->hres = E_OUTOFMEMORY;
 533     return ret;
 534 }
 535
 536 HRESULT parse_script(parser_ctx_t *ctx, const WCHAR *code)
 537 {
 538     ctx->code = ctx->ptr = code;
 539     ctx->end = ctx->code + strlenW(ctx->code);
 540
 541     vbsheap_init(&ctx->heap);
 542
 543     ctx->parse_complete = FALSE;
 544     ctx->hres = S_OK;
 545
 546     ctx->last_token = tNL;
 547     ctx->last_nl = 0;
 548     ctx->stats = ctx->stats_tail = NULL;
 549     ctx->option_explicit = FALSE;
 550
 551     parser_parse(ctx);
 552
 553     if(FAILED(ctx->hres))
 554         return ctx->hres;
 555     if(!ctx->parse_complete) {
 556         FIXME("parser failed on parsing %s\n", debugstr_w(ctx->ptr));
 557         return E_FAIL;
 558     }
 559
 560     return S_OK;
 561 }
 562
 563 void parser_release(parser_ctx_t *ctx)
 564 {
 565     vbsheap_free(&ctx->heap);
 566 }