git.oblomov.eu Git - wine/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Author: Michael Patra   <micky@marie.physik.tu-berlin.de>
   3 dnl                         <patra@itp1.physik.tu-berlin.de>
   4 dnl Ported to autoconf 2.5x by bero@redhat.com
   5 AC_REVISION([configure.in 1.00])
   6 AC_INIT(controls/edit.c)
   7 AC_CONFIG_HEADER(include/config.h)
   8 AC_CONFIG_AUX_DIR(tools)
   9
  10 dnl **** Command-line arguments ****
  11
  12 dnl Default values
  13 LIBEXT=so       # library type .so or .a
  14 TRACE_MSGS=yes  # the TRACE() macro
  15 DEBUG_MSGS=yes  # the TRACE(), WARN(), and FIXME() macros.
  16 CURSES=yes
  17 OPENGL=normal
  18
  19 AC_ARG_ENABLE(debug,
  20 [  --disable-debug         compile out all debugging messages],
  21 [if test "$enableval" = "no"; then DEBUG_MSGS="no"; fi])
  22
  23 AC_ARG_ENABLE(opengl,
  24 [  --enable-opengl         force usage of OpenGL even if the latter is thread-safe via pthread],
  25 [if test "$enableval" = "no"; then OPENGL="no"; elif test "$enableval" = "yes"; then OPENGL="yes"; fi])
  26
  27 AC_ARG_ENABLE(trace,
  28 [  --disable-trace         compile out TRACE messages],
  29 [if test "$enableval" = "no"; then TRACE_MSGS="no"; fi])
  30
  31 AC_ARG_WITH(curses,
  32 [  --without-curses        do not use curses],
  33 [if test "$withval" = "no"; then CURSES="no"; fi])
  34
  35 AC_ARG_WITH(reentrant-x,
  36 [  --without-reentrant-x   compile for use with non-reentrant X libraries])
  37
  38 AC_SUBST(OPTIONS)
  39
  40 if test "$DEBUG_MSGS" = "no"
  41 then
  42     AC_DEFINE(NO_DEBUG_MSGS, 1, [Define if all debug messages are to be compiled out])
  43 fi
  44
  45 if test "$TRACE_MSGS" = "no" -o "$DEBUG_MSGS" = "no"
  46 then
  47     AC_DEFINE(NO_TRACE_MSGS, 1, [Define if TRACE messages are to be compiled out])
  48 fi
  49
  50 dnl **** Check for some programs ****
  51
  52 AC_PROG_MAKE_SET
  53 AC_PROG_CC
  54 AC_PROG_CPP
  55 AC_PATH_XTRA
  56 AC_PROG_YACC
  57 AC_PROG_LEX
  58 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
  59 if test "$XLEX" = "none"
  60 then
  61         echo "*** Error: No suitable lex found. ***"
  62         echo "    Please install the 'flex' package."
  63         exit 1
  64 fi
  65 AC_PROG_RANLIB
  66 AC_PROG_INSTALL
  67 AC_PROG_LN_S
  68 AC_CHECK_PROG(C2MAN,c2man,c2man,\$(TOPSRCDIR)/tools/c2man.pl)
  69 AC_PATH_PROG(LDCONFIG, ldconfig, true, /sbin:/usr/sbin:$PATH)
  70 AC_CYGWIN
  71 AC_CHECK_PROG(DLLWRAP,dllwrap,dllwrap,false)
  72
  73 dnl Check for lint
  74 AC_CHECK_PROGS(LINT, lclint lint)
  75 if test "$LINT" = "lint"
  76 then
  77   LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
  78   dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
  79 fi
  80 AC_SUBST(LINT)
  81 AC_SUBST(LINTFLAGS)
  82
  83 if test "$CYGWIN" = "yes"
  84 then
  85     LDCOMBINE="ld -r --enable-stdcall-fixup"
  86 else
  87     LDCOMBINE="ld -r"
  88 fi
  89 AC_SUBST(LDCOMBINE)
  90
  91 dnl **** Check for some libraries ****
  92
  93 dnl Check for -lm
  94 AC_CHECK_LIB(m,sqrt)
  95 dnl Check for -li386 for NetBSD and OpenBSD
  96 AC_CHECK_LIB(i386,i386_set_ldt)
  97 dnl Check for -lossaudio for NetBSD
  98 AC_CHECK_LIB(ossaudio,_oss_ioctl)
  99 dnl Check for -lw for Solaris
 100 AC_CHECK_FUNCS(iswalnum,,AC_CHECK_LIB(w,iswalnum))
 101 dnl Check for -lnsl for Solaris
 102 AC_CHECK_FUNCS(gethostbyname,,AC_CHECK_LIB(nsl,gethostbyname))
 103 dnl Check for -lsocket for Solaris
 104 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
 105 dnl Check for -lxpg4 for FreeBSD
 106 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
 107 dnl Check for -lmmap for OS/2
 108 AC_CHECK_LIB(mmap,mmap)
 109 dnl Check for openpty
 110 AC_CHECK_FUNCS(openpty,,
 111         [AC_CHECK_LIB(util,openpty,
 112                 [AC_DEFINE(HAVE_OPENPTY)
 113                 LIBS="$LIBS -lutil"]
 114         )])
 115
 116 AC_CHECK_HEADERS(dlfcn.h,
 117     [AC_CHECK_FUNCS(dlopen,,
 118         [AC_CHECK_LIB(dl,dlopen,
 119                      [AC_DEFINE(HAVE_DLOPEN,1,[Define if you have dlopen])
 120                      LIBS="$LIBS -ldl"],
 121                      LIBEXT="a")]
 122         )],
 123         LIBEXT="a"
 124     )
 125
 126 JPEGLIB=""
 127 AC_SUBST(JPEGLIB)
 128 AC_CHECK_HEADERS(jpeglib.h,
 129     AC_CHECK_LIB(jpeg,jpeg_start_decompress,
 130         AC_DEFINE(HAVE_LIBJPEG,1,[Define if you have libjpeg including devel headers])
 131         JPEGLIB="-ljpeg"
 132     )
 133 )
 134
 135
 136 AC_SUBST(XLIB)
 137 AC_SUBST(XFILES)
 138 XFILES=""
 139 AC_SUBST(OPENGLFILES)
 140 OPENGLFILES=""
 141 AC_SUBST(GLU32FILES)
 142 GLU32FILES=""
 143 if test "$have_x" = "yes"
 144 then
 145     XLIB="-lXext -lX11"
 146     ac_save_CPPFLAGS="$CPPFLAGS"
 147     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 148
 149     dnl *** Check for -lXpm
 150     AC_CHECK_HEADERS(X11/xpm.h,
 151       [ dnl *** If X11/xpm.h exists...
 152         AC_CHECK_LIB(Xpm, XpmCreatePixmapFromData,
 153           [ AC_DEFINE(HAVE_LIBXXPM, 1, [Define if you have the Xpm library])
 154             X_PRE_LIBS="$X_PRE_LIBS -lXpm"],,
 155           $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 156         )
 157       ],
 158       [ dnl *** If X11/xpm.h does not exist...
 159         dnl NOTE: autoconf does not allow commas inside the third
 160         dnl       parameter to AC_CHECK_HEADERS, due to some quoting
 161         dnl       magic it does.
 162         echo "Install the following packages:"
 163         echo "Red Hat < 7.1     :       xpm xpm-devel"
 164         echo "Red Hat >= 7.1    :       XFree86-devel"
 165         echo "Caldera OpenLinux :       xpm xpm-devel xpm-devel-static"
 166         echo "SuSE              :       xpm"
 167         echo "Debian/Corel Linux:       xpm4g xpm4g-dev"
 168         echo
 169         echo "Or get the sources from ftp.x.org and all its mirror sites from "
 170         echo "the directory /contrib/libraries."
 171         echo
 172         exit 1
 173       ]
 174     )
 175
 176     dnl *** All of the following tests require X11/Xlib.h
 177     AC_CHECK_HEADERS(X11/Xlib.h,
 178       [
 179         dnl *** Check for X keyboard extension
 180         AC_CHECK_HEADERS(X11/XKBlib.h,
 181             [ dnl *** If X11/XKBlib.h exists...
 182               AC_CHECK_LIB(X11, XkbQueryExtension,
 183               AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
 184               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 185             ],
 186             AC_MSG_WARN([XKB extension not found!!])
 187         )
 188
 189         dnl *** Check for X Shm extension
 190         AC_CHECK_HEADERS(X11/extensions/XShm.h,
 191             [ dnl *** If X11/extensions/XShm.h exists...
 192               AC_CHECK_LIB(Xext, XShmQueryExtension,
 193               AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
 194               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 195             ],
 196             AC_MSG_WARN([Xshm extension not found!!])
 197         )
 198
 199         dnl *** Check for X shape extension
 200         AC_CHECK_HEADERS(X11/extensions/shape.h,
 201             [ dnl *** If X11/extensions/shape.h exists...
 202               AC_CHECK_LIB(Xext,XShapeQueryExtension,
 203               AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
 204               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 205             ],
 206             AC_MSG_WARN([XShape extension not found!!])
 207         )
 208
 209         dnl *** Check for XFree86 DGA / DGA 2.0 extension
 210         AC_CHECK_HEADERS(X11/extensions/xf86dga.h,
 211             [ dnl *** If X11/extensions/xf86dga.h exists, check
 212               dnl *** for XDGAQueryExtension()...
 213               AC_CHECK_LIB(Xxf86dga, XDGAQueryExtension,
 214                 [ dnl *** If found...
 215                   AC_DEFINE(HAVE_LIBXXF86DGA2, 1,
 216                             [Define if you have the Xxf86dga library version 2])
 217                   X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
 218                ],
 219                 [ dnl *** If not found, look for XF86DGAQueryExtension()
 220                   dnl *** instead (DGA 2.0 not found)...
 221                   AC_CHECK_LIB(Xxf86dga, XF86DGAQueryExtension,
 222                     [ AC_DEFINE(HAVE_LIBXXF86DGA, 1,
 223                                 [Define if you have the Xxf86dga library version 1])
 224                       X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
 225                     ],,
 226                     $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 227                   )
 228                 ],
 229                 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 230               )
 231             ],
 232             AC_MSG_WARN([DGA extension not found!!])
 233         )
 234
 235         dnl *** Check for XFree86 VMODE extension
 236         AC_CHECK_HEADERS(X11/extensions/xf86vmode.h,
 237             [ dnl *** If X11/extensions/xf86vmode.h exists...
 238                 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
 239                   [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
 240                      X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
 241                   ],,
 242                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 243                 )
 244             ],
 245             AC_MSG_WARN([XFree86 VMODE extension not found!!])
 246         )
 247
 248         dnl *** Check for XVideo extension supporting XvImages
 249         AC_CHECK_HEADERS(X11/extensions/Xvlib.h,
 250             [ dnl *** If X11/extensions/Xvlib.h exists...
 251                 AC_CHECK_LIB(Xv, XvShmCreateImage,
 252                   [ AC_DEFINE(HAVE_XVIDEO, 1, [Define if the X libraries support XVideo])
 253                      X_PRE_LIBS="$X_PRE_LIBS -lXv"
 254                   ],,
 255                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 256                 )
 257             ],
 258             AC_MSG_WARN([XVideo extension not found !!])
 259         )
 260
 261         dnl *** Check for XRender extension
 262         AC_CHECK_HEADERS(X11/extensions/Xrender.h,
 263             [ dnl *** If X11/extensions/Xrender.h exists...
 264                 AC_CHECK_LIB(Xrender, XRenderQueryExtension,
 265                   [ AC_DEFINE(HAVE_LIBXRENDER, 1, [Define if you have the XRender extension library])
 266                      X_PRE_LIBS="$X_PRE_LIBS -lXrender"
 267                   ],,
 268                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 269                 )
 270             ],
 271             AC_MSG_WARN([XRender extension not found !!])
 272         )
 273
 274       ]
 275     ) dnl *** End of X11/Xlib.h check
 276
 277     dnl Check for the presence of OpenGL
 278     if test $OPENGL = "yes" -o $OPENGL = "normal"
 279     then
 280         AC_CHECK_HEADERS(GL/gl.h GL/glx.h GL/glext.h)
 281         if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
 282         then
 283             dnl Check for some problems due to old Mesa versions
 284             AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_version_OK,
 285               AC_TRY_COMPILE(
 286                 [#include <GL/gl.h>],
 287                 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
 288                 [wine_cv_opengl_version_OK="yes"],
 289                 [wine_cv_opengl_version_OK="no"]
 290               )
 291             )
 292
 293             dnl Check for the thread-safety of the OpenGL library
 294             AC_CACHE_CHECK([for thread-safe OpenGL version],
 295                            wine_cv_opengl_version_threadsafe,
 296               [saved_libs=$LIBS
 297                LIBS="$X_LIBS -lGL"
 298                AC_TRY_LINK([],[pthread_getspecific();],
 299                               [wine_cv_opengl_version_threadsafe="yes"],
 300                               [wine_cv_opengl_version_threadsafe="no"])
 301                LIBS=$saved_libs]
 302             )
 303
 304             if test "$wine_cv_opengl_version_OK" = "yes" -a \( "$wine_cv_opengl_version_threadsafe" = "no" -o $OPENGL = "yes" \)
 305             then
 306                 dnl Check for the presence of the library
 307                 AC_CHECK_LIB(GL,glXCreateContext,
 308                              X_PRE_LIBS="$X_PRE_LIBS -lGL"
 309                              ,,
 310                              $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 311
 312                 if test $ac_cv_lib_GL_glXCreateContext = "yes"
 313                 then
 314
 315                         OPENGLFILES='$(OPENGLFILES)'
 316                         AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])
 317
 318                         AC_CHECK_LIB(GL,glXGetProcAddressARB,
 319                                      AC_DEFINE(HAVE_GLX_GETPROCADDRESS, 1,
 320                                                [Define if the OpenGL library supports the glXGetProcAddressARB call]),,
 321                                      $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 322
 323                         if test $ac_cv_lib_GL_glXGetProcAddressARB = "yes"
 324                         then
 325                                AC_CACHE_CHECK([for OpenGL extension functions prototypes], wine_cv_extension_prototypes,
 326                                   [AC_TRY_COMPILE([#include <GL/gl.h>
 327                                                   #ifdef HAVE_GL_GLEXT_H
 328                                                   # include <GL/glext.h>
 329                                                   #endif
 330                                                   ],
 331                                                  [PFNGLCOLORTABLEEXTPROC test_proc;],
 332                                                  [wine_cv_extension_prototypes="yes"],
 333                                                  [wine_cv_extension_prototypes="no"]
 334                                   )]
 335                                 )
 336                                 if test $wine_cv_extension_prototypes = "yes"
 337                                 then
 338                                     AC_DEFINE(HAVE_GLEXT_PROTOTYPES, 1,
 339                                               [Define if the OpenGL headers define extension typedefs])
 340                                 fi
 341                         fi
 342
 343                 fi
 344                 dnl Check for GLU32 library.
 345                 AC_CHECK_LIB(GLU,gluLookAt,
 346                              [X_PRE_LIBS="$X_PRE_LIBS -lGLU"
 347                              GLU32FILES='$(GLU32FILES)']
 348                              ,,
 349                              $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
 350                 )
 351              fi
 352          fi
 353     fi
 354
 355     CPPFLAGS="$ac_save_CPPFLAGS"
 356     XFILES='$(XFILES)'
 357 else
 358     XLIB=""
 359     X_CFLAGS=""
 360     X_LIBS=""
 361 fi
 362
 363 dnl **** Check which curses lib to use ***
 364 if test "$CURSES" = "yes"
 365 then
 366     AC_CHECK_HEADERS(ncurses.h,
 367         AC_CHECK_LIB(ncurses,waddch),
 368         [AC_CHECK_HEADERS(curses.h,[AC_CHECK_LIB(curses,waddch)])])
 369     AC_CHECK_FUNCS(getbkgd resizeterm)
 370 fi
 371
 372 CUPSLIBS=""
 373 dnl **** Check for CUPS ****
 374 wine_cv_warn_cups_h=no
 375 AC_CHECK_LIB(cups,cupsGetPPD,
 376         [AC_CHECK_HEADER(cups/cups.h,
 377             [AC_DEFINE(HAVE_CUPS, 1, [Define if we have CUPS])
 378             CUPSLIBS="-lcups"],
 379             wine_cv_warn_cups_h=yes)]
 380 )
 381 AC_SUBST(CUPSLIBS)
 382
 383 dnl **** Check for FreeType 2 ****
 384 AC_CHECK_LIB(freetype,FT_Init_FreeType,ft_lib=yes,ft_lib=no)
 385 if test "$ft_lib" = "no"
 386 then
 387     FREETYPELIBS=""
 388     FREETYPEINCL=""
 389     wine_cv_msg_freetype=no
 390 else
 391     AC_CHECK_PROG(ft_devel,freetype-config,freetype-config,no)
 392     if test "$ft_devel" = "no"
 393     then
 394         AC_CHECK_PROG(ft_devel2,freetype2-config,freetype2-config,no)
 395         if test "$ft_devel2" = "freetype2-config"
 396         then
 397                 ft_devel=$ft_devel2
 398         fi
 399     fi
 400     if test "$ft_devel" = "no"
 401     then
 402         FREETYPELIBS=""
 403         FREETYPEINCL=""
 404         wine_cv_msg_freetype=yes
 405     else
 406         AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
 407         FREETYPELIBS=`$ft_devel --libs`
 408         FREETYPEINCL=`$ft_devel --cflags`
 409         ac_save_CPPFLAGS="$CPPFLAGS"
 410         CPPFLAGS="$FREETYPEINCL $CPPFLAGS"
 411         AC_CHECK_HEADERS(freetype/freetype.h \
 412                          freetype/ftglyph.h \
 413                          freetype/tttables.h \
 414                          freetype/ftnames.h \
 415                          freetype/ftsnames.h \
 416                          freetype/ttnameid.h \
 417                          freetype/ftoutln.h \
 418                          freetype/internal/sfnt.h)
 419         CPPFLAGS="$ac_save_CPPFLAGS"
 420         wine_cv_msg_freetype=no
 421     fi
 422 fi
 423 AC_SUBST(FREETYPELIBS)
 424 AC_SUBST(FREETYPEINCL)
 425
 426 dnl **** Check for parport (currently Linux only) ****
 427 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
 428  AC_TRY_COMPILE(
 429    [#include <linux/ppdev.h>],
 430    [ioctl (1,PPCLAIM,0)],
 431    [ac_cv_c_ppdev="yes"],
 432    [ac_cv_c_ppdev="no"])
 433  )
 434 if test "$ac_cv_c_ppdev" = "yes"
 435 then
 436     AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
 437 fi
 438
 439 dnl **** Check for IPX (currently Linux only) ****
 440 AC_CACHE_CHECK([for GNU style IPX support], ac_cv_c_ipx_gnu,
 441  AC_TRY_COMPILE(
 442    [#include <sys/socket.h>
 443     #include <netipx/ipx.h>],
 444    [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
 445    [ac_cv_c_ipx_gnu="yes"],
 446    [ac_cv_c_ipx_gnu="no"])
 447  )
 448 if test "$ac_cv_c_ipx_gnu" = "yes"
 449 then
 450     AC_DEFINE(HAVE_IPX_GNU, 1, [Define if IPX should use netipx/ipx.h from libc])
 451 fi
 452
 453 if test "$ac_cv_c_ipx_gnu" = "no"
 454 then
 455  AC_CACHE_CHECK([for linux style IPX support], ac_cv_c_ipx_linux,
 456   AC_TRY_COMPILE(
 457     [#include <sys/socket.h>
 458      #include <asm/types.h>
 459      #include <linux/ipx.h>],
 460     [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
 461     [ac_cv_c_ipx_linux="yes"],
 462     [ac_cv_c_ipx_linux="no"])
 463   )
 464   if test "$ac_cv_c_ipx_linux" = "yes"
 465   then
 466       AC_DEFINE(HAVE_IPX_LINUX, 1, [Define if IPX includes are taken from Linux kernel])
 467   fi
 468 fi
 469
 470 dnl **** Check for Open Sound System ****
 471 AC_CHECK_HEADERS(sys/soundcard.h machine/soundcard.h soundcard.h, break)
 472
 473 AC_CACHE_CHECK([for Open Sound System],
 474         ac_cv_c_opensoundsystem,
 475         AC_TRY_COMPILE([
 476         #if defined(HAVE_SYS_SOUNDCARD_H)
 477                 #include <sys/soundcard.h>
 478         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 479                 #include <machine/soundcard.h>
 480         #elif defined(HAVE_SOUNDCARD_H)
 481                 #include <soundcard.h>
 482         #endif
 483         ],[
 484
 485 /* check for one of the Open Sound System specific SNDCTL_ defines */
 486 #if !defined(SNDCTL_DSP_STEREO)
 487 #error No open sound system
 488 #endif
 489 ],ac_cv_c_opensoundsystem="yes",ac_cv_c_opensoundsystem="no"))
 490
 491 if test "$ac_cv_c_opensoundsystem" = "yes"
 492 then
 493     AC_DEFINE(HAVE_OSS, 1, [Define if you have the Open Sound system])
 494 fi
 495
 496 AC_CACHE_CHECK([for Open Sound System/MIDI interface],
 497         ac_cv_c_opensoundsystem_midi,
 498         AC_TRY_COMPILE([
 499         #if defined(HAVE_SYS_SOUNDCARD_H)
 500                 #include <sys/soundcard.h>
 501         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 502                 #include <machine/soundcard.h>
 503         #elif defined(HAVE_SOUNDCARD_H)
 504                 #include <soundcard.h>
 505         #endif
 506         ],[
 507
 508 /* check for one of the Open Sound System specific SNDCTL_SEQ defines */
 509 #if !defined(SNDCTL_SEQ_SYNC)
 510 #error No open sound system MIDI interface
 511 #endif
 512 ],ac_cv_c_opensoundsystem_midi="yes",ac_cv_c_opensoundsystem_midi="no"))
 513
 514 if test "$ac_cv_c_opensoundsystem_midi" = "yes"
 515 then
 516     AC_DEFINE(HAVE_OSS_MIDI, 1, [Define if you have the Open Sound system (MIDI interface)])
 517 fi
 518
 519 dnl **** If ln -s doesn't work, use cp instead ****
 520 if test "$ac_cv_prog_LN_S" = "ln -s"; then : ; else LN_S=cp ; fi
 521
 522 dnl **** Check for broken glibc mmap64 ****
 523
 524 AC_CACHE_CHECK( [whether mmap64 works defined as mmap], ac_cv_mmap64_works,
 525         AC_TRY_RUN([
 526                 #define _FILE_OFFSET_BITS 64
 527                 #include <stdio.h>
 528                 #include <unistd.h>
 529                 #include <fcntl.h>
 530                 #include <sys/mman.h>
 531                 #include <errno.h>
 532
 533                 int main(int argc,char **argv) {
 534                         int fd = open("conftest.map",O_CREAT|O_RDWR,0600);
 535                         if (fd == -1) exit(1);
 536
 537                         unlink("conftest.map");
 538
 539                         write(fd,"test",4);
 540
 541                         if ((-1 == mmap(0,4,PROT_READ|PROT_WRITE,MAP_SHARED,fd,0)) &&
 542                             (errno == EINVAL)
 543                         ) {
 544                                 exit(1);
 545                         }
 546                         close(fd);
 547                         fprintf(stderr,"success!\n");
 548                         exit(0);
 549                 }
 550
 551         ],
 552     ac_cv_mmap64_works="yes",
 553     ac_cv_mmap64_works="no",
 554     ac_cv_mmap64_works="no") )
 555
 556 if test "$ac_cv_mmap64_works" = "yes"
 557 then
 558     AC_DEFINE(_FILE_OFFSET_BITS, 64, [Set this to 64 to enable 64-bit file support on Linux])
 559 fi
 560
 561 dnl **** Check for gcc strength-reduce bug ****
 562
 563 if test "x${GCC}" = "xyes"
 564 then
 565   CFLAGS="$CFLAGS -Wall"
 566   AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
 567                   AC_TRY_RUN([
 568 int     L[[4]] = {0,1,2,3};
 569 int main(void) {
 570   static int Array[[3]];
 571   unsigned int B = 3;
 572   int i;
 573   for(i=0; i<B; i++) Array[[i]] = i - 3;
 574   for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
 575   L[[i]] = 4;
 576
 577   exit( Array[[1]] != -2 || L[[2]] != 3);
 578 }],
 579     ac_cv_c_gcc_strength_bug="no",
 580     ac_cv_c_gcc_strength_bug="yes",
 581     ac_cv_c_gcc_strength_bug="yes") )
 582   if test "$ac_cv_c_gcc_strength_bug" = "yes"
 583   then
 584     CFLAGS="$CFLAGS -fno-strength-reduce"
 585   fi
 586
 587   dnl Check for -mpreferred-stack-boundary
 588   AC_CACHE_CHECK([for gcc -mpreferred-stack-boundary=2 support],
 589                  ac_cv_c_gcc_stack_boundary,
 590   [saved_cflags=$CFLAGS
 591   CFLAGS="$CFLAGS -mpreferred-stack-boundary=2"
 592   AC_TRY_COMPILE(,[return 0],ac_cv_c_gcc_stack_boundary="yes",ac_cv_c_gcc_stack_boundary="no")
 593   CFLAGS=$saved_cflags
 594   ])
 595   if test "$ac_cv_c_gcc_stack_boundary" = "yes"
 596   then
 597     CFLAGS="$CFLAGS -mpreferred-stack-boundary=2"
 598   fi
 599 fi
 600
 601 dnl **** Check if we need to place .type inside a .def directive ****
 602
 603 AC_CACHE_CHECK([whether .type must sit inside a .def directive],
 604                ac_cv_c_type_in_def,
 605 [saved_libs=$LIBS
 606 LIBS="conftest_asm.s $LIBS"
 607 cat > conftest_asm.s <<EOF
 608         .globl _ac_test
 609         .def _ac_test; .scl 2; .type 32; .endef
 610 _ac_test:
 611         .long 0
 612 EOF
 613 AC_TRY_LINK(,,ac_cv_c_type_in_def="yes",ac_cv_c_type_in_def="no")
 614 LIBS=$saved_libs])
 615 if test "$ac_cv_c_type_in_def" = "yes"
 616 then
 617   AC_DEFINE(NEED_TYPE_IN_DEF, 1, [Define if .type asm directive must be inside a .def directive])
 618 fi
 619
 620 dnl **** Check for underscore on external symbols ****
 621
 622 AC_CACHE_CHECK([whether external symbols need an underscore prefix],
 623                ac_cv_c_extern_prefix,
 624 [saved_libs=$LIBS
 625 LIBS="conftest_asm.s $LIBS"
 626 cat > conftest_asm.s <<EOF
 627         .globl _ac_test
 628 _ac_test:
 629         .long 0
 630 EOF
 631 AC_TRY_LINK([extern int ac_test;],[if (ac_test) return 1],
 632             ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no")
 633 LIBS=$saved_libs])
 634 if test "$ac_cv_c_extern_prefix" = "yes"
 635 then
 636   AC_DEFINE(NEED_UNDERSCORE_PREFIX, 1,
 637             [Define if symbols declared in assembly code need an underscore prefix])
 638 fi
 639
 640 dnl **** Check for .string in assembler ****
 641
 642 AC_CACHE_CHECK([whether assembler accepts .string],
 643                ac_cv_c_asm_string,
 644 [saved_libs=$LIBS
 645 LIBS="conftest_asm.s $LIBS"
 646 cat > conftest_asm.s <<EOF
 647         .string "test"
 648 EOF
 649 AC_TRY_LINK(,,ac_cv_c_asm_string="yes",ac_cv_c_asm_string="no")
 650 LIBS=$saved_libs])
 651 if test "$ac_cv_c_asm_string" = "yes"
 652 then
 653   AC_DEFINE(HAVE_ASM_STRING, 1, [Define to use .string instead of .ascii])
 654 fi
 655
 656 dnl **** Check for working dll ****
 657
 658 LDSHARED=""
 659 LDDLLFLAGS=""
 660 if test "$LIBEXT" = "so"
 661 then
 662   AC_CACHE_CHECK([whether we can build a GNU style ELF dll],
 663                  ac_cv_c_dll_gnuelf,
 664   [saved_cflags=$CFLAGS
 665   CFLAGS="$CFLAGS -fPIC -shared -Wl,-soname,conftest.so.1.0,-Bsymbolic"
 666   AC_TRY_LINK(,[return 1],ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")
 667   CFLAGS=$saved_cflags
 668   ])
 669   if test "$ac_cv_c_dll_gnuelf" = "yes"
 670   then
 671     LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"
 672     LDDLLFLAGS="-Wl,-Bsymbolic"
 673   else
 674     AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll,
 675                  ac_cv_c_dll_unixware,
 676     [saved_cflags=$CFLAGS
 677     CFLAGS="$CFLAGS -fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic"
 678     AC_TRY_LINK(,[return 1],ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")
 679     CFLAGS=$saved_cflags
 680     ])
 681     if test "$ac_cv_c_dll_unixware" = "yes"
 682     then
 683       LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
 684       LDDLLFLAGS="-Wl,-B,symbolic"
 685     fi
 686   fi
 687   if test "$ac_cv_c_dll_gnuelf" = "no" -a "$ac_cv_c_dll_unixware" = "no"
 688   then
 689     LIBEXT="a"
 690     if test "$DLLWRAP" = "dllwrap"; then
 691       dnl FIXME - check whether dllwrap works correctly...
 692       if test "$CYGWIN" = "yes"; then
 693         echo "*** use dllwrap for building shared library."
 694         LIBEXT="dll"
 695       fi
 696     fi
 697   fi
 698 fi
 699
 700 if test "$LIBEXT" = "a"; then
 701   echo "*** It is currently not possible to build WINE without shared"
 702   echo "*** library (.so) support to allow transparent switch between .so"
 703   echo "*** and .dll files."
 704   echo "*** If you are using Linux, you will need a newer binutils."
 705   exit 1
 706 fi
 707
 708 DLLFLAGS=""
 709 LDPATH=""
 710
 711 if test "$LIBEXT" = "so"; then
 712     DLLFLAGS="-fPIC"
 713     LDPATH="LD_LIBRARY_PATH=\"\$(TOPOBJDIR)/unicode:\$\$LD_LIBRARY_PATH\""
 714 elif test "$LIBEXT" = "dll"; then
 715     #DLLFLAGS="-fPIC" # -fPIC doesn't work(at least in cygwin-b20) - FIXME
 716     LDPATH="PATH=\"\$(TOPOBJDIR)/unicode:\$\$PATH\""
 717 fi
 718
 719 AC_SUBST(DLLFLAGS)
 720 AC_SUBST(LDSHARED)
 721 AC_SUBST(LDDLLFLAGS)
 722 AC_SUBST(LIBEXT)
 723 AC_SUBST(LDPATH)
 724
 725 dnl **** Check for reentrant libc ****
 726 dnl
 727 dnl For cross-compiling we blindly assume that libc is reentrant. This is
 728 dnl ok since non-reentrant libc is quite rare (mostly old libc5 versions).
 729
 730 AC_DEFUN([WINE_CHECK_ERRNO],
 731 [
 732   AC_CACHE_CHECK(for reentrant libc: $1, wine_cv_libc_r_$1,
 733   [AC_TRY_RUN([int myerrno = 0;
 734 char buf[256];
 735 int *$1(){return &myerrno;}
 736 main(){connect(0,buf,255); exit(!myerrno);}],
 737   wine_cv_libc_r_$1=yes, wine_cv_libc_r_$1=no,
 738   wine_cv_libc_r_$1=yes )
 739 ])
 740 if test "$wine_cv_libc_r_$1" = "yes"
 741 then
 742     wine_cv_libc_reentrant=$1
 743 fi
 744 ])
 745
 746 wine_cv_libc_reentrant=no
 747 dnl Linux style errno location
 748 WINE_CHECK_ERRNO(__errno_location)
 749 dnl FreeBSD style errno location
 750 WINE_CHECK_ERRNO(__error)
 751 dnl Solaris style errno location
 752 WINE_CHECK_ERRNO(___errno)
 753 dnl UnixWare style errno location
 754 WINE_CHECK_ERRNO(__thr_errno)
 755 dnl NetBSD style errno location
 756 WINE_CHECK_ERRNO(__errno)
 757
 758 if test "$wine_cv_libc_reentrant" != "no"
 759 then
 760   AC_DEFINE_UNQUOTED(ERRNO_LOCATION,$wine_cv_libc_reentrant,
 761                      [Define to the name of the function returning errno for reentrant libc])
 762 fi
 763
 764 dnl **** Check for reentrant X libraries ****
 765 dnl
 766 dnl This may fail to determine whether X libraries are reentrant if
 767 dnl AC_PATH_XTRA does not set x_libraries. In this case manual configuration
 768 dnl is possible with the --without-reentrant-x option.
 769
 770 if test "$have_x" = "yes" -a "$wine_cv_libc_reentrant" != "no"
 771 then
 772 AC_CACHE_CHECK( [for reentrant X libraries], wine_cv_x_reentrant,
 773   [ if test "x$with_reentrant_x" = "xno"
 774     then
 775         wine_cv_x_reentrant=no
 776     else
 777         libX11_check=none
 778         for dir in "$x_libraries" /usr/lib /usr/local/lib /lib; do
 779             if test -r $dir/libX11.so; then
 780                 libX11_check="-D $dir/libX11.so"
 781                 break 1
 782             fi
 783             if test -r $dir/libX11.a; then
 784                 libX11_check="$dir/libX11.a"
 785                 break 1
 786             fi
 787         done
 788         if test "$libX11_check" != "none"; then
 789             if nm $libX11_check | grep $wine_cv_libc_reentrant >/dev/null 2>&1
 790             then
 791                 wine_cv_x_reentrant=yes
 792             else
 793                 wine_cv_x_reentrant=no
 794             fi
 795         else
 796             wine_cv_x_reentrant=unknown
 797         fi
 798     fi ] )
 799 else
 800     wine_cv_x_reentrant=no
 801 fi
 802 if test "$wine_cv_x_reentrant" = "no"
 803 then
 804   AC_DEFINE(NO_REENTRANT_X11, 1,
 805             [Define if X libraries are not reentrant (compiled without -D_REENTRANT)])
 806 fi
 807
 808
 809 dnl **** Check for functions ****
 810
 811 AC_FUNC_ALLOCA()
 812 AC_CHECK_FUNCS(\
 813         __libc_fork \
 814         _lwp_create \
 815         clone \
 816         ecvt \
 817         finite \
 818         fpclass \
 819         ftruncate64 \
 820         getnetbyaddr \
 821         getnetbyname \
 822         getpagesize \
 823         getprotobyname \
 824         getprotobynumber \
 825         getrlimit \
 826         getservbyport \
 827         getsockopt \
 828         inet_network \
 829         lseek64 \
 830         lstat \
 831         memmove \
 832         mmap \
 833         rfork \
 834         select \
 835         sendmsg \
 836         settimeofday \
 837         sigaltstack \
 838         statfs \
 839         strcasecmp \
 840         strerror \
 841         strncasecmp \
 842         tcgetattr \
 843         timegm \
 844         usleep \
 845         vfscanf \
 846         wait4 \
 847         waitpid \
 848 )
 849
 850 dnl **** Check for header files ****
 851
 852 AC_CHECK_HEADERS(\
 853         arpa/inet.h \
 854         arpa/nameser.h \
 855         elf.h \
 856         float.h \
 857         ieeefp.h \
 858         libio.h \
 859         libutil.h \
 860         link.h \
 861         linux/cdrom.h \
 862         linux/input.h \
 863         linux/joystick.h \
 864         linux/ucdrom.h \
 865         net/if.h \
 866         netdb.h \
 867         netinet/in.h \
 868         netinet/in_systm.h \
 869         netinet/ip.h \
 870         netinet/tcp.h \
 871         pty.h \
 872         resolv.h \
 873         sched.h \
 874         socket.h \
 875         strings.h \
 876         sys/cdio.h \
 877         sys/errno.h \
 878         sys/file.h \
 879         sys/filio.h \
 880         sys/ipc.h \
 881         sys/link.h \
 882         sys/lwp.h \
 883         sys/mman.h \
 884         sys/modem.h \
 885         sys/mount.h \
 886         sys/msg.h \
 887         sys/param.h \
 888         sys/ptrace.h \
 889         sys/reg.h \
 890         sys/signal.h \
 891         sys/shm.h \
 892         sys/socket.h \
 893         sys/sockio.h \
 894         sys/statfs.h \
 895         sys/strtio.h \
 896         sys/syscall.h \
 897         sys/user.h \
 898         sys/wait.h \
 899         sys/v86.h \
 900         sys/v86intr.h \
 901         sys/vfs.h \
 902         sys/vm86.h \
 903         syscall.h \
 904         ucontext.h \
 905 )
 906 AC_HEADER_STAT()
 907
 908 dnl **** Check for types ****
 909
 910 AC_C_CONST()
 911 AC_C_INLINE()
 912 AC_TYPE_SIZE_T()
 913 AC_CHECK_SIZEOF(long long,0)
 914
 915 AC_CACHE_CHECK([whether linux/input.h is for real],
 916         wine_cv_linux_input_h,
 917         AC_TRY_COMPILE([
 918             #include <linux/input.h>
 919         ] , [
 920             int foo = EVIOCGBIT(EV_ABS,42);
 921             int bar = BTN_PINKIE;
 922             int fortytwo = 42;
 923         ],
 924         wine_cv_linux_input_h=yes,
 925         wine_cv_linux_input_h=no,
 926         no
 927         )
 928     )
 929     if test "$wine_cv_linux_input_h" = "yes"
 930     then
 931         AC_DEFINE(HAVE_CORRECT_LINUXINPUT_H, 1,
 932                   [Define if we have linux/input.h AND it contains the INPUT event API])
 933     fi
 934
 935
 936 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
 937         wine_cv_linux_gethostbyname_r_6,
 938         AC_TRY_COMPILE([
 939 #include <netdb.h>
 940         ], [
 941     char *name=NULL;
 942     struct hostent he;
 943     struct hostent *result;
 944     char *buf=NULL;
 945     int bufsize=0;
 946     int res,errnr;
 947     char *addr=NULL;
 948     int addrlen=0;
 949     int addrtype=0;
 950     res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
 951     res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
 952     ],
 953         wine_cv_linux_gethostbyname_r_6=yes,
 954         wine_cv_linux_gethostbyname_r_6=no
 955         )
 956    )
 957    if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
 958    then
 959       AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
 960                 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
 961    fi
 962
 963 if test "$ac_cv_header_linux_joystick_h" = "yes"
 964 then
 965    AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
 966         wine_cv_linux_joystick_22_api,
 967         AC_TRY_COMPILE([
 968         #include <sys/ioctl.h>
 969         #include <linux/joystick.h>
 970
 971         struct js_event blub;
 972         #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
 973         #error "no 2.2 header"
 974         #endif
 975         ],/*empty*/,
 976         wine_cv_linux_joystick_22_api=yes,
 977         wine_cv_linux_joystick_22_api=no,
 978         wine_cv_linux_joystick_22_api=no
 979         )
 980    )
 981    if test "$wine_cv_linux_joystick_22_api" = "yes"
 982    then
 983       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
 984                 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
 985    fi
 986 fi
 987
 988 dnl **** statfs checks ****
 989
 990 if test "$ac_cv_header_sys_vfs_h" = "yes"
 991 then
 992     AC_CACHE_CHECK( [whether sys/vfs.h defines statfs],
 993                     wine_cv_sys_vfs_has_statfs,
 994         AC_TRY_COMPILE([
 995         #include <sys/types.h>
 996         #ifdef HAVE_SYS_PARAM_H
 997         # include <sys/param.h>
 998         #endif
 999         #include <sys/vfs.h>
1000         ],[
1001                 struct statfs stfs;
1002
1003                 memset(&stfs,0,sizeof(stfs));
1004         ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
1005         )
1006     )
1007     if test "$wine_cv_sys_vfs_has_statfs" = "yes"
1008     then
1009       AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS, 1,
1010                 [Define if the struct statfs is defined by <sys/vfs.h>])
1011     fi
1012 fi
1013
1014 if test "$ac_cv_header_sys_statfs_h" = "yes"
1015 then
1016     AC_CACHE_CHECK( [whether sys/statfs.h defines statfs],
1017                     wine_cv_sys_statfs_has_statfs,
1018         AC_TRY_COMPILE([
1019         #include <sys/types.h>
1020         #ifdef HAVE_SYS_PARAM_H
1021         # include <sys/param.h>
1022         #endif
1023         #include <sys/statfs.h>
1024         ],[
1025                 struct statfs stfs;
1026         ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
1027         )
1028     )
1029     if test "$wine_cv_sys_statfs_has_statfs" = "yes"
1030     then
1031       AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS, 1,
1032                 [Define if the struct statfs is defined by <sys/statfs.h>])
1033     fi
1034 fi
1035
1036 if test "$ac_cv_header_sys_mount_h" = "yes"
1037 then
1038     AC_CACHE_CHECK( [whether sys/mount.h defines statfs],
1039                     wine_cv_sys_mount_has_statfs,
1040         AC_TRY_COMPILE([
1041         #include <sys/types.h>
1042         #ifdef HAVE_SYS_PARAM_H
1043         # include <sys/param.h>
1044         #endif
1045         #include <sys/mount.h>
1046         ],[
1047                 struct statfs stfs;
1048         ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
1049         )
1050     )
1051     if test "$wine_cv_sys_mount_has_statfs" = "yes"
1052     then
1053       AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT, 1,
1054                 [Define if the struct statfs is defined by <sys/mount.h>])
1055     fi
1056 fi
1057
1058 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1059
1060 AC_CACHE_CHECK( [for statfs.f_bfree], wine_cv_statfs_bfree,
1061   [ if test "x$statfs_bfree" = "xno"
1062     then
1063         wine_cv_statfs_bfree=no
1064     else
1065         AC_TRY_COMPILE([
1066         #include <sys/types.h>
1067         #ifdef HAVE_SYS_PARAM_H
1068         # include <sys/param.h>
1069         #endif
1070         #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1071         # include <sys/mount.h>
1072         #else
1073         # ifdef STATFS_DEFINED_BY_SYS_VFS
1074         #  include <sys/vfs.h>
1075         # else
1076         #  ifdef STATFS_DEFINED_BY_SYS_STATFS
1077         #   include <sys/statfs.h>
1078         #  endif
1079         # endif
1080         #endif
1081         ],[
1082                 struct statfs stfs;
1083
1084                 stfs.f_bfree++;
1085         ],wine_cv_statfs_bfree=yes,wine_cv_statfs_bfree=no
1086         )
1087     fi ] )
1088 if test "$wine_cv_statfs_bfree" = "yes"
1089 then
1090   AC_DEFINE(STATFS_HAS_BFREE, 1, [Define if the struct statfs has the member bfree])
1091 fi
1092
1093 AC_CACHE_CHECK( [for statfs.f_bavail], wine_cv_statfs_bavail,
1094   [ if test "x$statfs_bavail" = "xno"
1095     then
1096         wine_cv_statfs_bavail=no
1097     else
1098         AC_TRY_COMPILE([
1099         #include <sys/types.h>
1100         #ifdef HAVE_SYS_PARAM_H
1101         # include <sys/param.h>
1102         #endif
1103         #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1104         # include <sys/mount.h>
1105         #else
1106         # ifdef STATFS_DEFINED_BY_SYS_VFS
1107         #  include <sys/vfs.h>
1108         # else
1109         #  ifdef STATFS_DEFINED_BY_SYS_STATFS
1110         #   include <sys/statfs.h>
1111         #  endif
1112         # endif
1113         #endif
1114         ],[
1115                 struct statfs stfs;
1116
1117                 stfs.f_bavail++;
1118         ],wine_cv_statfs_bavail=yes,wine_cv_statfs_bavail=no
1119         )
1120     fi ] )
1121 if test "$wine_cv_statfs_bavail" = "yes"
1122 then
1123   AC_DEFINE(STATFS_HAS_BAVAIL, 1, [Define if the struct statfs has the member bavail])
1124 fi
1125
1126 dnl *** check for file descriptor passing with msg_accrights
1127
1128 AC_CACHE_CHECK([for msg_accrights in struct msghdr], ac_cv_c_msg_accrights,
1129  AC_TRY_COMPILE([#include <sys/types.h>
1130 #include <sys/socket.h>],[struct msghdr hdr; hdr.msg_accrights=0],
1131                 ac_cv_c_msg_accrights="yes", ac_cv_c_msg_accrights="no"))
1132 if test "$ac_cv_c_msg_accrights" = "yes"
1133 then
1134     AC_DEFINE(HAVE_MSGHDR_ACCRIGHTS, 1, [Define if struct msghdr contains msg_accrights])
1135 fi
1136
1137 dnl *** Check for the sa_len member in struct sockaddr
1138
1139 AC_CACHE_CHECK([for sa_len in struct sockaddr], ac_cv_c_sockaddr_sa_len,
1140  AC_TRY_COMPILE([#include <sys/types.h>
1141 #include <sys/socket.h>
1142 ], [static struct sockaddr addr; addr.sa_len = 1],
1143                 ac_cv_c_sockaddr_sa_len="yes", ac_cv_c_sockaddr_sa_len="no"))
1144 if test "$ac_cv_c_sockaddr_sa_len" = "yes"
1145 then
1146     AC_DEFINE(HAVE_SOCKADDR_SA_LEN, 1, [Define if struct sockaddr contains sa_len])
1147 fi
1148
1149 dnl *** Check for the sun_len member in struct sockaddr_un
1150
1151 AC_CACHE_CHECK([for sun_len in struct sockaddr_un], ac_cv_c_sockaddr_sun_len,
1152  AC_TRY_COMPILE([#include <sys/types.h>
1153 #include <sys/socket.h>
1154 #include <sys/un.h>], [static struct sockaddr_un addr; addr.sun_len = 1],
1155                 ac_cv_c_sockaddr_sun_len="yes", ac_cv_c_sockaddr_sun_len="no"))
1156 if test "$ac_cv_c_sockaddr_sun_len" = "yes"
1157 then
1158     AC_DEFINE(HAVE_SOCKADDR_SUN_LEN, 1, [Define if struct sockaddr_un contains sun_len])
1159 fi
1160
1161 dnl *** check for the need to define __i386__
1162
1163 AC_CACHE_CHECK([whether we need to define __i386__],ac_cv_cpp_def_i386,
1164  AC_EGREP_CPP(yes,[#if (defined(i386) || defined(__i386)) && !defined(__i386__)
1165 yes
1166 #endif],
1167  ac_cv_cpp_def_i386="yes", ac_cv_cpp_def_i386="no"))
1168 if test "$ac_cv_cpp_def_i386" = "yes"
1169 then
1170     CFLAGS="$CFLAGS -D__i386__"
1171     LINTFLAGS="$LINTFLAGS -D__i386__"
1172 fi
1173
1174 dnl $GCC is set by autoconf
1175 GCC_NO_BUILTIN=""
1176 if test "$GCC" = "yes"
1177 then
1178     GCC_NO_BUILTIN="-fno-builtin"
1179 fi
1180 AC_SUBST(GCC_NO_BUILTIN)
1181
1182 dnl **** Generate output files ****
1183
1184 AC_OUTPUT_COMMANDS([
1185 extra_subdirs="\
1186 dlls/ddraw/d3ddevice \
1187 dlls/ddraw/dclipper \
1188 dlls/ddraw/ddraw \
1189 dlls/ddraw/direct3d \
1190 dlls/ddraw/dpalette \
1191 dlls/ddraw/dsurface \
1192 dlls/dinput/joystick \
1193 dlls/dinput/keyboard \
1194 dlls/dinput/mouse \
1195 dlls/kernel/messages \
1196 dlls/user/dde \
1197 dlls/user/resources \
1198 dlls/wineps/data \
1199 "
1200 for i in $extra_subdirs; do [ -d $i ] || (echo "creating $i" && mkdir $i); done ])
1201
1202 MAKE_RULES=Make.rules
1203 AC_SUBST_FILE(MAKE_RULES)
1204
1205 MAKE_DLL_RULES=dlls/Makedll.rules
1206 AC_SUBST_FILE(MAKE_DLL_RULES)
1207
1208 MAKE_PROG_RULES=programs/Makeprog.rules
1209 AC_SUBST_FILE(MAKE_PROG_RULES)
1210
1211 AC_OUTPUT([
1212 Make.rules
1213 dlls/Makedll.rules
1214 programs/Makeprog.rules
1215 Makefile
1216 console/Makefile
1217 controls/Makefile
1218 debugger/Makefile
1219 dlls/Makefile
1220 dlls/advapi32/Makefile
1221 dlls/avifil32/Makefile
1222 dlls/comctl32/Makefile
1223 dlls/commdlg/Makefile
1224 dlls/crtdll/Makefile
1225 dlls/dciman32/Makefile
1226 dlls/ddraw/Makefile
1227 dlls/devenum/Makefile
1228 dlls/dinput/Makefile
1229 dlls/dplay/Makefile
1230 dlls/dplayx/Makefile
1231 dlls/dsound/Makefile
1232 dlls/gdi/Makefile
1233 dlls/glu32/Makefile
1234 dlls/icmp/Makefile
1235 dlls/imagehlp/Makefile
1236 dlls/imm32/Makefile
1237 dlls/kernel/Makefile
1238 dlls/lzexpand/Makefile
1239 dlls/mapi32/Makefile
1240 dlls/mpr/Makefile
1241 dlls/msacm/Makefile
1242 dlls/msdmo/Makefile
1243 dlls/msimg32/Makefile
1244 dlls/msnet32/Makefile
1245 dlls/msvcrt/Makefile
1246 dlls/msvideo/Makefile
1247 dlls/ntdll/Makefile
1248 dlls/odbc32/Makefile
1249 dlls/ole32/Makefile
1250 dlls/oleaut32/Makefile
1251 dlls/olecli/Makefile
1252 dlls/oledlg/Makefile
1253 dlls/olepro32/Makefile
1254 dlls/olesvr/Makefile
1255 dlls/opengl32/Makefile
1256 dlls/psapi/Makefile
1257 dlls/qcap/Makefile
1258 dlls/quartz/Makefile
1259 dlls/rasapi32/Makefile
1260 dlls/richedit/Makefile
1261 dlls/rpcrt4/Makefile
1262 dlls/serialui/Makefile
1263 dlls/setupapi/Makefile
1264 dlls/shdocvw/Makefile
1265 dlls/shell32/Makefile
1266 dlls/shfolder/Makefile
1267 dlls/shlwapi/Makefile
1268 dlls/sti/Makefile
1269 dlls/tapi32/Makefile
1270 dlls/ttydrv/Makefile
1271 dlls/url/Makefile
1272 dlls/urlmon/Makefile
1273 dlls/user/Makefile
1274 dlls/version/Makefile
1275 dlls/win32s/Makefile
1276 dlls/winaspi/Makefile
1277 dlls/winedos/Makefile
1278 dlls/wineps/Makefile
1279 dlls/wininet/Makefile
1280 dlls/winmm/Makefile
1281 dlls/winmm/joystick/Makefile
1282 dlls/winmm/mcianim/Makefile
1283 dlls/winmm/mciavi/Makefile
1284 dlls/winmm/mcicda/Makefile
1285 dlls/winmm/mciseq/Makefile
1286 dlls/winmm/mciwave/Makefile
1287 dlls/winmm/midimap/Makefile
1288 dlls/winmm/wavemap/Makefile
1289 dlls/winmm/wineoss/Makefile
1290 dlls/winnls/Makefile
1291 dlls/winsock/Makefile
1292 dlls/winspool/Makefile
1293 dlls/wintrust/Makefile
1294 dlls/wow32/Makefile
1295 dlls/wsock32/Makefile
1296 dlls/x11drv/Makefile
1297 documentation/Makefile
1298 documentation/wine.conf.man
1299 documentation/wine.man
1300 files/Makefile
1301 graphics/Makefile
1302 graphics/enhmetafiledrv/Makefile
1303 graphics/metafiledrv/Makefile
1304 graphics/win16drv/Makefile
1305 graphics/x11drv/Makefile
1306 if1632/Makefile
1307 include/Makefile
1308 library/Makefile
1309 libtest/Makefile
1310 loader/Makefile
1311 loader/dos/Makefile
1312 loader/ne/Makefile
1313 memory/Makefile
1314 misc/Makefile
1315 miscemu/Makefile
1316 msdos/Makefile
1317 objects/Makefile
1318 ole/Makefile
1319 programs/Makefile
1320 programs/avitools/Makefile
1321 programs/clock/Makefile
1322 programs/cmdlgtst/Makefile
1323 programs/control/Makefile
1324 programs/notepad/Makefile
1325 programs/osversioncheck/Makefile
1326 programs/progman/Makefile
1327 programs/regapi/Makefile
1328 programs/regtest/Makefile
1329 programs/uninstaller/Makefile
1330 programs/view/Makefile
1331 programs/wcmd/Makefile
1332 programs/winemine/Makefile
1333 programs/winetest/Makefile
1334 programs/winhelp/Makefile
1335 programs/winver/Makefile
1336 relay32/Makefile
1337 scheduler/Makefile
1338 server/Makefile
1339 tools/Makefile
1340 tools/winapi/Makefile
1341 tools/winebuild/Makefile
1342 tools/winedump/Makefile
1343 tools/winelauncher
1344 tools/wmc/Makefile
1345 tools/wrc/Makefile
1346 tsx11/Makefile
1347 unicode/Makefile
1348 win32/Makefile
1349 windows/Makefile
1350 windows/x11drv/Makefile ])
1351
1352 if test "$have_x" = "no"
1353 then
1354   echo
1355   echo "*** Warning: X development files not found. Wine will be built without"
1356   echo "*** X support, which currently does not work, and would probably not be"
1357   echo "*** what you want anyway. You will need to install devel packages of"
1358   echo "*** Xlib/Xfree86 and Xpm at the very least."
1359 elif test "$ac_cv_lib_Xpm_XpmCreatePixmapFromData" = "no"
1360 then
1361   echo
1362   echo "*** Warning: Xpm development files not found. Wine will be built without"
1363   echo "*** Xpm support, which currently does not work. You will need to install"
1364   echo "*** devel packages of Xpm."
1365 fi
1366
1367 if test "$ac_cv_lib_ncurses_resizeterm" = "no" -a "$ac_cv_lib_ncurses_waddch" = "yes"
1368 then
1369   echo
1370   echo "*** Warning: resizeterm not found in ncurses. Wine will be built without"
1371   echo "*** terminal resize support. Consider upgrading ncurses."
1372 fi
1373
1374 if test "$wine_cv_libc_reentrant" = "no"
1375 then
1376   echo
1377   echo "*** Warning: non-reentrant libc detected. Wine will be build without"
1378   echo "*** thread support. Consider upgrading libc to a more recent"
1379   echo "*** reentrant version of libc."
1380 fi
1381
1382 if test "$wine_cv_opengl_version_OK" = "no"
1383 then
1384   echo
1385   echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
1386   echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)."
1387 fi
1388
1389 if test "$wine_cv_opengl_version_threadsafe" = "yes" -a $OPENGL = "normal"
1390 then
1391   echo
1392   echo "*** Warning: the OpenGL version you have installed relies on libpthread for"
1393   echo "*** thread-safety. To prevent crashes, OpenGL support has been removed."
1394   echo "*** A fix for glibc 2.1.3 that seems to work is included in this version of Wine,"
1395   echo "*** start configure with '--enable-opengl' to force OpenGL support."
1396 fi
1397
1398 if test "$wine_cv_opengl_version_threadsafe" = "yes" -a $OPENGL = "yes"
1399 then
1400   echo
1401   echo "*** Warning: you explicitly linked in a thread-safe OpenGL version. If you"
1402   echo "*** experience unusual crashes on DirectDraw games, try first to disable OpenGL"
1403   echo "*** support before reporting bugs."
1404 fi
1405
1406 if test "$wine_cv_warn_cups_h" = "yes"
1407 then
1408   echo
1409   echo "*** Note: You have cups runtime libraries, but no development"
1410   echo "*** libraries. Install the cups-devel package or whichever package"
1411   echo "*** contains cups.h to enable CUPS support in WINE."
1412 fi
1413
1414 if test "$wine_cv_msg_freetype" = "yes"
1415 then
1416   echo
1417   echo "*** Note: Your system appears to have the FreeType 2 runtime libraries"
1418   echo "*** installed, but 'freetype-config' is not in your PATH. Install the"
1419   echo "*** freetype-devel package (or its equivalent on your distribution) to"
1420   echo "*** enable Wine to use TrueType fonts."
1421 fi
1422
1423 echo
1424 echo "Configure finished.  Do 'make depend && make' to compile Wine."
1425 echo
1426
1427 dnl Local Variables:
1428 dnl comment-start: "dnl "
1429 dnl comment-end: ""
1430 dnl comment-start-skip: "\\bdnl\\b\\s *"
1431 dnl compile-command: "autoconf"
1432 dnl End: