git.oblomov.eu Git - wine/blob - tools/widl/parser.y

   1 %{
   2 /*
   3  * IDL Compiler
   4  *
   5  * Copyright 2002 Ove Kaaven
   6  *
   7  * This library is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU Lesser General Public
   9  * License as published by the Free Software Foundation; either
  10  * version 2.1 of the License, or (at your option) any later version.
  11  *
  12  * This library is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15  * Lesser General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU Lesser General Public
  18  * License along with this library; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  20  */
  21
  22 #include "config.h"
  23
  24 #include <stdio.h>
  25 #include <stdlib.h>
  26 #include <stdarg.h>
  27 #include <assert.h>
  28 #include <ctype.h>
  29 #include <string.h>
  30 #ifdef HAVE_ALLOCA_H
  31 #include <alloca.h>
  32 #endif
  33
  34 #include "windef.h"
  35
  36 #include "widl.h"
  37 #include "utils.h"
  38 #include "parser.h"
  39 #include "header.h"
  40 #include "typelib.h"
  41
  42 #if defined(YYBYACC)
  43         /* Berkeley yacc (byacc) doesn't seem to know about these */
  44         /* Some *BSD supplied versions do define these though */
  45 # ifndef YYEMPTY
  46 #  define YYEMPTY       (-1)    /* Empty lookahead value of yychar */
  47 # endif
  48 # ifndef YYLEX
  49 #  define YYLEX         yylex()
  50 # endif
  51
  52 #elif defined(YYBISON)
  53         /* Bison was used for original development */
  54         /* #define YYEMPTY -2 */
  55         /* #define YYLEX   yylex() */
  56
  57 #else
  58         /* No yacc we know yet */
  59 # if !defined(YYEMPTY) || !defined(YYLEX)
  60 #  error Yacc version/type unknown. This version needs to be verified for settings of YYEMPTY and YYLEX.
  61 # elif defined(__GNUC__)        /* gcc defines the #warning directive */
  62 #  warning Yacc version/type unknown. It defines YYEMPTY and YYLEX, but is not tested
  63   /* #else we just take a chance that it works... */
  64 # endif
  65 #endif
  66
  67 static attr_t *make_attr(enum attr_type type);
  68 static attr_t *make_attrv(enum attr_type type, unsigned long val);
  69 static attr_t *make_attrp(enum attr_type type, void *val);
  70 static expr_t *make_expr(enum expr_type type);
  71 static expr_t *make_exprl(enum expr_type type, long val);
  72 static expr_t *make_exprs(enum expr_type type, char *val);
  73 static expr_t *make_exprt(enum expr_type type, typeref_t *tref, expr_t *expr);
  74 static expr_t *make_expr1(enum expr_type type, expr_t *expr);
  75 static expr_t *make_expr2(enum expr_type type, expr_t *exp1, expr_t *exp2);
  76 static expr_t *make_expr3(enum expr_type type, expr_t *expr1, expr_t *expr2, expr_t *expr3);
  77 static type_t *make_type(unsigned char type, type_t *ref);
  78 static typeref_t *make_tref(char *name, type_t *ref);
  79 static typeref_t *uniq_tref(typeref_t *ref);
  80 static type_t *type_ref(typeref_t *ref);
  81 static void set_type(var_t *v, typeref_t *ref, expr_t *arr);
  82 static ifref_t *make_ifref(type_t *iface);
  83 static var_t *make_var(char *name);
  84 static func_t *make_func(var_t *def, var_t *args);
  85 static class_t *make_class(char *name);
  86
  87 static type_t *reg_type(type_t *type, char *name, int t);
  88 static type_t *reg_types(type_t *type, var_t *names, int t);
  89 static type_t *find_type(char *name, int t);
  90 static type_t *find_type2(char *name, int t);
  91 static type_t *get_type(unsigned char type, char *name, int t);
  92 static type_t *get_typev(unsigned char type, var_t *name, int t);
  93 static int get_struct_type(var_t *fields);
  94
  95 static var_t *reg_const(var_t *var);
  96 static var_t *find_const(char *name, int f);
  97
  98 #define tsENUM   1
  99 #define tsSTRUCT 2
 100 #define tsUNION  3
 101
 102 static type_t std_bool = { "boolean" };
 103 static type_t std_int = { "int" };
 104 static type_t std_int64 = { "__int64" };
 105 static type_t std_uhyper = { "MIDL_uhyper" };
 106
 107 %}
 108 %union {
 109         attr_t *attr;
 110         expr_t *expr;
 111         type_t *type;
 112         typeref_t *tref;
 113         var_t *var;
 114         func_t *func;
 115         ifref_t *ifref;
 116         class_t *clas;
 117         char *str;
 118         UUID *uuid;
 119         unsigned int num;
 120 }
 121
 122 %token <str> aIDENTIFIER
 123 %token <str> aKNOWNTYPE
 124 %token <num> aNUM aHEXNUM
 125 %token <str> aSTRING
 126 %token <uuid> aUUID
 127 %token aEOF
 128 %token SHL SHR
 129 %token tAGGREGATABLE tALLOCATE tAPPOBJECT tARRAYS tASYNC tASYNCUUID
 130 %token tAUTOHANDLE tBINDABLE tBOOLEAN tBROADCAST tBYTE tBYTECOUNT
 131 %token tCALLAS tCALLBACK tCASE tCDECL tCHAR tCOCLASS tCODE tCOMMSTATUS
 132 %token tCONST tCONTEXTHANDLE tCONTEXTHANDLENOSERIALIZE
 133 %token tCONTEXTHANDLESERIALIZE tCONTROL tCPPQUOTE
 134 %token tDEFAULT
 135 %token tDEFAULTVALUE
 136 %token tDISPINTERFACE
 137 %token tDLLNAME tDOUBLE tDUAL
 138 %token tENDPOINT
 139 %token tENTRY tENUM tERRORSTATUST
 140 %token tEXPLICITHANDLE tEXTERN
 141 %token tFLOAT
 142 %token tHANDLE
 143 %token tHANDLET
 144 %token tHELPCONTEXT tHELPFILE
 145 %token tHELPSTRING tHELPSTRINGCONTEXT tHELPSTRINGDLL
 146 %token tHIDDEN
 147 %token tHYPER tID tIDEMPOTENT
 148 %token tIIDIS
 149 %token tIMPLICITHANDLE
 150 %token tIMPORT tIMPORTLIB
 151 %token tIN tINCLUDE tINLINE
 152 %token tINPUTSYNC
 153 %token tINT tINT64
 154 %token tINTERFACE
 155 %token tLENGTHIS tLIBRARY
 156 %token tLOCAL
 157 %token tLONG
 158 %token tMETHODS
 159 %token tMODULE
 160 %token tNONCREATABLE
 161 %token tOBJECT tODL tOLEAUTOMATION
 162 %token tOPTIONAL
 163 %token tOUT
 164 %token tPOINTERDEFAULT
 165 %token tPROPERTIES
 166 %token tPROPGET tPROPPUT tPROPPUTREF
 167 %token tPUBLIC
 168 %token tREADONLY tREF
 169 %token tRESTRICTED
 170 %token tRETVAL
 171 %token tSHORT
 172 %token tSIGNED
 173 %token tSINGLE
 174 %token tSIZEIS tSIZEOF
 175 %token tSOURCE
 176 %token tSTDCALL
 177 %token tSTRING tSTRUCT
 178 %token tSWITCH tSWITCHIS tSWITCHTYPE
 179 %token tTRANSMITAS
 180 %token tTYPEDEF
 181 %token tUNION
 182 %token tUNIQUE
 183 %token tUNSIGNED
 184 %token tUUID
 185 %token tV1ENUM
 186 %token tVARARG
 187 %token tVERSION
 188 %token tVOID
 189 %token tWCHAR tWIREMARSHAL
 190
 191 /* used in attr_t */
 192 %token tPOINTERTYPE
 193
 194 %type <attr> m_attributes attributes attrib_list attribute
 195 %type <expr> m_exprs /* exprs expr_list */ m_expr expr expr_list_const expr_const
 196 %type <expr> array array_list
 197 %type <type> inherit interface interfacehdr interfacedef interfacedec
 198 %type <type> dispinterface dispinterfacehdr dispinterfacedef
 199 %type <type> module modulehdr moduledef
 200 %type <type> base_type int_std
 201 %type <type> enumdef structdef typedef uniondef
 202 %type <ifref> gbl_statements coclass_ints coclass_int
 203 %type <tref> type
 204 %type <var> m_args no_args args arg
 205 %type <var> fields field s_field cases case enums enum_list enum constdef externdef
 206 %type <var> m_ident t_ident ident p_ident pident pident_list
 207 %type <var> dispint_props
 208 %type <func> funcdef int_statements
 209 %type <func> dispint_meths
 210 %type <clas> coclass coclasshdr coclassdef
 211 %type <num> pointer_type version
 212 %type <str> libraryhdr
 213
 214 %left ','
 215 %right COND
 216 %left '|'
 217 %left '&'
 218 %left '-' '+'
 219 %left '*' '/'
 220 %left SHL SHR
 221 %right '~'
 222 %right CAST
 223 %right PPTR
 224 %right NEG
 225
 226 %%
 227
 228 input:   gbl_statements                        { write_proxies($1); write_client($1); write_server($1); }
 229         ;
 230
 231 gbl_statements:                                 { $$ = NULL; }
 232         | gbl_statements interfacedec           { $$ = $1; }
 233         | gbl_statements interfacedef           { $$ = make_ifref($2); LINK($$, $1); }
 234         | gbl_statements coclassdef             { $$ = $1; add_coclass($2); }
 235         | gbl_statements moduledef              { $$ = $1; add_module($2); }
 236         | gbl_statements librarydef             { $$ = $1; }
 237         | gbl_statements statement              { $$ = $1; }
 238         ;
 239
 240 imp_statements:                                 {}
 241         | imp_statements interfacedec           { if (!parse_only) add_interface($2); }
 242         | imp_statements interfacedef           { if (!parse_only) add_interface($2); }
 243         | imp_statements coclassdef             { if (!parse_only) add_coclass($2); }
 244         | imp_statements moduledef              { if (!parse_only) add_module($2); }
 245         | imp_statements statement              {}
 246         ;
 247
 248 int_statements:                                 { $$ = NULL; }
 249         | int_statements funcdef ';'            { $$ = $2; LINK($$, $1); }
 250         | int_statements statement              { $$ = $1; }
 251         ;
 252
 253 statement: ';'                                  {}
 254         | constdef ';'                          { if (!parse_only && do_header) { write_constdef($1); } }
 255         | cppquote                              {}
 256         | enumdef ';'                           { if (!parse_only && do_header) { write_type(header, $1, NULL, NULL); fprintf(header, ";\n\n"); } }
 257         | externdef ';'                         { if (!parse_only && do_header) { write_externdef($1); } }
 258         | import                                {}
 259         | structdef ';'                         { if (!parse_only && do_header) { write_type(header, $1, NULL, NULL); fprintf(header, ";\n\n"); } }
 260         | typedef ';'                           {}
 261         | uniondef ';'                          { if (!parse_only && do_header) { write_type(header, $1, NULL, NULL); fprintf(header, ";\n\n"); } }
 262         ;
 263
 264 cppquote: tCPPQUOTE '(' aSTRING ')'             { if (!parse_only && do_header) fprintf(header, "%s\n", $3); }
 265         ;
 266 import_start: tIMPORT aSTRING ';'               { assert(yychar == YYEMPTY);
 267                                                   if (!do_import($2)) yychar = aEOF; }
 268         ;
 269 import:   import_start imp_statements aEOF      {}
 270         ;
 271
 272 libraryhdr: tLIBRARY aIDENTIFIER                { $$ = $2; }
 273         ;
 274 library_start: attributes libraryhdr '{'        { start_typelib($2, $1);
 275                                                   if (!parse_only && do_header) write_library($2, $1); }
 276         ;
 277 librarydef: library_start imp_statements '}'    { end_typelib(); }
 278         ;
 279
 280 m_args:                                         { $$ = NULL; }
 281         | args
 282         ;
 283
 284 no_args:  tVOID                                 { $$ = NULL; }
 285         ;
 286
 287 args:     arg
 288         | args ',' arg                          { LINK($3, $1); $$ = $3; }
 289         | no_args
 290         ;
 291
 292 /* split into two rules to get bison to resolve a tVOID conflict */
 293 arg:      attributes type pident array          { $$ = $3;
 294                                                   set_type($$, $2, $4);
 295                                                   $$->attrs = $1;
 296                                                 }
 297         | type pident array                     { $$ = $2;
 298                                                   set_type($$, $1, $3);
 299                                                 }
 300         | attributes type pident '(' m_args ')' { $$ = $3;
 301                                                   $$->ptr_level--;
 302                                                   set_type($$, $2, NULL);
 303                                                   $$->attrs = $1;
 304                                                   $$->args = $5;
 305                                                 }
 306         | type pident '(' m_args ')'            { $$ = $2;
 307                                                   $$->ptr_level--;
 308                                                   set_type($$, $1, NULL);
 309                                                   $$->args = $4;
 310                                                 }
 311         ;
 312
 313 array:                                          { $$ = NULL; }
 314         | '[' array_list ']'                    { $$ = $2; }
 315         | '[' '*' ']'                           { $$ = make_expr(EXPR_VOID); }
 316         ;
 317
 318 array_list: m_expr /* size of first dimension is optional */
 319         | array_list ',' expr                   { LINK($3, $1); $$ = $3; }
 320         | array_list ']' '[' expr               { LINK($4, $1); $$ = $4; }
 321         ;
 322
 323 m_attributes:                                   { $$ = NULL; }
 324         | attributes
 325         ;
 326
 327 attributes:
 328           '[' attrib_list ']'                   { $$ = $2; }
 329         ;
 330
 331 attrib_list: attribute
 332         | attrib_list ',' attribute             { LINK($3, $1); $$ = $3; }
 333         | attrib_list ']' '[' attribute         { LINK($4, $1); $$ = $4; }
 334         ;
 335
 336 attribute:
 337           tASYNC                                { $$ = make_attr(ATTR_ASYNC); }
 338         | tAUTOHANDLE                           { $$ = make_attr(ATTR_AUTO_HANDLE); }
 339         | tCALLAS '(' ident ')'                 { $$ = make_attrp(ATTR_CALLAS, $3); }
 340         | tCASE '(' expr_list_const ')'         { $$ = make_attrp(ATTR_CASE, $3); }
 341         | tCONTEXTHANDLE                        { $$ = make_attrv(ATTR_CONTEXTHANDLE, 0); }
 342         | tCONTEXTHANDLENOSERIALIZE             { $$ = make_attrv(ATTR_CONTEXTHANDLE, 0); /* RPC_CONTEXT_HANDLE_DONT_SERIALIZE */ }
 343         | tCONTEXTHANDLESERIALIZE               { $$ = make_attrv(ATTR_CONTEXTHANDLE, 0); /* RPC_CONTEXT_HANDLE_SERIALIZE */ }
 344         | tCONTROL                              { $$ = make_attr(ATTR_CONTROL); }
 345         | tDEFAULT                              { $$ = make_attr(ATTR_DEFAULT); }
 346         | tDEFAULTVALUE '(' expr_const ')'      { $$ = make_attrp(ATTR_DEFAULTVALUE_EXPR, $3); }
 347         | tDEFAULTVALUE '(' aSTRING ')'         { $$ = make_attrp(ATTR_DEFAULTVALUE_STRING, $3); }
 348         | tDLLNAME '(' aSTRING ')'              { $$ = make_attrp(ATTR_DLLNAME, $3); }
 349         | tDUAL                                 { $$ = make_attr(ATTR_DUAL); }
 350         | tENDPOINT '(' aSTRING ')'             { $$ = make_attrp(ATTR_ENDPOINT, $3); }
 351         | tENTRY '(' aSTRING ')'                { $$ = make_attrp(ATTR_ENTRY_STRING, $3); }
 352         | tENTRY '(' expr_const ')'             { $$ = make_attrp(ATTR_ENTRY_ORDINAL, $3); }
 353         | tEXPLICITHANDLE                       { $$ = make_attr(ATTR_EXPLICIT_HANDLE); }
 354         | tHANDLE                               { $$ = make_attr(ATTR_HANDLE); }
 355         | tHELPCONTEXT '(' expr_const ')'       { $$ = make_attrp(ATTR_HELPCONTEXT, $3); }
 356         | tHELPFILE '(' aSTRING ')'             { $$ = make_attrp(ATTR_HELPFILE, $3); }
 357         | tHELPSTRING '(' aSTRING ')'           { $$ = make_attrp(ATTR_HELPSTRING, $3); }
 358         | tHELPSTRINGCONTEXT '(' expr_const ')' { $$ = make_attrp(ATTR_HELPSTRINGCONTEXT, $3); }
 359         | tHELPSTRINGDLL '(' aSTRING ')'        { $$ = make_attrp(ATTR_HELPSTRINGDLL, $3); }
 360         | tHIDDEN                               { $$ = make_attr(ATTR_HIDDEN); }
 361         | tID '(' expr_const ')'                { $$ = make_attrp(ATTR_ID, $3); }
 362         | tIDEMPOTENT                           { $$ = make_attr(ATTR_IDEMPOTENT); }
 363         | tIIDIS '(' ident ')'                  { $$ = make_attrp(ATTR_IIDIS, $3); }
 364         | tIMPLICITHANDLE '(' tHANDLET aIDENTIFIER ')'  { $$ = make_attrp(ATTR_IMPLICIT_HANDLE, $4); }
 365         | tIN                                   { $$ = make_attr(ATTR_IN); }
 366         | tINPUTSYNC                            { $$ = make_attr(ATTR_INPUTSYNC); }
 367         | tLENGTHIS '(' m_exprs ')'             { $$ = make_attrp(ATTR_LENGTHIS, $3); }
 368         | tLOCAL                                { $$ = make_attr(ATTR_LOCAL); }
 369         | tNONCREATABLE                         { $$ = make_attr(ATTR_NONCREATABLE); }
 370         | tOBJECT                               { $$ = make_attr(ATTR_OBJECT); }
 371         | tODL                                  { $$ = make_attr(ATTR_ODL); }
 372         | tOLEAUTOMATION                        { $$ = make_attr(ATTR_OLEAUTOMATION); }
 373         | tOPTIONAL                             { $$ = make_attr(ATTR_OPTIONAL); }
 374         | tOUT                                  { $$ = make_attr(ATTR_OUT); }
 375         | tPOINTERDEFAULT '(' pointer_type ')'  { $$ = make_attrv(ATTR_POINTERDEFAULT, $3); }
 376         | tPROPGET                              { $$ = make_attr(ATTR_PROPGET); }
 377         | tPROPPUT                              { $$ = make_attr(ATTR_PROPPUT); }
 378         | tPROPPUTREF                           { $$ = make_attr(ATTR_PROPPUTREF); }
 379         | tPUBLIC                               { $$ = make_attr(ATTR_PUBLIC); }
 380         | tREADONLY                             { $$ = make_attr(ATTR_READONLY); }
 381         | tRESTRICTED                           { $$ = make_attr(ATTR_RESTRICTED); }
 382         | tRETVAL                               { $$ = make_attr(ATTR_RETVAL); }
 383         | tSIZEIS '(' m_exprs ')'               { $$ = make_attrp(ATTR_SIZEIS, $3); }
 384         | tSOURCE                               { $$ = make_attr(ATTR_SOURCE); }
 385         | tSTRING                               { $$ = make_attr(ATTR_STRING); }
 386         | tSWITCHIS '(' expr ')'                { $$ = make_attrp(ATTR_SWITCHIS, $3); }
 387         | tSWITCHTYPE '(' type ')'              { $$ = make_attrp(ATTR_SWITCHTYPE, type_ref($3)); }
 388         | tTRANSMITAS '(' type ')'              { $$ = make_attrp(ATTR_TRANSMITAS, type_ref($3)); }
 389         | tUUID '(' aUUID ')'                   { $$ = make_attrp(ATTR_UUID, $3); }
 390         | tV1ENUM                               { $$ = make_attr(ATTR_V1ENUM); }
 391         | tVARARG                               { $$ = make_attr(ATTR_VARARG); }
 392         | tVERSION '(' version ')'              { $$ = make_attrv(ATTR_VERSION, $3); }
 393         | tWIREMARSHAL '(' type ')'             { $$ = make_attrp(ATTR_WIREMARSHAL, type_ref($3)); }
 394         | pointer_type                          { $$ = make_attrv(ATTR_POINTERTYPE, $1); }
 395         ;
 396
 397 callconv:
 398         | tSTDCALL
 399         ;
 400
 401 cases:                                          { $$ = NULL; }
 402         | cases case                            { if ($2) { LINK($2, $1); $$ = $2; }
 403                                                   else { $$ = $1; }
 404                                                 }
 405         ;
 406
 407 case:     tCASE expr ':' field                  { attr_t *a = make_attrp(ATTR_CASE, $2);
 408                                                   $$ = $4; if (!$$) $$ = make_var(NULL);
 409                                                   LINK(a, $$->attrs); $$->attrs = a;
 410                                                 }
 411         | tDEFAULT ':' field                    { attr_t *a = make_attr(ATTR_DEFAULT);
 412                                                   $$ = $3; if (!$$) $$ = make_var(NULL);
 413                                                   LINK(a, $$->attrs); $$->attrs = a;
 414                                                 }
 415         ;
 416
 417 constdef: tCONST type ident '=' expr_const      { $$ = reg_const($3);
 418                                                   set_type($$, $2, NULL);
 419                                                   $$->eval = $5;
 420                                                   $$->lval = $5->cval;
 421                                                 }
 422         ;
 423
 424 enums:                                          { $$ = NULL; }
 425         | enum_list ','                         { $$ = $1; }
 426         | enum_list
 427         ;
 428
 429 enum_list: enum
 430         | enum_list ',' enum                    { LINK($3, $1); $$ = $3;
 431                                                   if ($1 && !$3->eval)
 432                                                     $3->lval = $1->lval + 1;
 433                                                 }
 434         ;
 435
 436 enum:     ident '=' expr_const                  { $$ = reg_const($1);
 437                                                   $$->eval = $3;
 438                                                   $$->lval = $3->cval;
 439                                                   $$->type = make_type(RPC_FC_LONG, &std_int);
 440                                                 }
 441         | ident                                 { $$ = reg_const($1);
 442                                                   $$->lval = 0; /* default for first enum entry */
 443                                                   $$->type = make_type(RPC_FC_LONG, &std_int);
 444                                                 }
 445         ;
 446
 447 enumdef: tENUM t_ident '{' enums '}'            { $$ = get_typev(RPC_FC_ENUM16, $2, tsENUM);
 448                                                   $$->fields = $4;
 449                                                   $$->defined = TRUE;
 450                                                   if(in_typelib)
 451                                                       add_enum($$);
 452                                                 }
 453         ;
 454
 455 m_exprs:  m_expr
 456         | m_exprs ',' m_expr                    { LINK($3, $1); $$ = $3; }
 457         ;
 458
 459 /*
 460 exprs:                                          { $$ = make_expr(EXPR_VOID); }
 461         | expr_list
 462         ;
 463
 464 expr_list: expr
 465         | expr_list ',' expr                    { LINK($3, $1); $$ = $3; }
 466         ;
 467 */
 468
 469 m_expr:                                         { $$ = make_expr(EXPR_VOID); }
 470         | expr
 471         ;
 472
 473 expr:     aNUM                                  { $$ = make_exprl(EXPR_NUM, $1); }
 474         | aHEXNUM                               { $$ = make_exprl(EXPR_HEXNUM, $1); }
 475         | aIDENTIFIER                           { $$ = make_exprs(EXPR_IDENTIFIER, $1); }
 476         | expr '?' expr ':' expr %prec COND     { $$ = make_expr3(EXPR_COND, $1, $3, $5); }
 477         | expr '|' expr                         { $$ = make_expr2(EXPR_OR , $1, $3); }
 478         | expr '&' expr                         { $$ = make_expr2(EXPR_AND, $1, $3); }
 479         | expr '+' expr                         { $$ = make_expr2(EXPR_ADD, $1, $3); }
 480         | expr '-' expr                         { $$ = make_expr2(EXPR_SUB, $1, $3); }
 481         | expr '*' expr                         { $$ = make_expr2(EXPR_MUL, $1, $3); }
 482         | expr '/' expr                         { $$ = make_expr2(EXPR_DIV, $1, $3); }
 483         | expr SHL expr                         { $$ = make_expr2(EXPR_SHL, $1, $3); }
 484         | expr SHR expr                         { $$ = make_expr2(EXPR_SHR, $1, $3); }
 485         | '~' expr                              { $$ = make_expr1(EXPR_NOT, $2); }
 486         | '-' expr %prec NEG                    { $$ = make_expr1(EXPR_NEG, $2); }
 487         | '*' expr %prec PPTR                   { $$ = make_expr1(EXPR_PPTR, $2); }
 488         | '(' type ')' expr %prec CAST          { $$ = make_exprt(EXPR_CAST, $2, $4); }
 489         | tSIZEOF '(' type ')'                  { $$ = make_exprt(EXPR_SIZEOF, $3, NULL); }
 490         | '(' expr ')'                          { $$ = $2; }
 491         ;
 492
 493 expr_list_const: expr_const
 494         | expr_list_const ',' expr_const        { LINK($3, $1); $$ = $3; }
 495         ;
 496
 497 expr_const: expr                                { $$ = $1;
 498                                                   if (!$$->is_const)
 499                                                       yyerror("expression is not constant\n");
 500                                                 }
 501         ;
 502
 503 externdef: tEXTERN tCONST type ident            { $$ = $4;
 504                                                   set_type($$, $3, NULL);
 505                                                 }
 506         ;
 507
 508 fields:                                         { $$ = NULL; }
 509         | fields field                          { if ($2) { LINK($2, $1); $$ = $2; }
 510                                                   else { $$ = $1; }
 511                                                 }
 512         ;
 513
 514 field:    s_field ';'                           { $$ = $1; }
 515         | m_attributes uniondef ';'             { $$ = make_var(NULL); $$->type = $2; $$->attrs = $1; }
 516         | attributes ';'                        { $$ = make_var(NULL); $$->attrs = $1; }
 517         | ';'                                   { $$ = NULL; }
 518         ;
 519
 520 s_field:  m_attributes type pident array        { $$ = $3; set_type($$, $2, $4); $$->attrs = $1; }
 521         ;
 522
 523 funcdef:
 524           m_attributes type callconv pident
 525           '(' m_args ')'                        { set_type($4, $2, NULL);
 526                                                   $4->attrs = $1;
 527                                                   $$ = make_func($4, $6);
 528                                                   if (is_attr($4->attrs, ATTR_IN)) {
 529                                                     yyerror("Inapplicable attribute");
 530                                                   }
 531                                                 }
 532         ;
 533
 534 m_ident:                                        { $$ = NULL; }
 535         | ident
 536         ;
 537
 538 t_ident:                                        { $$ = NULL; }
 539         | aIDENTIFIER                           { $$ = make_var($1); }
 540         | aKNOWNTYPE                            { $$ = make_var($1); }
 541         ;
 542
 543 ident:    aIDENTIFIER                           { $$ = make_var($1); }
 544 /* some "reserved words" used in attributes are also used as field names in some MS IDL files */
 545         | aKNOWNTYPE                            { $$ = make_var($<str>1); }
 546         | tASYNC                                { $$ = make_var($<str>1); }
 547         | tID                                   { $$ = make_var($<str>1); }
 548         | tRETVAL                               { $$ = make_var($<str>1); }
 549         | tVERSION                              { $$ = make_var($<str>1); }
 550         ;
 551
 552 base_type: tBYTE                                { $$ = make_type(RPC_FC_BYTE, NULL); }
 553         | tWCHAR                                { $$ = make_type(RPC_FC_WCHAR, NULL); }
 554         | int_std
 555         | tSIGNED int_std                       { $$ = $2; $$->sign = 1; }
 556         | tUNSIGNED int_std                     { $$ = $2; $$->sign = -1;
 557                                                   switch ($$->type) {
 558                                                   case RPC_FC_CHAR:  $$->type = RPC_FC_BYTE; $$->sign = 0; break;
 559                                                   case RPC_FC_SMALL: $$->type = RPC_FC_USMALL; break;
 560                                                   case RPC_FC_SHORT: $$->type = RPC_FC_USHORT; break;
 561                                                   case RPC_FC_LONG:  $$->type = RPC_FC_ULONG;  break;
 562                                                   case RPC_FC_HYPER:
 563                                                     if (!$$->ref) { $$->ref = &std_uhyper; $$->sign = 0; }
 564                                                     break;
 565                                                   default: break;
 566                                                   }
 567                                                 }
 568         | tUNSIGNED                             { $$ = make_type(RPC_FC_ULONG, &std_int); $$->sign = -1; }
 569         | tFLOAT                                { $$ = make_type(RPC_FC_FLOAT, NULL); }
 570         | tSINGLE                               { $$ = make_type(RPC_FC_FLOAT, NULL); }
 571         | tDOUBLE                               { $$ = make_type(RPC_FC_DOUBLE, NULL); }
 572         | tBOOLEAN                              { $$ = make_type(RPC_FC_BYTE, &std_bool); /* ? */ }
 573         | tERRORSTATUST                         { $$ = make_type(RPC_FC_ERROR_STATUS_T, NULL); }
 574         | tHANDLET                              { $$ = make_type(RPC_FC_BIND_PRIMITIVE, NULL); /* ? */ }
 575         ;
 576
 577 m_int:
 578         | tINT
 579         ;
 580
 581 int_std:  tINT                                  { $$ = make_type(RPC_FC_LONG, &std_int); } /* win32 only */
 582         | tSHORT m_int                          { $$ = make_type(RPC_FC_SHORT, NULL); }
 583         | tLONG m_int                           { $$ = make_type(RPC_FC_LONG, NULL); }
 584         | tHYPER m_int                          { $$ = make_type(RPC_FC_HYPER, NULL); }
 585         | tINT64                                { $$ = make_type(RPC_FC_HYPER, &std_int64); }
 586         | tCHAR                                 { $$ = make_type(RPC_FC_CHAR, NULL); }
 587         ;
 588
 589 coclass:  tCOCLASS aIDENTIFIER                  { $$ = make_class($2); }
 590         | tCOCLASS aKNOWNTYPE                   { $$ = make_class($2); }
 591         ;
 592
 593 coclasshdr: attributes coclass                  { $$ = $2;
 594                                                   $$->attrs = $1;
 595                                                   if (!parse_only && do_header) write_coclass($$);
 596                                                 }
 597         ;
 598
 599 coclassdef: coclasshdr '{' coclass_ints '}'     { $$ = $1;
 600                                                   $$->ifaces = $3;
 601                                                 }
 602         ;
 603
 604 coclass_ints:                                   { $$ = NULL; }
 605         | coclass_ints coclass_int              { LINK($2, $1); $$ = $2; }
 606         ;
 607
 608 coclass_int:
 609           m_attributes interfacedec             { $$ = make_ifref($2); $$->attrs = $1; }
 610         ;
 611
 612 dispinterface: tDISPINTERFACE aIDENTIFIER       { $$ = get_type(0, $2, 0); }
 613         |      tDISPINTERFACE aKNOWNTYPE        { $$ = get_type(0, $2, 0); }
 614         ;
 615
 616 dispinterfacehdr: attributes dispinterface      { $$ = $2;
 617                                                   if ($$->defined) yyerror("multiple definition error\n");
 618                                                   $$->attrs = $1;
 619                                                   $$->attrs = make_attr(ATTR_DISPINTERFACE);
 620                                                   LINK($$->attrs, $1);
 621                                                   $$->ref = find_type("IDispatch", 0);
 622                                                   if (!$$->ref) yyerror("IDispatch is undefined\n");
 623                                                   $$->defined = TRUE;
 624                                                   if (!parse_only && do_header) write_forward($$);
 625                                                 }
 626         ;
 627
 628 dispint_props: tPROPERTIES ':'                  { $$ = NULL; }
 629         | dispint_props s_field ';'             { LINK($2, $1); $$ = $2; }
 630         ;
 631
 632 dispint_meths: tMETHODS ':'                     { $$ = NULL; }
 633         | dispint_meths funcdef ';'             { LINK($2, $1); $$ = $2; }
 634         ;
 635
 636 dispinterfacedef: dispinterfacehdr '{'
 637           dispint_props
 638           dispint_meths
 639           '}'                                   { $$ = $1;
 640                                                   $$->fields = $3;
 641                                                   $$->funcs = $4;
 642                                                   if (!parse_only && do_header) write_dispinterface($$);
 643                                                 }
 644 /* FIXME: not sure how to handle this yet
 645         | dispinterfacehdr '{' interface '}'    { $$ = $1;
 646                                                   if (!parse_only && do_header) write_interface($$);
 647                                                 }
 648 */
 649         ;
 650
 651 inherit:                                        { $$ = NULL; }
 652         | ':' aKNOWNTYPE                        { $$ = find_type2($2, 0); }
 653         ;
 654
 655 interface: tINTERFACE aIDENTIFIER               { $$ = get_type(RPC_FC_IP, $2, 0); }
 656         |  tINTERFACE aKNOWNTYPE                { $$ = get_type(RPC_FC_IP, $2, 0); }
 657         ;
 658
 659 interfacehdr: attributes interface              { $$ = $2;
 660                                                   if ($$->defined) yyerror("multiple definition error\n");
 661                                                   $$->attrs = $1;
 662                                                   $$->defined = TRUE;
 663                                                   if (!parse_only && do_header) write_forward($$);
 664                                                 }
 665         ;
 666
 667 interfacedef: interfacehdr inherit
 668           '{' int_statements '}'                { $$ = $1;
 669                                                   $$->ref = $2;
 670                                                   $$->funcs = $4;
 671                                                   if (!parse_only && do_header) write_interface($$);
 672                                                 }
 673 /* MIDL is able to import the definition of a base class from inside the
 674  * definition of a derived class, I'll try to support it with this rule */
 675         | interfacehdr ':' aIDENTIFIER
 676           '{' import int_statements '}'         { $$ = $1;
 677                                                   $$->ref = find_type2($3, 0);
 678                                                   if (!$$->ref) yyerror("base class %s not found in import\n", $3);
 679                                                   $$->funcs = $6;
 680                                                   if (!parse_only && do_header) write_interface($$);
 681                                                 }
 682         | dispinterfacedef                      { $$ = $1; }
 683         ;
 684
 685 interfacedec:
 686           interface ';'                         { $$ = $1; if (!parse_only && do_header) write_forward($$); }
 687         | dispinterface ';'                     { $$ = $1; if (!parse_only && do_header) write_forward($$); }
 688         ;
 689
 690 module:   tMODULE aIDENTIFIER                   { $$ = make_type(0, NULL); $$->name = $2; }
 691         | tMODULE aKNOWNTYPE                    { $$ = make_type(0, NULL); $$->name = $2; }
 692         ;
 693
 694 modulehdr: attributes module                    { $$ = $2;
 695                                                   $$->attrs = $1;
 696                                                 }
 697         ;
 698
 699 moduledef: modulehdr '{' int_statements '}'     { $$ = $1;
 700                                                   $$->funcs = $3;
 701                                                   /* FIXME: if (!parse_only && do_header) write_module($$); */
 702                                                 }
 703         ;
 704
 705 p_ident:  '*' pident %prec PPTR                 { $$ = $2; $$->ptr_level++; }
 706         | tCONST p_ident                        { $$ = $2; /* FIXME */ }
 707         ;
 708
 709 pident:   ident
 710         | p_ident
 711         | '(' pident ')'                        { $$ = $2; }
 712         ;
 713
 714 pident_list:
 715           pident
 716         | pident_list ',' pident                { LINK($3, $1); $$ = $3; }
 717         ;
 718
 719 pointer_type:
 720           tREF                                  { $$ = RPC_FC_RP; }
 721         | tUNIQUE                               { $$ = RPC_FC_UP; }
 722         ;
 723
 724 structdef: tSTRUCT t_ident '{' fields '}'       { $$ = get_typev(RPC_FC_STRUCT, $2, tsSTRUCT);
 725                                                   /* overwrite RPC_FC_STRUCT with a more exact type */
 726                                                   $$->type = get_struct_type( $4 );
 727                                                   $$->fields = $4;
 728                                                   $$->defined = TRUE;
 729                                                   if(in_typelib)
 730                                                       add_struct($$);
 731                                                 }
 732         ;
 733
 734 type:     tVOID                                 { $$ = make_tref(NULL, make_type(0, NULL)); }
 735         | aKNOWNTYPE                            { $$ = make_tref($1, find_type($1, 0)); }
 736         | base_type                             { $$ = make_tref(NULL, $1); }
 737         | tCONST type                           { $$ = uniq_tref($2); $$->ref->is_const = TRUE; }
 738         | enumdef                               { $$ = make_tref(NULL, $1); }
 739         | tENUM aIDENTIFIER                     { $$ = make_tref(NULL, find_type2($2, tsENUM)); }
 740         | structdef                             { $$ = make_tref(NULL, $1); }
 741         | tSTRUCT aIDENTIFIER                   { $$ = make_tref(NULL, get_type(RPC_FC_STRUCT, $2, tsSTRUCT)); }
 742         | uniondef                              { $$ = make_tref(NULL, $1); }
 743         | tUNION aIDENTIFIER                    { $$ = make_tref(NULL, find_type2($2, tsUNION)); }
 744         ;
 745
 746 typedef: tTYPEDEF m_attributes type pident_list { typeref_t *tref = uniq_tref($3);
 747                                                   $4->tname = tref->name;
 748                                                   tref->name = NULL;
 749                                                   $$ = type_ref(tref);
 750                                                   $$->attrs = $2;
 751                                                   if (!parse_only && do_header) write_typedef($$, $4);
 752                                                   if (in_typelib && $$->attrs)
 753                                                       add_typedef($$, $4);
 754                                                   reg_types($$, $4, 0);
 755                                                 }
 756         ;
 757
 758 uniondef: tUNION t_ident '{' fields '}'         { $$ = get_typev(RPC_FC_NON_ENCAPSULATED_UNION, $2, tsUNION);
 759                                                   $$->fields = $4;
 760                                                   $$->defined = TRUE;
 761                                                 }
 762         | tUNION t_ident
 763           tSWITCH '(' s_field ')'
 764           m_ident '{' cases '}'                 { var_t *u = $7;
 765                                                   $$ = get_typev(RPC_FC_ENCAPSULATED_UNION, $2, tsUNION);
 766                                                   if (!u) u = make_var("tagged_union");
 767                                                   u->type = make_type(RPC_FC_NON_ENCAPSULATED_UNION, NULL);
 768                                                   u->type->fields = $9;
 769                                                   u->type->defined = TRUE;
 770                                                   LINK(u, $5); $$->fields = u;
 771                                                   $$->defined = TRUE;
 772                                                 }
 773         ;
 774
 775 version:
 776           aNUM                                  { $$ = MAKELONG($1, 0); }
 777         | aNUM '.' aNUM                         { $$ = MAKELONG($1, $3); }
 778         ;
 779
 780 %%
 781
 782 static attr_t *make_attr(enum attr_type type)
 783 {
 784   attr_t *a = xmalloc(sizeof(attr_t));
 785   a->type = type;
 786   a->u.ival = 0;
 787   INIT_LINK(a);
 788   return a;
 789 }
 790
 791 static attr_t *make_attrv(enum attr_type type, unsigned long val)
 792 {
 793   attr_t *a = xmalloc(sizeof(attr_t));
 794   a->type = type;
 795   a->u.ival = val;
 796   INIT_LINK(a);
 797   return a;
 798 }
 799
 800 static attr_t *make_attrp(enum attr_type type, void *val)
 801 {
 802   attr_t *a = xmalloc(sizeof(attr_t));
 803   a->type = type;
 804   a->u.pval = val;
 805   INIT_LINK(a);
 806   return a;
 807 }
 808
 809 static expr_t *make_expr(enum expr_type type)
 810 {
 811   expr_t *e = xmalloc(sizeof(expr_t));
 812   e->type = type;
 813   e->ref = NULL;
 814   e->u.lval = 0;
 815   e->is_const = FALSE;
 816   INIT_LINK(e);
 817   return e;
 818 }
 819
 820 static expr_t *make_exprl(enum expr_type type, long val)
 821 {
 822   expr_t *e = xmalloc(sizeof(expr_t));
 823   e->type = type;
 824   e->ref = NULL;
 825   e->u.lval = val;
 826   e->is_const = FALSE;
 827   INIT_LINK(e);
 828   /* check for numeric constant */
 829   if (type == EXPR_NUM || type == EXPR_HEXNUM) {
 830     e->is_const = TRUE;
 831     e->cval = val;
 832   }
 833   return e;
 834 }
 835
 836 static expr_t *make_exprs(enum expr_type type, char *val)
 837 {
 838   expr_t *e;
 839   e = xmalloc(sizeof(expr_t));
 840   e->type = type;
 841   e->ref = NULL;
 842   e->u.sval = val;
 843   e->is_const = FALSE;
 844   INIT_LINK(e);
 845   /* check for predefined constants */
 846   if (type == EXPR_IDENTIFIER) {
 847     var_t *c = find_const(val, 0);
 848     if (c) {
 849       e->u.sval = c->name;
 850       free(val);
 851       e->is_const = TRUE;
 852       e->cval = c->lval;
 853     }
 854   }
 855   return e;
 856 }
 857
 858 static expr_t *make_exprt(enum expr_type type, typeref_t *tref, expr_t *expr)
 859 {
 860   expr_t *e;
 861   e = xmalloc(sizeof(expr_t));
 862   e->type = type;
 863   e->ref = expr;
 864   e->u.tref = tref;
 865   e->is_const = FALSE;
 866   INIT_LINK(e);
 867   /* check for cast of constant expression */
 868   if (type == EXPR_CAST && expr->is_const) {
 869     e->is_const = TRUE;
 870     e->cval = expr->cval;
 871   }
 872   return e;
 873 }
 874
 875 static expr_t *make_expr1(enum expr_type type, expr_t *expr)
 876 {
 877   expr_t *e;
 878   e = xmalloc(sizeof(expr_t));
 879   e->type = type;
 880   e->ref = expr;
 881   e->u.lval = 0;
 882   e->is_const = FALSE;
 883   INIT_LINK(e);
 884   /* check for compile-time optimization */
 885   if (expr->is_const) {
 886     e->is_const = TRUE;
 887     switch (type) {
 888     case EXPR_NEG:
 889       e->cval = -expr->cval;
 890       break;
 891     case EXPR_NOT:
 892       e->cval = ~expr->cval;
 893       break;
 894     default:
 895       e->is_const = FALSE;
 896       break;
 897     }
 898   }
 899   return e;
 900 }
 901
 902 static expr_t *make_expr2(enum expr_type type, expr_t *expr1, expr_t *expr2)
 903 {
 904   expr_t *e;
 905   e = xmalloc(sizeof(expr_t));
 906   e->type = type;
 907   e->ref = expr1;
 908   e->u.ext = expr2;
 909   e->is_const = FALSE;
 910   INIT_LINK(e);
 911   /* check for compile-time optimization */
 912   if (expr1->is_const && expr2->is_const) {
 913     e->is_const = TRUE;
 914     switch (type) {
 915     case EXPR_ADD:
 916       e->cval = expr1->cval + expr2->cval;
 917       break;
 918     case EXPR_SUB:
 919       e->cval = expr1->cval - expr2->cval;
 920       break;
 921     case EXPR_MUL:
 922       e->cval = expr1->cval * expr2->cval;
 923       break;
 924     case EXPR_DIV:
 925       e->cval = expr1->cval / expr2->cval;
 926       break;
 927     case EXPR_OR:
 928       e->cval = expr1->cval | expr2->cval;
 929       break;
 930     case EXPR_AND:
 931       e->cval = expr1->cval & expr2->cval;
 932       break;
 933     case EXPR_SHL:
 934       e->cval = expr1->cval << expr2->cval;
 935       break;
 936     case EXPR_SHR:
 937       e->cval = expr1->cval >> expr2->cval;
 938       break;
 939     default:
 940       e->is_const = FALSE;
 941       break;
 942     }
 943   }
 944   return e;
 945 }
 946
 947 static expr_t *make_expr3(enum expr_type type, expr_t *expr1, expr_t *expr2, expr_t *expr3)
 948 {
 949   expr_t *e;
 950   e = xmalloc(sizeof(expr_t));
 951   e->type = type;
 952   e->ref = expr1;
 953   e->u.ext = expr2;
 954   e->ext2 = expr3;
 955   e->is_const = FALSE;
 956   INIT_LINK(e);
 957   /* check for compile-time optimization */
 958   if (expr1->is_const && expr2->is_const && expr3->is_const) {
 959     e->is_const = TRUE;
 960     switch (type) {
 961     case EXPR_COND:
 962       e->cval = expr1->cval ? expr2->cval : expr3->cval;
 963       break;
 964     default:
 965       e->is_const = FALSE;
 966       break;
 967     }
 968   }
 969   return e;
 970 }
 971
 972 static type_t *make_type(unsigned char type, type_t *ref)
 973 {
 974   type_t *t = xmalloc(sizeof(type_t));
 975   t->name = NULL;
 976   t->type = type;
 977   t->ref = ref;
 978   t->rname = NULL;
 979   t->attrs = NULL;
 980   t->funcs = NULL;
 981   t->fields = NULL;
 982   t->ignore = parse_only;
 983   t->is_const = FALSE;
 984   t->sign = 0;
 985   t->defined = FALSE;
 986   t->written = FALSE;
 987   t->typelib_idx = -1;
 988   INIT_LINK(t);
 989   return t;
 990 }
 991
 992 static typeref_t *make_tref(char *name, type_t *ref)
 993 {
 994   typeref_t *t = xmalloc(sizeof(typeref_t));
 995   t->name = name;
 996   t->ref = ref;
 997   t->uniq = ref ? 0 : 1;
 998   return t;
 999 }
1000
1001 static typeref_t *uniq_tref(typeref_t *ref)
1002 {
1003   typeref_t *t = ref;
1004   type_t *tp;
1005   if (t->uniq) return t;
1006   tp = make_type(0, t->ref);
1007   tp->name = t->name;
1008   t->name = NULL;
1009   t->ref = tp;
1010   t->uniq = 1;
1011   return t;
1012 }
1013
1014 static type_t *type_ref(typeref_t *ref)
1015 {
1016   type_t *t = ref->ref;
1017   if (ref->name) free(ref->name);
1018   free(ref);
1019   return t;
1020 }
1021
1022 static void set_type(var_t *v, typeref_t *ref, expr_t *arr)
1023 {
1024   v->type = ref->ref;
1025   v->tname = ref->name;
1026   ref->name = NULL;
1027   free(ref);
1028   v->array = arr;
1029 }
1030
1031 static ifref_t *make_ifref(type_t *iface)
1032 {
1033   ifref_t *l = xmalloc(sizeof(ifref_t));
1034   l->iface = iface;
1035   l->attrs = NULL;
1036   INIT_LINK(l);
1037   return l;
1038 }
1039
1040 static var_t *make_var(char *name)
1041 {
1042   var_t *v = xmalloc(sizeof(var_t));
1043   v->name = name;
1044   v->ptr_level = 0;
1045   v->type = NULL;
1046   v->tname = NULL;
1047   v->attrs = NULL;
1048   v->array = NULL;
1049   v->eval = NULL;
1050   v->lval = 0;
1051   INIT_LINK(v);
1052   return v;
1053 }
1054
1055 static func_t *make_func(var_t *def, var_t *args)
1056 {
1057   func_t *f = xmalloc(sizeof(func_t));
1058   f->def = def;
1059   f->args = args;
1060   f->ignore = parse_only;
1061   f->idx = -1;
1062   INIT_LINK(f);
1063   return f;
1064 }
1065
1066 static class_t *make_class(char *name)
1067 {
1068   class_t *c = xmalloc(sizeof(class_t));
1069   c->name = name;
1070   c->attrs = NULL;
1071   c->ifaces = NULL;
1072   INIT_LINK(c);
1073   return c;
1074 }
1075
1076 #define HASHMAX 64
1077
1078 static int hash_ident(const char *name)
1079 {
1080   const char *p = name;
1081   int sum = 0;
1082   /* a simple sum hash is probably good enough */
1083   while (*p) {
1084     sum += *p;
1085     p++;
1086   }
1087   return sum & (HASHMAX-1);
1088 }
1089
1090 /***** type repository *****/
1091
1092 struct rtype {
1093   char *name;
1094   type_t *type;
1095   int t;
1096   struct rtype *next;
1097 };
1098
1099 struct rtype *type_hash[HASHMAX];
1100
1101 static type_t *reg_type(type_t *type, char *name, int t)
1102 {
1103   struct rtype *nt;
1104   int hash;
1105   if (!name) {
1106     yyerror("registering named type without name\n");
1107     return type;
1108   }
1109   hash = hash_ident(name);
1110   nt = xmalloc(sizeof(struct rtype));
1111   nt->name = name;
1112   nt->type = type;
1113   nt->t = t;
1114   nt->next = type_hash[hash];
1115   type_hash[hash] = nt;
1116   return type;
1117 }
1118
1119 /* determine pointer type from attrs */
1120 static unsigned char get_pointer_type( type_t *type )
1121 {
1122   int t;
1123   if (is_attr( type->attrs, ATTR_STRING ))
1124   {
1125     type_t *t = type;
1126     while( t->type == 0 && t->ref )
1127       t = t->ref;
1128     switch( t->type )
1129     {
1130     case RPC_FC_CHAR:
1131       return RPC_FC_C_CSTRING;
1132     case RPC_FC_WCHAR:
1133       return RPC_FC_C_WSTRING;
1134     }
1135   }
1136   t = get_attrv( type->attrs, ATTR_POINTERTYPE );
1137   if (t) return t;
1138   return RPC_FC_FP;
1139 }
1140
1141 static type_t *reg_types(type_t *type, var_t *names, int t)
1142 {
1143   type_t *ptr = type;
1144   int ptrc = 0;
1145
1146   while (names) {
1147     var_t *next = NEXT_LINK(names);
1148     if (names->name) {
1149       type_t *cur = ptr;
1150       int cptr = names->ptr_level;
1151       if (cptr > ptrc) {
1152         while (cptr > ptrc) {
1153           int t = get_pointer_type( cur );
1154           cur = ptr = make_type(t, cur);
1155           ptrc++;
1156         }
1157       } else {
1158         while (cptr < ptrc) {
1159           cur = cur->ref;
1160           cptr++;
1161         }
1162       }
1163       reg_type(cur, names->name, t);
1164     }
1165     free(names);
1166     names = next;
1167   }
1168   return type;
1169 }
1170
1171 static type_t *find_type(char *name, int t)
1172 {
1173   struct rtype *cur = type_hash[hash_ident(name)];
1174   while (cur && (cur->t != t || strcmp(cur->name, name)))
1175     cur = cur->next;
1176   if (!cur) {
1177     yyerror("type %s not found\n", name);
1178     return NULL;
1179   }
1180   return cur->type;
1181 }
1182
1183 static type_t *find_type2(char *name, int t)
1184 {
1185   type_t *tp = find_type(name, t);
1186   free(name);
1187   return tp;
1188 }
1189
1190 int is_type(const char *name)
1191 {
1192   struct rtype *cur = type_hash[hash_ident(name)];
1193   while (cur && (cur->t || strcmp(cur->name, name)))
1194     cur = cur->next;
1195   if (cur) return TRUE;
1196   return FALSE;
1197 }
1198
1199 static type_t *get_type(unsigned char type, char *name, int t)
1200 {
1201   struct rtype *cur = NULL;
1202   type_t *tp;
1203   if (name) {
1204     cur = type_hash[hash_ident(name)];
1205     while (cur && (cur->t != t || strcmp(cur->name, name)))
1206       cur = cur->next;
1207   }
1208   if (cur) {
1209     free(name);
1210     return cur->type;
1211   }
1212   tp = make_type(type, NULL);
1213   tp->name = name;
1214   if (!name) return tp;
1215   return reg_type(tp, name, t);
1216 }
1217
1218 static type_t *get_typev(unsigned char type, var_t *name, int t)
1219 {
1220   char *sname = NULL;
1221   if (name) {
1222     sname = name->name;
1223     free(name);
1224   }
1225   return get_type(type, sname, t);
1226 }
1227
1228 static int get_struct_type(var_t *field)
1229 {
1230   int has_pointer = 0;
1231   int has_conformant_array = 0;
1232   int has_conformant_string = 0;
1233
1234   while (field)
1235   {
1236     type_t *t = field->type;
1237
1238     /* get the base type */
1239     while( (t->type == 0) && t->ref )
1240       t = t->ref;
1241
1242     switch (t->type)
1243     {
1244     /*
1245      * RPC_FC_BYTE, RPC_FC_STRUCT, etc
1246      *  Simple types don't effect the type of struct.
1247      *  A struct containing a simple struct is still a simple struct.
1248      *  So long as we can block copy the data, we return RPC_FC_STRUCT.
1249      */
1250     case 0: /* void pointer */
1251     case RPC_FC_BYTE:
1252     case RPC_FC_CHAR:
1253     case RPC_FC_SMALL:
1254     case RPC_FC_USMALL:
1255     case RPC_FC_WCHAR:
1256     case RPC_FC_SHORT:
1257     case RPC_FC_USHORT:
1258     case RPC_FC_LONG:
1259     case RPC_FC_ULONG:
1260     case RPC_FC_INT3264:
1261     case RPC_FC_UINT3264:
1262     case RPC_FC_HYPER:
1263     case RPC_FC_FLOAT:
1264     case RPC_FC_DOUBLE:
1265     case RPC_FC_STRUCT:
1266     case RPC_FC_ENUM16:
1267     case RPC_FC_ENUM32:
1268       break;
1269
1270     case RPC_FC_UP:
1271     case RPC_FC_FP:
1272       has_pointer = 1;
1273       break;
1274     case RPC_FC_CARRAY:
1275       has_conformant_array = 1;
1276       break;
1277     case RPC_FC_C_CSTRING:
1278     case RPC_FC_C_WSTRING:
1279       has_conformant_string = 1;
1280       break;
1281
1282     /*
1283      * Propagate member attributes
1284      *  a struct should be at least as complex as its member
1285      */
1286     case RPC_FC_CVSTRUCT:
1287       has_conformant_string = 1;
1288       has_pointer = 1;
1289       break;
1290
1291     case RPC_FC_CPSTRUCT:
1292       has_conformant_array = 1;
1293       has_pointer = 1;
1294       break;
1295
1296     case RPC_FC_CSTRUCT:
1297       has_conformant_array = 1;
1298       break;
1299
1300     case RPC_FC_PSTRUCT:
1301       has_pointer = 1;
1302       break;
1303
1304     default:
1305       fprintf(stderr,"Unknown struct member %s with type (0x%02x)\n",
1306               field->name, t->type);
1307       /* fallthru - treat it as complex */
1308
1309     /* as soon as we see one of these these members, it's bogus... */
1310     case RPC_FC_IP:
1311     case RPC_FC_ENCAPSULATED_UNION:
1312     case RPC_FC_NON_ENCAPSULATED_UNION:
1313     case RPC_FC_TRANSMIT_AS:
1314     case RPC_FC_REPRESENT_AS:
1315     case RPC_FC_PAD:
1316     case RPC_FC_EMBEDDED_COMPLEX:
1317     case RPC_FC_BOGUS_STRUCT:
1318       return RPC_FC_BOGUS_STRUCT;
1319     }
1320     field = NEXT_LINK(field);
1321   }
1322
1323   if( has_conformant_string && has_pointer )
1324     return RPC_FC_CVSTRUCT;
1325   if( has_conformant_array && has_pointer )
1326     return RPC_FC_CPSTRUCT;
1327   if( has_conformant_array )
1328     return RPC_FC_CSTRUCT;
1329   if( has_pointer )
1330     return RPC_FC_PSTRUCT;
1331   return RPC_FC_STRUCT;
1332 }
1333
1334 /***** constant repository *****/
1335
1336 struct rconst {
1337   char *name;
1338   var_t *var;
1339   struct rconst *next;
1340 };
1341
1342 struct rconst *const_hash[HASHMAX];
1343
1344 static var_t *reg_const(var_t *var)
1345 {
1346   struct rconst *nc;
1347   int hash;
1348   if (!var->name) {
1349     yyerror("registering constant without name\n");
1350     return var;
1351   }
1352   hash = hash_ident(var->name);
1353   nc = xmalloc(sizeof(struct rconst));
1354   nc->name = var->name;
1355   nc->var = var;
1356   nc->next = const_hash[hash];
1357   const_hash[hash] = nc;
1358   return var;
1359 }
1360
1361 static var_t *find_const(char *name, int f)
1362 {
1363   struct rconst *cur = const_hash[hash_ident(name)];
1364   while (cur && strcmp(cur->name, name))
1365     cur = cur->next;
1366   if (!cur) {
1367     if (f) yyerror("constant %s not found\n", name);
1368     return NULL;
1369   }
1370   return cur->var;
1371 }