git.oblomov.eu Git - wine/blob - tools/widl/parser.y

   1 %{
   2 /*
   3  * IDL Compiler
   4  *
   5  * Copyright 2002 Ove Kaaven
   6  *
   7  * This library is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU Lesser General Public
   9  * License as published by the Free Software Foundation; either
  10  * version 2.1 of the License, or (at your option) any later version.
  11  *
  12  * This library is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15  * Lesser General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU Lesser General Public
  18  * License along with this library; if not, write to the Free Software
  19  * Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA
  20  */
  21
  22 #include "config.h"
  23
  24 #include <stdio.h>
  25 #include <stdlib.h>
  26 #include <stdarg.h>
  27 #include <assert.h>
  28 #include <ctype.h>
  29 #include <string.h>
  30 #ifdef HAVE_ALLOCA_H
  31 #include <alloca.h>
  32 #endif
  33
  34 #include "windef.h"
  35
  36 #include "widl.h"
  37 #include "utils.h"
  38 #include "parser.h"
  39 #include "header.h"
  40 #include "typelib.h"
  41
  42 #if defined(YYBYACC)
  43         /* Berkeley yacc (byacc) doesn't seem to know about these */
  44         /* Some *BSD supplied versions do define these though */
  45 # ifndef YYEMPTY
  46 #  define YYEMPTY       (-1)    /* Empty lookahead value of yychar */
  47 # endif
  48 # ifndef YYLEX
  49 #  define YYLEX         yylex()
  50 # endif
  51
  52 #elif defined(YYBISON)
  53         /* Bison was used for original development */
  54         /* #define YYEMPTY -2 */
  55         /* #define YYLEX   yylex() */
  56
  57 #else
  58         /* No yacc we know yet */
  59 # if !defined(YYEMPTY) || !defined(YYLEX)
  60 #  error Yacc version/type unknown. This version needs to be verified for settings of YYEMPTY and YYLEX.
  61 # elif defined(__GNUC__)        /* gcc defines the #warning directive */
  62 #  warning Yacc version/type unknown. It defines YYEMPTY and YYLEX, but is not tested
  63   /* #else we just take a chance that it works... */
  64 # endif
  65 #endif
  66
  67 static attr_t *make_attr(enum attr_type type);
  68 static attr_t *make_attrv(enum attr_type type, unsigned long val);
  69 static attr_t *make_attrp(enum attr_type type, void *val);
  70 static expr_t *make_expr(enum expr_type type);
  71 static expr_t *make_exprl(enum expr_type type, long val);
  72 static expr_t *make_exprs(enum expr_type type, char *val);
  73 static expr_t *make_exprt(enum expr_type type, typeref_t *tref, expr_t *expr);
  74 static expr_t *make_expr1(enum expr_type type, expr_t *expr);
  75 static expr_t *make_expr2(enum expr_type type, expr_t *exp1, expr_t *exp2);
  76 static expr_t *make_expr3(enum expr_type type, expr_t *expr1, expr_t *expr2, expr_t *expr3);
  77 static type_t *make_type(unsigned char type, type_t *ref);
  78 static typeref_t *make_tref(char *name, type_t *ref);
  79 static typeref_t *uniq_tref(typeref_t *ref);
  80 static type_t *type_ref(typeref_t *ref);
  81 static void set_type(var_t *v, typeref_t *ref, expr_t *arr);
  82 static ifref_t *make_ifref(type_t *iface);
  83 static var_t *make_var(char *name);
  84 static func_t *make_func(var_t *def, var_t *args);
  85 static class_t *make_class(char *name);
  86
  87 static type_t *reg_type(type_t *type, const char *name, int t);
  88 static type_t *reg_types(type_t *type, var_t *names, int t);
  89 static type_t *find_type(const char *name, int t);
  90 static type_t *find_type2(char *name, int t);
  91 static type_t *get_type(unsigned char type, char *name, int t);
  92 static type_t *get_typev(unsigned char type, var_t *name, int t);
  93 static int get_struct_type(var_t *fields);
  94
  95 static var_t *reg_const(var_t *var);
  96 static var_t *find_const(char *name, int f);
  97
  98 #define tsENUM   1
  99 #define tsSTRUCT 2
 100 #define tsUNION  3
 101
 102 static type_t std_bool = { "boolean" };
 103 static type_t std_int = { "int" };
 104 static type_t std_int64 = { "__int64" };
 105 static type_t std_uhyper = { "MIDL_uhyper" };
 106
 107 %}
 108 %union {
 109         attr_t *attr;
 110         expr_t *expr;
 111         type_t *type;
 112         typeref_t *tref;
 113         var_t *var;
 114         func_t *func;
 115         ifref_t *ifref;
 116         class_t *clas;
 117         char *str;
 118         UUID *uuid;
 119         unsigned int num;
 120 }
 121
 122 %token <str> aIDENTIFIER
 123 %token <str> aKNOWNTYPE
 124 %token <num> aNUM aHEXNUM
 125 %token <str> aSTRING
 126 %token <uuid> aUUID
 127 %token aEOF
 128 %token SHL SHR
 129 %token tAGGREGATABLE tALLOCATE tAPPOBJECT tASYNC tASYNCUUID
 130 %token tAUTOHANDLE tBINDABLE tBOOLEAN tBROADCAST tBYTE tBYTECOUNT
 131 %token tCALLAS tCALLBACK tCASE tCDECL tCHAR tCOCLASS tCODE tCOMMSTATUS
 132 %token tCONST tCONTEXTHANDLE tCONTEXTHANDLENOSERIALIZE
 133 %token tCONTEXTHANDLESERIALIZE tCONTROL tCPPQUOTE
 134 %token tDEFAULT
 135 %token tDEFAULTCOLLELEM
 136 %token tDEFAULTVALUE
 137 %token tDEFAULTVTABLE
 138 %token tDISPLAYBIND
 139 %token tDISPINTERFACE
 140 %token tDLLNAME tDOUBLE tDUAL
 141 %token tENDPOINT
 142 %token tENTRY tENUM tERRORSTATUST
 143 %token tEXPLICITHANDLE tEXTERN
 144 %token tFLOAT
 145 %token tHANDLE
 146 %token tHANDLET
 147 %token tHELPCONTEXT tHELPFILE
 148 %token tHELPSTRING tHELPSTRINGCONTEXT tHELPSTRINGDLL
 149 %token tHIDDEN
 150 %token tHYPER tID tIDEMPOTENT
 151 %token tIIDIS
 152 %token tIMMEDIATEBIND
 153 %token tIMPLICITHANDLE
 154 %token tIMPORT tIMPORTLIB
 155 %token tIN tINLINE
 156 %token tINPUTSYNC
 157 %token tINT tINT64
 158 %token tINTERFACE
 159 %token tLCID
 160 %token tLENGTHIS tLIBRARY
 161 %token tLOCAL
 162 %token tLONG
 163 %token tMETHODS
 164 %token tMODULE
 165 %token tNONBROWSABLE
 166 %token tNONCREATABLE
 167 %token tNONEXTENSIBLE
 168 %token tOBJECT tODL tOLEAUTOMATION
 169 %token tOPTIONAL
 170 %token tOUT
 171 %token tPOINTERDEFAULT
 172 %token tPROPERTIES
 173 %token tPROPGET tPROPPUT tPROPPUTREF
 174 %token tPTR
 175 %token tPUBLIC
 176 %token tRANGE
 177 %token tREADONLY tREF
 178 %token tREQUESTEDIT
 179 %token tRESTRICTED
 180 %token tRETVAL
 181 %token tSHORT
 182 %token tSIGNED
 183 %token tSINGLE
 184 %token tSIZEIS tSIZEOF
 185 %token tSMALL
 186 %token tSOURCE
 187 %token tSTDCALL
 188 %token tSTRING tSTRUCT
 189 %token tSWITCH tSWITCHIS tSWITCHTYPE
 190 %token tTRANSMITAS
 191 %token tTYPEDEF
 192 %token tUNION
 193 %token tUNIQUE
 194 %token tUNSIGNED
 195 %token tUUID
 196 %token tV1ENUM
 197 %token tVARARG
 198 %token tVERSION
 199 %token tVOID
 200 %token tWCHAR tWIREMARSHAL
 201
 202 %type <attr> m_attributes attributes attrib_list attribute
 203 %type <expr> m_exprs /* exprs expr_list */ m_expr expr expr_list_const expr_const
 204 %type <expr> array array_list
 205 %type <type> inherit interface interfacehdr interfacedef interfacedec
 206 %type <type> dispinterface dispinterfacehdr dispinterfacedef
 207 %type <type> module modulehdr moduledef
 208 %type <type> base_type int_std
 209 %type <type> enumdef structdef typedef uniondef
 210 %type <ifref> gbl_statements coclass_ints coclass_int
 211 %type <tref> type
 212 %type <var> m_args no_args args arg
 213 %type <var> fields field s_field cases case enums enum_list enum constdef externdef
 214 %type <var> m_ident t_ident ident p_ident pident pident_list
 215 %type <var> dispint_props
 216 %type <func> funcdef int_statements
 217 %type <func> dispint_meths
 218 %type <clas> coclass coclasshdr coclassdef
 219 %type <num> pointer_type version
 220 %type <str> libraryhdr
 221
 222 %left ','
 223 %right '?' ':'
 224 %left '|'
 225 %left '&'
 226 %left '-' '+'
 227 %left '*' '/'
 228 %left SHL SHR
 229 %right '~'
 230 %right CAST
 231 %right PPTR
 232 %right NEG
 233
 234 %%
 235
 236 input:   gbl_statements                        { write_proxies($1); write_client($1); write_server($1); }
 237         ;
 238
 239 gbl_statements:                                 { $$ = NULL; }
 240         | gbl_statements interfacedec           { $$ = $1; }
 241         | gbl_statements interfacedef           { $$ = make_ifref($2); LINK($$, $1); }
 242         | gbl_statements coclassdef             { $$ = $1; add_coclass($2); }
 243         | gbl_statements moduledef              { $$ = $1; add_module($2); }
 244         | gbl_statements librarydef             { $$ = $1; }
 245         | gbl_statements statement              { $$ = $1; }
 246         ;
 247
 248 imp_statements:                                 {}
 249         | imp_statements interfacedec           { if (!parse_only) add_interface($2); }
 250         | imp_statements interfacedef           { if (!parse_only) add_interface($2); }
 251         | imp_statements coclassdef             { if (!parse_only) add_coclass($2); }
 252         | imp_statements moduledef              { if (!parse_only) add_module($2); }
 253         | imp_statements statement              {}
 254         | imp_statements importlib              {}
 255         ;
 256
 257 int_statements:                                 { $$ = NULL; }
 258         | int_statements funcdef ';'            { $$ = $2; LINK($$, $1); }
 259         | int_statements statement              { $$ = $1; }
 260         ;
 261
 262 statement: ';'                                  {}
 263         | constdef ';'                          { if (!parse_only && do_header) { write_constdef($1); } }
 264         | cppquote                              {}
 265         | enumdef ';'                           { if (!parse_only && do_header) { write_type(header, $1, NULL, NULL); fprintf(header, ";\n\n"); } }
 266         | externdef ';'                         { if (!parse_only && do_header) { write_externdef($1); } }
 267         | import                                {}
 268         | structdef ';'                         { if (!parse_only && do_header) { write_type(header, $1, NULL, NULL); fprintf(header, ";\n\n"); } }
 269         | typedef ';'                           {}
 270         | uniondef ';'                          { if (!parse_only && do_header) { write_type(header, $1, NULL, NULL); fprintf(header, ";\n\n"); } }
 271         ;
 272
 273 cppquote: tCPPQUOTE '(' aSTRING ')'             { if (!parse_only && do_header) fprintf(header, "%s\n", $3); }
 274         ;
 275 import_start: tIMPORT aSTRING ';'               { assert(yychar == YYEMPTY);
 276                                                   if (!do_import($2)) yychar = aEOF; }
 277         ;
 278 import:   import_start imp_statements aEOF      {}
 279         ;
 280
 281 importlib: tIMPORTLIB '(' aSTRING ')'           { if(!parse_only) add_importlib($3); }
 282         ;
 283
 284 libraryhdr: tLIBRARY aIDENTIFIER                { $$ = $2; }
 285         ;
 286 library_start: attributes libraryhdr '{'        { start_typelib($2, $1);
 287                                                   if (!parse_only && do_header) write_library($2, $1); }
 288         ;
 289 librarydef: library_start imp_statements '}'    { end_typelib(); }
 290         ;
 291
 292 m_args:                                         { $$ = NULL; }
 293         | args
 294         ;
 295
 296 no_args:  tVOID                                 { $$ = NULL; }
 297         ;
 298
 299 args:     arg
 300         | args ',' arg                          { LINK($3, $1); $$ = $3; }
 301         | no_args
 302         ;
 303
 304 /* split into two rules to get bison to resolve a tVOID conflict */
 305 arg:      attributes type pident array          { $$ = $3;
 306                                                   set_type($$, $2, $4);
 307                                                   $$->attrs = $1;
 308                                                 }
 309         | type pident array                     { $$ = $2;
 310                                                   set_type($$, $1, $3);
 311                                                 }
 312         | attributes type pident '(' m_args ')' { $$ = $3;
 313                                                   $$->ptr_level--;
 314                                                   set_type($$, $2, NULL);
 315                                                   $$->attrs = $1;
 316                                                   $$->args = $5;
 317                                                 }
 318         | type pident '(' m_args ')'            { $$ = $2;
 319                                                   $$->ptr_level--;
 320                                                   set_type($$, $1, NULL);
 321                                                   $$->args = $4;
 322                                                 }
 323         ;
 324
 325 array:                                          { $$ = NULL; }
 326         | '[' array_list ']'                    { $$ = $2; }
 327         | '[' '*' ']'                           { $$ = make_expr(EXPR_VOID); }
 328         ;
 329
 330 array_list: m_expr /* size of first dimension is optional */
 331         | array_list ',' expr                   { LINK($3, $1); $$ = $3; }
 332         | array_list ']' '[' expr               { LINK($4, $1); $$ = $4; }
 333         ;
 334
 335 m_attributes:                                   { $$ = NULL; }
 336         | attributes
 337         ;
 338
 339 attributes:
 340           '[' attrib_list ']'                   { $$ = $2; }
 341         ;
 342
 343 attrib_list: attribute
 344         | attrib_list ',' attribute             { LINK($3, $1); $$ = $3; }
 345         | attrib_list ']' '[' attribute         { LINK($4, $1); $$ = $4; }
 346         ;
 347
 348 attribute:
 349           tAGGREGATABLE                         { $$ = make_attr(ATTR_AGGREGATABLE); }
 350         | tAPPOBJECT                            { $$ = make_attr(ATTR_APPOBJECT); }
 351         | tASYNC                                { $$ = make_attr(ATTR_ASYNC); }
 352         | tAUTOHANDLE                           { $$ = make_attr(ATTR_AUTO_HANDLE); }
 353         | tBINDABLE                             { $$ = make_attr(ATTR_BINDABLE); }
 354         | tCALLAS '(' ident ')'                 { $$ = make_attrp(ATTR_CALLAS, $3); }
 355         | tCASE '(' expr_list_const ')'         { $$ = make_attrp(ATTR_CASE, $3); }
 356         | tCONTEXTHANDLE                        { $$ = make_attrv(ATTR_CONTEXTHANDLE, 0); }
 357         | tCONTEXTHANDLENOSERIALIZE             { $$ = make_attrv(ATTR_CONTEXTHANDLE, 0); /* RPC_CONTEXT_HANDLE_DONT_SERIALIZE */ }
 358         | tCONTEXTHANDLESERIALIZE               { $$ = make_attrv(ATTR_CONTEXTHANDLE, 0); /* RPC_CONTEXT_HANDLE_SERIALIZE */ }
 359         | tCONTROL                              { $$ = make_attr(ATTR_CONTROL); }
 360         | tDEFAULT                              { $$ = make_attr(ATTR_DEFAULT); }
 361         | tDEFAULTCOLLELEM                      { $$ = make_attr(ATTR_DEFAULTCOLLELEM); }
 362         | tDEFAULTVALUE '(' expr_const ')'      { $$ = make_attrp(ATTR_DEFAULTVALUE_EXPR, $3); }
 363         | tDEFAULTVALUE '(' aSTRING ')'         { $$ = make_attrp(ATTR_DEFAULTVALUE_STRING, $3); }
 364         | tDEFAULTVTABLE                        { $$ = make_attr(ATTR_DEFAULTVTABLE); }
 365         | tDISPLAYBIND                          { $$ = make_attr(ATTR_DISPLAYBIND); }
 366         | tDLLNAME '(' aSTRING ')'              { $$ = make_attrp(ATTR_DLLNAME, $3); }
 367         | tDUAL                                 { $$ = make_attr(ATTR_DUAL); }
 368         | tENDPOINT '(' aSTRING ')'             { $$ = make_attrp(ATTR_ENDPOINT, $3); }
 369         | tENTRY '(' aSTRING ')'                { $$ = make_attrp(ATTR_ENTRY_STRING, $3); }
 370         | tENTRY '(' expr_const ')'             { $$ = make_attrp(ATTR_ENTRY_ORDINAL, $3); }
 371         | tEXPLICITHANDLE                       { $$ = make_attr(ATTR_EXPLICIT_HANDLE); }
 372         | tHANDLE                               { $$ = make_attr(ATTR_HANDLE); }
 373         | tHELPCONTEXT '(' expr_const ')'       { $$ = make_attrp(ATTR_HELPCONTEXT, $3); }
 374         | tHELPFILE '(' aSTRING ')'             { $$ = make_attrp(ATTR_HELPFILE, $3); }
 375         | tHELPSTRING '(' aSTRING ')'           { $$ = make_attrp(ATTR_HELPSTRING, $3); }
 376         | tHELPSTRINGCONTEXT '(' expr_const ')' { $$ = make_attrp(ATTR_HELPSTRINGCONTEXT, $3); }
 377         | tHELPSTRINGDLL '(' aSTRING ')'        { $$ = make_attrp(ATTR_HELPSTRINGDLL, $3); }
 378         | tHIDDEN                               { $$ = make_attr(ATTR_HIDDEN); }
 379         | tID '(' expr_const ')'                { $$ = make_attrp(ATTR_ID, $3); }
 380         | tIDEMPOTENT                           { $$ = make_attr(ATTR_IDEMPOTENT); }
 381         | tIIDIS '(' ident ')'                  { $$ = make_attrp(ATTR_IIDIS, $3); }
 382         | tIMMEDIATEBIND                        { $$ = make_attr(ATTR_IMMEDIATEBIND); }
 383         | tIMPLICITHANDLE '(' tHANDLET aIDENTIFIER ')'  { $$ = make_attrp(ATTR_IMPLICIT_HANDLE, $4); }
 384         | tIN                                   { $$ = make_attr(ATTR_IN); }
 385         | tINPUTSYNC                            { $$ = make_attr(ATTR_INPUTSYNC); }
 386         | tLENGTHIS '(' m_exprs ')'             { $$ = make_attrp(ATTR_LENGTHIS, $3); }
 387         | tLOCAL                                { $$ = make_attr(ATTR_LOCAL); }
 388         | tNONBROWSABLE                         { $$ = make_attr(ATTR_NONBROWSABLE); }
 389         | tNONCREATABLE                         { $$ = make_attr(ATTR_NONCREATABLE); }
 390         | tNONEXTENSIBLE                        { $$ = make_attr(ATTR_NONEXTENSIBLE); }
 391         | tOBJECT                               { $$ = make_attr(ATTR_OBJECT); }
 392         | tODL                                  { $$ = make_attr(ATTR_ODL); }
 393         | tOLEAUTOMATION                        { $$ = make_attr(ATTR_OLEAUTOMATION); }
 394         | tOPTIONAL                             { $$ = make_attr(ATTR_OPTIONAL); }
 395         | tOUT                                  { $$ = make_attr(ATTR_OUT); }
 396         | tPOINTERDEFAULT '(' pointer_type ')'  { $$ = make_attrv(ATTR_POINTERDEFAULT, $3); }
 397         | tPROPGET                              { $$ = make_attr(ATTR_PROPGET); }
 398         | tPROPPUT                              { $$ = make_attr(ATTR_PROPPUT); }
 399         | tPROPPUTREF                           { $$ = make_attr(ATTR_PROPPUTREF); }
 400         | tPUBLIC                               { $$ = make_attr(ATTR_PUBLIC); }
 401         | tRANGE '(' expr_const ',' expr_const ')' { LINK($5, $3); $$ = make_attrp(ATTR_RANGE, $5); }
 402         | tREADONLY                             { $$ = make_attr(ATTR_READONLY); }
 403         | tREQUESTEDIT                          { $$ = make_attr(ATTR_REQUESTEDIT); }
 404         | tRESTRICTED                           { $$ = make_attr(ATTR_RESTRICTED); }
 405         | tRETVAL                               { $$ = make_attr(ATTR_RETVAL); }
 406         | tSIZEIS '(' m_exprs ')'               { $$ = make_attrp(ATTR_SIZEIS, $3); }
 407         | tSOURCE                               { $$ = make_attr(ATTR_SOURCE); }
 408         | tSTRING                               { $$ = make_attr(ATTR_STRING); }
 409         | tSWITCHIS '(' expr ')'                { $$ = make_attrp(ATTR_SWITCHIS, $3); }
 410         | tSWITCHTYPE '(' type ')'              { $$ = make_attrp(ATTR_SWITCHTYPE, type_ref($3)); }
 411         | tTRANSMITAS '(' type ')'              { $$ = make_attrp(ATTR_TRANSMITAS, type_ref($3)); }
 412         | tUUID '(' aUUID ')'                   { $$ = make_attrp(ATTR_UUID, $3); }
 413         | tV1ENUM                               { $$ = make_attr(ATTR_V1ENUM); }
 414         | tVARARG                               { $$ = make_attr(ATTR_VARARG); }
 415         | tVERSION '(' version ')'              { $$ = make_attrv(ATTR_VERSION, $3); }
 416         | tWIREMARSHAL '(' type ')'             { $$ = make_attrp(ATTR_WIREMARSHAL, type_ref($3)); }
 417         | pointer_type                          { $$ = make_attrv(ATTR_POINTERTYPE, $1); }
 418         ;
 419
 420 callconv:
 421         | tSTDCALL
 422         ;
 423
 424 cases:                                          { $$ = NULL; }
 425         | cases case                            { if ($2) { LINK($2, $1); $$ = $2; }
 426                                                   else { $$ = $1; }
 427                                                 }
 428         ;
 429
 430 case:     tCASE expr ':' field                  { attr_t *a = make_attrp(ATTR_CASE, $2);
 431                                                   $$ = $4; if (!$$) $$ = make_var(NULL);
 432                                                   LINK(a, $$->attrs); $$->attrs = a;
 433                                                 }
 434         | tDEFAULT ':' field                    { attr_t *a = make_attr(ATTR_DEFAULT);
 435                                                   $$ = $3; if (!$$) $$ = make_var(NULL);
 436                                                   LINK(a, $$->attrs); $$->attrs = a;
 437                                                 }
 438         ;
 439
 440 constdef: tCONST type ident '=' expr_const      { $$ = reg_const($3);
 441                                                   set_type($$, $2, NULL);
 442                                                   $$->eval = $5;
 443                                                 }
 444         ;
 445
 446 enums:                                          { $$ = NULL; }
 447         | enum_list ','                         { $$ = $1; }
 448         | enum_list
 449         ;
 450
 451 enum_list: enum                                 { if (!$$->eval)
 452                                                     $$->eval = make_exprl(EXPR_NUM, 0 /* default for first enum entry */);
 453                                                 }
 454         | enum_list ',' enum                    { LINK($3, $1); $$ = $3;
 455                                                   if (!$$->eval)
 456                                                     $$->eval = make_exprl(EXPR_NUM, $1->eval->cval + 1);
 457                                                 }
 458         ;
 459
 460 enum:     ident '=' expr_const                  { $$ = reg_const($1);
 461                                                   $$->eval = $3;
 462                                                   $$->type = make_type(RPC_FC_LONG, &std_int);
 463                                                 }
 464         | ident                                 { $$ = reg_const($1);
 465                                                   $$->type = make_type(RPC_FC_LONG, &std_int);
 466                                                 }
 467         ;
 468
 469 enumdef: tENUM t_ident '{' enums '}'            { $$ = get_typev(RPC_FC_ENUM16, $2, tsENUM);
 470                                                   $$->fields = $4;
 471                                                   $$->defined = TRUE;
 472                                                   if(in_typelib)
 473                                                       add_enum($$);
 474                                                 }
 475         ;
 476
 477 m_exprs:  m_expr
 478         | m_exprs ',' m_expr                    { LINK($3, $1); $$ = $3; }
 479         ;
 480
 481 /*
 482 exprs:                                          { $$ = make_expr(EXPR_VOID); }
 483         | expr_list
 484         ;
 485
 486 expr_list: expr
 487         | expr_list ',' expr                    { LINK($3, $1); $$ = $3; }
 488         ;
 489 */
 490
 491 m_expr:                                         { $$ = make_expr(EXPR_VOID); }
 492         | expr
 493         ;
 494
 495 expr:     aNUM                                  { $$ = make_exprl(EXPR_NUM, $1); }
 496         | aHEXNUM                               { $$ = make_exprl(EXPR_HEXNUM, $1); }
 497         | aIDENTIFIER                           { $$ = make_exprs(EXPR_IDENTIFIER, $1); }
 498         | expr '?' expr ':' expr                { $$ = make_expr3(EXPR_COND, $1, $3, $5); }
 499         | expr '|' expr                         { $$ = make_expr2(EXPR_OR , $1, $3); }
 500         | expr '&' expr                         { $$ = make_expr2(EXPR_AND, $1, $3); }
 501         | expr '+' expr                         { $$ = make_expr2(EXPR_ADD, $1, $3); }
 502         | expr '-' expr                         { $$ = make_expr2(EXPR_SUB, $1, $3); }
 503         | expr '*' expr                         { $$ = make_expr2(EXPR_MUL, $1, $3); }
 504         | expr '/' expr                         { $$ = make_expr2(EXPR_DIV, $1, $3); }
 505         | expr SHL expr                         { $$ = make_expr2(EXPR_SHL, $1, $3); }
 506         | expr SHR expr                         { $$ = make_expr2(EXPR_SHR, $1, $3); }
 507         | '~' expr                              { $$ = make_expr1(EXPR_NOT, $2); }
 508         | '-' expr %prec NEG                    { $$ = make_expr1(EXPR_NEG, $2); }
 509         | '*' expr %prec PPTR                   { $$ = make_expr1(EXPR_PPTR, $2); }
 510         | '(' type ')' expr %prec CAST          { $$ = make_exprt(EXPR_CAST, $2, $4); }
 511         | tSIZEOF '(' type ')'                  { $$ = make_exprt(EXPR_SIZEOF, $3, NULL); }
 512         | '(' expr ')'                          { $$ = $2; }
 513         ;
 514
 515 expr_list_const: expr_const
 516         | expr_list_const ',' expr_const        { LINK($3, $1); $$ = $3; }
 517         ;
 518
 519 expr_const: expr                                { $$ = $1;
 520                                                   if (!$$->is_const)
 521                                                       yyerror("expression is not constant");
 522                                                 }
 523         ;
 524
 525 externdef: tEXTERN tCONST type ident            { $$ = $4;
 526                                                   set_type($$, $3, NULL);
 527                                                 }
 528         ;
 529
 530 fields:                                         { $$ = NULL; }
 531         | fields field                          { if ($2) { LINK($2, $1); $$ = $2; }
 532                                                   else { $$ = $1; }
 533                                                 }
 534         ;
 535
 536 field:    s_field ';'                           { $$ = $1; }
 537         | m_attributes uniondef ';'             { $$ = make_var(NULL); $$->type = $2; $$->attrs = $1; }
 538         | attributes ';'                        { $$ = make_var(NULL); $$->attrs = $1; }
 539         | ';'                                   { $$ = NULL; }
 540         ;
 541
 542 s_field:  m_attributes type pident array        { $$ = $3; set_type($$, $2, $4); $$->attrs = $1; }
 543         ;
 544
 545 funcdef:
 546           m_attributes type callconv pident
 547           '(' m_args ')'                        { set_type($4, $2, NULL);
 548                                                   $4->attrs = $1;
 549                                                   $$ = make_func($4, $6);
 550                                                   if (is_attr($4->attrs, ATTR_IN)) {
 551                                                     yyerror("inapplicable attribute [in] for function '%s'",$$->def->name);
 552                                                   }
 553                                                 }
 554         ;
 555
 556 m_ident:                                        { $$ = NULL; }
 557         | ident
 558         ;
 559
 560 t_ident:                                        { $$ = NULL; }
 561         | aIDENTIFIER                           { $$ = make_var($1); }
 562         | aKNOWNTYPE                            { $$ = make_var($1); }
 563         ;
 564
 565 ident:    aIDENTIFIER                           { $$ = make_var($1); }
 566 /* some "reserved words" used in attributes are also used as field names in some MS IDL files */
 567         | aKNOWNTYPE                            { $$ = make_var($<str>1); }
 568         | tASYNC                                { $$ = make_var($<str>1); }
 569         | tID                                   { $$ = make_var($<str>1); }
 570         | tLCID                                 { $$ = make_var($<str>1); }
 571         | tOBJECT                               { $$ = make_var($<str>1); }
 572         | tRANGE                                { $$ = make_var($<str>1); }
 573         | tRETVAL                               { $$ = make_var($<str>1); }
 574         | tUUID                                 { $$ = make_var($<str>1); }
 575         | tVERSION                              { $$ = make_var($<str>1); }
 576         ;
 577
 578 base_type: tBYTE                                { $$ = make_type(RPC_FC_BYTE, NULL); }
 579         | tWCHAR                                { $$ = make_type(RPC_FC_WCHAR, NULL); }
 580         | int_std
 581         | tSIGNED int_std                       { $$ = $2; $$->sign = 1; }
 582         | tUNSIGNED int_std                     { $$ = $2; $$->sign = -1;
 583                                                   switch ($$->type) {
 584                                                   case RPC_FC_CHAR:  break;
 585                                                   case RPC_FC_SMALL: $$->type = RPC_FC_USMALL; break;
 586                                                   case RPC_FC_SHORT: $$->type = RPC_FC_USHORT; break;
 587                                                   case RPC_FC_LONG:  $$->type = RPC_FC_ULONG;  break;
 588                                                   case RPC_FC_HYPER:
 589                                                     if (!$$->ref) { $$->ref = &std_uhyper; $$->sign = 0; }
 590                                                     break;
 591                                                   default: break;
 592                                                   }
 593                                                 }
 594         | tUNSIGNED                             { $$ = make_type(RPC_FC_ULONG, &std_int); $$->sign = -1; }
 595         | tFLOAT                                { $$ = make_type(RPC_FC_FLOAT, NULL); }
 596         | tSINGLE                               { $$ = make_type(RPC_FC_FLOAT, NULL); }
 597         | tDOUBLE                               { $$ = make_type(RPC_FC_DOUBLE, NULL); }
 598         | tBOOLEAN                              { $$ = make_type(RPC_FC_BYTE, &std_bool); /* ? */ }
 599         | tERRORSTATUST                         { $$ = make_type(RPC_FC_ERROR_STATUS_T, NULL); }
 600         | tHANDLET                              { $$ = make_type(RPC_FC_BIND_PRIMITIVE, NULL); /* ? */ }
 601         ;
 602
 603 m_int:
 604         | tINT
 605         ;
 606
 607 int_std:  tINT                                  { $$ = make_type(RPC_FC_LONG, &std_int); } /* win32 only */
 608         | tSHORT m_int                          { $$ = make_type(RPC_FC_SHORT, NULL); }
 609         | tSMALL                                { $$ = make_type(RPC_FC_SMALL, NULL); }
 610         | tLONG m_int                           { $$ = make_type(RPC_FC_LONG, NULL); }
 611         | tHYPER m_int                          { $$ = make_type(RPC_FC_HYPER, NULL); }
 612         | tINT64                                { $$ = make_type(RPC_FC_HYPER, &std_int64); }
 613         | tCHAR                                 { $$ = make_type(RPC_FC_CHAR, NULL); }
 614         ;
 615
 616 coclass:  tCOCLASS aIDENTIFIER                  { $$ = make_class($2); }
 617         | tCOCLASS aKNOWNTYPE                   { $$ = make_class($2); }
 618         ;
 619
 620 coclasshdr: attributes coclass                  { $$ = $2;
 621                                                   $$->attrs = $1;
 622                                                   if (!parse_only && do_header)
 623                                                     write_coclass($$);
 624                                                 }
 625         ;
 626
 627 coclassdef: coclasshdr '{' coclass_ints '}'     { $$ = $1;
 628                                                   $$->ifaces = $3;
 629                                                 }
 630         ;
 631
 632 coclass_ints:                                   { $$ = NULL; }
 633         | coclass_ints coclass_int              { LINK($2, $1); $$ = $2; }
 634         ;
 635
 636 coclass_int:
 637           m_attributes interfacedec             { $$ = make_ifref($2); $$->attrs = $1; }
 638         ;
 639
 640 dispinterface: tDISPINTERFACE aIDENTIFIER       { $$ = get_type(0, $2, 0); }
 641         |      tDISPINTERFACE aKNOWNTYPE        { $$ = get_type(0, $2, 0); }
 642         ;
 643
 644 dispinterfacehdr: attributes dispinterface      { attr_t *attrs;
 645                                                   $$ = $2;
 646                                                   if ($$->defined) yyerror("multiple definition error");
 647                                                   attrs = make_attr(ATTR_DISPINTERFACE);
 648                                                   LINK(attrs, $1);
 649                                                   $$->attrs = attrs;
 650                                                   $$->ref = find_type("IDispatch", 0);
 651                                                   if (!$$->ref) yyerror("IDispatch is undefined");
 652                                                   $$->defined = TRUE;
 653                                                   if (!parse_only && do_header) write_forward($$);
 654                                                 }
 655         ;
 656
 657 dispint_props: tPROPERTIES ':'                  { $$ = NULL; }
 658         | dispint_props s_field ';'             { LINK($2, $1); $$ = $2; }
 659         ;
 660
 661 dispint_meths: tMETHODS ':'                     { $$ = NULL; }
 662         | dispint_meths funcdef ';'             { LINK($2, $1); $$ = $2; }
 663         ;
 664
 665 dispinterfacedef: dispinterfacehdr '{'
 666           dispint_props
 667           dispint_meths
 668           '}'                                   { $$ = $1;
 669                                                   $$->fields = $3;
 670                                                   $$->funcs = $4;
 671                                                   if (!parse_only && do_header) write_dispinterface($$);
 672                                                 }
 673 /* FIXME: not sure how to handle this yet
 674         | dispinterfacehdr '{' interface '}'    { $$ = $1;
 675                                                   if (!parse_only && do_header) write_interface($$);
 676                                                 }
 677 */
 678         ;
 679
 680 inherit:                                        { $$ = NULL; }
 681         | ':' aKNOWNTYPE                        { $$ = find_type2($2, 0); }
 682         ;
 683
 684 interface: tINTERFACE aIDENTIFIER               { $$ = get_type(RPC_FC_IP, $2, 0); }
 685         |  tINTERFACE aKNOWNTYPE                { $$ = get_type(RPC_FC_IP, $2, 0); }
 686         ;
 687
 688 interfacehdr: attributes interface              { $$ = $2;
 689                                                   if ($$->defined) yyerror("multiple definition error");
 690                                                   $$->attrs = $1;
 691                                                   $$->defined = TRUE;
 692                                                   if (!parse_only && do_header) write_forward($$);
 693                                                 }
 694         ;
 695
 696 interfacedef: interfacehdr inherit
 697           '{' int_statements '}'                { $$ = $1;
 698                                                   $$->ref = $2;
 699                                                   $$->funcs = $4;
 700                                                   if (!parse_only && do_header) write_interface($$);
 701                                                 }
 702 /* MIDL is able to import the definition of a base class from inside the
 703  * definition of a derived class, I'll try to support it with this rule */
 704         | interfacehdr ':' aIDENTIFIER
 705           '{' import int_statements '}'         { $$ = $1;
 706                                                   $$->ref = find_type2($3, 0);
 707                                                   if (!$$->ref) yyerror("base class '%s' not found in import", $3);
 708                                                   $$->funcs = $6;
 709                                                   if (!parse_only && do_header) write_interface($$);
 710                                                 }
 711         | dispinterfacedef                      { $$ = $1; }
 712         ;
 713
 714 interfacedec:
 715           interface ';'                         { $$ = $1; if (!parse_only && do_header) write_forward($$); }
 716         | dispinterface ';'                     { $$ = $1; if (!parse_only && do_header) write_forward($$); }
 717         ;
 718
 719 module:   tMODULE aIDENTIFIER                   { $$ = make_type(0, NULL); $$->name = $2; }
 720         | tMODULE aKNOWNTYPE                    { $$ = make_type(0, NULL); $$->name = $2; }
 721         ;
 722
 723 modulehdr: attributes module                    { $$ = $2;
 724                                                   $$->attrs = $1;
 725                                                 }
 726         ;
 727
 728 moduledef: modulehdr '{' int_statements '}'     { $$ = $1;
 729                                                   $$->funcs = $3;
 730                                                   /* FIXME: if (!parse_only && do_header) write_module($$); */
 731                                                 }
 732         ;
 733
 734 p_ident:  '*' pident %prec PPTR                 { $$ = $2; $$->ptr_level++; }
 735         | tCONST p_ident                        { $$ = $2; /* FIXME */ }
 736         ;
 737
 738 pident:   ident
 739         | p_ident
 740         | '(' pident ')'                        { $$ = $2; }
 741         ;
 742
 743 pident_list:
 744           pident
 745         | pident_list ',' pident                { LINK($3, $1); $$ = $3; }
 746         ;
 747
 748 pointer_type:
 749           tREF                                  { $$ = RPC_FC_RP; }
 750         | tUNIQUE                               { $$ = RPC_FC_UP; }
 751         | tPTR                                  { $$ = RPC_FC_FP; }
 752         ;
 753
 754 structdef: tSTRUCT t_ident '{' fields '}'       { $$ = get_typev(RPC_FC_STRUCT, $2, tsSTRUCT);
 755                                                   /* overwrite RPC_FC_STRUCT with a more exact type */
 756                                                   $$->type = get_struct_type( $4 );
 757                                                   $$->fields = $4;
 758                                                   $$->defined = TRUE;
 759                                                   if(in_typelib)
 760                                                       add_struct($$);
 761                                                 }
 762         ;
 763
 764 type:     tVOID                                 { $$ = make_tref(NULL, make_type(0, NULL)); }
 765         | aKNOWNTYPE                            { $$ = make_tref($1, find_type($1, 0)); }
 766         | base_type                             { $$ = make_tref(NULL, $1); }
 767         | tCONST type                           { $$ = uniq_tref($2); $$->ref->is_const = TRUE; }
 768         | enumdef                               { $$ = make_tref(NULL, $1); }
 769         | tENUM aIDENTIFIER                     { $$ = make_tref(NULL, find_type2($2, tsENUM)); }
 770         | structdef                             { $$ = make_tref(NULL, $1); }
 771         | tSTRUCT aIDENTIFIER                   { $$ = make_tref(NULL, get_type(RPC_FC_STRUCT, $2, tsSTRUCT)); }
 772         | uniondef                              { $$ = make_tref(NULL, $1); }
 773         | tUNION aIDENTIFIER                    { $$ = make_tref(NULL, find_type2($2, tsUNION)); }
 774         ;
 775
 776 typedef: tTYPEDEF m_attributes type pident_list { typeref_t *tref = uniq_tref($3);
 777                                                   $4->tname = tref->name;
 778                                                   tref->name = NULL;
 779                                                   $$ = type_ref(tref);
 780                                                   $$->attrs = $2;
 781                                                   if (!parse_only && do_header)
 782                                                     write_typedef($$, $4);
 783                                                   if (in_typelib && $$->attrs)
 784                                                     add_typedef($$, $4);
 785                                                   reg_types($$, $4, 0);
 786                                                 }
 787         ;
 788
 789 uniondef: tUNION t_ident '{' fields '}'         { $$ = get_typev(RPC_FC_NON_ENCAPSULATED_UNION, $2, tsUNION);
 790                                                   $$->fields = $4;
 791                                                   $$->defined = TRUE;
 792                                                 }
 793         | tUNION t_ident
 794           tSWITCH '(' s_field ')'
 795           m_ident '{' cases '}'                 { var_t *u = $7;
 796                                                   $$ = get_typev(RPC_FC_ENCAPSULATED_UNION, $2, tsUNION);
 797                                                   if (!u) u = make_var("tagged_union");
 798                                                   u->type = make_type(RPC_FC_NON_ENCAPSULATED_UNION, NULL);
 799                                                   u->type->fields = $9;
 800                                                   u->type->defined = TRUE;
 801                                                   LINK(u, $5); $$->fields = u;
 802                                                   $$->defined = TRUE;
 803                                                 }
 804         ;
 805
 806 version:
 807           aNUM                                  { $$ = MAKELONG($1, 0); }
 808         | aNUM '.' aNUM                         { $$ = MAKELONG($1, $3); }
 809         ;
 810
 811 %%
 812
 813 static attr_t *make_attr(enum attr_type type)
 814 {
 815   attr_t *a = xmalloc(sizeof(attr_t));
 816   a->type = type;
 817   a->u.ival = 0;
 818   INIT_LINK(a);
 819   return a;
 820 }
 821
 822 static attr_t *make_attrv(enum attr_type type, unsigned long val)
 823 {
 824   attr_t *a = xmalloc(sizeof(attr_t));
 825   a->type = type;
 826   a->u.ival = val;
 827   INIT_LINK(a);
 828   return a;
 829 }
 830
 831 static attr_t *make_attrp(enum attr_type type, void *val)
 832 {
 833   attr_t *a = xmalloc(sizeof(attr_t));
 834   a->type = type;
 835   a->u.pval = val;
 836   INIT_LINK(a);
 837   return a;
 838 }
 839
 840 static expr_t *make_expr(enum expr_type type)
 841 {
 842   expr_t *e = xmalloc(sizeof(expr_t));
 843   e->type = type;
 844   e->ref = NULL;
 845   e->u.lval = 0;
 846   e->is_const = FALSE;
 847   INIT_LINK(e);
 848   return e;
 849 }
 850
 851 static expr_t *make_exprl(enum expr_type type, long val)
 852 {
 853   expr_t *e = xmalloc(sizeof(expr_t));
 854   e->type = type;
 855   e->ref = NULL;
 856   e->u.lval = val;
 857   e->is_const = FALSE;
 858   INIT_LINK(e);
 859   /* check for numeric constant */
 860   if (type == EXPR_NUM || type == EXPR_HEXNUM) {
 861     e->is_const = TRUE;
 862     e->cval = val;
 863   }
 864   return e;
 865 }
 866
 867 static expr_t *make_exprs(enum expr_type type, char *val)
 868 {
 869   expr_t *e;
 870   e = xmalloc(sizeof(expr_t));
 871   e->type = type;
 872   e->ref = NULL;
 873   e->u.sval = val;
 874   e->is_const = FALSE;
 875   INIT_LINK(e);
 876   /* check for predefined constants */
 877   if (type == EXPR_IDENTIFIER) {
 878     var_t *c = find_const(val, 0);
 879     if (c) {
 880       e->u.sval = c->name;
 881       free(val);
 882       e->is_const = TRUE;
 883       e->cval = c->eval->cval;
 884     }
 885   }
 886   return e;
 887 }
 888
 889 static expr_t *make_exprt(enum expr_type type, typeref_t *tref, expr_t *expr)
 890 {
 891   expr_t *e;
 892   e = xmalloc(sizeof(expr_t));
 893   e->type = type;
 894   e->ref = expr;
 895   e->u.tref = tref;
 896   e->is_const = FALSE;
 897   INIT_LINK(e);
 898   /* check for cast of constant expression */
 899   if (type == EXPR_SIZEOF) {
 900     switch (tref->ref->type) {
 901       case RPC_FC_BYTE:
 902       case RPC_FC_CHAR:
 903       case RPC_FC_SMALL:
 904       case RPC_FC_USMALL:
 905         e->is_const = TRUE;
 906         e->cval = 1;
 907         break;
 908       case RPC_FC_WCHAR:
 909       case RPC_FC_USHORT:
 910       case RPC_FC_SHORT:
 911         e->is_const = TRUE;
 912         e->cval = 2;
 913         break;
 914       case RPC_FC_LONG:
 915       case RPC_FC_ULONG:
 916       case RPC_FC_FLOAT:
 917       case RPC_FC_ERROR_STATUS_T:
 918         e->is_const = TRUE;
 919         e->cval = 4;
 920         break;
 921       case RPC_FC_HYPER:
 922       case RPC_FC_DOUBLE:
 923         e->is_const = TRUE;
 924         e->cval = 8;
 925         break;
 926     }
 927   }
 928   if (type == EXPR_CAST && expr->is_const) {
 929     e->is_const = TRUE;
 930     e->cval = expr->cval;
 931   }
 932   return e;
 933 }
 934
 935 static expr_t *make_expr1(enum expr_type type, expr_t *expr)
 936 {
 937   expr_t *e;
 938   e = xmalloc(sizeof(expr_t));
 939   e->type = type;
 940   e->ref = expr;
 941   e->u.lval = 0;
 942   e->is_const = FALSE;
 943   INIT_LINK(e);
 944   /* check for compile-time optimization */
 945   if (expr->is_const) {
 946     e->is_const = TRUE;
 947     switch (type) {
 948     case EXPR_NEG:
 949       e->cval = -expr->cval;
 950       break;
 951     case EXPR_NOT:
 952       e->cval = ~expr->cval;
 953       break;
 954     default:
 955       e->is_const = FALSE;
 956       break;
 957     }
 958   }
 959   return e;
 960 }
 961
 962 static expr_t *make_expr2(enum expr_type type, expr_t *expr1, expr_t *expr2)
 963 {
 964   expr_t *e;
 965   e = xmalloc(sizeof(expr_t));
 966   e->type = type;
 967   e->ref = expr1;
 968   e->u.ext = expr2;
 969   e->is_const = FALSE;
 970   INIT_LINK(e);
 971   /* check for compile-time optimization */
 972   if (expr1->is_const && expr2->is_const) {
 973     e->is_const = TRUE;
 974     switch (type) {
 975     case EXPR_ADD:
 976       e->cval = expr1->cval + expr2->cval;
 977       break;
 978     case EXPR_SUB:
 979       e->cval = expr1->cval - expr2->cval;
 980       break;
 981     case EXPR_MUL:
 982       e->cval = expr1->cval * expr2->cval;
 983       break;
 984     case EXPR_DIV:
 985       e->cval = expr1->cval / expr2->cval;
 986       break;
 987     case EXPR_OR:
 988       e->cval = expr1->cval | expr2->cval;
 989       break;
 990     case EXPR_AND:
 991       e->cval = expr1->cval & expr2->cval;
 992       break;
 993     case EXPR_SHL:
 994       e->cval = expr1->cval << expr2->cval;
 995       break;
 996     case EXPR_SHR:
 997       e->cval = expr1->cval >> expr2->cval;
 998       break;
 999     default:
1000       e->is_const = FALSE;
1001       break;
1002     }
1003   }
1004   return e;
1005 }
1006
1007 static expr_t *make_expr3(enum expr_type type, expr_t *expr1, expr_t *expr2, expr_t *expr3)
1008 {
1009   expr_t *e;
1010   e = xmalloc(sizeof(expr_t));
1011   e->type = type;
1012   e->ref = expr1;
1013   e->u.ext = expr2;
1014   e->ext2 = expr3;
1015   e->is_const = FALSE;
1016   INIT_LINK(e);
1017   /* check for compile-time optimization */
1018   if (expr1->is_const && expr2->is_const && expr3->is_const) {
1019     e->is_const = TRUE;
1020     switch (type) {
1021     case EXPR_COND:
1022       e->cval = expr1->cval ? expr2->cval : expr3->cval;
1023       break;
1024     default:
1025       e->is_const = FALSE;
1026       break;
1027     }
1028   }
1029   return e;
1030 }
1031
1032 static type_t *make_type(unsigned char type, type_t *ref)
1033 {
1034   type_t *t = xmalloc(sizeof(type_t));
1035   t->name = NULL;
1036   t->type = type;
1037   t->ref = ref;
1038   t->attrs = NULL;
1039   t->funcs = NULL;
1040   t->fields = NULL;
1041   t->ignore = parse_only;
1042   t->is_const = FALSE;
1043   t->sign = 0;
1044   t->defined = FALSE;
1045   t->written = FALSE;
1046   t->typelib_idx = -1;
1047   INIT_LINK(t);
1048   return t;
1049 }
1050
1051 static typeref_t *make_tref(char *name, type_t *ref)
1052 {
1053   typeref_t *t = xmalloc(sizeof(typeref_t));
1054   t->name = name;
1055   t->ref = ref;
1056   t->uniq = ref ? 0 : 1;
1057   return t;
1058 }
1059
1060 static typeref_t *uniq_tref(typeref_t *ref)
1061 {
1062   typeref_t *t = ref;
1063   type_t *tp;
1064   if (t->uniq) return t;
1065   tp = make_type(0, t->ref);
1066   tp->name = t->name;
1067   t->name = NULL;
1068   t->ref = tp;
1069   t->uniq = 1;
1070   return t;
1071 }
1072
1073 static type_t *type_ref(typeref_t *ref)
1074 {
1075   type_t *t = ref->ref;
1076   if (ref->name) free(ref->name);
1077   free(ref);
1078   return t;
1079 }
1080
1081 static void set_type(var_t *v, typeref_t *ref, expr_t *arr)
1082 {
1083   v->type = ref->ref;
1084   v->tname = ref->name;
1085   ref->name = NULL;
1086   free(ref);
1087   v->array = arr;
1088 }
1089
1090 static ifref_t *make_ifref(type_t *iface)
1091 {
1092   ifref_t *l = xmalloc(sizeof(ifref_t));
1093   l->iface = iface;
1094   l->attrs = NULL;
1095   INIT_LINK(l);
1096   return l;
1097 }
1098
1099 static var_t *make_var(char *name)
1100 {
1101   var_t *v = xmalloc(sizeof(var_t));
1102   v->name = name;
1103   v->ptr_level = 0;
1104   v->type = NULL;
1105   v->tname = NULL;
1106   v->attrs = NULL;
1107   v->array = NULL;
1108   v->eval = NULL;
1109   INIT_LINK(v);
1110   return v;
1111 }
1112
1113 static func_t *make_func(var_t *def, var_t *args)
1114 {
1115   func_t *f = xmalloc(sizeof(func_t));
1116   f->def = def;
1117   f->args = args;
1118   f->ignore = parse_only;
1119   f->idx = -1;
1120   INIT_LINK(f);
1121   return f;
1122 }
1123
1124 static class_t *make_class(char *name)
1125 {
1126   class_t *c = xmalloc(sizeof(class_t));
1127   c->name = name;
1128   c->attrs = NULL;
1129   c->ifaces = NULL;
1130   INIT_LINK(c);
1131   return c;
1132 }
1133
1134 #define HASHMAX 64
1135
1136 static int hash_ident(const char *name)
1137 {
1138   const char *p = name;
1139   int sum = 0;
1140   /* a simple sum hash is probably good enough */
1141   while (*p) {
1142     sum += *p;
1143     p++;
1144   }
1145   return sum & (HASHMAX-1);
1146 }
1147
1148 /***** type repository *****/
1149
1150 struct rtype {
1151   const char *name;
1152   type_t *type;
1153   int t;
1154   struct rtype *next;
1155 };
1156
1157 struct rtype *type_hash[HASHMAX];
1158
1159 static type_t *reg_type(type_t *type, const char *name, int t)
1160 {
1161   struct rtype *nt;
1162   int hash;
1163   if (!name) {
1164     yyerror("registering named type without name");
1165     return type;
1166   }
1167   hash = hash_ident(name);
1168   nt = xmalloc(sizeof(struct rtype));
1169   nt->name = name;
1170   nt->type = type;
1171   nt->t = t;
1172   nt->next = type_hash[hash];
1173   type_hash[hash] = nt;
1174   return type;
1175 }
1176
1177 /* determine pointer type from attrs */
1178 static unsigned char get_pointer_type( type_t *type )
1179 {
1180   int t;
1181   if (is_attr( type->attrs, ATTR_STRING ))
1182   {
1183     type_t *t = type;
1184     while( t->type == 0 && t->ref )
1185       t = t->ref;
1186     switch( t->type )
1187     {
1188     case RPC_FC_CHAR:
1189       return RPC_FC_C_CSTRING;
1190     case RPC_FC_WCHAR:
1191       return RPC_FC_C_WSTRING;
1192     }
1193   }
1194   t = get_attrv( type->attrs, ATTR_POINTERTYPE );
1195   if (t) return t;
1196   return RPC_FC_FP;
1197 }
1198
1199 static type_t *reg_types(type_t *type, var_t *names, int t)
1200 {
1201   type_t *ptr = type;
1202   int ptrc = 0;
1203
1204   while (names) {
1205     var_t *next = NEXT_LINK(names);
1206     if (names->name) {
1207       type_t *cur = ptr;
1208       int cptr = names->ptr_level;
1209       if (cptr > ptrc) {
1210         while (cptr > ptrc) {
1211           int t = get_pointer_type( cur );
1212           cur = ptr = make_type(t, cur);
1213           ptrc++;
1214         }
1215       } else {
1216         while (cptr < ptrc) {
1217           cur = cur->ref;
1218           cptr++;
1219         }
1220       }
1221       reg_type(cur, names->name, t);
1222     }
1223     free(names);
1224     names = next;
1225   }
1226   return type;
1227 }
1228
1229 static type_t *find_type(const char *name, int t)
1230 {
1231   struct rtype *cur = type_hash[hash_ident(name)];
1232   while (cur && (cur->t != t || strcmp(cur->name, name)))
1233     cur = cur->next;
1234   if (!cur) {
1235     yyerror("type '%s' not found", name);
1236     return NULL;
1237   }
1238   return cur->type;
1239 }
1240
1241 static type_t *find_type2(char *name, int t)
1242 {
1243   type_t *tp = find_type(name, t);
1244   free(name);
1245   return tp;
1246 }
1247
1248 int is_type(const char *name)
1249 {
1250   struct rtype *cur = type_hash[hash_ident(name)];
1251   while (cur && (cur->t || strcmp(cur->name, name)))
1252     cur = cur->next;
1253   if (cur) return TRUE;
1254   return FALSE;
1255 }
1256
1257 static type_t *get_type(unsigned char type, char *name, int t)
1258 {
1259   struct rtype *cur = NULL;
1260   type_t *tp;
1261   if (name) {
1262     cur = type_hash[hash_ident(name)];
1263     while (cur && (cur->t != t || strcmp(cur->name, name)))
1264       cur = cur->next;
1265   }
1266   if (cur) {
1267     free(name);
1268     return cur->type;
1269   }
1270   tp = make_type(type, NULL);
1271   tp->name = name;
1272   if (!name) return tp;
1273   return reg_type(tp, name, t);
1274 }
1275
1276 static type_t *get_typev(unsigned char type, var_t *name, int t)
1277 {
1278   char *sname = NULL;
1279   if (name) {
1280     sname = name->name;
1281     free(name);
1282   }
1283   return get_type(type, sname, t);
1284 }
1285
1286 static int get_struct_type(var_t *field)
1287 {
1288   int has_pointer = 0;
1289   int has_conformance = 0;
1290   int has_variance = 0;
1291
1292   for (; field; field = NEXT_LINK(field))
1293   {
1294     type_t *t = field->type;
1295
1296     /* get the base type */
1297     while( (t->type == 0) && t->ref )
1298       t = t->ref;
1299
1300     if (field->ptr_level > 0)
1301     {
1302         has_pointer = 1;
1303         continue;
1304     }
1305
1306     if (is_string_type(field->attrs, 0, field->array))
1307     {
1308         has_conformance = 1;
1309         has_variance = 1;
1310         continue;
1311     }
1312
1313     if (is_array_type(field->attrs, 0, field->array))
1314     {
1315         if (field->array && !field->array->is_const)
1316         {
1317             has_conformance = 1;
1318             if (PREV_LINK(field))
1319                 yyerror("field '%s' deriving from a conformant array must be the last field in the structure",
1320                         field->name);
1321         }
1322         if (is_attr(field->attrs, ATTR_LENGTHIS))
1323             has_variance = 1;
1324     }
1325
1326     switch (t->type)
1327     {
1328     /*
1329      * RPC_FC_BYTE, RPC_FC_STRUCT, etc
1330      *  Simple types don't effect the type of struct.
1331      *  A struct containing a simple struct is still a simple struct.
1332      *  So long as we can block copy the data, we return RPC_FC_STRUCT.
1333      */
1334     case 0: /* void pointer */
1335     case RPC_FC_BYTE:
1336     case RPC_FC_CHAR:
1337     case RPC_FC_SMALL:
1338     case RPC_FC_USMALL:
1339     case RPC_FC_WCHAR:
1340     case RPC_FC_SHORT:
1341     case RPC_FC_USHORT:
1342     case RPC_FC_LONG:
1343     case RPC_FC_ULONG:
1344     case RPC_FC_INT3264:
1345     case RPC_FC_UINT3264:
1346     case RPC_FC_HYPER:
1347     case RPC_FC_FLOAT:
1348     case RPC_FC_DOUBLE:
1349     case RPC_FC_STRUCT:
1350     case RPC_FC_ENUM16:
1351     case RPC_FC_ENUM32:
1352       break;
1353
1354     case RPC_FC_UP:
1355     case RPC_FC_FP:
1356       has_pointer = 1;
1357       break;
1358     case RPC_FC_CARRAY:
1359       has_conformance = 1;
1360       if (PREV_LINK(field))
1361           yyerror("field '%s' deriving from a conformant array must be the last field in the structure",
1362                   field->name);
1363       break;
1364     case RPC_FC_C_CSTRING:
1365     case RPC_FC_C_WSTRING:
1366       has_conformance = 1;
1367       has_variance = 1;
1368       break;
1369
1370     /*
1371      * Propagate member attributes
1372      *  a struct should be at least as complex as its member
1373      */
1374     case RPC_FC_CVSTRUCT:
1375       has_conformance = 1;
1376       has_variance = 1;
1377       has_pointer = 1;
1378       break;
1379
1380     case RPC_FC_CPSTRUCT:
1381       has_conformance = 1;
1382       if (PREV_LINK(field))
1383           yyerror("field '%s' deriving from a conformant array must be the last field in the structure",
1384                   field->name);
1385       has_pointer = 1;
1386       break;
1387
1388     case RPC_FC_CSTRUCT:
1389       has_conformance = 1;
1390       if (PREV_LINK(field))
1391           yyerror("field '%s' deriving from a conformant array must be the last field in the structure",
1392                   field->name);
1393       break;
1394
1395     case RPC_FC_PSTRUCT:
1396       has_pointer = 1;
1397       break;
1398
1399     default:
1400       fprintf(stderr,"Unknown struct member %s with type (0x%02x)\n",
1401               field->name, t->type);
1402       /* fallthru - treat it as complex */
1403
1404     /* as soon as we see one of these these members, it's bogus... */
1405     case RPC_FC_IP:
1406     case RPC_FC_ENCAPSULATED_UNION:
1407     case RPC_FC_NON_ENCAPSULATED_UNION:
1408     case RPC_FC_TRANSMIT_AS:
1409     case RPC_FC_REPRESENT_AS:
1410     case RPC_FC_PAD:
1411     case RPC_FC_EMBEDDED_COMPLEX:
1412     case RPC_FC_BOGUS_STRUCT:
1413       return RPC_FC_BOGUS_STRUCT;
1414     }
1415   }
1416
1417   if( has_variance )
1418     return RPC_FC_CVSTRUCT;
1419   if( has_conformance && has_pointer )
1420     return RPC_FC_CPSTRUCT;
1421   if( has_conformance )
1422     return RPC_FC_CSTRUCT;
1423   if( has_pointer )
1424     return RPC_FC_PSTRUCT;
1425   return RPC_FC_STRUCT;
1426 }
1427
1428 /***** constant repository *****/
1429
1430 struct rconst {
1431   char *name;
1432   var_t *var;
1433   struct rconst *next;
1434 };
1435
1436 struct rconst *const_hash[HASHMAX];
1437
1438 static var_t *reg_const(var_t *var)
1439 {
1440   struct rconst *nc;
1441   int hash;
1442   if (!var->name) {
1443     yyerror("registering constant without name");
1444     return var;
1445   }
1446   hash = hash_ident(var->name);
1447   nc = xmalloc(sizeof(struct rconst));
1448   nc->name = var->name;
1449   nc->var = var;
1450   nc->next = const_hash[hash];
1451   const_hash[hash] = nc;
1452   return var;
1453 }
1454
1455 static var_t *find_const(char *name, int f)
1456 {
1457   struct rconst *cur = const_hash[hash_ident(name)];
1458   while (cur && strcmp(cur->name, name))
1459     cur = cur->next;
1460   if (!cur) {
1461     if (f) yyerror("constant '%s' not found", name);
1462     return NULL;
1463   }
1464   return cur->var;
1465 }