git.oblomov.eu Git - wine/blob - tools/widl/parser.y

   1 %{
   2 /*
   3  * IDL Compiler
   4  *
   5  * Copyright 2002 Ove Kaaven
   6  *
   7  * This library is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU Lesser General Public
   9  * License as published by the Free Software Foundation; either
  10  * version 2.1 of the License, or (at your option) any later version.
  11  *
  12  * This library is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15  * Lesser General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU Lesser General Public
  18  * License along with this library; if not, write to the Free Software
  19  * Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA
  20  */
  21
  22 #include "config.h"
  23
  24 #include <stdio.h>
  25 #include <stdlib.h>
  26 #include <stdarg.h>
  27 #include <assert.h>
  28 #include <ctype.h>
  29 #include <string.h>
  30 #ifdef HAVE_ALLOCA_H
  31 #include <alloca.h>
  32 #endif
  33
  34 #include "windef.h"
  35
  36 #include "widl.h"
  37 #include "utils.h"
  38 #include "parser.h"
  39 #include "header.h"
  40 #include "typelib.h"
  41 #include "typegen.h"
  42
  43 #if defined(YYBYACC)
  44         /* Berkeley yacc (byacc) doesn't seem to know about these */
  45         /* Some *BSD supplied versions do define these though */
  46 # ifndef YYEMPTY
  47 #  define YYEMPTY       (-1)    /* Empty lookahead value of yychar */
  48 # endif
  49 # ifndef YYLEX
  50 #  define YYLEX         yylex()
  51 # endif
  52
  53 #elif defined(YYBISON)
  54         /* Bison was used for original development */
  55         /* #define YYEMPTY -2 */
  56         /* #define YYLEX   yylex() */
  57
  58 #else
  59         /* No yacc we know yet */
  60 # if !defined(YYEMPTY) || !defined(YYLEX)
  61 #  error Yacc version/type unknown. This version needs to be verified for settings of YYEMPTY and YYLEX.
  62 # elif defined(__GNUC__)        /* gcc defines the #warning directive */
  63 #  warning Yacc version/type unknown. It defines YYEMPTY and YYLEX, but is not tested
  64   /* #else we just take a chance that it works... */
  65 # endif
  66 #endif
  67
  68 typedef struct list typelist_t;
  69 struct typenode {
  70   type_t *type;
  71   struct list entry;
  72 };
  73
  74 typelist_t incomplete_types = LIST_INIT(incomplete_types);
  75
  76 static void add_incomplete(type_t *t);
  77 static void fix_incomplete(void);
  78
  79 static str_list_t *append_str(str_list_t *list, char *str);
  80 static attr_list_t *append_attr(attr_list_t *list, attr_t *attr);
  81 static attr_t *make_attr(enum attr_type type);
  82 static attr_t *make_attrv(enum attr_type type, unsigned long val);
  83 static attr_t *make_attrp(enum attr_type type, void *val);
  84 static expr_t *make_expr(enum expr_type type);
  85 static expr_t *make_exprl(enum expr_type type, long val);
  86 static expr_t *make_exprd(enum expr_type type, double val);
  87 static expr_t *make_exprs(enum expr_type type, char *val);
  88 static expr_t *make_exprt(enum expr_type type, type_t *tref, expr_t *expr);
  89 static expr_t *make_expr1(enum expr_type type, expr_t *expr);
  90 static expr_t *make_expr2(enum expr_type type, expr_t *exp1, expr_t *exp2);
  91 static expr_t *make_expr3(enum expr_type type, expr_t *expr1, expr_t *expr2, expr_t *expr3);
  92 static type_t *make_type(unsigned char type, type_t *ref);
  93 static expr_list_t *append_expr(expr_list_t *list, expr_t *expr);
  94 static array_dims_t *append_array(array_dims_t *list, expr_t *expr);
  95 static void set_type(var_t *v, type_t *type, int ptr_level, array_dims_t *arr);
  96 static ifref_list_t *append_ifref(ifref_list_t *list, ifref_t *iface);
  97 static ifref_t *make_ifref(type_t *iface);
  98 static var_list_t *append_var(var_list_t *list, var_t *var);
  99 static var_t *make_var(char *name);
 100 static pident_list_t *append_pident(pident_list_t *list, pident_t *p);
 101 static pident_t *make_pident(var_t *var);
 102 static func_list_t *append_func(func_list_t *list, func_t *func);
 103 static func_t *make_func(var_t *def, var_list_t *args);
 104 static type_t *make_class(char *name);
 105 static type_t *make_safearray(type_t *type);
 106 static type_t *make_builtin(char *name);
 107 static type_t *make_int(int sign);
 108
 109 static type_t *reg_type(type_t *type, const char *name, int t);
 110 static type_t *reg_typedefs(type_t *type, var_list_t *names, attr_list_t *attrs);
 111 static type_t *find_type(const char *name, int t);
 112 static type_t *find_type2(char *name, int t);
 113 static type_t *get_type(unsigned char type, char *name, int t);
 114 static type_t *get_typev(unsigned char type, var_t *name, int t);
 115 static int get_struct_type(var_list_t *fields);
 116
 117 static var_t *reg_const(var_t *var);
 118 static var_t *find_const(char *name, int f);
 119
 120 static void write_libid(const char *name, const attr_list_t *attr);
 121 static void write_clsid(type_t *cls);
 122 static void write_diid(type_t *iface);
 123 static void write_iid(type_t *iface);
 124
 125 static int compute_method_indexes(type_t *iface);
 126 static char *gen_name(void);
 127 static void process_typedefs(var_list_t *names);
 128 static void check_arg(var_t *arg);
 129 static void check_all_user_types(ifref_list_t *ifaces);
 130
 131 #define tsENUM   1
 132 #define tsSTRUCT 2
 133 #define tsUNION  3
 134
 135 %}
 136 %union {
 137         attr_t *attr;
 138         attr_list_t *attr_list;
 139         str_list_t *str_list;
 140         expr_t *expr;
 141         expr_list_t *expr_list;
 142         array_dims_t *array_dims;
 143         type_t *type;
 144         var_t *var;
 145         var_list_t *var_list;
 146         pident_t *pident;
 147         pident_list_t *pident_list;
 148         func_t *func;
 149         func_list_t *func_list;
 150         ifref_t *ifref;
 151         ifref_list_t *ifref_list;
 152         char *str;
 153         UUID *uuid;
 154         unsigned int num;
 155         double dbl;
 156 }
 157
 158 %token <str> aIDENTIFIER
 159 %token <str> aKNOWNTYPE
 160 %token <num> aNUM aHEXNUM
 161 %token <dbl> aDOUBLE
 162 %token <str> aSTRING
 163 %token <uuid> aUUID
 164 %token aEOF
 165 %token SHL SHR
 166 %token tAGGREGATABLE tALLOCATE tAPPOBJECT tASYNC tASYNCUUID
 167 %token tAUTOHANDLE tBINDABLE tBOOLEAN tBROADCAST tBYTE tBYTECOUNT
 168 %token tCALLAS tCALLBACK tCASE tCDECL tCHAR tCOCLASS tCODE tCOMMSTATUS
 169 %token tCONST tCONTEXTHANDLE tCONTEXTHANDLENOSERIALIZE
 170 %token tCONTEXTHANDLESERIALIZE tCONTROL tCPPQUOTE
 171 %token tDEFAULT
 172 %token tDEFAULTCOLLELEM
 173 %token tDEFAULTVALUE
 174 %token tDEFAULTVTABLE
 175 %token tDISPLAYBIND
 176 %token tDISPINTERFACE
 177 %token tDLLNAME tDOUBLE tDUAL
 178 %token tENDPOINT
 179 %token tENTRY tENUM tERRORSTATUST
 180 %token tEXPLICITHANDLE tEXTERN
 181 %token tFALSE
 182 %token tFLOAT
 183 %token tHANDLE
 184 %token tHANDLET
 185 %token tHELPCONTEXT tHELPFILE
 186 %token tHELPSTRING tHELPSTRINGCONTEXT tHELPSTRINGDLL
 187 %token tHIDDEN
 188 %token tHYPER tID tIDEMPOTENT
 189 %token tIIDIS
 190 %token tIMMEDIATEBIND
 191 %token tIMPLICITHANDLE
 192 %token tIMPORT tIMPORTLIB
 193 %token tIN tINLINE
 194 %token tINPUTSYNC
 195 %token tINT tINT64
 196 %token tINTERFACE
 197 %token tLCID
 198 %token tLENGTHIS tLIBRARY
 199 %token tLOCAL
 200 %token tLONG
 201 %token tMETHODS
 202 %token tMODULE
 203 %token tNONBROWSABLE
 204 %token tNONCREATABLE
 205 %token tNONEXTENSIBLE
 206 %token tOBJECT tODL tOLEAUTOMATION
 207 %token tOPTIONAL
 208 %token tOUT
 209 %token tPOINTERDEFAULT
 210 %token tPROPERTIES
 211 %token tPROPGET tPROPPUT tPROPPUTREF
 212 %token tPTR
 213 %token tPUBLIC
 214 %token tRANGE
 215 %token tREADONLY tREF
 216 %token tREQUESTEDIT
 217 %token tRESTRICTED
 218 %token tRETVAL
 219 %token tSAFEARRAY
 220 %token tSHORT
 221 %token tSIGNED
 222 %token tSINGLE
 223 %token tSIZEIS tSIZEOF
 224 %token tSMALL
 225 %token tSOURCE
 226 %token tSTDCALL
 227 %token tSTRING tSTRUCT
 228 %token tSWITCH tSWITCHIS tSWITCHTYPE
 229 %token tTRANSMITAS
 230 %token tTRUE
 231 %token tTYPEDEF
 232 %token tUNION
 233 %token tUNIQUE
 234 %token tUNSIGNED
 235 %token tUUID
 236 %token tV1ENUM
 237 %token tVARARG
 238 %token tVERSION
 239 %token tVOID
 240 %token tWCHAR tWIREMARSHAL
 241
 242 %type <attr> attribute
 243 %type <attr_list> m_attributes attributes attrib_list
 244 %type <str_list> str_list
 245 %type <expr> m_expr expr expr_const
 246 %type <expr_list> m_exprs /* exprs expr_list */ expr_list_const
 247 %type <array_dims> array array_list
 248 %type <type> inherit interface interfacehdr interfacedef interfacedec
 249 %type <type> dispinterface dispinterfacehdr dispinterfacedef
 250 %type <type> module modulehdr moduledef
 251 %type <type> base_type int_std
 252 %type <type> enumdef structdef uniondef
 253 %type <type> type
 254 %type <ifref> coclass_int
 255 %type <ifref_list> gbl_statements coclass_ints
 256 %type <var> arg field s_field case enum constdef externdef
 257 %type <var_list> m_args no_args args fields cases enums enum_list dispint_props
 258 %type <var> m_ident t_ident ident
 259 %type <pident> p_ident pident
 260 %type <pident_list> pident_list
 261 %type <func> funcdef
 262 %type <func_list> int_statements dispint_meths
 263 %type <type> coclass coclasshdr coclassdef
 264 %type <num> pointer_type version
 265 %type <str> libraryhdr
 266
 267 %left ','
 268 %right '?' ':'
 269 %left '|'
 270 %left '&'
 271 %left '-' '+'
 272 %left '*' '/'
 273 %left SHL SHR
 274 %right '~'
 275 %right CAST
 276 %right PPTR
 277 %right NEG
 278
 279 %%
 280
 281 input:   gbl_statements                         { fix_incomplete();
 282                                                   check_all_user_types($1);
 283                                                   write_proxies($1);
 284                                                   write_client($1);
 285                                                   write_server($1);
 286                                                 }
 287         ;
 288
 289 gbl_statements:                                 { $$ = NULL; }
 290         | gbl_statements interfacedec           { $$ = $1; }
 291         | gbl_statements interfacedef           { $$ = append_ifref( $1, make_ifref($2) ); }
 292         | gbl_statements coclass ';'            { $$ = $1;
 293                                                   reg_type($2, $2->name, 0);
 294                                                   if (!parse_only && do_header) write_coclass_forward($2);
 295                                                 }
 296         | gbl_statements coclassdef             { $$ = $1;
 297                                                   add_typelib_entry($2);
 298                                                   reg_type($2, $2->name, 0);
 299                                                   if (!parse_only && do_header) write_coclass_forward($2);
 300                                                 }
 301         | gbl_statements moduledef              { $$ = $1; add_typelib_entry($2); }
 302         | gbl_statements librarydef             { $$ = $1; }
 303         | gbl_statements statement              { $$ = $1; }
 304         ;
 305
 306 imp_statements:                                 {}
 307         | imp_statements interfacedec           { if (!parse_only) add_typelib_entry($2); }
 308         | imp_statements interfacedef           { if (!parse_only) add_typelib_entry($2); }
 309         | imp_statements coclass ';'            { reg_type($2, $2->name, 0); if (!parse_only && do_header) write_coclass_forward($2); }
 310         | imp_statements coclassdef             { if (!parse_only) add_typelib_entry($2);
 311                                                   reg_type($2, $2->name, 0);
 312                                                   if (!parse_only && do_header) write_coclass_forward($2);
 313                                                 }
 314         | imp_statements moduledef              { if (!parse_only) add_typelib_entry($2); }
 315         | imp_statements statement              {}
 316         | imp_statements importlib              {}
 317         ;
 318
 319 int_statements:                                 { $$ = NULL; }
 320         | int_statements funcdef ';'            { $$ = append_func( $1, $2 ); }
 321         | int_statements statement              { $$ = $1; }
 322         ;
 323
 324 statement: ';'                                  {}
 325         | constdef ';'                          { if (!parse_only && do_header) { write_constdef($1); } }
 326         | cppquote                              {}
 327         | enumdef ';'                           { if (!parse_only && do_header) {
 328                                                     write_type(header, $1, FALSE, NULL);
 329                                                     fprintf(header, ";\n\n");
 330                                                   }
 331                                                 }
 332         | externdef ';'                         { if (!parse_only && do_header) { write_externdef($1); } }
 333         | import                                {}
 334         | structdef ';'                         { if (!parse_only && do_header) {
 335                                                     write_type(header, $1, FALSE, NULL);
 336                                                     fprintf(header, ";\n\n");
 337                                                   }
 338                                                 }
 339         | typedef ';'                           {}
 340         | uniondef ';'                          { if (!parse_only && do_header) {
 341                                                     write_type(header, $1, FALSE, NULL);
 342                                                     fprintf(header, ";\n\n");
 343                                                   }
 344                                                 }
 345         ;
 346
 347 cppquote: tCPPQUOTE '(' aSTRING ')'             { if (!parse_only && do_header) fprintf(header, "%s\n", $3); }
 348         ;
 349 import_start: tIMPORT aSTRING ';'               { assert(yychar == YYEMPTY);
 350                                                   if (!do_import($2)) yychar = aEOF; }
 351         ;
 352 import:   import_start imp_statements aEOF      {}
 353         ;
 354
 355 importlib: tIMPORTLIB '(' aSTRING ')'           { if(!parse_only) add_importlib($3); }
 356         ;
 357
 358 libraryhdr: tLIBRARY aIDENTIFIER                { $$ = $2; }
 359         ;
 360 library_start: attributes libraryhdr '{'        { start_typelib($2, $1);
 361                                                   if (!parse_only && do_header) write_library($2, $1);
 362                                                   if (!parse_only && do_idfile) write_libid($2, $1);
 363                                                 }
 364         ;
 365 librarydef: library_start imp_statements '}'    { end_typelib(); }
 366         ;
 367
 368 m_args:                                         { $$ = NULL; }
 369         | args
 370         ;
 371
 372 no_args:  tVOID                                 { $$ = NULL; }
 373         ;
 374
 375 args:     arg                                   { check_arg($1); $$ = append_var( NULL, $1 ); }
 376         | args ',' arg                          { check_arg($3); $$ = append_var( $1, $3); }
 377         | no_args
 378         ;
 379
 380 /* split into two rules to get bison to resolve a tVOID conflict */
 381 arg:      attributes type pident array          { $$ = $3->var;
 382                                                   $$->attrs = $1;
 383                                                   set_type($$, $2, $3->ptr_level, $4);
 384                                                   free($3);
 385                                                 }
 386         | type pident array                     { $$ = $2->var;
 387                                                   set_type($$, $1, $2->ptr_level, $3);
 388                                                   free($2);
 389                                                 }
 390         | attributes type pident '(' m_args ')' { $$ = $3->var;
 391                                                   $$->attrs = $1;
 392                                                   set_type($$, $2, $3->ptr_level - 1, NULL);
 393                                                   free($3);
 394                                                   $$->args = $5;
 395                                                 }
 396         | type pident '(' m_args ')'            { $$ = $2->var;
 397                                                   set_type($$, $1, $2->ptr_level - 1, NULL);
 398                                                   free($2);
 399                                                   $$->args = $4;
 400                                                 }
 401         ;
 402
 403 array:                                          { $$ = NULL; }
 404         | '[' array_list ']'                    { $$ = $2; }
 405         | '[' '*' ']'                           { $$ = append_array( NULL, make_expr(EXPR_VOID) ); }
 406         ;
 407
 408 array_list: m_expr /* size of first dimension is optional */ { $$ = append_array( NULL, $1 ); }
 409         | array_list ',' expr                   { $$ = append_array( $1, $3 ); }
 410         | array_list ']' '[' expr               { $$ = append_array( $1, $4 ); }
 411         ;
 412
 413 m_attributes:                                   { $$ = NULL; }
 414         | attributes
 415         ;
 416
 417 attributes:
 418           '[' attrib_list ']'                   { $$ = $2;
 419                                                   if (!$$)
 420                                                     yyerror("empty attribute lists unsupported");
 421                                                 }
 422         ;
 423
 424 attrib_list: attribute                          { $$ = append_attr( NULL, $1 ); }
 425         | attrib_list ',' attribute             { $$ = append_attr( $1, $3 ); }
 426         | attrib_list ']' '[' attribute         { $$ = append_attr( $1, $4 ); }
 427         ;
 428
 429 str_list: aSTRING                               { $$ = append_str( NULL, $1 ); }
 430         | str_list ',' aSTRING                  { $$ = append_str( $1, $3 ); }
 431         ;
 432
 433 attribute:                                      { $$ = NULL; }
 434         | tAGGREGATABLE                         { $$ = make_attr(ATTR_AGGREGATABLE); }
 435         | tAPPOBJECT                            { $$ = make_attr(ATTR_APPOBJECT); }
 436         | tASYNC                                { $$ = make_attr(ATTR_ASYNC); }
 437         | tAUTOHANDLE                           { $$ = make_attr(ATTR_AUTO_HANDLE); }
 438         | tBINDABLE                             { $$ = make_attr(ATTR_BINDABLE); }
 439         | tCALLAS '(' ident ')'                 { $$ = make_attrp(ATTR_CALLAS, $3); }
 440         | tCASE '(' expr_list_const ')'         { $$ = make_attrp(ATTR_CASE, $3); }
 441         | tCONTEXTHANDLE                        { $$ = make_attrv(ATTR_CONTEXTHANDLE, 0); }
 442         | tCONTEXTHANDLENOSERIALIZE             { $$ = make_attrv(ATTR_CONTEXTHANDLE, 0); /* RPC_CONTEXT_HANDLE_DONT_SERIALIZE */ }
 443         | tCONTEXTHANDLESERIALIZE               { $$ = make_attrv(ATTR_CONTEXTHANDLE, 0); /* RPC_CONTEXT_HANDLE_SERIALIZE */ }
 444         | tCONTROL                              { $$ = make_attr(ATTR_CONTROL); }
 445         | tDEFAULT                              { $$ = make_attr(ATTR_DEFAULT); }
 446         | tDEFAULTCOLLELEM                      { $$ = make_attr(ATTR_DEFAULTCOLLELEM); }
 447         | tDEFAULTVALUE '(' expr_const ')'      { $$ = make_attrp(ATTR_DEFAULTVALUE_EXPR, $3); }
 448         | tDEFAULTVALUE '(' aSTRING ')'         { $$ = make_attrp(ATTR_DEFAULTVALUE_STRING, $3); }
 449         | tDEFAULTVTABLE                        { $$ = make_attr(ATTR_DEFAULTVTABLE); }
 450         | tDISPLAYBIND                          { $$ = make_attr(ATTR_DISPLAYBIND); }
 451         | tDLLNAME '(' aSTRING ')'              { $$ = make_attrp(ATTR_DLLNAME, $3); }
 452         | tDUAL                                 { $$ = make_attr(ATTR_DUAL); }
 453         | tENDPOINT '(' str_list ')'            { $$ = make_attrp(ATTR_ENDPOINT, $3); }
 454         | tENTRY '(' aSTRING ')'                { $$ = make_attrp(ATTR_ENTRY_STRING, $3); }
 455         | tENTRY '(' expr_const ')'             { $$ = make_attrp(ATTR_ENTRY_ORDINAL, $3); }
 456         | tEXPLICITHANDLE                       { $$ = make_attr(ATTR_EXPLICIT_HANDLE); }
 457         | tHANDLE                               { $$ = make_attr(ATTR_HANDLE); }
 458         | tHELPCONTEXT '(' expr_const ')'       { $$ = make_attrp(ATTR_HELPCONTEXT, $3); }
 459         | tHELPFILE '(' aSTRING ')'             { $$ = make_attrp(ATTR_HELPFILE, $3); }
 460         | tHELPSTRING '(' aSTRING ')'           { $$ = make_attrp(ATTR_HELPSTRING, $3); }
 461         | tHELPSTRINGCONTEXT '(' expr_const ')' { $$ = make_attrp(ATTR_HELPSTRINGCONTEXT, $3); }
 462         | tHELPSTRINGDLL '(' aSTRING ')'        { $$ = make_attrp(ATTR_HELPSTRINGDLL, $3); }
 463         | tHIDDEN                               { $$ = make_attr(ATTR_HIDDEN); }
 464         | tID '(' expr_const ')'                { $$ = make_attrp(ATTR_ID, $3); }
 465         | tIDEMPOTENT                           { $$ = make_attr(ATTR_IDEMPOTENT); }
 466         | tIIDIS '(' ident ')'                  { $$ = make_attrp(ATTR_IIDIS, $3); }
 467         | tIMMEDIATEBIND                        { $$ = make_attr(ATTR_IMMEDIATEBIND); }
 468         | tIMPLICITHANDLE '(' tHANDLET aIDENTIFIER ')'  { $$ = make_attrp(ATTR_IMPLICIT_HANDLE, $4); }
 469         | tIN                                   { $$ = make_attr(ATTR_IN); }
 470         | tINPUTSYNC                            { $$ = make_attr(ATTR_INPUTSYNC); }
 471         | tLENGTHIS '(' m_exprs ')'             { $$ = make_attrp(ATTR_LENGTHIS, $3); }
 472         | tLOCAL                                { $$ = make_attr(ATTR_LOCAL); }
 473         | tNONBROWSABLE                         { $$ = make_attr(ATTR_NONBROWSABLE); }
 474         | tNONCREATABLE                         { $$ = make_attr(ATTR_NONCREATABLE); }
 475         | tNONEXTENSIBLE                        { $$ = make_attr(ATTR_NONEXTENSIBLE); }
 476         | tOBJECT                               { $$ = make_attr(ATTR_OBJECT); }
 477         | tODL                                  { $$ = make_attr(ATTR_ODL); }
 478         | tOLEAUTOMATION                        { $$ = make_attr(ATTR_OLEAUTOMATION); }
 479         | tOPTIONAL                             { $$ = make_attr(ATTR_OPTIONAL); }
 480         | tOUT                                  { $$ = make_attr(ATTR_OUT); }
 481         | tPOINTERDEFAULT '(' pointer_type ')'  { $$ = make_attrv(ATTR_POINTERDEFAULT, $3); }
 482         | tPROPGET                              { $$ = make_attr(ATTR_PROPGET); }
 483         | tPROPPUT                              { $$ = make_attr(ATTR_PROPPUT); }
 484         | tPROPPUTREF                           { $$ = make_attr(ATTR_PROPPUTREF); }
 485         | tPUBLIC                               { $$ = make_attr(ATTR_PUBLIC); }
 486         | tRANGE '(' expr_const ',' expr_const ')' { expr_list_t *list = append_expr( NULL, $3 );
 487                                                      list = append_expr( list, $5 );
 488                                                      $$ = make_attrp(ATTR_RANGE, list); }
 489         | tREADONLY                             { $$ = make_attr(ATTR_READONLY); }
 490         | tREQUESTEDIT                          { $$ = make_attr(ATTR_REQUESTEDIT); }
 491         | tRESTRICTED                           { $$ = make_attr(ATTR_RESTRICTED); }
 492         | tRETVAL                               { $$ = make_attr(ATTR_RETVAL); }
 493         | tSIZEIS '(' m_exprs ')'               { $$ = make_attrp(ATTR_SIZEIS, $3); }
 494         | tSOURCE                               { $$ = make_attr(ATTR_SOURCE); }
 495         | tSTRING                               { $$ = make_attr(ATTR_STRING); }
 496         | tSWITCHIS '(' expr ')'                { $$ = make_attrp(ATTR_SWITCHIS, $3); }
 497         | tSWITCHTYPE '(' type ')'              { $$ = make_attrp(ATTR_SWITCHTYPE, $3); }
 498         | tTRANSMITAS '(' type ')'              { $$ = make_attrp(ATTR_TRANSMITAS, $3); }
 499         | tUUID '(' aUUID ')'                   { $$ = make_attrp(ATTR_UUID, $3); }
 500         | tV1ENUM                               { $$ = make_attr(ATTR_V1ENUM); }
 501         | tVARARG                               { $$ = make_attr(ATTR_VARARG); }
 502         | tVERSION '(' version ')'              { $$ = make_attrv(ATTR_VERSION, $3); }
 503         | tWIREMARSHAL '(' type ')'             { $$ = make_attrp(ATTR_WIREMARSHAL, $3); }
 504         | pointer_type                          { $$ = make_attrv(ATTR_POINTERTYPE, $1); }
 505         ;
 506
 507 callconv:
 508         | tSTDCALL
 509         ;
 510
 511 cases:                                          { $$ = NULL; }
 512         | cases case                            { $$ = append_var( $1, $2 ); }
 513         ;
 514
 515 case:     tCASE expr ':' field                  { attr_t *a = make_attrp(ATTR_CASE, append_expr( NULL, $2 ));
 516                                                   $$ = $4; if (!$$) $$ = make_var(NULL);
 517                                                   $$->attrs = append_attr( $$->attrs, a );
 518                                                 }
 519         | tDEFAULT ':' field                    { attr_t *a = make_attr(ATTR_DEFAULT);
 520                                                   $$ = $3; if (!$$) $$ = make_var(NULL);
 521                                                   $$->attrs = append_attr( $$->attrs, a );
 522                                                 }
 523         ;
 524
 525 constdef: tCONST type ident '=' expr_const      { $$ = reg_const($3);
 526                                                   set_type($$, $2, 0, NULL);
 527                                                   $$->eval = $5;
 528                                                 }
 529         ;
 530
 531 enums:                                          { $$ = NULL; }
 532         | enum_list ','                         { $$ = $1; }
 533         | enum_list
 534         ;
 535
 536 enum_list: enum                                 { if (!$1->eval)
 537                                                     $1->eval = make_exprl(EXPR_NUM, 0 /* default for first enum entry */);
 538                                                   $$ = append_var( NULL, $1 );
 539                                                 }
 540         | enum_list ',' enum                    { if (!$3->eval)
 541                                                   {
 542                                                     var_t *last = LIST_ENTRY( list_tail($$), var_t, entry );
 543                                                     $3->eval = make_exprl(EXPR_NUM, last->eval->cval + 1);
 544                                                   }
 545                                                   $$ = append_var( $1, $3 );
 546                                                 }
 547         ;
 548
 549 enum:     ident '=' expr_const                  { $$ = reg_const($1);
 550                                                   $$->eval = $3;
 551                                                   $$->type = make_int(0);
 552                                                 }
 553         | ident                                 { $$ = reg_const($1);
 554                                                   $$->type = make_int(0);
 555                                                 }
 556         ;
 557
 558 enumdef: tENUM t_ident '{' enums '}'            { $$ = get_typev(RPC_FC_ENUM16, $2, tsENUM);
 559                                                   $$->kind = TKIND_ENUM;
 560                                                   $$->fields = $4;
 561                                                   $$->defined = TRUE;
 562                                                   if(in_typelib)
 563                                                       add_typelib_entry($$);
 564                                                 }
 565         ;
 566
 567 m_exprs:  m_expr                                { $$ = append_expr( NULL, $1 ); }
 568         | m_exprs ',' m_expr                    { $$ = append_expr( $1, $3 ); }
 569         ;
 570
 571 /*
 572 exprs:                                          { $$ = make_expr(EXPR_VOID); }
 573         | expr_list
 574         ;
 575
 576 expr_list: expr
 577         | expr_list ',' expr                    { LINK($3, $1); $$ = $3; }
 578         ;
 579 */
 580
 581 m_expr:                                         { $$ = make_expr(EXPR_VOID); }
 582         | expr
 583         ;
 584
 585 expr:     aNUM                                  { $$ = make_exprl(EXPR_NUM, $1); }
 586         | aHEXNUM                               { $$ = make_exprl(EXPR_HEXNUM, $1); }
 587         | aDOUBLE                               { $$ = make_exprd(EXPR_DOUBLE, $1); }
 588         | tFALSE                                { $$ = make_exprl(EXPR_TRUEFALSE, 0); }
 589         | tTRUE                                 { $$ = make_exprl(EXPR_TRUEFALSE, 1); }
 590         | aIDENTIFIER                           { $$ = make_exprs(EXPR_IDENTIFIER, $1); }
 591         | expr '?' expr ':' expr                { $$ = make_expr3(EXPR_COND, $1, $3, $5); }
 592         | expr '|' expr                         { $$ = make_expr2(EXPR_OR , $1, $3); }
 593         | expr '&' expr                         { $$ = make_expr2(EXPR_AND, $1, $3); }
 594         | expr '+' expr                         { $$ = make_expr2(EXPR_ADD, $1, $3); }
 595         | expr '-' expr                         { $$ = make_expr2(EXPR_SUB, $1, $3); }
 596         | expr '*' expr                         { $$ = make_expr2(EXPR_MUL, $1, $3); }
 597         | expr '/' expr                         { $$ = make_expr2(EXPR_DIV, $1, $3); }
 598         | expr SHL expr                         { $$ = make_expr2(EXPR_SHL, $1, $3); }
 599         | expr SHR expr                         { $$ = make_expr2(EXPR_SHR, $1, $3); }
 600         | '~' expr                              { $$ = make_expr1(EXPR_NOT, $2); }
 601         | '-' expr %prec NEG                    { $$ = make_expr1(EXPR_NEG, $2); }
 602         | '*' expr %prec PPTR                   { $$ = make_expr1(EXPR_PPTR, $2); }
 603         | '(' type ')' expr %prec CAST          { $$ = make_exprt(EXPR_CAST, $2, $4); }
 604         | tSIZEOF '(' type ')'                  { $$ = make_exprt(EXPR_SIZEOF, $3, NULL); }
 605         | '(' expr ')'                          { $$ = $2; }
 606         ;
 607
 608 expr_list_const: expr_const                     { $$ = append_expr( NULL, $1 ); }
 609         | expr_list_const ',' expr_const        { $$ = append_expr( $1, $3 ); }
 610         ;
 611
 612 expr_const: expr                                { $$ = $1;
 613                                                   if (!$$->is_const)
 614                                                       yyerror("expression is not constant");
 615                                                 }
 616         ;
 617
 618 externdef: tEXTERN tCONST type ident            { $$ = $4;
 619                                                   set_type($$, $3, 0, NULL);
 620                                                 }
 621         ;
 622
 623 fields:                                         { $$ = NULL; }
 624         | fields field                          { $$ = append_var( $1, $2 ); }
 625         ;
 626
 627 field:    s_field ';'                           { $$ = $1; }
 628         | m_attributes uniondef ';'             { $$ = make_var(NULL); $$->type = $2; $$->attrs = $1; }
 629         | attributes ';'                        { $$ = make_var(NULL); $$->attrs = $1; }
 630         | ';'                                   { $$ = NULL; }
 631         ;
 632
 633 s_field:  m_attributes type pident array        { $$ = $3->var;
 634                                                   $$->attrs = $1;
 635                                                   set_type($$, $2, $3->ptr_level, $4);
 636                                                   free($3);
 637                                                 }
 638         ;
 639
 640 funcdef:
 641           m_attributes type callconv pident
 642           '(' m_args ')'                        { var_t *v = $4->var;
 643                                                   v->attrs = $1;
 644                                                   set_type(v, $2, $4->ptr_level, NULL);
 645                                                   free($4);
 646                                                   $$ = make_func(v, $6);
 647                                                   if (is_attr(v->attrs, ATTR_IN)) {
 648                                                     yyerror("inapplicable attribute [in] for function '%s'",$$->def->name);
 649                                                   }
 650                                                 }
 651         ;
 652
 653 m_ident:                                        { $$ = NULL; }
 654         | ident
 655         ;
 656
 657 t_ident:                                        { $$ = NULL; }
 658         | aIDENTIFIER                           { $$ = make_var($1); }
 659         | aKNOWNTYPE                            { $$ = make_var($1); }
 660         ;
 661
 662 ident:    aIDENTIFIER                           { $$ = make_var($1); }
 663 /* some "reserved words" used in attributes are also used as field names in some MS IDL files */
 664         | aKNOWNTYPE                            { $$ = make_var($<str>1); }
 665         ;
 666
 667 base_type: tBYTE                                { $$ = make_builtin($<str>1); }
 668         | tWCHAR                                { $$ = make_builtin($<str>1); }
 669         | int_std
 670         | tSIGNED int_std                       { $$ = $2; $$->sign = 1; }
 671         | tUNSIGNED int_std                     { $$ = $2; $$->sign = -1;
 672                                                   switch ($$->type) {
 673                                                   case RPC_FC_CHAR:  break;
 674                                                   case RPC_FC_SMALL: $$->type = RPC_FC_USMALL; break;
 675                                                   case RPC_FC_SHORT: $$->type = RPC_FC_USHORT; break;
 676                                                   case RPC_FC_LONG:  $$->type = RPC_FC_ULONG;  break;
 677                                                   case RPC_FC_HYPER:
 678                                                     if ($$->name[0] == 'h') /* hyper, as opposed to __int64 */
 679                                                     {
 680                                                       $$ = alias($$, "MIDL_uhyper");
 681                                                       $$->sign = 0;
 682                                                     }
 683                                                     break;
 684                                                   default: break;
 685                                                   }
 686                                                 }
 687         | tUNSIGNED                             { $$ = make_int(-1); }
 688         | tFLOAT                                { $$ = make_builtin($<str>1); }
 689         | tSINGLE                               { $$ = duptype(find_type("float", 0), 1); }
 690         | tDOUBLE                               { $$ = make_builtin($<str>1); }
 691         | tBOOLEAN                              { $$ = make_builtin($<str>1); }
 692         | tERRORSTATUST                         { $$ = make_builtin($<str>1); }
 693         | tHANDLET                              { $$ = make_builtin($<str>1); }
 694         ;
 695
 696 m_int:
 697         | tINT
 698         ;
 699
 700 int_std:  tINT                                  { $$ = make_builtin($<str>1); }
 701         | tSHORT m_int                          { $$ = make_builtin($<str>1); }
 702         | tSMALL                                { $$ = make_builtin($<str>1); }
 703         | tLONG m_int                           { $$ = make_builtin($<str>1); }
 704         | tHYPER m_int                          { $$ = make_builtin($<str>1); }
 705         | tINT64                                { $$ = make_builtin($<str>1); }
 706         | tCHAR                                 { $$ = make_builtin($<str>1); }
 707         ;
 708
 709 coclass:  tCOCLASS aIDENTIFIER                  { $$ = make_class($2); }
 710         | tCOCLASS aKNOWNTYPE                   { $$ = find_type($2, 0);
 711                                                   if ($$->defined) yyerror("multiple definition error");
 712                                                   if ($$->kind != TKIND_COCLASS) yyerror("%s was not declared a coclass", $2);
 713                                                 }
 714         ;
 715
 716 coclasshdr: attributes coclass                  { $$ = $2;
 717                                                   $$->attrs = $1;
 718                                                   if (!parse_only && do_header)
 719                                                     write_coclass($$);
 720                                                   if (!parse_only && do_idfile)
 721                                                     write_clsid($$);
 722                                                 }
 723         ;
 724
 725 coclassdef: coclasshdr '{' coclass_ints '}'     { $$ = $1;
 726                                                   $$->ifaces = $3;
 727                                                   $$->defined = TRUE;
 728                                                 }
 729         ;
 730
 731 coclass_ints:                                   { $$ = NULL; }
 732         | coclass_ints coclass_int              { $$ = append_ifref( $1, $2 ); }
 733         ;
 734
 735 coclass_int:
 736           m_attributes interfacedec             { $$ = make_ifref($2); $$->attrs = $1; }
 737         ;
 738
 739 dispinterface: tDISPINTERFACE aIDENTIFIER       { $$ = get_type(0, $2, 0); $$->kind = TKIND_DISPATCH; }
 740         |      tDISPINTERFACE aKNOWNTYPE        { $$ = get_type(0, $2, 0); $$->kind = TKIND_DISPATCH; }
 741         ;
 742
 743 dispinterfacehdr: attributes dispinterface      { attr_t *attrs;
 744                                                   $$ = $2;
 745                                                   if ($$->defined) yyerror("multiple definition error");
 746                                                   attrs = make_attr(ATTR_DISPINTERFACE);
 747                                                   $$->attrs = append_attr( $1, attrs );
 748                                                   $$->ref = find_type("IDispatch", 0);
 749                                                   if (!$$->ref) yyerror("IDispatch is undefined");
 750                                                   $$->defined = TRUE;
 751                                                   if (!parse_only && do_header) write_forward($$);
 752                                                 }
 753         ;
 754
 755 dispint_props: tPROPERTIES ':'                  { $$ = NULL; }
 756         | dispint_props s_field ';'             { $$ = append_var( $1, $2 ); }
 757         ;
 758
 759 dispint_meths: tMETHODS ':'                     { $$ = NULL; }
 760         | dispint_meths funcdef ';'             { $$ = append_func( $1, $2 ); }
 761         ;
 762
 763 dispinterfacedef: dispinterfacehdr '{'
 764           dispint_props
 765           dispint_meths
 766           '}'                                   { $$ = $1;
 767                                                   $$->fields = $3;
 768                                                   $$->funcs = $4;
 769                                                   if (!parse_only && do_header) write_dispinterface($$);
 770                                                   if (!parse_only && do_idfile) write_diid($$);
 771                                                 }
 772         | dispinterfacehdr
 773          '{' interface ';' '}'                  { $$ = $1;
 774                                                   $$->fields = $3->fields;
 775                                                   $$->funcs = $3->funcs;
 776                                                   if (!parse_only && do_header) write_dispinterface($$);
 777                                                   if (!parse_only && do_idfile) write_diid($$);
 778                                                 }
 779         ;
 780
 781 inherit:                                        { $$ = NULL; }
 782         | ':' aKNOWNTYPE                        { $$ = find_type2($2, 0); }
 783         ;
 784
 785 interface: tINTERFACE aIDENTIFIER               { $$ = get_type(RPC_FC_IP, $2, 0); $$->kind = TKIND_INTERFACE; }
 786         |  tINTERFACE aKNOWNTYPE                { $$ = get_type(RPC_FC_IP, $2, 0); $$->kind = TKIND_INTERFACE; }
 787         ;
 788
 789 interfacehdr: attributes interface              { $$ = $2;
 790                                                   if ($$->defined) yyerror("multiple definition error");
 791                                                   $$->attrs = $1;
 792                                                   $$->defined = TRUE;
 793                                                   if (!parse_only && do_header) write_forward($$);
 794                                                 }
 795         ;
 796
 797 interfacedef: interfacehdr inherit
 798           '{' int_statements '}'                { $$ = $1;
 799                                                   $$->ref = $2;
 800                                                   $$->funcs = $4;
 801                                                   compute_method_indexes($$);
 802                                                   if (!parse_only && do_header) write_interface($$);
 803                                                   if (!parse_only && do_idfile) write_iid($$);
 804                                                 }
 805 /* MIDL is able to import the definition of a base class from inside the
 806  * definition of a derived class, I'll try to support it with this rule */
 807         | interfacehdr ':' aIDENTIFIER
 808           '{' import int_statements '}'         { $$ = $1;
 809                                                   $$->ref = find_type2($3, 0);
 810                                                   if (!$$->ref) yyerror("base class '%s' not found in import", $3);
 811                                                   $$->funcs = $6;
 812                                                   compute_method_indexes($$);
 813                                                   if (!parse_only && do_header) write_interface($$);
 814                                                   if (!parse_only && do_idfile) write_iid($$);
 815                                                 }
 816         | dispinterfacedef                      { $$ = $1; }
 817         ;
 818
 819 interfacedec:
 820           interface ';'                         { $$ = $1; if (!parse_only && do_header) write_forward($$); }
 821         | dispinterface ';'                     { $$ = $1; if (!parse_only && do_header) write_forward($$); }
 822         ;
 823
 824 module:   tMODULE aIDENTIFIER                   { $$ = make_type(0, NULL); $$->name = $2; $$->kind = TKIND_MODULE; }
 825         | tMODULE aKNOWNTYPE                    { $$ = make_type(0, NULL); $$->name = $2; $$->kind = TKIND_MODULE; }
 826         ;
 827
 828 modulehdr: attributes module                    { $$ = $2;
 829                                                   $$->attrs = $1;
 830                                                 }
 831         ;
 832
 833 moduledef: modulehdr '{' int_statements '}'     { $$ = $1;
 834                                                   $$->funcs = $3;
 835                                                   /* FIXME: if (!parse_only && do_header) write_module($$); */
 836                                                 }
 837         ;
 838
 839 p_ident:  '*' pident %prec PPTR                 { $$ = $2; $$->ptr_level++; }
 840         | tCONST p_ident                        { $$ = $2; /* FIXME */ }
 841         ;
 842
 843 pident:   ident                                 { $$ = make_pident($1); }
 844         | p_ident
 845         | '(' pident ')'                        { $$ = $2; }
 846         ;
 847
 848 pident_list:
 849         pident                                  { $$ = append_pident( NULL, $1 ); }
 850         | pident_list ',' pident                { $$ = append_pident( $1, $3 ); }
 851         ;
 852
 853 pointer_type:
 854           tREF                                  { $$ = RPC_FC_RP; }
 855         | tUNIQUE                               { $$ = RPC_FC_UP; }
 856         | tPTR                                  { $$ = RPC_FC_FP; }
 857         ;
 858
 859 structdef: tSTRUCT t_ident '{' fields '}'       { $$ = get_typev(RPC_FC_STRUCT, $2, tsSTRUCT);
 860                                                   /* overwrite RPC_FC_STRUCT with a more exact type */
 861                                                   $$->type = get_struct_type( $4 );
 862                                                   $$->kind = TKIND_RECORD;
 863                                                   $$->fields = $4;
 864                                                   $$->defined = TRUE;
 865                                                   if(in_typelib)
 866                                                       add_typelib_entry($$);
 867                                                 }
 868         ;
 869
 870 type:     tVOID                                 { $$ = duptype(find_type("void", 0), 1); }
 871         | aKNOWNTYPE                            { $$ = find_type($1, 0); }
 872         | base_type                             { $$ = $1; }
 873         | tCONST type                           { $$ = duptype($2, 1); $$->is_const = TRUE; }
 874         | enumdef                               { $$ = $1; }
 875         | tENUM aIDENTIFIER                     { $$ = find_type2($2, tsENUM); }
 876         | structdef                             { $$ = $1; }
 877         | tSTRUCT aIDENTIFIER                   { $$ = get_type(RPC_FC_STRUCT, $2, tsSTRUCT); }
 878         | uniondef                              { $$ = $1; }
 879         | tUNION aIDENTIFIER                    { $$ = find_type2($2, tsUNION); }
 880         | tSAFEARRAY '(' type ')'               { $$ = make_safearray($3); }
 881         ;
 882
 883 typedef: tTYPEDEF m_attributes type pident_list { reg_typedefs($3, $4, $2);
 884                                                   process_typedefs($4);
 885                                                 }
 886         ;
 887
 888 uniondef: tUNION t_ident '{' fields '}'         { $$ = get_typev(RPC_FC_NON_ENCAPSULATED_UNION, $2, tsUNION);
 889                                                   $$->kind = TKIND_UNION;
 890                                                   $$->fields = $4;
 891                                                   $$->defined = TRUE;
 892                                                 }
 893         | tUNION t_ident
 894           tSWITCH '(' s_field ')'
 895           m_ident '{' cases '}'                 { var_t *u = $7;
 896                                                   $$ = get_typev(RPC_FC_ENCAPSULATED_UNION, $2, tsUNION);
 897                                                   $$->kind = TKIND_UNION;
 898                                                   if (!u) u = make_var( xstrdup("tagged_union") );
 899                                                   u->type = make_type(RPC_FC_NON_ENCAPSULATED_UNION, NULL);
 900                                                   u->type->kind = TKIND_UNION;
 901                                                   u->type->fields = $9;
 902                                                   u->type->defined = TRUE;
 903                                                   $$->fields = append_var( $$->fields, $5 );
 904                                                   $$->fields = append_var( $$->fields, u );
 905                                                   $$->defined = TRUE;
 906                                                 }
 907         ;
 908
 909 version:
 910           aNUM                                  { $$ = MAKELONG($1, 0); }
 911         | aNUM '.' aNUM                         { $$ = MAKELONG($1, $3); }
 912         ;
 913
 914 %%
 915
 916 static void decl_builtin(const char *name, unsigned char type)
 917 {
 918   type_t *t = make_type(type, NULL);
 919   t->name = xstrdup(name);
 920   reg_type(t, name, 0);
 921 }
 922
 923 static type_t *make_builtin(char *name)
 924 {
 925   /* NAME is strdup'd in the lexer */
 926   type_t *t = duptype(find_type(name, 0), 0);
 927   t->name = name;
 928   return t;
 929 }
 930
 931 static type_t *make_int(int sign)
 932 {
 933   type_t *t = duptype(find_type("int", 0), 1);
 934
 935   t->sign = sign;
 936   if (sign < 0)
 937     t->type = t->type == RPC_FC_LONG ? RPC_FC_ULONG : RPC_FC_USHORT;
 938
 939   return t;
 940 }
 941
 942 void init_types(void)
 943 {
 944   decl_builtin("void", 0);
 945   decl_builtin("byte", RPC_FC_BYTE);
 946   decl_builtin("wchar_t", RPC_FC_WCHAR);
 947   decl_builtin("int", RPC_FC_LONG);     /* win32 */
 948   decl_builtin("short", RPC_FC_SHORT);
 949   decl_builtin("small", RPC_FC_SMALL);
 950   decl_builtin("long", RPC_FC_LONG);
 951   decl_builtin("hyper", RPC_FC_HYPER);
 952   decl_builtin("__int64", RPC_FC_HYPER);
 953   decl_builtin("char", RPC_FC_CHAR);
 954   decl_builtin("float", RPC_FC_FLOAT);
 955   decl_builtin("double", RPC_FC_DOUBLE);
 956   decl_builtin("boolean", RPC_FC_BYTE);
 957   decl_builtin("error_status_t", RPC_FC_ERROR_STATUS_T);
 958   decl_builtin("handle_t", RPC_FC_BIND_PRIMITIVE);
 959 }
 960
 961 static str_list_t *append_str(str_list_t *list, char *str)
 962 {
 963     struct str_list_entry_t *entry;
 964
 965     if (!str) return list;
 966     if (!list)
 967     {
 968         list = xmalloc( sizeof(*list) );
 969         list_init( list );
 970     }
 971     entry = xmalloc( sizeof(*entry) );
 972     entry->str = str;
 973     list_add_tail( list, &entry->entry );
 974     return list;
 975 }
 976
 977 static attr_list_t *append_attr(attr_list_t *list, attr_t *attr)
 978 {
 979     if (!attr) return list;
 980     if (!list)
 981     {
 982         list = xmalloc( sizeof(*list) );
 983         list_init( list );
 984     }
 985     list_add_tail( list, &attr->entry );
 986     return list;
 987 }
 988
 989 static attr_t *make_attr(enum attr_type type)
 990 {
 991   attr_t *a = xmalloc(sizeof(attr_t));
 992   a->type = type;
 993   a->u.ival = 0;
 994   return a;
 995 }
 996
 997 static attr_t *make_attrv(enum attr_type type, unsigned long val)
 998 {
 999   attr_t *a = xmalloc(sizeof(attr_t));
1000   a->type = type;
1001   a->u.ival = val;
1002   return a;
1003 }
1004
1005 static attr_t *make_attrp(enum attr_type type, void *val)
1006 {
1007   attr_t *a = xmalloc(sizeof(attr_t));
1008   a->type = type;
1009   a->u.pval = val;
1010   return a;
1011 }
1012
1013 static expr_t *make_expr(enum expr_type type)
1014 {
1015   expr_t *e = xmalloc(sizeof(expr_t));
1016   e->type = type;
1017   e->ref = NULL;
1018   e->u.lval = 0;
1019   e->is_const = FALSE;
1020   e->cval = 0;
1021   return e;
1022 }
1023
1024 static expr_t *make_exprl(enum expr_type type, long val)
1025 {
1026   expr_t *e = xmalloc(sizeof(expr_t));
1027   e->type = type;
1028   e->ref = NULL;
1029   e->u.lval = val;
1030   e->is_const = FALSE;
1031   /* check for numeric constant */
1032   if (type == EXPR_NUM || type == EXPR_HEXNUM || type == EXPR_TRUEFALSE) {
1033     /* make sure true/false value is valid */
1034     assert(type != EXPR_TRUEFALSE || val == 0 || val == 1);
1035     e->is_const = TRUE;
1036     e->cval = val;
1037   }
1038   return e;
1039 }
1040
1041 static expr_t *make_exprd(enum expr_type type, double val)
1042 {
1043   expr_t *e = xmalloc(sizeof(expr_t));
1044   e->type = type;
1045   e->ref = NULL;
1046   e->u.dval = val;
1047   e->is_const = TRUE;
1048   e->cval = val;
1049   return e;
1050 }
1051
1052 static expr_t *make_exprs(enum expr_type type, char *val)
1053 {
1054   expr_t *e;
1055   e = xmalloc(sizeof(expr_t));
1056   e->type = type;
1057   e->ref = NULL;
1058   e->u.sval = val;
1059   e->is_const = FALSE;
1060   /* check for predefined constants */
1061   if (type == EXPR_IDENTIFIER) {
1062     var_t *c = find_const(val, 0);
1063     if (c) {
1064       e->u.sval = c->name;
1065       free(val);
1066       e->is_const = TRUE;
1067       e->cval = c->eval->cval;
1068     }
1069   }
1070   return e;
1071 }
1072
1073 static expr_t *make_exprt(enum expr_type type, type_t *tref, expr_t *expr)
1074 {
1075   expr_t *e;
1076   e = xmalloc(sizeof(expr_t));
1077   e->type = type;
1078   e->ref = expr;
1079   e->u.tref = tref;
1080   e->is_const = FALSE;
1081   /* check for cast of constant expression */
1082   if (type == EXPR_SIZEOF) {
1083     switch (tref->type) {
1084       case RPC_FC_BYTE:
1085       case RPC_FC_CHAR:
1086       case RPC_FC_SMALL:
1087       case RPC_FC_USMALL:
1088         e->is_const = TRUE;
1089         e->cval = 1;
1090         break;
1091       case RPC_FC_WCHAR:
1092       case RPC_FC_USHORT:
1093       case RPC_FC_SHORT:
1094         e->is_const = TRUE;
1095         e->cval = 2;
1096         break;
1097       case RPC_FC_LONG:
1098       case RPC_FC_ULONG:
1099       case RPC_FC_FLOAT:
1100       case RPC_FC_ERROR_STATUS_T:
1101         e->is_const = TRUE;
1102         e->cval = 4;
1103         break;
1104       case RPC_FC_HYPER:
1105       case RPC_FC_DOUBLE:
1106         e->is_const = TRUE;
1107         e->cval = 8;
1108         break;
1109     }
1110   }
1111   if (type == EXPR_CAST && expr->is_const) {
1112     e->is_const = TRUE;
1113     e->cval = expr->cval;
1114   }
1115   return e;
1116 }
1117
1118 static expr_t *make_expr1(enum expr_type type, expr_t *expr)
1119 {
1120   expr_t *e;
1121   e = xmalloc(sizeof(expr_t));
1122   e->type = type;
1123   e->ref = expr;
1124   e->u.lval = 0;
1125   e->is_const = FALSE;
1126   /* check for compile-time optimization */
1127   if (expr->is_const) {
1128     e->is_const = TRUE;
1129     switch (type) {
1130     case EXPR_NEG:
1131       e->cval = -expr->cval;
1132       break;
1133     case EXPR_NOT:
1134       e->cval = ~expr->cval;
1135       break;
1136     default:
1137       e->is_const = FALSE;
1138       break;
1139     }
1140   }
1141   return e;
1142 }
1143
1144 static expr_t *make_expr2(enum expr_type type, expr_t *expr1, expr_t *expr2)
1145 {
1146   expr_t *e;
1147   e = xmalloc(sizeof(expr_t));
1148   e->type = type;
1149   e->ref = expr1;
1150   e->u.ext = expr2;
1151   e->is_const = FALSE;
1152   /* check for compile-time optimization */
1153   if (expr1->is_const && expr2->is_const) {
1154     e->is_const = TRUE;
1155     switch (type) {
1156     case EXPR_ADD:
1157       e->cval = expr1->cval + expr2->cval;
1158       break;
1159     case EXPR_SUB:
1160       e->cval = expr1->cval - expr2->cval;
1161       break;
1162     case EXPR_MUL:
1163       e->cval = expr1->cval * expr2->cval;
1164       break;
1165     case EXPR_DIV:
1166       e->cval = expr1->cval / expr2->cval;
1167       break;
1168     case EXPR_OR:
1169       e->cval = expr1->cval | expr2->cval;
1170       break;
1171     case EXPR_AND:
1172       e->cval = expr1->cval & expr2->cval;
1173       break;
1174     case EXPR_SHL:
1175       e->cval = expr1->cval << expr2->cval;
1176       break;
1177     case EXPR_SHR:
1178       e->cval = expr1->cval >> expr2->cval;
1179       break;
1180     default:
1181       e->is_const = FALSE;
1182       break;
1183     }
1184   }
1185   return e;
1186 }
1187
1188 static expr_t *make_expr3(enum expr_type type, expr_t *expr1, expr_t *expr2, expr_t *expr3)
1189 {
1190   expr_t *e;
1191   e = xmalloc(sizeof(expr_t));
1192   e->type = type;
1193   e->ref = expr1;
1194   e->u.ext = expr2;
1195   e->ext2 = expr3;
1196   e->is_const = FALSE;
1197   /* check for compile-time optimization */
1198   if (expr1->is_const && expr2->is_const && expr3->is_const) {
1199     e->is_const = TRUE;
1200     switch (type) {
1201     case EXPR_COND:
1202       e->cval = expr1->cval ? expr2->cval : expr3->cval;
1203       break;
1204     default:
1205       e->is_const = FALSE;
1206       break;
1207     }
1208   }
1209   return e;
1210 }
1211
1212 static expr_list_t *append_expr(expr_list_t *list, expr_t *expr)
1213 {
1214     if (!expr) return list;
1215     if (!list)
1216     {
1217         list = xmalloc( sizeof(*list) );
1218         list_init( list );
1219     }
1220     list_add_tail( list, &expr->entry );
1221     return list;
1222 }
1223
1224 static array_dims_t *append_array(array_dims_t *list, expr_t *expr)
1225 {
1226     if (!expr) return list;
1227     if (!list)
1228     {
1229         list = xmalloc( sizeof(*list) );
1230         list_init( list );
1231     }
1232     list_add_tail( list, &expr->entry );
1233     return list;
1234 }
1235
1236 static type_t *make_type(unsigned char type, type_t *ref)
1237 {
1238   type_t *t = xmalloc(sizeof(type_t));
1239   t->name = NULL;
1240   t->kind = TKIND_PRIMITIVE;
1241   t->type = type;
1242   t->ref = ref;
1243   t->attrs = NULL;
1244   t->orig = NULL;
1245   t->funcs = NULL;
1246   t->fields = NULL;
1247   t->ifaces = NULL;
1248   t->dim = 0;
1249   t->size_is = NULL;
1250   t->length_is = NULL;
1251   t->typestring_offset = 0;
1252   t->ptrdesc = 0;
1253   t->declarray = FALSE;
1254   t->ignore = (parse_only != 0);
1255   t->is_const = FALSE;
1256   t->sign = 0;
1257   t->defined = FALSE;
1258   t->written = FALSE;
1259   t->user_types_registered = FALSE;
1260   t->tfswrite = FALSE;
1261   t->typelib_idx = -1;
1262   return t;
1263 }
1264
1265 static void set_type(var_t *v, type_t *type, int ptr_level, array_dims_t *arr)
1266 {
1267   expr_list_t *sizes = get_attrp(v->attrs, ATTR_SIZEIS);
1268   expr_list_t *lengs = get_attrp(v->attrs, ATTR_LENGTHIS);
1269   int ptr_type = get_attrv(v->attrs, ATTR_POINTERTYPE);
1270   int sizeless, has_varconf;
1271   expr_t *dim;
1272   type_t *atype, **ptype;
1273
1274   v->type = type;
1275
1276   for ( ; 0 < ptr_level; --ptr_level)
1277   {
1278     v->type = make_type(RPC_FC_RP, v->type);
1279     if (ptr_level == 1 && ptr_type && !arr)
1280     {
1281       v->type->type = ptr_type;
1282       ptr_type = 0;
1283     }
1284   }
1285
1286   if (ptr_type)
1287   {
1288     if (is_ptr(v->type))
1289     {
1290       v->type = duptype(v->type, 1);
1291       v->type->type = ptr_type;
1292     }
1293     else if (!arr)
1294       error("%s: pointer attribute applied to non-pointer type", v->name);
1295   }
1296
1297   sizeless = FALSE;
1298   if (arr) LIST_FOR_EACH_ENTRY_REV(dim, arr, expr_t, entry)
1299   {
1300     if (sizeless)
1301       error("%s: only the first array dimension can be unspecified\n", v->name);
1302
1303     if (dim->is_const)
1304     {
1305       unsigned int align = 0;
1306       size_t size = type_memsize(v->type, &align);
1307
1308       if (dim->cval <= 0)
1309         error("%s: array dimension must be positive\n", v->name);
1310
1311       if (0xffffffffuL / size < (unsigned long) dim->cval)
1312         error("%s: total array size is too large", v->name);
1313       else if (0xffffuL < size * dim->cval)
1314         v->type = make_type(RPC_FC_LGFARRAY, v->type);
1315       else
1316         v->type = make_type(RPC_FC_SMFARRAY, v->type);
1317     }
1318     else
1319     {
1320       sizeless = TRUE;
1321       v->type = make_type(RPC_FC_CARRAY, v->type);
1322     }
1323
1324     v->type->declarray = TRUE;
1325     v->type->dim = dim->cval;
1326   }
1327
1328   ptype = &v->type;
1329   has_varconf = FALSE;
1330   if (sizes) LIST_FOR_EACH_ENTRY(dim, sizes, expr_t, entry)
1331   {
1332     if (dim->type != EXPR_VOID)
1333     {
1334       has_varconf = TRUE;
1335       atype = *ptype = duptype(*ptype, 0);
1336
1337       if (atype->type == RPC_FC_SMFARRAY || atype->type == RPC_FC_LGFARRAY)
1338         error("%s: cannot specify size_is for a fixed sized array\n", v->name);
1339
1340       if (atype->type != RPC_FC_CARRAY && !is_ptr(atype))
1341         error("%s: size_is attribute applied to illegal type\n", v->name);
1342
1343       atype->type = RPC_FC_CARRAY;
1344       atype->size_is = dim;
1345     }
1346
1347     ptype = &(*ptype)->ref;
1348     if (*ptype == NULL)
1349       error("%s: too many expressions in size_is attribute\n", v->name);
1350   }
1351
1352   ptype = &v->type;
1353   if (lengs) LIST_FOR_EACH_ENTRY(dim, lengs, expr_t, entry)
1354   {
1355     if (dim->type != EXPR_VOID)
1356     {
1357       has_varconf = TRUE;
1358       atype = *ptype = duptype(*ptype, 0);
1359
1360       if (atype->type == RPC_FC_SMFARRAY)
1361         atype->type = RPC_FC_SMVARRAY;
1362       else if (atype->type == RPC_FC_LGFARRAY)
1363         atype->type = RPC_FC_LGVARRAY;
1364       else if (atype->type == RPC_FC_CARRAY)
1365         atype->type = RPC_FC_CVARRAY;
1366       else
1367         error("%s: length_is attribute applied to illegal type\n", v->name);
1368
1369       atype->length_is = dim;
1370     }
1371
1372     ptype = &(*ptype)->ref;
1373     if (*ptype == NULL)
1374       error("%s: too many expressions in length_is attribute\n", v->name);
1375   }
1376
1377   if (has_varconf && !last_array(v->type))
1378   {
1379     ptype = &v->type;
1380     for (ptype = &v->type; is_array(*ptype); ptype = &(*ptype)->ref)
1381     {
1382       *ptype = duptype(*ptype, 0);
1383       (*ptype)->type = RPC_FC_BOGUS_ARRAY;
1384     }
1385   }
1386
1387   if (is_array(v->type))
1388   {
1389     const type_t *rt = v->type->ref;
1390     switch (rt->type)
1391     {
1392     case RPC_FC_BOGUS_STRUCT:
1393     case RPC_FC_NON_ENCAPSULATED_UNION:
1394     case RPC_FC_ENCAPSULATED_UNION:
1395     case RPC_FC_ENUM16:
1396       v->type->type = RPC_FC_BOGUS_ARRAY;
1397       break;
1398     /* FC_RP should be above, but widl overuses these, and will break things.  */
1399     case RPC_FC_UP:
1400     case RPC_FC_RP:
1401       if (rt->ref->type == RPC_FC_IP)
1402         v->type->type = RPC_FC_BOGUS_ARRAY;
1403       break;
1404     default:
1405       if (is_user_type(rt))
1406         v->type->type = RPC_FC_BOGUS_ARRAY;
1407     }
1408   }
1409 }
1410
1411 static ifref_list_t *append_ifref(ifref_list_t *list, ifref_t *iface)
1412 {
1413     if (!iface) return list;
1414     if (!list)
1415     {
1416         list = xmalloc( sizeof(*list) );
1417         list_init( list );
1418     }
1419     list_add_tail( list, &iface->entry );
1420     return list;
1421 }
1422
1423 static ifref_t *make_ifref(type_t *iface)
1424 {
1425   ifref_t *l = xmalloc(sizeof(ifref_t));
1426   l->iface = iface;
1427   l->attrs = NULL;
1428   return l;
1429 }
1430
1431 static var_list_t *append_var(var_list_t *list, var_t *var)
1432 {
1433     if (!var) return list;
1434     if (!list)
1435     {
1436         list = xmalloc( sizeof(*list) );
1437         list_init( list );
1438     }
1439     list_add_tail( list, &var->entry );
1440     return list;
1441 }
1442
1443 static var_t *make_var(char *name)
1444 {
1445   var_t *v = xmalloc(sizeof(var_t));
1446   v->name = name;
1447   v->type = NULL;
1448   v->args = NULL;
1449   v->attrs = NULL;
1450   v->eval = NULL;
1451   return v;
1452 }
1453
1454 static pident_list_t *append_pident(pident_list_t *list, pident_t *p)
1455 {
1456   if (!p) return list;
1457   if (!list) {
1458     list = xmalloc(sizeof(*list));
1459     list_init(list);
1460   }
1461   list_add_tail(list, &p->entry);
1462   return list;
1463 }
1464
1465 static pident_t *make_pident(var_t *var)
1466 {
1467   pident_t *p = xmalloc(sizeof(*p));
1468   p->var = var;
1469   p->ptr_level = 0;
1470   return p;
1471 }
1472
1473 static func_list_t *append_func(func_list_t *list, func_t *func)
1474 {
1475     if (!func) return list;
1476     if (!list)
1477     {
1478         list = xmalloc( sizeof(*list) );
1479         list_init( list );
1480     }
1481     list_add_tail( list, &func->entry );
1482     return list;
1483 }
1484
1485 static func_t *make_func(var_t *def, var_list_t *args)
1486 {
1487   func_t *f = xmalloc(sizeof(func_t));
1488   f->def = def;
1489   f->args = args;
1490   f->ignore = parse_only;
1491   f->idx = -1;
1492   return f;
1493 }
1494
1495 static type_t *make_class(char *name)
1496 {
1497   type_t *c = make_type(0, NULL);
1498   c->name = name;
1499   c->kind = TKIND_COCLASS;
1500   return c;
1501 }
1502
1503 static type_t *make_safearray(type_t *type)
1504 {
1505   type_t *sa = duptype(find_type("SAFEARRAY", 0), 1);
1506   sa->ref = type;
1507   return make_type(RPC_FC_FP, sa);
1508 }
1509
1510 #define HASHMAX 64
1511
1512 static int hash_ident(const char *name)
1513 {
1514   const char *p = name;
1515   int sum = 0;
1516   /* a simple sum hash is probably good enough */
1517   while (*p) {
1518     sum += *p;
1519     p++;
1520   }
1521   return sum & (HASHMAX-1);
1522 }
1523
1524 /***** type repository *****/
1525
1526 struct rtype {
1527   const char *name;
1528   type_t *type;
1529   int t;
1530   struct rtype *next;
1531 };
1532
1533 struct rtype *type_hash[HASHMAX];
1534
1535 static type_t *reg_type(type_t *type, const char *name, int t)
1536 {
1537   struct rtype *nt;
1538   int hash;
1539   if (!name) {
1540     yyerror("registering named type without name");
1541     return type;
1542   }
1543   hash = hash_ident(name);
1544   nt = xmalloc(sizeof(struct rtype));
1545   nt->name = name;
1546   nt->type = type;
1547   nt->t = t;
1548   nt->next = type_hash[hash];
1549   type_hash[hash] = nt;
1550   return type;
1551 }
1552
1553 static int is_incomplete(const type_t *t)
1554 {
1555   return !t->defined && (is_struct(t->type) || is_union(t->type));
1556 }
1557
1558 static void add_incomplete(type_t *t)
1559 {
1560   struct typenode *tn = xmalloc(sizeof *tn);
1561   tn->type = t;
1562   list_add_tail(&incomplete_types, &tn->entry);
1563 }
1564
1565 static void fix_type(type_t *t)
1566 {
1567   if (t->kind == TKIND_ALIAS && is_incomplete(t)) {
1568     type_t *ot = t->orig;
1569     fix_type(ot);
1570     t->fields = ot->fields;
1571     t->defined = ot->defined;
1572   }
1573 }
1574
1575 static void fix_incomplete(void)
1576 {
1577   struct typenode *tn, *next;
1578
1579   LIST_FOR_EACH_ENTRY_SAFE(tn, next, &incomplete_types, struct typenode, entry) {
1580     fix_type(tn->type);
1581     free(tn);
1582   }
1583 }
1584
1585 static type_t *reg_typedefs(type_t *type, pident_list_t *pidents, attr_list_t *attrs)
1586 {
1587   type_t *ptr = type;
1588   const pident_t *pident;
1589   int ptrc = 0;
1590   int is_str = is_attr(attrs, ATTR_STRING);
1591   unsigned char ptr_type = get_attrv(attrs, ATTR_POINTERTYPE);
1592
1593   if (is_str)
1594   {
1595     type_t *t = type;
1596     unsigned char c;
1597
1598     while (is_ptr(t))
1599       t = t->ref;
1600
1601     c = t->type;
1602     if (c != RPC_FC_CHAR && c != RPC_FC_BYTE && c != RPC_FC_WCHAR)
1603     {
1604       pident = LIST_ENTRY( list_head( pidents ), const pident_t, entry );
1605       yyerror("'%s': [string] attribute is only valid on 'char', 'byte', or 'wchar_t' pointers and arrays",
1606               pident->var->name);
1607     }
1608   }
1609
1610   /* We must generate names for tagless enum, struct or union.
1611      Typedef-ing a tagless enum, struct or union means we want the typedef
1612      to be included in a library whether it has other attributes or not,
1613      hence the public attribute.  */
1614   if ((type->kind == TKIND_ENUM || type->kind == TKIND_RECORD
1615        || type->kind == TKIND_UNION) && ! type->name && ! parse_only)
1616   {
1617     if (! is_attr(attrs, ATTR_PUBLIC))
1618       attrs = append_attr( attrs, make_attr(ATTR_PUBLIC) );
1619     type->name = gen_name();
1620   }
1621
1622   LIST_FOR_EACH_ENTRY( pident, pidents, const pident_t, entry )
1623   {
1624     var_t *name = pident->var;
1625
1626     if (name->name) {
1627       type_t *cur = ptr;
1628       int cptr = pident->ptr_level;
1629       if (cptr > ptrc) {
1630         while (cptr > ptrc) {
1631           cur = ptr = make_type(RPC_FC_RP, cur);
1632           ptrc++;
1633         }
1634       } else {
1635         while (cptr < ptrc) {
1636           cur = cur->ref;
1637           cptr++;
1638         }
1639       }
1640       cur = alias(cur, name->name);
1641       cur->attrs = attrs;
1642       if (ptr_type)
1643       {
1644         if (is_ptr(cur))
1645           cur->type = ptr_type;
1646         else
1647           yyerror("'%s': pointer attribute applied to non-pointer type",
1648                   cur->name);
1649       }
1650       else if (is_str && ! is_ptr(cur))
1651         yyerror("'%s': [string] attribute applied to non-pointer type",
1652                 cur->name);
1653
1654       if (is_incomplete(cur))
1655         add_incomplete(cur);
1656       reg_type(cur, cur->name, 0);
1657     }
1658   }
1659   return type;
1660 }
1661
1662 static type_t *find_type(const char *name, int t)
1663 {
1664   struct rtype *cur = type_hash[hash_ident(name)];
1665   while (cur && (cur->t != t || strcmp(cur->name, name)))
1666     cur = cur->next;
1667   if (!cur) {
1668     yyerror("type '%s' not found", name);
1669     return NULL;
1670   }
1671   return cur->type;
1672 }
1673
1674 static type_t *find_type2(char *name, int t)
1675 {
1676   type_t *tp = find_type(name, t);
1677   free(name);
1678   return tp;
1679 }
1680
1681 int is_type(const char *name)
1682 {
1683   struct rtype *cur = type_hash[hash_ident(name)];
1684   while (cur && (cur->t || strcmp(cur->name, name)))
1685     cur = cur->next;
1686   if (cur) return TRUE;
1687   return FALSE;
1688 }
1689
1690 static type_t *get_type(unsigned char type, char *name, int t)
1691 {
1692   struct rtype *cur = NULL;
1693   type_t *tp;
1694   if (name) {
1695     cur = type_hash[hash_ident(name)];
1696     while (cur && (cur->t != t || strcmp(cur->name, name)))
1697       cur = cur->next;
1698   }
1699   if (cur) {
1700     free(name);
1701     return cur->type;
1702   }
1703   tp = make_type(type, NULL);
1704   tp->name = name;
1705   if (!name) return tp;
1706   return reg_type(tp, name, t);
1707 }
1708
1709 static type_t *get_typev(unsigned char type, var_t *name, int t)
1710 {
1711   char *sname = NULL;
1712   if (name) {
1713     sname = name->name;
1714     free(name);
1715   }
1716   return get_type(type, sname, t);
1717 }
1718
1719 static int get_struct_type(var_list_t *fields)
1720 {
1721   int has_pointer = 0;
1722   int has_conformance = 0;
1723   int has_variance = 0;
1724   var_t *field;
1725
1726   if (get_padding(fields))
1727     return RPC_FC_BOGUS_STRUCT;
1728
1729   if (fields) LIST_FOR_EACH_ENTRY( field, fields, var_t, entry )
1730   {
1731     type_t *t = field->type;
1732
1733     if (is_ptr(t))
1734     {
1735         do
1736             t = t->ref;
1737         while (is_ptr(t));
1738
1739         switch (t->type)
1740         {
1741         case RPC_FC_IP:
1742         case RPC_FC_ENCAPSULATED_UNION:
1743         case RPC_FC_NON_ENCAPSULATED_UNION:
1744         case RPC_FC_BOGUS_STRUCT:
1745             return RPC_FC_BOGUS_STRUCT;
1746         }
1747
1748         has_pointer = 1;
1749         continue;
1750     }
1751
1752     if (field->type->declarray)
1753     {
1754         if (is_string_type(field->attrs, field->type))
1755         {
1756             if (is_conformant_array(field->type))
1757                 has_conformance = 1;
1758             has_variance = 1;
1759             continue;
1760         }
1761
1762         if (is_array(field->type->ref))
1763             return RPC_FC_BOGUS_STRUCT;
1764
1765         if (is_conformant_array(field->type))
1766         {
1767             has_conformance = 1;
1768             if (field->type->declarray && list_next(fields, &field->entry))
1769                 yyerror("field '%s' deriving from a conformant array must be the last field in the structure",
1770                         field->name);
1771         }
1772         if (field->type->length_is)
1773             has_variance = 1;
1774
1775         t = field->type->ref;
1776     }
1777
1778     switch (t->type)
1779     {
1780     /*
1781      * RPC_FC_BYTE, RPC_FC_STRUCT, etc
1782      *  Simple types don't effect the type of struct.
1783      *  A struct containing a simple struct is still a simple struct.
1784      *  So long as we can block copy the data, we return RPC_FC_STRUCT.
1785      */
1786     case 0: /* void pointer */
1787     case RPC_FC_BYTE:
1788     case RPC_FC_CHAR:
1789     case RPC_FC_SMALL:
1790     case RPC_FC_USMALL:
1791     case RPC_FC_WCHAR:
1792     case RPC_FC_SHORT:
1793     case RPC_FC_USHORT:
1794     case RPC_FC_LONG:
1795     case RPC_FC_ULONG:
1796     case RPC_FC_INT3264:
1797     case RPC_FC_UINT3264:
1798     case RPC_FC_HYPER:
1799     case RPC_FC_FLOAT:
1800     case RPC_FC_DOUBLE:
1801     case RPC_FC_STRUCT:
1802     case RPC_FC_ENUM16:
1803     case RPC_FC_ENUM32:
1804       break;
1805
1806     case RPC_FC_RP:
1807     case RPC_FC_UP:
1808     case RPC_FC_FP:
1809     case RPC_FC_OP:
1810     case RPC_FC_CARRAY:
1811     case RPC_FC_CVARRAY:
1812       has_pointer = 1;
1813       break;
1814
1815     /*
1816      * Propagate member attributes
1817      *  a struct should be at least as complex as its member
1818      */
1819     case RPC_FC_CVSTRUCT:
1820       has_conformance = 1;
1821       has_variance = 1;
1822       has_pointer = 1;
1823       break;
1824
1825     case RPC_FC_CPSTRUCT:
1826       has_conformance = 1;
1827       if (list_next( fields, &field->entry ))
1828           yyerror("field '%s' deriving from a conformant array must be the last field in the structure",
1829                   field->name);
1830       has_pointer = 1;
1831       break;
1832
1833     case RPC_FC_CSTRUCT:
1834       has_conformance = 1;
1835       if (list_next( fields, &field->entry ))
1836           yyerror("field '%s' deriving from a conformant array must be the last field in the structure",
1837                   field->name);
1838       break;
1839
1840     case RPC_FC_PSTRUCT:
1841       has_pointer = 1;
1842       break;
1843
1844     default:
1845       fprintf(stderr,"Unknown struct member %s with type (0x%02x)\n",
1846               field->name, t->type);
1847       /* fallthru - treat it as complex */
1848
1849     /* as soon as we see one of these these members, it's bogus... */
1850     case RPC_FC_IP:
1851     case RPC_FC_ENCAPSULATED_UNION:
1852     case RPC_FC_NON_ENCAPSULATED_UNION:
1853     case RPC_FC_TRANSMIT_AS:
1854     case RPC_FC_REPRESENT_AS:
1855     case RPC_FC_PAD:
1856     case RPC_FC_EMBEDDED_COMPLEX:
1857     case RPC_FC_BOGUS_STRUCT:
1858     case RPC_FC_BOGUS_ARRAY:
1859       return RPC_FC_BOGUS_STRUCT;
1860     }
1861   }
1862
1863   if( has_variance )
1864   {
1865     if ( has_conformance )
1866       return RPC_FC_CVSTRUCT;
1867     else
1868       return RPC_FC_BOGUS_STRUCT;
1869   }
1870   if( has_conformance && has_pointer )
1871     return RPC_FC_CPSTRUCT;
1872   if( has_conformance )
1873     return RPC_FC_CSTRUCT;
1874   if( has_pointer )
1875     return RPC_FC_PSTRUCT;
1876   return RPC_FC_STRUCT;
1877 }
1878
1879 /***** constant repository *****/
1880
1881 struct rconst {
1882   char *name;
1883   var_t *var;
1884   struct rconst *next;
1885 };
1886
1887 struct rconst *const_hash[HASHMAX];
1888
1889 static var_t *reg_const(var_t *var)
1890 {
1891   struct rconst *nc;
1892   int hash;
1893   if (!var->name) {
1894     yyerror("registering constant without name");
1895     return var;
1896   }
1897   hash = hash_ident(var->name);
1898   nc = xmalloc(sizeof(struct rconst));
1899   nc->name = var->name;
1900   nc->var = var;
1901   nc->next = const_hash[hash];
1902   const_hash[hash] = nc;
1903   return var;
1904 }
1905
1906 static var_t *find_const(char *name, int f)
1907 {
1908   struct rconst *cur = const_hash[hash_ident(name)];
1909   while (cur && strcmp(cur->name, name))
1910     cur = cur->next;
1911   if (!cur) {
1912     if (f) yyerror("constant '%s' not found", name);
1913     return NULL;
1914   }
1915   return cur->var;
1916 }
1917
1918 static void write_libid(const char *name, const attr_list_t *attr)
1919 {
1920   const UUID *uuid = get_attrp(attr, ATTR_UUID);
1921   write_guid(idfile, "LIBID", name, uuid);
1922 }
1923
1924 static void write_clsid(type_t *cls)
1925 {
1926   const UUID *uuid = get_attrp(cls->attrs, ATTR_UUID);
1927   write_guid(idfile, "CLSID", cls->name, uuid);
1928 }
1929
1930 static void write_diid(type_t *iface)
1931 {
1932   const UUID *uuid = get_attrp(iface->attrs, ATTR_UUID);
1933   write_guid(idfile, "DIID", iface->name, uuid);
1934 }
1935
1936 static void write_iid(type_t *iface)
1937 {
1938   const UUID *uuid = get_attrp(iface->attrs, ATTR_UUID);
1939   write_guid(idfile, "IID", iface->name, uuid);
1940 }
1941
1942 static int compute_method_indexes(type_t *iface)
1943 {
1944   int idx;
1945   func_t *f;
1946
1947   if (iface->ref)
1948     idx = compute_method_indexes(iface->ref);
1949   else
1950     idx = 0;
1951
1952   if (!iface->funcs)
1953     return idx;
1954
1955   LIST_FOR_EACH_ENTRY( f, iface->funcs, func_t, entry )
1956     if (! is_callas(f->def->attrs))
1957       f->idx = idx++;
1958
1959   return idx;
1960 }
1961
1962 static char *gen_name(void)
1963 {
1964   static const char format[] = "__WIDL_%s_generated_name_%08lX";
1965   static unsigned long n = 0;
1966   static const char *file_id;
1967   static size_t size;
1968   char *name;
1969
1970   if (! file_id)
1971   {
1972     char *dst = dup_basename(input_name, ".idl");
1973     file_id = dst;
1974
1975     for (; *dst; ++dst)
1976       if (! isalnum((unsigned char) *dst))
1977         *dst = '_';
1978
1979     size = sizeof format - 7 + strlen(file_id) + 8;
1980   }
1981
1982   name = xmalloc(size);
1983   sprintf(name, format, file_id, n++);
1984   return name;
1985 }
1986
1987 static void process_typedefs(pident_list_t *pidents)
1988 {
1989   pident_t *pident, *next;
1990
1991   if (!pidents) return;
1992   LIST_FOR_EACH_ENTRY_SAFE( pident, next, pidents, pident_t, entry )
1993   {
1994     var_t *var = pident->var;
1995     type_t *type = find_type(var->name, 0);
1996
1997     if (! parse_only && do_header)
1998       write_typedef(type);
1999     if (in_typelib && type->attrs)
2000       add_typelib_entry(type);
2001
2002     free(pident);
2003     free(var);
2004   }
2005 }
2006
2007 static void check_arg(var_t *arg)
2008 {
2009   type_t *t = arg->type;
2010
2011   if (t->type == 0 && ! is_var_ptr(arg))
2012     yyerror("argument '%s' has void type", arg->name);
2013 }
2014
2015 static void check_all_user_types(ifref_list_t *ifrefs)
2016 {
2017   const ifref_t *ifref;
2018   const func_t *f;
2019
2020   if (ifrefs) LIST_FOR_EACH_ENTRY(ifref, ifrefs, const ifref_t, entry)
2021   {
2022     const func_list_t *fs = ifref->iface->funcs;
2023     if (fs) LIST_FOR_EACH_ENTRY(f, fs, const func_t, entry)
2024       check_for_user_types(f->args);
2025   }
2026 }