git.oblomov.eu Git - wine/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Original author: Michael Patra
   3 dnl See ChangeLog file for detailed change history.
   4
   5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
   6
   7 AC_PREREQ(2.53b)
   8 AC_INIT([Wine],WINE_VERSION,[wine-devel@winehq.org])
   9 AC_CONFIG_SRCDIR(server/atom.c)
  10 AC_CONFIG_HEADERS(include/config.h)
  11 AC_CONFIG_AUX_DIR(tools)
  12
  13 dnl **** Command-line arguments ****
  14
  15 AC_ARG_ENABLE(win16, AC_HELP_STRING([--disable-win16],[do not include Win16 support]))
  16 AC_ARG_ENABLE(debug, AC_HELP_STRING([--disable-debug],[compile out all debugging messages]))
  17 AC_ARG_ENABLE(trace, AC_HELP_STRING([--disable-trace],[compile out TRACE messages]))
  18 AC_ARG_ENABLE(win64, AC_HELP_STRING([--enable-win64], [build a Win64 emulator on AMD64 (won't run Win32 binaries)]))
  19
  20 AC_ARG_WITH(opengl,    AC_HELP_STRING([--without-opengl],[do not use OpenGL]))
  21 AC_ARG_WITH(curses,    AC_HELP_STRING([--without-curses],[do not use curses]))
  22 AC_ARG_WITH(wine-tools,AC_HELP_STRING([--with-wine-tools=<dir>],[use Wine tools from directory <dir>]))
  23
  24 AC_SUBST(DLLDEFS,"")
  25 if test "x$enable_debug" = "xno"
  26 then
  27   DLLDEFS="$DLLDEFS -DWINE_NO_DEBUG_MSGS"
  28 fi
  29 if test "x$enable_trace" = "xno" -o "x$enable_debug" = "xno"
  30 then
  31   DLLDEFS="$DLLDEFS -DWINE_NO_TRACE_MSGS"
  32 fi
  33
  34 AC_CANONICAL_HOST
  35 case $host in
  36   x86_64*linux*)
  37     if test "x$enable_win64" != "xyes"
  38     then
  39       test -n "$CC" || CC="gcc -m32"
  40       test -n "$LD" || LD="ld -m elf_i386"
  41       test -n "$AS" || AS="as --32"
  42       host_cpu="i386"
  43     fi
  44     ;;
  45 esac
  46
  47 dnl enable_win16 defaults to yes on x86, to no on other CPUs
  48 case $host_cpu in
  49   *i[[3456789]]86*)
  50     if test "x$enable_win16" != "xno"
  51     then
  52       enable_win16="yes"
  53     fi
  54     ;;
  55 esac
  56
  57 AC_SUBST(WIN16_FILES,"\$(WIN16_FILES)")
  58 AC_SUBST(WIN16_INSTALL,"\$(WIN16_INSTALL)")
  59 if test "x$enable_win16" != "xyes"
  60 then
  61   WIN16_FILES=""
  62   WIN16_INSTALL=""
  63 fi
  64
  65 dnl **** Check for some programs ****
  66
  67 AC_PROG_MAKE_SET
  68 AC_PROG_CC
  69 AC_PROG_CXX
  70 dnl We can't use AC_PROG_CPP for winegcc, it uses by default $(CC) -E
  71 AC_CHECK_TOOL(CPPBIN,cpp,cpp)
  72
  73 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
  74   [if test -z "$with_wine_tools"; then
  75      if test "$cross_compiling" = "yes"; then
  76        AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
  77      else
  78        wine_cv_toolsdir="\$(TOPOBJDIR)"
  79      fi
  80    elif test -d "$with_wine_tools/tools/winebuild"; then
  81      case $with_wine_tools in
  82        /*) wine_cv_toolsdir="$with_wine_tools" ;;
  83        *)  wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
  84      esac
  85    else
  86      AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
  87    fi])
  88 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
  89
  90 AC_PATH_XTRA
  91 AC_PROG_LEX
  92
  93 dnl **** Just additional warning checks, since AC_PROG just sets 'lex' even
  94 dnl **** without one present.
  95 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
  96 if test "$XLEX" = "none"
  97 then
  98   AC_MSG_ERROR([no suitable lex found. Please install the 'flex' package.])
  99 fi
 100
 101 dnl Check for bison
 102 AC_CHECK_PROGS(BISON,bison,none)
 103 if test "$BISON" = "none"
 104 then
 105   AC_MSG_ERROR([no suitable bison found. Please install the 'bison' package.])
 106 fi
 107
 108 AC_CHECK_TOOLS(AS,[gas as],as)
 109 AC_CHECK_TOOL(LD,ld,ld)
 110 AC_CHECK_TOOL(AR,ar,ar)
 111 AC_PROG_RANLIB
 112 AC_CHECK_TOOL(STRIP,strip,strip)
 113 AC_CHECK_TOOL(WINDRES,windres,false)
 114 AC_PROG_LN_S
 115 WINE_PROG_LN
 116 AC_PROG_EGREP
 117 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
 118 AC_PROG_INSTALL
 119 dnl Prepend src dir to install path dir if it's a relative path
 120 case "$INSTALL" in
 121   [[\\/$]]* | ?:[[\\/]]* ) ;;
 122   *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
 123 esac
 124
 125 dnl Check for lint
 126 AC_CHECK_PROGS(LINT, lclint lint)
 127 if test "$LINT" = "lint"
 128 then
 129   LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
 130   dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
 131 fi
 132 AC_SUBST(LINT)
 133 AC_SUBST(LINTFLAGS)
 134
 135 dnl Check for various programs
 136 AC_CHECK_PROGS(FONTFORGE, fontforge, false)
 137 AC_CHECK_PROGS(PKG_CONFIG, pkg-config, false)
 138
 139 case $host_cpu in
 140   *i[[3456789]]86*)
 141     AC_CHECK_PROGS(PRELINK, prelink, false, [/sbin /usr/sbin $PATH])
 142     ;;
 143 esac
 144
 145 dnl **** Check for some libraries ****
 146
 147 dnl Check for -li386 for NetBSD and OpenBSD
 148 AC_CHECK_LIB(i386,i386_set_ldt)
 149 dnl Check for -lossaudio for NetBSD
 150 AC_CHECK_LIB(ossaudio,_oss_ioctl)
 151 dnl Check for -lnsl for Solaris
 152 AC_CHECK_FUNCS(gethostbyname,,AC_CHECK_LIB(nsl,gethostbyname))
 153 dnl Check for -lsocket for Solaris
 154 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
 155 dnl Check for -lresolv for Solaris
 156 AC_CHECK_FUNCS(inet_aton,,AC_CHECK_LIB(resolv,inet_aton))
 157 dnl Check for -lxpg4 for FreeBSD
 158 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
 159 dnl Check for -lpoll for Mac OS X/Darwin
 160 AC_CHECK_LIB(poll,poll)
 161 dnl Check for -lresolv for Mac OS X/Darwin
 162 AC_CHECK_LIB(resolv,res_9_init)
 163 dnl Check for -lpthread
 164 AC_CHECK_LIB(pthread,pthread_create,AC_SUBST(LIBPTHREAD,"-lpthread"))
 165
 166 AC_SUBST(XLIB,"")
 167 AC_SUBST(XFILES,"")
 168 AC_SUBST(OPENGLFILES,"")
 169 AC_SUBST(GLU32FILES,"")
 170 AC_SUBST(OPENGL_LIBS,"")
 171
 172 dnl **** Check for header files ****
 173
 174 AC_CHECK_HEADERS(\
 175         IOKit/IOKitLib.h \
 176         alsa/asoundlib.h \
 177         arpa/inet.h \
 178         arpa/nameser.h \
 179         asm/types.h \
 180         capi20.h \
 181         cups/cups.h \
 182         curses.h \
 183         direct.h \
 184         dlfcn.h \
 185         elf.h \
 186         float.h \
 187         fontconfig/fontconfig.h \
 188         getopt.h \
 189         gif_lib.h \
 190         ieeefp.h \
 191         io.h \
 192         jack/jack.h \
 193         jpeglib.h \
 194         lber.h \
 195         lcms.h \
 196         lcms/lcms.h \
 197         ldap.h \
 198         libaudioio.h \
 199         link.h \
 200         linux/cdrom.h \
 201         linux/compiler.h \
 202         linux/hdreg.h \
 203         linux/input.h \
 204         linux/ioctl.h \
 205         linux/joystick.h \
 206         linux/major.h \
 207         linux/param.h \
 208         linux/serial.h \
 209         linux/ucdrom.h \
 210         mach/machine.h \
 211         machine/cpu.h \
 212         machine/limits.h \
 213         machine/soundcard.h \
 214         mntent.h \
 215         ncurses.h \
 216         netdb.h \
 217         netinet/in.h \
 218         netinet/in_systm.h \
 219         netinet/tcp.h \
 220         netinet/tcp_fsm.h \
 221         openssl/err.h \
 222         openssl/ssl.h \
 223         poll.h \
 224         process.h \
 225         pthread.h \
 226         pwd.h \
 227         regex.h \
 228         sched.h \
 229         scsi/scsi.h \
 230         scsi/scsi_ioctl.h \
 231         scsi/sg.h \
 232         soundcard.h \
 233         stdint.h \
 234         strings.h \
 235         sys/asoundlib.h \
 236         sys/cdio.h \
 237         sys/elf32.h \
 238         sys/epoll.h \
 239         sys/errno.h \
 240         sys/exec_elf.h \
 241         sys/filio.h \
 242         sys/ioctl.h \
 243         sys/ipc.h \
 244         sys/limits.h \
 245         sys/link.h \
 246         sys/lwp.h \
 247         sys/mman.h \
 248         sys/modem.h \
 249         sys/msg.h \
 250         sys/mtio.h \
 251         sys/param.h \
 252         sys/poll.h \
 253         sys/ptrace.h \
 254         sys/reg.h \
 255         sys/resource.h \
 256         sys/scsiio.h \
 257         sys/shm.h \
 258         sys/signal.h \
 259         sys/socket.h \
 260         sys/sockio.h \
 261         sys/soundcard.h \
 262         sys/statvfs.h \
 263         sys/strtio.h \
 264         sys/syscall.h \
 265         sys/sysctl.h \
 266         sys/time.h \
 267         sys/times.h \
 268         sys/uio.h \
 269         sys/un.h \
 270         sys/vm86.h \
 271         sys/wait.h \
 272         syscall.h \
 273         termios.h \
 274         unicode/ubidi.h \
 275         unistd.h \
 276         utime.h \
 277         valgrind/memcheck.h
 278 )
 279 AC_HEADER_STAT()
 280
 281 dnl Check for broken kernel header that doesn't define __user
 282 AC_CHECK_HEADERS([linux/capi.h],,,[#define __user])
 283
 284 dnl **** Check for X11 ****
 285
 286 if test "$have_x" = "yes"
 287 then
 288     XLIB="-lXext -lX11"
 289     ac_save_CPPFLAGS="$CPPFLAGS"
 290     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 291
 292     dnl *** All of the following tests require X11/Xlib.h
 293     AC_CHECK_HEADERS([X11/Xlib.h \
 294                       X11/XKBlib.h \
 295                       X11/Xutil.h \
 296                       X11/extensions/shape.h \
 297                       X11/extensions/XInput.h \
 298                       X11/extensions/XShm.h \
 299                       X11/extensions/Xrandr.h \
 300                       X11/extensions/Xrender.h \
 301                       X11/extensions/xf86dga.h \
 302                       X11/extensions/xf86vmode.h],,,
 303 [#ifdef HAVE_X11_XLIB_H
 304 # include <X11/Xlib.h>
 305 #endif
 306 #ifdef HAVE_X11_XUTIL_H
 307 # include <X11/Xutil.h>
 308 #endif])
 309
 310         dnl *** Check for X keyboard extension
 311         if test "$ac_cv_header_X11_XKBlib_h" = "yes"
 312         then
 313               AC_CHECK_LIB(X11, XkbQueryExtension,
 314               AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
 315               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 316         fi
 317
 318         dnl *** Check for X Shm extension
 319         if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
 320         then
 321               AC_CHECK_LIB(Xext, XShmQueryExtension,
 322               AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
 323               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 324         fi
 325
 326         dnl *** Check for X shape extension
 327         if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
 328         then
 329               AC_CHECK_LIB(Xext,XShapeQueryExtension,
 330               AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
 331               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 332         fi
 333
 334         dnl *** Check for XFree86 DGA / DGA 2.0 extension
 335         if test "$ac_cv_header_X11_extensions_xf86dga_h" = "yes"
 336         then
 337               AC_CHECK_LIB(Xxf86dga, XDGAQueryExtension,
 338                 [ AC_DEFINE(HAVE_LIBXXF86DGA2, 1,
 339                             [Define if you have the Xxf86dga library version 2])
 340                   X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
 341                 ],,
 342                 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 343         fi
 344
 345         dnl *** Check for XFree86 VMODE extension
 346         if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
 347         then
 348                 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
 349                   [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
 350                      X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
 351                   ],,
 352                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 353         fi
 354
 355         dnl *** Check for X RandR extension
 356         if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes"
 357         then
 358                 AC_TRY_COMPILE([#include <X11/Xlib.h>
 359 #include <X11/extensions/Xrandr.h>],[static typeof(XRRSetScreenConfigAndRate) * func;],
 360                   [AC_DEFINE(HAVE_LIBXRANDR, 1, [Define if you have the Xrandr library])])
 361         fi
 362
 363         dnl *** Check for Transform functions in Xrender
 364         if test "$ac_cv_header_X11_extensions_Xrender_h" = "yes"
 365         then
 366               AC_CHECK_LIB(Xrender, XRenderSetPictureTransform,
 367                 [AC_DEFINE(HAVE_XRENDERSETPICTURETRANSFORM, 1,
 368                  [Define if Xrender has the XRenderSetPictureTransform function])],,
 369                 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 370         fi
 371     dnl *** End of X11/Xlib.h check
 372
 373     dnl Check for the presence of OpenGL
 374     if test "x$with_opengl" != "xno"
 375     then
 376         AC_CHECK_HEADERS(GL/gl.h GL/glx.h GL/glext.h GL/glu.h,,,
 377 [#ifdef HAVE_GL_GLX_H
 378 # include <GL/glx.h>
 379 #endif])
 380         if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
 381         then
 382             dnl Check for some problems due to old Mesa versions
 383             AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_version_OK,
 384               AC_TRY_COMPILE(
 385                 [#include <GL/gl.h>],
 386                 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
 387                 [wine_cv_opengl_version_OK="yes"],
 388                 [wine_cv_opengl_version_OK="no"]
 389               )
 390             )
 391
 392             if test "$wine_cv_opengl_version_OK" = "yes"
 393             then
 394                 dnl Check for the presence of the library
 395                 AC_CHECK_LIB(GL,glXCreateContext,
 396                              OPENGL_LIBS="-lGL"
 397                              ,,
 398                              $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 399
 400                 if test "$ac_cv_lib_GL_glXCreateContext" = "yes"
 401                 then
 402                         OPENGLFILES='$(OPENGLFILES)'
 403                         AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])
 404                 else
 405                     if test -f /usr/X11R6/lib/libGL.a
 406                     then
 407                        AC_MSG_ERROR([/usr/X11R6/lib/libGL.a is present on your system.
 408 This prevents linking to OpenGL. Delete the file and restart configure.])
 409                     fi
 410                 fi
 411
 412                 dnl Check for GLU32 library.
 413                 AC_CHECK_LIB(GLU,gluLookAt,
 414                              [OPENGL_LIBS="$OPENGL_LIBS -lGLU"
 415                              GLU32FILES='$(GLU32FILES)']
 416                              ,,
 417                              $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
 418                 )
 419              fi
 420
 421              dnl Check for glut32 library.
 422              AC_CHECK_LIB(glut,glutMainLoop,
 423                        [AC_SUBST(GLUT_LIBS,"-lglut -lXmu -lXi")
 424                         AC_SUBST(GLUT32FILES,'$(GLUT32FILES)')],,
 425                         $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXmu -lXi -lX11 $X_EXTRA_LIBS)
 426          fi
 427     fi
 428
 429     dnl **** Check for NAS ****
 430     AC_SUBST(NASLIBS,"")
 431     AC_CHECK_HEADERS(audio/audiolib.h,
 432          [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
 433           AC_CHECK_LIB(audio,AuCreateFlow,
 434                        [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
 435                         NASLIBS="-laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],,
 436                        [-lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
 437
 438     CPPFLAGS="$ac_save_CPPFLAGS"
 439     XFILES='$(XFILES)'
 440 else
 441     XLIB=""
 442     X_CFLAGS=""
 443     X_LIBS=""
 444 fi
 445
 446 dnl **** Check for libxml2 ****
 447
 448 AC_SUBST(XML2LIBS,"")
 449 AC_SUBST(XML2INCL,"")
 450 AC_SUBST(XSLTLIBS,"")
 451 AC_SUBST(XSLTINCL,"")
 452 if test "$PKG_CONFIG" != "false"
 453 then
 454     ac_save_CPPFLAGS="$CPPFLAGS"
 455     ac_xml_libs="`$PKG_CONFIG --libs libxml-2.0`"
 456     ac_xml_cflags="`$PKG_CONFIG --cflags libxml-2.0`"
 457     CPPFLAGS="$CPPFLAGS $ac_xml_cflags"
 458     AC_CHECK_HEADERS(libxml/parser.h,
 459         [AC_CHECK_LIB(xml2, xmlParseMemory,
 460             [AC_DEFINE(HAVE_LIBXML2, 1, [Define if you have the libxml2 library])
 461              XML2LIBS="$ac_xml_libs"
 462              XML2INCL="$ac_xml_cflags"],,$ac_xml_libs)
 463          AC_CHECK_LIB(xml2, xmlReadMemory,
 464             [AC_DEFINE(HAVE_XMLREADMEMORY,1,[Define if libxml2 has the xmlReadMemory function])],,$ac_xml_libs)
 465         ])
 466     CPPFLAGS="$ac_save_CPPFLAGS"
 467     ac_xslt_libs="`$PKG_CONFIG --libs libxslt`"
 468     ac_xslt_cflags="`$PKG_CONFIG --cflags libxslt`"
 469     CPPFLAGS="$CPPFLAGS $ac_xslt_cflags"
 470     AC_CHECK_HEADERS([libxslt/pattern.h libxslt/transform.h],
 471         [AC_CHECK_LIB(xslt, xsltCompilePattern,
 472             [AC_DEFINE(HAVE_LIBXSLT, 1, [Define if you have the libxslt library])
 473              XSLTLIBS="$ac_xslt_libs"
 474              XSLTINCL="$ac_xslt_cflags"],,$ac_xslt_libs)
 475         ],,
 476 [#ifdef HAVE_LIBXSLT_PATTERN_H
 477 # include <libxslt/pattern.h>
 478 #endif])
 479     CPPFLAGS="$ac_save_CPPFLAGS"
 480 fi
 481
 482 dnl **** Check which curses lib to use ***
 483 CURSESLIBS=""
 484 if test "x$with_curses" != "xno"
 485 then
 486     if test "$ac_cv_header_ncurses_h" = "yes"
 487     then
 488         AC_CHECK_LIB(ncurses,waddch,
 489             [AC_DEFINE(HAVE_LIBNCURSES, 1, [Define if you have the ncurses library (-lncurses)])
 490              CURSESLIBS="-lncurses"])
 491     elif test "$ac_cv_header_curses_h" = "yes"
 492     then
 493         AC_CHECK_LIB(curses,waddch,
 494             [AC_DEFINE(HAVE_LIBCURSES, 1, [Define if you have the curses library (-lcurses)])
 495              CURSESLIBS="-lcurses"])
 496     fi
 497 fi
 498 AC_SUBST(CURSESLIBS)
 499
 500 dnl **** Check for SANE ****
 501 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
 502 AC_SUBST(SANELIBS,"")
 503 AC_SUBST(SANEINCL,"")
 504 if test "$sane_devel" != "no"
 505 then
 506     SANELIBS="`$sane_devel --libs`"
 507     SANEINCL="`$sane_devel --cflags`"
 508     ac_save_CPPFLAGS="$CPPFLAGS"
 509     ac_save_LIBS="$LIBS"
 510     CPPFLAGS="$CPPFLAGS $SANEINCL"
 511     LIBS="$LIBS $SANELIBS"
 512     AC_CHECK_HEADER(sane/sane.h,
 513                     [AC_CHECK_LIB(sane,sane_open,
 514                                   [AC_DEFINE(HAVE_SANE, 1, [Define if we have SANE development environment])],
 515                                   [SANELIBS=""
 516                                   SANEINCL=""])],
 517                     [SANELIBS=""
 518                     SANEINCL=""])
 519     LIBS="$ac_save_LIBS"
 520     CPPFLAGS="$ac_save_CPPFLAGS"
 521 fi
 522
 523 dnl **** Check for the ICU library ****
 524 if test "$ac_cv_header_unicode_ubidi_h" = "yes"
 525 then
 526     saved_libs="$LIBS"
 527     ICU_LIB_DIR="${ICU_LIB_DIR-/usr/lib}"
 528     ICUUC_LIB="${ICUUC_LIB-$ICU_LIB_DIR/libsicuuc.a}"
 529     ICUDATA_LIB="${ICUDATA_LIB-$ICU_LIB_DIR/libsicudata.a}"
 530     AC_MSG_CHECKING(whether can link with ICU libraries $ICUUC_LIB and $ICUDATA_LIB)
 531     LIBS="$LIBS $ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s"
 532     AC_TRY_LINK([#include <unicode/ubidi.h>],[ubidi_open()],
 533                 [AC_DEFINE(HAVE_ICU,1,[Define to 1 if the ICU libraries are installed])
 534                  AC_SUBST(ICULIBS,"$ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s")
 535                  AC_MSG_RESULT(yes)],
 536                 [AC_MSG_RESULT(no)])
 537     LIBS="$saved_libs"
 538 fi
 539
 540 dnl **** Check for LittleCMS ***
 541 AC_SUBST(LCMSLIBS,"")
 542 if test "$ac_cv_header_lcms_h" = "yes" -o "$ac_cv_header_lcms_lcms_h" = "yes"
 543 then
 544     AC_CHECK_LIB(lcms, cmsOpenProfileFromFile,
 545         [AC_DEFINE(HAVE_LCMS, 1, [Define if you have the LittleCMS development environment])
 546          LCMSLIBS="-llcms"])
 547 fi
 548
 549 dnl **** Check for OpenLDAP ***
 550 AC_SUBST(LDAPLIBS,"")
 551 if test "$ac_cv_header_ldap_h" = "yes" -a "$ac_cv_header_lber_h" = "yes"
 552 then
 553     AC_CHECK_LIB(ldap_r, ldap_initialize,
 554         [AC_CHECK_LIB(lber, ber_init,
 555             [AC_DEFINE(HAVE_LDAP, 1, [Define if you have the OpenLDAP development environment])
 556              LDAPLIBS="-lldap_r -llber"],,
 557              [$LIBPTHREAD])],,
 558              [$LIBPTHREAD])
 559     WINE_CHECK_LIB_FUNCS(\
 560         ldap_count_references \
 561         ldap_first_reference \
 562         ldap_next_reference \
 563         ldap_parse_reference,
 564         [$LDAPLIBS $LIBPTHREAD])
 565 fi
 566
 567 dnl **** Check for FreeType 2 ****
 568 AC_SUBST(FREETYPELIBS,"")
 569 AC_SUBST(FREETYPEINCL,"")
 570 AC_CHECK_LIB(freetype,FT_Init_FreeType,ft_lib=yes,ft_lib=no,$X_LIBS)
 571 if test "$ft_lib" = "no"
 572 then
 573     wine_cv_msg_freetype=no
 574 else
 575     AC_CHECK_PROG(ft_devel,freetype-config,freetype-config,no)
 576     if test "$ft_devel" = "no"
 577     then
 578         AC_CHECK_PROG(ft_devel2,freetype2-config,freetype2-config,no)
 579         if test "$ft_devel2" = "freetype2-config"
 580         then
 581                 ft_devel=$ft_devel2
 582         fi
 583     fi
 584     if test "$ft_devel" = "no"
 585     then
 586         wine_cv_msg_freetype=yes
 587     else
 588         FREETYPELIBS=`$ft_devel --libs`
 589         FREETYPEINCL=`$ft_devel --cflags`
 590         ac_save_CPPFLAGS="$CPPFLAGS"
 591         CPPFLAGS="$FREETYPEINCL $CPPFLAGS"
 592         AC_CHECK_HEADERS(ft2build.h \
 593                          freetype/freetype.h \
 594                          freetype/ftglyph.h \
 595                          freetype/tttables.h \
 596                          freetype/ftnames.h \
 597                          freetype/ftsnames.h \
 598                          freetype/ttnameid.h \
 599                          freetype/ftoutln.h \
 600                          freetype/ftwinfnt.h \
 601                          freetype/ftmodapi.h \
 602                          freetype/internal/sfnt.h,,,
 603                          [#if HAVE_FT2BUILD_H
 604                           #include <ft2build.h>
 605                           #endif])
 606         AC_TRY_CPP([#include <ft2build.h>
 607                     #include <freetype/fttrigon.h>],
 608                     [AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
 609           [Define if you have the <freetype/fttrigon.h> header file.])
 610                     wine_cv_fttrigon=yes],
 611                     wine_cv_fttrigon=no)
 612         AC_CHECK_TYPES(FT_TrueTypeEngineType,,,[#include <freetype/ftmodapi.h>])
 613         CPPFLAGS="$ac_save_CPPFLAGS"
 614         dnl Check that we have at least freetype/freetype.h
 615         if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
 616         then
 617             AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
 618             wine_cv_msg_freetype=no
 619         else
 620             FREETYPELIBS=""
 621             FREETYPEINCL=""
 622             wine_cv_msg_freetype=yes
 623         fi
 624     fi
 625 fi
 626
 627 dnl Only build the fonts dir if we have both freetype and fontforge
 628 if test "$FONTFORGE" != "false" -a -n "$FREETYPELIBS"
 629 then
 630   AC_SUBST(FONTSSUBDIRS,"fonts")
 631 fi
 632
 633 dnl **** Check for parport (currently Linux only) ****
 634 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
 635  AC_TRY_COMPILE(
 636    [#include <linux/ppdev.h>],
 637    [ioctl (1,PPCLAIM,0)],
 638    [ac_cv_c_ppdev="yes"],
 639    [ac_cv_c_ppdev="no"])
 640  )
 641 if test "$ac_cv_c_ppdev" = "yes"
 642 then
 643     AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
 644 fi
 645
 646 dnl **** Check for va_copy ****
 647 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
 648  AC_TRY_LINK(
 649    [#include <stdarg.h>],
 650    [va_list ap1, ap2;
 651     va_copy(ap1,ap2);
 652    ],
 653    [ac_cv_c_va_copy="yes"],
 654    [ac_cv_c_va_copy="no"])
 655  )
 656 if test "$ac_cv_c_va_copy" = "yes"
 657 then
 658     AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
 659 fi
 660 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
 661  AC_TRY_LINK(
 662    [#include <stdarg.h>],
 663    [va_list ap1, ap2;
 664     __va_copy(ap1,ap2);
 665    ],
 666    [ac_cv_c___va_copy="yes"],
 667    [ac_cv_c___va_copy="no"])
 668  )
 669 if test "$ac_cv_c___va_copy" = "yes"
 670 then
 671     AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
 672 fi
 673
 674 dnl **** Check for sigsetjmp ****
 675 AC_CACHE_CHECK([for sigsetjmp], ac_cv_c_sigsetjmp,
 676  AC_TRY_LINK(
 677    [#include <setjmp.h>],
 678    [sigjmp_buf buf;
 679     sigsetjmp( buf, 1 );
 680     siglongjmp( buf, 1 );],
 681    [ac_cv_c_sigsetjmp="yes"],
 682    [ac_cv_c_sigsetjmp="no"])
 683  )
 684 if test "$ac_cv_c_sigsetjmp" = "yes"
 685 then
 686     AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have the sigsetjmp (and siglongjmp) function])
 687 fi
 688
 689 dnl **** Check for pthread_rwlock_t ****
 690 AC_CHECK_TYPES([pthread_rwlock_t, pthread_rwlockattr_t],,,[#define _GNU_SOURCE
 691 #include <pthread.h>])
 692
 693 dnl **** Check for pthread functions ****
 694 WINE_CHECK_LIB_FUNCS(\
 695         pthread_getattr_np \
 696         pthread_get_stackaddr_np \
 697         pthread_get_stacksize_np,
 698         [$LIBPTHREAD])
 699
 700 dnl **** Check for aRts Sound Server ****
 701 AC_PATH_PROG(ARTSCCONFIG, artsc-config)
 702 if test x$ARTSCCONFIG != x -a x$ARTSCCONFIG != x'"$ARTSCCONFIG"';
 703 then
 704     ARTSC_CFLAGS=""
 705     for i in `$ARTSCCONFIG --cflags`
 706     do
 707       case "$i" in
 708         -I*) ARTSC_CFLAGS="$ARTSC_CFLAGS $i";;
 709       esac
 710     done
 711     ARTSC_LIBS=`$ARTSCCONFIG --libs`
 712     save_CFLAGS="$CFLAGS"
 713     CFLAGS="$CFLAGS $ARTSC_CFLAGS"
 714     AC_CHECK_LIB(artsc,arts_init,
 715         [AC_TRY_COMPILE([#include <artsc.h>],[arts_stream_t stream;],
 716             [AC_SUBST(ARTSLIBS, $ARTSC_LIBS)
 717             AC_SUBST(ARTSINCL, $ARTSC_CFLAGS)
 718             AC_DEFINE(HAVE_ARTS, 1, [Define if you have ARTS sound server])])],,
 719             $ARTSC_LIBS)
 720     CFLAGS="$save_CFLAGS"
 721 fi
 722
 723 dnl **** Check for EsounD ****
 724 AC_PATH_PROG(ESDCONFIG, esd-config)
 725 if test x$ESDCONFIG != x -a x$ESDCONFIG != x'"$ESDCONFIG"';
 726 then
 727     ESD_CFLAGS=""
 728     for i in `$ESDCONFIG --cflags`
 729     do
 730       case "$i" in
 731         -I*) ESD_CFLAGS="$ESD_CFLAGS $i";;
 732       esac
 733     done
 734     ESD_LIBS=`$ESDCONFIG --libs`
 735     save_CFLAGS="$CFLAGS"
 736     CFLAGS="$CFLAGS $ESD_CFLAGS"
 737     AC_CHECK_LIB(esd,esd_open_sound,
 738         [AC_SUBST(ESDLIBS, $ESD_LIBS)
 739          AC_SUBST(ESDINCL, $ESD_CFLAGS)
 740          AC_DEFINE(HAVE_ESD, 1, [Define if you have EsounD sound server])])
 741     CFLAGS="$save_CFLAGS"
 742 fi
 743
 744 dnl **** Check for ALSA 1.x ****
 745 AC_SUBST(ALSALIBS,"")
 746 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
 747 then
 748     AC_CHECK_LIB(asound,snd_pcm_hw_params_get_access,
 749         [AC_TRY_COMPILE([#ifdef HAVE_ALSA_ASOUNDLIB_H
 750 #include <alsa/asoundlib.h>
 751 #elif defined(HAVE_SYS_ASOUNDLIB_H)
 752 #include <sys/asoundlib.h>
 753 #endif],
 754                         [int ret = snd_pcm_hw_params_get_access(NULL, NULL)],
 755                         [AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA 1.x including devel headers])
 756                          ALSALIBS="-lasound"])])
 757 fi
 758
 759 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
 760
 761 AC_SUBST(AUDIOIOLIBS,"")
 762 if test "$ac_cv_header_libaudioio_h" = "yes"
 763 then
 764     AC_CHECK_LIB(audioio,AudioIOGetVersion,
 765                   [AUDIOIOLIBS="-laudioio"
 766                    AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])
 767 fi
 768
 769 dnl **** Check for capi4linux ****
 770
 771 if test "$ac_cv_header_capi20_h" = "yes" -a "$ac_cv_header_linux_capi_h" = "yes"
 772 then
 773     AC_CHECK_LIB(capi20,capi20_register,[AC_DEFINE(HAVE_CAPI4LINUX,1,[Define if you have capi4linux libs and headers])])
 774 fi
 775
 776 dnl **** Check for gcc specific options ****
 777
 778 AC_SUBST(EXTRACFLAGS,"")
 779 if test "x${GCC}" = "xyes"
 780 then
 781   EXTRACFLAGS="-Wall -pipe"
 782
 783   dnl Check for strength-reduce bug
 784   AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
 785                   AC_TRY_RUN([
 786 int     L[[4]] = {0,1,2,3};
 787 int main(void) {
 788   static int Array[[3]];
 789   unsigned int B = 3;
 790   int i;
 791   for(i=0; i<B; i++) Array[[i]] = i - 3;
 792   for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
 793   L[[i]] = 4;
 794
 795   exit( Array[[1]] != -2 || L[[2]] != 3);
 796 }],
 797     ac_cv_c_gcc_strength_bug="no",
 798     ac_cv_c_gcc_strength_bug="yes",
 799     ac_cv_c_gcc_strength_bug="yes") )
 800   if test "$ac_cv_c_gcc_strength_bug" = "yes"
 801   then
 802     EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
 803   fi
 804
 805   dnl Check for -fshort-wchar
 806   AC_CACHE_CHECK([for gcc -fshort-wchar support], ac_cv_c_gcc_fshort_wchar,
 807       [WINE_TRY_CFLAGS([-fshort-wchar],
 808                       ac_cv_c_gcc_fshort_wchar="yes",ac_cv_c_gcc_fshort_wchar="no")])
 809   if test "$ac_cv_c_gcc_fshort_wchar" = "yes"
 810   then
 811       AC_DEFINE(CC_FLAG_SHORT_WCHAR, "-fshort-wchar", [Specifies the compiler flag that forces a short wchar_t])
 812   fi
 813
 814   dnl Check for -fno-strict-aliasing
 815   AC_CACHE_CHECK([for gcc -fno-strict-aliasing support], ac_cv_c_gcc_no_strict_aliasing,
 816       [WINE_TRY_CFLAGS([-fno-strict-aliasing],
 817                       ac_cv_c_gcc_no_strict_aliasing="yes",ac_cv_c_gcc_no_strict_aliasing="no")])
 818   if test "$ac_cv_c_gcc_no_strict_aliasing" = "yes"
 819   then
 820     EXTRACFLAGS="$EXTRACFLAGS -fno-strict-aliasing"
 821   fi
 822
 823   dnl Check for -gstabs+ option
 824   AC_CACHE_CHECK([for gcc -gstabs+ support], ac_cv_c_gcc_gstabs,
 825       [WINE_TRY_CFLAGS([-gstabs+],ac_cv_c_gcc_gstabs="yes", ac_cv_c_gcc_gstabs="no")])
 826   if test "$ac_cv_c_gcc_gstabs" = "yes"
 827   then
 828     EXTRACFLAGS="$EXTRACFLAGS -gstabs+"
 829   fi
 830
 831   dnl Check for -Wdeclaration-after-statement option
 832   AC_CACHE_CHECK([for gcc -Wdeclaration-after-statement support], ac_cv_c_gcc_decl_after_statement,
 833       [WINE_TRY_CFLAGS([-Wdeclaration-after-statement],ac_cv_c_gcc_decl_after_statement="yes", ac_cv_c_gcc_decl_after_statement="no")])
 834   if test "$ac_cv_c_gcc_decl_after_statement" = "yes"
 835   then
 836     EXTRACFLAGS="$EXTRACFLAGS -Wdeclaration-after-statement"
 837   fi
 838
 839   dnl Check for noisy string.h
 840   saved_CFLAGS="$CFLAGS"
 841   CFLAGS="$CFLAGS -Wpointer-arith -Werror"
 842   AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
 843       AC_TRY_COMPILE([#include <string.h>],[],
 844                      [ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
 845   CFLAGS="$saved_CFLAGS"
 846   if test "$ac_cv_c_string_h_warnings" = "no"
 847   then
 848     EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
 849   fi
 850
 851   AC_SUBST(BUILTINFLAG,"")
 852   saved_CFLAGS="$CFLAGS"
 853   CFLAGS="$CFLAGS -Werror"
 854   AC_CACHE_CHECK([for builtin wchar inlines], ac_cv_c_builtin_wchar_ctype,
 855       AC_TRY_COMPILE([],
 856                      [int iswlower(unsigned short);],
 857                      [ac_cv_c_builtin_wchar_ctype=no],[ac_cv_c_builtin_wchar_ctype=yes]))
 858   CFLAGS="$saved_CFLAGS"
 859   if test "$ac_cv_c_builtin_wchar_ctype" = "yes"
 860   then
 861     BUILTINFLAG=""
 862     for builtin in \
 863       iswalnum iswalpha iswcntrl iswdigit iswgraph iswlower \
 864       iswprint iswpunct iswspace iswupper iswxdigit towlower towupper
 865     do
 866       BUILTINFLAG="$BUILTINFLAG -fno-builtin-$builtin"
 867     done
 868   fi
 869 fi
 870
 871 dnl **** Check how to define a function in assembly code ****
 872
 873 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
 874   WINE_TRY_ASM_LINK(
 875       ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
 876       ac_cv_asm_func_def=".def",
 877     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
 878       ac_cv_asm_func_def=".type @function",
 879     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
 880       ac_cv_asm_func_def=".type 2",
 881       ac_cv_asm_func_def="unknown")])]))
 882
 883 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
 884 case "$ac_cv_asm_func_def" in
 885   ".def")
 886      AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
 887   ".type @function")
 888      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
 889   ".type 2")
 890      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
 891   *)
 892      AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
 893 esac
 894
 895 dnl **** Check for underscore on external symbols ****
 896
 897 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
 898     WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
 899                       [extern int ac_test;],
 900                       [if (ac_test) return 1],
 901                       ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
 902
 903 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
 904 if test "$ac_cv_c_extern_prefix" = "yes"
 905 then
 906   AC_DEFINE([__ASM_NAME(name)], ["_" name])
 907 else
 908   AC_DEFINE([__ASM_NAME(name)], [name])
 909 fi
 910
 911 dnl **** Check for working dll ****
 912
 913 AC_SUBST(DLLEXT,"")
 914 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
 915 AC_SUBST(DLLIBS,"")
 916 AC_SUBST(LDSHARED,"")
 917 AC_SUBST(LDDLLFLAGS,"")
 918 AC_SUBST(LIBEXT,"so")
 919 AC_SUBST(IMPLIBEXT,"def")
 920
 921 case $host_os in
 922   cygwin*|mingw32*)
 923     AC_CHECK_TOOL(DLLTOOL,dlltool,false)
 924     AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
 925     if test "$DLLWRAP" = "false"; then
 926       LIBEXT="a"
 927     else
 928       dnl FIXME - check whether dllwrap works correctly...
 929       LIBEXT="dll"
 930     fi
 931     IMPLIBEXT="a"
 932     dnl We can't build 16-bit NE dlls
 933     WIN16_FILES=""
 934     WIN16_INSTALL=""
 935     ;;
 936   *)
 937     if test "$ac_cv_header_dlfcn_h" = "yes"
 938     then
 939         AC_CHECK_FUNCS(dlopen,,
 940             [AC_CHECK_LIB(dl,dlopen,
 941                          [AC_DEFINE(HAVE_DLOPEN,1,[Define if you have dlopen])
 942                           DLLIBS="-ldl"],
 943                          [LIBEXT="a"])])
 944         WINE_CHECK_LIB_FUNCS(dladdr,[$DLLIBS])
 945     else
 946         LIBEXT="a"
 947     fi
 948
 949     if test "$LIBEXT" = "so"
 950     then
 951       DLLFLAGS="$DLLFLAGS -fPIC"
 952       DLLEXT=".so"
 953       AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
 954           [WINE_TRY_SHLIB_FLAGS([-fPIC -shared -Wl,-soname,conftest.so.1.0,-Bsymbolic],
 955                                 ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
 956       if test "$ac_cv_c_dll_gnuelf" = "yes"
 957       then
 958         LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"
 959         LDDLLFLAGS="-shared -Wl,-Bsymbolic"
 960         AC_CACHE_CHECK([whether the linker accepts -z defs], ac_cv_c_dll_zdefs,
 961           [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs],
 962                            ac_cv_c_dll_zdefs="yes",ac_cv_c_dll_zdefs="no")])
 963         if test "$ac_cv_c_dll_zdefs" = "yes"
 964         then
 965           LDDLLFLAGS="$LDDLLFLAGS,-z,defs"
 966         fi
 967
 968         AC_CACHE_CHECK([whether the linker accepts -init and -fini], ac_cv_c_dll_init_fini,
 969           [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-init,__wine_spec_init,-fini,__wine_spec_fini],
 970                            ac_cv_c_dll_init_fini="yes",ac_cv_c_dll_init_fini="no")])
 971         if test "$ac_cv_c_dll_init_fini" = "yes"
 972         then
 973           LDDLLFLAGS="$LDDLLFLAGS,-init,__wine_spec_init,-fini,__wine_spec_fini"
 974         fi
 975
 976         AC_CACHE_CHECK([whether the linker accepts version scripts], ac_cv_c_ld_version_scripts,
 977           [echo '{ global: *; };' >conftest.map
 978            WINE_TRY_CFLAGS([-fPIC -shared -Wl,--version-script=conftest.map],
 979                            ac_cv_c_ld_version_scripts="yes",ac_cv_c_ld_version_scripts="no")
 980            rm -f conftest.map])
 981         if test "$ac_cv_c_ld_version_scripts" = "yes"
 982         then
 983           LDSHARED="$LDSHARED \$(VERSCRIPT:%=-Wl,--version-script=%)"
 984         fi
 985
 986         AC_CACHE_CHECK([whether the linker accepts --export-dynamic], ac_cv_c_export_dynamic,
 987           [WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
 988                            ac_cv_c_export_dynamic="yes",ac_cv_c_export_dynamic="no")])
 989         if test "$ac_cv_c_export_dynamic" = "yes"
 990         then
 991           AC_SUBST(LDEXECFLAGS,["-Wl,--export-dynamic"])
 992         fi
 993
 994         AC_CACHE_CHECK([whether the linker accepts --rpath], ac_cv_ld_rpath,
 995           [WINE_TRY_CFLAGS([-fPIC -Wl,--rpath,\$ORIGIN/../lib],
 996                            ac_cv_ld_rpath="yes",ac_cv_ld_rpath="no")])
 997         if test "$ac_cv_ld_rpath" = "yes"
 998         then
 999           AC_SUBST(LDEXERPATH,["-Wl,--rpath,\\\$\$ORIGIN/\`\$(RELPATH) \$(bindir) \$(libdir)\`"])
1000           AC_SUBST(LDDLLRPATH,["-Wl,--rpath,\\\$\$ORIGIN/\`\$(RELPATH) \$(dlldir) \$(libdir)\`"])
1001         fi
1002
1003         case $host_cpu in
1004           *i[[3456789]]86*)
1005             AC_CACHE_CHECK([whether we can relocate the executable to 0x7bf00000], ac_cv_ld_reloc_exec,
1006               [WINE_TRY_CFLAGS([-Wl,--section-start,.interp=0x7bf00400],
1007                                ac_cv_ld_reloc_exec="yes", ac_cv_ld_reloc_exec="no")])
1008             if test "$ac_cv_ld_reloc_exec" = "yes"
1009             then
1010               LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x7bf00400"
1011             fi
1012             ;;
1013         esac
1014
1015       else
1016         AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
1017             [WINE_TRY_SHLIB_FLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
1018                                   ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
1019         if test "$ac_cv_c_dll_unixware" = "yes"
1020         then
1021           LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
1022           LDDLLFLAGS="-Wl,-G,-B,symbolic"
1023
1024         else
1025           AC_CACHE_CHECK(whether we can build a Mach-O (Mac OS X/Darwin) dll, ac_cv_c_dll_macho,
1026             [WINE_TRY_SHLIB_FLAGS([-bundle], ac_cv_c_dll_macho="yes", ac_cv_c_dll_macho="no")])
1027           if test "$ac_cv_c_dll_macho" = "yes"
1028           then
1029             LIBEXT="dylib"
1030             LDDLLFLAGS="-bundle"
1031             LDSHARED="\$(CC) -dynamiclib"
1032             STRIP="$STRIP -u -r"
1033             dnl declare needed frameworks
1034             AC_SUBST(COREFOUNDATIONLIB,"-framework CoreFoundation")
1035             AC_SUBST(IOKITLIB,"-framework IOKit -framework CoreFoundation")
1036             AC_SUBST(LDEXECFLAGS,["-image_base 0x7bf00000 -Wl,-segaddr,WINE_DOS,0x00000000,-segaddr,WINE_SHARED_HEAP,0x7ffe0000"])
1037             case $host_cpu in
1038               *powerpc*)
1039                 CFLAGS="$CFLAGS -ffixed-r13"
1040                 LDDLLFLAGS="$LDDLLFLAGS -read_only_relocs warning"
1041                 ;;
1042             esac
1043
1044           else
1045             AC_CACHE_CHECK(whether we can build an HP-UX dll, ac_cv_c_dll_hpux,
1046               [WINE_TRY_SHLIB_FLAGS([-shared], ac_cv_c_dll_hpux="yes", ac_cv_c_dll_hpux="no")])
1047             if test "$ac_cv_c_dll_hpux" = "yes"
1048             then
1049               LIBEXT="sl"
1050               DLLEXT=".sl"
1051               LDDLLFLAGS="-shared -fPIC"
1052               LDSHARED="\$(CC) -shared"
1053             fi
1054           fi
1055         fi
1056       fi
1057     fi
1058
1059     dnl Check for cross compiler to build test programs
1060     AC_SUBST(CROSSTEST,"")
1061     if test "$cross_compiling" = "no"
1062     then
1063       AC_CHECK_PROGS(CROSSCC,i586-mingw32msvc-gcc i386-mingw32msvc-gcc i386-mingw32-gcc mingw-gcc,false)
1064       AC_CHECK_PROGS(DLLTOOL,i586-mingw32msvc-dlltool i386-mingw32msvc-dlltool i386-mingw32-dlltool mingw-dlltool,false)
1065       AC_CHECK_PROGS(CROSSWINDRES,i586-mingw32msvc-windres i386-mingw32msvc-windres i386-mingw32-windres mingw-windres,false)
1066       if test "$CROSSCC" != "false"; then CROSSTEST="\$(CROSSTEST)"; fi
1067     fi
1068     ;;
1069 esac
1070
1071 if test "$LIBEXT" = "a"; then
1072   AC_MSG_ERROR(
1073 [could not find a way to build shared libraries.
1074 It is currently not possible to build Wine without shared library
1075 (.so) support to allow transparent switch between .so and .dll files.
1076 If you are using Linux, you will need a newer binutils.]
1077 )
1078 fi
1079
1080 case $build_os in
1081   cygwin*|mingw32*)
1082     AC_SUBST(LDPATH,"PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$PATH\"") ;;
1083   darwin*|macosx*)
1084     AC_SUBST(LDPATH,"DYLD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$DYLD_LIBRARY_PATH\"") ;;
1085   *)
1086     AC_SUBST(LDPATH,"LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$LD_LIBRARY_PATH\"") ;;
1087 esac
1088
1089 dnl Mingw needs explicit msvcrt for linking libwine and winsock for wininet
1090 case $host_os in
1091   mingw32*)
1092     AC_SUBST(CRTLIBS,"-lmsvcrt")
1093     AC_SUBST(SOCKETLIBS,"-lws2_32")
1094     ;;
1095 esac
1096
1097 case $host_cpu in
1098   *i[[3456789]]86*)
1099     case $host_os in
1100       linux* | k*bsd*-gnu)
1101         AC_SUBST(MAIN_BINARY,"wine-glibc")
1102         AC_SUBST(EXTRA_BINARIES,"wine-kthread wine-pthread wine-preloader") ;;
1103       darwin*)
1104         AC_SUBST(MAIN_BINARY,"wine-pthread") ;;
1105       *)
1106         AC_SUBST(MAIN_BINARY,"wine-kthread") ;;
1107     esac
1108     ;;
1109   *) AC_SUBST(MAIN_BINARY,"wine-pthread") ;;
1110 esac
1111
1112 dnl **** Get the soname for libraries that we load dynamically ****
1113
1114 if test "$LIBEXT" = "so" -o "$LIBEXT" = "dylib"
1115 then
1116   WINE_GET_SONAME(X11,XCreateWindow,[$X_LIBS $X_EXTRA_LIBS])
1117   WINE_GET_SONAME(Xext,XextCreateExtension,[$X_LIBS -lX11 $X_EXTRA_LIBS])
1118   WINE_GET_SONAME(Xi,XOpenDevice,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1119   WINE_GET_SONAME(Xrender,XRenderQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1120   WINE_GET_SONAME(Xrandr,XRRQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1121   WINE_GET_SONAME(freetype,FT_Init_FreeType,[$X_LIBS])
1122   WINE_GET_SONAME(GL,glXQueryExtension,[$X_LIBS $X_EXTRA_LIBS])
1123   WINE_GET_SONAME(txc_dxtn,fetch_2d_texel_rgba_dxt1)
1124   WINE_GET_SONAME(cups,cupsGetDefault)
1125   WINE_GET_SONAME(jack,jack_client_new)
1126   WINE_GET_SONAME(fontconfig,FcInit)
1127   WINE_GET_SONAME(ssl,SSL_library_init)
1128   WINE_GET_SONAME(crypto,BIO_new_socket)
1129   WINE_GET_SONAME(ncurses,waddch)
1130   WINE_GET_SONAME(curses,waddch)
1131   WINE_GET_SONAME(jpeg,jpeg_start_decompress)
1132   WINE_GET_SONAME(ungif,DGifOpen)
1133   WINE_GET_SONAME(gif,DGifOpen)
1134   WINE_GET_SONAME(capi20,capi20_isinstalled)
1135 fi
1136
1137
1138 dnl **** Check for functions ****
1139
1140 AC_CHECK_FUNCS(\
1141         _lwp_create \
1142         _lwp_self \
1143         _pclose \
1144         _popen \
1145         _snprintf \
1146         _spawnvp \
1147         _stricmp \
1148         _strnicmp \
1149         _vsnprintf \
1150         asctime_r \
1151         chsize \
1152         clone \
1153         epoll_create \
1154         ffs \
1155         finite \
1156         fork \
1157         fpclass \
1158         fstatfs \
1159         fstatvfs \
1160         ftruncate \
1161         futimes \
1162         futimesat \
1163         getaddrinfo \
1164         getnameinfo \
1165         getnetbyname \
1166         getopt_long \
1167         getpagesize \
1168         getprotobyname \
1169         getprotobynumber \
1170         getpwuid \
1171         getservbyport \
1172         gettid \
1173         gettimeofday \
1174         getuid \
1175         inet_network \
1176         lstat \
1177         memmove \
1178         mmap \
1179         pclose \
1180         popen \
1181         pread \
1182         pwrite \
1183         readlink \
1184         rfork \
1185         sched_yield \
1186         select \
1187         sendmsg \
1188         settimeofday \
1189         sigaltstack \
1190         sigprocmask \
1191         snprintf \
1192         spawnvp \
1193         statfs \
1194         statvfs \
1195         strcasecmp \
1196         strerror \
1197         strncasecmp \
1198         tcgetattr \
1199         timegm \
1200         usleep \
1201         vsnprintf \
1202         wait4 \
1203         waitpid \
1204 )
1205
1206 dnl **** Checks for headers that depend on other ones ****
1207
1208 AC_CHECK_HEADERS([sys/mount.h sys/statfs.h sys/user.h sys/vfs.h],,,
1209     [#include <sys/types.h>
1210      #if HAVE_SYS_PARAM_H
1211      # include <sys/param.h>
1212      #endif])
1213
1214 AC_CHECK_HEADERS([net/if.h net/if_arp.h net/if_dl.h net/if_types.h net/route.h netipx/ipx.h],,,
1215     [#include <sys/types.h>
1216      #if HAVE_SYS_SOCKET_H
1217      # include <sys/socket.h>
1218      #endif])
1219
1220 AC_CHECK_HEADERS([resolv.h],,,
1221     [#include <sys/types.h>
1222      #if HAVE_SYS_SOCKET_H
1223      # include <sys/socket.h>
1224      #endif
1225      #if HAVE_NETINET_IN_H
1226      # include <netinet/in.h>
1227      #endif
1228      #if HAVE_ARPA_NAMESER_H
1229      # include <arpa/nameser.h>
1230      #endif])
1231
1232 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
1233
1234 AC_CHECK_HEADERS([linux/ipx.h linux/videodev.h],,,
1235 [#ifdef HAVE_SYS_TIME_H
1236 #include <sys/time.h>
1237 #endif
1238 #include <sys/types.h>
1239 #ifdef HAVE_ASM_TYPES_H
1240 #include <asm/types.h>
1241 #endif])
1242
1243 dnl **** Check for types ****
1244
1245 AC_C_CONST
1246 AC_C_INLINE
1247 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t, long long, fsblkcnt_t, fsfilcnt_t])
1248 AC_CHECK_TYPES([sigset_t],,,[#include <signal.h>])
1249 AC_CHECK_TYPES([request_sense],,,[#include <linux/cdrom.h>])
1250
1251 AC_CHECK_MEMBERS([struct ff_effect.direction],,,
1252 [#ifdef HAVE_LINUX_INPUT_H
1253 #include <linux/input.h>
1254 #endif])
1255
1256 AC_CACHE_CHECK([for sigaddset],wine_cv_have_sigaddset,
1257                AC_TRY_LINK([#include <signal.h>],[sigset_t set; sigaddset(&set,SIGTERM);],
1258                            wine_cv_have_sigaddset=yes,wine_cv_have_sigaddset=no))
1259 if test "$wine_cv_have_sigaddset" = "yes"
1260 then
1261   AC_DEFINE(HAVE_SIGADDSET, 1, [Define if sigaddset is supported])
1262 fi
1263
1264
1265 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1266         wine_cv_linux_gethostbyname_r_6,
1267         AC_TRY_LINK([
1268 #include <netdb.h>
1269         ], [
1270     char *name=NULL;
1271     struct hostent he;
1272     struct hostent *result;
1273     char *buf=NULL;
1274     int bufsize=0;
1275     int res,errnr;
1276     char *addr=NULL;
1277     int addrlen=0;
1278     int addrtype=0;
1279     res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1280     res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1281     ],
1282         wine_cv_linux_gethostbyname_r_6=yes,
1283         wine_cv_linux_gethostbyname_r_6=no
1284         )
1285    )
1286    if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1287    then
1288       AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1289                 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1290    fi
1291
1292 if test "$ac_cv_header_linux_joystick_h" = "yes"
1293 then
1294    AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1295         wine_cv_linux_joystick_22_api,
1296         AC_TRY_COMPILE([
1297         #include <sys/ioctl.h>
1298         #include <linux/joystick.h>
1299
1300         struct js_event blub;
1301         #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1302         #error "no 2.2 header"
1303         #endif
1304         ],/*empty*/,
1305         wine_cv_linux_joystick_22_api=yes,
1306         wine_cv_linux_joystick_22_api=no,
1307         wine_cv_linux_joystick_22_api=no
1308         )
1309    )
1310    if test "$wine_cv_linux_joystick_22_api" = "yes"
1311    then
1312       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1313                 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1314    fi
1315 fi
1316
1317 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1318
1319 dnl Check for statfs members
1320 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail, struct statfs.f_frsize, struct statfs.f_ffree, struct statfs.f_favail, struct statfs.f_namelen],,,
1321 [#include <sys/types.h>
1322 #ifdef HAVE_SYS_PARAM_H
1323 # include <sys/param.h>
1324 #endif
1325 #ifdef HAVE_SYS_MOUNT_H
1326 # include <sys/mount.h>
1327 #endif
1328 #ifdef HAVE_SYS_VFS_H
1329 # include <sys/vfs.h>
1330 #endif
1331 #ifdef HAVE_SYS_STATFS_H
1332 # include <sys/statfs.h>
1333 #endif])
1334
1335 AC_CHECK_MEMBERS([struct statvfs.f_blocks],,,
1336 [#ifdef HAVE_SYS_STATVFS_H
1337 #include <sys/statvfs.h>
1338 #endif])
1339
1340 dnl Check for socket structure members
1341 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
1342 [#include <sys/types.h>
1343 #ifdef HAVE_SYS_SOCKET_H
1344 # include <sys/socket.h>
1345 #endif
1346 #ifdef HAVE_SYS_UN_H
1347 # include <sys/un.h>
1348 #endif])
1349
1350 dnl Check for scsireq_t and sg_io_hdr_t members
1351 AC_CHECK_MEMBERS([scsireq_t.cmd, sg_io_hdr_t.interface_id],,,
1352 [#include <sys/types.h>
1353 #ifdef HAVE_SCSI_SG_H
1354 #include <scsi/sg.h>
1355 #endif])
1356
1357 dnl Check for siginfo_t members
1358 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
1359
1360 dnl Check for struct mtget members
1361 AC_CHECK_MEMBERS([struct mtget.mt_blksiz, struct mtget.mt_gstat, struct mtget.mt_blkno],,,
1362 [#include <sys/types.h>
1363 #ifdef HAVE_SYS_MTIO_H
1364 #include <sys/mtio.h>
1365 #endif])
1366
1367 dnl Check for struct option
1368 AC_CHECK_MEMBERS([struct option.name],,,
1369 [#ifdef HAVE_GETOPT_H
1370 #include <getopt.h>
1371 #endif])
1372
1373 dnl Check for stat.st_blocks
1374 AC_CHECK_MEMBERS([struct stat.st_blocks])
1375
1376 dnl Check for sin6_scope_id
1377 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_scope_id],,,
1378 [#ifdef HAVE_SYS_TYPES_H
1379 #include <sys/types.h>
1380 #endif
1381 #ifdef HAVE_NETINET_IN_H
1382 #include <netinet/in.h>
1383 #endif])
1384
1385 dnl Check for the external timezone variables timezone and daylight
1386 AC_CACHE_CHECK([for timezone variable], ac_cv_have_timezone,
1387                AC_TRY_LINK([#include <time.h>],[timezone;],
1388                            ac_cv_have_timezone="yes", ac_cv_have_timezone="no"))
1389 if test "$ac_cv_have_timezone" = "yes"
1390 then
1391     AC_DEFINE(HAVE_TIMEZONE, 1, [Define if you have the timezone variable])
1392 fi
1393 AC_CACHE_CHECK([for daylight variable], ac_cv_have_daylight,
1394                AC_TRY_LINK([#include <time.h>],[daylight;],
1395                            ac_cv_have_daylight="yes", ac_cv_have_daylight="no"))
1396 if test "$ac_cv_have_daylight" = "yes"
1397 then
1398     AC_DEFINE(HAVE_DAYLIGHT, 1, [Define if you have the daylight variable])
1399 fi
1400
1401 dnl *** check for the need to define platform-specific symbols
1402
1403 case $host_cpu in
1404   *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
1405   *x86_64*)         WINE_CHECK_DEFINE([__x86_64__]) ;;
1406   *alpha*)          WINE_CHECK_DEFINE([__ALPHA__]) ;;
1407   *sparc*)          WINE_CHECK_DEFINE([__sparc__]) ;;
1408   *powerpc*)        WINE_CHECK_DEFINE([__powerpc__]) ;;
1409 esac
1410
1411 case $host_vendor in
1412   *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
1413 esac
1414
1415 dnl **** Generate output files ****
1416
1417 AH_TOP([#define __WINE_CONFIG_H])
1418
1419 WINE_CONFIG_EXTRA_DIR(dlls/gdi/enhmfdrv)
1420 WINE_CONFIG_EXTRA_DIR(dlls/gdi/mfdrv)
1421 WINE_CONFIG_EXTRA_DIR(dlls/kernel/messages)
1422 WINE_CONFIG_EXTRA_DIR(dlls/user/resources)
1423 WINE_CONFIG_EXTRA_DIR(dlls/wineps/data)
1424 WINE_CONFIG_EXTRA_DIR(include/wine)
1425
1426 MAKE_RULES=Make.rules
1427 AC_SUBST_FILE(MAKE_RULES)
1428
1429 MAKE_DLL_RULES=dlls/Makedll.rules
1430 AC_SUBST_FILE(MAKE_DLL_RULES)
1431
1432 MAKE_IMPLIB_RULES=dlls/Makeimplib.rules
1433 AC_SUBST_FILE(MAKE_IMPLIB_RULES)
1434
1435 MAKE_TEST_RULES=dlls/Maketest.rules
1436 AC_SUBST_FILE(MAKE_TEST_RULES)
1437
1438 MAKE_LIB_RULES=libs/Makelib.rules
1439 AC_SUBST_FILE(MAKE_LIB_RULES)
1440
1441 MAKE_PROG_RULES=programs/Makeprog.rules
1442 AC_SUBST_FILE(MAKE_PROG_RULES)
1443
1444 AC_CONFIG_FILES([
1445 Make.rules
1446 dlls/Makedll.rules
1447 dlls/Makeimplib.rules
1448 dlls/Maketest.rules
1449 libs/Makelib.rules
1450 programs/Makeprog.rules
1451 Makefile
1452 dlls/Makefile
1453 dlls/activeds/Makefile
1454 dlls/advapi32/Makefile
1455 dlls/advapi32/tests/Makefile
1456 dlls/advpack/Makefile
1457 dlls/advpack/tests/Makefile
1458 dlls/amstream/Makefile
1459 dlls/atl/Makefile
1460 dlls/avicap32/Makefile
1461 dlls/avifil32/Makefile
1462 dlls/cabinet/Makefile
1463 dlls/cabinet/tests/Makefile
1464 dlls/capi2032/Makefile
1465 dlls/cards/Makefile
1466 dlls/cfgmgr32/Makefile
1467 dlls/comcat/Makefile
1468 dlls/comctl32/Makefile
1469 dlls/comctl32/tests/Makefile
1470 dlls/commdlg/Makefile
1471 dlls/crtdll/Makefile
1472 dlls/crypt32/Makefile
1473 dlls/crypt32/tests/Makefile
1474 dlls/cryptdll/Makefile
1475 dlls/ctl3d32/Makefile
1476 dlls/d3d8/Makefile
1477 dlls/d3d9/Makefile
1478 dlls/d3d9/tests/Makefile
1479 dlls/d3dim/Makefile
1480 dlls/d3drm/Makefile
1481 dlls/d3dx8/Makefile
1482 dlls/d3dxof/Makefile
1483 dlls/dbghelp/Makefile
1484 dlls/dciman32/Makefile
1485 dlls/ddraw/Makefile
1486 dlls/ddraw/tests/Makefile
1487 dlls/devenum/Makefile
1488 dlls/dinput/Makefile
1489 dlls/dinput/tests/Makefile
1490 dlls/dinput8/Makefile
1491 dlls/dmband/Makefile
1492 dlls/dmcompos/Makefile
1493 dlls/dmime/Makefile
1494 dlls/dmloader/Makefile
1495 dlls/dmscript/Makefile
1496 dlls/dmstyle/Makefile
1497 dlls/dmsynth/Makefile
1498 dlls/dmusic/Makefile
1499 dlls/dmusic32/Makefile
1500 dlls/dplay/Makefile
1501 dlls/dplayx/Makefile
1502 dlls/dpnet/Makefile
1503 dlls/dpnhpast/Makefile
1504 dlls/dsound/Makefile
1505 dlls/dsound/tests/Makefile
1506 dlls/dswave/Makefile
1507 dlls/dxdiagn/Makefile
1508 dlls/dxerr8/Makefile
1509 dlls/dxerr9/Makefile
1510 dlls/dxguid/Makefile
1511 dlls/gdi/Makefile
1512 dlls/gdi/tests/Makefile
1513 dlls/glu32/Makefile
1514 dlls/glut32/Makefile
1515 dlls/hhctrl.ocx/Makefile
1516 dlls/iccvid/Makefile
1517 dlls/icmp/Makefile
1518 dlls/ifsmgr.vxd/Makefile
1519 dlls/imagehlp/Makefile
1520 dlls/imm32/Makefile
1521 dlls/iphlpapi/Makefile
1522 dlls/iphlpapi/tests/Makefile
1523 dlls/itss/Makefile
1524 dlls/kernel/Makefile
1525 dlls/kernel/tests/Makefile
1526 dlls/lz32/Makefile
1527 dlls/lz32/tests/Makefile
1528 dlls/mapi32/Makefile
1529 dlls/mapi32/tests/Makefile
1530 dlls/mciavi32/Makefile
1531 dlls/mcicda/Makefile
1532 dlls/mciseq/Makefile
1533 dlls/midimap/Makefile
1534 dlls/mlang/Makefile
1535 dlls/mlang/tests/Makefile
1536 dlls/mmdevldr.vxd/Makefile
1537 dlls/monodebg.vxd/Makefile
1538 dlls/mpr/Makefile
1539 dlls/msacm/Makefile
1540 dlls/msacm/imaadp32/Makefile
1541 dlls/msacm/msadp32/Makefile
1542 dlls/msacm/msg711/Makefile
1543 dlls/msacm/tests/Makefile
1544 dlls/msacm/winemp3/Makefile
1545 dlls/mscms/Makefile
1546 dlls/mscms/tests/Makefile
1547 dlls/msdmo/Makefile
1548 dlls/msftedit/Makefile
1549 dlls/mshtml/Makefile
1550 dlls/mshtml/tests/Makefile
1551 dlls/msi/Makefile
1552 dlls/msi/tests/Makefile
1553 dlls/msimg32/Makefile
1554 dlls/msisys/Makefile
1555 dlls/msnet32/Makefile
1556 dlls/msrle32/Makefile
1557 dlls/msvcrt/Makefile
1558 dlls/msvcrt/tests/Makefile
1559 dlls/msvcrt20/Makefile
1560 dlls/msvcrt40/Makefile
1561 dlls/msvcrtd/Makefile
1562 dlls/msvcrtd/tests/Makefile
1563 dlls/msvfw32/Makefile
1564 dlls/msvidc32/Makefile
1565 dlls/mswsock/Makefile
1566 dlls/msxml3/Makefile
1567 dlls/msxml3/tests/Makefile
1568 dlls/netapi32/Makefile
1569 dlls/netapi32/tests/Makefile
1570 dlls/newdev/Makefile
1571 dlls/ntdll/Makefile
1572 dlls/ntdll/tests/Makefile
1573 dlls/objsel/Makefile
1574 dlls/odbc32/Makefile
1575 dlls/odbccp32/Makefile
1576 dlls/ole32/Makefile
1577 dlls/ole32/tests/Makefile
1578 dlls/oleacc/Makefile
1579 dlls/oleaut32/Makefile
1580 dlls/oleaut32/tests/Makefile
1581 dlls/olecli32/Makefile
1582 dlls/oledlg/Makefile
1583 dlls/olepro32/Makefile
1584 dlls/olesvr32/Makefile
1585 dlls/opengl32/Makefile
1586 dlls/powrprof/Makefile
1587 dlls/psapi/Makefile
1588 dlls/psapi/tests/Makefile
1589 dlls/qcap/Makefile
1590 dlls/quartz/Makefile
1591 dlls/quartz/tests/Makefile
1592 dlls/rasapi32/Makefile
1593 dlls/riched20/Makefile
1594 dlls/riched20/tests/Makefile
1595 dlls/richedit/Makefile
1596 dlls/rpcrt4/Makefile
1597 dlls/rpcrt4/tests/Makefile
1598 dlls/rsabase/Makefile
1599 dlls/rsabase/tests/Makefile
1600 dlls/rsaenh/Makefile
1601 dlls/rsaenh/tests/Makefile
1602 dlls/secur32/Makefile
1603 dlls/secur32/tests/Makefile
1604 dlls/security/Makefile
1605 dlls/sensapi/Makefile
1606 dlls/serialui/Makefile
1607 dlls/setupapi/Makefile
1608 dlls/setupapi/tests/Makefile
1609 dlls/sfc/Makefile
1610 dlls/shdocvw/Makefile
1611 dlls/shdocvw/tests/Makefile
1612 dlls/shell32/Makefile
1613 dlls/shell32/tests/Makefile
1614 dlls/shfolder/Makefile
1615 dlls/shlwapi/Makefile
1616 dlls/shlwapi/tests/Makefile
1617 dlls/snmpapi/Makefile
1618 dlls/stdole2.tlb/Makefile
1619 dlls/stdole32.tlb/Makefile
1620 dlls/sti/Makefile
1621 dlls/strmiids/Makefile
1622 dlls/tapi32/Makefile
1623 dlls/twain/Makefile
1624 dlls/unicows/Makefile
1625 dlls/url/Makefile
1626 dlls/urlmon/Makefile
1627 dlls/urlmon/tests/Makefile
1628 dlls/user/Makefile
1629 dlls/user/tests/Makefile
1630 dlls/usp10/Makefile
1631 dlls/usp10/tests/Makefile
1632 dlls/uuid/Makefile
1633 dlls/uxtheme/Makefile
1634 dlls/vdhcp.vxd/Makefile
1635 dlls/vdmdbg/Makefile
1636 dlls/version/Makefile
1637 dlls/version/tests/Makefile
1638 dlls/vmm.vxd/Makefile
1639 dlls/vnbt.vxd/Makefile
1640 dlls/vnetbios.vxd/Makefile
1641 dlls/vtdapi.vxd/Makefile
1642 dlls/vwin32.vxd/Makefile
1643 dlls/w32skrnl/Makefile
1644 dlls/winecrt0/Makefile
1645 dlls/wined3d/Makefile
1646 dlls/winedos/Makefile
1647 dlls/wineps/Makefile
1648 dlls/wininet/Makefile
1649 dlls/wininet/tests/Makefile
1650 dlls/winmm/Makefile
1651 dlls/winmm/joystick/Makefile
1652 dlls/winmm/mciwave/Makefile
1653 dlls/winmm/tests/Makefile
1654 dlls/winmm/wavemap/Makefile
1655 dlls/winmm/winealsa/Makefile
1656 dlls/winmm/winearts/Makefile
1657 dlls/winmm/wineaudioio/Makefile
1658 dlls/winmm/wineesd/Makefile
1659 dlls/winmm/winejack/Makefile
1660 dlls/winmm/winenas/Makefile
1661 dlls/winmm/wineoss/Makefile
1662 dlls/winnls32/Makefile
1663 dlls/winspool/Makefile
1664 dlls/winspool/tests/Makefile
1665 dlls/wintab32/Makefile
1666 dlls/wintrust/Makefile
1667 dlls/wldap32/Makefile
1668 dlls/wnaspi32/Makefile
1669 dlls/wow32/Makefile
1670 dlls/ws2_32/Makefile
1671 dlls/ws2_32/tests/Makefile
1672 dlls/wsock32/Makefile
1673 dlls/wtsapi32/Makefile
1674 dlls/x11drv/Makefile
1675 documentation/Makefile
1676 fonts/Makefile
1677 include/Makefile
1678 libs/Makefile
1679 libs/port/Makefile
1680 libs/unicode/Makefile
1681 libs/wine/Makefile
1682 libs/wpp/Makefile
1683 loader/Makefile
1684 programs/Makefile
1685 programs/clock/Makefile
1686 programs/cmdlgtst/Makefile
1687 programs/control/Makefile
1688 programs/eject/Makefile
1689 programs/expand/Makefile
1690 programs/explorer/Makefile
1691 programs/hh/Makefile
1692 programs/icinfo/Makefile
1693 programs/msiexec/Makefile
1694 programs/notepad/Makefile
1695 programs/progman/Makefile
1696 programs/regedit/Makefile
1697 programs/regsvr32/Makefile
1698 programs/rpcss/Makefile
1699 programs/rundll32/Makefile
1700 programs/start/Makefile
1701 programs/taskmgr/Makefile
1702 programs/uninstaller/Makefile
1703 programs/view/Makefile
1704 programs/wcmd/Makefile
1705 programs/wineboot/Makefile
1706 programs/winebrowser/Makefile
1707 programs/winecfg/Makefile
1708 programs/wineconsole/Makefile
1709 programs/winedbg/Makefile
1710 programs/winefile/Makefile
1711 programs/winemenubuilder/Makefile
1712 programs/winemine/Makefile
1713 programs/winepath/Makefile
1714 programs/winetest/Makefile
1715 programs/winevdm/Makefile
1716 programs/winhelp/Makefile
1717 programs/winver/Makefile
1718 programs/wordpad/Makefile
1719 server/Makefile
1720 tools/Makefile
1721 tools/widl/Makefile
1722 tools/winapi/Makefile
1723 tools/winebuild/Makefile
1724 tools/winedump/Makefile
1725 tools/winegcc/Makefile
1726 tools/wmc/Makefile
1727 tools/wrc/Makefile])
1728
1729 AC_OUTPUT
1730
1731 if test "$have_x" = "no"
1732 then
1733   echo
1734   echo "*** Warning: X development files not found. Wine will be built without"
1735   echo "*** X support, which currently does not work, and would probably not be"
1736   echo "*** what you want anyway. You will need to install devel packages of"
1737   echo "*** Xlib/Xfree86 at the very least."
1738 fi
1739
1740 if test "$wine_cv_opengl_version_OK" = "no"
1741 then
1742   echo
1743   echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
1744   echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)."
1745 fi
1746
1747 if test "$wine_cv_msg_freetype" = "yes"
1748 then
1749   echo
1750   echo "*** Note: Your system appears to have the FreeType 2 runtime libraries"
1751   echo "*** installed, but 'freetype-config' is not in your PATH. Install the"
1752   echo "*** freetype-devel package (or its equivalent on your distribution) to"
1753   echo "*** enable Wine to use TrueType fonts."
1754 fi
1755
1756 if test -z "$ALSALIBS" -a \
1757         -z "$ARTSC_LIBS" -a \
1758         -z "$AUDIOIOLIBS" -a \
1759         -z "$NASLIBS" -a \
1760         -z "$ESD_LIBS" -a \
1761         -z "$ac_cv_lib_soname_jack" -a \
1762         "$ac_cv_header_sys_soundcard_h" != "yes" -a \
1763         "$ac_cv_header_machine_soundcard_h" != "yes" -a \
1764         "$ac_cv_header_soundcard_h" != "yes"
1765 then
1766     echo "*** No sound system was found. Windows applications will be silent."
1767     echo "*** The currently supported sound systems are:"
1768     echo "*** ALSA, ARTS, EsounD, AudioIO, Jack, NAS and OSS"
1769 fi
1770
1771 echo
1772 echo "Configure finished.  Do '${ac_make} depend && ${ac_make}' to compile Wine."
1773 echo
1774
1775 dnl Local Variables:
1776 dnl comment-start: "dnl "
1777 dnl comment-end: ""
1778 dnl comment-start-skip: "\\bdnl\\b\\s *"
1779 dnl compile-command: "autoconf && autoheader"
1780 dnl End: