git.oblomov.eu Git - wine/blob - debugger/dbg.y

   1 %{
   2 /*
   3  * Parser for command lines in the Wine debugger
   4  *
   5  * Copyright 1993 Eric Youngdale
   6  * Copyright 1995 Morten Welinder
   7  * Copyright 2000 Eric Pouech
   8  *
   9  * This library is free software; you can redistribute it and/or
  10  * modify it under the terms of the GNU Lesser General Public
  11  * License as published by the Free Software Foundation; either
  12  * version 2.1 of the License, or (at your option) any later version.
  13  *
  14  * This library is distributed in the hope that it will be useful,
  15  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  16  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17  * Lesser General Public License for more details.
  18  *
  19  * You should have received a copy of the GNU Lesser General Public
  20  * License along with this library; if not, write to the Free Software
  21  * Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  22  */
  23
  24 #include "config.h"
  25
  26 #include <stdio.h>
  27 #include <stdlib.h>
  28 #include <string.h>
  29 #include <signal.h>
  30 #include <unistd.h>
  31
  32 #include "wine/exception.h"
  33 #include "debugger.h"
  34 #include "expr.h"
  35 #include "msvcrt/excpt.h"
  36
  37 extern FILE * yyin;
  38
  39 static void mode_command(int);
  40 int yylex(void);
  41 int yyerror(char *);
  42
  43 %}
  44
  45 %union
  46 {
  47     DBG_VALUE        value;
  48     char *           string;
  49     int              integer;
  50     struct list_id   listing;
  51     struct expr *    expression;
  52     struct datatype* type;
  53 }
  54
  55 %token tCONT tPASS tSTEP tLIST tNEXT tQUIT tHELP tBACKTRACE tINFO tWALK tUP tDOWN
  56 %token tENABLE tDISABLE tBREAK tWATCH tDELETE tSET tMODE tPRINT tEXAM tABORT tVM86
  57 %token tCLASS tMAPS tMODULE tSTACK tSEGMENTS tREGS tWND tQUEUE tLOCAL
  58 %token tPROCESS tTHREAD tMODREF tEOL
  59 %token tFRAME tSHARE tCOND tDISPLAY tUNDISPLAY tDISASSEMBLE
  60 %token tSTEPI tNEXTI tFINISH tSHOW tDIR tWHATIS
  61 %token <string> tPATH
  62 %token <string> tIDENTIFIER tSTRING tDEBUGSTR tINTVAR
  63 %token <integer> tNUM tFORMAT
  64 %token tSYMBOLFILE tRUN tATTACH tDETACH tNOPROCESS
  65
  66 %token tCHAR tSHORT tINT tLONG tFLOAT tDOUBLE tUNSIGNED tSIGNED
  67 %token tSTRUCT tUNION tENUM
  68
  69 /* %left ',' */
  70 /* %left '=' OP_OR_EQUAL OP_XOR_EQUAL OP_AND_EQUAL OP_SHL_EQUAL \
  71          OP_SHR_EQUAL OP_PLUS_EQUAL OP_MINUS_EQUAL \
  72          OP_TIMES_EQUAL OP_DIVIDE_EQUAL OP_MODULO_EQUAL */
  73 /* %left OP_COND */ /* ... ? ... : ... */
  74 %left OP_LOR
  75 %left OP_LAND
  76 %left '|'
  77 %left '^'
  78 %left '&'
  79 %left OP_EQ OP_NE
  80 %left '<' '>' OP_LE OP_GE
  81 %left OP_SHL OP_SHR
  82 %left '+' '-'
  83 %left '*' '/' '%'
  84 %left OP_SIGN '!' '~' OP_DEREF /* OP_INC OP_DEC OP_ADDR */
  85 %left '.' '[' OP_DRF
  86 %nonassoc ':'
  87
  88 %type <expression> expr lval lvalue
  89 %type <type> type_expr
  90 %type <value> expr_addr lval_addr
  91 %type <integer> expr_value
  92 %type <string> pathname identifier
  93
  94 %type <listing> list_arg
  95
  96 %%
  97
  98 input: line
  99     | input line
 100     ;
 101
 102 line: command
 103     | tEOL
 104     | error tEOL                { yyerrok; }
 105     ;
 106
 107 command:
 108       tQUIT tEOL                { DEBUG_ExitMode = EXIT_QUIT; return 1; }
 109     | tHELP tEOL                { DEBUG_Help(); }
 110     | tHELP tINFO tEOL          { DEBUG_HelpInfo(); }
 111     | tCONT tEOL                { DEBUG_CurrThread->exec_count = 1;
 112                                   DEBUG_CurrThread->exec_mode = EXEC_CONT; return 1; }
 113     | tPASS tEOL                { DEBUG_ExitMode = EXIT_PASS; return 1; }
 114     | tCONT tNUM tEOL           { DEBUG_CurrThread->exec_count = $2;
 115                                   DEBUG_CurrThread->exec_mode = EXEC_CONT; return 1; }
 116     | tSTEP tEOL                { DEBUG_CurrThread->exec_count = 1;
 117                                   DEBUG_CurrThread->exec_mode = EXEC_STEP_INSTR; return 1; }
 118     | tNEXT tEOL                { DEBUG_CurrThread->exec_count = 1;
 119                                   DEBUG_CurrThread->exec_mode = EXEC_STEP_OVER; return 1; }
 120     | tSTEP tNUM tEOL           { DEBUG_CurrThread->exec_count = $2;
 121                                   DEBUG_CurrThread->exec_mode = EXEC_STEP_INSTR; return 1; }
 122     | tNEXT tNUM tEOL           { DEBUG_CurrThread->exec_count = $2;
 123                                   DEBUG_CurrThread->exec_mode = EXEC_STEP_OVER; return 1; }
 124     | tSTEPI tEOL               { DEBUG_CurrThread->exec_count = 1;
 125                                   DEBUG_CurrThread->exec_mode = EXEC_STEPI_INSTR; return 1; }
 126     | tNEXTI tEOL               { DEBUG_CurrThread->exec_count = 1;
 127                                   DEBUG_CurrThread->exec_mode = EXEC_STEPI_OVER; return 1; }
 128     | tSTEPI tNUM tEOL          { DEBUG_CurrThread->exec_count = $2;
 129                                   DEBUG_CurrThread->exec_mode = EXEC_STEPI_INSTR; return 1; }
 130     | tNEXTI tNUM tEOL          { DEBUG_CurrThread->exec_count = $2;
 131                                   DEBUG_CurrThread->exec_mode = EXEC_STEPI_OVER; return 1; }
 132     | tABORT tEOL               { kill(getpid(), SIGABRT); }
 133     | tMODE tNUM tEOL           { mode_command($2); }
 134     | tMODE tVM86 tEOL          { DEBUG_CurrThread->dbg_mode = MODE_VM86; }
 135     | tENABLE tNUM tEOL         { DEBUG_EnableBreakpoint( $2, TRUE ); }
 136     | tDISABLE tNUM tEOL        { DEBUG_EnableBreakpoint( $2, FALSE ); }
 137     | tDELETE tBREAK tNUM tEOL  { DEBUG_DelBreakpoint( $3 ); }
 138     | tBACKTRACE tEOL           { DEBUG_BackTrace(DEBUG_CurrTid, TRUE); }
 139     | tBACKTRACE tNUM tEOL      { DEBUG_BackTrace($2, TRUE); }
 140     | tUP tEOL                  { DEBUG_SetFrame( curr_frame + 1 );  }
 141     | tUP tNUM tEOL             { DEBUG_SetFrame( curr_frame + $2 ); }
 142     | tDOWN tEOL                { DEBUG_SetFrame( curr_frame - 1 );  }
 143     | tDOWN tNUM tEOL           { DEBUG_SetFrame( curr_frame - $2 ); }
 144     | tFRAME tNUM tEOL          { DEBUG_SetFrame( $2 ); }
 145     | tFINISH tEOL              { DEBUG_CurrThread->exec_count = 0;
 146                                   DEBUG_CurrThread->exec_mode = EXEC_FINISH; return 1; }
 147     | tSHOW tDIR tEOL           { DEBUG_ShowDir(); }
 148     | tDIR pathname tEOL        { DEBUG_AddPath( $2 ); }
 149     | tDIR tEOL                 { DEBUG_NukePath(); }
 150     | tDISPLAY tEOL             { DEBUG_InfoDisplay(); }
 151     | tDISPLAY expr tEOL        { DEBUG_AddDisplay($2, 1, 0); }
 152     | tDISPLAY tFORMAT expr tEOL{ DEBUG_AddDisplay($3, $2 >> 8, $2 & 0xff); }
 153     | tDELETE tDISPLAY tNUM tEOL{ DEBUG_DelDisplay( $3 ); }
 154     | tDELETE tDISPLAY tEOL     { DEBUG_DelDisplay( -1 ); }
 155     | tUNDISPLAY tNUM tEOL      { DEBUG_DelDisplay( $2 ); }
 156     | tUNDISPLAY tEOL           { DEBUG_DelDisplay( -1 ); }
 157     | tCOND tNUM tEOL           { DEBUG_AddBPCondition($2, NULL); }
 158     | tCOND tNUM expr tEOL      { DEBUG_AddBPCondition($2, $3); }
 159     | tSYMBOLFILE pathname tEOL { DEBUG_ReadSymbolTable($2); }
 160     | tWHATIS expr_addr tEOL    { DEBUG_PrintType(&$2); DEBUG_FreeExprMem(); }
 161     | tATTACH tNUM tEOL         { if (DEBUG_Attach($2, FALSE)) return 1; }
 162     | tDETACH tEOL              { DEBUG_ExitMode = EXIT_DETACH; return 1; }
 163     | list_command
 164     | disassemble_command
 165     | set_command
 166     | x_command
 167     | print_command
 168     | break_command
 169     | watch_command
 170     | info_command
 171     | walk_command
 172     | run_command
 173     | noprocess_state
 174     ;
 175
 176 set_command:
 177       tSET lval_addr '=' expr_value tEOL { DEBUG_WriteMemory(&$2,$4); DEBUG_FreeExprMem(); }
 178     | tSET '+' tIDENTIFIER tEOL {DEBUG_DbgChannel(TRUE, NULL, $3);}
 179     | tSET '-' tIDENTIFIER tEOL {DEBUG_DbgChannel(FALSE, NULL, $3);}
 180     | tSET tIDENTIFIER '+' tIDENTIFIER tEOL {DEBUG_DbgChannel(TRUE, $2, $4);}
 181     | tSET tIDENTIFIER '-' tIDENTIFIER tEOL {DEBUG_DbgChannel(FALSE, $2, $4);}
 182     ;
 183
 184 pathname:
 185       tIDENTIFIER              { $$ = $1; }
 186     | tPATH                    { $$ = $1; }
 187     ;
 188
 189 disassemble_command:
 190       tDISASSEMBLE tEOL              { DEBUG_Disassemble( NULL, NULL, 10 ); }
 191     | tDISASSEMBLE expr_addr tEOL    { DEBUG_Disassemble( & $2, NULL, 10 ); }
 192     | tDISASSEMBLE expr_addr ',' expr_addr tEOL { DEBUG_Disassemble( & $2, & $4, 0 ); }
 193     ;
 194
 195 list_command:
 196       tLIST tEOL               { DEBUG_List( NULL, NULL, 10 ); }
 197     | tLIST '-' tEOL           { DEBUG_List( NULL, NULL, -10 ); }
 198     | tLIST list_arg tEOL      { DEBUG_List( & $2, NULL, 10 ); }
 199     | tLIST ',' list_arg tEOL  { DEBUG_List( NULL, & $3, -10 ); }
 200     | tLIST list_arg ',' list_arg tEOL { DEBUG_List( & $2, & $4, 0 ); }
 201     ;
 202
 203 list_arg:
 204       tNUM                     { $$.sourcefile = NULL; $$.line = $1; }
 205     | pathname ':' tNUM        { $$.sourcefile = $1; $$.line = $3; }
 206     | tIDENTIFIER              { DEBUG_GetFuncInfo( & $$, NULL, $1); }
 207     | pathname ':' tIDENTIFIER { DEBUG_GetFuncInfo( & $$, $1, $3); }
 208     | '*' expr_addr            { DEBUG_FindNearestSymbol( & $2.addr, FALSE, NULL, 0, & $$ );
 209                                  DEBUG_FreeExprMem(); }
 210     ;
 211
 212 x_command:
 213       tEXAM expr_addr tEOL     { DEBUG_ExamineMemory( &$2, 1, 'x'); DEBUG_FreeExprMem(); }
 214     | tEXAM tFORMAT expr_addr tEOL  { DEBUG_ExamineMemory( &$3, $2>>8, $2&0xff );
 215                                       DEBUG_FreeExprMem(); }
 216     ;
 217
 218 print_command:
 219       tPRINT expr_addr tEOL    { DEBUG_Print( &$2, 1, 0, 0 ); DEBUG_FreeExprMem(); }
 220     | tPRINT tFORMAT expr_addr tEOL { DEBUG_Print( &$3, $2 >> 8, $2 & 0xff, 0 );
 221                                       DEBUG_FreeExprMem(); }
 222     ;
 223
 224 break_command:
 225       tBREAK '*' expr_addr tEOL{ DEBUG_AddBreakpoint( &$3, NULL ); DEBUG_FreeExprMem(); }
 226     | tBREAK identifier tEOL   { DEBUG_AddBreakpointFromId($2, -1); }
 227     | tBREAK identifier ':' tNUM tEOL  { DEBUG_AddBreakpointFromId($2, $4); }
 228     | tBREAK tNUM tEOL         { DEBUG_AddBreakpointFromLineno($2); }
 229     | tBREAK tEOL              { DEBUG_AddBreakpointFromLineno(-1); }
 230     ;
 231
 232 watch_command:
 233       tWATCH '*' expr_addr tEOL { DEBUG_AddWatchpoint( &$3, 1 ); DEBUG_FreeExprMem(); }
 234     | tWATCH identifier tEOL    { DEBUG_AddWatchpointFromId($2); }
 235     ;
 236
 237 info_command:
 238       tINFO tBREAK tEOL         { DEBUG_InfoBreakpoints(); }
 239     | tINFO tCLASS tSTRING tEOL { DEBUG_InfoClass( $3 ); }
 240     | tINFO tSHARE tEOL         { DEBUG_InfoShare(); }
 241     | tINFO tMODULE expr_value tEOL   { DEBUG_DumpModule( $3 ); DEBUG_FreeExprMem(); }
 242     | tINFO tQUEUE expr_value tEOL    { DEBUG_DumpQueue( $3 ); DEBUG_FreeExprMem(); }
 243     | tINFO tREGS tEOL          { DEBUG_InfoRegisters(); }
 244     | tINFO tSEGMENTS expr_value tEOL { DEBUG_InfoSegments( $3, 1 ); DEBUG_FreeExprMem(); }
 245     | tINFO tSEGMENTS tEOL      { DEBUG_InfoSegments( 0, -1 ); }
 246     | tINFO tSTACK tEOL         { DEBUG_InfoStack(); }
 247     | tINFO tMAPS tEOL          { DEBUG_InfoVirtual(); }
 248     | tINFO tWND expr_value tEOL{ DEBUG_InfoWindow( (HWND)$3 ); DEBUG_FreeExprMem(); }
 249     | tINFO tLOCAL tEOL         { DEBUG_InfoLocals(); }
 250     | tINFO tDISPLAY tEOL       { DEBUG_InfoDisplay(); }
 251     ;
 252
 253 walk_command:
 254       tWALK tCLASS tEOL         { DEBUG_WalkClasses(); }
 255     | tWALK tMODULE tEOL        { DEBUG_WalkModules(); }
 256     | tWALK tQUEUE tEOL         { DEBUG_WalkQueues(); }
 257     | tWALK tWND tEOL           { DEBUG_WalkWindows( 0, 0 ); }
 258     | tWALK tWND tNUM tEOL      { DEBUG_WalkWindows( (HWND)$3, 0 ); }
 259     | tWALK tPROCESS tEOL       { DEBUG_WalkProcess(); }
 260     | tWALK tTHREAD tEOL        { DEBUG_WalkThreads(); }
 261     | tWALK tMODREF expr_value tEOL   { DEBUG_WalkModref( $3 ); DEBUG_FreeExprMem(); }
 262     ;
 263
 264 run_command:
 265       tRUN tEOL                 { DEBUG_Run(NULL); }
 266     | tRUN tSTRING tEOL         { DEBUG_Run($2); }
 267     ;
 268
 269 noprocess_state:
 270       tNOPROCESS tEOL           {} /* <CR> shall not barf anything */
 271     | tNOPROCESS tSTRING tEOL   { DEBUG_Printf(DBG_CHN_MESG, "No process loaded, cannot execute '%s'\n", $2); }
 272     ;
 273
 274 type_expr:
 275       type_expr '*'             { $$ = $1 ? DEBUG_FindOrMakePointerType($1) : NULL; }
 276     | tINT                      { $$ = DEBUG_GetBasicType(DT_BASIC_INT); }
 277     | tCHAR                     { $$ = DEBUG_GetBasicType(DT_BASIC_CHAR); }
 278     | tLONG tINT                { $$ = DEBUG_GetBasicType(DT_BASIC_LONGINT); }
 279     | tUNSIGNED tINT            { $$ = DEBUG_GetBasicType(DT_BASIC_UINT); }
 280     | tLONG tUNSIGNED tINT      { $$ = DEBUG_GetBasicType(DT_BASIC_ULONGINT); }
 281     | tLONG tLONG tINT          { $$ = DEBUG_GetBasicType(DT_BASIC_LONGLONGINT); }
 282     | tLONG tLONG tUNSIGNED tINT{ $$ = DEBUG_GetBasicType(DT_BASIC_ULONGLONGINT); }
 283     | tSHORT tINT               { $$ = DEBUG_GetBasicType(DT_BASIC_SHORTINT); }
 284     | tSHORT tUNSIGNED tINT     { $$ = DEBUG_GetBasicType(DT_BASIC_USHORTINT); }
 285     | tSIGNED tCHAR             { $$ = DEBUG_GetBasicType(DT_BASIC_SCHAR); }
 286     | tUNSIGNED tCHAR           { $$ = DEBUG_GetBasicType(DT_BASIC_UCHAR); }
 287     | tFLOAT                    { $$ = DEBUG_GetBasicType(DT_BASIC_FLOAT); }
 288     | tDOUBLE                   { $$ = DEBUG_GetBasicType(DT_BASIC_DOUBLE); }
 289     | tLONG tDOUBLE             { $$ = DEBUG_GetBasicType(DT_BASIC_LONGDOUBLE); }
 290     | tSTRUCT tIDENTIFIER       { $$ = DEBUG_TypeCast(DT_STRUCT, $2); }
 291     | tUNION tIDENTIFIER        { $$ = DEBUG_TypeCast(DT_STRUCT, $2); }
 292     | tENUM tIDENTIFIER         { $$ = DEBUG_TypeCast(DT_ENUM, $2); }
 293     ;
 294
 295 expr_addr: expr                 { $$ = DEBUG_EvalExpr($1); }
 296     ;
 297
 298 expr_value: expr                { DBG_VALUE value = DEBUG_EvalExpr($1);
 299                                   /* expr_value is typed as an integer */
 300                                   $$ = DEBUG_ReadMemory(&value); }
 301     ;
 302
 303 /*
 304  * The expr rule builds an expression tree.  When we are done, we call
 305  * EvalExpr to evaluate the value of the expression.  The advantage of
 306  * the two-step approach is that it is possible to save expressions for
 307  * use in 'display' commands, and in conditional watchpoints.
 308  */
 309 expr:
 310       tNUM                       { $$ = DEBUG_ConstExpr($1); }
 311     | tSTRING                    { $$ = DEBUG_StringExpr($1); }
 312     | tINTVAR                    { $$ = DEBUG_IntVarExpr($1); }
 313     | tIDENTIFIER                { $$ = DEBUG_SymbolExpr($1); }
 314     | expr OP_DRF tIDENTIFIER    { $$ = DEBUG_StructPExpr($1, $3); }
 315     | expr '.' tIDENTIFIER       { $$ = DEBUG_StructExpr($1, $3); }
 316     | tIDENTIFIER '(' ')'        { $$ = DEBUG_CallExpr($1, 0); }
 317     | tIDENTIFIER '(' expr ')'   { $$ = DEBUG_CallExpr($1, 1, $3); }
 318     | tIDENTIFIER '(' expr ',' expr ')'  { $$ = DEBUG_CallExpr($1, 2, $3, $5); }
 319     | tIDENTIFIER '(' expr ',' expr ',' expr ')'         { $$ = DEBUG_CallExpr($1, 3, $3, $5, $7); }
 320     | tIDENTIFIER '(' expr ',' expr ',' expr ',' expr ')'        { $$ = DEBUG_CallExpr($1, 4, $3, $5, $7, $9); }
 321     | tIDENTIFIER '(' expr ',' expr ',' expr ',' expr ',' expr ')'       { $$ = DEBUG_CallExpr($1, 5, $3, $5, $7, $9, $11); }
 322     | expr '[' expr ']'          { $$ = DEBUG_BinopExpr(EXP_OP_ARR, $1, $3); }
 323     | expr ':' expr              { $$ = DEBUG_BinopExpr(EXP_OP_SEG, $1, $3); }
 324     | expr OP_LOR expr           { $$ = DEBUG_BinopExpr(EXP_OP_LOR, $1, $3); }
 325     | expr OP_LAND expr          { $$ = DEBUG_BinopExpr(EXP_OP_LAND, $1, $3); }
 326     | expr '|' expr              { $$ = DEBUG_BinopExpr(EXP_OP_OR, $1, $3); }
 327     | expr '&' expr              { $$ = DEBUG_BinopExpr(EXP_OP_AND, $1, $3); }
 328     | expr '^' expr              { $$ = DEBUG_BinopExpr(EXP_OP_XOR, $1, $3); }
 329     | expr OP_EQ expr            { $$ = DEBUG_BinopExpr(EXP_OP_EQ, $1, $3); }
 330     | expr '>' expr              { $$ = DEBUG_BinopExpr(EXP_OP_GT, $1, $3); }
 331     | expr '<' expr              { $$ = DEBUG_BinopExpr(EXP_OP_LT, $1, $3); }
 332     | expr OP_GE expr            { $$ = DEBUG_BinopExpr(EXP_OP_GE, $1, $3); }
 333     | expr OP_LE expr            { $$ = DEBUG_BinopExpr(EXP_OP_LE, $1, $3); }
 334     | expr OP_NE expr            { $$ = DEBUG_BinopExpr(EXP_OP_NE, $1, $3); }
 335     | expr OP_SHL expr           { $$ = DEBUG_BinopExpr(EXP_OP_SHL, $1, $3); }
 336     | expr OP_SHR expr           { $$ = DEBUG_BinopExpr(EXP_OP_SHR, $1, $3); }
 337     | expr '+' expr              { $$ = DEBUG_BinopExpr(EXP_OP_ADD, $1, $3); }
 338     | expr '-' expr              { $$ = DEBUG_BinopExpr(EXP_OP_SUB, $1, $3); }
 339     | expr '*' expr              { $$ = DEBUG_BinopExpr(EXP_OP_MUL, $1, $3); }
 340     | expr '/' expr              { $$ = DEBUG_BinopExpr(EXP_OP_DIV, $1, $3); }
 341     | expr '%' expr              { $$ = DEBUG_BinopExpr(EXP_OP_REM, $1, $3); }
 342     | '-' expr %prec OP_SIGN     { $$ = DEBUG_UnopExpr(EXP_OP_NEG, $2); }
 343     | '+' expr %prec OP_SIGN     { $$ = $2; }
 344     | '!' expr                   { $$ = DEBUG_UnopExpr(EXP_OP_NOT, $2); }
 345     | '~' expr                   { $$ = DEBUG_UnopExpr(EXP_OP_LNOT, $2); }
 346     | '(' expr ')'               { $$ = $2; }
 347     | '*' expr %prec OP_DEREF    { $$ = DEBUG_UnopExpr(EXP_OP_DEREF, $2); }
 348     | '&' expr %prec OP_DEREF    { $$ = DEBUG_UnopExpr(EXP_OP_ADDR, $2); }
 349     | '(' type_expr ')' expr %prec OP_DEREF { $$ = DEBUG_TypeCastExpr($2, $4); }
 350     ;
 351
 352 /*
 353  * The lvalue rule builds an expression tree.  This is a limited form
 354  * of expression that is suitable to be used as an lvalue.
 355  */
 356 lval_addr: lval                  { $$ = DEBUG_EvalExpr($1); }
 357     ;
 358
 359 lval: lvalue                     { $$ = $1; }
 360     | '*' expr                   { $$ = DEBUG_UnopExpr(EXP_OP_FORCE_DEREF, $2); }
 361     ;
 362
 363 lvalue: tNUM                     { $$ = DEBUG_ConstExpr($1); }
 364     | tINTVAR                    { $$ = DEBUG_IntVarExpr($1); }
 365     | tIDENTIFIER                { $$ = DEBUG_SymbolExpr($1); }
 366     | lvalue OP_DRF tIDENTIFIER  { $$ = DEBUG_StructPExpr($1, $3); }
 367     | lvalue '.' tIDENTIFIER     { $$ = DEBUG_StructExpr($1, $3); }
 368     | lvalue '[' expr ']'        { $$ = DEBUG_BinopExpr(EXP_OP_ARR, $1, $3); }
 369     ;
 370
 371 identifier: tIDENTIFIER          { $$ = $1; }
 372     | identifier '.' tIDENTIFIER { char* ptr = DBG_alloc(strlen($1) + 1 + strlen($3)+ 1);
 373                                    sprintf(ptr, "%s.%s", $1, $3); $$ = DEBUG_MakeSymbol(ptr);
 374                                    DBG_free(ptr); }
 375     | identifier ':' ':' tIDENTIFIER { char* ptr = DBG_alloc(strlen($1) + 2 + strlen($4) + 1);
 376                                    sprintf(ptr, "%s::%s", $1, $4); $$ = DEBUG_MakeSymbol(ptr);
 377                                    DBG_free(ptr); }
 378     ;
 379
 380 %%
 381
 382 static void mode_command(int newmode)
 383 {
 384     switch(newmode)
 385     {
 386     case 16: DEBUG_CurrThread->dbg_mode = MODE_16; break;
 387     case 32: DEBUG_CurrThread->dbg_mode = MODE_32; break;
 388     default: DEBUG_Printf(DBG_CHN_MESG,"Invalid mode (use 16, 32 or vm86)\n");
 389     }
 390 }
 391
 392 void DEBUG_Exit(DWORD ec)
 393 {
 394    ExitProcess(ec);
 395 }
 396
 397 static WINE_EXCEPTION_FILTER(wine_dbg_cmd)
 398 {
 399    DEBUG_Printf(DBG_CHN_MESG, "\nwine_dbg_cmd: ");
 400    switch (GetExceptionCode()) {
 401    case DEBUG_STATUS_INTERNAL_ERROR:
 402       DEBUG_Printf(DBG_CHN_MESG, "WineDbg internal error\n");
 403       break;
 404    case DEBUG_STATUS_NO_SYMBOL:
 405       DEBUG_Printf(DBG_CHN_MESG, "Undefined symbol\n");
 406       break;
 407    case DEBUG_STATUS_DIV_BY_ZERO:
 408       DEBUG_Printf(DBG_CHN_MESG, "Division by zero\n");
 409       break;
 410    case DEBUG_STATUS_BAD_TYPE:
 411       DEBUG_Printf(DBG_CHN_MESG, "No type or type mismatch\n");
 412       break;
 413    case DEBUG_STATUS_NO_FIELD:
 414       DEBUG_Printf(DBG_CHN_MESG, "No such field in structure or union\n");
 415       break;
 416    default:
 417       DEBUG_Printf(DBG_CHN_MESG, "Exception %lx\n", GetExceptionCode());
 418       break;
 419    }
 420
 421    return EXCEPTION_EXECUTE_HANDLER;
 422 }
 423
 424 /***********************************************************************
 425  *           DEBUG_Parser
 426  *
 427  * Debugger editline parser
 428  */
 429 void    DEBUG_Parser(void)
 430 {
 431     BOOL                ret_ok;
 432 #ifdef YYDEBUG
 433     yydebug = 0;
 434 #endif
 435     yyin = stdin;
 436
 437     DEBUG_ExitMode = EXIT_CONTINUE;
 438
 439     ret_ok = FALSE;
 440     do {
 441        __TRY {
 442           ret_ok = TRUE;
 443           yyparse();
 444        } __EXCEPT(wine_dbg_cmd) {
 445           ret_ok = FALSE;
 446        }
 447        __ENDTRY;
 448        DEBUG_FlushSymbols();
 449     } while (!ret_ok);
 450 }
 451
 452 int yyerror(char* s)
 453 {
 454    DEBUG_Printf(DBG_CHN_MESG, "%s\n", s);
 455    return 0;
 456 }