git.oblomov.eu Git - wine/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Author: Michael Patra   <micky@marie.physik.tu-berlin.de>
   3 dnl                         <patra@itp1.physik.tu-berlin.de>
   4 dnl Ported to autoconf 2.5x by bero@redhat.com
   5 AC_REVISION([configure.in 1.00])
   6 AC_INIT(controls/edit.c)
   7 AC_CONFIG_HEADER(include/config.h)
   8 AC_CONFIG_AUX_DIR(tools)
   9
  10 dnl **** Command-line arguments ****
  11
  12 dnl Default values
  13 LIBEXT=so       # library type .so or .a
  14 TRACE_MSGS=yes  # the TRACE() macro
  15 DEBUG_MSGS=yes  # the TRACE(), WARN(), and FIXME() macros.
  16 CURSES=yes
  17 OPENGL=normal
  18
  19 AC_ARG_ENABLE(debug,
  20 [  --disable-debug         compile out all debugging messages],
  21 [if test "$enableval" = "no"; then DEBUG_MSGS="no"; fi])
  22
  23 AC_ARG_ENABLE(opengl,
  24 [  --enable-opengl         force usage of OpenGL even if the latter is thread-safe via pthread],
  25 [if test "$enableval" = "no"; then OPENGL="no"; elif test "$enableval" = "yes"; then OPENGL="yes"; fi])
  26
  27 AC_ARG_ENABLE(trace,
  28 [  --disable-trace         compile out TRACE messages],
  29 [if test "$enableval" = "no"; then TRACE_MSGS="no"; fi])
  30
  31 AC_ARG_WITH(curses,
  32 [  --without-curses        do not use curses],
  33 [if test "$withval" = "no"; then CURSES="no"; fi])
  34
  35 AC_ARG_WITH(reentrant-x,
  36 [  --without-reentrant-x   compile for use with non-reentrant X libraries])
  37
  38 AC_SUBST(OPTIONS)
  39
  40 if test "$DEBUG_MSGS" = "no"
  41 then
  42     OPTIONS="$OPTIONS -DNO_DEBUG_MSGS"
  43 fi
  44
  45 if test "$TRACE_MSGS" = "no" -o "$DEBUG_MSGS" = "no"
  46 then
  47     OPTIONS="$OPTIONS -DNO_TRACE_MSGS"
  48 fi
  49
  50 dnl **** Check for some programs ****
  51
  52 AC_PROG_MAKE_SET
  53 AC_PROG_CC
  54 AC_PROG_CPP
  55 AC_PATH_XTRA
  56 AC_PROG_YACC
  57 AC_PROG_LEX
  58
  59 dnl **** Just additional warning checks, since AC_PROG just sets 'yacc' even
  60 dnl **** without one present.
  61 AC_CHECK_PROGS(XYACC,$YACC bison yacc,none)
  62 if test "$XYACC" = "none"
  63 then
  64         echo "*** Error: No suitable bison/yacc found. ***"
  65         echo "    Please install the 'bison' package."
  66         exit 1
  67 fi
  68 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
  69 if test "$XLEX" = "none"
  70 then
  71         echo "*** Error: No suitable lex found. ***"
  72         echo "    Please install the 'flex' package."
  73         exit 1
  74 fi
  75 AC_PROG_RANLIB
  76 AC_PROG_INSTALL
  77 AC_PROG_LN_S
  78 AC_CHECK_PROG(C2MAN,c2man,c2man,\$(TOPSRCDIR)/tools/c2man.pl)
  79 AC_PATH_PROG(LDCONFIG, ldconfig, true, /sbin:/usr/sbin:$PATH)
  80 AC_CYGWIN
  81 AC_CHECK_PROG(DLLWRAP,dllwrap,dllwrap,false)
  82
  83 dnl Check for lint
  84 AC_CHECK_PROGS(LINT, lclint lint)
  85 if test "$LINT" = "lint"
  86 then
  87   LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
  88   dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
  89 fi
  90 AC_SUBST(LINT)
  91 AC_SUBST(LINTFLAGS)
  92
  93 if test "$CYGWIN" = "yes"
  94 then
  95     LDCOMBINE="ld -r --enable-stdcall-fixup"
  96 else
  97     LDCOMBINE="ld -r"
  98 fi
  99 AC_SUBST(LDCOMBINE)
 100
 101 dnl **** Check for some libraries ****
 102
 103 dnl Check for -lm
 104 AC_CHECK_LIB(m,sqrt)
 105 dnl Check for -li386 for NetBSD and OpenBSD
 106 AC_CHECK_LIB(i386,i386_set_ldt)
 107 dnl Check for -lossaudio for NetBSD
 108 AC_CHECK_LIB(ossaudio,_oss_ioctl)
 109 dnl Check for -lw for Solaris
 110 AC_CHECK_FUNCS(iswalnum,,AC_CHECK_LIB(w,iswalnum))
 111 dnl Check for -lnsl for Solaris
 112 AC_CHECK_FUNCS(gethostbyname,,AC_CHECK_LIB(nsl,gethostbyname))
 113 dnl Check for -lsocket for Solaris
 114 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
 115 dnl Check for -lxpg4 for FreeBSD
 116 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
 117 dnl Check for -lmmap for OS/2
 118 AC_CHECK_LIB(mmap,mmap)
 119
 120 dnl Check for openpty
 121 UTILLIBS=""
 122 AC_SUBST(UTILLIBS)
 123 AC_CHECK_FUNCS(openpty,,
 124         [AC_CHECK_LIB(util,openpty,
 125                 [AC_DEFINE(HAVE_OPENPTY)
 126                 UTILLIBS="-lutil"]
 127         )])
 128
 129 DLLIBS=""
 130 AC_SUBST(DLLIBS)
 131 AC_CHECK_HEADERS(dlfcn.h,
 132     [AC_CHECK_FUNCS(dlopen,,
 133         [AC_CHECK_LIB(dl,dlopen,
 134                      [AC_DEFINE(HAVE_DLOPEN,1,[Define if you have dlopen])
 135                      DLLIBS="-ldl"],
 136                      LIBEXT="a")]
 137         )],
 138         LIBEXT="a"
 139     )
 140
 141 JPEGLIB=""
 142 AC_SUBST(JPEGLIB)
 143 AC_CHECK_HEADERS(jpeglib.h,
 144     AC_CHECK_LIB(jpeg,jpeg_start_decompress,
 145         AC_DEFINE(HAVE_LIBJPEG,1,[Define if you have libjpeg including devel headers])
 146         JPEGLIB="-ljpeg"
 147     )
 148 )
 149
 150
 151 AC_SUBST(XLIB)
 152 AC_SUBST(XFILES)
 153 XFILES=""
 154 AC_SUBST(OPENGLFILES)
 155 OPENGLFILES=""
 156 AC_SUBST(GLU32FILES)
 157 GLU32FILES=""
 158 if test "$have_x" = "yes"
 159 then
 160     XLIB="-lXext -lX11"
 161     ac_save_CPPFLAGS="$CPPFLAGS"
 162     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 163
 164     dnl *** All of the following tests require X11/Xlib.h
 165     AC_CHECK_HEADERS(X11/Xlib.h,
 166       [
 167         dnl *** Check for X keyboard extension
 168         AC_CHECK_HEADERS(X11/XKBlib.h,
 169             [ dnl *** If X11/XKBlib.h exists...
 170               AC_CHECK_LIB(X11, XkbQueryExtension,
 171               AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
 172               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 173             ],
 174             AC_MSG_WARN([XKB extension not found!!])
 175         )
 176
 177         dnl *** Check for X Shm extension
 178         AC_CHECK_HEADERS(X11/extensions/XShm.h,
 179             [ dnl *** If X11/extensions/XShm.h exists...
 180               AC_CHECK_LIB(Xext, XShmQueryExtension,
 181               AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
 182               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 183             ],
 184             AC_MSG_WARN([Xshm extension not found!!])
 185         )
 186
 187         dnl *** Check for X shape extension
 188         AC_CHECK_HEADERS(X11/extensions/shape.h,
 189             [ dnl *** If X11/extensions/shape.h exists...
 190               AC_CHECK_LIB(Xext,XShapeQueryExtension,
 191               AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
 192               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 193             ],
 194             AC_MSG_WARN([XShape extension not found!!])
 195         )
 196
 197         dnl *** Check for XFree86 DGA / DGA 2.0 extension
 198         AC_CHECK_HEADERS(X11/extensions/xf86dga.h,
 199             [ dnl *** If X11/extensions/xf86dga.h exists, check
 200               dnl *** for XDGAQueryExtension()...
 201               AC_CHECK_LIB(Xxf86dga, XDGAQueryExtension,
 202                 [ dnl *** If found...
 203                   AC_DEFINE(HAVE_LIBXXF86DGA2, 1,
 204                             [Define if you have the Xxf86dga library version 2])
 205                   X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
 206                ],
 207                 [ dnl *** If not found, look for XF86DGAQueryExtension()
 208                   dnl *** instead (DGA 2.0 not found)...
 209                   AC_CHECK_LIB(Xxf86dga, XF86DGAQueryExtension,
 210                     [ AC_DEFINE(HAVE_LIBXXF86DGA, 1,
 211                                 [Define if you have the Xxf86dga library version 1])
 212                       X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
 213                     ],,
 214                     $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 215                   )
 216                 ],
 217                 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 218               )
 219             ],
 220             AC_MSG_WARN([DGA extension not found!!])
 221         )
 222
 223         dnl *** Check for XFree86 VMODE extension
 224         AC_CHECK_HEADERS(X11/extensions/xf86vmode.h,
 225             [ dnl *** If X11/extensions/xf86vmode.h exists...
 226                 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
 227                   [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
 228                      X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
 229                   ],,
 230                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 231                 )
 232             ],
 233             AC_MSG_WARN([XFree86 VMODE extension not found!!])
 234         )
 235
 236         dnl *** Check for XVideo extension supporting XvImages
 237         AC_CHECK_HEADERS(X11/extensions/Xvlib.h,
 238             [ dnl *** If X11/extensions/Xvlib.h exists...
 239                 AC_CHECK_LIB(Xv, XvShmCreateImage,
 240                   [ AC_DEFINE(HAVE_XVIDEO, 1, [Define if the X libraries support XVideo])
 241                      X_PRE_LIBS="$X_PRE_LIBS -lXv"
 242                   ],,
 243                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 244                 )
 245             ],
 246             AC_MSG_WARN([XVideo extension not found !!])
 247         )
 248
 249         dnl *** Check for XRender extension
 250         AC_CHECK_HEADERS(X11/extensions/Xrender.h,
 251             [ dnl *** If X11/extensions/Xrender.h exists...
 252                 AC_CHECK_LIB(Xrender, XRenderQueryExtension,
 253                   [ AC_DEFINE(HAVE_LIBXRENDER, 1, [Define if you have the XRender extension library])
 254                      X_PRE_LIBS="$X_PRE_LIBS -lXrender"
 255                   ],,
 256                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 257                 )
 258             ],
 259             AC_MSG_WARN([XRender extension not found !!])
 260         )
 261
 262       ]
 263     ) dnl *** End of X11/Xlib.h check
 264
 265     dnl Check for the presence of OpenGL
 266     if test $OPENGL = "yes" -o $OPENGL = "normal"
 267     then
 268         if test -e /usr/X11R6/lib/libGL.a -a ! -e /usr/X11R6/lib/libGL.so
 269         then
 270             AC_MSG_ERROR([/usr/X11R6/lib/libGL.a is present on your system.
 271 This prevents linking to OpenGL. Delete the file and restart configure.])
 272         fi
 273
 274         AC_CHECK_HEADERS(GL/gl.h GL/glx.h GL/glext.h)
 275         if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
 276         then
 277             dnl Check for some problems due to old Mesa versions
 278             AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_version_OK,
 279               AC_TRY_COMPILE(
 280                 [#include <GL/gl.h>],
 281                 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
 282                 [wine_cv_opengl_version_OK="yes"],
 283                 [wine_cv_opengl_version_OK="no"]
 284               )
 285             )
 286
 287             dnl Check for the thread-safety of the OpenGL library
 288             AC_CACHE_CHECK([for thread-safe OpenGL version],
 289                            wine_cv_opengl_version_threadsafe,
 290               [saved_libs=$LIBS
 291                LIBS="$X_LIBS -lGL"
 292                AC_TRY_LINK([],[pthread_getspecific();],
 293                               [wine_cv_opengl_version_threadsafe="yes"],
 294                               [wine_cv_opengl_version_threadsafe="no"])
 295                LIBS=$saved_libs]
 296             )
 297
 298             if test "$wine_cv_opengl_version_OK" = "yes" -a \( "$wine_cv_opengl_version_threadsafe" = "no" -o $OPENGL = "yes" \)
 299             then
 300                 dnl Check for the presence of the library
 301                 AC_CHECK_LIB(GL,glXCreateContext,
 302                              X_PRE_LIBS="$X_PRE_LIBS -lGL"
 303                              ,,
 304                              $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 305
 306                 if test "$ac_cv_lib_GL_glXCreateContext" = "yes"
 307                 then
 308                         OPENGLFILES='$(OPENGLFILES)'
 309                         AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])
 310
 311                         AC_CHECK_LIB(GL,glXGetProcAddressARB,
 312                                      AC_DEFINE(HAVE_GLX_GETPROCADDRESS, 1,
 313                                                [Define if the OpenGL library supports the glXGetProcAddressARB call]),,
 314                                      $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 315
 316                         if test "$ac_cv_lib_GL_glXGetProcAddressARB" = "yes"
 317                         then
 318                                AC_CACHE_CHECK([for OpenGL extension functions prototypes], wine_cv_extension_prototypes,
 319                                   [AC_TRY_COMPILE([#include <GL/gl.h>
 320                                                   #ifdef HAVE_GL_GLEXT_H
 321                                                   # include <GL/glext.h>
 322                                                   #endif
 323                                                   ],
 324                                                  [PFNGLCOLORTABLEEXTPROC test_proc;],
 325                                                  [wine_cv_extension_prototypes="yes"],
 326                                                  [wine_cv_extension_prototypes="no"]
 327                                   )]
 328                                 )
 329                                 if test "$wine_cv_extension_prototypes" = "yes"
 330                                 then
 331                                     AC_DEFINE(HAVE_GLEXT_PROTOTYPES, 1,
 332                                               [Define if the OpenGL headers define extension typedefs])
 333                                 fi
 334                         fi
 335
 336                 fi
 337                 dnl Check for GLU32 library.
 338                 AC_CHECK_LIB(GLU,gluLookAt,
 339                              [X_PRE_LIBS="$X_PRE_LIBS -lGLU"
 340                              GLU32FILES='$(GLU32FILES)']
 341                              ,,
 342                              $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
 343                 )
 344              fi
 345          fi
 346     fi
 347
 348     CPPFLAGS="$ac_save_CPPFLAGS"
 349     XFILES='$(XFILES)'
 350 else
 351     XLIB=""
 352     X_CFLAGS=""
 353     X_LIBS=""
 354 fi
 355
 356 dnl **** Check which curses lib to use ***
 357 CURSESLIBS=""
 358 if test "$CURSES" = "yes"
 359 then
 360     AC_CHECK_HEADERS(ncurses.h,
 361         [AC_CHECK_LIB(ncurses,waddch,
 362             [AC_DEFINE(HAVE_LIBNCURSES, 1, [Define if you have the ncurses library (-lncurses)])
 363              CURSESLIBS="-lncurses"],
 364              [AC_CHECK_HEADERS(curses.h,
 365                  [AC_CHECK_LIB(curses,waddch,
 366                      [AC_DEFINE(HAVE_LIBCURSES, 1, [Define if you have the curses library (-lcurses)])
 367                       CURSESLIBS="-lcurses"])])])])
 368     saved_libs="$LIBS"
 369     LIBS="$CURSESLIBS $LIBS"
 370     AC_CHECK_FUNCS(getbkgd resizeterm)
 371     LIBS="$saved_libs"
 372 fi
 373 AC_SUBST(CURSESLIBS)
 374
 375 CUPSLIBS=""
 376 dnl **** Check for CUPS ****
 377 wine_cv_warn_cups_h=no
 378 AC_CHECK_LIB(cups,cupsGetPPD,
 379         [AC_CHECK_HEADER(cups/cups.h,
 380             [AC_DEFINE(HAVE_CUPS, 1, [Define if we have CUPS])
 381             CUPSLIBS="-lcups"],
 382             wine_cv_warn_cups_h=yes)]
 383 )
 384 AC_SUBST(CUPSLIBS)
 385
 386 dnl **** Check for FreeType 2 ****
 387 AC_CHECK_LIB(freetype,FT_Init_FreeType,ft_lib=yes,ft_lib=no,$X_LIBS)
 388 if test "$ft_lib" = "no"
 389 then
 390     FREETYPELIBS=""
 391     FREETYPEINCL=""
 392     wine_cv_msg_freetype=no
 393 else
 394     AC_CHECK_PROG(ft_devel,freetype-config,freetype-config,no)
 395     if test "$ft_devel" = "no"
 396     then
 397         AC_CHECK_PROG(ft_devel2,freetype2-config,freetype2-config,no)
 398         if test "$ft_devel2" = "freetype2-config"
 399         then
 400                 ft_devel=$ft_devel2
 401         fi
 402     fi
 403     if test "$ft_devel" = "no"
 404     then
 405         FREETYPELIBS=""
 406         FREETYPEINCL=""
 407         wine_cv_msg_freetype=yes
 408     else
 409         AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
 410         FREETYPELIBS=`$ft_devel --libs`
 411         FREETYPEINCL=`$ft_devel --cflags`
 412         ac_save_CPPFLAGS="$CPPFLAGS"
 413         CPPFLAGS="$FREETYPEINCL $CPPFLAGS"
 414         AC_CHECK_HEADERS(freetype/freetype.h \
 415                          freetype/ftglyph.h \
 416                          freetype/tttables.h \
 417                          freetype/ftnames.h \
 418                          freetype/ftsnames.h \
 419                          freetype/ttnameid.h \
 420                          freetype/ftoutln.h \
 421                          freetype/internal/sfnt.h)
 422         CPPFLAGS="$ac_save_CPPFLAGS"
 423         wine_cv_msg_freetype=no
 424     fi
 425 fi
 426 AC_SUBST(FREETYPELIBS)
 427 AC_SUBST(FREETYPEINCL)
 428
 429 dnl **** Check for parport (currently Linux only) ****
 430 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
 431  AC_TRY_COMPILE(
 432    [#include <linux/ppdev.h>],
 433    [ioctl (1,PPCLAIM,0)],
 434    [ac_cv_c_ppdev="yes"],
 435    [ac_cv_c_ppdev="no"])
 436  )
 437 if test "$ac_cv_c_ppdev" = "yes"
 438 then
 439     AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
 440 fi
 441
 442 dnl **** Check for IPX (currently Linux only) ****
 443 AC_CACHE_CHECK([for GNU style IPX support], ac_cv_c_ipx_gnu,
 444  AC_TRY_COMPILE(
 445    [#include <sys/socket.h>
 446     #include <netipx/ipx.h>],
 447    [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
 448    [ac_cv_c_ipx_gnu="yes"],
 449    [ac_cv_c_ipx_gnu="no"])
 450  )
 451 if test "$ac_cv_c_ipx_gnu" = "yes"
 452 then
 453     AC_DEFINE(HAVE_IPX_GNU, 1, [Define if IPX should use netipx/ipx.h from libc])
 454 fi
 455
 456 if test "$ac_cv_c_ipx_gnu" = "no"
 457 then
 458  AC_CACHE_CHECK([for linux style IPX support], ac_cv_c_ipx_linux,
 459   AC_TRY_COMPILE(
 460     [#include <sys/socket.h>
 461      #include <asm/types.h>
 462      #include <linux/ipx.h>],
 463     [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
 464     [ac_cv_c_ipx_linux="yes"],
 465     [ac_cv_c_ipx_linux="no"])
 466   )
 467   if test "$ac_cv_c_ipx_linux" = "yes"
 468   then
 469       AC_DEFINE(HAVE_IPX_LINUX, 1, [Define if IPX includes are taken from Linux kernel])
 470   fi
 471 fi
 472
 473 dnl **** Check for Open Sound System ****
 474 AC_CHECK_HEADERS(sys/soundcard.h machine/soundcard.h soundcard.h, break)
 475
 476 AC_CACHE_CHECK([for Open Sound System],
 477         ac_cv_c_opensoundsystem,
 478         AC_TRY_COMPILE([
 479         #if defined(HAVE_SYS_SOUNDCARD_H)
 480                 #include <sys/soundcard.h>
 481         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 482                 #include <machine/soundcard.h>
 483         #elif defined(HAVE_SOUNDCARD_H)
 484                 #include <soundcard.h>
 485         #endif
 486         ],[
 487
 488 /* check for one of the Open Sound System specific SNDCTL_ defines */
 489 #if !defined(SNDCTL_DSP_STEREO)
 490 #error No open sound system
 491 #endif
 492 ],ac_cv_c_opensoundsystem="yes",ac_cv_c_opensoundsystem="no"))
 493
 494 if test "$ac_cv_c_opensoundsystem" = "yes"
 495 then
 496     AC_DEFINE(HAVE_OSS, 1, [Define if you have the Open Sound system])
 497 fi
 498
 499 AC_CACHE_CHECK([for Open Sound System/MIDI interface],
 500         ac_cv_c_opensoundsystem_midi,
 501         AC_TRY_COMPILE([
 502         #if defined(HAVE_SYS_SOUNDCARD_H)
 503                 #include <sys/soundcard.h>
 504         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 505                 #include <machine/soundcard.h>
 506         #elif defined(HAVE_SOUNDCARD_H)
 507                 #include <soundcard.h>
 508         #endif
 509         ],[
 510
 511 /* check for one of the Open Sound System specific SNDCTL_SEQ defines */
 512 #if !defined(SNDCTL_SEQ_SYNC)
 513 #error No open sound system MIDI interface
 514 #endif
 515 ],ac_cv_c_opensoundsystem_midi="yes",ac_cv_c_opensoundsystem_midi="no"))
 516
 517 if test "$ac_cv_c_opensoundsystem_midi" = "yes"
 518 then
 519     AC_DEFINE(HAVE_OSS_MIDI, 1, [Define if you have the Open Sound system (MIDI interface)])
 520 fi
 521
 522 dnl **** If ln -s doesn't work, use cp instead ****
 523 if test "$ac_cv_prog_LN_S" = "ln -s"; then : ; else LN_S=cp ; fi
 524
 525 dnl **** Check for broken glibc mmap64 ****
 526
 527 AC_CACHE_CHECK( [whether mmap64 works defined as mmap], ac_cv_mmap64_works,
 528         AC_TRY_RUN([
 529                 #define _FILE_OFFSET_BITS 64
 530                 #include <stdio.h>
 531                 #include <unistd.h>
 532                 #include <fcntl.h>
 533                 #include <sys/mman.h>
 534                 #include <errno.h>
 535
 536                 int main(int argc,char **argv) {
 537                         int fd = open("conftest.map",O_CREAT|O_RDWR,0600);
 538                         if (fd == -1) exit(1);
 539
 540                         unlink("conftest.map");
 541
 542                         write(fd,"test",4);
 543
 544                         if ((-1 == mmap(0,4,PROT_READ|PROT_WRITE,MAP_SHARED,fd,0)) &&
 545                             (errno == EINVAL)
 546                         ) {
 547                                 exit(1);
 548                         }
 549                         close(fd);
 550                         fprintf(stderr,"success!\n");
 551                         exit(0);
 552                 }
 553
 554         ],
 555     ac_cv_mmap64_works="yes",
 556     ac_cv_mmap64_works="no",
 557     ac_cv_mmap64_works="no") )
 558
 559 if test "$ac_cv_mmap64_works" = "yes"
 560 then
 561     AC_DEFINE(_FILE_OFFSET_BITS, 64, [Set this to 64 to enable 64-bit file support on Linux])
 562 fi
 563
 564 dnl **** Check for gcc strength-reduce bug ****
 565
 566 if test "x${GCC}" = "xyes"
 567 then
 568   CFLAGS="$CFLAGS -Wall"
 569   AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
 570                   AC_TRY_RUN([
 571 int     L[[4]] = {0,1,2,3};
 572 int main(void) {
 573   static int Array[[3]];
 574   unsigned int B = 3;
 575   int i;
 576   for(i=0; i<B; i++) Array[[i]] = i - 3;
 577   for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
 578   L[[i]] = 4;
 579
 580   exit( Array[[1]] != -2 || L[[2]] != 3);
 581 }],
 582     ac_cv_c_gcc_strength_bug="no",
 583     ac_cv_c_gcc_strength_bug="yes",
 584     ac_cv_c_gcc_strength_bug="yes") )
 585   if test "$ac_cv_c_gcc_strength_bug" = "yes"
 586   then
 587     CFLAGS="$CFLAGS -fno-strength-reduce"
 588   fi
 589
 590   dnl Check for -mpreferred-stack-boundary
 591   AC_CACHE_CHECK([for gcc -mpreferred-stack-boundary=2 support],
 592                  ac_cv_c_gcc_stack_boundary,
 593   [saved_cflags=$CFLAGS
 594   CFLAGS="$CFLAGS -mpreferred-stack-boundary=2"
 595   AC_TRY_COMPILE(,[return 0],ac_cv_c_gcc_stack_boundary="yes",ac_cv_c_gcc_stack_boundary="no")
 596   CFLAGS=$saved_cflags
 597   ])
 598   if test "$ac_cv_c_gcc_stack_boundary" = "yes"
 599   then
 600     CFLAGS="$CFLAGS -mpreferred-stack-boundary=2"
 601   fi
 602 fi
 603
 604 dnl **** Check if we need to place .type inside a .def directive ****
 605
 606 AC_CACHE_CHECK([whether .type must sit inside a .def directive],
 607                ac_cv_c_type_in_def,
 608 [saved_libs=$LIBS
 609 LIBS="conftest_asm.s $LIBS"
 610 cat > conftest_asm.s <<EOF
 611         .globl _ac_test
 612         .def _ac_test; .scl 2; .type 32; .endef
 613 _ac_test:
 614         .long 0
 615 EOF
 616 AC_TRY_LINK(,,ac_cv_c_type_in_def="yes",ac_cv_c_type_in_def="no")
 617 LIBS=$saved_libs])
 618 if test "$ac_cv_c_type_in_def" = "yes"
 619 then
 620   AC_DEFINE(NEED_TYPE_IN_DEF, 1, [Define if .type asm directive must be inside a .def directive])
 621 fi
 622
 623 dnl **** Check for underscore on external symbols ****
 624
 625 AC_CACHE_CHECK([whether external symbols need an underscore prefix],
 626                ac_cv_c_extern_prefix,
 627 [saved_libs=$LIBS
 628 LIBS="conftest_asm.s $LIBS"
 629 cat > conftest_asm.s <<EOF
 630         .globl _ac_test
 631 _ac_test:
 632         .long 0
 633 EOF
 634 AC_TRY_LINK([extern int ac_test;],[if (ac_test) return 1],
 635             ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no")
 636 LIBS=$saved_libs])
 637 if test "$ac_cv_c_extern_prefix" = "yes"
 638 then
 639   AC_DEFINE(NEED_UNDERSCORE_PREFIX, 1,
 640             [Define if symbols declared in assembly code need an underscore prefix])
 641 fi
 642
 643 dnl **** Check for .string in assembler ****
 644
 645 AC_CACHE_CHECK([whether assembler accepts .string],
 646                ac_cv_c_asm_string,
 647 [saved_libs=$LIBS
 648 LIBS="conftest_asm.s $LIBS"
 649 cat > conftest_asm.s <<EOF
 650         .string "test"
 651 EOF
 652 AC_TRY_LINK(,,ac_cv_c_asm_string="yes",ac_cv_c_asm_string="no")
 653 LIBS=$saved_libs])
 654 if test "$ac_cv_c_asm_string" = "yes"
 655 then
 656   AC_DEFINE(HAVE_ASM_STRING, 1, [Define to use .string instead of .ascii])
 657 fi
 658
 659 dnl **** Check for working dll ****
 660
 661 LDSHARED=""
 662 LDDLLFLAGS=""
 663 if test "$LIBEXT" = "so"
 664 then
 665   AC_CACHE_CHECK([whether we can build a GNU style ELF dll],
 666                  ac_cv_c_dll_gnuelf,
 667   [saved_cflags=$CFLAGS
 668   CFLAGS="$CFLAGS -fPIC -shared -Wl,-soname,conftest.so.1.0,-Bsymbolic"
 669   AC_TRY_LINK(,[return 1],ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")
 670   CFLAGS=$saved_cflags
 671   ])
 672   if test "$ac_cv_c_dll_gnuelf" = "yes"
 673   then
 674     LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"
 675     LDDLLFLAGS="-Wl,-Bsymbolic"
 676   else
 677     AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll,
 678                  ac_cv_c_dll_unixware,
 679     [saved_cflags=$CFLAGS
 680     CFLAGS="$CFLAGS -fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic"
 681     AC_TRY_LINK(,[return 1],ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")
 682     CFLAGS=$saved_cflags
 683     ])
 684     if test "$ac_cv_c_dll_unixware" = "yes"
 685     then
 686       LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
 687       LDDLLFLAGS="-Wl,-B,symbolic"
 688     fi
 689   fi
 690   if test "$ac_cv_c_dll_gnuelf" = "no" -a "$ac_cv_c_dll_unixware" = "no"
 691   then
 692     LIBEXT="a"
 693     if test "$DLLWRAP" = "dllwrap"; then
 694       dnl FIXME - check whether dllwrap works correctly...
 695       if test "$CYGWIN" = "yes"; then
 696         echo "*** use dllwrap for building shared library."
 697         LIBEXT="dll"
 698       fi
 699     fi
 700   fi
 701 fi
 702
 703 if test "$LIBEXT" = "a"; then
 704   echo "*** It is currently not possible to build WINE without shared"
 705   echo "*** library (.so) support to allow transparent switch between .so"
 706   echo "*** and .dll files."
 707   echo "*** If you are using Linux, you will need a newer binutils."
 708   exit 1
 709 fi
 710
 711 DLLFLAGS=""
 712 LDPATH=""
 713
 714 if test "$LIBEXT" = "so"; then
 715     DLLFLAGS="-fPIC"
 716     LDPATH="LD_LIBRARY_PATH=\"\$(TOPOBJDIR)/unicode:\$\$LD_LIBRARY_PATH\""
 717 elif test "$LIBEXT" = "dll"; then
 718     #DLLFLAGS="-fPIC" # -fPIC doesn't work(at least in cygwin-b20) - FIXME
 719     LDPATH="PATH=\"\$(TOPOBJDIR)/unicode:\$\$PATH\""
 720 fi
 721
 722 AC_SUBST(DLLFLAGS)
 723 AC_SUBST(LDSHARED)
 724 AC_SUBST(LDDLLFLAGS)
 725 AC_SUBST(LIBEXT)
 726 AC_SUBST(LDPATH)
 727
 728 dnl **** Check for reentrant libc ****
 729 dnl
 730 dnl For cross-compiling we blindly assume that libc is reentrant. This is
 731 dnl ok since non-reentrant libc is quite rare (mostly old libc5 versions).
 732
 733 AC_DEFUN([WINE_CHECK_ERRNO],
 734 [
 735   AC_CACHE_CHECK(for reentrant libc: $1, wine_cv_libc_r_$1,
 736   [AC_TRY_RUN([int myerrno = 0;
 737 char buf[256];
 738 int *$1(){return &myerrno;}
 739 main(){connect(0,buf,255); exit(!myerrno);}],
 740   wine_cv_libc_r_$1=yes, wine_cv_libc_r_$1=no,
 741   wine_cv_libc_r_$1=yes )
 742 ])
 743 if test "$wine_cv_libc_r_$1" = "yes"
 744 then
 745     wine_cv_libc_reentrant=$1
 746 fi
 747 ])
 748
 749 wine_cv_libc_reentrant=no
 750 dnl Linux style errno location
 751 WINE_CHECK_ERRNO(__errno_location)
 752 dnl FreeBSD style errno location
 753 WINE_CHECK_ERRNO(__error)
 754 dnl Solaris style errno location
 755 WINE_CHECK_ERRNO(___errno)
 756 dnl UnixWare style errno location
 757 WINE_CHECK_ERRNO(__thr_errno)
 758 dnl NetBSD style errno location
 759 WINE_CHECK_ERRNO(__errno)
 760
 761 if test "$wine_cv_libc_reentrant" != "no"
 762 then
 763   AC_DEFINE_UNQUOTED(ERRNO_LOCATION,$wine_cv_libc_reentrant,
 764                      [Define to the name of the function returning errno for reentrant libc])
 765 fi
 766
 767 dnl **** Check for reentrant X libraries ****
 768 dnl
 769 dnl This may fail to determine whether X libraries are reentrant if
 770 dnl AC_PATH_XTRA does not set x_libraries. In this case manual configuration
 771 dnl is possible with the --without-reentrant-x option.
 772
 773 if test "$have_x" = "yes" -a "$wine_cv_libc_reentrant" != "no"
 774 then
 775 AC_CACHE_CHECK( [for reentrant X libraries], wine_cv_x_reentrant,
 776   [ if test "x$with_reentrant_x" = "xno"
 777     then
 778         wine_cv_x_reentrant=no
 779     else
 780         libX11_check=none
 781         for dir in "$x_libraries" /usr/lib /usr/local/lib /lib; do
 782             if test -r $dir/libX11.so; then
 783                 libX11_check="-D $dir/libX11.so"
 784                 break 1
 785             fi
 786             if test -r $dir/libX11.a; then
 787                 libX11_check="$dir/libX11.a"
 788                 break 1
 789             fi
 790         done
 791         if test "$libX11_check" != "none"; then
 792             if nm $libX11_check | grep $wine_cv_libc_reentrant >/dev/null 2>&1
 793             then
 794                 wine_cv_x_reentrant=yes
 795             else
 796                 wine_cv_x_reentrant=no
 797             fi
 798         else
 799             wine_cv_x_reentrant=unknown
 800         fi
 801     fi ] )
 802 else
 803     wine_cv_x_reentrant=no
 804 fi
 805 if test "$wine_cv_x_reentrant" = "no"
 806 then
 807   AC_DEFINE(NO_REENTRANT_X11, 1,
 808             [Define if X libraries are not reentrant (compiled without -D_REENTRANT)])
 809 fi
 810
 811
 812 dnl **** Check for functions ****
 813
 814 AC_FUNC_ALLOCA()
 815 AC_CHECK_FUNCS(\
 816         __libc_fork \
 817         _lwp_create \
 818         clone \
 819         ecvt \
 820         finite \
 821         fpclass \
 822         ftruncate64 \
 823         getnetbyaddr \
 824         getnetbyname \
 825         getpagesize \
 826         getprotobyname \
 827         getprotobynumber \
 828         getrlimit \
 829         getservbyport \
 830         getsockopt \
 831         inet_network \
 832         lseek64 \
 833         lstat \
 834         memmove \
 835         mmap \
 836         pread \
 837         pwrite \
 838         rfork \
 839         select \
 840         sendmsg \
 841         settimeofday \
 842         sigaltstack \
 843         statfs \
 844         strcasecmp \
 845         strerror \
 846         strncasecmp \
 847         tcgetattr \
 848         timegm \
 849         usleep \
 850         vfscanf \
 851         wait4 \
 852         waitpid \
 853 )
 854
 855 dnl **** Check for header files ****
 856
 857 AC_CHECK_HEADERS(\
 858         arpa/inet.h \
 859         arpa/nameser.h \
 860         elf.h \
 861         float.h \
 862         ieeefp.h \
 863         libio.h \
 864         libutil.h \
 865         link.h \
 866         linux/cdrom.h \
 867         linux/input.h \
 868         linux/joystick.h \
 869         linux/ucdrom.h \
 870         net/if.h \
 871         netdb.h \
 872         netinet/in.h \
 873         netinet/in_systm.h \
 874         netinet/ip.h \
 875         netinet/tcp.h \
 876         pty.h \
 877         resolv.h \
 878         sched.h \
 879         socket.h \
 880         stdint.h \
 881         strings.h \
 882         sys/cdio.h \
 883         sys/errno.h \
 884         sys/file.h \
 885         sys/filio.h \
 886         sys/ipc.h \
 887         sys/link.h \
 888         sys/lwp.h \
 889         sys/mman.h \
 890         sys/modem.h \
 891         sys/mount.h \
 892         sys/msg.h \
 893         sys/param.h \
 894         sys/ptrace.h \
 895         sys/reg.h \
 896         sys/signal.h \
 897         sys/shm.h \
 898         sys/socket.h \
 899         sys/sockio.h \
 900         sys/statfs.h \
 901         sys/strtio.h \
 902         sys/syscall.h \
 903         sys/user.h \
 904         sys/wait.h \
 905         sys/v86.h \
 906         sys/v86intr.h \
 907         sys/vfs.h \
 908         sys/vm86.h \
 909         syscall.h \
 910         ucontext.h \
 911 )
 912 AC_HEADER_STAT()
 913
 914 dnl **** Check for types ****
 915
 916 AC_C_CONST()
 917 AC_C_INLINE()
 918 AC_TYPE_SIZE_T()
 919 AC_CHECK_SIZEOF(long long,0)
 920
 921 AC_CACHE_CHECK([whether linux/input.h is for real],
 922         wine_cv_linux_input_h,
 923         AC_TRY_COMPILE([
 924             #include <linux/input.h>
 925         ] , [
 926             int foo = EVIOCGBIT(EV_ABS,42);
 927             int bar = BTN_PINKIE;
 928             int fortytwo = 42;
 929         ],
 930         wine_cv_linux_input_h=yes,
 931         wine_cv_linux_input_h=no,
 932         no
 933         )
 934     )
 935     if test "$wine_cv_linux_input_h" = "yes"
 936     then
 937         AC_DEFINE(HAVE_CORRECT_LINUXINPUT_H, 1,
 938                   [Define if we have linux/input.h AND it contains the INPUT event API])
 939     fi
 940
 941
 942 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
 943         wine_cv_linux_gethostbyname_r_6,
 944         AC_TRY_COMPILE([
 945 #include <netdb.h>
 946         ], [
 947     char *name=NULL;
 948     struct hostent he;
 949     struct hostent *result;
 950     char *buf=NULL;
 951     int bufsize=0;
 952     int res,errnr;
 953     char *addr=NULL;
 954     int addrlen=0;
 955     int addrtype=0;
 956     res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
 957     res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
 958     ],
 959         wine_cv_linux_gethostbyname_r_6=yes,
 960         wine_cv_linux_gethostbyname_r_6=no
 961         )
 962    )
 963    if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
 964    then
 965       AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
 966                 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
 967    fi
 968
 969 if test "$ac_cv_header_linux_joystick_h" = "yes"
 970 then
 971    AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
 972         wine_cv_linux_joystick_22_api,
 973         AC_TRY_COMPILE([
 974         #include <sys/ioctl.h>
 975         #include <linux/joystick.h>
 976
 977         struct js_event blub;
 978         #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
 979         #error "no 2.2 header"
 980         #endif
 981         ],/*empty*/,
 982         wine_cv_linux_joystick_22_api=yes,
 983         wine_cv_linux_joystick_22_api=no,
 984         wine_cv_linux_joystick_22_api=no
 985         )
 986    )
 987    if test "$wine_cv_linux_joystick_22_api" = "yes"
 988    then
 989       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
 990                 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
 991    fi
 992 fi
 993
 994 dnl **** statfs checks ****
 995
 996 if test "$ac_cv_header_sys_vfs_h" = "yes"
 997 then
 998     AC_CACHE_CHECK( [whether sys/vfs.h defines statfs],
 999                     wine_cv_sys_vfs_has_statfs,
1000         AC_TRY_COMPILE([
1001         #include <sys/types.h>
1002         #ifdef HAVE_SYS_PARAM_H
1003         # include <sys/param.h>
1004         #endif
1005         #include <sys/vfs.h>
1006         ],[
1007                 struct statfs stfs;
1008
1009                 memset(&stfs,0,sizeof(stfs));
1010         ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
1011         )
1012     )
1013     if test "$wine_cv_sys_vfs_has_statfs" = "yes"
1014     then
1015       AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS, 1,
1016                 [Define if the struct statfs is defined by <sys/vfs.h>])
1017     fi
1018 fi
1019
1020 if test "$ac_cv_header_sys_statfs_h" = "yes"
1021 then
1022     AC_CACHE_CHECK( [whether sys/statfs.h defines statfs],
1023                     wine_cv_sys_statfs_has_statfs,
1024         AC_TRY_COMPILE([
1025         #include <sys/types.h>
1026         #ifdef HAVE_SYS_PARAM_H
1027         # include <sys/param.h>
1028         #endif
1029         #include <sys/statfs.h>
1030         ],[
1031                 struct statfs stfs;
1032         ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
1033         )
1034     )
1035     if test "$wine_cv_sys_statfs_has_statfs" = "yes"
1036     then
1037       AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS, 1,
1038                 [Define if the struct statfs is defined by <sys/statfs.h>])
1039     fi
1040 fi
1041
1042 if test "$ac_cv_header_sys_mount_h" = "yes"
1043 then
1044     AC_CACHE_CHECK( [whether sys/mount.h defines statfs],
1045                     wine_cv_sys_mount_has_statfs,
1046         AC_TRY_COMPILE([
1047         #include <sys/types.h>
1048         #ifdef HAVE_SYS_PARAM_H
1049         # include <sys/param.h>
1050         #endif
1051         #include <sys/mount.h>
1052         ],[
1053                 struct statfs stfs;
1054         ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
1055         )
1056     )
1057     if test "$wine_cv_sys_mount_has_statfs" = "yes"
1058     then
1059       AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT, 1,
1060                 [Define if the struct statfs is defined by <sys/mount.h>])
1061     fi
1062 fi
1063
1064 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1065
1066 AC_CACHE_CHECK( [for statfs.f_bfree], wine_cv_statfs_bfree,
1067   [ if test "x$statfs_bfree" = "xno"
1068     then
1069         wine_cv_statfs_bfree=no
1070     else
1071         AC_TRY_COMPILE([
1072         #include <sys/types.h>
1073         #ifdef HAVE_SYS_PARAM_H
1074         # include <sys/param.h>
1075         #endif
1076         #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1077         # include <sys/mount.h>
1078         #else
1079         # ifdef STATFS_DEFINED_BY_SYS_VFS
1080         #  include <sys/vfs.h>
1081         # else
1082         #  ifdef STATFS_DEFINED_BY_SYS_STATFS
1083         #   include <sys/statfs.h>
1084         #  endif
1085         # endif
1086         #endif
1087         ],[
1088                 struct statfs stfs;
1089
1090                 stfs.f_bfree++;
1091         ],wine_cv_statfs_bfree=yes,wine_cv_statfs_bfree=no
1092         )
1093     fi ] )
1094 if test "$wine_cv_statfs_bfree" = "yes"
1095 then
1096   AC_DEFINE(STATFS_HAS_BFREE, 1, [Define if the struct statfs has the member bfree])
1097 fi
1098
1099 AC_CACHE_CHECK( [for statfs.f_bavail], wine_cv_statfs_bavail,
1100   [ if test "x$statfs_bavail" = "xno"
1101     then
1102         wine_cv_statfs_bavail=no
1103     else
1104         AC_TRY_COMPILE([
1105         #include <sys/types.h>
1106         #ifdef HAVE_SYS_PARAM_H
1107         # include <sys/param.h>
1108         #endif
1109         #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1110         # include <sys/mount.h>
1111         #else
1112         # ifdef STATFS_DEFINED_BY_SYS_VFS
1113         #  include <sys/vfs.h>
1114         # else
1115         #  ifdef STATFS_DEFINED_BY_SYS_STATFS
1116         #   include <sys/statfs.h>
1117         #  endif
1118         # endif
1119         #endif
1120         ],[
1121                 struct statfs stfs;
1122
1123                 stfs.f_bavail++;
1124         ],wine_cv_statfs_bavail=yes,wine_cv_statfs_bavail=no
1125         )
1126     fi ] )
1127 if test "$wine_cv_statfs_bavail" = "yes"
1128 then
1129   AC_DEFINE(STATFS_HAS_BAVAIL, 1, [Define if the struct statfs has the member bavail])
1130 fi
1131
1132 dnl *** check for file descriptor passing with msg_accrights
1133
1134 AC_CACHE_CHECK([for msg_accrights in struct msghdr], ac_cv_c_msg_accrights,
1135  AC_TRY_COMPILE([#include <sys/types.h>
1136 #include <sys/socket.h>],[struct msghdr hdr; hdr.msg_accrights=0],
1137                 ac_cv_c_msg_accrights="yes", ac_cv_c_msg_accrights="no"))
1138 if test "$ac_cv_c_msg_accrights" = "yes"
1139 then
1140     AC_DEFINE(HAVE_MSGHDR_ACCRIGHTS, 1, [Define if struct msghdr contains msg_accrights])
1141 fi
1142
1143 dnl *** Check for the sa_len member in struct sockaddr
1144
1145 AC_CACHE_CHECK([for sa_len in struct sockaddr], ac_cv_c_sockaddr_sa_len,
1146  AC_TRY_COMPILE([#include <sys/types.h>
1147 #include <sys/socket.h>
1148 ], [static struct sockaddr addr; addr.sa_len = 1],
1149                 ac_cv_c_sockaddr_sa_len="yes", ac_cv_c_sockaddr_sa_len="no"))
1150 if test "$ac_cv_c_sockaddr_sa_len" = "yes"
1151 then
1152     AC_DEFINE(HAVE_SOCKADDR_SA_LEN, 1, [Define if struct sockaddr contains sa_len])
1153 fi
1154
1155 dnl *** Check for the sun_len member in struct sockaddr_un
1156
1157 AC_CACHE_CHECK([for sun_len in struct sockaddr_un], ac_cv_c_sockaddr_sun_len,
1158  AC_TRY_COMPILE([#include <sys/types.h>
1159 #include <sys/socket.h>
1160 #include <sys/un.h>], [static struct sockaddr_un addr; addr.sun_len = 1],
1161                 ac_cv_c_sockaddr_sun_len="yes", ac_cv_c_sockaddr_sun_len="no"))
1162 if test "$ac_cv_c_sockaddr_sun_len" = "yes"
1163 then
1164     AC_DEFINE(HAVE_SOCKADDR_SUN_LEN, 1, [Define if struct sockaddr_un contains sun_len])
1165 fi
1166
1167 dnl *** check for the need to define __i386__
1168
1169 AC_CACHE_CHECK([whether we need to define __i386__],ac_cv_cpp_def_i386,
1170  AC_EGREP_CPP(yes,[#if (defined(i386) || defined(__i386)) && !defined(__i386__)
1171 yes
1172 #endif],
1173  ac_cv_cpp_def_i386="yes", ac_cv_cpp_def_i386="no"))
1174 if test "$ac_cv_cpp_def_i386" = "yes"
1175 then
1176     CFLAGS="$CFLAGS -D__i386__"
1177     LINTFLAGS="$LINTFLAGS -D__i386__"
1178 fi
1179
1180 dnl $GCC is set by autoconf
1181 GCC_NO_BUILTIN=""
1182 if test "$GCC" = "yes"
1183 then
1184     GCC_NO_BUILTIN="-fno-builtin"
1185 fi
1186 AC_SUBST(GCC_NO_BUILTIN)
1187
1188 dnl **** Generate output files ****
1189
1190 AC_DEFINE(__WINE_CONFIG_H, 1,
1191           [This must always be defined to allow checking for config.h inclusion])
1192
1193 AC_OUTPUT_COMMANDS([
1194 extra_subdirs="\
1195 dlls/ddraw/d3ddevice \
1196 dlls/ddraw/dclipper \
1197 dlls/ddraw/ddraw \
1198 dlls/ddraw/direct3d \
1199 dlls/ddraw/dpalette \
1200 dlls/ddraw/dsurface \
1201 dlls/dinput/joystick \
1202 dlls/dinput/keyboard \
1203 dlls/dinput/mouse \
1204 dlls/kernel/messages \
1205 dlls/user/dde \
1206 dlls/user/resources \
1207 dlls/wineps/data \
1208 "
1209 for i in $extra_subdirs; do [ -d $i ] || (echo "creating $i" && mkdir $i); done ])
1210
1211 MAKE_RULES=Make.rules
1212 AC_SUBST_FILE(MAKE_RULES)
1213
1214 MAKE_DLL_RULES=dlls/Makedll.rules
1215 AC_SUBST_FILE(MAKE_DLL_RULES)
1216
1217 MAKE_PROG_RULES=programs/Makeprog.rules
1218 AC_SUBST_FILE(MAKE_PROG_RULES)
1219
1220 AC_OUTPUT([
1221 Make.rules
1222 dlls/Makedll.rules
1223 programs/Makeprog.rules
1224 Makefile
1225 console/Makefile
1226 controls/Makefile
1227 debugger/Makefile
1228 dlls/Makefile
1229 dlls/advapi32/Makefile
1230 dlls/avicap32/Makefile
1231 dlls/avifil32/Makefile
1232 dlls/comctl32/Makefile
1233 dlls/commdlg/Makefile
1234 dlls/crtdll/Makefile
1235 dlls/crypt32/Makefile
1236 dlls/dciman32/Makefile
1237 dlls/ddraw/Makefile
1238 dlls/devenum/Makefile
1239 dlls/dinput/Makefile
1240 dlls/dplay/Makefile
1241 dlls/dplayx/Makefile
1242 dlls/dsound/Makefile
1243 dlls/gdi/Makefile
1244 dlls/glu32/Makefile
1245 dlls/icmp/Makefile
1246 dlls/imagehlp/Makefile
1247 dlls/imm32/Makefile
1248 dlls/kernel/Makefile
1249 dlls/lzexpand/Makefile
1250 dlls/mapi32/Makefile
1251 dlls/mpr/Makefile
1252 dlls/msacm/Makefile
1253 dlls/msdmo/Makefile
1254 dlls/msimg32/Makefile
1255 dlls/msnet32/Makefile
1256 dlls/msrle32/Makefile
1257 dlls/msvcrt/Makefile
1258 dlls/msvideo/Makefile
1259 dlls/netapi32/Makefile
1260 dlls/ntdll/Makefile
1261 dlls/odbc32/Makefile
1262 dlls/ole32/Makefile
1263 dlls/oleaut32/Makefile
1264 dlls/olecli/Makefile
1265 dlls/oledlg/Makefile
1266 dlls/olepro32/Makefile
1267 dlls/olesvr/Makefile
1268 dlls/opengl32/Makefile
1269 dlls/psapi/Makefile
1270 dlls/qcap/Makefile
1271 dlls/quartz/Makefile
1272 dlls/rasapi32/Makefile
1273 dlls/richedit/Makefile
1274 dlls/rpcrt4/Makefile
1275 dlls/serialui/Makefile
1276 dlls/setupapi/Makefile
1277 dlls/shdocvw/Makefile
1278 dlls/shell32/Makefile
1279 dlls/shfolder/Makefile
1280 dlls/shlwapi/Makefile
1281 dlls/sti/Makefile
1282 dlls/tapi32/Makefile
1283 dlls/ttydrv/Makefile
1284 dlls/url/Makefile
1285 dlls/urlmon/Makefile
1286 dlls/user/Makefile
1287 dlls/version/Makefile
1288 dlls/win32s/Makefile
1289 dlls/winaspi/Makefile
1290 dlls/winedos/Makefile
1291 dlls/wineps/Makefile
1292 dlls/wininet/Makefile
1293 dlls/winmm/Makefile
1294 dlls/winmm/joystick/Makefile
1295 dlls/winmm/mcianim/Makefile
1296 dlls/winmm/mciavi/Makefile
1297 dlls/winmm/mcicda/Makefile
1298 dlls/winmm/mciseq/Makefile
1299 dlls/winmm/mciwave/Makefile
1300 dlls/winmm/midimap/Makefile
1301 dlls/winmm/wavemap/Makefile
1302 dlls/winmm/wineoss/Makefile
1303 dlls/winnls/Makefile
1304 dlls/winsock/Makefile
1305 dlls/winspool/Makefile
1306 dlls/wintrust/Makefile
1307 dlls/wow32/Makefile
1308 dlls/wsock32/Makefile
1309 dlls/x11drv/Makefile
1310 documentation/Makefile
1311 documentation/wine.conf.man
1312 documentation/wine.man
1313 files/Makefile
1314 graphics/Makefile
1315 graphics/enhmetafiledrv/Makefile
1316 graphics/metafiledrv/Makefile
1317 graphics/win16drv/Makefile
1318 graphics/x11drv/Makefile
1319 if1632/Makefile
1320 include/Makefile
1321 library/Makefile
1322 libtest/Makefile
1323 loader/Makefile
1324 loader/ne/Makefile
1325 memory/Makefile
1326 misc/Makefile
1327 miscemu/Makefile
1328 msdos/Makefile
1329 objects/Makefile
1330 ole/Makefile
1331 programs/Makefile
1332 programs/avitools/Makefile
1333 programs/clock/Makefile
1334 programs/cmdlgtst/Makefile
1335 programs/control/Makefile
1336 programs/notepad/Makefile
1337 programs/osversioncheck/Makefile
1338 programs/progman/Makefile
1339 programs/regapi/Makefile
1340 programs/regtest/Makefile
1341 programs/uninstaller/Makefile
1342 programs/view/Makefile
1343 programs/wcmd/Makefile
1344 programs/wineconsole/Makefile
1345 programs/winemine/Makefile
1346 programs/winetest/Makefile
1347 programs/winhelp/Makefile
1348 programs/winver/Makefile
1349 relay32/Makefile
1350 scheduler/Makefile
1351 server/Makefile
1352 tools/Makefile
1353 tools/winapi/Makefile
1354 tools/winebuild/Makefile
1355 tools/winedump/Makefile
1356 tools/winelauncher
1357 tools/wmc/Makefile
1358 tools/wrc/Makefile
1359 tsx11/Makefile
1360 unicode/Makefile
1361 win32/Makefile
1362 windows/Makefile
1363 windows/x11drv/Makefile ])
1364
1365 if test "$have_x" = "no"
1366 then
1367   echo
1368   echo "*** Warning: X development files not found. Wine will be built without"
1369   echo "*** X support, which currently does not work, and would probably not be"
1370   echo "*** what you want anyway. You will need to install devel packages of"
1371   echo "*** Xlib/Xfree86 at the very least."
1372 fi
1373
1374 if test "$ac_cv_lib_ncurses_resizeterm" = "no" -a "$ac_cv_lib_ncurses_waddch" = "yes"
1375 then
1376   echo
1377   echo "*** Warning: resizeterm not found in ncurses. Wine will be built without"
1378   echo "*** terminal resize support. Consider upgrading ncurses."
1379 fi
1380
1381 if test "$wine_cv_libc_reentrant" = "no"
1382 then
1383   echo
1384   echo "*** Warning: non-reentrant libc detected. Wine will be build without"
1385   echo "*** thread support. Consider upgrading libc to a more recent"
1386   echo "*** reentrant version of libc."
1387 fi
1388
1389 if test "$wine_cv_opengl_version_OK" = "no"
1390 then
1391   echo
1392   echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
1393   echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)."
1394 fi
1395
1396 if test "$wine_cv_opengl_version_threadsafe" = "yes" -a $OPENGL = "normal"
1397 then
1398   echo
1399   echo "*** Warning: the OpenGL version you have installed relies on libpthread for"
1400   echo "*** thread-safety. To prevent crashes, OpenGL support has been removed."
1401   echo "*** A fix for glibc 2.1.3 that seems to work is included in this version of Wine,"
1402   echo "*** start configure with '--enable-opengl' to force OpenGL support."
1403 fi
1404
1405 if test "$wine_cv_opengl_version_threadsafe" = "yes" -a $OPENGL = "yes"
1406 then
1407   echo
1408   echo "*** Warning: you explicitly linked in a thread-safe OpenGL version. If you"
1409   echo "*** experience unusual crashes on DirectDraw games, try first to disable OpenGL"
1410   echo "*** support before reporting bugs."
1411 fi
1412
1413 if test "$wine_cv_warn_cups_h" = "yes"
1414 then
1415   echo
1416   echo "*** Note: You have cups runtime libraries, but no development"
1417   echo "*** libraries. Install the cups-devel package or whichever package"
1418   echo "*** contains cups.h to enable CUPS support in WINE."
1419 fi
1420
1421 if test "$wine_cv_msg_freetype" = "yes"
1422 then
1423   echo
1424   echo "*** Note: Your system appears to have the FreeType 2 runtime libraries"
1425   echo "*** installed, but 'freetype-config' is not in your PATH. Install the"
1426   echo "*** freetype-devel package (or its equivalent on your distribution) to"
1427   echo "*** enable Wine to use TrueType fonts."
1428 fi
1429
1430 echo
1431 echo "Configure finished.  Do 'make depend && make' to compile Wine."
1432 echo
1433
1434 dnl Local Variables:
1435 dnl comment-start: "dnl "
1436 dnl comment-end: ""
1437 dnl comment-start-skip: "\\bdnl\\b\\s *"
1438 dnl compile-command: "autoconf"
1439 dnl End: