git.oblomov.eu Git - wine/blob - aclocal.m4

   1 dnl Macros used to build the Wine configure script
   2 dnl
   3 dnl Copyright 2002 Alexandre Julliard
   4 dnl
   5 dnl This library is free software; you can redistribute it and/or
   6 dnl modify it under the terms of the GNU Lesser General Public
   7 dnl License as published by the Free Software Foundation; either
   8 dnl version 2.1 of the License, or (at your option) any later version.
   9 dnl
  10 dnl This library is distributed in the hope that it will be useful,
  11 dnl but WITHOUT ANY WARRANTY; without even the implied warranty of
  12 dnl MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  13 dnl Lesser General Public License for more details.
  14 dnl
  15 dnl You should have received a copy of the GNU Lesser General Public
  16 dnl License along with this library; if not, write to the Free Software
  17 dnl Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA
  18 dnl
  19 dnl As a special exception to the GNU Lesser General Public License,
  20 dnl if you distribute this file as part of a program that contains a
  21 dnl configuration script generated by Autoconf, you may include it
  22 dnl under the same distribution terms that you use for the rest of
  23 dnl that program.
  24
  25 dnl **** Get the ldd program name; used by WINE_GET_SONAME ****
  26 dnl
  27 dnl Usage: WINE_PATH_LDD
  28 dnl
  29 AC_DEFUN([WINE_PATH_LDD],[AC_PATH_PROG(LDD,ldd,true,/sbin:/usr/sbin:$PATH)])
  30
  31 dnl **** Extract the soname of a library ****
  32 dnl
  33 dnl Usage: WINE_CHECK_SONAME(library, function, [action-if-found, [action-if-not-found, [other_libraries, [pattern]]]])
  34 dnl
  35 AC_DEFUN([WINE_CHECK_SONAME],
  36 [AC_REQUIRE([WINE_PATH_LDD])dnl
  37 AS_VAR_PUSHDEF([ac_Lib],[ac_cv_lib_soname_$1])dnl
  38 m4_pushdef([ac_lib_pattern],m4_default([$6],[lib$1]))dnl
  39 AC_MSG_CHECKING([for -l$1])
  40 AC_CACHE_VAL(ac_Lib,
  41 [ac_check_soname_save_LIBS=$LIBS
  42 LIBS="-l$1 $5 $LIBS"
  43   AC_LINK_IFELSE([AC_LANG_CALL([], [$2])],
  44   [case "$LIBEXT" in
  45     dll) AS_VAR_SET(ac_Lib,[`$ac_cv_path_LDD conftest.exe | grep "$1" | sed -e "s/dll.*/dll/"';2,$d'`]) ;;
  46     dylib) AS_VAR_SET(ac_Lib,[`otool -L conftest$ac_exeext | grep "ac_lib_pattern\\.[[0-9A-Za-z.]]*dylib" | sed -e "s/^.*\/\(ac_lib_pattern\.[[0-9A-Za-z.]]*dylib\).*$/\1/"';2,$d'`]) ;;
  47     *) AS_VAR_SET(ac_Lib,[`$ac_cv_path_LDD conftest$ac_exeext | grep "ac_lib_pattern\\.$LIBEXT" | sed -e "s/^.*\(ac_lib_pattern\.$LIBEXT[[^      ]]*\).*$/\1/"';2,$d'`]) ;;
  48   esac])
  49   LIBS=$ac_check_soname_save_LIBS])dnl
  50 AS_IF([test "x]AS_VAR_GET(ac_Lib)[" = "x"],
  51       [AC_MSG_RESULT([not found])
  52        $4],
  53       [AC_MSG_RESULT(AS_VAR_GET(ac_Lib))
  54        AC_DEFINE_UNQUOTED(AS_TR_CPP(SONAME_LIB$1),["]AS_VAR_GET(ac_Lib)["],
  55                           [Define to the soname of the lib$1 library.])
  56        $3])dnl
  57 m4_popdef([ac_lib_pattern])dnl
  58 AS_VAR_POPDEF([ac_Lib])])
  59
  60 dnl **** Link C code with an assembly file ****
  61 dnl
  62 dnl Usage: WINE_TRY_ASM_LINK(asm-code,includes,function,[action-if-found,[action-if-not-found]])
  63 dnl
  64 AC_DEFUN([WINE_TRY_ASM_LINK],
  65 [AC_LINK_IFELSE([AC_LANG_PROGRAM([[$2]],[[asm($1); $3]])],[$4],[$5])])
  66
  67 dnl **** Check if we can link an empty program with special CFLAGS ****
  68 dnl
  69 dnl Usage: WINE_TRY_CFLAGS(flags,[action-if-yes,[action-if-no]])
  70 dnl
  71 dnl The default action-if-yes is to append the flags to EXTRACFLAGS.
  72 dnl
  73 AC_DEFUN([WINE_TRY_CFLAGS],
  74 [AS_VAR_PUSHDEF([ac_var], ac_cv_cflags_[[$1]])dnl
  75 AC_CACHE_CHECK([whether the compiler supports $1], ac_var,
  76 [ac_wine_try_cflags_saved=$CFLAGS
  77 CFLAGS="$CFLAGS $1"
  78 AC_LINK_IFELSE([AC_LANG_SOURCE([[int main(int argc, char **argv) { return 0; }]])],
  79                [AS_VAR_SET(ac_var,yes)], [AS_VAR_SET(ac_var,no)])
  80 CFLAGS=$ac_wine_try_cflags_saved])
  81 AS_IF([test AS_VAR_GET(ac_var) = yes],
  82       [m4_default([$2], [EXTRACFLAGS="$EXTRACFLAGS $1"])], [$3])dnl
  83 AS_VAR_POPDEF([ac_var])])
  84
  85 dnl **** Check if we can link an empty shared lib (no main) with special CFLAGS ****
  86 dnl
  87 dnl Usage: WINE_TRY_SHLIB_FLAGS(flags,[action-if-yes,[action-if-no]])
  88 dnl
  89 AC_DEFUN([WINE_TRY_SHLIB_FLAGS],
  90 [ac_wine_try_cflags_saved=$CFLAGS
  91 CFLAGS="$CFLAGS $1"
  92 AC_LINK_IFELSE([AC_LANG_SOURCE([void myfunc() {}])],[$2],[$3])
  93 CFLAGS=$ac_wine_try_cflags_saved])
  94
  95 dnl **** Check whether we need to define a symbol on the compiler command line ****
  96 dnl
  97 dnl Usage: WINE_CHECK_DEFINE(name),[action-if-yes,[action-if-no]])
  98 dnl
  99 AC_DEFUN([WINE_CHECK_DEFINE],
 100 [AS_VAR_PUSHDEF([ac_var],[ac_cv_cpp_def_$1])dnl
 101 AC_CACHE_CHECK([whether we need to define $1],ac_var,
 102     AC_EGREP_CPP(yes,[#ifndef $1
 103 yes
 104 #endif],
 105     [AS_VAR_SET(ac_var,yes)],[AS_VAR_SET(ac_var,no)]))
 106 AS_IF([test AS_VAR_GET(ac_var) = yes],
 107       [CFLAGS="$CFLAGS -D$1"
 108   LINTFLAGS="$LINTFLAGS -D$1"])dnl
 109 AS_VAR_POPDEF([ac_var])])
 110
 111 dnl **** Check for functions with some extra libraries ****
 112 dnl
 113 dnl Usage: WINE_CHECK_LIB_FUNCS(funcs,libs,[action-if-found,[action-if-not-found]])
 114 dnl
 115 AC_DEFUN([WINE_CHECK_LIB_FUNCS],
 116 [ac_wine_check_funcs_save_LIBS="$LIBS"
 117 LIBS="$LIBS $2"
 118 AC_CHECK_FUNCS([$1],[$3],[$4])
 119 LIBS="$ac_wine_check_funcs_save_LIBS"])
 120
 121 dnl **** Check for a mingw program, trying the various mingw prefixes ****
 122 dnl
 123 dnl Usage: WINE_CHECK_MINGW_PROG(variable,prog,[value-if-not-found],[path])
 124 dnl
 125 AC_DEFUN([WINE_CHECK_MINGW_PROG],
 126 [case "$host_cpu" in
 127   i[[3456789]]86*)
 128     ac_prefix_list="m4_foreach([ac_wine_prefix],[w64-mingw32, pc-mingw32, mingw32msvc, mingw32],
 129                         m4_foreach([ac_wine_cpu],[i686,i586,i486,i386],[ac_wine_cpu-ac_wine_prefix-$2 ]))" ;;
 130   x86_64)
 131     ac_prefix_list="m4_foreach([ac_wine_prefix],[pc-mingw32, w64-mingw32, mingw32msvc],
 132                         m4_foreach([ac_wine_cpu],[x86_64,amd64],[ac_wine_cpu-ac_wine_prefix-$2 ]))" ;;
 133   *)
 134     ac_prefix_list="" ;;
 135 esac
 136 AC_CHECK_PROGS([$1],[$ac_prefix_list],[$3],[$4])])
 137
 138
 139 dnl **** Define helper functions for creating config.status files ****
 140 dnl
 141 dnl Usage: AC_REQUIRE([WINE_CONFIG_HELPERS])
 142 dnl
 143 AC_DEFUN([WINE_CONFIG_HELPERS],
 144 [ALL_MAKEFILE_DEPENDS="
 145 # Rules automatically generated by configure
 146
 147 .INIT: Makefile
 148 .MAKEFILEDEPS:
 149 all: Makefile
 150 Makefile: Makefile.in Make.vars.in Make.rules config.status
 151         @./config.status Make.tmp Makefile"
 152
 153 ALL_POT_FILES=""
 154 AC_SUBST(ALL_WINETEST_DEPENDS,["# Test binaries"])
 155 AC_SUBST(ALL_TEST_BINARIES,"")
 156
 157 wine_fn_append_file ()
 158 {
 159     AS_VAR_APPEND($[1]," \\$as_nl       $[2]")
 160 }
 161
 162 wine_fn_append_rule ()
 163 {
 164     AS_VAR_APPEND($[1],"$as_nl$[2]")
 165 }
 166
 167 wine_fn_has_flag ()
 168 {
 169     expr ",$[2]," : ".*,$[1],.*" >/dev/null
 170 }
 171
 172 wine_fn_all_dir_rules ()
 173 {
 174     ac_dir=$[1]
 175     ac_alldeps=$[2]
 176     ac_makedep="\$(MAKEDEP)"
 177     ac_input=Make.vars.in:$ac_dir/Makefile.in
 178     if test $ac_dir != tools
 179     then
 180         dnl makedep is in tools so tools makefile cannot depend on it
 181         ac_alldeps="$[2] $ac_makedep"
 182     fi
 183     case $[2] in
 184       *.in) ac_input=$ac_input:$[2] ;;
 185       *) ac_makedep="$[2] $ac_makedep" ;;
 186     esac
 187
 188     wine_fn_append_file ALL_DIRS $ac_dir
 189     wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 190 "__clean__: $ac_dir/__clean__
 191 .PHONY: $ac_dir/__clean__
 192 $ac_dir/__clean__: $ac_dir/Makefile
 193         @cd $ac_dir && \$(MAKE) clean
 194         \$(RM) $ac_dir/Makefile
 195 $ac_dir/Makefile: $ac_dir/Makefile.in Make.vars.in config.status $ac_alldeps
 196         @./config.status --file $ac_dir/Makefile:$ac_input && cd $ac_dir && \$(MAKE) depend
 197 depend: $ac_dir/__depend__
 198 .PHONY: $ac_dir/__depend__
 199 $ac_dir/__depend__: $ac_makedep dummy
 200         @./config.status --file $ac_dir/Makefile:$ac_input && cd $ac_dir && \$(MAKE) depend"
 201 }
 202
 203 wine_fn_config_makefile ()
 204 {
 205     ac_dir=$[1]
 206     ac_enable=$[2]
 207     AS_VAR_IF([$ac_enable],[no],[return 0])
 208
 209     wine_fn_all_dir_rules $ac_dir Make.rules
 210     wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 211 "all: $ac_dir
 212 .PHONY: $ac_dir
 213 $ac_dir: $ac_dir/Makefile dummy
 214         @cd $ac_dir && \$(MAKE)
 215 install:: $ac_dir
 216         @cd $ac_dir && \$(MAKE) install
 217 install-lib:: $ac_dir
 218         @cd $ac_dir && \$(MAKE) install-lib
 219 install-dev:: $ac_dir
 220         @cd $ac_dir && \$(MAKE) install-dev
 221 uninstall:: $ac_dir/Makefile
 222         @cd $ac_dir && \$(MAKE) uninstall"
 223 }
 224
 225 wine_fn_config_lib ()
 226 {
 227     ac_name=$[1]
 228     ac_dir=dlls/$ac_name
 229     wine_fn_all_dir_rules $ac_dir dlls/Makeimplib.rules
 230     wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 231 "all __builddeps__: $ac_dir
 232 $ac_dir: $ac_dir/Makefile tools/widl tools/winebuild tools/winegcc include dummy
 233         @cd $ac_dir && \$(MAKE)
 234 install install-dev:: $ac_dir
 235         @cd $ac_dir && \$(MAKE) install
 236 uninstall:: $ac_dir/Makefile
 237         @cd $ac_dir && \$(MAKE) uninstall"
 238 }
 239
 240 wine_fn_config_dll ()
 241 {
 242     ac_name=$[1]
 243     ac_dir=dlls/$ac_name
 244     ac_enable=$[2]
 245     ac_flags=$[3]
 246     ac_implib=${4:-$ac_name}
 247     ac_file=$ac_dir/lib$ac_implib
 248     ac_deps="tools/widl tools/winebuild tools/winegcc include"
 249     ac_implibflags=""
 250
 251     case $ac_name in
 252       *16) ac_implibflags=" -m16" ;;
 253     esac
 254
 255     wine_fn_all_dir_rules $ac_dir dlls/Makedll.rules
 256
 257     AS_VAR_IF([$ac_enable],[no],
 258               dnl enable_win16 is special in that it disables import libs too
 259               [test "$ac_enable" != enable_win16 || return 0],
 260               [wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 261 "all: $ac_dir
 262 .PHONY: $ac_dir
 263 $ac_dir: $ac_dir/Makefile __builddeps__ dummy
 264         @cd $ac_dir && \$(MAKE)
 265 install:: $ac_dir/Makefile __builddeps__
 266         @cd $ac_dir && \$(MAKE) install
 267 install-lib:: $ac_dir/Makefile __builddeps__
 268         @cd $ac_dir && \$(MAKE) install-lib
 269 uninstall manpages htmlpages sgmlpages xmlpages:: $ac_dir/Makefile
 270         @cd $ac_dir && \$(MAKE) \$[@]"
 271
 272         if test "x$enable_maintainer_mode" = xyes
 273         then
 274             if wine_fn_has_flag mc $ac_flags
 275             then
 276                 wine_fn_append_file ALL_POT_FILES $ac_dir/msg.pot
 277                 wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 278 "$ac_dir/msg.pot: $ac_dir"
 279             fi
 280             if wine_fn_has_flag po $ac_flags
 281             then
 282                 wine_fn_append_file ALL_POT_FILES $ac_dir/rsrc.pot
 283                 wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 284 "$ac_dir/rsrc.pot: $ac_dir"
 285             fi
 286         fi])
 287
 288     if wine_fn_has_flag staticimplib $ac_flags
 289     then
 290         wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 291 "__builddeps__: $ac_file.$IMPLIBEXT $ac_file.$STATIC_IMPLIBEXT
 292 $ac_file.$IMPLIBEXT $ac_file.$STATIC_IMPLIBEXT $ac_file.cross.a: $ac_deps
 293 $ac_file.def: $ac_dir/$ac_name.spec $ac_dir/Makefile
 294         @cd $ac_dir && \$(MAKE) lib$ac_implib.def
 295 $ac_file.$STATIC_IMPLIBEXT: $ac_dir/Makefile dummy
 296         @cd $ac_dir && \$(MAKE) lib$ac_implib.$STATIC_IMPLIBEXT
 297 install-dev:: $ac_dir/Makefile __builddeps__
 298         @cd $ac_dir && \$(MAKE) install-dev"
 299         if test "x$CROSSTEST_DISABLE" = x
 300         then
 301             wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 302 "__builddeps__: $ac_file.cross.a
 303 $ac_file.cross.a: $ac_dir/Makefile dummy
 304         @cd $ac_dir && \$(MAKE) lib$ac_implib.cross.a"
 305         fi
 306
 307     elif wine_fn_has_flag implib $ac_flags
 308     then
 309         wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 310 "__builddeps__: $ac_file.$IMPLIBEXT
 311 $ac_file.def: $ac_dir/$ac_name.spec $ac_dir/Makefile \$(WINEBUILD)
 312         \$(WINEBUILD) \$(TARGETFLAGS)$ac_implibflags -w --def -o \$[@] --export \$(srcdir)/$ac_dir/$ac_name.spec
 313 $ac_file.a: $ac_dir/$ac_name.spec $ac_dir/Makefile \$(WINEBUILD)
 314         \$(WINEBUILD) \$(TARGETFLAGS)$ac_implibflags -w --implib -o \$[@] --export \$(srcdir)/$ac_dir/$ac_name.spec
 315 install-dev:: $ac_dir/Makefile __builddeps__
 316         @cd $ac_dir && \$(MAKE) install-dev"
 317         if test "x$CROSSTEST_DISABLE" = x
 318         then
 319             wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 320 "__builddeps__: $ac_file.cross.a
 321 $ac_file.cross.a: $ac_dir/$ac_name.spec $ac_dir/Makefile \$(WINEBUILD)
 322         \$(WINEBUILD) \$(CROSSTARGET:%=-b %)$ac_implibflags -w --implib -o \$[@] --export \$(srcdir)/$ac_dir/$ac_name.spec"
 323         fi
 324
 325         if test "$ac_name" != "$ac_implib"
 326         then
 327             wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 328 "__builddeps__: dlls/lib$ac_implib.$IMPLIBEXT
 329 dlls/lib$ac_implib.$IMPLIBEXT: $ac_file.$IMPLIBEXT
 330         \$(RM) \$[@] && \$(LN_S) $ac_name/lib$ac_implib.$IMPLIBEXT \$[@]
 331 clean::
 332         \$(RM) dlls/lib$ac_implib.$IMPLIBEXT"
 333             if test "x$CROSSTEST_DISABLE" = x
 334             then
 335                 wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 336 "__builddeps__: dlls/lib$ac_implib.cross.a
 337 dlls/lib$ac_implib.cross.a: $ac_file.cross.a
 338         \$(RM) \$[@] && \$(LN_S) $ac_name/lib$ac_implib.cross.a \$[@]"
 339             fi
 340         fi
 341     fi
 342 }
 343
 344 wine_fn_config_program ()
 345 {
 346     ac_name=$[1]
 347     ac_dir=programs/$ac_name
 348     ac_enable=$[2]
 349     ac_flags=$[3]
 350     wine_fn_all_dir_rules $ac_dir programs/Makeprog.rules
 351
 352     AS_VAR_IF([$ac_enable],[no],,[wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 353 "all: $ac_dir
 354 .PHONY: $ac_dir
 355 $ac_dir: $ac_dir/Makefile __builddeps__ dummy
 356         @cd $ac_dir && \$(MAKE)"
 357
 358     if test "x$enable_maintainer_mode" = xyes
 359     then
 360         if wine_fn_has_flag mc $ac_flags
 361         then
 362             wine_fn_append_file ALL_POT_FILES $ac_dir/msg.pot
 363             wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 364 "$ac_dir/msg.pot: $ac_dir"
 365         fi
 366         if wine_fn_has_flag po $ac_flags
 367         then
 368             wine_fn_append_file ALL_POT_FILES $ac_dir/rsrc.pot
 369             wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 370 "$ac_dir/rsrc.pot: $ac_dir"
 371         fi
 372     fi
 373
 374     wine_fn_has_flag install $ac_flags || return
 375     wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 376 "install install-lib:: $ac_dir/Makefile __builddeps__
 377         @cd $ac_dir && \$(MAKE) install
 378 uninstall:: $ac_dir/Makefile
 379         @cd $ac_dir && \$(MAKE) uninstall"
 380     if test -n "$DLLEXT" -a "x$enable_tools" != xno && wine_fn_has_flag installbin $ac_flags
 381     then
 382         wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 383 "install install-lib:: tools \$(DESTDIR)\$(bindir)
 384         \$(INSTALL_SCRIPT) tools/wineapploader \$(DESTDIR)\$(bindir)/$ac_name
 385 uninstall::
 386         \$(RM) \$(DESTDIR)\$(bindir)/$ac_name"
 387     fi])
 388 }
 389
 390 wine_fn_config_test ()
 391 {
 392     ac_dir=$[1]
 393     ac_name=$[2]
 394     wine_fn_append_file ALL_TEST_BINARIES $ac_name.exe
 395     wine_fn_append_rule ALL_WINETEST_DEPENDS \
 396 "$ac_name.exe: \$(top_builddir)/$ac_dir/$ac_name.exe$DLLEXT
 397         cp \$(top_builddir)/$ac_dir/$ac_name.exe$DLLEXT \$[@] && \$(STRIP) \$[@]
 398 $ac_name.rc:
 399         echo \"$ac_name.exe TESTRES \\\"$ac_name.exe\\\"\" >\$[@] || (\$(RM) \$[@] && false)
 400 $ac_name.res: $ac_name.rc $ac_name.exe"
 401     wine_fn_all_dir_rules $ac_dir Maketest.rules
 402
 403     AS_VAR_IF([enable_tests],[no],,[wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 404 "all programs/winetest: $ac_dir
 405 .PHONY: $ac_dir
 406 $ac_dir: $ac_dir/Makefile __builddeps__ dummy
 407         @cd $ac_dir && \$(MAKE)
 408 test: $ac_dir/__test__
 409 .PHONY: $ac_dir/__test__
 410 $ac_dir/__test__: dummy
 411         @cd $ac_dir && \$(MAKE) test
 412 testclean::
 413         \$(RM) $ac_dir/*.ok"
 414
 415         if test "x$CROSSTEST_DISABLE" = x
 416         then
 417             wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 418 "crosstest: $ac_dir/__crosstest__
 419 .PHONY: $ac_dir/__crosstest__
 420 $ac_dir/__crosstest__: $ac_dir/Makefile __builddeps__ dummy
 421         @cd $ac_dir && \$(MAKE) crosstest"
 422         fi])
 423 }
 424
 425 wine_fn_config_tool ()
 426 {
 427     ac_dir=$[1]
 428     AS_VAR_IF([enable_tools],[no],[return 0])
 429
 430     wine_fn_all_dir_rules $ac_dir Make.rules
 431
 432     case $ac_dir in
 433       dnl tools directory has both install-lib and install-dev
 434       tools) wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 435 "install:: $ac_dir
 436         @cd $ac_dir && \$(MAKE) install
 437 install-lib:: $ac_dir
 438         @cd $ac_dir && \$(MAKE) install-lib
 439 install-dev:: $ac_dir
 440         @cd $ac_dir && \$(MAKE) install-dev" ;;
 441       *)     wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 442 "install install-dev:: $ac_dir
 443         @cd $ac_dir && \$(MAKE) install" ;;
 444     esac
 445     wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 446 "uninstall:: $ac_dir/Makefile
 447         @cd $ac_dir && \$(MAKE) uninstall
 448 all __tooldeps__: $ac_dir
 449 .PHONY: $ac_dir
 450 $ac_dir: $ac_dir/Makefile libs/port dummy
 451         @cd $ac_dir && \$(MAKE)"
 452     case $ac_dir in
 453       tools/winebuild) wine_fn_append_rule ALL_MAKEFILE_DEPENDS "\$(WINEBUILD): $ac_dir" ;;
 454     esac
 455 }
 456
 457 wine_fn_config_makerules ()
 458 {
 459     ac_rules=$[1]
 460     ac_deps=$[2]
 461     wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 462 "$ac_rules: $ac_rules.in $ac_deps config.status
 463         @./config.status $ac_rules
 464 distclean::
 465         \$(RM) $ac_rules"
 466 }
 467
 468 wine_fn_config_symlink ()
 469 {
 470     ac_link=$[1]
 471     wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 472 "$ac_link:
 473         @./config.status $ac_link
 474 distclean::
 475         \$(RM) $ac_link"
 476 }
 477
 478 if test "x$CROSSTEST_DISABLE" != x
 479 then
 480     wine_fn_append_rule ALL_MAKEFILE_DEPENDS \
 481 "crosstest:
 482         @echo \"crosstest is not supported (mingw not installed?)\" && false"
 483 fi])
 484
 485 dnl **** Define helper function to append a file to a makefile file list ****
 486 dnl
 487 dnl Usage: WINE_APPEND_FILE(var,file)
 488 dnl
 489 AC_DEFUN([WINE_APPEND_FILE],[AC_REQUIRE([WINE_CONFIG_HELPERS])wine_fn_append_file $1 "$2"])
 490
 491 dnl **** Define helper function to append a rule to a makefile command list ****
 492 dnl
 493 dnl Usage: WINE_APPEND_RULE(var,rule)
 494 dnl
 495 AC_DEFUN([WINE_APPEND_RULE],[AC_REQUIRE([WINE_CONFIG_HELPERS])wine_fn_append_rule $1 "$2"])
 496
 497 dnl **** Create nonexistent directories from config.status ****
 498 dnl
 499 dnl Usage: WINE_CONFIG_EXTRA_DIR(dirname)
 500 dnl
 501 AC_DEFUN([WINE_CONFIG_EXTRA_DIR],
 502 [AC_CONFIG_COMMANDS([$1],[test -d "$1" || { AC_MSG_NOTICE([creating $1]); AS_MKDIR_P("$1"); }])])
 503
 504 dnl **** Create symlinks from config.status ****
 505 dnl
 506 dnl Usage: WINE_CONFIG_SYMLINK(name,target,enable)
 507 dnl
 508 AC_DEFUN([WINE_CONFIG_SYMLINK],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 509 m4_ifval([$3],[if test "x$[$3]" != xno; then
 510 ])AC_CONFIG_LINKS([$1:]m4_default([$2],[$1]))dnl
 511 m4_if([$2],,[test "$srcdir" = "." || ])wine_fn_config_symlink $1[]m4_ifval([$3],[
 512 fi])])
 513
 514 dnl **** Create a make rules file from config.status ****
 515 dnl
 516 dnl Usage: WINE_CONFIG_MAKERULES(file,var,deps)
 517 dnl
 518 AC_DEFUN([WINE_CONFIG_MAKERULES],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 519 wine_fn_config_makerules $1 $3
 520 $2=$1
 521 AC_SUBST_FILE([$2])dnl
 522 AC_CONFIG_FILES([$1])])
 523
 524 dnl **** Create a makefile from config.status ****
 525 dnl
 526 dnl Usage: WINE_CONFIG_MAKEFILE(file,enable)
 527 dnl
 528 AC_DEFUN([WINE_CONFIG_MAKEFILE],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 529 AS_VAR_PUSHDEF([ac_enable],m4_default([$2],[enable_]$1))dnl
 530 wine_fn_config_makefile [$1] ac_enable[]dnl
 531 AS_VAR_POPDEF([ac_enable])])
 532
 533 dnl **** Create a dll makefile from config.status ****
 534 dnl
 535 dnl Usage: WINE_CONFIG_DLL(name,enable,flags,implib)
 536 dnl
 537 AC_DEFUN([WINE_CONFIG_DLL],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 538 AS_VAR_PUSHDEF([ac_enable],m4_default([$2],[enable_]$1))dnl
 539 wine_fn_config_dll [$1] ac_enable [$3] [$4]dnl
 540 AS_VAR_POPDEF([ac_enable])])
 541
 542 dnl **** Create a program makefile from config.status ****
 543 dnl
 544 dnl Usage: WINE_CONFIG_PROGRAM(name,enable,flags)
 545 dnl
 546 AC_DEFUN([WINE_CONFIG_PROGRAM],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 547 AS_VAR_PUSHDEF([ac_enable],m4_default([$2],[enable_]$1))dnl
 548 wine_fn_config_program [$1] ac_enable [$3]dnl
 549 AS_VAR_POPDEF([ac_enable])])
 550
 551 dnl **** Create a test makefile from config.status ****
 552 dnl
 553 dnl Usage: WINE_CONFIG_TEST(dir)
 554 dnl
 555 AC_DEFUN([WINE_CONFIG_TEST],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 556 m4_pushdef([ac_suffix],m4_if(m4_substr([$1],0,9),[programs/],[.exe_test],[_test]))dnl
 557 m4_pushdef([ac_name],[m4_bpatsubst([$1],[.*/\(.*\)/tests$],[\1])])dnl
 558 wine_fn_config_test $1 ac_name[]ac_suffix[]dnl
 559 m4_popdef([ac_suffix])dnl
 560 m4_popdef([ac_name])])
 561
 562 dnl **** Create a static lib makefile from config.status ****
 563 dnl
 564 dnl Usage: WINE_CONFIG_LIB(name)
 565 dnl
 566 AC_DEFUN([WINE_CONFIG_LIB],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 567 wine_fn_config_lib $1])
 568
 569 dnl **** Create a tool makefile from config.status ****
 570 dnl
 571 dnl Usage: WINE_CONFIG_TOOL(name)
 572 dnl
 573 AC_DEFUN([WINE_CONFIG_TOOL],[AC_REQUIRE([WINE_CONFIG_HELPERS])dnl
 574 wine_fn_config_tool $1])
 575
 576 dnl **** Add a message to the list displayed at the end ****
 577 dnl
 578 dnl Usage: WINE_NOTICE(notice)
 579 dnl Usage: WINE_NOTICE_WITH(with_flag, test, notice)
 580 dnl Usage: WINE_WARNING(warning)
 581 dnl Usage: WINE_WARNING_WITH(with_flag, test, warning)
 582 dnl Usage: WINE_PRINT_MESSAGES
 583 dnl
 584 AC_DEFUN([WINE_NOTICE],[AS_VAR_APPEND([wine_notices],["|$1"])])
 585 AC_DEFUN([WINE_WARNING],[AS_VAR_APPEND([wine_warnings],["|$1"])])
 586
 587 AC_DEFUN([WINE_NOTICE_WITH],[AS_IF([$2],[case "x$with_$1" in
 588   x)   WINE_NOTICE([$3]) ;;
 589   xno) ;;
 590   *)   AC_MSG_ERROR([$3
 591 This is an error since --with-$1 was requested.]) ;;
 592 esac])])
 593
 594 AC_DEFUN([WINE_WARNING_WITH],[AS_IF([$2],[case "x$with_$1" in
 595   x)   WINE_WARNING([$3]) ;;
 596   xno) ;;
 597   *)   AC_MSG_ERROR([$3
 598 This is an error since --with-$1 was requested.]) ;;
 599 esac])])
 600
 601 AC_DEFUN([WINE_ERROR_WITH],[AS_IF([$2],[case "x$with_$1" in
 602   xno) ;;
 603   *)   AC_MSG_ERROR([$3
 604 Use the --without-$1 option if you really want this.]) ;;
 605 esac])])
 606
 607 AC_DEFUN([WINE_PRINT_MESSAGES],[ac_save_IFS="$IFS"
 608 if test "x$wine_notices != "x; then
 609     echo >&AS_MESSAGE_FD
 610     IFS="|"
 611     for msg in $wine_notices; do
 612         IFS="$ac_save_IFS"
 613         if test -n "$msg"; then
 614             AC_MSG_NOTICE([$msg])
 615         fi
 616     done
 617 fi
 618 IFS="|"
 619 for msg in $wine_warnings; do
 620     IFS="$ac_save_IFS"
 621     if test -n "$msg"; then
 622         echo >&2
 623         AC_MSG_WARN([$msg])
 624     fi
 625 done
 626 IFS="$ac_save_IFS"])
 627
 628 dnl Local Variables:
 629 dnl compile-command: "autoreconf --warnings=all"
 630 dnl End: