git.oblomov.eu Git - wine/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Original author: Michael Patra
   3 dnl See ChangeLog file for detailed change history.
   4
   5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
   6
   7 dnl autoconf versions before 2.59d don't handle multi-line subst variables correctly
   8 AC_PREREQ(2.59d)
   9 AC_INIT([Wine],[WINE_VERSION],[wine-devel@winehq.org],[wine],[http://www.winehq.org])
  10 AC_CONFIG_SRCDIR(server/atom.c)
  11 AC_CONFIG_HEADERS(include/config.h)
  12 AC_CONFIG_AUX_DIR(tools)
  13
  14 dnl autoconf versions before 2.63b don't have AS_VAR_APPEND
  15 m4_ifdef([AS_VAR_APPEND],,[as_fn_append () { eval $[1]=\$$[1]\$[2]; }
  16 AC_DEFUN([AS_VAR_APPEND],[as_fn_append $1 $2])])dnl
  17
  18 dnl **** Command-line arguments ****
  19
  20 AC_ARG_ENABLE(win16, AS_HELP_STRING([--disable-win16],[do not include Win16 support]))
  21 AC_ARG_ENABLE(win64, AS_HELP_STRING([--enable-win64],[build a Win64 emulator on AMD64 (won't run Win32 binaries)]))
  22 AC_ARG_ENABLE(tests, AS_HELP_STRING([--disable-tests],[do not build the regression tests]))
  23 AC_ARG_ENABLE(maintainer-mode, AS_HELP_STRING([--enable-maintainer-mode],[enable maintainer-specific build rules]),
  24                                ,[AC_SUBST([MAINTAINER_MODE],[\#])])
  25
  26 AC_ARG_WITH(alsa,      AS_HELP_STRING([--without-alsa],[do not use the Alsa sound support]),
  27             [if test "x$withval" = "xno"; then ac_cv_header_sys_asoundlib_h=no; ac_cv_header_alsa_asoundlib_h=no; fi])
  28 AC_ARG_WITH(audioio,   AS_HELP_STRING([--without-audioio],[do not use the AudioIO sound support]),
  29             [if test "x$withval" = "xno"; then ac_cv_header_libaudioio_h=no; fi])
  30 AC_ARG_WITH(capi,      AS_HELP_STRING([--without-capi],[do not use CAPI (ISDN support)]),
  31             [if test "x$withval" = "xno"; then ac_cv_header_capi20_h=no; ac_cv_header_linux_capi_h=no; fi])
  32 AC_ARG_WITH(cms,       AS_HELP_STRING([--without-cms],[do not use CMS (color management support)]),
  33             [if test "x$withval" = "xno"; then ac_cv_header_lcms_h=no; ac_cv_header_lcms_lcms_h=no; fi])
  34 AC_ARG_WITH(coreaudio, AS_HELP_STRING([--without-coreaudio],[do not use the CoreAudio sound support]),
  35             [if test "x$withval" = "xno"; then ac_cv_header_CoreAudio_CoreAudio_h=no; fi])
  36 AC_ARG_WITH(cups,      AS_HELP_STRING([--without-cups],[do not use CUPS]))
  37 AC_ARG_WITH(curses,    AS_HELP_STRING([--without-curses],[do not use (n)curses]),
  38             [if test "x$withval" = "xno"; then ac_cv_header_ncurses_h=no; ac_cv_header_curses_h=no; fi])
  39 AC_ARG_WITH(esd,       AS_HELP_STRING([--without-esd],[do not use the EsounD sound support]))
  40 AC_ARG_WITH(fontconfig,AS_HELP_STRING([--without-fontconfig],[do not use fontconfig]),
  41             [if test "x$withval" = "xno"; then ac_cv_header_fontconfig_fontconfig_h=no; fi])
  42 AC_ARG_WITH(freetype,  AS_HELP_STRING([--without-freetype],[do not use the FreeType library]))
  43 AC_ARG_WITH(gphoto,    AS_HELP_STRING([--without-gphoto],[do not use gphoto (Digital Camera support)]))
  44 AC_ARG_WITH(glu,       AS_HELP_STRING([--without-glu],[do not use the GLU library]),
  45             [if test "x$withval" = "xno"; then ac_cv_header_GL_glu_h=no; fi])
  46 AC_ARG_WITH(gnutls,    AS_HELP_STRING([--without-gnutls],[do not use GnuTLS (schannel support)]))
  47 AC_ARG_WITH(gsm,       AS_HELP_STRING([--without-gsm],[do not use libgsm (GSM 06.10 codec support)]),
  48             [if test "x$withval" = "xno"; then ac_cv_header_gsm_h=no; ac_cv_header_gsm_gsm_h=no; fi])
  49 AC_ARG_WITH(hal,       AS_HELP_STRING([--without-hal],[do not use HAL (dynamic device support)]))
  50 AC_ARG_WITH(jack,      AS_HELP_STRING([--without-jack],[do not use the Jack sound support]),
  51             [if test "x$withval" = "xno"; then ac_cv_header_jack_jack_h=no; fi])
  52 AC_ARG_WITH(jpeg,      AS_HELP_STRING([--without-jpeg],[do not use JPEG]),
  53             [if test "x$withval" = "xno"; then ac_cv_header_jpeglib_h=no; fi])
  54 AC_ARG_WITH(ldap,      AS_HELP_STRING([--without-ldap],[do not use LDAP]),
  55             [if test "x$withval" = "xno"; then ac_cv_header_ldap_h=no; ac_cv_header_lber_h=no; fi])
  56 AC_ARG_WITH(mpg123,    AS_HELP_STRING([--without-mpg123],[do not use the mpg123 library]),
  57             [if test "x$withval" = "xno"; then ac_cv_header_mpg123_h=no; fi])
  58 AC_ARG_WITH(nas,       AS_HELP_STRING([--without-nas],[do not use the NAS sound support]),
  59             [if test "x$withval" = "xno"; then ac_cv_header_audio_audiolib_h=no; fi])
  60 AC_ARG_WITH(openal,    AS_HELP_STRING([--without-openal],[do not use OpenAL]),
  61             [if test "x$withval" = "xno"; then ac_cv_header_AL_al_h=no; ac_cv_header_OpenAL_al_h=no; fi])
  62 AC_ARG_WITH(opengl,    AS_HELP_STRING([--without-opengl],[do not use OpenGL]))
  63 AC_ARG_WITH(openssl,   AS_HELP_STRING([--without-openssl],[do not use OpenSSL]),
  64             [if test "x$withval" = "xno"; then ac_cv_header_openssl_err_h=no; ac_cv_header_openssl_ssl_h=no; fi])
  65 AC_ARG_WITH(oss,       AS_HELP_STRING([--without-oss],[do not use the OSS sound support]),
  66             [if test "x$withval" = "xno"; then ac_cv_header_soundcard_h=no; ac_cv_header_sys_soundcard_h=no; ac_cv_header_machine_soundcard_h=no; fi])
  67 AC_ARG_WITH(png,       AS_HELP_STRING([--without-png],[do not use PNG]),
  68             [if test "x$withval" = "xno"; then ac_cv_header_png_h=no; fi])
  69 AC_ARG_WITH(pthread,   AS_HELP_STRING([--without-pthread],[do not use the pthread library]),
  70             [if test "x$withval" = "xno"; then ac_cv_header_pthread_h=no; fi])
  71 AC_ARG_WITH(sane,      AS_HELP_STRING([--without-sane],[do not use SANE (scanner support)]))
  72 AC_ARG_WITH(tiff,       AS_HELP_STRING([--without-tiff],[do not use TIFF]),
  73             [if test "x$withval" = "xno"; then ac_cv_header_tiffio_h=no; fi])
  74 AC_ARG_WITH(v4l,       AS_HELP_STRING([--without-v4l],[do not use v4l1 (v4l support)]))
  75 AC_ARG_WITH(xcomposite,AS_HELP_STRING([--without-xcomposite],[do not use the Xcomposite extension]),
  76             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_Xcomposite_h=no; fi])
  77 AC_ARG_WITH(xcursor,   AS_HELP_STRING([--without-xcursor],[do not use the Xcursor extension]),
  78             [if test "x$withval" = "xno"; then ac_cv_header_X11_Xcursor_Xcursor_h=no; fi])
  79 AC_ARG_WITH(xinerama,  AS_HELP_STRING([--without-xinerama],[do not use Xinerama (multi-monitor support)]),
  80             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_Xinerama_h=no; fi])
  81 AC_ARG_WITH(xinput,    AS_HELP_STRING([--without-xinput],[do not use the Xinput extension]),
  82             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_XInput_h=no; fi])
  83 AC_ARG_WITH(xml,       AS_HELP_STRING([--without-xml],[do not use XML]))
  84 AC_ARG_WITH(xrandr,    AS_HELP_STRING([--without-xrandr],[do not use Xrandr (resolution changes)]),
  85             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_Xrandr_h=no; fi])
  86 AC_ARG_WITH(xrender,   AS_HELP_STRING([--without-xrender],[do not use the Xrender extension]),
  87             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_Xrender_h=no; fi])
  88 AC_ARG_WITH(xshape,    AS_HELP_STRING([--without-xshape],[do not use the Xshape extension]),
  89             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_shape_h=no; fi])
  90 AC_ARG_WITH(xshm,      AS_HELP_STRING([--without-xshm],[do not use XShm (shared memory extension)]),
  91             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_XShm_h=no; fi])
  92 AC_ARG_WITH(xslt,      AS_HELP_STRING([--without-xslt],[do not use XSLT]))
  93 AC_ARG_WITH(xxf86vm,   AS_HELP_STRING([--without-xxf86vm],[do not use XFree video mode extension]),
  94             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_xf86vmode_h=no; ac_cv_header_X11_extensions_xf86vmproto_h=no; fi])
  95
  96 AC_ARG_WITH(wine-tools,AS_HELP_STRING([--with-wine-tools=DIR],[use Wine tools from directory DIR]))
  97 AC_ARG_WITH(wine64,    AS_HELP_STRING([--with-wine64=DIR],[use the 64-bit Wine in DIR for a Wow64 build]))
  98
  99 AC_CANONICAL_HOST
 100
 101 dnl check for out of tree build with unclean source tree
 102 case "$srcdir" in
 103  .) ;;
 104  *) if test -f "$srcdir/Makefile" -o -f "$srcdir/include/config.h"; then
 105       AC_MSG_ERROR([you are building out of the source tree, but the source tree contains object files.
 106 You need to run 'make distclean' in the source tree first.])
 107     fi ;;
 108 esac
 109
 110 dnl **** Check for some programs ****
 111
 112 AC_PROG_MAKE_SET
 113 AC_PROG_CC
 114 AC_PROG_CXX
 115 dnl We can't use AC_PROG_CPP for winegcc, it uses by default $(CC) -E
 116 AC_CHECK_TOOL(CPPBIN,cpp,cpp)
 117 AC_DEFINE_UNQUOTED(EXEEXT,["$ac_exeext"],[Define to the file extension for executables.])
 118
 119 case $host in
 120   *-darwin*)
 121     if test "x$enable_win64" = "xyes"
 122     then
 123       CC="$CC -m64"
 124       CXX="$CXX -m64"
 125       LD="${LD:-ld} -arch x86_64"
 126       AS="${AS:-as} -arch x86_64"
 127       host_cpu="x86_64"
 128       notice_platform="64-bit "
 129       AC_SUBST(TARGETFLAGS,"-m64")
 130     else
 131       CC="$CC -m32"
 132       CXX="$CXX -m32"
 133       LD="${LD:-ld} -arch i386"
 134       AS="${AS:-as} -arch i386"
 135       host_cpu="i386"
 136       notice_platform="32-bit "
 137       AC_SUBST(TARGETFLAGS,"-m32")
 138       enable_win16=${enable_win16:-yes}
 139     fi
 140     ;;
 141   x86_64*)
 142     if test "x$enable_win64" != "xyes" -a "$cross_compiling" != "yes"
 143     then
 144       CC="$CC -m32"
 145       CXX="$CXX -m32"
 146       AC_MSG_CHECKING([whether $CC works])
 147       AC_LINK_IFELSE(AC_LANG_PROGRAM(),AC_MSG_RESULT([yes]),
 148                      [AC_MSG_RESULT([no])
 149                       AC_MSG_ERROR([Cannot build a 32-bit program, you need to install 32-bit development libraries.])])
 150       LD="${LD:-ld} -m elf_i386"
 151       AS="${AS:-as} --32"
 152       host_cpu="i386"
 153       notice_platform="32-bit "
 154       AC_SUBST(TARGETFLAGS,"-m32")
 155       enable_win16=${enable_win16:-yes}
 156     else
 157       if test "x${GCC}" = "xyes"
 158       then
 159         AC_MSG_CHECKING([whether $CC supports __builtin_ms_va_list])
 160         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stdarg.h>]], [[void func(__builtin_ms_va_list *args);]])],
 161                           [AC_MSG_RESULT([yes])],
 162                           [AC_MSG_RESULT([no])
 163                            AC_MSG_ERROR([You need gcc >= 4.4 to build Wine as 64-bit.])])
 164       fi
 165       AC_SUBST(TARGETFLAGS,"-m64")
 166     fi
 167     ;;
 168   *-mingw32*|*-cygwin*)
 169     enable_win16=${enable_win16:-no}
 170     CFLAGS="$CFLAGS -D_WIN32"
 171     ;;
 172   i[[3456789]]86*)
 173     enable_win16=${enable_win16:-yes}
 174     ;;
 175 esac
 176
 177 dnl enable_win16 defaults to yes on x86, to no on other CPUs
 178 enable_win16=${enable_win16:-no}
 179
 180 dnl Disable winetest too if tests are disabled
 181 enable_winetest=${enable_winetest:-$enable_tests}
 182
 183 dnl Some special cases for the wow64 build
 184 if test -n "$with_wine64"
 185 then
 186     if test "x$enable_win64" = "xyes"
 187     then
 188         AC_MSG_ERROR([--enable-win64 and --with-wine64 are mutually exclusive.
 189 --enable-win64 should be used in the 64-bit build tree, --with-wine64 in the 32-bit Wow64 build tree.])
 190     fi
 191     AC_SUBST([WOW64_DISABLE],[\#])
 192     enable_fonts=${enable_fonts:-no}
 193     enable_rpcss=${enable_rpcss:-no}
 194     enable_server=${enable_server:-no}
 195     enable_tools=${enable_tools:-no}
 196     enable_wineboot=${enable_wineboot:-no}
 197     enable_winedbg=${enable_winedbg:-no}
 198     enable_winemenubuilder=${enable_winemenubuilder:-no}
 199     test "x$libdir" != "x\${exec_prefix}/lib" || libdir="\${exec_prefix}/lib32"
 200 fi
 201
 202 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
 203   [wine_cv_toolsdir="$with_wine_tools"
 204    if test -z "$with_wine_tools"; then
 205      if test "$cross_compiling" = "yes"; then
 206        AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
 207      elif test -n "$with_wine64"; then
 208        wine_cv_toolsdir="$with_wine64"
 209      fi
 210    fi
 211    if test -z "$wine_cv_toolsdir"; then
 212      wine_cv_toolsdir="\$(TOPOBJDIR)"
 213    elif test -d "$wine_cv_toolsdir/tools/winebuild"; then
 214      case "$wine_cv_toolsdir" in
 215        /*) ;;
 216        *)  wine_cv_toolsdir="\$(TOPOBJDIR)/$wine_cv_toolsdir" ;;
 217      esac
 218    else
 219      AC_MSG_ERROR([could not find Wine tools in $wine_cv_toolsdir])
 220    fi])
 221 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
 222 if test -n "$host_alias" -a "$host_alias" != "$build_alias"
 223 then
 224     AC_SUBST(TARGETFLAGS,"-b $host_alias $TARGETFLAGS")
 225 fi
 226
 227 dnl Check for flex
 228 AC_CHECK_PROGS(FLEX,flex,none)
 229 if test "$FLEX" = "none"
 230 then
 231   AC_MSG_ERROR([no suitable flex found. Please install the 'flex' package.])
 232 fi
 233 AC_MSG_CHECKING([whether flex is recent enough])
 234 cat >conftest.l <<EOF
 235 %top{
 236 #include "prediluvian.h"
 237 }
 238 %%
 239 EOF
 240 if $FLEX -t conftest.l >/dev/null 2>&1
 241 then
 242   AC_MSG_RESULT([yes])
 243 else
 244   AC_MSG_RESULT([no])
 245   AC_MSG_ERROR([Your flex version is too old. Please install flex version 2.5.33 or newer.])
 246 fi
 247
 248 dnl Check for bison
 249 AC_CHECK_PROGS(BISON,bison,none)
 250 if test "$BISON" = "none"
 251 then
 252   AC_MSG_ERROR([no suitable bison found. Please install the 'bison' package.])
 253 fi
 254
 255 AC_CHECK_TOOLS(AR,[ar gar],ar)
 256 AC_SUBST(ARFLAGS,rc)
 257 AC_PROG_RANLIB
 258 AC_CHECK_TOOL(STRIP,strip,strip)
 259 AC_PROG_LN_S
 260 AC_PROG_EGREP
 261 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
 262 AC_PROG_INSTALL
 263 dnl Prepend src dir to install path dir if it's a relative path
 264 case "$INSTALL" in
 265   [[\\/$]]* | ?:[[\\/]]* ) ;;
 266   *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
 267 esac
 268
 269 dnl Check for lint
 270 AC_CHECK_PROGS(LINT, lclint lint)
 271 if test "$LINT" = "lint"
 272 then
 273   LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
 274   dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
 275 fi
 276 AC_SUBST(LINT)
 277 AC_SUBST(LINTFLAGS)
 278
 279 dnl Check for various programs
 280 AC_CHECK_PROGS(FONTFORGE, fontforge, false)
 281 AC_CHECK_PROGS(PKG_CONFIG, pkg-config, false)
 282 AC_CHECK_PROGS(RSVG, rsvg, false)
 283 AC_CHECK_PROGS(CONVERT, convert, false)
 284 AC_CHECK_PROGS(ICOTOOL, icotool, false)
 285
 286 if test "${enable_maintainer_mode+set}" = set
 287 then
 288   if test "$FONTFORGE" = "false"; then WINE_WARNING([fontforge is missing, fonts can't be rebuilt.]); fi
 289   if test "$RSVG" = "false"; then WINE_WARNING([rsvg is missing, icons can't be rebuilt.]); fi
 290   if test "$CONVERT" = "false"; then WINE_WARNING([imagemagick is missing, icons can't be rebuilt.]); fi
 291
 292   dnl Check the icotool version
 293   if test "$ICOTOOL" = false
 294   then
 295     WINE_WARNING([icotool is missing, icons can't be rebuilt.])
 296   else
 297     AC_MSG_CHECKING([for recent enough icotool])
 298     icotool_version=`icotool --version | head -n1`
 299     if test "x$icotool_version" != "x"
 300     then
 301       icotool_version_major=`expr "$icotool_version" : '.* \([[0-9]]*\).[[0-9]]*'`
 302       icotool_version_minor=`expr "$icotool_version" : '.* [[0-9]]*.\([[0-9]]*\)'`
 303       if test "$icotool_version_major" -eq 0 -a "$icotool_version_minor" -lt 29
 304       then
 305         ICOTOOL=false
 306         WINE_WARNING([icotool version 0.29.0 or newer is needed to rebuild icons.])
 307       fi
 308     fi
 309     if test "$ICOTOOL" = false
 310     then
 311       AC_MSG_RESULT([no ($icotool_version_major.$icotool_version_minor)])
 312     else
 313       AC_MSG_RESULT([yes ($icotool_version_major.$icotool_version_minor)])
 314     fi
 315   fi
 316
 317 fi
 318
 319 case $host_cpu in
 320   *i[[3456789]]86*)
 321     AC_PATH_PROG(PRELINK, prelink, false, [/sbin /usr/sbin $PATH])
 322     ;;
 323 esac
 324
 325 dnl **** Check for some libraries ****
 326
 327 dnl Check for -li386 for NetBSD and OpenBSD
 328 AC_CHECK_LIB(i386,i386_set_ldt)
 329 dnl Check for -lossaudio for NetBSD
 330 AC_CHECK_LIB(ossaudio,_oss_ioctl)
 331
 332 AC_SUBST(XLIB,"")
 333 AC_SUBST(OPENGL_LIBS,"")
 334
 335 dnl **** Check for header files ****
 336
 337 AC_SYS_LARGEFILE()
 338
 339 AC_CHECK_HEADERS(\
 340         AL/al.h \
 341         AudioToolbox/AudioConverter.h \
 342         AudioToolbox/AudioFile.h \
 343         AudioToolbox/AudioFileStream.h \
 344         AudioUnit/AudioUnit.h \
 345         Carbon/Carbon.h \
 346         CoreAudio/CoreAudio.h \
 347         DiskArbitration/DiskArbitration.h \
 348         IOKit/IOKitLib.h \
 349         IOKit/hid/IOHIDLib.h \
 350         OpenAL/al.h \
 351         alias.h \
 352         alsa/asoundlib.h \
 353         arpa/inet.h \
 354         arpa/nameser.h \
 355         asm/types.h \
 356         capi20.h \
 357         curses.h \
 358         direct.h \
 359         dirent.h \
 360         dlfcn.h \
 361         elf.h \
 362         float.h \
 363         fnmatch.h \
 364         fontconfig/fontconfig.h \
 365         getopt.h \
 366         grp.h \
 367         gsm.h \
 368         gsm/gsm.h \
 369         ieeefp.h \
 370         inet/mib2.h \
 371         io.h \
 372         jack/jack.h \
 373         jpeglib.h \
 374         kstat.h \
 375         lber.h \
 376         lcms.h \
 377         lcms/lcms.h \
 378         ldap.h \
 379         libaudioio.h \
 380         link.h \
 381         linux/cdrom.h \
 382         linux/compiler.h \
 383         linux/hdreg.h \
 384         linux/input.h \
 385         linux/ioctl.h \
 386         linux/joystick.h \
 387         linux/major.h \
 388         linux/param.h \
 389         linux/serial.h \
 390         linux/types.h \
 391         linux/ucdrom.h \
 392         mach-o/nlist.h \
 393         mach/mach.h \
 394         mach/machine.h \
 395         machine/cpu.h \
 396         machine/limits.h \
 397         machine/soundcard.h \
 398         mntent.h \
 399         mpg123.h \
 400         ncurses.h \
 401         netdb.h \
 402         netinet/in.h \
 403         netinet/in_systm.h \
 404         netinet/tcp.h \
 405         netinet/tcp_fsm.h \
 406         openssl/err.h \
 407         openssl/ssl.h \
 408         png.h \
 409         poll.h \
 410         port.h \
 411         process.h \
 412         pthread.h \
 413         pwd.h \
 414         regex.h \
 415         sched.h \
 416         scsi/scsi.h \
 417         scsi/scsi_ioctl.h \
 418         scsi/sg.h \
 419         soundcard.h \
 420         stdbool.h \
 421         stdint.h \
 422         strings.h \
 423         stropts.h \
 424         sys/asoundlib.h \
 425         sys/cdio.h \
 426         sys/elf32.h \
 427         sys/epoll.h \
 428         sys/errno.h \
 429         sys/event.h \
 430         sys/exec_elf.h \
 431         sys/filio.h \
 432         sys/inotify.h \
 433         sys/ioctl.h \
 434         sys/ipc.h \
 435         sys/limits.h \
 436         sys/link.h \
 437         sys/mman.h \
 438         sys/modem.h \
 439         sys/msg.h \
 440         sys/mtio.h \
 441         sys/param.h \
 442         sys/poll.h \
 443         sys/prctl.h \
 444         sys/protosw.h \
 445         sys/ptrace.h \
 446         sys/resource.h \
 447         sys/scsiio.h \
 448         sys/shm.h \
 449         sys/signal.h \
 450         sys/socket.h \
 451         sys/socketvar.h \
 452         sys/sockio.h \
 453         sys/soundcard.h \
 454         sys/statvfs.h \
 455         sys/strtio.h \
 456         sys/syscall.h \
 457         sys/tihdr.h \
 458         sys/time.h \
 459         sys/timeout.h \
 460         sys/times.h \
 461         sys/uio.h \
 462         sys/un.h \
 463         sys/utsname.h \
 464         sys/vm86.h \
 465         sys/wait.h \
 466         syscall.h \
 467         termios.h \
 468         tiffio.h \
 469         unistd.h \
 470         utime.h \
 471         valgrind/memcheck.h \
 472         valgrind/valgrind.h \
 473         zlib.h
 474 )
 475 AC_HEADER_STAT()
 476
 477 dnl **** Checks for headers that depend on other ones ****
 478
 479 AC_CHECK_HEADERS([sys/mount.h sys/statfs.h sys/sysctl.h sys/user.h sys/vfs.h],,,
 480     [#include <sys/types.h>
 481      #ifdef HAVE_SYS_PARAM_H
 482      # include <sys/param.h>
 483      #endif])
 484
 485 AC_CHECK_HEADERS(\
 486         netinet/ip.h \
 487         net/if.h \
 488         net/if_arp.h \
 489         net/if_dl.h \
 490         net/if_types.h \
 491         net/route.h \
 492         netinet/if_ether.h \
 493         netinet/if_inarp.h \
 494         netinet/in_pcb.h \
 495         netinet/ip_icmp.h \
 496         netinet/ip_var.h \
 497         netinet/udp.h \
 498         netipx/ipx.h \
 499 ,,,[#include <sys/types.h>
 500      #ifdef HAVE_SYS_SOCKET_H
 501      # include <sys/socket.h>
 502      #endif
 503      #ifdef HAVE_SYS_SOCKETVAR_H
 504      # include <sys/socketvar.h>
 505      #endif
 506      #ifdef HAVE_NET_ROUTE_H
 507      # include <net/route.h>
 508      #endif
 509      #ifdef HAVE_NETINET_IN_H
 510      # include <netinet/in.h>
 511      #endif
 512      #ifdef HAVE_NETINET_IN_SYSTM_H
 513      # include <netinet/in_systm.h>
 514      #endif
 515      #ifdef HAVE_NET_IF_H
 516      # include <net/if.h>
 517      #endif
 518      #ifdef HAVE_NETINET_IP_H
 519      # include <netinet/ip.h>
 520      #endif])
 521
 522 AC_CHECK_HEADERS([netinet/tcp_timer.h netinet/udp_var.h netinet/icmp_var.h netinet/tcp_var.h ],,,
 523     [#include <sys/types.h>
 524      #ifdef HAVE_ALIAS_H
 525      # include <alias.h>
 526      #endif
 527      #ifdef HAVE_SYS_SOCKET_H
 528      # include <sys/socket.h>
 529      #endif
 530      #ifdef HAVE_SYS_SOCKETVAR_H
 531      # include <sys/socketvar.h>
 532      #endif
 533      #ifdef HAVE_SYS_TIMEOUT_H
 534      # include <sys/timeout.h>
 535      #endif
 536      #ifdef HAVE_NETINET_IN_H
 537      # include <netinet/in.h>
 538      #endif
 539      #ifdef HAVE_NETINET_IN_SYSTM_H
 540      # include <netinet/in_systm.h>
 541      #endif
 542      #ifdef HAVE_NETINET_IP_H
 543      # include <netinet/ip.h>
 544      #endif
 545      #ifdef HAVE_NETINET_IP_VAR_H
 546      # include <netinet/ip_var.h>
 547      #endif
 548      #ifdef HAVE_NETINET_IP_ICMP_H
 549      # include <netinet/ip_icmp.h>
 550      #endif
 551      #ifdef HAVE_NETINET_UDP_H
 552      # include <netinet/udp.h>
 553      #endif
 554      #ifdef HAVE_NETINET_TCP_H
 555      # include <netinet/tcp.h>
 556      #endif
 557      #ifdef HAVE_NETINET_TCP_TIMER_H
 558      #include <netinet/tcp_timer.h>
 559      #endif])
 560
 561 AC_CHECK_HEADERS([linux/ipx.h linux/irda.h],,,
 562     [#include <sys/types.h>
 563      #ifdef HAVE_ASM_TYPES_H
 564      # include <asm/types.h>
 565      #endif
 566      #ifdef HAVE_SYS_SOCKET_H
 567      # include <sys/socket.h>
 568      #endif
 569      #ifdef HAVE_LINUX_TYPES_H
 570      # include <linux/types.h>
 571      #endif])
 572
 573 AC_CHECK_HEADERS([mach-o/dyld_images.h],,,
 574     [#ifdef HAVE_STDBOOL_H
 575      # include <stdbool.h>
 576      #endif
 577      #ifdef HAVE_STDINT_H
 578      # include <stdint.h>
 579      #endif])
 580
 581 AC_CHECK_HEADERS([resolv.h],,,
 582     [#include <sys/types.h>
 583      #ifdef HAVE_SYS_SOCKET_H
 584      # include <sys/socket.h>
 585      #endif
 586      #ifdef HAVE_NETINET_IN_H
 587      # include <netinet/in.h>
 588      #endif
 589      #ifdef HAVE_ARPA_NAMESER_H
 590      # include <arpa/nameser.h>
 591      #endif])
 592
 593 AC_CHECK_HEADERS([ifaddrs.h],,,[#include <sys/types.h>])
 594
 595 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
 596
 597 AC_CHECK_HEADERS([sys/thr.h],,,
 598 [#include <sys/types.h>
 599 #ifdef HAVE_UCONTEXT_H
 600 #include <ucontext.h>
 601 #endif])
 602
 603 AC_CHECK_HEADERS([pthread_np.h],,,
 604 [#ifdef HAVE_PTHREAD_H
 605 #include <pthread.h>
 606 #endif])
 607
 608 AC_CHECK_HEADERS([linux/videodev.h],,,
 609 [#ifdef HAVE_SYS_TIME_H
 610 #include <sys/time.h>
 611 #endif
 612 #include <sys/types.h>
 613 #ifdef HAVE_ASM_TYPES_H
 614 #include <asm/types.h>
 615 #endif])
 616
 617 dnl Check for broken kernel header that doesn't define __user
 618 AC_CHECK_HEADERS([linux/capi.h],,,[#define __user])
 619
 620 dnl **** Check for working dll ****
 621
 622 AC_SUBST(DLLEXT,"")
 623 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
 624 AC_SUBST(LDSHARED,"")
 625 AC_SUBST(LDDLLFLAGS,"")
 626 AC_SUBST(LIBEXT,"so")
 627 AC_SUBST(IMPLIBEXT,"def")
 628 AC_SUBST(LDRPATH_INSTALL,"")
 629 AC_SUBST(LDRPATH_LOCAL,"")
 630 STATIC_IMPLIBEXT="def.a"
 631 WINE_PATH_LDD
 632
 633 case $host_os in
 634   cygwin*|mingw32*)
 635     AC_CHECK_TOOL(DLLTOOL,dlltool,false)
 636     AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
 637     if test "$DLLWRAP" = "false"; then
 638       LIBEXT="a"
 639     else
 640       dnl FIXME - check whether dllwrap works correctly...
 641       LIBEXT="dll"
 642     fi
 643     IMPLIBEXT="a"
 644     STATIC_IMPLIBEXT="a"
 645     dnl Disable modules that can't be used on Windows
 646     enable_iphlpapi=${enable_iphlpapi:-no}
 647     enable_kernel32=${enable_kernel32:-no}
 648     enable_msvcrt=${enable_msvcrt:-no}
 649     enable_ntdll=${enable_ntdll:-no}
 650     enable_ws2_32=${enable_ws2_32:-no}
 651     enable_loader=${enable_loader:-no}
 652     enable_server=${enable_server:-no}
 653     dnl Disable dependencies that are not useful on Windows
 654     with_x=${with_x:-no}
 655     with_pthread=${with_pthread:-no}
 656     ;;
 657   darwin*|macosx*)
 658     DLLEXT=".so"
 659     LIBEXT="dylib"
 660     DLLFLAGS="$DLLFLAGS -fPIC"
 661     LDDLLFLAGS="-bundle -multiply_defined suppress"
 662     LIBWINE_LDFLAGS="-multiply_defined suppress"
 663     LDSHARED="\$(CC) -dynamiclib"
 664     STRIP="$STRIP -x"
 665     LDRPATH_LOCAL="&& install_name_tool -change @executable_path/\`\$(RELPATH) \$(bindir) \$(libdir)\`/libwine.1.dylib @executable_path/\$(TOPOBJDIR)/libs/wine/libwine.1.dylib \$@ || \$(RM) \$@"
 666     dnl declare needed frameworks
 667     AC_SUBST(SECURITYLIB,"-framework Security -framework CoreFoundation")
 668     AC_SUBST(COREFOUNDATIONLIB,"-framework CoreFoundation")
 669     AC_SUBST(IOKITLIB,"-framework IOKit -framework CoreFoundation")
 670     AC_SUBST(LDEXECFLAGS,["-image_base 0x7bf00000 -Wl,-segaddr,WINE_DOS,0x00000000,-segaddr,WINE_SHAREDHEAP,0x7f000000"])
 671     if test "$ac_cv_header_DiskArbitration_DiskArbitration_h" = "yes"
 672     then
 673         dnl DiskArbitration API is not public on Darwin < 8.0, use it only if header found
 674         AC_SUBST(DISKARBITRATIONLIB,"-framework DiskArbitration -framework CoreFoundation")
 675     fi
 676     if test "$ac_cv_header_CoreAudio_CoreAudio_h" = "yes" -a "$ac_cv_header_AudioUnit_AudioUnit_h" = "yes"
 677     then
 678         dnl CoreServices needed by AudioUnit
 679         AC_SUBST(COREAUDIO,"-framework CoreAudio -framework AudioUnit -framework CoreServices -framework AudioToolbox -framework CoreMIDI")
 680         ac_save_LIBS="$LIBS"
 681         if test "$ac_cv_header_AudioToolbox_AudioFile_h" = "yes"
 682         then
 683             LIBS="$LIBS $COREAUDIO"
 684             AC_CHECK_FUNCS(AudioFileStreamOpen)
 685             LIBS="$ac_save_LIBS"
 686         fi
 687         test "x$ac_cv_func_AudioFileStreamOpen" = xyes || WINE_NOTICE([AudioToolbox version too old, mp3 codec won't be supported.])
 688     fi
 689     if test "$ac_cv_header_OpenAL_al_h" = "yes"
 690     then
 691         AC_SUBST(FRAMEWORK_OPENAL,"-framework OpenAL")
 692         AC_DEFINE_UNQUOTED(HAVE_OPENAL,1,[Define to 1 if OpenAL is available])
 693         ac_cv_lib_openal=yes
 694     fi
 695     if test "$ac_cv_header_IOKit_hid_IOHIDLib_h" = "yes"
 696     then
 697         ac_save_LIBS="$LIBS"
 698         LIBS="$LIBS $IOKITLIB"
 699         AC_CHECK_FUNCS(IOHIDManagerCreate)
 700         LIBS="$ac_save_LIBS"
 701     fi
 702     case $host_cpu in
 703       *powerpc*)
 704         LDDLLFLAGS="$LDDLLFLAGS -read_only_relocs warning"  dnl FIXME
 705         ;;
 706     esac
 707     dnl Enable quartz driver on Mac OS X
 708     if test "$ac_cv_header_Carbon_Carbon_h" = "yes"
 709     then
 710         AC_SUBST(CARBONLIB,"-framework Carbon")
 711         enable_winequartz_drv=${enable_winequartz_drv:-yes}
 712     fi
 713     dnl Check for Xcode 3.x broken 16-bit support
 714     if test "x$enable_win16" = "xyes"
 715     then
 716         AC_MSG_CHECKING([whether 16-bit code can be built correctly])
 717         AC_RUN_IFELSE(AC_LANG_PROGRAM([[asm(".text\n"
 718                                             "bad:\tnop;nop\n"
 719                                             "good:\tnop;nop\n\t"
 720                                             ".globl _testfunc\n"
 721                                             "_testfunc:\tcallw good");
 722                                         extern void testfunc();]],
 723                                       [[unsigned short *p = (unsigned short *)testfunc;
 724                                         return p[[0]] != 0xe866 || p[[1]] != 0xfffa]]),
 725                                       AC_MSG_RESULT(yes),
 726                                       [AC_MSG_RESULT(no)
 727                                        AC_MSG_ERROR([Xcode 3.x cannot build 16-bit code correctly. Use --disable-win16 if you don't need 16-bit support.])],
 728                                        AC_MSG_RESULT([[cross-compiling, assuming yes]]))
 729     fi
 730     ;;
 731   *)
 732     DLLFLAGS="$DLLFLAGS -fPIC"
 733     DLLEXT=".so"
 734     AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
 735         [WINE_TRY_SHLIB_FLAGS([-fPIC -shared -Wl,-Bsymbolic],
 736                               ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
 737     if test "$ac_cv_c_dll_gnuelf" = "yes"
 738     then
 739       LDSHARED="\$(CC) -shared"
 740       LDDLLFLAGS="-shared -Wl,-Bsymbolic"
 741       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-soname,confest.so.1],
 742                       [LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"],
 743                       [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-h,confest.so.1],
 744                                        [LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-h,%)"])])
 745
 746       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs], [LDDLLFLAGS="$LDDLLFLAGS,-z,defs"])
 747
 748       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-init,__wine_spec_init,-fini,__wine_spec_fini],
 749                       [LDDLLFLAGS="$LDDLLFLAGS,-init,__wine_spec_init,-fini,__wine_spec_fini"])
 750
 751       echo '{ global: *; };' >conftest.map
 752       WINE_TRY_CFLAGS([-fPIC -shared -Wl,--version-script=conftest.map],
 753                       [LDSHARED="$LDSHARED \$(VERSCRIPT:%=-Wl,--version-script=%)"])
 754       rm -f conftest.map
 755
 756       WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
 757                       [AC_SUBST(LDEXECFLAGS,["-Wl,--export-dynamic"])])
 758
 759       WINE_TRY_CFLAGS([-fPIC -Wl,--rpath,\$ORIGIN/../lib],
 760                       [LDRPATH_INSTALL="-Wl,--rpath,\\\$\$ORIGIN/\`\$(RELPATH) \$(bindir) \$(libdir)\`"
 761                        LDRPATH_LOCAL="-Wl,--rpath,\\\$\$ORIGIN/\$(TOPOBJDIR)/libs/wine"],
 762           [WINE_TRY_CFLAGS([-fPIC -Wl,-R,\$ORIGIN/../lib],
 763                            [LDRPATH_INSTALL="-Wl,-R,\\\$\$ORIGIN/\`\$(RELPATH) \$(bindir) \$(libdir)\`"
 764                             LDRPATH_LOCAL="-Wl,-R,\\\$\$ORIGIN/\$(TOPOBJDIR)/libs/wine"])])
 765
 766       WINE_TRY_CFLAGS([-Wl,--enable-new-dtags],
 767                       [LDRPATH_INSTALL="$LDRPATH_INSTALL -Wl,--enable-new-dtags"])
 768
 769       case $host_cpu in
 770         *i[[3456789]]86* | x86_64)
 771           WINE_TRY_CFLAGS([-Wl,--section-start,.interp=0x7bf00400],
 772                           [LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x7bf00400"])
 773           ;;
 774       esac
 775
 776     else
 777       AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
 778           [WINE_TRY_SHLIB_FLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
 779                                 ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
 780       if test "$ac_cv_c_dll_unixware" = "yes"
 781       then
 782         LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
 783         LDDLLFLAGS="-Wl,-G,-B,symbolic"
 784
 785       else
 786         AC_CACHE_CHECK(whether we can build an HP-UX dll, ac_cv_c_dll_hpux,
 787           [WINE_TRY_SHLIB_FLAGS([-shared], ac_cv_c_dll_hpux="yes", ac_cv_c_dll_hpux="no")])
 788         if test "$ac_cv_c_dll_hpux" = "yes"
 789         then
 790           LIBEXT="sl"
 791           DLLEXT=".sl"
 792           LDDLLFLAGS="-shared -fPIC"
 793           LDSHARED="\$(CC) -shared"
 794         fi
 795       fi
 796     fi
 797     ;;
 798 esac
 799
 800 enable_winequartz_drv=${enable_winequartz_drv:-no}
 801
 802 if test "$LIBEXT" = "a"; then
 803   AC_MSG_ERROR(
 804 [could not find a way to build shared libraries.
 805 It is currently not possible to build Wine without shared library
 806 (.so) support to allow transparent switch between .so and .dll files.
 807 If you are using Linux, you will need a newer binutils.]
 808 )
 809 fi
 810
 811 dnl Check for cross compiler to build test programs
 812 if test "$cross_compiling" = "no" -a "$LIBEXT" != "dll"
 813 then
 814     WINE_CHECK_MINGW_PROG(CROSSCC,gcc,false)
 815     if test "$CROSSCC" != "false"
 816     then
 817         AC_SUBST(CROSSTEST,"\$(CROSSTEST)")
 818         set x $CROSSCC
 819         shift
 820         target=""
 821         while test $# -ge 1
 822         do
 823             case "$1" in
 824               *-gcc) target=`expr "$1" : '\(.*\)-gcc'` ;;
 825             esac
 826             shift
 827         done
 828         if test -n "$target"
 829         then
 830             AC_SUBST(CROSSTARGET,"$target")
 831         fi
 832     fi
 833 fi
 834
 835 dnl **** Check for pthread ****
 836
 837 if test "$ac_cv_header_pthread_h" = "yes"
 838 then
 839     AC_CHECK_LIB(pthread,pthread_create,[AC_SUBST(LIBPTHREAD,"-lpthread")])
 840 fi
 841 WINE_ERROR_WITH(pthread,[test "x$LIBPTHREAD" = "x"],[pthread ${notice_platform}development files not found.
 842 Wine cannot support threads without libpthread.])
 843
 844 dnl **** Check for X11 ****
 845
 846 AC_PATH_XTRA
 847
 848 if test "$have_x" = "yes"
 849 then
 850     XLIB="-lX11"
 851     ac_save_CPPFLAGS="$CPPFLAGS"
 852     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 853
 854     WINE_CHECK_SONAME(X11,XCreateWindow,,,[$X_LIBS $X_EXTRA_LIBS])
 855     WINE_CHECK_SONAME(Xext,XextCreateExtension,[XLIB="-lXext $XLIB"],,[$X_LIBS -lX11 $X_EXTRA_LIBS])
 856
 857     dnl *** All of the following tests require X11/Xlib.h
 858     AC_CHECK_HEADERS([X11/Xlib.h \
 859                       X11/XKBlib.h \
 860                       X11/Xutil.h \
 861                       X11/Xcursor/Xcursor.h \
 862                       X11/extensions/shape.h \
 863                       X11/extensions/XInput.h \
 864                       X11/extensions/XShm.h \
 865                       X11/extensions/Xcomposite.h \
 866                       X11/extensions/Xinerama.h \
 867                       X11/extensions/Xrandr.h \
 868                       X11/extensions/Xrender.h \
 869                       X11/extensions/xf86vmode.h \
 870                       X11/extensions/xf86vmproto.h],,,
 871 [#ifdef HAVE_X11_XLIB_H
 872 # include <X11/Xlib.h>
 873 #endif
 874 #ifdef HAVE_X11_XUTIL_H
 875 # include <X11/Xutil.h>
 876 #endif])
 877
 878         dnl *** Check for X keyboard extension
 879         if test "$ac_cv_header_X11_XKBlib_h" = "yes"
 880         then
 881               AC_CHECK_LIB(X11, XkbQueryExtension,
 882               AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
 883               $X_LIBS $XLIB $X_EXTRA_LIBS)
 884         fi
 885
 886         dnl *** Check for X cursor
 887         if test "$ac_cv_header_X11_Xcursor_Xcursor_h" = "yes"
 888         then
 889             WINE_CHECK_SONAME(Xcursor,XcursorImageLoadCursor,,,[$X_LIBS $XLIB $X_EXTRA_LIBS])
 890         fi
 891         WINE_NOTICE_WITH(xcursor,[test "x$ac_cv_lib_soname_Xcursor" = "x"],
 892                          [libxcursor ${notice_platform}development files not found, the Xcursor extension won't be supported.])
 893
 894         dnl *** Check for X input extension
 895         if test "$ac_cv_header_X11_extensions_XInput_h" = "yes"
 896         then
 897             WINE_CHECK_SONAME(Xi,XOpenDevice,,,[$X_LIBS $XLIB $X_EXTRA_LIBS])
 898         fi
 899         WINE_NOTICE_WITH(xinput,[test "x$ac_cv_lib_soname_Xi" = "x"],
 900                          [libxi ${notice_platform}development files not found, the Xinput extension won't be supported.])
 901
 902         dnl *** Check for X Shm extension
 903         if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
 904         then
 905               AC_CHECK_LIB(Xext, XShmQueryExtension,
 906               AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
 907               $X_LIBS $XLIB $X_EXTRA_LIBS)
 908         fi
 909         WINE_NOTICE_WITH(xshm,[test "$ac_cv_lib_Xext_XShmQueryExtension" != "yes"],
 910                          [XShm ${notice_platform}development files not found, X Shared Memory won't be supported.])
 911
 912         dnl *** Check for X shape extension
 913         if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
 914         then
 915               AC_CHECK_LIB(Xext,XShapeQueryExtension,
 916               AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
 917               $X_LIBS $XLIB $X_EXTRA_LIBS)
 918         fi
 919         WINE_NOTICE_WITH(xshape,[test "$ac_cv_lib_Xext_XShapeQueryExtension" != "yes"],
 920                          [XShape ${notice_platform}development files not found, XShape won't be supported.])
 921
 922         dnl *** Check for XFree86 VMODE extension
 923         if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes" -o "$ac_cv_header_X11_extensions_xf86vmproto_h" = "yes"
 924         then
 925             WINE_CHECK_SONAME(Xxf86vm,XF86VidModeQueryExtension,,,[$X_LIBS $XLIB $X_EXTRA_LIBS])
 926         fi
 927         WINE_NOTICE_WITH(xxf86vm,[test "x$ac_cv_lib_soname_Xxf86vm" = "x"],
 928                          [libXxf86vm ${notice_platform}development files not found, XFree86 Vidmode won't be supported.])
 929
 930         dnl *** Check for Transform functions in Xrender
 931         if test "$ac_cv_header_X11_extensions_Xrender_h" = "yes" -a "x$ac_cv_lib_soname_X11" != "x" -a "x$ac_cv_lib_soname_Xext" != "x"
 932         then
 933             WINE_CHECK_SONAME(Xrender,XRenderQueryExtension,
 934               [AC_CHECK_LIB(Xrender,XRenderSetPictureTransform,
 935                 [AC_DEFINE(HAVE_XRENDERSETPICTURETRANSFORM, 1,
 936                  [Define if Xrender has the XRenderSetPictureTransform function])],,
 937                 [$X_LIBS $XLIB $X_EXTRA_LIBS])],,[$X_LIBS $XLIB $X_EXTRA_LIBS])
 938
 939         fi
 940         WINE_WARNING_WITH(xrender,[test "x$ac_cv_lib_soname_Xrender" = "x"],
 941                          [libxrender ${notice_platform}development files not found, XRender won't be supported.])
 942
 943         dnl *** Check for X RandR extension
 944         if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes" -a "x$ac_cv_lib_soname_Xrender" != "x"
 945         then
 946                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
 947 #include <X11/extensions/Xrandr.h>]], [[static typeof(XRRSetScreenConfigAndRate) * func;]])],
 948                   [WINE_CHECK_SONAME(Xrandr,XRRQueryExtension,,,[$X_LIBS $XLIB $X_EXTRA_LIBS])])
 949         fi
 950         WINE_NOTICE_WITH(xrandr,[test "x$ac_cv_lib_soname_Xrandr" = "x"],
 951                          [libxrandr ${notice_platform}development files not found, XRandr won't be supported.])
 952
 953         dnl *** Check for Xinerama extension
 954         if test "$ac_cv_header_X11_extensions_Xinerama_h" = "yes"
 955         then
 956                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
 957 #include <X11/extensions/Xinerama.h>]], [[static typeof(XineramaQueryScreens) * func;]])],
 958                   [WINE_CHECK_SONAME(Xinerama,XineramaQueryScreens,,,[$X_LIBS $XLIB $X_EXTRA_LIBS])])
 959         fi
 960         WINE_NOTICE_WITH(xinerama,[test "x$ac_cv_lib_soname_Xinerama" = "x"],
 961                          [libxinerama ${notice_platform}development files not found, multi-monitor setups won't be supported.])
 962
 963         dnl *** Check for X Composite extension
 964         if test "$ac_cv_header_X11_extensions_Xcomposite_h" = "yes"
 965         then
 966             WINE_CHECK_SONAME(Xcomposite,XCompositeRedirectWindow,,,[$X_LIBS $XLIB $X_EXTRA_LIBS])
 967         fi
 968         WINE_NOTICE_WITH(xcomposite,[test "x$ac_cv_lib_soname_Xcomposite" = "x"],
 969                          [libxcomposite ${notice_platform}development files not found, Xcomposite won't be supported.])
 970
 971         dnl *** Check for XICCallback struct
 972         AC_CHECK_MEMBERS([XICCallback.callback],,,
 973 [#ifdef HAVE_X11_XLIB_H
 974 #include <X11/Xlib.h>
 975 #endif])
 976
 977     dnl *** End of X11/Xlib.h check
 978
 979     dnl Check for the presence of OpenGL
 980     opengl_msg=""
 981     if test "x$with_opengl" != "xno"
 982     then
 983         AC_CHECK_HEADERS(GL/gl.h GL/glx.h GL/glu.h,,,
 984 [#ifdef HAVE_GL_GLX_H
 985 # include <GL/glx.h>
 986 #endif])
 987         if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
 988         then
 989             dnl Check for some problems due to old Mesa versions
 990             AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_header_version_OK,
 991               AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GL/gl.h>]], [[GLenum test = GL_UNSIGNED_SHORT_5_6_5;]])],
 992                 [wine_cv_opengl_header_version_OK="yes"],
 993                 [wine_cv_opengl_header_version_OK="no"]))
 994
 995             if test "$wine_cv_opengl_header_version_OK" = "yes"
 996             then
 997                 dnl Check for the presence of the library
 998                 WINE_CHECK_SONAME(GL,glXCreateContext,
 999                              [OPENGL_LIBS="-lGL"
1000                              AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])],
1001                              [WINE_CHECK_SONAME(GL,glXCreateContext,
1002                                     [OPENGL_LIBS="-Xlinker -dylib_file -Xlinker /System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib:/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib -lGL"
1003                                     AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])],
1004                                     [if test -f /usr/X11R6/lib/libGL.a
1005                                     then
1006                                         opengl_msg="/usr/X11R6/lib/libGL.a is present on your system.
1007 This probably prevents linking to OpenGL. Try deleting the file and restarting configure."
1008                                     else
1009                                         opengl_msg="No OpenGL library found on this system."
1010                                     fi],
1011                                     $X_LIBS $XLIB -lm $X_EXTRA_LIBS -dylib_file /System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib:/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib)],
1012                              $X_LIBS $XLIB -lm $X_EXTRA_LIBS)
1013                  if test "$ac_cv_header_GL_glu_h" = "yes"
1014                  then
1015                     WINE_CHECK_SONAME(GLU,gluLookAt,,,[$OPENGL_LIBS $X_LIBS $X_PRE_LIBS $XLIB -lm $X_EXTRA_LIBS])
1016                  fi
1017                  WINE_NOTICE_WITH(glu,[test "x$ac_cv_lib_soname_GLU" = "x"],
1018                                  [libGLU ${notice_platform}development files not found, GLU won't be supported.])
1019              else
1020                  opengl_msg="Old Mesa headers detected. Consider upgrading your Mesa libraries."
1021              fi
1022          else
1023              opengl_msg="OpenGL development headers not found."
1024          fi
1025          test -n "$opengl_msg" && enable_opengl32=${enable_opengl32:-no}
1026          test "x$ac_cv_lib_soname_GLU" = "x" && enable_glu32=${enable_glu32:-no}
1027     else
1028          enable_opengl32=${enable_opengl32:-no}
1029          enable_glu32=${enable_glu32:-no}
1030     fi
1031     WINE_WARNING_WITH(opengl,[test -n "$opengl_msg"],[$opengl_msg
1032 OpenGL and Direct3D won't be supported.])
1033
1034     dnl **** Check for NAS ****
1035     AC_SUBST(NASLIBS,"")
1036     AC_CHECK_HEADERS(audio/audiolib.h,
1037          [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
1038           AC_CHECK_LIB(audio,AuCreateFlow,
1039                        [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
1040                         AC_CHECK_LIB(Xau,XauGetBestAuthByAddr,
1041                           [NASLIBS="-lXau -laudio -lXt $X_LIBS $XLIB $X_EXTRA_LIBS"],
1042                           [NASLIBS="-laudio -lXt $X_LIBS $XLIB $X_EXTRA_LIBS"],
1043                           [$X_LIBS])
1044                        ],,
1045                        [-lXt $X_LIBS $XLIB $X_EXTRA_LIBS])])
1046
1047     CPPFLAGS="$ac_save_CPPFLAGS"
1048 else
1049     XLIB=""
1050     X_CFLAGS=""
1051     X_LIBS=""
1052     enable_winex11_drv=${enable_winex11_drv:-no}
1053     enable_opengl32=${enable_opengl32:-no}
1054     enable_glu32=${enable_glu32:-no}
1055 fi
1056 WINE_ERROR_WITH(x,[test "x$XLIB" = "x"],[X ${notice_platform}development files not found. Wine will be built
1057 without X support, which probably isn't what you want. You will need to install
1058 ${notice_platform}development packages of Xlib/Xfree86 at the very least.])
1059
1060 dnl **** Check for libxml2 ****
1061
1062 AC_SUBST(XML2LIBS,"")
1063 AC_SUBST(XML2INCL,"")
1064 AC_SUBST(XSLTINCL,"")
1065 if test "x$with_xml" != "xno"
1066 then
1067     ac_save_CPPFLAGS="$CPPFLAGS"
1068     if test "$PKG_CONFIG" != "false"
1069     then
1070         ac_xml_libs="`$PKG_CONFIG --libs libxml-2.0 2>/dev/null`"
1071         ac_xml_cflags="`$PKG_CONFIG --cflags libxml-2.0 2>/dev/null`"
1072     else
1073         ac_xml_libs="`xml2-config --libs 2>/dev/null`"
1074         ac_xml_cflags="`xml2-config --cflags  2>/dev/null`"
1075     fi
1076     CPPFLAGS="$CPPFLAGS $ac_xml_cflags"
1077     AC_CHECK_HEADERS(libxml/parser.h,
1078             [AC_CHECK_LIB(xml2, xmlParseMemory,
1079                 [AC_DEFINE(HAVE_LIBXML2, 1, [Define if you have the libxml2 library])
1080                  XML2LIBS="$ac_xml_libs"
1081                  XML2INCL="$ac_xml_cflags"],,$ac_xml_libs)
1082              AC_CHECK_LIB(xml2, xmlReadMemory,
1083                 [AC_DEFINE(HAVE_XMLREADMEMORY,1,[Define if libxml2 has the xmlReadMemory function])],,$ac_xml_libs)
1084              AC_CHECK_LIB(xml2, xmlNewDocPI,
1085                 [AC_DEFINE(HAVE_XMLNEWDOCPI,1,[Define if libxml2 has the xmlNewDocPI function])],,$ac_xml_libs)
1086         ])
1087     CPPFLAGS="$ac_save_CPPFLAGS"
1088 fi
1089 WINE_WARNING_WITH(xml,[test "$ac_cv_lib_xml2_xmlParseMemory" != "yes"],
1090                  [libxml2 ${notice_platform}development files not found, XML won't be supported.])
1091
1092 if test "x$with_xslt" != "xno"
1093 then
1094     if test "$PKG_CONFIG" != "false"
1095     then
1096         ac_xslt_libs="`$PKG_CONFIG --libs libxslt 2>/dev/null`"
1097         ac_xslt_cflags="`$PKG_CONFIG --cflags libxslt 2>/dev/null`"
1098     else
1099         ac_xslt_libs="`xslt-config --libs 2>/dev/null`"
1100         ac_xslt_cflags="`xslt-config --cflags 2>/dev/null`"
1101     fi
1102     ac_save_CPPFLAGS="$CPPFLAGS"
1103     CPPFLAGS="$CPPFLAGS $ac_xslt_cflags"
1104     AC_CHECK_HEADERS([libxslt/pattern.h libxslt/transform.h],,,
1105     [#ifdef HAVE_LIBXSLT_PATTERN_H
1106 # include <libxslt/pattern.h>
1107 #endif])
1108     CPPFLAGS="$ac_save_CPPFLAGS"
1109     if test "$ac_cv_header_libxslt_transform_h" = "yes"
1110     then
1111         WINE_CHECK_SONAME(xslt,xsltCompilePattern,
1112                          [XSLTINCL="$ac_xslt_cflags"],,[$ac_xslt_libs])
1113     fi
1114 fi
1115 WINE_WARNING_WITH(xslt,[test "x$ac_cv_lib_soname_xslt" = "x"],
1116                  [libxslt ${notice_platform}development files not found, xslt won't be supported.])
1117
1118 dnl **** Check for libhal ****
1119 AC_SUBST(HALINCL,"")
1120 if test "x$with_hal" != "xno"
1121 then
1122     ac_save_CPPFLAGS="$CPPFLAGS"
1123     if test "$PKG_CONFIG" != "false"
1124     then
1125         ac_hal_libs="`$PKG_CONFIG --libs hal 2>/dev/null`"
1126         ac_hal_cflags="`$PKG_CONFIG --cflags hal 2>/dev/null`"
1127         CPPFLAGS="$CPPFLAGS $ac_hal_cflags"
1128     fi
1129     AC_CHECK_HEADERS([dbus/dbus.h hal/libhal.h])
1130     if test "$ac_cv_header_dbus_dbus_h" = "yes" -a "$ac_cv_header_hal_libhal_h" = "yes"
1131     then
1132         AC_CHECK_LIB(dbus-1, dbus_connection_close,
1133           [WINE_CHECK_SONAME(hal, libhal_ctx_new,
1134             [HALINCL="$ac_hal_cflags"],,[$ac_hal_libs])],,[$ac_hal_libs])
1135     fi
1136     CPPFLAGS="$ac_save_CPPFLAGS"
1137 fi
1138 WINE_NOTICE_WITH(hal,[test "x$ac_cv_lib_soname_hal" = "x"],
1139                  [libhal/libdbus ${notice_platform}development files not found, no dynamic device support.])
1140
1141 dnl **** Check for libgnutls ****
1142 if test "x$with_gnutls" != "xno"
1143 then
1144     ac_save_CPPFLAGS="$CPPFLAGS"
1145     if test "$PKG_CONFIG" != "false"
1146     then
1147         ac_gnutls_libs="`$PKG_CONFIG --libs gnutls 2>/dev/null`"
1148         ac_gnutls_cflags="`$PKG_CONFIG --cflags gnutls 2>/dev/null`"
1149         CPPFLAGS="$CPPFLAGS $ac_gnutls_cflags"
1150     fi
1151     AC_CHECK_HEADER(gnutls/gnutls.h,
1152         [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <gnutls/gnutls.h>]], [[typeof(gnutls_mac_get_key_size) *pfunc;]])],
1153             [WINE_CHECK_SONAME(gnutls,gnutls_global_init,
1154                 [AC_SUBST(GNUTLSINCL,"$ac_gnutls_cflags")],,[$ac_gnutls_libs])])])
1155     CPPFLAGS="$ac_save_CPPFLAGS"
1156 fi
1157 WINE_NOTICE_WITH(gnutls,[test "x$ac_cv_lib_soname_gnutls" = "x"],
1158                  [libgnutls ${notice_platform}development files not found, no schannel support.])
1159
1160 dnl **** Check which curses lib to use ***
1161 CURSESLIBS=""
1162 if test "$ac_cv_header_ncurses_h" = "yes"
1163 then
1164     WINE_CHECK_SONAME(ncurses,waddch,[CURSESLIBS="-lncurses"])
1165 elif test "$ac_cv_header_curses_h" = "yes"
1166 then
1167     WINE_CHECK_SONAME(curses,waddch,[CURSESLIBS="-lcurses"])
1168 fi
1169 ac_save_LIBS="$LIBS"
1170 LIBS="$LIBS $CURSESLIBS"
1171 AC_CHECK_FUNCS(mousemask)
1172 LIBS="$ac_save_LIBS"
1173 WINE_NOTICE_WITH(curses,[test "x$ac_cv_lib_soname_curses$ac_cv_lib_soname_ncurses" = "x"],
1174                  [lib(n)curses ${notice_platform}development files not found, curses won't be supported.])
1175
1176 dnl **** Check for SANE ****
1177 if test "x$with_sane" != "xno"
1178 then
1179     ac_save_CPPFLAGS="$CPPFLAGS"
1180     AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
1181     if test "$sane_devel" != "no"
1182     then
1183         ac_sane_incl="`$sane_devel --cflags`"
1184         ac_sane_libs="`$sane_devel --ldflags`"
1185         CPPFLAGS="$CPPFLAGS $ac_sane_incl"
1186     fi
1187     AC_CHECK_HEADER(sane/sane.h,
1188         [WINE_CHECK_SONAME(sane,sane_init,[AC_SUBST(SANEINCL,"$ac_sane_incl")],,[$ac_sane_libs])])
1189     CPPFLAGS="$ac_save_CPPFLAGS"
1190 fi
1191 WINE_NOTICE_WITH(sane,[test "x$ac_cv_lib_soname_sane" = "x"],
1192                  [libsane ${notice_platform}development files not found, scanners won't be supported.])
1193
1194 dnl **** Check for libv4l1 ****
1195 if test "x$with_v4l" != "xno"
1196 then
1197     WINE_CHECK_SONAME(v4l1,v4l1_open,,,)
1198 fi
1199 WINE_NOTICE_WITH(v4l,[test "x$ac_cv_lib_soname_v4l1" = "x"],
1200                  [libv4l ${notice_platform}development files not found.])
1201
1202 dnl **** Check for libgphoto2 ****
1203 if test "x$with_gphoto" != "xno"
1204 then
1205     ac_save_CPPFLAGS="$CPPFLAGS"
1206     AC_CHECK_PROG(gphoto2_devel,gphoto2-config,gphoto2-config,no)
1207     AC_CHECK_PROG(gphoto2port_devel,gphoto2-port-config,gphoto2-port-config,no)
1208     if test "$gphoto2_devel" != "no" -a "$gphoto2port_devel" != "no"
1209     then
1210         ac_gphoto2_incl="`$gphoto2_devel --cflags` `$gphoto2port_devel --cflags`"
1211         ac_gphoto2_libs=""
1212         for i in `$gphoto2_devel --libs` `$gphoto2port_devel --libs`
1213         do
1214             case "$i" in
1215             -L/usr/lib|-L/usr/lib64) ;;
1216             -L*|-l*) ac_gphoto2_libs="$ac_gphoto2_libs $i";;
1217             esac
1218         done
1219         CPPFLAGS="$CPPFLAGS $ac_gphoto2_incl"
1220     fi
1221     ac_gphoto2_libs=${ac_gphoto2_libs:-"-lgphoto2"}
1222     AC_CHECK_HEADER(gphoto2-camera.h,
1223                     [AC_CHECK_LIB(gphoto2,gp_camera_new,
1224                                   [AC_DEFINE(HAVE_GPHOTO2, 1, [Define if we have libgphoto2 development environment])
1225                                    AC_SUBST(GPHOTO2LIBS,"$ac_gphoto2_libs")
1226                                    AC_SUBST(GPHOTO2INCL,"$ac_gphoto2_incl")],,
1227                                   [$ac_gphoto2_libs])])
1228     CPPFLAGS="$ac_save_CPPFLAGS"
1229 fi
1230 WINE_NOTICE_WITH(gphoto,[test "$ac_cv_lib_gphoto2_gp_camera_new" != "yes"],
1231                  [libgphoto2 ${notice_platform}development files not found, digital cameras won't be supported.])
1232
1233
1234 dnl **** Check for resolver library ***
1235 AC_SUBST(RESOLVLIBS,"")
1236 if test "$ac_cv_header_resolv_h" = "yes"
1237 then
1238     ac_save_LIBS="$LIBS"
1239     LIBS="$LIBS -lresolv"
1240     AC_LINK_IFELSE([AC_LANG_PROGRAM([[#ifdef HAVE_NETINET_IN_H
1241 #include <netinet/in.h>
1242 #endif
1243 #include <resolv.h>]],[[res_init();]])],
1244         [AC_DEFINE(HAVE_RESOLV, 1, [Define if you have the resolver library and header])
1245          RESOLVLIBS="-lresolv"])
1246     LIBS="$ac_save_LIBS"
1247 fi
1248
1249 dnl **** Check for LittleCMS ***
1250 AC_SUBST(LCMSLIBS,"")
1251 if test "$ac_cv_header_lcms_h" = "yes" -o "$ac_cv_header_lcms_lcms_h" = "yes"
1252 then
1253     AC_CHECK_LIB(lcms, cmsOpenProfileFromFile,
1254         [AC_DEFINE(HAVE_LCMS, 1, [Define if you have the LittleCMS development environment])
1255          LCMSLIBS="-llcms"])
1256 fi
1257 WINE_NOTICE_WITH(cms,[test "$ac_cv_lib_lcms_cmsOpenProfileFromFile" != "yes"],
1258                  [liblcms ${notice_platform}development files not found, Color Management won't be supported.])
1259
1260 dnl **** Check for FreeType 2 ****
1261 if test "x$with_freetype" != "xno"
1262 then
1263     AC_CHECK_PROGS(ft_devel,[freetype-config freetype2-config],no)
1264     if test "$ft_devel" != "no"
1265     then
1266         ac_freetype_incl=`$ft_devel --cflags`
1267         ac_freetype_libs=`$ft_devel --libs`
1268     fi
1269     ac_freetype_libs=${ac_freetype_libs:-"-lfreetype"}
1270     WINE_CHECK_SONAME(freetype,FT_Init_FreeType,[ft_lib=yes],[ft_lib=no],[$ac_freetype_libs])
1271     if test "$ft_lib" = "yes"
1272     then
1273         ac_save_CPPFLAGS="$CPPFLAGS"
1274         CPPFLAGS="$ac_freetype_incl $CPPFLAGS"
1275         AC_CHECK_HEADERS(ft2build.h \
1276                          freetype/freetype.h \
1277                          freetype/ftglyph.h \
1278                          freetype/fttypes.h \
1279                          freetype/tttables.h \
1280                          freetype/ftsnames.h \
1281                          freetype/ttnameid.h \
1282                          freetype/ftoutln.h \
1283                          freetype/ftwinfnt.h \
1284                          freetype/ftmodapi.h \
1285                          freetype/ftlcdfil.h \
1286                          freetype/internal/sfnt.h,,,
1287                          [#ifdef HAVE_FT2BUILD_H
1288                           # include <ft2build.h>
1289                           #endif])
1290         AC_PREPROC_IFELSE([AC_LANG_SOURCE([[#include <ft2build.h>
1291                     #include <freetype/fttrigon.h>]])],[AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
1292           [Define if you have the <freetype/fttrigon.h> header file.])
1293                     wine_cv_fttrigon=yes],[wine_cv_fttrigon=no])
1294         AC_CHECK_TYPES(FT_TrueTypeEngineType,,,[#include <freetype/ftmodapi.h>])
1295         ac_save_CFLAGS="$CFLAGS"
1296         CFLAGS="$CFLAGS $ac_freetype_libs"
1297         AC_CHECK_FUNCS(FT_Load_Sfnt_Table)
1298         CFLAGS="$ac_save_CFLAGS"
1299         CPPFLAGS="$ac_save_CPPFLAGS"
1300         dnl Check that we have at least freetype/freetype.h
1301         if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
1302         then
1303             AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
1304             AC_SUBST(FREETYPELIBS,"$ac_freetype_libs")
1305             AC_SUBST(FREETYPEINCL,"$ac_freetype_incl")
1306         fi
1307     fi
1308 fi
1309 WINE_ERROR_WITH(freetype,[test "x$FREETYPELIBS" = "x"],[FreeType ${notice_platform}development files not found. Fonts will not be built.])
1310 test "x$FREETYPELIBS" = "x" && enable_fonts=${enable_fonts:-no}
1311
1312 dnl **** Check for parport (currently Linux only) ****
1313 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
1314  AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef HAVE_SYS_IOCTL_H
1315 # include <sys/ioctl.h>
1316 #endif
1317 #include <linux/ppdev.h>]], [[ioctl (1,PPCLAIM,0)]])],
1318     [ac_cv_c_ppdev="yes"],[ac_cv_c_ppdev="no"]))
1319 if test "$ac_cv_c_ppdev" = "yes"
1320 then
1321     AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
1322 fi
1323
1324 dnl **** Check for pthread functions ****
1325 WINE_CHECK_LIB_FUNCS(\
1326         pthread_attr_get_np \
1327         pthread_getattr_np \
1328         pthread_get_stackaddr_np \
1329         pthread_get_stacksize_np,
1330         [$LIBPTHREAD])
1331
1332 dnl **** Check for zlib ****
1333 if test "$ac_cv_header_zlib_h" = "yes"
1334 then
1335     AC_CHECK_LIB(z,inflate,[AC_DEFINE(HAVE_ZLIB,1,[Define to 1 if you have the `z' library (-lz).])
1336                             AC_SUBST(ZLIB,"-lz")])
1337 fi
1338
1339 dnl **** Check for EsounD ****
1340 if test "x$with_esd" != xno
1341 then
1342     save_CFLAGS="$CFLAGS"
1343     AC_PATH_PROG(ESDCONFIG, esd-config, no)
1344     if test "x$ESDCONFIG" != "xno"
1345     then
1346         ac_esd_incl=""
1347         for i in `$ESDCONFIG --cflags`
1348         do
1349             case "$i" in
1350                 -I*) ac_esd_incl="$ac_esd_incl $i";;
1351             esac
1352         done
1353         ac_esd_libs=`$ESDCONFIG --libs`
1354         CFLAGS="$CFLAGS $ac_esd_incl"
1355     fi
1356     ac_esd_libs=${ac_esd_libs:-"-lesd"}
1357     AC_CHECK_HEADER(esd.h,
1358         [AC_CHECK_LIB(esd,esd_open_sound,
1359             [AC_SUBST(ESDINCL, "$ac_esd_incl")
1360              AC_SUBST(ESDLIBS, "$ac_esd_libs")
1361              AC_DEFINE(HAVE_ESD, 1, [Define if you have EsounD sound server])],,
1362             [$ac_esd_libs])])
1363     CFLAGS="$save_CFLAGS"
1364 fi
1365
1366 dnl **** Check for ALSA 1.x ****
1367 AC_SUBST(ALSALIBS,"")
1368 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
1369 then
1370     AC_CHECK_LIB(asound,snd_pcm_hw_params_get_access,
1371         [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef HAVE_ALSA_ASOUNDLIB_H
1372 #include <alsa/asoundlib.h>
1373 #elif defined(HAVE_SYS_ASOUNDLIB_H)
1374 #include <sys/asoundlib.h>
1375 #endif]], [[int ret = snd_pcm_hw_params_get_access(NULL, NULL)]])],
1376                         [AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA 1.x including devel headers])
1377                          ALSALIBS="-lasound"],[])])
1378 fi
1379
1380 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
1381 AC_SUBST(AUDIOIOLIBS,"")
1382 if test "$ac_cv_header_libaudioio_h" = "yes"
1383 then
1384     AC_CHECK_LIB(audioio,AudioIOGetVersion,
1385                   [AUDIOIOLIBS="-laudioio"
1386                    AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])
1387 fi
1388
1389 dnl **** Check for capi4linux ****
1390
1391 if test "$ac_cv_header_capi20_h" = "yes" -a "$ac_cv_header_linux_capi_h" = "yes"
1392 then
1393     WINE_CHECK_SONAME(capi20,capi20_register)
1394 fi
1395 WINE_NOTICE_WITH(capi,[test "x$ac_cv_lib_soname_capi20" = "x"],
1396                  [libcapi20 ${notice_platform}development files not found, ISDN won't be supported.])
1397
1398 dnl **** Check for cups ****
1399 AC_SUBST(CUPSINCL,"")
1400 if test "x$with_cups" != "xno"
1401 then
1402     ac_save_CPPFLAGS="$CPPFLAGS"
1403     ac_cups_cflags=`cups-config --cflags 2>/dev/null`
1404     ac_cups_libs=`cups-config --ldflags 2>/dev/null`
1405     CPPFLAGS="$CPPFLAGS $ac_cups_cflags"
1406     AC_CHECK_HEADERS(cups/cups.h,
1407             [WINE_CHECK_SONAME(cups,cupsGetDefault,
1408                        [CUPSINCL="$ac_cups_cflags"],,
1409                        [$ac_cups_libs])])
1410     CPPFLAGS="$ac_save_CPPFLAGS"
1411 fi
1412 WINE_NOTICE_WITH(cups,[test "x$ac_cv_lib_soname_cups" = "x"],
1413                  [libcups ${notice_platform}development files not found, CUPS won't be supported.])
1414
1415 dnl **** Check for jack ****
1416 if test "$ac_cv_header_jack_jack_h" = "yes"
1417 then
1418     WINE_CHECK_SONAME(jack,jack_client_new,,,,[[libjack-*[[0-9.]]*]])
1419 fi
1420
1421 dnl **** Check for fontconfig ****
1422 if test "$ac_cv_header_fontconfig_fontconfig_h" = "yes"
1423 then
1424     WINE_CHECK_SONAME(fontconfig,FcInit)
1425 elif test -n "$X_CFLAGS" -a "x$with_fontconfig" != "xno"
1426 then
1427     dnl fontconfig is in the X directory on Mac OS X
1428     ac_save_CPPFLAGS="$CPPFLAGS"
1429     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
1430     $as_unset ac_cv_header_fontconfig_fontconfig_h
1431     AC_CHECK_HEADERS([fontconfig/fontconfig.h])
1432     CPPFLAGS="$ac_save_CPPFLAGS"
1433     if test "$ac_cv_header_fontconfig_fontconfig_h" = "yes"
1434     then
1435         AC_SUBST(FONTCONFIGINCL,"$X_CFLAGS")
1436         WINE_CHECK_SONAME(fontconfig,FcInit,,,[$X_LIBS])
1437     fi
1438 fi
1439 WINE_NOTICE_WITH(fontconfig,[test "x$ac_cv_lib_soname_fontconfig" = "x"],
1440                  [fontconfig ${notice_platform}development files not found, fontconfig won't be supported.])
1441
1442 dnl **** Check for SSL ****
1443 if test "$ac_cv_header_openssl_err_h" = "yes" -a "$ac_cv_header_openssl_ssl_h" = "yes"
1444 then
1445     WINE_CHECK_SONAME(ssl,SSL_library_init)
1446     WINE_CHECK_SONAME(crypto,BIO_new_socket)
1447 fi
1448 WINE_WARNING_WITH(openssl,[test "x$ac_cv_lib_soname_ssl" = "x" -o "x$ac_cv_lib_soname_crypto" = "x"],
1449                  [OpenSSL ${notice_platform}development files not found, SSL won't be supported.])
1450
1451 dnl **** Check for gsm codec ****
1452 if test "$ac_cv_header_gsm_h" = "yes" -o "$ac_cv_header_gsm_gsm_h" = "yes"
1453 then
1454     WINE_CHECK_SONAME(gsm,gsm_create)
1455 fi
1456 WINE_NOTICE_WITH(gsm,[test "x$ac_cv_lib_soname_gsm" = "x"],
1457                  [libgsm ${notice_platform}development files not found, gsm 06.10 codec won't be supported.])
1458
1459 dnl **** Check for libjpeg ****
1460 if test "$ac_cv_header_jpeglib_h" = "yes"
1461 then
1462     WINE_CHECK_SONAME(jpeg,jpeg_start_decompress)
1463 fi
1464 WINE_WARNING_WITH(jpeg,[test "x$ac_cv_lib_soname_jpeg" = "x"],
1465                  [libjpeg ${notice_platform}development files not found, JPEG won't be supported.])
1466
1467 dnl **** Check for libpng ****
1468 if test "$ac_cv_header_png_h" = "yes"
1469 then
1470     WINE_CHECK_SONAME(png,png_create_read_struct,,,-lm -lz,[[libpng[[0-9]]*]])
1471     AC_CHECK_LIB(png,png_set_expand_gray_1_2_4_to_8,
1472         [AC_DEFINE(HAVE_PNG_SET_EXPAND_GRAY_1_2_4_TO_8,1,[Define to 1 if libpng has the png_set_expand_gray_1_2_4_to_8 function.])]
1473         ,,-lm -lz)
1474 elif test -n "$X_CFLAGS" -a "x$with_png" != "xno"
1475 then
1476     dnl libpng is in the X directory on Mac OS X
1477     ac_save_CPPFLAGS="$CPPFLAGS"
1478     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
1479     $as_unset ac_cv_header_png_h
1480     AC_CHECK_HEADERS([png.h])
1481     CPPFLAGS="$ac_save_CPPFLAGS"
1482     if test "$ac_cv_header_png_h" = "yes"
1483     then
1484         AC_SUBST(PNGINCL,"$X_CFLAGS")
1485         WINE_CHECK_SONAME(png,png_create_read_struct,,,[$X_LIBS -lm -lz],[[libpng[[0-9]]*]])
1486         AC_CHECK_LIB(png,png_set_expand_gray_1_2_4_to_8,
1487                 [AC_DEFINE(HAVE_PNG_SET_EXPAND_GRAY_1_2_4_TO_8,1)],,[$X_LIBS -lm -lz])
1488     fi
1489 fi
1490 WINE_WARNING_WITH(png,[test "x$ac_cv_lib_soname_png" = "x"],
1491                  [libpng ${notice_platform}development files not found, PNG won't be supported.])
1492
1493 dnl **** Check for libtiff ****
1494 if test "$ac_cv_header_tiffio_h" = "yes"
1495 then
1496     WINE_CHECK_SONAME(tiff,TIFFClientOpen)
1497 fi
1498 WINE_NOTICE_WITH(tiff,[test "x$ac_cv_lib_soname_tiff" = "x"],
1499                  [libtiff ${notice_platform}development files not found, TIFF won't be supported.])
1500
1501 dnl **** Check for mpg123 ****
1502 if test "$ac_cv_header_mpg123_h" = "yes"
1503 then
1504     AC_CHECK_LIB(mpg123,mpg123_feed,[AC_SUBST(LIBMPG123,"-lmpg123")])
1505 fi
1506 WINE_NOTICE_WITH(mpg123,[test "x$ac_cv_lib_mpg123_mpg123_feed" != xyes -a x"$ac_cv_header_CoreAudio_CoreAudio_h" != xyes],
1507                  [libmpg123 ${notice_platform}development files not found (or too old), mp3 codec won't be supported.])
1508 test "x$ac_cv_lib_mpg123_mpg123_feed" = xyes -o "x$ac_cv_func_AudioFileStreamOpen" = xyes || enable_winemp3_acm=${enable_winemp3_acm:-no}
1509
1510 dnl **** Check for OpenAL 1.1 ****
1511 if test "$ac_cv_header_AL_al_h" = "yes"
1512 then
1513     WINE_CHECK_SONAME(openal,alGetSource3i,[AC_SUBST(LIBOPENAL,"-lopenal")
1514                       ac_cv_lib_openal=yes
1515                       AC_DEFINE_UNQUOTED(HAVE_OPENAL,1,[Define to 1 if OpenAL is available])],,)
1516 fi
1517 WINE_NOTICE_WITH(openal,[test "x$ac_cv_lib_openal" != xyes],
1518                  [libopenal ${notice_platform}development files not found (or too old), OpenAL won't be supported.])
1519 test "x$ac_cv_lib_openal" = xyes || enable_openal32=${enable_openal32:-no}
1520
1521 dnl **** Check for libkstat ****
1522 if test "$ac_cv_header_kstat_h" = "yes"
1523 then
1524     AC_CHECK_LIB(kstat,kstat_open,
1525                  [AC_DEFINE(HAVE_LIBKSTAT, 1, [Define to 1 if you have the `kstat' library (-lkstat).])
1526                   AC_SUBST(LIBKSTAT,"-lkstat")])
1527 fi
1528
1529 dnl **** Check for libodbc ****
1530 WINE_CHECK_SONAME(odbc,SQLConnect,,[AC_DEFINE_UNQUOTED(SONAME_LIBODBC,["libodbc.$LIBEXT"])])
1531
1532 dnl **** Check for any sound system ****
1533 if test "x$ALSALIBS$AUDIOIOLIBS$COREAUDIO$NASLIBS$ESDLIBS$ac_cv_lib_soname_jack" = "x" -a \
1534         "$ac_cv_header_sys_soundcard_h" != "yes" -a \
1535         "$ac_cv_header_machine_soundcard_h" != "yes" -a \
1536         "$ac_cv_header_soundcard_h" != "yes" -a \
1537         "x$with_alsa$with_audioio$with_coreaudio$with_nas$with_esd$with_jack$with_oss" != xnonononononono
1538 then
1539     WINE_WARNING([No sound system was found. Windows applications will be silent.])
1540 fi
1541
1542 dnl **** Check for gcc specific options ****
1543
1544 AC_SUBST(EXTRACFLAGS,"")
1545 if test "x${GCC}" = "xyes"
1546 then
1547   EXTRACFLAGS="-Wall -pipe"
1548
1549   dnl Check for strength-reduce bug
1550   AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
1551                   AC_RUN_IFELSE([AC_LANG_PROGRAM([[int L[[4]] = {0,1,2,3};]],
1552 [[static int Array[[3]];
1553   unsigned int B = 3;
1554   int i;
1555   for(i=0; i<B; i++) Array[[i]] = i - 3;
1556   for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
1557   L[[i]] = 4;
1558   return (Array[[1]] != -2 || L[[2]] != 3)]])],
1559     [ac_cv_c_gcc_strength_bug="no"],[ac_cv_c_gcc_strength_bug="yes"],[ac_cv_c_gcc_strength_bug="yes"]) )
1560   if test "$ac_cv_c_gcc_strength_bug" = "yes"
1561   then
1562     EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
1563   fi
1564
1565   dnl Check for some compiler flags
1566   WINE_TRY_CFLAGS([-fno-builtin],[AC_SUBST(BUILTINFLAG,"-fno-builtin")])
1567   WINE_TRY_CFLAGS([-fno-strict-aliasing])
1568   WINE_TRY_CFLAGS([-Wdeclaration-after-statement])
1569   WINE_TRY_CFLAGS([-Wstrict-prototypes])
1570   WINE_TRY_CFLAGS([-Wtype-limits])
1571   WINE_TRY_CFLAGS([-Wwrite-strings])
1572
1573   dnl Check for noisy string.h
1574   saved_CFLAGS="$CFLAGS"
1575   CFLAGS="$CFLAGS -Wpointer-arith -Werror"
1576   AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
1577       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string.h>]], [[]])],[ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
1578   CFLAGS="$saved_CFLAGS"
1579   if test "$ac_cv_c_string_h_warnings" = "no"
1580   then
1581     EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
1582   fi
1583
1584   dnl Enable -Werror for maintainer mode
1585   if test "${enable_maintainer_mode+set}" = set
1586   then
1587       WINE_TRY_CFLAGS([-Werror])
1588   fi
1589
1590   dnl Check for ms_hook_prologue support
1591   saved_CFLAGS="$CFLAGS"
1592   CFLAGS="$CFLAGS -Werror"
1593   AC_CACHE_CHECK([for ms_hook_prologue attribute], ac_cv_have_ms_hook_prologue,
1594                  AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[int __attribute__((__ms_hook_prologue__)) test(void) { return 0; }]])],
1595                                    [ac_cv_have_ms_hook_prologue="yes"],[ac_cv_have_ms_hook_prologue="no"]))
1596   CFLAGS="$saved_CFLAGS"
1597   if test "$ac_cv_have_ms_hook_prologue" = "yes"
1598   then
1599       AC_DEFINE(DECLSPEC_HOTPATCH, [__attribute__((__ms_hook_prologue__))],
1600                 [Define to a function attribute for Microsoft hotpatch assembly prefix.])
1601   else
1602       AC_DEFINE(DECLSPEC_HOTPATCH, [/* */])
1603   fi
1604 fi
1605
1606 dnl **** Check for underscore on external symbols ****
1607
1608 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
1609     WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
1610                       [extern int ac_test;],
1611                       [if (ac_test) return 1],
1612                       ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
1613
1614 case $host_cpu in
1615   *i[[3456789]]86*)
1616     AC_CACHE_CHECK([whether external symbols need stdcall decoration], ac_cv_c_stdcall_suffix,
1617         WINE_TRY_ASM_LINK(["jmp _ac_test@4"],
1618 [#ifndef _MSC_VER
1619 #define __stdcall __attribute__((__stdcall__))
1620 #endif
1621 int __stdcall ac_test(int i) { return i; }],
1622                           [if (ac_test(1)) return 1],
1623                           ac_cv_c_stdcall_suffix="yes",ac_cv_c_stdcall_suffix="no")) ;;
1624   *) ac_cv_c_stdcall_suffix="no" ;;
1625 esac
1626
1627 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
1628 if test "$ac_cv_c_extern_prefix" = "yes"
1629 then
1630     AC_DEFINE([__ASM_NAME(name)], ["_" name])
1631     asm_name_prefix="_"
1632 else
1633     AC_DEFINE([__ASM_NAME(name)], [name])
1634     asm_name_prefix=""
1635 fi
1636
1637 AH_TEMPLATE(__ASM_STDCALL,[Define to a macro to generate an stdcall suffix])
1638 if test "$ac_cv_c_stdcall_suffix" = "yes"
1639 then
1640     AC_DEFINE([__ASM_STDCALL(args)],["@" #args])
1641 else
1642     AC_DEFINE([__ASM_STDCALL(args)],[""])
1643 fi
1644
1645 dnl **** Check how to define a function in assembly code ****
1646
1647 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
1648   WINE_TRY_ASM_LINK(
1649       ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
1650       ac_cv_asm_func_def=".def",
1651     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
1652       ac_cv_asm_func_def=".type @function",
1653     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
1654       ac_cv_asm_func_def=".type 2",
1655       ac_cv_asm_func_def="unknown")])]))
1656
1657 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
1658 case "$ac_cv_asm_func_def" in
1659   ".def")
1660      AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"])
1661      asm_func_header=".def $asm_name_prefix\" #name suffix \"; .scl 2; .type 32; .endef" ;;
1662   ".type @function")
1663      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"])
1664      asm_func_header=".type $asm_name_prefix\" #name suffix \",@function" ;;
1665   ".type 2")
1666      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"])
1667      asm_func_header=".type $asm_name_prefix\" #name suffix \",2" ;;
1668   *)
1669      AC_DEFINE([__ASM_FUNC(name)], [""])
1670      asm_func_header="" ;;
1671 esac
1672
1673 AC_CACHE_CHECK([whether asm() works outside of functions], ac_cv_c_asm_outside_funcs,
1674     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[asm(".text\n\t.long 0");]],)],
1675                       ac_cv_c_asm_outside_funcs="yes",ac_cv_c_asm_outside_funcs="no"))
1676
1677 AC_CACHE_CHECK([whether .previous is supported in assembly code], ac_cv_c_dot_previous,
1678     WINE_TRY_ASM_LINK([".text\nac_test:\t.long 0\n\t.previous"],,,
1679                       ac_cv_c_dot_previous="yes",ac_cv_c_dot_previous="no"))
1680
1681 AC_CACHE_CHECK([whether CFI directives are supported in assembly code], ac_cv_c_cfi_support,
1682     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[asm(".text\nac_test:\t.cfi_startproc\n\t.long 0\n\t.cfi_endproc");]])],
1683                       ac_cv_c_cfi_support="yes",ac_cv_c_cfi_support="no"))
1684
1685 asm_func_header=".globl $asm_name_prefix\" #name suffix \"\\n\\t$asm_func_header\\n$asm_name_prefix\" #name suffix \":\\n\\t"
1686 asm_func_trailer=""
1687 if test "$ac_cv_c_dot_previous" = "yes"
1688 then
1689    asm_func_trailer="\\n\\t.previous"
1690 fi
1691 if test "$ac_cv_c_cfi_support" = "yes"
1692 then
1693    asm_func_header="$asm_func_header.cfi_startproc\\n\\t"
1694    asm_func_trailer="\\n\\t.cfi_endproc$asm_func_trailer"
1695    AC_DEFINE([__ASM_CFI(str)],[str],[Define to a macro to output a .cfi assembly pseudo-op])
1696    AC_SUBST([UNWINDFLAGS],[-fasynchronous-unwind-tables])
1697 else
1698    AC_DEFINE([__ASM_CFI(str)],[""])
1699 fi
1700
1701 asm_func_code="$asm_func_header\" code \"$asm_func_trailer"
1702
1703 AH_TEMPLATE(__ASM_DEFINE_FUNC,[Define to a macro to define an assembly function])
1704 if test "$ac_cv_c_asm_outside_funcs" = "yes"
1705 then
1706     AC_DEFINE_UNQUOTED([__ASM_DEFINE_FUNC(name,suffix,code)],[asm(".text\n\t.align 4\n\t$asm_func_code");])
1707 else
1708     AC_DEFINE_UNQUOTED([__ASM_DEFINE_FUNC(name,suffix,code)],[void __asm_dummy_##name(void) { asm(".text\n\t.align 4\n\t$asm_func_code"); }])
1709 fi
1710 AC_DEFINE([__ASM_GLOBAL_FUNC(name,code)],[__ASM_DEFINE_FUNC(name,"",code)],
1711           [Define to a macro to generate an assembly function with C calling convention])
1712 AC_DEFINE([__ASM_STDCALL_FUNC(name,args,code)],[__ASM_DEFINE_FUNC(name,__ASM_STDCALL(args),code)],
1713           [Define to a macro to generate an assembly function with stdcall calling convention])
1714
1715 dnl **** Platform-specific checks ****
1716
1717 AC_SUBST(LDPATH,"")
1718 case $build_os in
1719   cygwin*|mingw32*)
1720     AC_SUBST(TOOLSEXT,".exe")
1721     LDPATH="PATH=\"\$(TOOLSDIR)/libs/wine:\$\$PATH\""
1722     ;;
1723   darwin*|macosx*)
1724     ;;
1725   *)
1726     LDPATH="LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/wine:\$\$LD_LIBRARY_PATH\""
1727     ;;
1728 esac
1729
1730 dnl Mingw needs explicit msvcrt for linking libwine and winsock for wininet
1731 case $host_os in
1732   mingw32*)
1733     AC_SUBST(CRTLIBS,"-lmsvcrt")
1734     AC_SUBST(SOCKETLIBS,"-L\$(TOPOBJDIR)/dlls/ws2_32 -lws2_32")
1735     ;;
1736 esac
1737
1738 AC_SUBST(MAIN_BINARY,"wine")
1739 test -z "$with_wine64" || MAIN_BINARY="wine32"
1740
1741 case $host_cpu in
1742   *i[[3456789]]86*)
1743     case $host_os in
1744       linux*)
1745         AC_SUBST(EXTRA_BINARIES,"wine-preloader") ;;
1746     esac
1747     ;;
1748 esac
1749
1750 dnl **** Check for functions ****
1751
1752 ac_save_CFLAGS="$CFLAGS"
1753 CFLAGS="$CFLAGS $BUILTINFLAG"
1754 AC_CHECK_FUNCS(\
1755         _pclose \
1756         _popen \
1757         _snprintf \
1758         _spawnvp \
1759         _strdup \
1760         _stricmp \
1761         _strnicmp \
1762         _strtoi64 \
1763         _strtoui64 \
1764         _vsnprintf \
1765         asctime_r \
1766         chsize \
1767         dlopen \
1768         epoll_create \
1769         ffs \
1770         finite \
1771         fnmatch \
1772         fork \
1773         fpclass \
1774         fstatfs \
1775         fstatvfs \
1776         ftruncate \
1777         futimes \
1778         futimesat \
1779         getdirentries \
1780         getopt_long \
1781         getpagesize \
1782         getpwuid \
1783         gettid \
1784         gettimeofday \
1785         getuid \
1786         kqueue \
1787         lstat \
1788         memmove \
1789         mmap \
1790         pclose \
1791         pipe2 \
1792         poll \
1793         popen \
1794         port_create \
1795         prctl \
1796         pread \
1797         pwrite \
1798         readdir \
1799         readlink \
1800         sched_setaffinity \
1801         sched_yield \
1802         select \
1803         setproctitle \
1804         setrlimit \
1805         settimeofday \
1806         sigaltstack \
1807         sigprocmask \
1808         snprintf \
1809         spawnvp \
1810         statfs \
1811         statvfs \
1812         strcasecmp \
1813         strdup \
1814         strerror \
1815         strncasecmp \
1816         strtold \
1817         strtoll \
1818         strtoull \
1819         symlink \
1820         tcgetattr \
1821         thr_kill2 \
1822         timegm \
1823         usleep \
1824         vsnprintf \
1825         wait4 \
1826         waitpid \
1827 )
1828 CFLAGS="$ac_save_CFLAGS"
1829
1830 dnl Check for -ldl
1831 if test "$ac_cv_func_dlopen" = no
1832 then
1833     AC_CHECK_LIB(dl,dlopen,[AC_DEFINE(HAVE_DLOPEN,1) AC_SUBST(LIBDL,"-ldl")])
1834 fi
1835 WINE_CHECK_LIB_FUNCS(dladdr,[$LIBDL])
1836
1837 dnl Check for -lpoll for Mac OS X/Darwin
1838 if test "$ac_cv_func_poll" = no
1839 then
1840     AC_CHECK_LIB(poll,poll,[AC_DEFINE(HAVE_POLL,1) AC_SUBST(LIBPOLL,"-lpoll")])
1841 fi
1842
1843 dnl Check for -lnsl for Solaris
1844 AC_SEARCH_LIBS(gethostbyname, nsl)
1845
1846 dnl Check for -lsocket for Solaris
1847 AC_SEARCH_LIBS(connect, socket)
1848
1849 dnl Check for -lresolv for Solaris
1850 AC_SEARCH_LIBS(inet_aton, resolv)
1851
1852 dnl **** Check for functions which may rely on -lsocket on Solaris.
1853 AC_CHECK_FUNCS(\
1854         getaddrinfo \
1855         getnameinfo \
1856         getnetbyname \
1857         getprotobyname \
1858         getprotobynumber \
1859         getservbyport \
1860         inet_network \
1861         inet_ntop \
1862         inet_pton \
1863         sendmsg \
1864         socketpair \
1865 )
1866
1867 dnl **** Check for OpenLDAP ***
1868 AC_SUBST(LDAPLIBS,"")
1869 if test "$ac_cv_header_ldap_h" = "yes" -a "$ac_cv_header_lber_h" = "yes"
1870 then
1871     AC_CHECK_TYPE(LDAPSortKey,
1872         [AC_CHECK_LIB(ldap_r, ldap_initialize,
1873             [AC_CHECK_LIB(lber, ber_init,
1874                 [AC_DEFINE(HAVE_LDAP, 1, [Define if you have the OpenLDAP development environment])
1875                  LDAPLIBS="-lldap_r -llber"],,
1876                  [$LIBPTHREAD])],,
1877                  [$LIBPTHREAD])],,
1878         [#include <ldap.h>])
1879     WINE_CHECK_LIB_FUNCS(\
1880         ldap_count_references \
1881         ldap_first_reference \
1882         ldap_next_reference \
1883         ldap_parse_reference \
1884         ldap_parse_sort_control \
1885         ldap_parse_sortresponse_control \
1886         ldap_parse_vlv_control \
1887         ldap_parse_vlvresponse_control,
1888         [$LDAPLIBS $LIBPTHREAD])
1889 fi
1890 WINE_NOTICE_WITH(ldap,[test "x$LDAPLIBS" = "x"],
1891                  [libldap (OpenLDAP) ${notice_platform}development files not found, LDAP won't be supported.])
1892
1893 AC_CACHE_CHECK([whether mkdir takes only one argument],
1894         wine_cv_one_arg_mkdir,
1895         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/stat.h>]],[[mkdir("foo");]])],
1896                           [wine_cv_one_arg_mkdir=yes],[wine_cv_one_arg_mkdir=no]))
1897 if test "$wine_cv_one_arg_mkdir" = "yes"
1898 then
1899   AC_DEFINE(HAVE_ONE_ARG_MKDIR, 1, [Define if mkdir takes only one argument])
1900 fi
1901
1902 dnl **** Check for types ****
1903
1904 AC_C_CONST
1905 AC_C_INLINE
1906 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t, long long, fsblkcnt_t, fsfilcnt_t])
1907 AC_CHECK_TYPES([sigset_t],,,[#include <sys/types.h>
1908 #include <signal.h>])
1909 AC_CHECK_TYPES([request_sense],,,[#include <linux/cdrom.h>])
1910
1911 AC_CHECK_TYPES([struct xinpgen],,,
1912 [#include <sys/types.h>
1913 #ifdef HAVE_SYS_SOCKET_H
1914 #include <sys/socket.h>
1915 #endif
1916 #ifdef HAVE_SYS_SOCKETVAR_H
1917 #include <sys/socketvar.h>
1918 #endif
1919 #ifdef HAVE_NET_ROUTE_H
1920 #include <net/route.h>
1921 #endif
1922 #ifdef HAVE_NETINET_IN_H
1923 #include <netinet/in.h>
1924 #endif
1925 #ifdef HAVE_NETINET_IN_SYSTM_H
1926 #include <netinet/in_systm.h>
1927 #endif
1928 #ifdef HAVE_NETINET_IP_H
1929 #include <netinet/ip.h>
1930 #endif
1931 #ifdef HAVE_NETINET_IN_PCB_H
1932 #include <netinet/in_pcb.h>
1933 #endif])
1934
1935 AC_CHECK_MEMBERS([struct ff_effect.direction],,,
1936 [#ifdef HAVE_LINUX_INPUT_H
1937 #include <linux/input.h>
1938 #endif])
1939
1940 AC_CACHE_CHECK([for sigaddset],wine_cv_have_sigaddset,
1941                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <signal.h>]], [[sigset_t set; sigaddset(&set,SIGTERM);]])],[wine_cv_have_sigaddset=yes],[wine_cv_have_sigaddset=no]))
1942 if test "$wine_cv_have_sigaddset" = "yes"
1943 then
1944   AC_DEFINE(HAVE_SIGADDSET, 1, [Define if sigaddset is supported])
1945 fi
1946
1947
1948 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1949         wine_cv_linux_gethostbyname_r_6,
1950         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],[[
1951     char *name=0;
1952     struct hostent he;
1953     struct hostent *result;
1954     char *buf=0;
1955     int bufsize=0;
1956     int res,errnr;
1957     char *addr=0;
1958     int addrlen=0;
1959     int addrtype=0;
1960     res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1961     res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1962     ]])],[wine_cv_linux_gethostbyname_r_6=yes],[wine_cv_linux_gethostbyname_r_6=no
1963         ])
1964    )
1965    if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1966    then
1967       AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1968                 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1969    fi
1970
1971 if test "$ac_cv_header_linux_joystick_h" = "yes"
1972 then
1973    AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1974         wine_cv_linux_joystick_22_api,
1975         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1976         #include <sys/ioctl.h>
1977         #include <sys/types.h>
1978         #include <linux/joystick.h>
1979
1980         struct js_event blub;
1981         #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1982         #error "no 2.2 header"
1983         #endif
1984         ]], [[/*empty*/]])],[wine_cv_linux_joystick_22_api=yes],[wine_cv_linux_joystick_22_api=no])
1985    )
1986    if test "$wine_cv_linux_joystick_22_api" = "yes"
1987    then
1988       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1989                 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1990    fi
1991 fi
1992
1993 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1994
1995 dnl Check for statfs members
1996 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail, struct statfs.f_frsize, struct statfs.f_ffree, struct statfs.f_favail, struct statfs.f_namelen],,,
1997 [#include <sys/types.h>
1998 #ifdef HAVE_SYS_PARAM_H
1999 # include <sys/param.h>
2000 #endif
2001 #ifdef HAVE_SYS_MOUNT_H
2002 # include <sys/mount.h>
2003 #endif
2004 #ifdef HAVE_SYS_VFS_H
2005 # include <sys/vfs.h>
2006 #endif
2007 #ifdef HAVE_SYS_STATFS_H
2008 # include <sys/statfs.h>
2009 #endif])
2010
2011 AC_CHECK_MEMBERS([struct statvfs.f_blocks],,,
2012 [#ifdef HAVE_SYS_STATVFS_H
2013 #include <sys/statvfs.h>
2014 #endif])
2015
2016 dnl Check for socket structure members
2017 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
2018 [#include <sys/types.h>
2019 #ifdef HAVE_SYS_SOCKET_H
2020 # include <sys/socket.h>
2021 #endif
2022 #ifdef HAVE_SYS_UN_H
2023 # include <sys/un.h>
2024 #endif])
2025
2026 dnl Check for scsireq_t and sg_io_hdr_t members
2027 AC_CHECK_MEMBERS([scsireq_t.cmd, sg_io_hdr_t.interface_id],,,
2028 [#include <sys/types.h>
2029 #ifdef HAVE_SCSI_SG_H
2030 #include <scsi/sg.h>
2031 #endif])
2032
2033 dnl Check for siginfo_t members
2034 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
2035
2036 dnl Check for struct mtget members
2037 AC_CHECK_MEMBERS([struct mtget.mt_blksiz, struct mtget.mt_gstat, struct mtget.mt_blkno],,,
2038 [#include <sys/types.h>
2039 #ifdef HAVE_SYS_MTIO_H
2040 #include <sys/mtio.h>
2041 #endif])
2042
2043 dnl Check for struct option
2044 AC_CHECK_MEMBERS([struct option.name],,,
2045 [#ifdef HAVE_GETOPT_H
2046 #include <getopt.h>
2047 #endif])
2048
2049 dnl Check for stat.st_blocks and ns-resolved times
2050 AC_CHECK_MEMBERS([struct stat.st_blocks,struct stat.st_mtim,struct stat.st_ctim,struct stat.st_atim])
2051
2052 dnl Check for sin6_scope_id
2053 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_scope_id],,,
2054 [#ifdef HAVE_SYS_TYPES_H
2055 #include <sys/types.h>
2056 #endif
2057 #ifdef HAVE_NETINET_IN_H
2058 #include <netinet/in.h>
2059 #endif])
2060
2061 dnl Check for ns_msg ptr member
2062 AC_CHECK_MEMBERS([ns_msg._msg_ptr],,,
2063 [#ifdef HAVE_SYS_TYPES_H
2064 #include <sys/types.h>
2065 #endif
2066 #ifdef HAVE_NETINET_IN_H
2067 # include <netinet/in.h>
2068 #endif
2069 #ifdef HAVE_ARPA_NAMESER_H
2070 # include <arpa/nameser.h>
2071 #endif])
2072
2073 dnl Check for struct icmpstat.icps_outhist
2074 AC_CHECK_MEMBERS([struct icmpstat.icps_outhist],,,
2075 [#ifdef HAVE_SYS_TYPES_H
2076 #include <sys/types.h>
2077 #endif
2078 #ifdef HAVE_ALIAS_H
2079 #include <alias.h>
2080 #endif
2081 #ifdef HAVE_SYS_SOCKET_H
2082 #include <sys/socket.h>
2083 #endif
2084 #ifdef HAVE_SYS_SOCKETVAR_H
2085 #include <sys/socketvar.h>
2086 #endif
2087 #ifdef HAVE_SYS_TIMEOUT_H
2088 #include <sys/timeout.h>
2089 #endif
2090 #ifdef HAVE_NETINET_IN_H
2091 #include <netinet/in.h>
2092 #endif
2093 #ifdef HAVE_NETINET_IN_SYSTM_H
2094 #include <netinet/in_systm.h>
2095 #endif
2096 #ifdef HAVE_NETINET_IP_H
2097 #include <netinet/ip.h>
2098 #endif
2099 #ifdef HAVE_NETINET_IP_VAR_H
2100 #include <netinet/ip_var.h>
2101 #endif
2102 #ifdef HAVE_NETINET_IP_ICMP_H
2103 #include <netinet/ip_icmp.h>
2104 #endif
2105 #ifdef HAVE_NETINET_ICMP_VAR
2106 #include <netinet/icmp_var.h>
2107 #endif])
2108
2109 dnl Check for struct ifreq.ifr_hwaddr
2110 AC_CHECK_MEMBERS([struct ifreq.ifr_hwaddr],,,
2111 [#ifdef HAVE_SYS_TYPES_H
2112 #include <sys/types.h>
2113 #endif
2114 #ifdef HAVE_NET_IF_H
2115 # include <net/if.h>
2116 #endif])
2117
2118 dnl Check for the external timezone variables timezone and daylight
2119 AC_CACHE_CHECK([for timezone variable], ac_cv_have_timezone,
2120                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[timezone = 1]])],[ac_cv_have_timezone="yes"],[ac_cv_have_timezone="no"]))
2121 if test "$ac_cv_have_timezone" = "yes"
2122 then
2123     AC_DEFINE(HAVE_TIMEZONE, 1, [Define if you have the timezone variable])
2124 fi
2125 AC_CACHE_CHECK([for daylight variable], ac_cv_have_daylight,
2126                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[daylight = 1]])],[ac_cv_have_daylight="yes"],[ac_cv_have_daylight="no"]))
2127 if test "$ac_cv_have_daylight" = "yes"
2128 then
2129     AC_DEFINE(HAVE_DAYLIGHT, 1, [Define if you have the daylight variable])
2130 fi
2131
2132 dnl Check for isinf
2133 AC_CACHE_CHECK([for isinf], ac_cv_have_isinf,
2134                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; int i=isinf(f)]])],[ac_cv_have_isinf="yes"],[ac_cv_have_isinf="no"]))
2135 if test "$ac_cv_have_isinf" = "yes"
2136 then
2137     AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have the `isinf' function.])
2138 fi
2139
2140 dnl Check for isnan
2141 AC_CACHE_CHECK([for isnan], ac_cv_have_isnan,
2142                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; int i=isnan(f)]])],[ac_cv_have_isnan="yes"],[ac_cv_have_isnan="no"]))
2143 if test "$ac_cv_have_isnan" = "yes"
2144 then
2145     AC_DEFINE(HAVE_ISNAN, 1, [Define to 1 if you have the `isnan' function.])
2146 fi
2147
2148 dnl *** check for the need to define platform-specific symbols
2149
2150 case $host_cpu in
2151   *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
2152   *x86_64*)         WINE_CHECK_DEFINE([__x86_64__]) ;;
2153   *alpha*)          WINE_CHECK_DEFINE([__ALPHA__]) ;;
2154   *sparc*)          WINE_CHECK_DEFINE([__sparc__]) ;;
2155   *powerpc*)        WINE_CHECK_DEFINE([__powerpc__]) ;;
2156 esac
2157
2158 case $host_vendor in
2159   *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
2160 esac
2161
2162 dnl **** Generate output files ****
2163
2164 AH_TOP([#ifndef WINE_CROSSTEST
2165 #define __WINE_CONFIG_H])
2166 AH_BOTTOM([#endif /* WINE_CROSSTEST */])
2167
2168 AC_CONFIG_COMMANDS([include/stamp-h], [echo timestamp > include/stamp-h])
2169
2170 WINE_CONFIG_SYMLINK(dlls/wineps.drv/generic.ppd)
2171 WINE_CONFIG_SYMLINK(fonts/marlett.ttf,,enable_fonts)
2172 WINE_CONFIG_SYMLINK(fonts/symbol.ttf,,enable_fonts)
2173 WINE_CONFIG_SYMLINK(fonts/tahoma.ttf,,enable_fonts)
2174 WINE_CONFIG_SYMLINK(fonts/tahomabd.ttf,,enable_fonts)
2175 WINE_CONFIG_SYMLINK(wine,tools/winewrapper)
2176
2177 WINE_CONFIG_EXTRA_DIR(dlls/gdi32/enhmfdrv)
2178 WINE_CONFIG_EXTRA_DIR(dlls/gdi32/mfdrv)
2179 WINE_CONFIG_EXTRA_DIR(dlls/kernel32/nls)
2180 WINE_CONFIG_EXTRA_DIR(dlls/user32/resources)
2181 WINE_CONFIG_EXTRA_DIR(dlls/wineps.drv/data)
2182 WINE_CONFIG_EXTRA_DIR(include/wine)
2183
2184 WINE_CONFIG_MAKERULES([Make.rules],[MAKE_RULES])
2185 WINE_CONFIG_MAKERULES([Maketest.rules],[MAKE_TEST_RULES],[Make.rules])
2186 WINE_CONFIG_MAKERULES([dlls/Makedll.rules],[MAKE_DLL_RULES],[Make.rules])
2187 WINE_CONFIG_MAKERULES([dlls/Makeimplib.rules],[MAKE_IMPLIB_RULES],[Make.rules])
2188 WINE_CONFIG_MAKERULES([programs/Makeprog.rules],[MAKE_PROG_RULES],[Make.rules])
2189
2190 WINE_CONFIG_DLL(acledit)
2191 WINE_CONFIG_DLL(aclui,,[aclui])
2192 WINE_CONFIG_DLL(activeds,,[activeds])
2193 WINE_CONFIG_DLL(actxprxy)
2194 WINE_CONFIG_LIB(adsiid)
2195 WINE_CONFIG_DLL(advapi32,,[advapi32])
2196 WINE_CONFIG_TEST(dlls/advapi32/tests)
2197 WINE_CONFIG_DLL(advpack,,[advpack])
2198 WINE_CONFIG_TEST(dlls/advpack/tests)
2199 WINE_CONFIG_DLL(amstream)
2200 WINE_CONFIG_TEST(dlls/amstream/tests)
2201 WINE_CONFIG_DLL(appwiz.cpl)
2202 WINE_CONFIG_DLL(atl,,[atl])
2203 WINE_CONFIG_DLL(authz)
2204 WINE_CONFIG_DLL(avicap32,,[avicap32])
2205 WINE_CONFIG_DLL(avifil32,,[avifil32])
2206 WINE_CONFIG_TEST(dlls/avifil32/tests)
2207 WINE_CONFIG_DLL(avifile.dll16,enable_win16)
2208 WINE_CONFIG_DLL(avrt,,[avrt])
2209 WINE_CONFIG_DLL(bcrypt)
2210 WINE_CONFIG_DLL(browseui)
2211 WINE_CONFIG_TEST(dlls/browseui/tests)
2212 WINE_CONFIG_DLL(cabinet,,[cabinet])
2213 WINE_CONFIG_TEST(dlls/cabinet/tests)
2214 WINE_CONFIG_DLL(capi2032,,[capi2032])
2215 WINE_CONFIG_DLL(cards,,[cards])
2216 WINE_CONFIG_DLL(cfgmgr32,,[cfgmgr32])
2217 WINE_CONFIG_DLL(clusapi,,[clusapi])
2218 WINE_CONFIG_DLL(comcat)
2219 WINE_CONFIG_TEST(dlls/comcat/tests)
2220 WINE_CONFIG_DLL(comctl32,,[comctl32])
2221 WINE_CONFIG_TEST(dlls/comctl32/tests)
2222 WINE_CONFIG_DLL(comdlg32,,[comdlg32])
2223 WINE_CONFIG_TEST(dlls/comdlg32/tests)
2224 WINE_CONFIG_DLL(comm.drv16,enable_win16)
2225 WINE_CONFIG_DLL(commdlg.dll16,enable_win16)
2226 WINE_CONFIG_DLL(compobj.dll16,enable_win16)
2227 WINE_CONFIG_DLL(compstui,,[compstui])
2228 WINE_CONFIG_DLL(credui,,[credui])
2229 WINE_CONFIG_TEST(dlls/credui/tests)
2230 WINE_CONFIG_DLL(crtdll,,[crtdll])
2231 WINE_CONFIG_DLL(crypt32,,[crypt32])
2232 WINE_CONFIG_TEST(dlls/crypt32/tests)
2233 WINE_CONFIG_DLL(cryptdlg)
2234 WINE_CONFIG_DLL(cryptdll,,[cryptdll])
2235 WINE_CONFIG_DLL(cryptnet,,[cryptnet])
2236 WINE_CONFIG_TEST(dlls/cryptnet/tests)
2237 WINE_CONFIG_DLL(cryptui,,[cryptui])
2238 WINE_CONFIG_TEST(dlls/cryptui/tests)
2239 WINE_CONFIG_DLL(ctapi32)
2240 WINE_CONFIG_DLL(ctl3d.dll16,enable_win16)
2241 WINE_CONFIG_DLL(ctl3d32,,[ctl3d32])
2242 WINE_CONFIG_DLL(ctl3dv2.dll16,enable_win16)
2243 WINE_CONFIG_DLL(d3d10,,[d3d10])
2244 WINE_CONFIG_TEST(dlls/d3d10/tests)
2245 WINE_CONFIG_DLL(d3d10core,,[d3d10core])
2246 WINE_CONFIG_TEST(dlls/d3d10core/tests)
2247 WINE_CONFIG_DLL(d3d8,,[d3d8])
2248 WINE_CONFIG_TEST(dlls/d3d8/tests)
2249 WINE_CONFIG_DLL(d3d9,,[d3d9])
2250 WINE_CONFIG_TEST(dlls/d3d9/tests)
2251 WINE_CONFIG_DLL(d3dim,,[d3dim])
2252 WINE_CONFIG_DLL(d3drm,,[d3drm])
2253 WINE_CONFIG_TEST(dlls/d3drm/tests)
2254 WINE_CONFIG_DLL(d3dx9_24)
2255 WINE_CONFIG_DLL(d3dx9_25)
2256 WINE_CONFIG_DLL(d3dx9_26)
2257 WINE_CONFIG_DLL(d3dx9_27)
2258 WINE_CONFIG_DLL(d3dx9_28)
2259 WINE_CONFIG_DLL(d3dx9_29)
2260 WINE_CONFIG_DLL(d3dx9_30)
2261 WINE_CONFIG_DLL(d3dx9_31)
2262 WINE_CONFIG_DLL(d3dx9_32)
2263 WINE_CONFIG_DLL(d3dx9_33)
2264 WINE_CONFIG_DLL(d3dx9_34)
2265 WINE_CONFIG_DLL(d3dx9_35)
2266 WINE_CONFIG_DLL(d3dx9_36,,[d3dx9])
2267 WINE_CONFIG_TEST(dlls/d3dx9_36/tests)
2268 WINE_CONFIG_DLL(d3dx9_37)
2269 WINE_CONFIG_DLL(d3dx9_38)
2270 WINE_CONFIG_DLL(d3dx9_39)
2271 WINE_CONFIG_DLL(d3dx9_40)
2272 WINE_CONFIG_DLL(d3dx9_41)
2273 WINE_CONFIG_DLL(d3dx9_42)
2274 WINE_CONFIG_DLL(d3dxof,,[d3dxof])
2275 WINE_CONFIG_TEST(dlls/d3dxof/tests)
2276 WINE_CONFIG_DLL(dbghelp,,[dbghelp])
2277 WINE_CONFIG_DLL(dciman32,,[dciman32])
2278 WINE_CONFIG_DLL(ddeml.dll16,enable_win16)
2279 WINE_CONFIG_DLL(ddraw,,[ddraw])
2280 WINE_CONFIG_TEST(dlls/ddraw/tests)
2281 WINE_CONFIG_DLL(ddrawex)
2282 WINE_CONFIG_TEST(dlls/ddrawex/tests)
2283 WINE_CONFIG_DLL(devenum)
2284 WINE_CONFIG_DLL(dinput,,[dinput],[data_formats.c])
2285 WINE_CONFIG_TEST(dlls/dinput/tests)
2286 WINE_CONFIG_DLL(dinput8,,[dinput8])
2287 WINE_CONFIG_DLL(dispdib.dll16,enable_win16)
2288 WINE_CONFIG_DLL(dispex)
2289 WINE_CONFIG_TEST(dlls/dispex/tests)
2290 WINE_CONFIG_DLL(display.drv16,enable_win16)
2291 WINE_CONFIG_DLL(dmband)
2292 WINE_CONFIG_DLL(dmcompos)
2293 WINE_CONFIG_DLL(dmime)
2294 WINE_CONFIG_DLL(dmloader)
2295 WINE_CONFIG_TEST(dlls/dmloader/tests)
2296 WINE_CONFIG_DLL(dmscript)
2297 WINE_CONFIG_DLL(dmstyle)
2298 WINE_CONFIG_DLL(dmsynth)
2299 WINE_CONFIG_DLL(dmusic)
2300 WINE_CONFIG_DLL(dmusic32,,[dmusic32])
2301 WINE_CONFIG_DLL(dnsapi,,[dnsapi])
2302 WINE_CONFIG_TEST(dlls/dnsapi/tests)
2303 WINE_CONFIG_DLL(dplay,,[dplay])
2304 WINE_CONFIG_DLL(dplayx,,[dplayx])
2305 WINE_CONFIG_TEST(dlls/dplayx/tests)
2306 WINE_CONFIG_DLL(dpnaddr)
2307 WINE_CONFIG_DLL(dpnet,,[dpnet])
2308 WINE_CONFIG_DLL(dpnhpast)
2309 WINE_CONFIG_DLL(dpnlobby)
2310 WINE_CONFIG_DLL(dpwsockx)
2311 WINE_CONFIG_DLL(drmclien)
2312 WINE_CONFIG_DLL(dsound,,[dsound])
2313 WINE_CONFIG_TEST(dlls/dsound/tests)
2314 WINE_CONFIG_DLL(dssenh)
2315 WINE_CONFIG_DLL(dswave)
2316 WINE_CONFIG_DLL(dwmapi,,[dwmapi])
2317 WINE_CONFIG_DLL(dxdiagn)
2318 WINE_CONFIG_TEST(dlls/dxdiagn/tests)
2319 WINE_CONFIG_LIB(dxerr8)
2320 WINE_CONFIG_LIB(dxerr9)
2321 WINE_CONFIG_DLL(dxgi,,[dxgi])
2322 WINE_CONFIG_TEST(dlls/dxgi/tests)
2323 WINE_CONFIG_LIB(dxguid)
2324 WINE_CONFIG_DLL(faultrep)
2325 WINE_CONFIG_DLL(fltlib)
2326 WINE_CONFIG_DLL(fusion)
2327 WINE_CONFIG_TEST(dlls/fusion/tests)
2328 WINE_CONFIG_DLL(fwpuclnt)
2329 WINE_CONFIG_DLL(gdi.exe16,enable_win16)
2330 WINE_CONFIG_DLL(gdi32,,[gdi32])
2331 WINE_CONFIG_TEST(dlls/gdi32/tests)
2332 WINE_CONFIG_DLL(gdiplus,,[gdiplus])
2333 WINE_CONFIG_TEST(dlls/gdiplus/tests)
2334 WINE_CONFIG_DLL(glu32,,[glu32])
2335 WINE_CONFIG_DLL(gphoto2.ds)
2336 WINE_CONFIG_DLL(gpkcsp)
2337 WINE_CONFIG_DLL(hal)
2338 WINE_CONFIG_DLL(hhctrl.ocx)
2339 WINE_CONFIG_DLL(hid,,[hid])
2340 WINE_CONFIG_DLL(hlink,,[hlink])
2341 WINE_CONFIG_TEST(dlls/hlink/tests)
2342 WINE_CONFIG_DLL(hnetcfg)
2343 WINE_CONFIG_DLL(httpapi)
2344 WINE_CONFIG_DLL(iccvid)
2345 WINE_CONFIG_DLL(icmp)
2346 WINE_CONFIG_DLL(ifsmgr.vxd,enable_win16)
2347 WINE_CONFIG_DLL(imaadp32.acm)
2348 WINE_CONFIG_DLL(imagehlp,,[imagehlp])
2349 WINE_CONFIG_TEST(dlls/imagehlp/tests)
2350 WINE_CONFIG_DLL(imm.dll16,enable_win16)
2351 WINE_CONFIG_DLL(imm32,,[imm32])
2352 WINE_CONFIG_TEST(dlls/imm32/tests)
2353 WINE_CONFIG_DLL(inetcomm,,[inetcomm])
2354 WINE_CONFIG_TEST(dlls/inetcomm/tests)
2355 WINE_CONFIG_DLL(inetmib1)
2356 WINE_CONFIG_TEST(dlls/inetmib1/tests)
2357 WINE_CONFIG_DLL(infosoft)
2358 WINE_CONFIG_TEST(dlls/infosoft/tests)
2359 WINE_CONFIG_DLL(initpki)
2360 WINE_CONFIG_DLL(inkobj)
2361 WINE_CONFIG_DLL(inseng)
2362 WINE_CONFIG_DLL(iphlpapi,,[iphlpapi])
2363 WINE_CONFIG_TEST(dlls/iphlpapi/tests)
2364 WINE_CONFIG_DLL(itircl)
2365 WINE_CONFIG_DLL(itss)
2366 WINE_CONFIG_TEST(dlls/itss/tests)
2367 WINE_CONFIG_DLL(jscript)
2368 WINE_CONFIG_TEST(dlls/jscript/tests)
2369 WINE_CONFIG_DLL(kernel32,,[kernel32])
2370 WINE_CONFIG_TEST(dlls/kernel32/tests)
2371 WINE_CONFIG_DLL(keyboard.drv16,enable_win16)
2372 WINE_CONFIG_DLL(krnl386.exe16,enable_win16,[kernel])
2373 WINE_CONFIG_DLL(loadperf,,[loadperf])
2374 WINE_CONFIG_DLL(localspl)
2375 WINE_CONFIG_TEST(dlls/localspl/tests)
2376 WINE_CONFIG_DLL(localui)
2377 WINE_CONFIG_TEST(dlls/localui/tests)
2378 WINE_CONFIG_DLL(lz32,,[lz32])
2379 WINE_CONFIG_TEST(dlls/lz32/tests)
2380 WINE_CONFIG_DLL(lzexpand.dll16,enable_win16)
2381 WINE_CONFIG_DLL(mapi32,,[mapi32])
2382 WINE_CONFIG_TEST(dlls/mapi32/tests)
2383 WINE_CONFIG_DLL(mapistub)
2384 WINE_CONFIG_DLL(mciavi32)
2385 WINE_CONFIG_DLL(mcicda)
2386 WINE_CONFIG_DLL(mciqtz32)
2387 WINE_CONFIG_DLL(mciseq)
2388 WINE_CONFIG_DLL(mciwave)
2389 WINE_CONFIG_DLL(midimap)
2390 WINE_CONFIG_DLL(mlang,,[mlang])
2391 WINE_CONFIG_TEST(dlls/mlang/tests)
2392 WINE_CONFIG_DLL(mmdevapi)
2393 WINE_CONFIG_TEST(dlls/mmdevapi/tests)
2394 WINE_CONFIG_DLL(mmdevldr.vxd,enable_win16)
2395 WINE_CONFIG_DLL(mmsystem.dll16,enable_win16)
2396 WINE_CONFIG_DLL(monodebg.vxd,enable_win16)
2397 WINE_CONFIG_DLL(mountmgr.sys)
2398 WINE_CONFIG_DLL(mouse.drv16,enable_win16)
2399 WINE_CONFIG_DLL(mpr,,[mpr])
2400 WINE_CONFIG_DLL(mprapi,,[mprapi])
2401 WINE_CONFIG_DLL(msacm.dll16,enable_win16)
2402 WINE_CONFIG_DLL(msacm32.drv)
2403 WINE_CONFIG_DLL(msacm32,,[msacm32])
2404 WINE_CONFIG_TEST(dlls/msacm32/tests)
2405 WINE_CONFIG_DLL(msadp32.acm)
2406 WINE_CONFIG_DLL(mscat32)
2407 WINE_CONFIG_DLL(mscms,,[mscms])
2408 WINE_CONFIG_TEST(dlls/mscms/tests)
2409 WINE_CONFIG_DLL(mscoree)
2410 WINE_CONFIG_DLL(msctf)
2411 WINE_CONFIG_TEST(dlls/msctf/tests)
2412 WINE_CONFIG_DLL(msdaps)
2413 WINE_CONFIG_DLL(msdmo,,[msdmo])
2414 WINE_CONFIG_DLL(msftedit)
2415 WINE_CONFIG_DLL(msg711.acm)
2416 WINE_CONFIG_DLL(msgsm32.acm)
2417 WINE_CONFIG_DLL(mshtml.tlb)
2418 WINE_CONFIG_DLL(mshtml,,[mshtml])
2419 WINE_CONFIG_TEST(dlls/mshtml/tests)
2420 WINE_CONFIG_DLL(msi,,[msi])
2421 WINE_CONFIG_TEST(dlls/msi/tests)
2422 WINE_CONFIG_DLL(msimg32,,[msimg32])
2423 WINE_CONFIG_DLL(msimtf)
2424 WINE_CONFIG_DLL(msisip)
2425 WINE_CONFIG_DLL(msisys.ocx)
2426 WINE_CONFIG_DLL(msnet32)
2427 WINE_CONFIG_DLL(msrle32)
2428 WINE_CONFIG_DLL(mssign32)
2429 WINE_CONFIG_DLL(mssip32)
2430 WINE_CONFIG_DLL(mstask)
2431 WINE_CONFIG_TEST(dlls/mstask/tests)
2432 WINE_CONFIG_DLL(msvcirt)
2433 WINE_CONFIG_DLL(msvcr70,,[msvcr70])
2434 WINE_CONFIG_DLL(msvcr71,,[msvcr71])
2435 WINE_CONFIG_DLL(msvcr80)
2436 WINE_CONFIG_DLL(msvcr90)
2437 WINE_CONFIG_TEST(dlls/msvcr90/tests)
2438 WINE_CONFIG_DLL(msvcrt,,[msvcrt])
2439 WINE_CONFIG_TEST(dlls/msvcrt/tests)
2440 WINE_CONFIG_DLL(msvcrt20,,[msvcrt20])
2441 WINE_CONFIG_DLL(msvcrt40,,[msvcrt40])
2442 WINE_CONFIG_DLL(msvcrtd,,[msvcrtd])
2443 WINE_CONFIG_TEST(dlls/msvcrtd/tests)
2444 WINE_CONFIG_DLL(msvfw32,,[msvfw32])
2445 WINE_CONFIG_TEST(dlls/msvfw32/tests)
2446 WINE_CONFIG_DLL(msvidc32)
2447 WINE_CONFIG_DLL(msvideo.dll16,enable_win16)
2448 WINE_CONFIG_DLL(mswsock,,[mswsock])
2449 WINE_CONFIG_DLL(msxml3)
2450 WINE_CONFIG_TEST(dlls/msxml3/tests)
2451 WINE_CONFIG_DLL(msxml4)
2452 WINE_CONFIG_DLL(nddeapi,,[nddeapi])
2453 WINE_CONFIG_DLL(netapi32,,[netapi32])
2454 WINE_CONFIG_TEST(dlls/netapi32/tests)
2455 WINE_CONFIG_DLL(newdev,,[newdev])
2456 WINE_CONFIG_DLL(ntdll,,[ntdll])
2457 WINE_CONFIG_TEST(dlls/ntdll/tests)
2458 WINE_CONFIG_DLL(ntdsapi,,[ntdsapi])
2459 WINE_CONFIG_TEST(dlls/ntdsapi/tests)
2460 WINE_CONFIG_DLL(ntoskrnl.exe,,[ntoskrnl.exe])
2461 WINE_CONFIG_DLL(ntprint)
2462 WINE_CONFIG_TEST(dlls/ntprint/tests)
2463 WINE_CONFIG_DLL(objsel)
2464 WINE_CONFIG_DLL(odbc32,,[odbc32])
2465 WINE_CONFIG_DLL(odbccp32,,[odbccp32])
2466 WINE_CONFIG_TEST(dlls/odbccp32/tests)
2467 WINE_CONFIG_DLL(ole2.dll16,enable_win16)
2468 WINE_CONFIG_DLL(ole2conv.dll16,enable_win16)
2469 WINE_CONFIG_DLL(ole2disp.dll16,enable_win16)
2470 WINE_CONFIG_DLL(ole2nls.dll16,enable_win16)
2471 WINE_CONFIG_DLL(ole2prox.dll16,enable_win16)
2472 WINE_CONFIG_DLL(ole2thk.dll16,enable_win16)
2473 WINE_CONFIG_DLL(ole32,,[ole32])
2474 WINE_CONFIG_TEST(dlls/ole32/tests)
2475 WINE_CONFIG_DLL(oleacc,,[oleacc])
2476 WINE_CONFIG_TEST(dlls/oleacc/tests)
2477 WINE_CONFIG_DLL(oleaut32,,[oleaut32])
2478 WINE_CONFIG_TEST(dlls/oleaut32/tests)
2479 WINE_CONFIG_DLL(olecli.dll16,enable_win16)
2480 WINE_CONFIG_DLL(olecli32,,[olecli32])
2481 WINE_CONFIG_DLL(oledb32)
2482 WINE_CONFIG_TEST(dlls/oledb32/tests)
2483 WINE_CONFIG_DLL(oledlg,,[oledlg])
2484 WINE_CONFIG_DLL(olepro32,,[olepro32])
2485 WINE_CONFIG_DLL(olesvr.dll16,enable_win16)
2486 WINE_CONFIG_DLL(olesvr32,,[olesvr32])
2487 WINE_CONFIG_DLL(olethk32)
2488 WINE_CONFIG_DLL(openal32)
2489 WINE_CONFIG_DLL(opengl32,,[opengl32])
2490 WINE_CONFIG_TEST(dlls/opengl32/tests)
2491 WINE_CONFIG_DLL(pdh,,[pdh])
2492 WINE_CONFIG_TEST(dlls/pdh/tests)
2493 WINE_CONFIG_DLL(pidgen)
2494 WINE_CONFIG_DLL(powrprof,,[powrprof])
2495 WINE_CONFIG_DLL(printui)
2496 WINE_CONFIG_DLL(propsys)
2497 WINE_CONFIG_DLL(psapi,,[psapi])
2498 WINE_CONFIG_TEST(dlls/psapi/tests)
2499 WINE_CONFIG_DLL(pstorec)
2500 WINE_CONFIG_DLL(qcap)
2501 WINE_CONFIG_DLL(qedit)
2502 WINE_CONFIG_TEST(dlls/qedit/tests)
2503 WINE_CONFIG_DLL(qmgr)
2504 WINE_CONFIG_TEST(dlls/qmgr/tests)
2505 WINE_CONFIG_DLL(qmgrprxy)
2506 WINE_CONFIG_DLL(quartz,,[quartz])
2507 WINE_CONFIG_TEST(dlls/quartz/tests)
2508 WINE_CONFIG_DLL(query)
2509 WINE_CONFIG_DLL(rasapi16.dll16,enable_win16)
2510 WINE_CONFIG_DLL(rasapi32,,[rasapi32])
2511 WINE_CONFIG_TEST(dlls/rasapi32/tests)
2512 WINE_CONFIG_DLL(rasdlg,,[rasdlg])
2513 WINE_CONFIG_DLL(resutils,,[resutils])
2514 WINE_CONFIG_DLL(riched20,,[riched20])
2515 WINE_CONFIG_TEST(dlls/riched20/tests)
2516 WINE_CONFIG_DLL(riched32)
2517 WINE_CONFIG_TEST(dlls/riched32/tests)
2518 WINE_CONFIG_DLL(rpcrt4,,[rpcrt4])
2519 WINE_CONFIG_TEST(dlls/rpcrt4/tests)
2520 WINE_CONFIG_DLL(rsabase)
2521 WINE_CONFIG_DLL(rsaenh,,[rsaenh])
2522 WINE_CONFIG_TEST(dlls/rsaenh/tests)
2523 WINE_CONFIG_DLL(rtutils,,[rtutils])
2524 WINE_CONFIG_DLL(sane.ds)
2525 WINE_CONFIG_DLL(sccbase)
2526 WINE_CONFIG_DLL(schannel)
2527 WINE_CONFIG_TEST(dlls/schannel/tests)
2528 WINE_CONFIG_DLL(secur32,,[secur32])
2529 WINE_CONFIG_TEST(dlls/secur32/tests)
2530 WINE_CONFIG_DLL(security)
2531 WINE_CONFIG_DLL(sensapi,,[sensapi])
2532 WINE_CONFIG_DLL(serialui,,[serialui])
2533 WINE_CONFIG_TEST(dlls/serialui/tests)
2534 WINE_CONFIG_DLL(setupapi,,[setupapi])
2535 WINE_CONFIG_TEST(dlls/setupapi/tests)
2536 WINE_CONFIG_DLL(setupx.dll16,enable_win16)
2537 WINE_CONFIG_DLL(sfc,,[sfc])
2538 WINE_CONFIG_DLL(sfc_os,,[sfc_os])
2539 WINE_CONFIG_DLL(shdoclc)
2540 WINE_CONFIG_DLL(shdocvw,,[shdocvw])
2541 WINE_CONFIG_TEST(dlls/shdocvw/tests)
2542 WINE_CONFIG_DLL(shell.dll16,enable_win16)
2543 WINE_CONFIG_DLL(shell32,,[shell32])
2544 WINE_CONFIG_TEST(dlls/shell32/tests)
2545 WINE_CONFIG_DLL(shfolder,,[shfolder])
2546 WINE_CONFIG_DLL(shlwapi,,[shlwapi])
2547 WINE_CONFIG_TEST(dlls/shlwapi/tests)
2548 WINE_CONFIG_DLL(slbcsp)
2549 WINE_CONFIG_DLL(slc,,[slc])
2550 WINE_CONFIG_DLL(snmpapi,,[snmpapi])
2551 WINE_CONFIG_TEST(dlls/snmpapi/tests)
2552 WINE_CONFIG_DLL(softpub)
2553 WINE_CONFIG_DLL(sound.drv16,enable_win16)
2554 WINE_CONFIG_DLL(spoolss,,[spoolss])
2555 WINE_CONFIG_TEST(dlls/spoolss/tests)
2556 WINE_CONFIG_DLL(stdole2.tlb)
2557 WINE_CONFIG_DLL(stdole32.tlb)
2558 WINE_CONFIG_DLL(sti,,[sti])
2559 WINE_CONFIG_TEST(dlls/sti/tests)
2560 WINE_CONFIG_DLL(storage.dll16,enable_win16)
2561 WINE_CONFIG_DLL(stress.dll16,enable_win16)
2562 WINE_CONFIG_LIB(strmiids)
2563 WINE_CONFIG_DLL(svrapi)
2564 WINE_CONFIG_DLL(sxs)
2565 WINE_CONFIG_DLL(system.drv16,enable_win16)
2566 WINE_CONFIG_DLL(t2embed)
2567 WINE_CONFIG_DLL(tapi32,,[tapi32])
2568 WINE_CONFIG_DLL(toolhelp.dll16,enable_win16)
2569 WINE_CONFIG_DLL(traffic)
2570 WINE_CONFIG_DLL(twain.dll16,enable_win16)
2571 WINE_CONFIG_DLL(twain_32)
2572 WINE_CONFIG_TEST(dlls/twain_32/tests)
2573 WINE_CONFIG_DLL(typelib.dll16,enable_win16)
2574 WINE_CONFIG_DLL(unicows,,[unicows])
2575 WINE_CONFIG_DLL(updspapi)
2576 WINE_CONFIG_DLL(url,,[url])
2577 WINE_CONFIG_DLL(urlmon,,[urlmon])
2578 WINE_CONFIG_TEST(dlls/urlmon/tests)
2579 WINE_CONFIG_DLL(usbd.sys,,[usbd.sys])
2580 WINE_CONFIG_DLL(user.exe16,enable_win16)
2581 WINE_CONFIG_DLL(user32,,[user32])
2582 WINE_CONFIG_TEST(dlls/user32/tests)
2583 WINE_CONFIG_DLL(userenv,,[userenv])
2584 WINE_CONFIG_TEST(dlls/userenv/tests)
2585 WINE_CONFIG_DLL(usp10,,[usp10])
2586 WINE_CONFIG_TEST(dlls/usp10/tests)
2587 WINE_CONFIG_LIB(uuid)
2588 WINE_CONFIG_DLL(uxtheme,,[uxtheme])
2589 WINE_CONFIG_TEST(dlls/uxtheme/tests)
2590 WINE_CONFIG_DLL(vdhcp.vxd,enable_win16)
2591 WINE_CONFIG_DLL(vdmdbg,,[vdmdbg])
2592 WINE_CONFIG_DLL(ver.dll16,enable_win16)
2593 WINE_CONFIG_DLL(version,,[version])
2594 WINE_CONFIG_TEST(dlls/version/tests)
2595 WINE_CONFIG_DLL(vmm.vxd,enable_win16)
2596 WINE_CONFIG_DLL(vnbt.vxd,enable_win16)
2597 WINE_CONFIG_DLL(vnetbios.vxd,enable_win16)
2598 WINE_CONFIG_DLL(vtdapi.vxd,enable_win16)
2599 WINE_CONFIG_DLL(vwin32.vxd,enable_win16)
2600 WINE_CONFIG_DLL(w32skrnl,enable_win16)
2601 WINE_CONFIG_DLL(w32sys.dll16,enable_win16)
2602 WINE_CONFIG_DLL(wbemprox)
2603 WINE_CONFIG_DLL(wiaservc)
2604 WINE_CONFIG_DLL(win32s16.dll16,enable_win16)
2605 WINE_CONFIG_DLL(win87em.dll16,enable_win16)
2606 WINE_CONFIG_DLL(winaspi.dll16,enable_win16)
2607 WINE_CONFIG_DLL(windebug.dll16,enable_win16)
2608 WINE_CONFIG_DLL(windowscodecs,,[windowscodecs])
2609 WINE_CONFIG_TEST(dlls/windowscodecs/tests)
2610 WINE_CONFIG_DLL(winealsa.drv)
2611 WINE_CONFIG_DLL(wineaudioio.drv)
2612 WINE_CONFIG_DLL(winecoreaudio.drv)
2613 WINE_CONFIG_LIB(winecrt0)
2614 WINE_CONFIG_DLL(wined3d,,[wined3d])
2615 WINE_CONFIG_DLL(wineesd.drv)
2616 WINE_CONFIG_DLL(winejack.drv)
2617 WINE_CONFIG_DLL(winejoystick.drv)
2618 WINE_CONFIG_DLL(winemapi)
2619 WINE_CONFIG_DLL(winemp3.acm)
2620 WINE_CONFIG_DLL(winenas.drv)
2621 WINE_CONFIG_DLL(wineoss.drv)
2622 WINE_CONFIG_DLL(wineps.drv)
2623 WINE_CONFIG_DLL(wineps16.drv16,enable_win16)
2624 WINE_CONFIG_DLL(winequartz.drv)
2625 WINE_CONFIG_DLL(winex11.drv)
2626 WINE_CONFIG_DLL(wing.dll16,enable_win16)
2627 WINE_CONFIG_DLL(wing32)
2628 WINE_CONFIG_DLL(winhttp,,[winhttp])
2629 WINE_CONFIG_TEST(dlls/winhttp/tests)
2630 WINE_CONFIG_DLL(wininet,,[wininet])
2631 WINE_CONFIG_TEST(dlls/wininet/tests)
2632 WINE_CONFIG_DLL(winmm,,[winmm])
2633 WINE_CONFIG_TEST(dlls/winmm/tests)
2634 WINE_CONFIG_DLL(winnls.dll16,enable_win16)
2635 WINE_CONFIG_DLL(winnls32,,[winnls32])
2636 WINE_CONFIG_DLL(winscard,,[winscard])
2637 WINE_CONFIG_DLL(winsock.dll16,enable_win16)
2638 WINE_CONFIG_DLL(winspool.drv,,[winspool])
2639 WINE_CONFIG_TEST(dlls/winspool.drv/tests)
2640 WINE_CONFIG_DLL(wintab.dll16,enable_win16)
2641 WINE_CONFIG_DLL(wintab32,,[wintab32])
2642 WINE_CONFIG_TEST(dlls/wintab32/tests)
2643 WINE_CONFIG_DLL(wintrust,,[wintrust])
2644 WINE_CONFIG_TEST(dlls/wintrust/tests)
2645 WINE_CONFIG_DLL(wldap32,,[wldap32])
2646 WINE_CONFIG_TEST(dlls/wldap32/tests)
2647 WINE_CONFIG_DLL(wmi)
2648 WINE_CONFIG_DLL(wmiutils)
2649 WINE_CONFIG_DLL(wnaspi32,,[wnaspi32])
2650 WINE_CONFIG_DLL(wow32,enable_win16,[wow32])
2651 WINE_CONFIG_DLL(ws2_32,,[ws2_32])
2652 WINE_CONFIG_TEST(dlls/ws2_32/tests)
2653 WINE_CONFIG_DLL(wsock32,,[wsock32])
2654 WINE_CONFIG_DLL(wtsapi32,,[wtsapi32])
2655 WINE_CONFIG_DLL(wuapi)
2656 WINE_CONFIG_DLL(wuaueng)
2657 WINE_CONFIG_DLL(xinput1_1)
2658 WINE_CONFIG_DLL(xinput1_2)
2659 WINE_CONFIG_DLL(xinput1_3,,[xinput])
2660 WINE_CONFIG_TEST(dlls/xinput1_3/tests)
2661 WINE_CONFIG_DLL(xinput9_1_0)
2662 WINE_CONFIG_DLL(xmllite)
2663 WINE_CONFIG_TEST(dlls/xmllite/tests)
2664 WINE_CONFIG_MAKEFILE([documentation])
2665 WINE_CONFIG_MAKEFILE([fonts])
2666 WINE_CONFIG_MAKEFILE([include])
2667 WINE_CONFIG_MAKEFILE([libs/port])
2668 WINE_CONFIG_MAKEFILE([libs/wine])
2669 WINE_CONFIG_MAKEFILE([libs/wpp])
2670 WINE_CONFIG_MAKEFILE([loader])
2671 WINE_CONFIG_PROGRAM(attrib,install)
2672 WINE_CONFIG_PROGRAM(cacls,install)
2673 WINE_CONFIG_PROGRAM(clock,install)
2674 WINE_CONFIG_PROGRAM(cmd,install)
2675 WINE_CONFIG_TEST(programs/cmd/tests)
2676 WINE_CONFIG_PROGRAM(cmdlgtst)
2677 WINE_CONFIG_PROGRAM(control,install)
2678 WINE_CONFIG_PROGRAM(dxdiag,install)
2679 WINE_CONFIG_PROGRAM(eject,install)
2680 WINE_CONFIG_PROGRAM(expand,install)
2681 WINE_CONFIG_PROGRAM(explorer,install)
2682 WINE_CONFIG_PROGRAM(extrac32,install)
2683 WINE_CONFIG_PROGRAM(hh,install)
2684 WINE_CONFIG_PROGRAM(icinfo,install)
2685 WINE_CONFIG_PROGRAM(iexplore,install)
2686 WINE_CONFIG_PROGRAM(lodctr,install)
2687 WINE_CONFIG_PROGRAM(mshta,install)
2688 WINE_CONFIG_PROGRAM(msiexec,installbin)
2689 WINE_CONFIG_PROGRAM(net,install)
2690 WINE_CONFIG_PROGRAM(ngen,install)
2691 WINE_CONFIG_PROGRAM(notepad,installbin)
2692 WINE_CONFIG_PROGRAM(oleview,install)
2693 WINE_CONFIG_PROGRAM(ping,install)
2694 WINE_CONFIG_PROGRAM(progman,install)
2695 WINE_CONFIG_PROGRAM(reg,install)
2696 WINE_CONFIG_PROGRAM(regedit,installbin)
2697 WINE_CONFIG_PROGRAM(regsvr32,installbin)
2698 WINE_CONFIG_PROGRAM(rpcss,install)
2699 WINE_CONFIG_PROGRAM(rundll32,install)
2700 WINE_CONFIG_PROGRAM(secedit,install)
2701 WINE_CONFIG_PROGRAM(services,install)
2702 WINE_CONFIG_PROGRAM(spoolsv,install)
2703 WINE_CONFIG_PROGRAM(start,install)
2704 WINE_CONFIG_PROGRAM(svchost,install)
2705 WINE_CONFIG_PROGRAM(taskmgr,install)
2706 WINE_CONFIG_PROGRAM(termsv,install)
2707 WINE_CONFIG_PROGRAM(uninstaller,install)
2708 WINE_CONFIG_PROGRAM(unlodctr,install)
2709 WINE_CONFIG_PROGRAM(view)
2710 WINE_CONFIG_PROGRAM(wineboot,installbin)
2711 WINE_CONFIG_PROGRAM(winebrowser,install)
2712 WINE_CONFIG_PROGRAM(winecfg,installbin)
2713 WINE_CONFIG_PROGRAM(wineconsole,installbin)
2714 WINE_CONFIG_PROGRAM(winedbg,installbin)
2715 WINE_CONFIG_PROGRAM(winedevice,install)
2716 WINE_CONFIG_PROGRAM(winefile,installbin)
2717 WINE_CONFIG_PROGRAM(winemenubuilder,install)
2718 WINE_CONFIG_PROGRAM(winemine,installbin)
2719 WINE_CONFIG_PROGRAM(winepath,installbin)
2720 WINE_CONFIG_PROGRAM(winetest)
2721 WINE_CONFIG_PROGRAM(winevdm,install,enable_win16)
2722 WINE_CONFIG_PROGRAM(winhelp.exe16,install,enable_win16)
2723 WINE_CONFIG_PROGRAM(winhlp32,install)
2724 WINE_CONFIG_PROGRAM(winoldap.mod16,install,enable_win16)
2725 WINE_CONFIG_PROGRAM(winver,install)
2726 WINE_CONFIG_PROGRAM(wordpad,install)
2727 WINE_CONFIG_PROGRAM(write,install)
2728 WINE_CONFIG_PROGRAM(xcopy,install)
2729 WINE_CONFIG_MAKEFILE([server])
2730 WINE_CONFIG_TOOL(tools)
2731 WINE_CONFIG_TOOL(tools/widl)
2732 WINE_CONFIG_TOOL(tools/winebuild)
2733 WINE_CONFIG_TOOL(tools/winedump)
2734 WINE_CONFIG_TOOL(tools/winegcc)
2735 WINE_CONFIG_TOOL(tools/wmc)
2736 WINE_CONFIG_TOOL(tools/wrc)
2737 dnl End of auto-generated output commands
2738
2739 AC_CONFIG_COMMANDS([Makefile], [wine_fn_output_makefile Makefile],
2740 [wine_fn_output_makefile ()
2741 {
2742     cat Make.tmp - <<\_WINE_EOF >\$tmp/makefile && mv -f \$tmp/makefile \$[]1 && rm -f Make.tmp && return
2743 $ALL_MAKEFILE_DEPENDS
2744 _WINE_EOF
2745     AS_ERROR([could not create Makefile])
2746 }])
2747
2748 AC_CONFIG_FILES([Make.tmp:Makefile.in])
2749
2750 dnl Some final makefile rules
2751
2752 if test -n "$with_wine64"
2753 then
2754 WINE_APPEND_RULE([ALL_MAKEFILE_DEPENDS],
2755 [all: fonts server $with_wine64/loader/wine32
2756 fonts server:
2757         \$(RM) \$[@] && \$(LN_S) $with_wine64/\$[@] \$[@]
2758 $with_wine64/loader/wine32:
2759         \$(RM) \$[@] && \$(LN_S) $ac_pwd/loader/wine32 \$[@]
2760 clean::
2761         \$(RM) fonts server $with_wine64/loader/wine32])
2762 fi
2763
2764 WINE_APPEND_RULE([ALL_MAKEFILE_DEPENDS],
2765 [uninstall::
2766         -rmdir \$(DESTDIR)\$(datadir)/wine \$(DESTDIR)\$(fakedlldir) \$(DESTDIR)\$(dlldir)])
2767
2768 AC_OUTPUT
2769
2770 if test "$no_create" = "yes"
2771 then
2772   exit 0
2773 fi
2774
2775 WINE_PRINT_MESSAGES
2776
2777 echo "
2778 $as_me: Finished.  Do '${ac_make}' to compile Wine.
2779 " >&AS_MESSAGE_FD
2780
2781 dnl Local Variables:
2782 dnl comment-start: "dnl "
2783 dnl comment-end: ""
2784 dnl comment-start-skip: "\\bdnl\\b\\s *"
2785 dnl compile-command: "autoreconf --warnings=all"
2786 dnl End: