git.oblomov.eu Git - wine/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Original author: Michael Patra
   3 dnl See ChangeLog file for detailed change history.
   4
   5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
   6
   7 AC_PREREQ(2.53)
   8 AC_INIT([Wine],WINE_VERSION,[wine-devel@winehq.org])
   9 AC_CONFIG_SRCDIR(server/atom.c)
  10 AC_CONFIG_HEADERS(include/config.h)
  11 AC_CONFIG_AUX_DIR(tools)
  12
  13 dnl **** Command-line arguments ****
  14
  15 AC_ARG_ENABLE(win16, AC_HELP_STRING([--disable-win16],[do not include Win16 support]))
  16 AC_ARG_ENABLE(debug, AC_HELP_STRING([--disable-debug],[compile out all debugging messages]))
  17 AC_ARG_ENABLE(trace, AC_HELP_STRING([--disable-trace],[compile out TRACE messages]))
  18 AC_ARG_ENABLE(win64, AC_HELP_STRING([--enable-win64], [build a Win64 emulator on AMD64 (won't run Win32 binaries)]))
  19
  20 AC_ARG_WITH(opengl,    AC_HELP_STRING([--without-opengl],[do not use OpenGL]))
  21 AC_ARG_WITH(curses,    AC_HELP_STRING([--without-curses],[do not use curses]))
  22 AC_ARG_WITH(wine-tools,AC_HELP_STRING([--with-wine-tools=<dir>],[use Wine tools from directory <dir>]))
  23
  24 AC_SUBST(DLLDEFS,"")
  25 if test "x$enable_debug" = "xno"
  26 then
  27   DLLDEFS="$DLLDEFS -DWINE_NO_DEBUG_MSGS"
  28 fi
  29 if test "x$enable_trace" = "xno" -o "x$enable_debug" = "xno"
  30 then
  31   DLLDEFS="$DLLDEFS -DWINE_NO_TRACE_MSGS"
  32 fi
  33
  34 AC_CANONICAL_HOST
  35 case $host in
  36   x86_64*linux*)
  37     if test "x$enable_win64" != "xyes"
  38     then
  39       test -n "$CC" || CC="gcc -m32"
  40       test -n "$LD" || LD="ld -m elf_i386"
  41       test -n "$AS" || AS="as --32"
  42       host_cpu="i386"
  43     fi
  44     ;;
  45 esac
  46
  47 dnl enable_win16 defaults to yes on x86, to no on other CPUs
  48 case $host_cpu in
  49   *i[[3456789]]86*)
  50     if test "x$enable_win16" != "xno"
  51     then
  52       enable_win16="yes"
  53     fi
  54     ;;
  55 esac
  56
  57 AC_SUBST(WIN16_FILES,"\$(WIN16_FILES)")
  58 AC_SUBST(WIN16_INSTALL,"\$(WIN16_INSTALL)")
  59 if test "x$enable_win16" != "xyes"
  60 then
  61   WIN16_FILES=""
  62   WIN16_INSTALL=""
  63 fi
  64
  65 dnl **** Check for some programs ****
  66
  67 AC_PROG_MAKE_SET
  68 AC_PROG_CC
  69 AC_PROG_CXX
  70 dnl We can't use AC_PROG_CPP for winegcc, it uses by default $(CC) -E
  71 AC_CHECK_TOOL(CPPBIN,cpp,cpp)
  72
  73 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
  74   [if test -z "$with_wine_tools"; then
  75      if test "$cross_compiling" = "yes"; then
  76        AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
  77      else
  78        wine_cv_toolsdir="\$(TOPOBJDIR)"
  79      fi
  80    elif test -d "$with_wine_tools/tools/winebuild"; then
  81      case $with_wine_tools in
  82        /*) wine_cv_toolsdir="$with_wine_tools" ;;
  83        *)  wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
  84      esac
  85    else
  86      AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
  87    fi])
  88 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
  89
  90 AC_PATH_XTRA
  91 AC_PROG_LEX
  92
  93 dnl **** Just additional warning checks, since AC_PROG just sets 'lex' even
  94 dnl **** without one present.
  95 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
  96 if test "$XLEX" = "none"
  97 then
  98   AC_MSG_ERROR([no suitable lex found. Please install the 'flex' package.])
  99 fi
 100
 101 dnl Check for bison
 102 AC_CHECK_PROGS(BISON,bison,none)
 103 if test "$BISON" = "none"
 104 then
 105   AC_MSG_ERROR([no suitable bison found. Please install the 'bison' package.])
 106 fi
 107
 108 AC_CHECK_TOOLS(AS,[gas as],as)
 109 AC_CHECK_TOOL(LD,ld,ld)
 110 AC_CHECK_TOOL(AR,ar,ar)
 111 AC_PROG_RANLIB
 112 AC_CHECK_TOOL(STRIP,strip,strip)
 113 AC_CHECK_TOOL(WINDRES,windres,false)
 114 AC_PROG_LN_S
 115 WINE_PROG_LN
 116 AC_PROG_EGREP
 117 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
 118 AC_PROG_INSTALL
 119 dnl Prepend src dir to install path dir if it's a relative path
 120 case "$INSTALL" in
 121   [[\\/$]]* | ?:[[\\/]]* ) ;;
 122   *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
 123 esac
 124
 125 dnl Check for lint
 126 AC_CHECK_PROGS(LINT, lclint lint)
 127 if test "$LINT" = "lint"
 128 then
 129   LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
 130   dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
 131 fi
 132 AC_SUBST(LINT)
 133 AC_SUBST(LINTFLAGS)
 134
 135 dnl Check for various programs
 136 AC_CHECK_PROGS(FONTFORGE, fontforge, false)
 137
 138 dnl **** Check for some libraries ****
 139
 140 dnl Check for -li386 for NetBSD and OpenBSD
 141 AC_CHECK_LIB(i386,i386_set_ldt)
 142 dnl Check for -lossaudio for NetBSD
 143 AC_CHECK_LIB(ossaudio,_oss_ioctl)
 144 dnl Check for -lw for Solaris
 145 AC_CHECK_FUNCS(iswalnum,,AC_CHECK_LIB(w,iswalnum))
 146 dnl Check for -lnsl for Solaris
 147 AC_CHECK_FUNCS(gethostbyname,,AC_CHECK_LIB(nsl,gethostbyname))
 148 dnl Check for -lsocket for Solaris
 149 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
 150 dnl Check for -lresolv for Solaris
 151 AC_CHECK_FUNCS(inet_aton,,AC_CHECK_LIB(resolv,inet_aton))
 152 dnl Check for -lxpg4 for FreeBSD
 153 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
 154 dnl Check for -lpoll for Mac OS X/Darwin
 155 AC_CHECK_LIB(poll,poll)
 156 dnl Check for -lresolv for Mac OS X/Darwin
 157 AC_CHECK_LIB(resolv,res_9_init)
 158 dnl Check for -lpthread
 159 AC_CHECK_LIB(pthread,pthread_create,AC_SUBST(LIBPTHREAD,"-lpthread"))
 160
 161 AC_SUBST(XLIB)
 162 AC_SUBST(XFILES)
 163 XFILES=""
 164 AC_SUBST(OPENGLFILES)
 165 OPENGLFILES=""
 166 AC_SUBST(GLU32FILES)
 167 GLU32FILES=""
 168 AC_SUBST(OPENGL_LIBS)
 169 OPENGL_LIBS=""
 170
 171 dnl **** Check for header files ****
 172
 173 AC_CHECK_HEADERS(\
 174         IOKit/IOKitLib.h \
 175         arpa/inet.h \
 176         arpa/nameser.h \
 177         asm/types.h \
 178         cups/cups.h \
 179         direct.h \
 180         elf.h \
 181         float.h \
 182         fontconfig/fontconfig.h \
 183         getopt.h \
 184         gif_lib.h \
 185         ieeefp.h \
 186         io.h \
 187         jack/jack.h \
 188         jpeglib.h \
 189         lber.h \
 190         lcms/lcms.h \
 191         lcms.h \
 192         ldap.h \
 193         link.h \
 194         linux/cdrom.h \
 195         linux/compiler.h \
 196         linux/hdreg.h \
 197         linux/input.h \
 198         linux/ioctl.h \
 199         linux/joystick.h \
 200         linux/major.h \
 201         linux/param.h \
 202         linux/serial.h \
 203         linux/ucdrom.h \
 204         mach/machine.h \
 205         machine/cpu.h \
 206         machine/limits.h \
 207         mntent.h \
 208         netdb.h \
 209         netinet/in.h \
 210         netinet/in_systm.h \
 211         netinet/tcp.h \
 212         netinet/tcp_fsm.h \
 213         openssl/ssl.h \
 214         poll.h \
 215         process.h \
 216         pthread.h \
 217         pwd.h \
 218         regex.h \
 219         sched.h \
 220         scsi/sg.h \
 221         scsi/scsi.h \
 222         scsi/scsi_ioctl.h \
 223         stdint.h \
 224         strings.h \
 225         sys/cdio.h \
 226         sys/elf32.h \
 227         sys/errno.h \
 228         sys/epoll.h \
 229         sys/exec_elf.h \
 230         sys/filio.h \
 231         sys/ioctl.h \
 232         sys/ipc.h \
 233         sys/link.h \
 234         sys/lwp.h \
 235         sys/mman.h \
 236         sys/modem.h \
 237         sys/msg.h \
 238         sys/param.h \
 239         sys/poll.h \
 240         sys/ptrace.h \
 241         sys/reg.h \
 242         sys/scsiio.h \
 243         sys/shm.h \
 244         sys/signal.h \
 245         sys/socket.h \
 246         sys/sockio.h \
 247         sys/statfs.h \
 248         sys/statvfs.h \
 249         sys/strtio.h \
 250         sys/syscall.h \
 251         sys/sysctl.h \
 252         sys/time.h \
 253         sys/times.h \
 254         sys/uio.h \
 255         sys/un.h \
 256         sys/vfs.h \
 257         sys/vm86.h \
 258         sys/wait.h \
 259         syscall.h \
 260         termios.h \
 261         unistd.h \
 262         utime.h \
 263         valgrind/memcheck.h
 264 )
 265 AC_HEADER_STAT()
 266
 267 dnl **** Check for X11 ****
 268
 269 if test "$have_x" = "yes"
 270 then
 271     XLIB="-lXext -lX11"
 272     ac_save_CPPFLAGS="$CPPFLAGS"
 273     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 274
 275     dnl *** All of the following tests require X11/Xlib.h
 276     AC_CHECK_HEADERS(X11/Xlib.h,
 277       [
 278         AC_CHECK_HEADERS([X11/XKBlib.h \
 279                           X11/Xutil.h \
 280                           X11/extensions/shape.h \
 281                           X11/extensions/XInput.h \
 282                           X11/extensions/XShm.h \
 283                           X11/extensions/Xrandr.h \
 284                           X11/extensions/Xrender.h \
 285                           X11/extensions/xf86dga.h \
 286                           X11/extensions/xf86vmode.h],,,
 287                          [#include <X11/Xlib.h>
 288                           #ifdef HAVE_X11_XUTIL_H
 289                           # include <X11/Xutil.h>
 290                           #endif])
 291
 292         dnl *** Check for X keyboard extension
 293         if test "$ac_cv_header_X11_XKBlib_h" = "yes"
 294         then
 295               AC_CHECK_LIB(X11, XkbQueryExtension,
 296               AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
 297               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 298         fi
 299
 300         dnl *** Check for X Shm extension
 301         if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
 302         then
 303               AC_CHECK_LIB(Xext, XShmQueryExtension,
 304               AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
 305               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 306         fi
 307
 308         dnl *** Check for X shape extension
 309         if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
 310         then
 311               AC_CHECK_LIB(Xext,XShapeQueryExtension,
 312               AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
 313               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 314         fi
 315
 316         dnl *** Check for XFree86 DGA / DGA 2.0 extension
 317         if test "$ac_cv_header_X11_extensions_xf86dga_h" = "yes"
 318         then
 319               AC_CHECK_LIB(Xxf86dga, XDGAQueryExtension,
 320                 [ AC_DEFINE(HAVE_LIBXXF86DGA2, 1,
 321                             [Define if you have the Xxf86dga library version 2])
 322                   X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
 323                 ],,
 324                 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 325         fi
 326
 327         dnl *** Check for XFree86 VMODE extension
 328         if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
 329         then
 330                 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
 331                   [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
 332                      X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
 333                   ],,
 334                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 335         fi
 336
 337         dnl *** Check for X RandR extension
 338         if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes"
 339         then
 340                 AC_TRY_COMPILE([#include <X11/Xlib.h>
 341 #include <X11/extensions/Xrandr.h>],[static typeof(XRRSetScreenConfigAndRate) * func;],
 342                   [AC_DEFINE(HAVE_LIBXRANDR, 1, [Define if you have the Xrandr library])])
 343         fi
 344
 345         dnl *** Check for Transform functions in Xrender
 346         if test "$ac_cv_header_X11_extensions_Xrender_h" = "yes"
 347         then
 348               AC_CHECK_LIB(Xrender, XRenderSetPictureTransform,
 349                 [AC_DEFINE(HAVE_XRENDERSETPICTURETRANSFORM, 1,
 350                  [Define if Xrender has the XRenderSetPictureTransform function])],,
 351                 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 352         fi
 353       ]
 354     ) dnl *** End of X11/Xlib.h check
 355
 356     dnl Check for the presence of OpenGL
 357     if test "x$with_opengl" != "xno"
 358     then
 359         AC_CHECK_HEADERS(GL/gl.h GL/glx.h)
 360         if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
 361         then
 362             AC_CHECK_HEADERS(GL/glext.h,,,[#include <GL/glx.h>])
 363             dnl Check for some problems due to old Mesa versions
 364             AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_version_OK,
 365               AC_TRY_COMPILE(
 366                 [#include <GL/gl.h>],
 367                 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
 368                 [wine_cv_opengl_version_OK="yes"],
 369                 [wine_cv_opengl_version_OK="no"]
 370               )
 371             )
 372
 373             if test "$wine_cv_opengl_version_OK" = "yes"
 374             then
 375                 dnl Check for the presence of the library
 376                 AC_CHECK_LIB(GL,glXCreateContext,
 377                              OPENGL_LIBS="-lGL"
 378                              ,,
 379                              $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 380
 381                 if test "$ac_cv_lib_GL_glXCreateContext" = "yes"
 382                 then
 383                         OPENGLFILES='$(OPENGLFILES)'
 384                         AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])
 385                 else
 386                     if test -f /usr/X11R6/lib/libGL.a
 387                     then
 388                        AC_MSG_ERROR([/usr/X11R6/lib/libGL.a is present on your system.
 389 This prevents linking to OpenGL. Delete the file and restart configure.])
 390                     fi
 391                 fi
 392
 393                 dnl Check for GLU32 library.
 394                 AC_CHECK_LIB(GLU,gluLookAt,
 395                              [OPENGL_LIBS="$OPENGL_LIBS -lGLU"
 396                              GLU32FILES='$(GLU32FILES)']
 397                              ,,
 398                              $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
 399                 )
 400              fi
 401
 402              dnl Check for glut32 library.
 403              AC_CHECK_LIB(glut,glutMainLoop,
 404                        [AC_SUBST(GLUT_LIBS,"-lglut -lXmu -lXi")
 405                         AC_SUBST(GLUT32FILES,'$(GLUT32FILES)')],,
 406                         $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXmu -lXi -lX11 $X_EXTRA_LIBS)
 407          fi
 408     fi
 409
 410     dnl **** Check for NAS ****
 411     AC_SUBST(NASLIBS,"")
 412     AC_CHECK_HEADERS(audio/audiolib.h,
 413          [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
 414           AC_CHECK_LIB(audio,AuCreateFlow,
 415                        [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
 416                         NASLIBS="-laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],,
 417                        [-lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
 418
 419     CPPFLAGS="$ac_save_CPPFLAGS"
 420     XFILES='$(XFILES)'
 421 else
 422     XLIB=""
 423     X_CFLAGS=""
 424     X_LIBS=""
 425 fi
 426
 427 dnl **** Check which curses lib to use ***
 428 CURSESLIBS=""
 429 if test "x$with_curses" != "xno"
 430 then
 431     AC_CHECK_HEADERS(ncurses.h,
 432         [AC_CHECK_LIB(ncurses,waddch,
 433             [AC_DEFINE(HAVE_LIBNCURSES, 1, [Define if you have the ncurses library (-lncurses)])
 434              CURSESLIBS="-lncurses"],
 435              [AC_CHECK_HEADERS(curses.h,
 436                  [AC_CHECK_LIB(curses,waddch,
 437                      [AC_DEFINE(HAVE_LIBCURSES, 1, [Define if you have the curses library (-lcurses)])
 438                       CURSESLIBS="-lcurses"])])])])
 439 fi
 440 AC_SUBST(CURSESLIBS)
 441
 442 dnl **** Check for SANE ****
 443 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
 444 if test "$sane_devel" = "no"
 445 then
 446     SANELIBS=""
 447     SANEINCL=""
 448 else
 449     SANELIBS="`$sane_devel --libs`"
 450     SANEINCL="`$sane_devel --cflags`"
 451     ac_save_CPPFLAGS="$CPPFLAGS"
 452     ac_save_LIBS="$LIBS"
 453     CPPFLAGS="$CPPFLAGS $SANEINCL"
 454     LIBS="$LIBS $SANELIBS"
 455     AC_CHECK_HEADER(sane/sane.h,
 456                     [AC_CHECK_LIB(sane,sane_open,
 457                                   [AC_DEFINE(HAVE_SANE, 1, [Define if we have SANE development environment])],
 458                                   [SANELIBS=""
 459                                   SANEINCL=""])],
 460                     [SANELIBS=""
 461                     SANEINCL=""])
 462     LIBS="$ac_save_LIBS"
 463     CPPFLAGS="$ac_save_CPPFLAGS"
 464 fi
 465 AC_SUBST(SANELIBS)
 466 AC_SUBST(SANEINCL)
 467
 468 dnl **** Check for the ICU library ****
 469 AC_CHECK_HEADERS(unicode/ubidi.h)
 470 if test "$ac_cv_header_unicode_ubidi_h" = "yes"
 471 then
 472     saved_libs="$LIBS"
 473     ICU_LIB_DIR="${ICU_LIB_DIR-/usr/lib}"
 474     ICUUC_LIB="${ICUUC_LIB-$ICU_LIB_DIR/libsicuuc.a}"
 475     ICUDATA_LIB="${ICUDATA_LIB-$ICU_LIB_DIR/libsicudata.a}"
 476     AC_MSG_CHECKING(whether can link with ICU libraries $ICUUC_LIB and $ICUDATA_LIB)
 477     LIBS="$LIBS $ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s"
 478     AC_TRY_LINK([#include <unicode/ubidi.h>],[ubidi_open()],
 479                 [AC_DEFINE(HAVE_ICU,1,[Define to 1 if the ICU libraries are installed])
 480                  AC_SUBST(ICULIBS,"$ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s")
 481                  AC_MSG_RESULT(yes)],
 482                 [AC_MSG_RESULT(no)])
 483     LIBS="$saved_libs"
 484 fi
 485
 486 dnl **** Check for LittleCMS ***
 487 AC_SUBST(LCMSLIBS,"")
 488 if test "$ac_cv_header_lcms_h" = "yes" -o "$ac_cv_header_lcms_lcms_h" = "yes"
 489 then
 490     AC_CHECK_LIB(lcms, cmsOpenProfileFromFile,
 491         [AC_DEFINE(HAVE_LCMS, 1, [Define if you have the LittleCMS development environment])
 492          LCMSLIBS="-llcms"])
 493 fi
 494
 495 dnl **** Check for OpenLDAP ***
 496 AC_SUBST(LDAPLIBS,"")
 497 if test "$ac_cv_header_ldap_h" = "yes" -a "$ac_cv_header_lber_h" = "yes"
 498 then
 499     AC_CHECK_LIB(ldap, ldap_init,
 500         [AC_CHECK_LIB(lber, ber_init,
 501             [AC_DEFINE(HAVE_LDAP, 1, [Define if you have the OpenLDAP development environment])
 502              LDAPLIBS="-lldap -llber"])])
 503 fi
 504
 505 dnl **** Check for FreeType 2 ****
 506 AC_CHECK_LIB(freetype,FT_Init_FreeType,ft_lib=yes,ft_lib=no,$X_LIBS)
 507 if test "$ft_lib" = "no"
 508 then
 509     FREETYPELIBS=""
 510     FREETYPEINCL=""
 511     wine_cv_msg_freetype=no
 512 else
 513     AC_CHECK_PROG(ft_devel,freetype-config,freetype-config,no)
 514     if test "$ft_devel" = "no"
 515     then
 516         AC_CHECK_PROG(ft_devel2,freetype2-config,freetype2-config,no)
 517         if test "$ft_devel2" = "freetype2-config"
 518         then
 519                 ft_devel=$ft_devel2
 520         fi
 521     fi
 522     if test "$ft_devel" = "no"
 523     then
 524         FREETYPELIBS=""
 525         FREETYPEINCL=""
 526         wine_cv_msg_freetype=yes
 527     else
 528         FREETYPELIBS=`$ft_devel --libs`
 529         FREETYPEINCL=`$ft_devel --cflags`
 530         ac_save_CPPFLAGS="$CPPFLAGS"
 531         CPPFLAGS="$FREETYPEINCL $CPPFLAGS"
 532         AC_CHECK_HEADERS(ft2build.h \
 533                          freetype/freetype.h \
 534                          freetype/ftglyph.h \
 535                          freetype/tttables.h \
 536                          freetype/ftnames.h \
 537                          freetype/ftsnames.h \
 538                          freetype/ttnameid.h \
 539                          freetype/ftoutln.h \
 540                          freetype/ftwinfnt.h \
 541                          freetype/internal/sfnt.h,,,
 542                          [#if HAVE_FT2BUILD_H
 543                           #include <ft2build.h>
 544                           #endif])
 545         AC_TRY_CPP([#include <ft2build.h>
 546                     #include <freetype/fttrigon.h>],
 547                     [AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
 548           [Define if you have the <freetype/fttrigon.h> header file.])
 549                     wine_cv_fttrigon=yes],
 550                     wine_cv_fttrigon=no)
 551         CPPFLAGS="$ac_save_CPPFLAGS"
 552         dnl Check that we have at least freetype/freetype.h
 553         if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
 554         then
 555             AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
 556             wine_cv_msg_freetype=no
 557         else
 558             FREETYPELIBS=""
 559             FREETYPEINCL=""
 560             wine_cv_msg_freetype=yes
 561         fi
 562     fi
 563 fi
 564 AC_SUBST(FREETYPELIBS)
 565 AC_SUBST(FREETYPEINCL)
 566
 567 dnl Only build the fonts dir if we have both freetype and fontforge
 568 if test "$FONTFORGE" != "false" -a -n "$FREETYPELIBS"
 569 then
 570   AC_SUBST(FONTSSUBDIRS,"fonts")
 571 fi
 572
 573 dnl **** Check for parport (currently Linux only) ****
 574 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
 575  AC_TRY_COMPILE(
 576    [#include <linux/ppdev.h>],
 577    [ioctl (1,PPCLAIM,0)],
 578    [ac_cv_c_ppdev="yes"],
 579    [ac_cv_c_ppdev="no"])
 580  )
 581 if test "$ac_cv_c_ppdev" = "yes"
 582 then
 583     AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
 584 fi
 585
 586 dnl **** Check for va_copy ****
 587 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
 588  AC_TRY_LINK(
 589    [#include <stdarg.h>],
 590    [va_list ap1, ap2;
 591     va_copy(ap1,ap2);
 592    ],
 593    [ac_cv_c_va_copy="yes"],
 594    [ac_cv_c_va_copy="no"])
 595  )
 596 if test "$ac_cv_c_va_copy" = "yes"
 597 then
 598     AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
 599 fi
 600 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
 601  AC_TRY_LINK(
 602    [#include <stdarg.h>],
 603    [va_list ap1, ap2;
 604     __va_copy(ap1,ap2);
 605    ],
 606    [ac_cv_c___va_copy="yes"],
 607    [ac_cv_c___va_copy="no"])
 608  )
 609 if test "$ac_cv_c___va_copy" = "yes"
 610 then
 611     AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
 612 fi
 613
 614 dnl **** Check for sigsetjmp ****
 615 AC_CACHE_CHECK([for sigsetjmp], ac_cv_c_sigsetjmp,
 616  AC_TRY_LINK(
 617    [#include <setjmp.h>],
 618    [sigjmp_buf buf;
 619     sigsetjmp( buf, 1 );
 620     siglongjmp( buf, 1 );],
 621    [ac_cv_c_sigsetjmp="yes"],
 622    [ac_cv_c_sigsetjmp="no"])
 623  )
 624 if test "$ac_cv_c_sigsetjmp" = "yes"
 625 then
 626     AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have the sigsetjmp (and siglongjmp) function])
 627 fi
 628
 629 dnl **** Check for pthread_rwlock_t ****
 630 AC_CHECK_TYPES([pthread_rwlock_t, pthread_rwlockattr_t],,,[#define _GNU_SOURCE
 631 #include <pthread.h>])
 632
 633 dnl **** Check for pthread functions ****
 634 ac_save_LIBS="$LIBS"
 635 LIBS="$LIBS $LIBPTHREAD"
 636 AC_CHECK_FUNCS(\
 637         pthread_getattr_np \
 638         pthread_get_stackaddr_np \
 639         pthread_get_stacksize_np \
 640 )
 641 LIBS="$ac_save_LIBS"
 642
 643 dnl **** Check for Open Sound System ****
 644 AC_CHECK_HEADERS(sys/soundcard.h machine/soundcard.h soundcard.h, break)
 645
 646 AC_CACHE_CHECK([for Open Sound System],
 647         ac_cv_c_opensoundsystem,
 648         AC_TRY_COMPILE([
 649         #if defined(HAVE_SYS_SOUNDCARD_H)
 650                 #include <sys/soundcard.h>
 651         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 652                 #include <machine/soundcard.h>
 653         #elif defined(HAVE_SOUNDCARD_H)
 654                 #include <soundcard.h>
 655         #endif
 656         ],[
 657
 658 /* check for one of the Open Sound System specific SNDCTL_ defines */
 659 #if !defined(SNDCTL_DSP_STEREO)
 660 #error No open sound system
 661 #endif
 662 ],ac_cv_c_opensoundsystem="yes",ac_cv_c_opensoundsystem="no"))
 663
 664 if test "$ac_cv_c_opensoundsystem" = "yes"
 665 then
 666     AC_DEFINE(HAVE_OSS, 1, [Define if you have the Open Sound system])
 667 fi
 668
 669 AC_CACHE_CHECK([for Open Sound System/MIDI interface],
 670         ac_cv_c_opensoundsystem_midi,
 671         AC_TRY_COMPILE([
 672         #if defined(HAVE_SYS_SOUNDCARD_H)
 673                 #include <sys/soundcard.h>
 674         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 675                 #include <machine/soundcard.h>
 676         #elif defined(HAVE_SOUNDCARD_H)
 677                 #include <soundcard.h>
 678         #endif
 679         ],[
 680
 681 /* check for one of the Open Sound System specific SNDCTL_SEQ defines */
 682 #if !defined(SNDCTL_SEQ_SYNC)
 683 #error No open sound system MIDI interface
 684 #endif
 685 ],ac_cv_c_opensoundsystem_midi="yes",ac_cv_c_opensoundsystem_midi="no"))
 686
 687 if test "$ac_cv_c_opensoundsystem_midi" = "yes"
 688 then
 689     AC_DEFINE(HAVE_OSS_MIDI, 1, [Define if you have the Open Sound system (MIDI interface)])
 690 fi
 691
 692 dnl **** Check for aRts Sound Server ****
 693 AC_PATH_PROG(ARTSCCONFIG, artsc-config)
 694 if test x$ARTSCCONFIG != x -a x$ARTSCCONFIG != x'"$ARTSCCONFIG"';
 695 then
 696     ARTSC_CFLAGS=""
 697     for i in `$ARTSCCONFIG --cflags`
 698     do
 699       case "$i" in
 700         -I*) ARTSC_CFLAGS="$ARTSC_CFLAGS $i";;
 701       esac
 702     done
 703     ARTSC_LIBS=`$ARTSCCONFIG --libs`
 704     save_CFLAGS="$CFLAGS"
 705     CFLAGS="$CFLAGS $ARTSC_CFLAGS"
 706     AC_CHECK_LIB(artsc,arts_init,
 707         [AC_TRY_COMPILE([#include <artsc.h>],[arts_stream_t stream;],
 708             [AC_SUBST(ARTSLIBS, $ARTSC_LIBS)
 709             AC_SUBST(ARTSINCL, $ARTSC_CFLAGS)
 710             AC_DEFINE(HAVE_ARTS, 1, [Define if you have ARTS sound server])])],,
 711             $ARTSC_LIBS)
 712     CFLAGS="$save_CFLAGS"
 713 fi
 714
 715 dnl **** Check for ALSA 1.x ****
 716 AC_SUBST(ALSALIBS,"")
 717 AC_CHECK_HEADERS(alsa/asoundlib.h sys/asoundlib.h, break)
 718 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
 719 then
 720     AC_CHECK_LIB(asound,snd_pcm_hw_params_get_access,
 721         [AC_TRY_COMPILE([#ifdef HAVE_ALSA_ASOUNDLIB_H
 722 #include <alsa/asoundlib.h>
 723 #elif defined(HAVE_SYS_ASOUNDLIB_H)
 724 #include <sys/asoundlib.h>
 725 #endif],
 726                         [int ret = snd_pcm_hw_params_get_access(NULL, NULL)],
 727                         [AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA 1.x including devel headers])
 728                          ALSALIBS="-lasound"])])
 729 fi
 730
 731 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
 732
 733 AC_SUBST(AUDIOIOLIBS,"")
 734 AC_CHECK_HEADERS(libaudioio.h,
 735     [AC_CHECK_LIB(audioio,AudioIOGetVersion,
 736                   [AUDIOIOLIBS="-laudioio"
 737                    AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])])
 738
 739 dnl **** Check for capi4linux ****
 740
 741 AC_CHECK_HEADERS(capi20.h,[
 742         AC_CHECK_HEADERS(linux/capi.h,[
 743                 AC_CHECK_LIB(capi20,capi20_register,[
 744                         AC_DEFINE(HAVE_CAPI4LINUX,1,[Define if you have capi4linux libs and headers])
 745                 ])
 746         ])
 747 ])
 748
 749 dnl **** Check for broken glibc mmap64 ****
 750
 751 AC_CACHE_CHECK( [whether mmap64 works defined as mmap], ac_cv_mmap64_works,
 752         AC_TRY_RUN([
 753                 #define _FILE_OFFSET_BITS 64
 754                 #include <stdio.h>
 755                 #include <unistd.h>
 756                 #include <fcntl.h>
 757                 #include <sys/mman.h>
 758                 #include <errno.h>
 759
 760                 int main(int argc,char **argv) {
 761                         int fd = open("conftest.map",O_CREAT|O_RDWR,0600);
 762                         if (fd == -1) exit(1);
 763
 764                         unlink("conftest.map");
 765
 766                         write(fd,"test",4);
 767
 768                         if ((-1 == mmap(0,4,PROT_READ|PROT_WRITE,MAP_SHARED,fd,0)) &&
 769                             (errno == EINVAL)
 770                         ) {
 771                                 exit(1);
 772                         }
 773                         close(fd);
 774                         fprintf(stderr,"success!\n");
 775                         exit(0);
 776                 }
 777
 778         ],
 779     ac_cv_mmap64_works="yes",
 780     ac_cv_mmap64_works="no",
 781     ac_cv_mmap64_works="no") )
 782
 783 if test "$ac_cv_mmap64_works" = "yes"
 784 then
 785     AC_DEFINE(_FILE_OFFSET_BITS, 64, [Set this to 64 to enable 64-bit file support on Linux])
 786 fi
 787
 788 dnl **** Check for gcc specific options ****
 789
 790 AC_SUBST(EXTRACFLAGS,"")
 791 if test "x${GCC}" = "xyes"
 792 then
 793   EXTRACFLAGS="-Wall -pipe"
 794
 795   dnl Check for strength-reduce bug
 796   AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
 797                   AC_TRY_RUN([
 798 int     L[[4]] = {0,1,2,3};
 799 int main(void) {
 800   static int Array[[3]];
 801   unsigned int B = 3;
 802   int i;
 803   for(i=0; i<B; i++) Array[[i]] = i - 3;
 804   for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
 805   L[[i]] = 4;
 806
 807   exit( Array[[1]] != -2 || L[[2]] != 3);
 808 }],
 809     ac_cv_c_gcc_strength_bug="no",
 810     ac_cv_c_gcc_strength_bug="yes",
 811     ac_cv_c_gcc_strength_bug="yes") )
 812   if test "$ac_cv_c_gcc_strength_bug" = "yes"
 813   then
 814     EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
 815   fi
 816
 817   dnl Check for -fshort-wchar
 818   AC_CACHE_CHECK([for gcc -fshort-wchar support], ac_cv_c_gcc_fshort_wchar,
 819       [WINE_TRY_CFLAGS([-fshort-wchar],
 820                       ac_cv_c_gcc_fshort_wchar="yes",ac_cv_c_gcc_fshort_wchar="no")])
 821   if test "$ac_cv_c_gcc_fshort_wchar" = "yes"
 822   then
 823       AC_DEFINE(CC_FLAG_SHORT_WCHAR, "-fshort-wchar", [Specifies the compiler flag that forces a short wchar_t])
 824   fi
 825
 826   dnl Check for -mpreferred-stack-boundary
 827   AC_CACHE_CHECK([for gcc -mpreferred-stack-boundary=2 support], ac_cv_c_gcc_stack_boundary,
 828       [WINE_TRY_CFLAGS([-mpreferred-stack-boundary=2],
 829                       ac_cv_c_gcc_stack_boundary="yes",ac_cv_c_gcc_stack_boundary="no")])
 830   if test "$ac_cv_c_gcc_stack_boundary" = "yes"
 831   then
 832     EXTRACFLAGS="$EXTRACFLAGS -mpreferred-stack-boundary=2"
 833   fi
 834
 835   dnl Check for -fno-strict-aliasing
 836   AC_CACHE_CHECK([for gcc -fno-strict-aliasing support], ac_cv_c_gcc_no_strict_aliasing,
 837       [WINE_TRY_CFLAGS([-fno-strict-aliasing],
 838                       ac_cv_c_gcc_no_strict_aliasing="yes",ac_cv_c_gcc_no_strict_aliasing="no")])
 839   if test "$ac_cv_c_gcc_no_strict_aliasing" = "yes"
 840   then
 841     EXTRACFLAGS="$EXTRACFLAGS -fno-strict-aliasing"
 842   fi
 843
 844   dnl Check for -gstabs+ option
 845   AC_CACHE_CHECK([for gcc -gstabs+ support], ac_cv_c_gcc_gstabs,
 846       [WINE_TRY_CFLAGS([-gstabs+],ac_cv_c_gcc_gstabs="yes", ac_cv_c_gcc_gstabs="no")])
 847   if test "$ac_cv_c_gcc_gstabs" = "yes"
 848   then
 849     EXTRACFLAGS="$EXTRACFLAGS -gstabs+"
 850   fi
 851
 852   dnl Check for noisy string.h
 853   saved_CFLAGS="$CFLAGS"
 854   CFLAGS="$CFLAGS -Wpointer-arith -Werror"
 855   AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
 856       AC_TRY_COMPILE([#include <string.h>],[],
 857                      [ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
 858   CFLAGS="$saved_CFLAGS"
 859   if test "$ac_cv_c_string_h_warnings" = "no"
 860   then
 861     EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
 862   fi
 863 fi
 864
 865 dnl **** Check how to define a function in assembly code ****
 866
 867 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
 868   WINE_TRY_ASM_LINK(
 869       ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
 870       ac_cv_asm_func_def=".def",
 871     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
 872       ac_cv_asm_func_def=".type @function",
 873     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
 874       ac_cv_asm_func_def=".type 2",
 875       ac_cv_asm_func_def="unknown")])]))
 876
 877 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
 878 case "$ac_cv_asm_func_def" in
 879   ".def")
 880      AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
 881   ".type @function")
 882      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
 883   ".type 2")
 884      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
 885   *)
 886      AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
 887 esac
 888
 889 dnl **** Check for underscore on external symbols ****
 890
 891 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
 892     WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
 893                       [extern int ac_test;],
 894                       [if (ac_test) return 1],
 895                       ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
 896
 897 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
 898 if test "$ac_cv_c_extern_prefix" = "yes"
 899 then
 900   AC_DEFINE([__ASM_NAME(name)], ["_" name])
 901 else
 902   AC_DEFINE([__ASM_NAME(name)], [name])
 903 fi
 904
 905 dnl **** Check for working dll ****
 906
 907 AC_SUBST(DLLEXT,"")
 908 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
 909 AC_SUBST(DLLIBS,"")
 910 AC_SUBST(LDSHARED,"")
 911 AC_SUBST(LDDLLFLAGS,"")
 912 AC_SUBST(LIBEXT,"so")
 913 AC_SUBST(IMPLIBEXT,"def")
 914
 915 case $host_os in
 916   cygwin*|mingw32*)
 917     AC_CHECK_TOOL(DLLTOOL,dlltool,false)
 918     AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
 919     if test "$DLLWRAP" = "false"; then
 920       LIBEXT="a"
 921     else
 922       dnl FIXME - check whether dllwrap works correctly...
 923       LIBEXT="dll"
 924     fi
 925     IMPLIBEXT="a"
 926     dnl We can't build 16-bit NE dlls
 927     WIN16_FILES=""
 928     WIN16_INSTALL=""
 929     ;;
 930   *)
 931     AC_CHECK_HEADERS(dlfcn.h,
 932         [AC_CHECK_FUNCS(dlopen,,
 933             [AC_CHECK_LIB(dl,dlopen,
 934                          [AC_DEFINE(HAVE_DLOPEN,1,[Define if you have dlopen])
 935                           DLLIBS="-ldl"],
 936                          [LIBEXT="a"])])],
 937         [LIBEXT="a"])
 938
 939     if test "$LIBEXT" = "so"
 940     then
 941       DLLFLAGS="$DLLFLAGS -fPIC"
 942       DLLEXT=".so"
 943       AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
 944           [WINE_TRY_SHLIB_FLAGS([-fPIC -shared -Wl,-soname,conftest.so.1.0,-Bsymbolic],
 945                                 ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
 946       if test "$ac_cv_c_dll_gnuelf" = "yes"
 947       then
 948         LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"
 949         LDDLLFLAGS="-shared -Wl,-Bsymbolic"
 950         AC_CACHE_CHECK([whether the linker accepts -z defs], ac_cv_c_dll_zdefs,
 951           [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs],
 952                            ac_cv_c_dll_zdefs="yes",ac_cv_c_dll_zdefs="no")])
 953         if test "$ac_cv_c_dll_zdefs" = "yes"
 954         then
 955           LDDLLFLAGS="$LDDLLFLAGS,-z,defs"
 956         fi
 957
 958         AC_CACHE_CHECK([whether the linker accepts -init and -fini], ac_cv_c_dll_init_fini,
 959           [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-init,__wine_spec_init,-fini,__wine_spec_fini],
 960                            ac_cv_c_dll_init_fini="yes",ac_cv_c_dll_init_fini="no")])
 961         if test "$ac_cv_c_dll_init_fini" = "yes"
 962         then
 963           LDDLLFLAGS="$LDDLLFLAGS,-init,__wine_spec_init,-fini,__wine_spec_fini"
 964         fi
 965
 966         AC_CACHE_CHECK([whether the linker accepts version scripts], ac_cv_c_ld_version_scripts,
 967           [echo '{ global: *; };' >conftest.map
 968            WINE_TRY_CFLAGS([-fPIC -shared -Wl,--version-script=conftest.map],
 969                            ac_cv_c_ld_version_scripts="yes",ac_cv_c_ld_version_scripts="no")
 970            rm -f conftest.map])
 971         if test "$ac_cv_c_ld_version_scripts" = "yes"
 972         then
 973           LDSHARED="$LDSHARED \$(VERSCRIPT:%=-Wl,--version-script=%)"
 974         fi
 975
 976         AC_CACHE_CHECK([whether the linker accepts --export-dynamic], ac_cv_c_export_dynamic,
 977           [WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
 978                            ac_cv_c_export_dynamic="yes",ac_cv_c_export_dynamic="no")])
 979         if test "$ac_cv_c_export_dynamic" = "yes"
 980         then
 981           AC_SUBST(LDEXECFLAGS,["-Wl,--export-dynamic"])
 982         fi
 983
 984         case $host_cpu in
 985           *i[[3456789]]86*)
 986             AC_CACHE_CHECK([whether we can relocate the executable to 0x7bf00000], ac_cv_ld_reloc_exec,
 987               [WINE_TRY_CFLAGS([-Wl,--section-start,.interp=0x7bf00400],
 988                                ac_cv_ld_reloc_exec="yes", ac_cv_ld_reloc_exec="no")])
 989             if test "$ac_cv_ld_reloc_exec" = "yes"
 990             then
 991               LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x7bf00400"
 992             fi
 993             ;;
 994         esac
 995
 996       else
 997         AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
 998             [WINE_TRY_SHLIB_FLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
 999                                   ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
1000         if test "$ac_cv_c_dll_unixware" = "yes"
1001         then
1002           LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
1003           LDDLLFLAGS="-Wl,-G,-B,symbolic"
1004
1005         else
1006           AC_CACHE_CHECK(whether we can build a Mach-O (Mac OS X/Darwin) dll, ac_cv_c_dll_macho,
1007             [WINE_TRY_SHLIB_FLAGS([-bundle], ac_cv_c_dll_macho="yes", ac_cv_c_dll_macho="no")])
1008           if test "$ac_cv_c_dll_macho" = "yes"
1009           then
1010             LIBEXT="dylib"
1011             LDDLLFLAGS="-bundle -flat_namespace -undefined suppress -read_only_relocs warning"
1012             LDSHARED="\$(CC) -dynamiclib"
1013             CFLAGS="$CFLAGS -ffixed-r13 -no-cpp-precomp"
1014             STRIP="$STRIP -u -r"
1015             dnl Relocate wine executable
1016             AC_SUBST(LDEXECFLAGS,"-seg1addr 0x120000")
1017             dnl Relocate libwine.dyld too
1018             AC_SUBST(LDLIBWINEFLAGS,"-seg1addr 0x140000")
1019             dnl declare needed frameworks
1020             AC_SUBST(COREFOUNDATIONLIB,"-framework CoreFoundation")
1021             AC_SUBST(IOKITLIB,"-framework IOKit")
1022             dnl using IOKit imply we use CoreFoundation too
1023             IOKITLIB="$IOKITLIB $COREFOUNDATIONLIB"
1024           else
1025             AC_CACHE_CHECK(whether we can build an HP-UX dll, ac_cv_c_dll_hpux,
1026               [WINE_TRY_SHLIB_FLAGS([-shared], ac_cv_c_dll_hpux="yes", ac_cv_c_dll_hpux="no")])
1027             if test "$ac_cv_c_dll_hpux" = "yes"
1028             then
1029               LIBEXT="sl"
1030               DLLEXT=".sl"
1031               LDDLLFLAGS="-shared -fPIC"
1032               LDSHARED="\$(CC) -shared"
1033             fi
1034           fi
1035         fi
1036       fi
1037     fi
1038
1039     dnl Check for cross compiler to build test programs
1040     AC_SUBST(CROSSTEST,"")
1041     if test "$cross_compiling" = "no"
1042     then
1043       AC_CHECK_PROGS(CROSSCC,i586-mingw32msvc-gcc i386-mingw32msvc-gcc i386-mingw32-gcc mingw-gcc,false)
1044       AC_CHECK_PROGS(DLLTOOL,i586-mingw32msvc-dlltool i386-mingw32msvc-dlltool i386-mingw32-dlltool mingw-dlltool,false)
1045       AC_CHECK_PROGS(CROSSWINDRES,i586-mingw32msvc-windres i386-mingw32msvc-windres i386-mingw32-windres mingw-windres,false)
1046       if test "$CROSSCC" != "false"; then CROSSTEST="\$(CROSSTEST)"; fi
1047     fi
1048     ;;
1049 esac
1050
1051 if test "$LIBEXT" = "a"; then
1052   AC_MSG_ERROR(
1053 [could not find a way to build shared libraries.
1054 It is currently not possible to build Wine without shared library
1055 (.so) support to allow transparent switch between .so and .dll files.
1056 If you are using Linux, you will need a newer binutils.]
1057 )
1058 fi
1059
1060 case $build_os in
1061   cygwin*|mingw32*)
1062     AC_SUBST(LDPATH,"PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$PATH\"") ;;
1063   darwin*|macosx*)
1064     AC_SUBST(LDPATH,"DYLD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$DYLD_LIBRARY_PATH\"") ;;
1065   *)
1066     AC_SUBST(LDPATH,"LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$LD_LIBRARY_PATH\"") ;;
1067 esac
1068
1069 dnl Mingw needs explicit msvcrt for linking libwine and winsock for wininet
1070 case $host_os in
1071   mingw32*)
1072     AC_SUBST(CRTLIBS,"-lmsvcrt")
1073     AC_SUBST(SOCKETLIBS,"-lws2_32")
1074     ;;
1075 esac
1076
1077 case $host_os in
1078   linux*)
1079     case $host_cpu in
1080       *i[[3456789]]86*) AC_SUBST(WINE_BINARIES,"wine-glibc wine-kthread wine-pthread wine-preloader") ;;
1081       *) AC_SUBST(WINE_BINARIES,"wine-glibc wine-kthread wine-pthread") ;;
1082     esac
1083     AC_SUBST(MAIN_BINARY,"wine-glibc")
1084     ;;
1085   darwin*)
1086     AC_SUBST(WINE_BINARIES,"wine-pthread")
1087     AC_SUBST(MAIN_BINARY,"wine-pthread")
1088     ;;
1089   *)
1090     AC_SUBST(WINE_BINARIES,"wine-kthread")
1091     AC_SUBST(MAIN_BINARY,"wine-kthread")
1092     ;;
1093 esac
1094
1095 dnl **** Get the soname for libraries that we load dynamically ****
1096
1097 if test "$LIBEXT" = "so" -o "$LIBEXT" = "dylib"
1098 then
1099   WINE_GET_SONAME(X11,XCreateWindow,[$X_LIBS $X_EXTRA_LIBS])
1100   WINE_GET_SONAME(Xext,XextCreateExtension,[$X_LIBS -lX11 $X_EXTRA_LIBS])
1101   WINE_GET_SONAME(Xi,XOpenDevice,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1102   WINE_GET_SONAME(Xrender,XRenderQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1103   WINE_GET_SONAME(Xrandr,XRRQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1104   WINE_GET_SONAME(freetype,FT_Init_FreeType,[$X_LIBS])
1105   WINE_GET_SONAME(GL,glXQueryExtension,[$X_LIBS $X_EXTRA_LIBS])
1106   WINE_GET_SONAME(txc_dxtn,fetch_2d_texel_rgba_dxt1)
1107   WINE_GET_SONAME(cups,cupsGetDefault)
1108   WINE_GET_SONAME(jack,jack_client_new)
1109   WINE_GET_SONAME(fontconfig,FcInit)
1110   WINE_GET_SONAME(ssl,SSL_library_init)
1111   WINE_GET_SONAME(crypto,BIO_new_socket)
1112   WINE_GET_SONAME(ncurses,waddch)
1113   WINE_GET_SONAME(curses,waddch)
1114   WINE_GET_SONAME(jpeg,jpeg_start_decompress)
1115   WINE_GET_SONAME(ungif,DGifOpen)
1116   WINE_GET_SONAME(gif,DGifOpen)
1117   WINE_GET_SONAME(capi20,capi20_isinstalled)
1118 fi
1119
1120
1121 dnl **** Check for functions ****
1122
1123 AC_FUNC_ALLOCA()
1124 AC_CHECK_FUNCS(\
1125         _lwp_create \
1126         _lwp_self \
1127         _pclose \
1128         _popen \
1129         _snprintf \
1130         _spawnvp \
1131         _stricmp \
1132         _strnicmp \
1133         _vsnprintf \
1134         chsize \
1135         clone \
1136         epoll_create \
1137         ffs \
1138         finite \
1139         fork \
1140         fpclass \
1141         fstatfs \
1142         fstatvfs \
1143         ftruncate \
1144         futimes \
1145         futimesat \
1146         getnetbyname \
1147         getopt_long \
1148         getpagesize \
1149         getprotobyname \
1150         getprotobynumber \
1151         getpwuid \
1152         getservbyport \
1153         gettid \
1154         gettimeofday \
1155         getuid \
1156         inet_network \
1157         lstat \
1158         memmove \
1159         mmap \
1160         pclose \
1161         popen \
1162         pread \
1163         pwrite \
1164         readlink \
1165         rfork \
1166         sched_yield \
1167         select \
1168         sendmsg \
1169         settimeofday \
1170         sigaltstack \
1171         sigprocmask \
1172         snprintf \
1173         spawnvp \
1174         statfs \
1175         statvfs \
1176         strcasecmp \
1177         strerror \
1178         strncasecmp \
1179         tcgetattr \
1180         timegm \
1181         usleep \
1182         vsnprintf \
1183         wait4 \
1184         waitpid \
1185 )
1186
1187 dnl **** Checks for headers that depend on other ones ****
1188
1189 AC_CHECK_HEADERS(sys/mount.h sys/user.h,,,
1190     [#include <sys/types.h>
1191      #if HAVE_SYS_PARAM_H
1192      # include <sys/param.h>
1193      #endif])
1194
1195 AC_CHECK_HEADERS([net/if.h net/if_arp.h net/if_dl.h net/if_types.h net/route.h],,,
1196     [#include <sys/types.h>
1197      #if HAVE_SYS_SOCKET_H
1198      # include <sys/socket.h>
1199      #endif])
1200
1201 AC_CHECK_HEADERS([resolv.h],,,
1202     [#include <sys/types.h>
1203      #if HAVE_SYS_SOCKET_H
1204      # include <sys/socket.h>
1205      #endif
1206      #if HAVE_NETINET_IN_H
1207      # include <netinet/in.h>
1208      #endif
1209      #if HAVE_ARPA_NAMESER_H
1210      # include <arpa/nameser.h>
1211      #endif])
1212
1213 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
1214
1215 dnl **** Check for v4l(2) headers ****
1216
1217 AC_CHECK_HEADERS(linux/videodev.h,,,
1218 [#ifdef HAVE_SYS_TIME_H
1219 #include <sys/time.h>
1220 #endif
1221 #include <sys/types.h>
1222 #ifdef HAVE_ASM_TYPES_H
1223 #include <asm/types.h>
1224 #endif])
1225
1226 dnl **** Check for IPX headers (currently Linux only) ****
1227
1228 AC_CACHE_CHECK([for GNU style IPX support], ac_cv_c_ipx_gnu,
1229  AC_TRY_COMPILE(
1230    [#include <sys/types.h>
1231     #ifdef HAVE_SYS_SOCKET_H
1232     # include <sys/socket.h>
1233     #endif
1234     #include <netipx/ipx.h>],
1235    [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
1236    [ac_cv_c_ipx_gnu="yes"],
1237    [ac_cv_c_ipx_gnu="no"])
1238  )
1239 if test "$ac_cv_c_ipx_gnu" = "yes"
1240 then
1241     AC_DEFINE(HAVE_IPX_GNU, 1, [Define if IPX should use netipx/ipx.h from libc])
1242 fi
1243
1244 if test "$ac_cv_c_ipx_gnu" = "no"
1245 then
1246  AC_CACHE_CHECK([for linux style IPX support], ac_cv_c_ipx_linux,
1247   AC_TRY_COMPILE(
1248     [#include <sys/types.h>
1249      #ifdef HAVE_SYS_SOCKET_H
1250      # include <sys/socket.h>
1251      #endif
1252      #include <asm/types.h>
1253      #include <linux/ipx.h>],
1254     [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
1255     [ac_cv_c_ipx_linux="yes"],
1256     [ac_cv_c_ipx_linux="no"])
1257   )
1258   if test "$ac_cv_c_ipx_linux" = "yes"
1259   then
1260       AC_DEFINE(HAVE_IPX_LINUX, 1, [Define if IPX includes are taken from Linux kernel])
1261   fi
1262 fi
1263
1264 dnl **** Check for types ****
1265
1266 AC_C_CONST
1267 AC_C_INLINE
1268 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t, long long, fsblkcnt_t, fsfilcnt_t])
1269 AC_CHECK_TYPES([sigset_t],,,[#include <signal.h>])
1270 AC_CHECK_TYPES([request_sense],,,[#include <linux/cdrom.h>])
1271
1272 AC_CACHE_CHECK([whether linux/input.h is for real],
1273         wine_cv_linux_input_h,
1274         AC_TRY_COMPILE([
1275             #include <linux/input.h>
1276         ] , [
1277             int foo = EVIOCGBIT(EV_ABS,42);
1278             int bar = BTN_PINKIE;
1279             int fortytwo = 42;
1280         ],
1281         wine_cv_linux_input_h=yes,
1282         wine_cv_linux_input_h=no,
1283         no
1284         )
1285     )
1286     if test "$wine_cv_linux_input_h" = "yes"
1287     then
1288         AC_DEFINE(HAVE_CORRECT_LINUXINPUT_H, 1,
1289                   [Define if we have linux/input.h AND it contains the INPUT event API])
1290     fi
1291
1292 AC_CHECK_MEMBERS([struct ff_effect.direction],,,
1293 [#ifdef HAVE_LINUX_INPUT_H
1294 #include <linux/input.h>
1295 #endif])
1296
1297 AC_CACHE_CHECK([for sigaddset],wine_cv_have_sigaddset,
1298                AC_TRY_LINK([#include <signal.h>],[sigset_t set; sigaddset(&set,SIGTERM);],
1299                            wine_cv_have_sigaddset=yes,wine_cv_have_sigaddset=no))
1300 if test "$wine_cv_have_sigaddset" = "yes"
1301 then
1302   AC_DEFINE(HAVE_SIGADDSET, 1, [Define if sigaddset is supported])
1303 fi
1304
1305
1306 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1307         wine_cv_linux_gethostbyname_r_6,
1308         AC_TRY_LINK([
1309 #include <netdb.h>
1310         ], [
1311     char *name=NULL;
1312     struct hostent he;
1313     struct hostent *result;
1314     char *buf=NULL;
1315     int bufsize=0;
1316     int res,errnr;
1317     char *addr=NULL;
1318     int addrlen=0;
1319     int addrtype=0;
1320     res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1321     res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1322     ],
1323         wine_cv_linux_gethostbyname_r_6=yes,
1324         wine_cv_linux_gethostbyname_r_6=no
1325         )
1326    )
1327    if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1328    then
1329       AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1330                 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1331    fi
1332
1333 if test "$ac_cv_header_linux_joystick_h" = "yes"
1334 then
1335    AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1336         wine_cv_linux_joystick_22_api,
1337         AC_TRY_COMPILE([
1338         #include <sys/ioctl.h>
1339         #include <linux/joystick.h>
1340
1341         struct js_event blub;
1342         #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1343         #error "no 2.2 header"
1344         #endif
1345         ],/*empty*/,
1346         wine_cv_linux_joystick_22_api=yes,
1347         wine_cv_linux_joystick_22_api=no,
1348         wine_cv_linux_joystick_22_api=no
1349         )
1350    )
1351    if test "$wine_cv_linux_joystick_22_api" = "yes"
1352    then
1353       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1354                 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1355    fi
1356 fi
1357
1358 dnl **** statfs checks ****
1359
1360 if test "$ac_cv_header_sys_vfs_h" = "yes"
1361 then
1362     AC_CACHE_CHECK( [whether sys/vfs.h defines statfs],
1363                     wine_cv_sys_vfs_has_statfs,
1364         AC_TRY_COMPILE([
1365         #include <sys/types.h>
1366         #ifdef HAVE_SYS_PARAM_H
1367         # include <sys/param.h>
1368         #endif
1369         #include <sys/vfs.h>
1370         ],[
1371                 struct statfs stfs;
1372
1373                 memset(&stfs,0,sizeof(stfs));
1374         ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
1375         )
1376     )
1377     if test "$wine_cv_sys_vfs_has_statfs" = "yes"
1378     then
1379       AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS, 1,
1380                 [Define if the struct statfs is defined by <sys/vfs.h>])
1381     fi
1382 fi
1383
1384 if test "$ac_cv_header_sys_statfs_h" = "yes"
1385 then
1386     AC_CACHE_CHECK( [whether sys/statfs.h defines statfs],
1387                     wine_cv_sys_statfs_has_statfs,
1388         AC_TRY_COMPILE([
1389         #include <sys/types.h>
1390         #ifdef HAVE_SYS_PARAM_H
1391         # include <sys/param.h>
1392         #endif
1393         #include <sys/statfs.h>
1394         ],[
1395                 struct statfs stfs;
1396         ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
1397         )
1398     )
1399     if test "$wine_cv_sys_statfs_has_statfs" = "yes"
1400     then
1401       AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS, 1,
1402                 [Define if the struct statfs is defined by <sys/statfs.h>])
1403     fi
1404 fi
1405
1406 if test "$ac_cv_header_sys_mount_h" = "yes"
1407 then
1408     AC_CACHE_CHECK( [whether sys/mount.h defines statfs],
1409                     wine_cv_sys_mount_has_statfs,
1410         AC_TRY_COMPILE([
1411         #include <sys/types.h>
1412         #ifdef HAVE_SYS_PARAM_H
1413         # include <sys/param.h>
1414         #endif
1415         #include <sys/mount.h>
1416         ],[
1417                 struct statfs stfs;
1418         ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
1419         )
1420     )
1421     if test "$wine_cv_sys_mount_has_statfs" = "yes"
1422     then
1423       AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT, 1,
1424                 [Define if the struct statfs is defined by <sys/mount.h>])
1425     fi
1426 fi
1427
1428 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1429
1430 dnl Check for statfs members
1431 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail, struct statfs.f_frsize, struct statfs.f_ffree, struct statfs.f_favail, struct statfs.f_namelen],,,
1432 [#include <sys/types.h>
1433 #ifdef HAVE_SYS_PARAM_H
1434 # include <sys/param.h>
1435 #endif
1436 #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1437 # include <sys/mount.h>
1438 #else
1439 # ifdef STATFS_DEFINED_BY_SYS_VFS
1440 #  include <sys/vfs.h>
1441 # else
1442 #  ifdef STATFS_DEFINED_BY_SYS_STATFS
1443 #   include <sys/statfs.h>
1444 #  endif
1445 # endif
1446 #endif])
1447
1448 AC_CHECK_MEMBERS([struct statvfs.f_blocks],,,
1449 [#ifdef HAVE_SYS_STATVFS_H
1450 #include <sys/statvfs.h>
1451 #endif])
1452
1453 dnl Check for socket structure members
1454 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
1455 [#include <sys/types.h>
1456 #ifdef HAVE_SYS_SOCKET_H
1457 # include <sys/socket.h>
1458 #endif
1459 #ifdef HAVE_SYS_UN_H
1460 # include <sys/un.h>
1461 #endif])
1462
1463 dnl Check for scsireq_t and sg_io_hdr_t members
1464 AC_CHECK_MEMBERS([scsireq_t.cmd, sg_io_hdr_t.interface_id],,,
1465 [#include <sys/types.h>
1466 #ifdef HAVE_SCSI_SG_H
1467 #include <scsi/sg.h>
1468 #endif])
1469
1470 dnl Check for siginfo_t members
1471 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
1472
1473 dnl Check for struct option
1474 AC_CHECK_MEMBERS([struct option.name],,,
1475 [#ifdef HAVE_GETOPT_H
1476 #include <getopt.h>
1477 #endif])
1478
1479 dnl Check for stat.st_blocks
1480 AC_CHECK_MEMBERS([struct stat.st_blocks])
1481
1482 dnl Check for the external timezone variables timezone and daylight
1483 AC_CACHE_CHECK([for timezone variable], ac_cv_have_timezone,
1484                AC_TRY_LINK([#include <time.h>],[timezone;],
1485                            ac_cv_have_timezone="yes", ac_cv_have_timezone="no"))
1486 if test "$ac_cv_have_timezone" = "yes"
1487 then
1488     AC_DEFINE(HAVE_TIMEZONE, 1, [Define if you have the timezone variable])
1489 fi
1490 AC_CACHE_CHECK([for daylight variable], ac_cv_have_daylight,
1491                AC_TRY_LINK([#include <time.h>],[daylight;],
1492                            ac_cv_have_daylight="yes", ac_cv_have_daylight="no"))
1493 if test "$ac_cv_have_daylight" = "yes"
1494 then
1495     AC_DEFINE(HAVE_DAYLIGHT, 1, [Define if you have the daylight variable])
1496 fi
1497
1498 dnl *** check for the need to define platform-specific symbols
1499
1500 case $host_cpu in
1501   *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
1502   *alpha*)          WINE_CHECK_DEFINE([__ALPHA__]) ;;
1503   *sparc*)          WINE_CHECK_DEFINE([__sparc__]) ;;
1504   *powerpc*)        WINE_CHECK_DEFINE([__powerpc__]) ;;
1505 esac
1506
1507 case $host_vendor in
1508   *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
1509 esac
1510
1511 dnl **** Generate output files ****
1512
1513 AH_TOP([#define __WINE_CONFIG_H])
1514
1515 WINE_CONFIG_EXTRA_DIR(dlls/gdi/enhmfdrv)
1516 WINE_CONFIG_EXTRA_DIR(dlls/gdi/mfdrv)
1517 WINE_CONFIG_EXTRA_DIR(dlls/kernel/messages)
1518 WINE_CONFIG_EXTRA_DIR(dlls/user/resources)
1519 WINE_CONFIG_EXTRA_DIR(dlls/wineps/data)
1520 WINE_CONFIG_EXTRA_DIR(include/wine)
1521 WINE_CONFIG_EXTRA_DIR(programs/regedit/tests)
1522
1523 MAKE_RULES=Make.rules
1524 AC_SUBST_FILE(MAKE_RULES)
1525
1526 MAKE_DLL_RULES=dlls/Makedll.rules
1527 AC_SUBST_FILE(MAKE_DLL_RULES)
1528
1529 MAKE_TEST_RULES=dlls/Maketest.rules
1530 AC_SUBST_FILE(MAKE_TEST_RULES)
1531
1532 MAKE_LIB_RULES=libs/Makelib.rules
1533 AC_SUBST_FILE(MAKE_LIB_RULES)
1534
1535 MAKE_PROG_RULES=programs/Makeprog.rules
1536 AC_SUBST_FILE(MAKE_PROG_RULES)
1537
1538 AC_CONFIG_FILES([
1539 Make.rules
1540 dlls/Makedll.rules
1541 dlls/Maketest.rules
1542 libs/Makelib.rules
1543 programs/Makeprog.rules
1544 Makefile
1545 dlls/Makefile
1546 dlls/activeds/Makefile
1547 dlls/advapi32/Makefile
1548 dlls/advapi32/tests/Makefile
1549 dlls/advpack/Makefile
1550 dlls/advpack/tests/Makefile
1551 dlls/amstream/Makefile
1552 dlls/atl/Makefile
1553 dlls/avicap32/Makefile
1554 dlls/avifil32/Makefile
1555 dlls/cabinet/Makefile
1556 dlls/capi2032/Makefile
1557 dlls/cards/Makefile
1558 dlls/cfgmgr32/Makefile
1559 dlls/comcat/Makefile
1560 dlls/comctl32/Makefile
1561 dlls/comctl32/tests/Makefile
1562 dlls/commdlg/Makefile
1563 dlls/crtdll/Makefile
1564 dlls/crypt32/Makefile
1565 dlls/crypt32/tests/Makefile
1566 dlls/cryptdll/Makefile
1567 dlls/ctl3d/Makefile
1568 dlls/d3d8/Makefile
1569 dlls/d3d9/Makefile
1570 dlls/d3dim/Makefile
1571 dlls/d3drm/Makefile
1572 dlls/d3dx8/Makefile
1573 dlls/d3dxof/Makefile
1574 dlls/dbghelp/Makefile
1575 dlls/dciman32/Makefile
1576 dlls/ddraw/Makefile
1577 dlls/ddraw/tests/Makefile
1578 dlls/devenum/Makefile
1579 dlls/dinput/Makefile
1580 dlls/dinput/tests/Makefile
1581 dlls/dinput8/Makefile
1582 dlls/dmband/Makefile
1583 dlls/dmcompos/Makefile
1584 dlls/dmime/Makefile
1585 dlls/dmloader/Makefile
1586 dlls/dmscript/Makefile
1587 dlls/dmstyle/Makefile
1588 dlls/dmsynth/Makefile
1589 dlls/dmusic/Makefile
1590 dlls/dmusic32/Makefile
1591 dlls/dplay/Makefile
1592 dlls/dplayx/Makefile
1593 dlls/dpnet/Makefile
1594 dlls/dpnhpast/Makefile
1595 dlls/dsound/Makefile
1596 dlls/dsound/tests/Makefile
1597 dlls/dswave/Makefile
1598 dlls/dxdiagn/Makefile
1599 dlls/dxerr8/Makefile
1600 dlls/dxerr9/Makefile
1601 dlls/dxguid/Makefile
1602 dlls/gdi/Makefile
1603 dlls/gdi/tests/Makefile
1604 dlls/glu32/Makefile
1605 dlls/glut32/Makefile
1606 dlls/hhctrl.ocx/Makefile
1607 dlls/iccvid/Makefile
1608 dlls/icmp/Makefile
1609 dlls/ifsmgr.vxd/Makefile
1610 dlls/imagehlp/Makefile
1611 dlls/imm32/Makefile
1612 dlls/iphlpapi/Makefile
1613 dlls/iphlpapi/tests/Makefile
1614 dlls/itss/Makefile
1615 dlls/kernel/Makefile
1616 dlls/kernel/tests/Makefile
1617 dlls/lzexpand/Makefile
1618 dlls/lzexpand/tests/Makefile
1619 dlls/mapi32/Makefile
1620 dlls/mapi32/tests/Makefile
1621 dlls/midimap/Makefile
1622 dlls/mlang/Makefile
1623 dlls/mlang/tests/Makefile
1624 dlls/mmdevldr.vxd/Makefile
1625 dlls/monodebg.vxd/Makefile
1626 dlls/mpr/Makefile
1627 dlls/msacm/Makefile
1628 dlls/msacm/imaadp32/Makefile
1629 dlls/msacm/msadp32/Makefile
1630 dlls/msacm/msg711/Makefile
1631 dlls/msacm/winemp3/Makefile
1632 dlls/msacm/tests/Makefile
1633 dlls/mscms/Makefile
1634 dlls/mscms/tests/Makefile
1635 dlls/msdmo/Makefile
1636 dlls/mshtml/Makefile
1637 dlls/mshtml/tests/Makefile
1638 dlls/msi/Makefile
1639 dlls/msi/tests/Makefile
1640 dlls/msimg32/Makefile
1641 dlls/msisys/Makefile
1642 dlls/msnet32/Makefile
1643 dlls/msrle32/Makefile
1644 dlls/msvcrt/Makefile
1645 dlls/msvcrt/tests/Makefile
1646 dlls/msvcrt20/Makefile
1647 dlls/msvcrt40/Makefile
1648 dlls/msvcrtd/Makefile
1649 dlls/msvcrtd/tests/Makefile
1650 dlls/msvidc32/Makefile
1651 dlls/msvideo/Makefile
1652 dlls/mswsock/Makefile
1653 dlls/netapi32/Makefile
1654 dlls/netapi32/tests/Makefile
1655 dlls/newdev/Makefile
1656 dlls/ntdll/Makefile
1657 dlls/ntdll/tests/Makefile
1658 dlls/objsel/Makefile
1659 dlls/odbc32/Makefile
1660 dlls/odbccp32/Makefile
1661 dlls/ole32/Makefile
1662 dlls/ole32/tests/Makefile
1663 dlls/oleacc/Makefile
1664 dlls/oleaut32/Makefile
1665 dlls/oleaut32/tests/Makefile
1666 dlls/olecli/Makefile
1667 dlls/oledlg/Makefile
1668 dlls/olepro32/Makefile
1669 dlls/olesvr/Makefile
1670 dlls/opengl32/Makefile
1671 dlls/powrprof/Makefile
1672 dlls/psapi/Makefile
1673 dlls/psapi/tests/Makefile
1674 dlls/qcap/Makefile
1675 dlls/quartz/Makefile
1676 dlls/quartz/tests/Makefile
1677 dlls/rasapi32/Makefile
1678 dlls/riched20/Makefile
1679 dlls/richedit/Makefile
1680 dlls/rpcrt4/Makefile
1681 dlls/rpcrt4/tests/Makefile
1682 dlls/rsabase/Makefile
1683 dlls/rsabase/tests/Makefile
1684 dlls/rsaenh/Makefile
1685 dlls/rsaenh/tests/Makefile
1686 dlls/secur32/Makefile
1687 dlls/sensapi/Makefile
1688 dlls/serialui/Makefile
1689 dlls/setupapi/Makefile
1690 dlls/shdocvw/Makefile
1691 dlls/shell32/Makefile
1692 dlls/shell32/tests/Makefile
1693 dlls/shfolder/Makefile
1694 dlls/shlwapi/Makefile
1695 dlls/shlwapi/tests/Makefile
1696 dlls/snmpapi/Makefile
1697 dlls/stdole2.tlb/Makefile
1698 dlls/stdole32.tlb/Makefile
1699 dlls/sti/Makefile
1700 dlls/strmiids/Makefile
1701 dlls/tapi32/Makefile
1702 dlls/ttydrv/Makefile
1703 dlls/twain/Makefile
1704 dlls/unicows/Makefile
1705 dlls/url/Makefile
1706 dlls/urlmon/Makefile
1707 dlls/urlmon/tests/Makefile
1708 dlls/user/Makefile
1709 dlls/user/tests/Makefile
1710 dlls/usp10/Makefile
1711 dlls/uuid/Makefile
1712 dlls/uxtheme/Makefile
1713 dlls/vdhcp.vxd/Makefile
1714 dlls/vdmdbg/Makefile
1715 dlls/version/Makefile
1716 dlls/version/tests/Makefile
1717 dlls/vmm.vxd/Makefile
1718 dlls/vnbt.vxd/Makefile
1719 dlls/vnetbios.vxd/Makefile
1720 dlls/vtdapi.vxd/Makefile
1721 dlls/vwin32.vxd/Makefile
1722 dlls/win32s/Makefile
1723 dlls/winaspi/Makefile
1724 dlls/wined3d/Makefile
1725 dlls/winedos/Makefile
1726 dlls/wineps/Makefile
1727 dlls/wininet/Makefile
1728 dlls/wininet/tests/Makefile
1729 dlls/winmm/Makefile
1730 dlls/winmm/joystick/Makefile
1731 dlls/winmm/mcianim/Makefile
1732 dlls/winmm/mciavi/Makefile
1733 dlls/mcicda/Makefile
1734 dlls/winmm/mciseq/Makefile
1735 dlls/winmm/mciwave/Makefile
1736 dlls/winmm/tests/Makefile
1737 dlls/winmm/wavemap/Makefile
1738 dlls/winmm/winealsa/Makefile
1739 dlls/winmm/winearts/Makefile
1740 dlls/winmm/wineaudioio/Makefile
1741 dlls/winmm/winejack/Makefile
1742 dlls/winmm/winenas/Makefile
1743 dlls/winmm/wineoss/Makefile
1744 dlls/winnls/Makefile
1745 dlls/winsock/Makefile
1746 dlls/winsock/tests/Makefile
1747 dlls/winspool/Makefile
1748 dlls/winspool/tests/Makefile
1749 dlls/wintab32/Makefile
1750 dlls/wintrust/Makefile
1751 dlls/wldap32/Makefile
1752 dlls/wow32/Makefile
1753 dlls/wsock32/Makefile
1754 dlls/wtsapi32/Makefile
1755 dlls/x11drv/Makefile
1756 documentation/Makefile
1757 fonts/Makefile
1758 include/Makefile
1759 libs/Makefile
1760 libs/port/Makefile
1761 libs/unicode/Makefile
1762 libs/wine/Makefile
1763 libs/wpp/Makefile
1764 loader/Makefile
1765 programs/Makefile
1766 programs/avitools/Makefile
1767 programs/clock/Makefile
1768 programs/cmdlgtst/Makefile
1769 programs/control/Makefile
1770 programs/expand/Makefile
1771 programs/hh/Makefile
1772 programs/msiexec/Makefile
1773 programs/notepad/Makefile
1774 programs/progman/Makefile
1775 programs/regedit/Makefile
1776 programs/regsvr32/Makefile
1777 programs/rpcss/Makefile
1778 programs/rundll32/Makefile
1779 programs/start/Makefile
1780 programs/taskmgr/Makefile
1781 programs/uninstaller/Makefile
1782 programs/view/Makefile
1783 programs/wcmd/Makefile
1784 programs/wineboot/Makefile
1785 programs/winebrowser/Makefile
1786 programs/winecfg/Makefile
1787 programs/wineconsole/Makefile
1788 programs/winedbg/Makefile
1789 programs/winefile/Makefile
1790 programs/winemenubuilder/Makefile
1791 programs/winemine/Makefile
1792 programs/winepath/Makefile
1793 programs/winetest/Makefile
1794 programs/winevdm/Makefile
1795 programs/winhelp/Makefile
1796 programs/winver/Makefile
1797 server/Makefile
1798 tools/Makefile
1799 tools/widl/Makefile
1800 tools/winapi/Makefile
1801 tools/winebuild/Makefile
1802 tools/winedump/Makefile
1803 tools/winegcc/Makefile
1804 tools/wmc/Makefile
1805 tools/wrc/Makefile])
1806
1807 AC_OUTPUT
1808
1809 if test "$have_x" = "no"
1810 then
1811   echo
1812   echo "*** Warning: X development files not found. Wine will be built without"
1813   echo "*** X support, which currently does not work, and would probably not be"
1814   echo "*** what you want anyway. You will need to install devel packages of"
1815   echo "*** Xlib/Xfree86 at the very least."
1816 fi
1817
1818 if test "$wine_cv_opengl_version_OK" = "no"
1819 then
1820   echo
1821   echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
1822   echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)."
1823 fi
1824
1825 if test "$wine_cv_msg_freetype" = "yes"
1826 then
1827   echo
1828   echo "*** Note: Your system appears to have the FreeType 2 runtime libraries"
1829   echo "*** installed, but 'freetype-config' is not in your PATH. Install the"
1830   echo "*** freetype-devel package (or its equivalent on your distribution) to"
1831   echo "*** enable Wine to use TrueType fonts."
1832 fi
1833
1834 if test -z "$ALSALIBS" -a -z "$ARTSC_LIBS" -a -z "$AUDIOIOLIBS" -a \
1835         -z "$ac_cv_lib_soname_jack" -a -z "$NASLIBS" -a \
1836         "$ac_cv_c_opensoundsystem" = "no"
1837 then
1838     echo "*** No sound system was found. Windows applications will be silent."
1839     echo "*** The currently supported sound systems are:"
1840     echo "*** ALSA, ARTS, AudioIO, Jack, NAS and OSS"
1841 fi
1842
1843 echo
1844 echo "Configure finished.  Do '${ac_make} depend && ${ac_make}' to compile Wine."
1845 echo
1846
1847 dnl Local Variables:
1848 dnl comment-start: "dnl "
1849 dnl comment-end: ""
1850 dnl comment-start-skip: "\\bdnl\\b\\s *"
1851 dnl compile-command: "autoconf"
1852 dnl End: