git.oblomov.eu Git - wine/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Original author: Michael Patra
   3 dnl See ChangeLog file for detailed change history.
   4
   5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
   6
   7 AC_PREREQ(2.53)
   8 AC_INIT([Wine],WINE_VERSION,[wine-devel@winehq.org])
   9 AC_CONFIG_SRCDIR(server/atom.c)
  10 AC_CONFIG_HEADERS(include/config.h)
  11 AC_CONFIG_AUX_DIR(tools)
  12
  13 dnl **** Command-line arguments ****
  14
  15 AC_ARG_ENABLE(win16, AC_HELP_STRING([--disable-win16],[do not include Win16 support]))
  16 AC_ARG_ENABLE(debug, AC_HELP_STRING([--disable-debug],[compile out all debugging messages]))
  17 AC_ARG_ENABLE(trace, AC_HELP_STRING([--disable-trace],[compile out TRACE messages]))
  18
  19 AC_ARG_WITH(opengl,    AC_HELP_STRING([--without-opengl],[do not use OpenGL]))
  20 AC_ARG_WITH(curses,    AC_HELP_STRING([--without-curses],[do not use curses]))
  21 AC_ARG_WITH(wine-tools,AC_HELP_STRING([--with-wine-tools=<dir>],[use Wine tools from directory <dir>]))
  22
  23 AC_SUBST(WIN16_FILES,"\$(WIN16_FILES)")
  24 AC_SUBST(WIN16_INSTALL,"\$(WIN16_INSTALL)")
  25 if test "x$enable_win16" = "xno"
  26 then
  27   WIN16_FILES=""
  28   WIN16_INSTALL=""
  29 fi
  30 if test "x$enable_debug" = "xno"
  31 then
  32     AC_DEFINE(NO_DEBUG_MSGS,1,[Define to disable all debug messages.])
  33 fi
  34 if test "x$enable_trace" = "xno" -o "x$enable_debug" = "xno"
  35 then
  36     AC_DEFINE(NO_TRACE_MSGS,1,[Define to disable trace messages.])
  37 fi
  38
  39 dnl **** Check for some programs ****
  40
  41 AC_CANONICAL_HOST
  42 AC_PROG_MAKE_SET
  43 AC_PROG_CC
  44 AC_PROG_CXX
  45 dnl We can't use AC_PROG_CPP for winegcc, it uses by default $(CC) -E
  46 AC_CHECK_TOOL(CPPBIN,cpp,cpp)
  47
  48 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
  49   [if test -z "$with_wine_tools"; then
  50      if test "$cross_compiling" = "yes"; then
  51        AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
  52      else
  53        wine_cv_toolsdir="\$(TOPOBJDIR)"
  54      fi
  55    elif test -d "$with_wine_tools/tools/winebuild"; then
  56      case $with_wine_tools in
  57        /*) wine_cv_toolsdir="$with_wine_tools" ;;
  58        *)  wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
  59      esac
  60    else
  61      AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
  62    fi])
  63 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
  64
  65 AC_PATH_XTRA
  66 AC_PROG_LEX
  67
  68 dnl **** Just additional warning checks, since AC_PROG just sets 'lex' even
  69 dnl **** without one present.
  70 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
  71 if test "$XLEX" = "none"
  72 then
  73   AC_MSG_ERROR([no suitable lex found. Please install the 'flex' package.])
  74 fi
  75
  76 dnl Check for bison
  77 AC_CHECK_PROGS(BISON,bison,none)
  78 if test "$BISON" = "none"
  79 then
  80   AC_MSG_ERROR([no suitable bison found. Please install the 'bison' package.])
  81 fi
  82
  83 AC_CHECK_TOOLS(AS,[gas as],as)
  84 AC_CHECK_TOOL(LD,ld,ld)
  85 AC_CHECK_TOOL(AR,ar,ar)
  86 AC_PROG_RANLIB
  87 AC_CHECK_TOOL(STRIP,strip,strip)
  88 AC_CHECK_TOOL(WINDRES,windres,false)
  89 AC_PROG_LN_S
  90 WINE_PROG_LN
  91 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
  92 AC_PROG_INSTALL
  93 dnl Prepend src dir to install path dir if it's a relative path
  94 case "$INSTALL" in
  95   [[\\/$]]* | ?:[[\\/]]* ) ;;
  96   *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
  97 esac
  98
  99 dnl Check for lint
 100 AC_CHECK_PROGS(LINT, lclint lint)
 101 if test "$LINT" = "lint"
 102 then
 103   LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
 104   dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
 105 fi
 106 AC_SUBST(LINT)
 107 AC_SUBST(LINTFLAGS)
 108
 109 dnl Check for db2html
 110 AC_CHECK_PROGS(DB2HTML, docbook2html db2html, false)
 111 AC_SUBST(DB2HTML)
 112
 113 dnl Check for db2pdf
 114 AC_CHECK_PROGS(DB2PDF, docbook2pdf db2pdf, false)
 115 AC_SUBST(DB2PDF)
 116
 117 dnl Check for db2ps
 118 AC_CHECK_PROGS(DB2PS, docbook2ps db2ps, false)
 119 AC_SUBST(DB2PS)
 120
 121 dnl Check for db2txt
 122 AC_CHECK_PROGS(DB2TXT, docbook2txt db2txt, false)
 123 AC_SUBST(DB2TXT)
 124
 125 dnl **** Check for some libraries ****
 126
 127 dnl Check for -li386 for NetBSD and OpenBSD
 128 AC_CHECK_LIB(i386,i386_set_ldt)
 129 dnl Check for -lossaudio for NetBSD
 130 AC_CHECK_LIB(ossaudio,_oss_ioctl)
 131 dnl Check for -lw for Solaris
 132 AC_CHECK_FUNCS(iswalnum,,AC_CHECK_LIB(w,iswalnum))
 133 dnl Check for -lnsl for Solaris
 134 AC_CHECK_FUNCS(gethostbyname,,AC_CHECK_LIB(nsl,gethostbyname))
 135 dnl Check for -lsocket for Solaris
 136 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
 137 dnl Check for -lresolv for Solaris
 138 AC_CHECK_FUNCS(inet_aton,,AC_CHECK_LIB(resolv,inet_aton))
 139 dnl Check for -lxpg4 for FreeBSD
 140 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
 141 dnl Check for -lpoll for Mac OS X/Darwin
 142 AC_CHECK_LIB(poll,poll)
 143 dnl Check for -lresolv for Mac OS X/Darwin
 144 AC_CHECK_LIB(resolv,res_9_init)
 145 dnl Check for -lpthread
 146 AC_CHECK_LIB(pthread,pthread_create,AC_SUBST(LIBPTHREAD,"-lpthread"))
 147
 148 AC_SUBST(XLIB)
 149 AC_SUBST(XFILES)
 150 XFILES=""
 151 AC_SUBST(OPENGLFILES)
 152 OPENGLFILES=""
 153 AC_SUBST(GLU32FILES)
 154 GLU32FILES=""
 155 AC_SUBST(OPENGL_LIBS)
 156 OPENGL_LIBS=""
 157 if test "$have_x" = "yes"
 158 then
 159     XLIB="-lXext -lX11"
 160     ac_save_CPPFLAGS="$CPPFLAGS"
 161     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 162
 163     dnl *** All of the following tests require X11/Xlib.h
 164     AC_CHECK_HEADERS(X11/Xlib.h,
 165       [
 166         AC_CHECK_HEADERS([X11/XKBlib.h \
 167                           X11/Xutil.h \
 168                           X11/extensions/shape.h \
 169                           X11/extensions/XInput.h \
 170                           X11/extensions/XShm.h \
 171                           X11/extensions/Xrandr.h \
 172                           X11/extensions/Xrender.h \
 173                           X11/extensions/Xvlib.h \
 174                           X11/extensions/xf86dga.h \
 175                           X11/extensions/xf86vmode.h],,,
 176                          [#include <X11/Xlib.h>
 177                           #ifdef HAVE_X11_XUTIL_H
 178                           # include <X11/Xutil.h>
 179                           #endif])
 180
 181         dnl *** Check for X keyboard extension
 182         if test "$ac_cv_header_X11_XKBlib_h" = "yes"
 183         then
 184               AC_CHECK_LIB(X11, XkbQueryExtension,
 185               AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
 186               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 187         fi
 188
 189         dnl *** Check for X Shm extension
 190         if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
 191         then
 192               AC_CHECK_LIB(Xext, XShmQueryExtension,
 193               AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
 194               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 195         fi
 196
 197         dnl *** Check for X shape extension
 198         if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
 199         then
 200               AC_CHECK_LIB(Xext,XShapeQueryExtension,
 201               AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
 202               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 203         fi
 204
 205         dnl *** Check for XFree86 DGA / DGA 2.0 extension
 206         if test "$ac_cv_header_X11_extensions_xf86dga_h" = "yes"
 207         then
 208               AC_CHECK_LIB(Xxf86dga, XDGAQueryExtension,
 209                 [ dnl *** If found...
 210                   AC_DEFINE(HAVE_LIBXXF86DGA2, 1,
 211                             [Define if you have the Xxf86dga library version 2])
 212                   X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
 213                ],
 214                 [ dnl *** If not found, look for XF86DGAQueryExtension()
 215                   dnl *** instead (DGA 2.0 not found)...
 216                   AC_CHECK_LIB(Xxf86dga, XF86DGAQueryExtension,
 217                     [ AC_DEFINE(HAVE_LIBXXF86DGA, 1,
 218                                 [Define if you have the Xxf86dga library version 1])
 219                       X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
 220                     ],,
 221                     $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 222                   )
 223                 ],
 224                 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 225         fi
 226
 227         dnl *** Check for XFree86 VMODE extension
 228         if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
 229         then
 230                 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
 231                   [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
 232                      X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
 233                   ],,
 234                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 235         fi
 236
 237         dnl *** Check for X RandR extension
 238         if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes"
 239         then
 240                 AC_TRY_COMPILE([#include <X11/Xlib.h>
 241 #include <X11/extensions/Xrandr.h>],[static typeof(XRRSetScreenConfigAndRate) * func;],
 242                   [AC_DEFINE(HAVE_LIBXRANDR, 1, [Define if you have the Xrandr library])])
 243         fi
 244
 245         dnl *** Check for XVideo extension supporting XvImages
 246         if test "$ac_cv_header_X11_extensions_Xvlib_h" = "yes"
 247         then
 248                 AC_CHECK_LIB(Xv, XvShmCreateImage,
 249                   [ AC_DEFINE(HAVE_XVIDEO, 1, [Define if the X libraries support XVideo])
 250                      X_PRE_LIBS="$X_PRE_LIBS -lXv"
 251                   ],,
 252                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 253         fi
 254       ]
 255     ) dnl *** End of X11/Xlib.h check
 256
 257     dnl Check for the presence of OpenGL
 258     if test "x$with_opengl" != "xno"
 259     then
 260         if test -f /usr/X11R6/lib/libGL.a -a ! -f /usr/X11R6/lib/libGL.so
 261         then
 262             AC_MSG_ERROR([/usr/X11R6/lib/libGL.a is present on your system.
 263 This prevents linking to OpenGL. Delete the file and restart configure.])
 264         fi
 265
 266         AC_CHECK_HEADERS(GL/gl.h GL/glx.h)
 267         if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
 268         then
 269             AC_CHECK_HEADERS(GL/glext.h,,,[#include <GL/glx.h>])
 270             dnl Check for some problems due to old Mesa versions
 271             AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_version_OK,
 272               AC_TRY_COMPILE(
 273                 [#include <GL/gl.h>],
 274                 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
 275                 [wine_cv_opengl_version_OK="yes"],
 276                 [wine_cv_opengl_version_OK="no"]
 277               )
 278             )
 279
 280             if test "$wine_cv_opengl_version_OK" = "yes"
 281             then
 282                 dnl Check for the presence of the library
 283                 AC_CHECK_LIB(GL,glXCreateContext,
 284                              OPENGL_LIBS="-lGL"
 285                              ,,
 286                              $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 287
 288                 if test "$ac_cv_lib_GL_glXCreateContext" = "yes"
 289                 then
 290                         OPENGLFILES='$(OPENGLFILES)'
 291                         AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])
 292
 293                         AC_CHECK_LIB(GL,glXGetProcAddressARB,
 294                                      AC_DEFINE(HAVE_GLX_GETPROCADDRESS, 1,
 295                                                [Define if the OpenGL library supports the glXGetProcAddressARB call]),,
 296                                      $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 297
 298                         if test "$ac_cv_lib_GL_glXGetProcAddressARB" = "yes"
 299                         then
 300                                AC_CACHE_CHECK([for OpenGL extension functions prototypes], wine_cv_extension_prototypes,
 301                                   [AC_TRY_COMPILE([#include <GL/gl.h>
 302                                                   #ifdef HAVE_GL_GLEXT_H
 303                                                   # include <GL/glext.h>
 304                                                   #endif
 305                                                   ],
 306                                                  [PFNGLCOLORTABLEEXTPROC test_proc;],
 307                                                  [wine_cv_extension_prototypes="yes"],
 308                                                  [wine_cv_extension_prototypes="no"]
 309                                   )]
 310                                 )
 311                                 if test "$wine_cv_extension_prototypes" = "yes"
 312                                 then
 313                                     AC_DEFINE(HAVE_GLEXT_PROTOTYPES, 1,
 314                                               [Define if the OpenGL headers define extension typedefs])
 315                                 fi
 316                         fi
 317
 318                 fi
 319                 dnl Check for GLU32 library.
 320                 AC_CHECK_LIB(GLU,gluLookAt,
 321                              [OPENGL_LIBS="$OPENGL_LIBS -lGLU"
 322                              GLU32FILES='$(GLU32FILES)']
 323                              ,,
 324                              $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
 325                 )
 326              fi
 327
 328              dnl Check for glut32 library.
 329              AC_CHECK_LIB(glut,glutMainLoop,
 330                        [AC_SUBST(GLUT_LIBS,"-lglut -lXmu -lXi")
 331                         AC_SUBST(GLUT32FILES,'$(GLUT32FILES)')],,
 332                         $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXmu -lXi -lX11 $X_EXTRA_LIBS)
 333          fi
 334     fi
 335
 336     dnl **** Check for NAS ****
 337     AC_SUBST(NASLIBS,"")
 338     AC_CHECK_HEADERS(audio/audiolib.h,
 339          [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
 340           AC_CHECK_LIB(audio,AuCreateFlow,
 341                        [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
 342                         NASLIBS="-laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],,
 343                        [-lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
 344
 345     CPPFLAGS="$ac_save_CPPFLAGS"
 346     XFILES='$(XFILES)'
 347 else
 348     XLIB=""
 349     X_CFLAGS=""
 350     X_LIBS=""
 351 fi
 352
 353 dnl **** Check which curses lib to use ***
 354 CURSESLIBS=""
 355 if test "x$with_curses" != "xno"
 356 then
 357     AC_CHECK_HEADERS(ncurses.h,
 358         [AC_CHECK_LIB(ncurses,waddch,
 359             [AC_DEFINE(HAVE_LIBNCURSES, 1, [Define if you have the ncurses library (-lncurses)])
 360              CURSESLIBS="-lncurses"],
 361              [AC_CHECK_HEADERS(curses.h,
 362                  [AC_CHECK_LIB(curses,waddch,
 363                      [AC_DEFINE(HAVE_LIBCURSES, 1, [Define if you have the curses library (-lcurses)])
 364                       CURSESLIBS="-lcurses"])])])])
 365     saved_libs="$LIBS"
 366     LIBS="$CURSESLIBS $LIBS"
 367     AC_CHECK_FUNCS(getbkgd resizeterm)
 368     LIBS="$saved_libs"
 369 fi
 370 AC_SUBST(CURSESLIBS)
 371
 372 dnl **** Check for SANE ****
 373 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
 374 if test "$sane_devel" = "no"
 375 then
 376     SANELIBS=""
 377     SANEINCL=""
 378 else
 379     SANELIBS="`$sane_devel --libs`"
 380     SANEINCL="`$sane_devel --cflags`"
 381     ac_save_CPPFLAGS="$CPPFLAGS"
 382     ac_save_LIBS="$LIBS"
 383     CPPFLAGS="$CPPFLAGS $SANEINCL"
 384     LIBS="$LIBS $SANELIBS"
 385     AC_CHECK_HEADER(sane/sane.h,
 386                     [AC_CHECK_LIB(sane,sane_open,
 387                                   [AC_DEFINE(HAVE_SANE, 1, [Define if we have SANE development environment])],
 388                                   [SANELIBS=""
 389                                   SANEINCL=""])],
 390                     [SANELIBS=""
 391                     SANEINCL=""])
 392     LIBS="$ac_save_LIBS"
 393     CPPFLAGS="$ac_save_CPPFLAGS"
 394 fi
 395 AC_SUBST(SANELIBS)
 396 AC_SUBST(SANEINCL)
 397
 398 dnl **** Check for the ICU library ****
 399 AC_CHECK_HEADERS(unicode/ubidi.h)
 400 if test "$ac_cv_header_unicode_ubidi_h" = "yes"
 401 then
 402     saved_libs="$LIBS"
 403     ICU_LIB_DIR="${ICU_LIB_DIR-/usr/lib}"
 404     ICUUC_LIB="${ICUUC_LIB-$ICU_LIB_DIR/libsicuuc.a}"
 405     ICUDATA_LIB="${ICUDATA_LIB-$ICU_LIB_DIR/libsicudata.a}"
 406     AC_MSG_CHECKING(whether can link with ICU libraries $ICUUC_LIB and $ICUDATA_LIB)
 407     LIBS="$LIBS $ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s"
 408     AC_TRY_LINK([#include <unicode/ubidi.h>],[ubidi_open()],
 409                 [AC_DEFINE(HAVE_ICU,1,[Define to 1 if the ICU libraries are installed])
 410                  AC_SUBST(ICULIBS,"$ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s")
 411                  AC_MSG_RESULT(yes)],
 412                 [AC_MSG_RESULT(no)])
 413     LIBS="$saved_libs"
 414 fi
 415
 416 dnl **** Check for FreeType 2 ****
 417 AC_CHECK_LIB(freetype,FT_Init_FreeType,ft_lib=yes,ft_lib=no,$X_LIBS)
 418 if test "$ft_lib" = "no"
 419 then
 420     FREETYPEINCL=""
 421     wine_cv_msg_freetype=no
 422 else
 423     AC_CHECK_PROG(ft_devel,freetype-config,freetype-config,no)
 424     if test "$ft_devel" = "no"
 425     then
 426         AC_CHECK_PROG(ft_devel2,freetype2-config,freetype2-config,no)
 427         if test "$ft_devel2" = "freetype2-config"
 428         then
 429                 ft_devel=$ft_devel2
 430         fi
 431     fi
 432     if test "$ft_devel" = "no"
 433     then
 434         FREETYPEINCL=""
 435         wine_cv_msg_freetype=yes
 436     else
 437         FREETYPEINCL=`$ft_devel --cflags`
 438         ac_save_CPPFLAGS="$CPPFLAGS"
 439         CPPFLAGS="$FREETYPEINCL $CPPFLAGS"
 440         AC_CHECK_HEADERS(ft2build.h \
 441                          freetype/freetype.h \
 442                          freetype/ftglyph.h \
 443                          freetype/tttables.h \
 444                          freetype/ftnames.h \
 445                          freetype/ftsnames.h \
 446                          freetype/ttnameid.h \
 447                          freetype/ftoutln.h \
 448                          freetype/ftwinfnt.h \
 449                          freetype/internal/sfnt.h,,,
 450                          [#if HAVE_FT2BUILD_H
 451                           #include <ft2build.h>
 452                           #endif])
 453         AC_TRY_CPP([#include <ft2build.h>
 454                     #include <freetype/fttrigon.h>],
 455                     [AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
 456           [Define if you have the <freetype/fttrigon.h> header file.])
 457                     wine_cv_fttrigon=yes],
 458                     wine_cv_fttrigon=no)
 459         CPPFLAGS="$ac_save_CPPFLAGS"
 460         dnl Check that we have at least freetype/freetype.h
 461         if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
 462         then
 463             AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
 464             wine_cv_msg_freetype=no
 465         else
 466             FREETYPEINCL=""
 467             wine_cv_msg_freetype=yes
 468         fi
 469     fi
 470 fi
 471 AC_SUBST(FREETYPEINCL)
 472
 473 dnl **** Check for parport (currently Linux only) ****
 474 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
 475  AC_TRY_COMPILE(
 476    [#include <linux/ppdev.h>],
 477    [ioctl (1,PPCLAIM,0)],
 478    [ac_cv_c_ppdev="yes"],
 479    [ac_cv_c_ppdev="no"])
 480  )
 481 if test "$ac_cv_c_ppdev" = "yes"
 482 then
 483     AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
 484 fi
 485
 486 dnl **** Check for va_copy ****
 487 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
 488  AC_TRY_LINK(
 489    [#include <stdarg.h>],
 490    [va_list ap1, ap2;
 491     va_copy(ap1,ap2);
 492    ],
 493    [ac_cv_c_va_copy="yes"],
 494    [ac_cv_c_va_copy="no"])
 495  )
 496 if test "$ac_cv_c_va_copy" = "yes"
 497 then
 498     AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
 499 fi
 500 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
 501  AC_TRY_LINK(
 502    [#include <stdarg.h>],
 503    [va_list ap1, ap2;
 504     __va_copy(ap1,ap2);
 505    ],
 506    [ac_cv_c___va_copy="yes"],
 507    [ac_cv_c___va_copy="no"])
 508  )
 509 if test "$ac_cv_c___va_copy" = "yes"
 510 then
 511     AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
 512 fi
 513
 514 dnl **** Check for sigsetjmp ****
 515 AC_CACHE_CHECK([for sigsetjmp], ac_cv_c_sigsetjmp,
 516  AC_TRY_LINK(
 517    [#include <setjmp.h>],
 518    [sigjmp_buf buf;
 519     sigsetjmp( buf, 1 );
 520     siglongjmp( buf, 1 );],
 521    [ac_cv_c_sigsetjmp="yes"],
 522    [ac_cv_c_sigsetjmp="no"])
 523  )
 524 if test "$ac_cv_c_sigsetjmp" = "yes"
 525 then
 526     AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have the sigsetjmp (and siglongjmp) function])
 527 fi
 528
 529 dnl **** Check for pthread_rwlock_t ****
 530 AC_CHECK_TYPES([pthread_rwlock_t, pthread_rwlockattr_t],,,[#define _GNU_SOURCE
 531 #include <pthread.h>])
 532
 533 dnl **** Check for pthread functions ****
 534 ac_save_LIBS="$LIBS"
 535 LIBS="$LIBS $LIBPTHREAD"
 536 AC_CHECK_FUNCS(\
 537         pthread_getattr_np \
 538         pthread_get_stackaddr_np \
 539         pthread_get_stacksize_np \
 540 )
 541 LIBS="$ac_save_LIBS"
 542
 543 dnl **** Check for Open Sound System ****
 544 AC_CHECK_HEADERS(sys/soundcard.h machine/soundcard.h soundcard.h, break)
 545
 546 AC_CACHE_CHECK([for Open Sound System],
 547         ac_cv_c_opensoundsystem,
 548         AC_TRY_COMPILE([
 549         #if defined(HAVE_SYS_SOUNDCARD_H)
 550                 #include <sys/soundcard.h>
 551         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 552                 #include <machine/soundcard.h>
 553         #elif defined(HAVE_SOUNDCARD_H)
 554                 #include <soundcard.h>
 555         #endif
 556         ],[
 557
 558 /* check for one of the Open Sound System specific SNDCTL_ defines */
 559 #if !defined(SNDCTL_DSP_STEREO)
 560 #error No open sound system
 561 #endif
 562 ],ac_cv_c_opensoundsystem="yes",ac_cv_c_opensoundsystem="no"))
 563
 564 if test "$ac_cv_c_opensoundsystem" = "yes"
 565 then
 566     AC_DEFINE(HAVE_OSS, 1, [Define if you have the Open Sound system])
 567 fi
 568
 569 AC_CACHE_CHECK([for Open Sound System/MIDI interface],
 570         ac_cv_c_opensoundsystem_midi,
 571         AC_TRY_COMPILE([
 572         #if defined(HAVE_SYS_SOUNDCARD_H)
 573                 #include <sys/soundcard.h>
 574         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 575                 #include <machine/soundcard.h>
 576         #elif defined(HAVE_SOUNDCARD_H)
 577                 #include <soundcard.h>
 578         #endif
 579         ],[
 580
 581 /* check for one of the Open Sound System specific SNDCTL_SEQ defines */
 582 #if !defined(SNDCTL_SEQ_SYNC)
 583 #error No open sound system MIDI interface
 584 #endif
 585 ],ac_cv_c_opensoundsystem_midi="yes",ac_cv_c_opensoundsystem_midi="no"))
 586
 587 if test "$ac_cv_c_opensoundsystem_midi" = "yes"
 588 then
 589     AC_DEFINE(HAVE_OSS_MIDI, 1, [Define if you have the Open Sound system (MIDI interface)])
 590 fi
 591
 592 dnl **** Check for aRts Sound Server ****
 593 AC_PATH_PROG(ARTSCCONFIG, artsc-config)
 594 if test x$ARTSCCONFIG != x -a x$ARTSCCONFIG != x'"$ARTSCCONFIG"';
 595 then
 596     ARTSC_CFLAGS=""
 597     for i in `$ARTSCCONFIG --cflags`
 598     do
 599       case "$i" in
 600         -I*) ARTSC_CFLAGS="$ARTSC_CFLAGS $i";;
 601       esac
 602     done
 603     ARTSC_LIBS=`$ARTSCCONFIG --libs`
 604     save_CFLAGS="$CFLAGS"
 605     CFLAGS="$CFLAGS $ARTSC_CFLAGS"
 606     AC_TRY_COMPILE([#include <artsc.h>],[arts_stream_t stream;],
 607         [AC_SUBST(ARTSLIBS, $ARTSC_LIBS)
 608          AC_SUBST(ARTSINCL, $ARTSC_CFLAGS)
 609          AC_DEFINE(HAVE_ARTS, 1, [Define if you have ARTS sound server])])
 610     CFLAGS="$save_CFLAGS"
 611 fi
 612
 613 dnl **** Check for ALSA ****
 614 AC_SUBST(ALSALIBS,"")
 615 AC_CHECK_HEADERS(alsa/asoundlib.h sys/asoundlib.h, break)
 616 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
 617 then
 618     AC_CHECK_LIB(asound,snd_pcm_open,
 619         AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA including devel headers])
 620         ALSALIBS="-lasound")
 621 fi
 622
 623 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
 624
 625 AC_SUBST(AUDIOIOLIBS,"")
 626 AC_CHECK_HEADERS(libaudioio.h,
 627     [AC_CHECK_LIB(audioio,AudioIOGetVersion,
 628                   [AUDIOIOLIBS="-laudioio"
 629                    AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])])
 630
 631 dnl **** Check for capi4linux ****
 632
 633 AC_CHECK_HEADERS(capi20.h,[
 634         AC_CHECK_HEADERS(linux/capi.h,[
 635                 AC_CHECK_LIB(capi20,capi20_register,[
 636                         AC_DEFINE(HAVE_CAPI4LINUX,1,[Define if you have capi4linux libs and headers])
 637                         AC_SUBST(CAPI4LINUXLIBS,"-lcapi20")
 638                 ])
 639         ])
 640 ])
 641
 642 dnl **** Check for broken glibc mmap64 ****
 643
 644 AC_CACHE_CHECK( [whether mmap64 works defined as mmap], ac_cv_mmap64_works,
 645         AC_TRY_RUN([
 646                 #define _FILE_OFFSET_BITS 64
 647                 #include <stdio.h>
 648                 #include <unistd.h>
 649                 #include <fcntl.h>
 650                 #include <sys/mman.h>
 651                 #include <errno.h>
 652
 653                 int main(int argc,char **argv) {
 654                         int fd = open("conftest.map",O_CREAT|O_RDWR,0600);
 655                         if (fd == -1) exit(1);
 656
 657                         unlink("conftest.map");
 658
 659                         write(fd,"test",4);
 660
 661                         if ((-1 == mmap(0,4,PROT_READ|PROT_WRITE,MAP_SHARED,fd,0)) &&
 662                             (errno == EINVAL)
 663                         ) {
 664                                 exit(1);
 665                         }
 666                         close(fd);
 667                         fprintf(stderr,"success!\n");
 668                         exit(0);
 669                 }
 670
 671         ],
 672     ac_cv_mmap64_works="yes",
 673     ac_cv_mmap64_works="no",
 674     ac_cv_mmap64_works="no") )
 675
 676 if test "$ac_cv_mmap64_works" = "yes"
 677 then
 678     AC_DEFINE(_FILE_OFFSET_BITS, 64, [Set this to 64 to enable 64-bit file support on Linux])
 679 fi
 680
 681 dnl **** Check for gcc specific options ****
 682
 683 AC_SUBST(EXTRACFLAGS,"")
 684 if test "x${GCC}" = "xyes"
 685 then
 686   EXTRACFLAGS="-Wall -pipe"
 687
 688   dnl Check for strength-reduce bug
 689   AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
 690                   AC_TRY_RUN([
 691 int     L[[4]] = {0,1,2,3};
 692 int main(void) {
 693   static int Array[[3]];
 694   unsigned int B = 3;
 695   int i;
 696   for(i=0; i<B; i++) Array[[i]] = i - 3;
 697   for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
 698   L[[i]] = 4;
 699
 700   exit( Array[[1]] != -2 || L[[2]] != 3);
 701 }],
 702     ac_cv_c_gcc_strength_bug="no",
 703     ac_cv_c_gcc_strength_bug="yes",
 704     ac_cv_c_gcc_strength_bug="yes") )
 705   if test "$ac_cv_c_gcc_strength_bug" = "yes"
 706   then
 707     EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
 708   fi
 709
 710   dnl Check for -fshort-wchar
 711   AC_CACHE_CHECK([for gcc -fshort-wchar support], ac_cv_c_gcc_fshort_wchar,
 712       [WINE_TRY_CFLAGS([-fshort-wchar],
 713                       ac_cv_c_gcc_fshort_wchar="yes",ac_cv_c_gcc_fshort_wchar="no")])
 714   if test "$ac_cv_c_gcc_fshort_wchar" = "yes"
 715   then
 716       AC_DEFINE(CC_FLAG_SHORT_WCHAR, "-fshort-wchar", [Specifies the compiler flag that forces a short wchar_t])
 717   fi
 718
 719   dnl Check for -mpreferred-stack-boundary
 720   AC_CACHE_CHECK([for gcc -mpreferred-stack-boundary=2 support], ac_cv_c_gcc_stack_boundary,
 721       [WINE_TRY_CFLAGS([-mpreferred-stack-boundary=2],
 722                       ac_cv_c_gcc_stack_boundary="yes",ac_cv_c_gcc_stack_boundary="no")])
 723   if test "$ac_cv_c_gcc_stack_boundary" = "yes"
 724   then
 725     EXTRACFLAGS="$EXTRACFLAGS -mpreferred-stack-boundary=2"
 726   fi
 727
 728   dnl Check for -fno-strict-aliasing
 729   AC_CACHE_CHECK([for gcc -fno-strict-aliasing support], ac_cv_c_gcc_no_strict_aliasing,
 730       [WINE_TRY_CFLAGS([-fno-strict-aliasing],
 731                       ac_cv_c_gcc_no_strict_aliasing="yes",ac_cv_c_gcc_no_strict_aliasing="no")])
 732   if test "$ac_cv_c_gcc_no_strict_aliasing" = "yes"
 733   then
 734     EXTRACFLAGS="$EXTRACFLAGS -fno-strict-aliasing"
 735   fi
 736
 737   dnl Check for -gstabs+ option
 738   AC_CACHE_CHECK([for gcc -gstabs+ support], ac_cv_c_gcc_gstabs,
 739       [WINE_TRY_CFLAGS([-gstabs+],ac_cv_c_gcc_gstabs="yes", ac_cv_c_gcc_gstabs="no")])
 740   if test "$ac_cv_c_gcc_gstabs" = "yes"
 741   then
 742     EXTRACFLAGS="$EXTRACFLAGS -gstabs+"
 743   fi
 744
 745   dnl Check for noisy string.h
 746   saved_CFLAGS="$CFLAGS"
 747   CFLAGS="$CFLAGS -Wpointer-arith -Werror"
 748   AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
 749       AC_TRY_COMPILE([#include <string.h>],[],
 750                      [ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
 751   CFLAGS="$saved_CFLAGS"
 752   if test "$ac_cv_c_string_h_warnings" = "no"
 753   then
 754     EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
 755   fi
 756 fi
 757
 758 dnl **** Check how to define a function in assembly code ****
 759
 760 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
 761   WINE_TRY_ASM_LINK(
 762       ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
 763       ac_cv_asm_func_def=".def",
 764     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
 765       ac_cv_asm_func_def=".type @function",
 766     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
 767       ac_cv_asm_func_def=".type 2",
 768       ac_cv_asm_func_def="unknown")])]))
 769
 770 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
 771 case "$ac_cv_asm_func_def" in
 772   ".def")
 773      AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
 774   ".type @function")
 775      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
 776   ".type 2")
 777      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
 778   *)
 779      AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
 780 esac
 781
 782 dnl **** Check for underscore on external symbols ****
 783
 784 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
 785     WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
 786                       [extern int ac_test;],
 787                       [if (ac_test) return 1],
 788                       ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
 789
 790 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
 791 if test "$ac_cv_c_extern_prefix" = "yes"
 792 then
 793   AC_DEFINE([__ASM_NAME(name)], ["_" name])
 794 else
 795   AC_DEFINE([__ASM_NAME(name)], [name])
 796 fi
 797
 798 dnl **** Check how to do strings in assembler ****
 799
 800 AC_CACHE_CHECK([for assembler keyword for ASCII strings], ac_cv_c_asm_string,
 801     WINE_TRY_ASM_LINK([".data\\n\\t.string \\"test\\"\\n\\t.text"],,,ac_cv_c_asm_string=".string",
 802       WINE_TRY_ASM_LINK([".data\\n\\t.asciz \\"test\\"\\n\\t.text"],,,ac_cv_c_asm_string=".asciz",
 803         WINE_TRY_ASM_LINK([".data\\n\\t.ascii \\"test\\"\\n\\t.text"],,,ac_cv_c_asm_string=".ascii",
 804           AC_MSG_ERROR([could not discover how to produce C strings with assembler.])))))
 805
 806 AC_DEFINE_UNQUOTED(__ASM_STRING, ["$ac_cv_c_asm_string"],
 807                    [Define to the assembler keyword used to specify an ASCII string])
 808
 809 dnl **** Check for .short in assembler ****
 810
 811 AC_CACHE_CHECK([for assembler keyword for word values], ac_cv_c_asm_short,
 812     WINE_TRY_ASM_LINK([".data\\n\\t.short 1\\n\\t.text"],,,ac_cv_c_asm_short=".short",
 813       WINE_TRY_ASM_LINK([".data\\n\\t.half 1\\n\\t.text"],,,ac_cv_c_asm_short=".half",
 814         AC_MSG_ERROR([could not discover how to specify word values with assembler.]))))
 815
 816 AC_DEFINE_UNQUOTED(__ASM_SHORT, ["$ac_cv_c_asm_short"],
 817                    [Define to the assembler keyword used to specify a word value])
 818
 819 dnl **** Check for .size in assembler ****
 820
 821 AC_CACHE_CHECK([for .size in assembler], ac_cv_c_asm_size,
 822     WINE_TRY_ASM_LINK([".globl _ac_test\n.size _ac_test, . - _ac_test"],,,
 823                       ac_cv_c_asm_size="yes",ac_cv_c_asm_size="no"))
 824
 825 if test "$ac_cv_c_asm_size" = "yes"
 826 then
 827   AC_DEFINE(HAVE_ASM_DOT_SIZE, 1, [Define if the assembler keyword .size is accepted])
 828 fi
 829
 830 dnl **** Check for working dll ****
 831
 832 AC_SUBST(DLLEXT,"")
 833 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
 834 AC_SUBST(DLLIBS,"")
 835 AC_SUBST(LDSHARED,"")
 836 AC_SUBST(LDDLLFLAGS,"")
 837 AC_SUBST(LIBEXT,"so")
 838 AC_SUBST(IMPLIBEXT,"def")
 839
 840 case $host_os in
 841   cygwin*|mingw32*)
 842     AC_CHECK_TOOL(DLLTOOL,dlltool,false)
 843     AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
 844     if test "$DLLWRAP" = "false"; then
 845       LIBEXT="a"
 846     else
 847       dnl FIXME - check whether dllwrap works correctly...
 848       LIBEXT="dll"
 849     fi
 850     IMPLIBEXT="a"
 851     ;;
 852   *)
 853     AC_CHECK_HEADERS(dlfcn.h,
 854         [AC_CHECK_FUNCS(dlopen,,
 855             [AC_CHECK_LIB(dl,dlopen,
 856                          [AC_DEFINE(HAVE_DLOPEN,1,[Define if you have dlopen])
 857                           DLLIBS="-ldl"],
 858                          [LIBEXT="a"])])],
 859         [LIBEXT="a"])
 860
 861     if test "$LIBEXT" = "so"
 862     then
 863       DLLFLAGS="$DLLFLAGS -fPIC"
 864       DLLEXT=".so"
 865       AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
 866           [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-soname,conftest.so.1.0,-Bsymbolic],
 867                            ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
 868       if test "$ac_cv_c_dll_gnuelf" = "yes"
 869       then
 870         LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"
 871         LDDLLFLAGS="-shared -Wl,-Bsymbolic"
 872         AC_CACHE_CHECK([whether the linker accepts -z defs], ac_cv_c_dll_zdefs,
 873           [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs],
 874                            ac_cv_c_dll_zdefs="yes",ac_cv_c_dll_zdefs="no")])
 875         if test "$ac_cv_c_dll_zdefs" = "yes"
 876         then
 877           LDDLLFLAGS="$LDDLLFLAGS,-z,defs"
 878         fi
 879
 880         AC_CACHE_CHECK([whether the linker accepts -init and -fini], ac_cv_c_dll_init_fini,
 881           [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-init,__wine_spec_init,-fini,__wine_spec_fini],
 882                            ac_cv_c_dll_init_fini="yes",ac_cv_c_dll_init_fini="no")])
 883         if test "$ac_cv_c_dll_init_fini" = "yes"
 884         then
 885           LDDLLFLAGS="$LDDLLFLAGS,-init,__wine_spec_init,-fini,__wine_spec_fini"
 886         fi
 887
 888         AC_CACHE_CHECK([whether the linker accepts version scripts], ac_cv_c_ld_version_scripts,
 889           [echo '{ global: *; };' >conftest.map
 890            WINE_TRY_CFLAGS([-fPIC -shared -Wl,--version-script=conftest.map],
 891                            ac_cv_c_ld_version_scripts="yes",ac_cv_c_ld_version_scripts="no")
 892            rm -f conftest.map])
 893         if test "$ac_cv_c_ld_version_scripts" = "yes"
 894         then
 895           LDSHARED="$LDSHARED \$(VERSCRIPT:%=-Wl,--version-script=%)"
 896         fi
 897
 898         AC_CACHE_CHECK([whether the linker accepts --export-dynamic], ac_cv_c_export_dynamic,
 899           [WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
 900                            ac_cv_c_export_dynamic="yes",ac_cv_c_export_dynamic="no")])
 901         if test "$ac_cv_c_export_dynamic" = "yes"
 902         then
 903           AC_SUBST(LDEXECFLAGS,["-Wl,--export-dynamic"])
 904         fi
 905
 906         case $host_cpu in
 907           *i[[3456789]]86*)
 908             AC_CACHE_CHECK([whether we can relocate the executable to 0x77f00000], ac_cv_ld_reloc_exec,
 909               [WINE_TRY_CFLAGS([-Wl,--section-start,.interp=0x77f00400],
 910                                ac_cv_ld_reloc_exec="yes", ac_cv_ld_reloc_exec="no")])
 911             if test "$ac_cv_ld_reloc_exec" = "yes"
 912             then
 913               LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x77f00400"
 914             fi
 915             ;;
 916         esac
 917
 918       else
 919         AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
 920             [WINE_TRY_CFLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
 921                              ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
 922         if test "$ac_cv_c_dll_unixware" = "yes"
 923         then
 924           LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
 925           LDDLLFLAGS="-Wl,-G,-B,symbolic"
 926
 927         else
 928           AC_CACHE_CHECK(whether we can build a Mach-O (Mac OS X/Darwin) dll, ac_cv_c_dll_macho,
 929             [WINE_TRY_CFLAGS([-bundle], ac_cv_c_dll_macho="yes", ac_cv_c_dll_macho="no")])
 930           if test "$ac_cv_c_dll_macho" = "yes"
 931           then
 932             LIBEXT="dylib"
 933             LDDLLFLAGS="-bundle -flat_namespace -undefined suppress"
 934             LDSHARED="\$(CC) -dynamiclib"
 935             CFLAGS="$CFLAGS -ffixed-r13 -no-cpp-precomp"
 936             STRIP="$STRIP -u -r"
 937             dnl Relocate wine executable
 938             AC_SUBST(LDEXECFLAGS,"-seg1addr 0x120000")
 939             dnl Relocate libwine.dyld too
 940             AC_SUBST(LDLIBWINEFLAGS,"-seg1addr 0x140000")
 941           fi
 942         fi
 943       fi
 944     fi
 945
 946     dnl Check for cross compiler to build test programs
 947     AC_SUBST(CROSSTEST,"")
 948     if test "$cross_compiling" = "no"
 949     then
 950       AC_CHECK_PROGS(CROSSCC,i586-mingw32msvc-gcc i386-mingw32msvc-gcc i386-mingw32-gcc mingw-gcc,false)
 951       AC_CHECK_PROGS(DLLTOOL,i586-mingw32msvc-dlltool i386-mingw32msvc-dlltool i386-mingw32-dlltool mingw-dlltool,false)
 952       AC_CHECK_PROGS(CROSSWINDRES,i586-mingw32msvc-windres i386-mingw32msvc-windres i386-mingw32-windres mingw-windres,false)
 953       if test "$CROSSCC" != "false"; then CROSSTEST="\$(CROSSTEST)"; fi
 954     fi
 955     ;;
 956 esac
 957
 958 if test "$LIBEXT" = "a"; then
 959   AC_MSG_ERROR(
 960 [could not find a way to build shared libraries.
 961 It is currently not possible to build Wine without shared library
 962 (.so) support to allow transparent switch between .so and .dll files.
 963 If you are using Linux, you will need a newer binutils.]
 964 )
 965 fi
 966
 967 case $build_os in
 968   cygwin*|mingw32*)
 969     AC_SUBST(LDPATH,"PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$PATH\"") ;;
 970   darwin*|macosx*)
 971     AC_SUBST(LDPATH,"DYLD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$DYLD_LIBRARY_PATH\"") ;;
 972   *)
 973     AC_SUBST(LDPATH,"LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$LD_LIBRARY_PATH\"") ;;
 974 esac
 975
 976 dnl Mingw needs explicit msvcrt for linking libwine
 977 case $host_os in
 978   mingw32*)
 979     AC_SUBST(CRTLIBS,"-lmsvcrt") ;;
 980 esac
 981
 982 case $host_os in
 983   linux*)
 984     AC_SUBST(WINE_BINARIES,"wine-glibc wine-kthread wine-pthread wine-preloader")
 985     AC_SUBST(MAIN_BINARY,"wine-glibc")
 986     ;;
 987   darwin*)
 988     AC_SUBST(WINE_BINARIES,"wine-pthread")
 989     AC_SUBST(MAIN_BINARY,"wine-pthread")
 990     ;;
 991   *)
 992     AC_SUBST(WINE_BINARIES,"wine-kthread")
 993     AC_SUBST(MAIN_BINARY,"wine-kthread")
 994     ;;
 995 esac
 996
 997 dnl **** Get the soname for libraries that we load dynamically ****
 998
 999 if test "$LIBEXT" = "so" -o "$LIBEXT" = "dylib"
1000 then
1001   WINE_GET_SONAME(X11,XCreateWindow,[$X_LIBS $X_EXTRA_LIBS])
1002   WINE_GET_SONAME(Xext,XextCreateExtension,[$X_LIBS -lX11 $X_EXTRA_LIBS])
1003   WINE_GET_SONAME(Xi,XOpenDevice,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1004   WINE_GET_SONAME(Xrender,XRenderQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1005   WINE_GET_SONAME(Xrandr,XRRQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1006   WINE_GET_SONAME(freetype,FT_Init_FreeType,[$X_LIBS])
1007   WINE_GET_SONAME(GL,glXQueryExtension,[$X_LIBS $X_EXTRA_LIBS])
1008   WINE_GET_SONAME(txc_dxtn,fetch_2d_texel_rgba_dxt1)
1009   WINE_GET_SONAME(cups,cupsGetDefault)
1010   WINE_GET_SONAME(jack,jack_client_new)
1011   WINE_GET_SONAME(fontconfig,FcInit)
1012   WINE_GET_SONAME(ssl,SSL_library_init)
1013   WINE_GET_SONAME(crypto,BIO_new_socket)
1014   WINE_GET_SONAME(ncurses,waddch)
1015   WINE_GET_SONAME(curses,waddch)
1016   WINE_GET_SONAME(jpeg,jpeg_start_decompress)
1017   WINE_GET_SONAME(ungif,DGifOpen)
1018 fi
1019
1020
1021 dnl **** Check for functions ****
1022
1023 AC_FUNC_ALLOCA()
1024 AC_CHECK_FUNCS(\
1025         _lwp_create \
1026         _lwp_self \
1027         _pclose \
1028         _popen \
1029         _snprintf \
1030         _spawnvp \
1031         _stricmp \
1032         _strnicmp \
1033         _vsnprintf \
1034         chsize \
1035         clone \
1036         finite \
1037         fpclass \
1038         fstatfs \
1039         fstatvfs \
1040         ftruncate \
1041         ftruncate64 \
1042         futimes \
1043         getnetbyaddr \
1044         getnetbyname \
1045         getopt_long \
1046         getpagesize \
1047         getprotobyname \
1048         getprotobynumber \
1049         getpwuid \
1050         getservbyport \
1051         gettid \
1052         gettimeofday \
1053         inet_network \
1054         lseek64 \
1055         lstat \
1056         memmove \
1057         mmap \
1058         pclose \
1059         popen \
1060         pread \
1061         pwrite \
1062         readlink \
1063         rfork \
1064         select \
1065         sendmsg \
1066         settimeofday \
1067         sigaltstack \
1068         snprintf \
1069         spawnvp \
1070         statfs \
1071         statvfs \
1072         strcasecmp \
1073         strerror \
1074         strncasecmp \
1075         tcgetattr \
1076         timegm \
1077         usleep \
1078         vfscanf \
1079         vsnprintf \
1080         wait4 \
1081         waitpid \
1082 )
1083
1084 dnl **** Check for header files ****
1085
1086 AC_CHECK_HEADERS(\
1087         arpa/inet.h \
1088         arpa/nameser.h \
1089         cups/cups.h \
1090         direct.h \
1091         elf.h \
1092         float.h \
1093         fontconfig/fontconfig.h \
1094         getopt.h \
1095         gif_lib.h \
1096         ieeefp.h \
1097         io.h \
1098         jack/jack.h \
1099         jpeglib.h \
1100         libio.h \
1101         libutil.h \
1102         link.h \
1103         linux/cdrom.h \
1104         linux/hdreg.h \
1105         linux/input.h \
1106         linux/ioctl.h \
1107         linux/joystick.h \
1108         linux/major.h \
1109         linux/param.h \
1110         linux/serial.h \
1111         linux/ucdrom.h \
1112         machine/cpu.h \
1113         mntent.h \
1114         netdb.h \
1115         netinet/in.h \
1116         netinet/in_systm.h \
1117         netinet/tcp.h \
1118         netinet/tcp_fsm.h \
1119         openssl/ssl.h \
1120         process.h \
1121         pthread.h \
1122         pty.h \
1123         pwd.h \
1124         regex.h \
1125         sched.h \
1126         scsi/sg.h \
1127         scsi/scsi.h \
1128         scsi/scsi_ioctl.h \
1129         socket.h \
1130         stdint.h \
1131         strings.h \
1132         sys/cdio.h \
1133         sys/elf32.h \
1134         sys/errno.h \
1135         sys/exec_elf.h \
1136         sys/file.h \
1137         sys/filio.h \
1138         sys/inttypes.h \
1139         sys/ioctl.h \
1140         sys/ipc.h \
1141         sys/link.h \
1142         sys/lwp.h \
1143         sys/mman.h \
1144         sys/modem.h \
1145         sys/msg.h \
1146         sys/param.h \
1147         sys/poll.h \
1148         sys/ptrace.h \
1149         sys/reg.h \
1150         sys/scsiio.h \
1151         sys/shm.h \
1152         sys/signal.h \
1153         sys/socket.h \
1154         sys/sockio.h \
1155         sys/statfs.h \
1156         sys/statvfs.h \
1157         sys/strtio.h \
1158         sys/syscall.h \
1159         sys/sysctl.h \
1160         sys/time.h \
1161         sys/times.h \
1162         sys/uio.h \
1163         sys/un.h \
1164         sys/v86.h \
1165         sys/v86intr.h \
1166         sys/vfs.h \
1167         sys/vm86.h \
1168         sys/wait.h \
1169         syscall.h \
1170         termios.h \
1171         unistd.h \
1172         utime.h \
1173         valgrind/memcheck.h
1174 )
1175 AC_HEADER_STAT()
1176
1177 dnl **** Checks for headers that depend on other ones ****
1178
1179 AC_CHECK_HEADERS(sys/mount.h sys/user.h,,,
1180     [#include <sys/types.h>
1181      #if HAVE_SYS_PARAM_H
1182      # include <sys/param.h>
1183      #endif])
1184
1185 AC_CHECK_HEADERS([net/if.h net/if_arp.h net/if_dl.h net/if_types.h net/route.h],,,
1186     [#include <sys/types.h>
1187      #if HAVE_SYS_SOCKET_H
1188      # include <sys/socket.h>
1189      #endif])
1190
1191 AC_CHECK_HEADERS([resolv.h],,,
1192     [#include <sys/types.h>
1193      #if HAVE_SYS_SOCKET_H
1194      # include <sys/socket.h>
1195      #endif
1196      #if HAVE_NETINET_IN_H
1197      # include <netinet/in.h>
1198      #endif
1199      #if HAVE_ARPA_NAMESER_H
1200      # include <arpa/nameser.h>
1201      #endif])
1202
1203 AC_CHECK_HEADERS(netinet/ip.h,,,
1204     [#include <sys/types.h>
1205      #if HAVE_SYS_SOCKET_H
1206      # include <sys/socket.h>
1207      #endif
1208      #if HAVE_NETINET_IN_SYSTM_H
1209      # include <netinet/in_systm.h>
1210      #endif])
1211
1212 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
1213
1214 dnl **** Check for IPX headers (currently Linux only) ****
1215
1216 AC_CACHE_CHECK([for GNU style IPX support], ac_cv_c_ipx_gnu,
1217  AC_TRY_COMPILE(
1218    [#include <sys/types.h>
1219     #ifdef HAVE_SYS_SOCKET_H
1220     # include <sys/socket.h>
1221     #endif
1222     #include <netipx/ipx.h>],
1223    [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
1224    [ac_cv_c_ipx_gnu="yes"],
1225    [ac_cv_c_ipx_gnu="no"])
1226  )
1227 if test "$ac_cv_c_ipx_gnu" = "yes"
1228 then
1229     AC_DEFINE(HAVE_IPX_GNU, 1, [Define if IPX should use netipx/ipx.h from libc])
1230 fi
1231
1232 if test "$ac_cv_c_ipx_gnu" = "no"
1233 then
1234  AC_CACHE_CHECK([for linux style IPX support], ac_cv_c_ipx_linux,
1235   AC_TRY_COMPILE(
1236     [#include <sys/types.h>
1237      #ifdef HAVE_SYS_SOCKET_H
1238      # include <sys/socket.h>
1239      #endif
1240      #include <asm/types.h>
1241      #include <linux/ipx.h>],
1242     [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
1243     [ac_cv_c_ipx_linux="yes"],
1244     [ac_cv_c_ipx_linux="no"])
1245   )
1246   if test "$ac_cv_c_ipx_linux" = "yes"
1247   then
1248       AC_DEFINE(HAVE_IPX_LINUX, 1, [Define if IPX includes are taken from Linux kernel])
1249   fi
1250 fi
1251
1252 dnl **** Check for types ****
1253
1254 AC_C_CONST
1255 AC_C_INLINE
1256 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t, long long, fsblkcnt_t, fsfilcnt_t])
1257
1258 AC_CACHE_CHECK([whether linux/input.h is for real],
1259         wine_cv_linux_input_h,
1260         AC_TRY_COMPILE([
1261             #include <linux/input.h>
1262         ] , [
1263             int foo = EVIOCGBIT(EV_ABS,42);
1264             int bar = BTN_PINKIE;
1265             int fortytwo = 42;
1266         ],
1267         wine_cv_linux_input_h=yes,
1268         wine_cv_linux_input_h=no,
1269         no
1270         )
1271     )
1272     if test "$wine_cv_linux_input_h" = "yes"
1273     then
1274         AC_DEFINE(HAVE_CORRECT_LINUXINPUT_H, 1,
1275                   [Define if we have linux/input.h AND it contains the INPUT event API])
1276     fi
1277
1278
1279 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1280         wine_cv_linux_gethostbyname_r_6,
1281         AC_TRY_LINK([
1282 #include <netdb.h>
1283         ], [
1284     char *name=NULL;
1285     struct hostent he;
1286     struct hostent *result;
1287     char *buf=NULL;
1288     int bufsize=0;
1289     int res,errnr;
1290     char *addr=NULL;
1291     int addrlen=0;
1292     int addrtype=0;
1293     res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1294     res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1295     ],
1296         wine_cv_linux_gethostbyname_r_6=yes,
1297         wine_cv_linux_gethostbyname_r_6=no
1298         )
1299    )
1300    if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1301    then
1302       AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1303                 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1304    fi
1305
1306 if test "$ac_cv_header_linux_joystick_h" = "yes"
1307 then
1308    AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1309         wine_cv_linux_joystick_22_api,
1310         AC_TRY_COMPILE([
1311         #include <sys/ioctl.h>
1312         #include <linux/joystick.h>
1313
1314         struct js_event blub;
1315         #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1316         #error "no 2.2 header"
1317         #endif
1318         ],/*empty*/,
1319         wine_cv_linux_joystick_22_api=yes,
1320         wine_cv_linux_joystick_22_api=no,
1321         wine_cv_linux_joystick_22_api=no
1322         )
1323    )
1324    if test "$wine_cv_linux_joystick_22_api" = "yes"
1325    then
1326       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1327                 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1328    fi
1329 fi
1330
1331 dnl **** statfs checks ****
1332
1333 if test "$ac_cv_header_sys_vfs_h" = "yes"
1334 then
1335     AC_CACHE_CHECK( [whether sys/vfs.h defines statfs],
1336                     wine_cv_sys_vfs_has_statfs,
1337         AC_TRY_COMPILE([
1338         #include <sys/types.h>
1339         #ifdef HAVE_SYS_PARAM_H
1340         # include <sys/param.h>
1341         #endif
1342         #include <sys/vfs.h>
1343         ],[
1344                 struct statfs stfs;
1345
1346                 memset(&stfs,0,sizeof(stfs));
1347         ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
1348         )
1349     )
1350     if test "$wine_cv_sys_vfs_has_statfs" = "yes"
1351     then
1352       AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS, 1,
1353                 [Define if the struct statfs is defined by <sys/vfs.h>])
1354     fi
1355 fi
1356
1357 if test "$ac_cv_header_sys_statfs_h" = "yes"
1358 then
1359     AC_CACHE_CHECK( [whether sys/statfs.h defines statfs],
1360                     wine_cv_sys_statfs_has_statfs,
1361         AC_TRY_COMPILE([
1362         #include <sys/types.h>
1363         #ifdef HAVE_SYS_PARAM_H
1364         # include <sys/param.h>
1365         #endif
1366         #include <sys/statfs.h>
1367         ],[
1368                 struct statfs stfs;
1369         ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
1370         )
1371     )
1372     if test "$wine_cv_sys_statfs_has_statfs" = "yes"
1373     then
1374       AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS, 1,
1375                 [Define if the struct statfs is defined by <sys/statfs.h>])
1376     fi
1377 fi
1378
1379 if test "$ac_cv_header_sys_mount_h" = "yes"
1380 then
1381     AC_CACHE_CHECK( [whether sys/mount.h defines statfs],
1382                     wine_cv_sys_mount_has_statfs,
1383         AC_TRY_COMPILE([
1384         #include <sys/types.h>
1385         #ifdef HAVE_SYS_PARAM_H
1386         # include <sys/param.h>
1387         #endif
1388         #include <sys/mount.h>
1389         ],[
1390                 struct statfs stfs;
1391         ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
1392         )
1393     )
1394     if test "$wine_cv_sys_mount_has_statfs" = "yes"
1395     then
1396       AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT, 1,
1397                 [Define if the struct statfs is defined by <sys/mount.h>])
1398     fi
1399 fi
1400
1401 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1402
1403 dnl Check for statfs members
1404 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail, struct statfs.f_frsize, struct statfs.f_ffree, struct statfs.f_favail, struct statfs.f_namelen],,,
1405 [#include <sys/types.h>
1406 #ifdef HAVE_SYS_PARAM_H
1407 # include <sys/param.h>
1408 #endif
1409 #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1410 # include <sys/mount.h>
1411 #else
1412 # ifdef STATFS_DEFINED_BY_SYS_VFS
1413 #  include <sys/vfs.h>
1414 # else
1415 #  ifdef STATFS_DEFINED_BY_SYS_STATFS
1416 #   include <sys/statfs.h>
1417 #  endif
1418 # endif
1419 #endif])
1420
1421 AC_CHECK_MEMBERS([struct statvfs.f_blocks],,,
1422 [#ifdef HAVE_SYS_STATVFS_H
1423 #include <sys/statvfs.h>
1424 #endif])
1425
1426 dnl Check for socket structure members
1427 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
1428 [#include <sys/types.h>
1429 #ifdef HAVE_SYS_SOCKET_H
1430 # include <sys/socket.h>
1431 #endif
1432 #ifdef HAVE_SYS_UN_H
1433 # include <sys/un.h>
1434 #endif])
1435
1436 dnl Check for siginfo_t members
1437 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
1438
1439 dnl Check for struct option
1440 AC_CHECK_MEMBERS([struct option.name],,,
1441 [#ifdef HAVE_GETOPT_H
1442 #include <getopt.h>
1443 #endif])
1444
1445 dnl Check for stat.st_blocks
1446 AC_CHECK_MEMBERS([struct stat.st_blocks])
1447
1448 dnl *** check for the need to define platform-specific symbols
1449
1450 case $host_cpu in
1451   *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
1452   *alpha*)          WINE_CHECK_DEFINE([__ALPHA__]) ;;
1453   *sparc*)          WINE_CHECK_DEFINE([__sparc__]) ;;
1454   *powerpc*)        WINE_CHECK_DEFINE([__powerpc__]) ;;
1455 esac
1456
1457 case $host_vendor in
1458   *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
1459 esac
1460
1461 dnl **** Generate output files ****
1462
1463 AH_TOP([#define __WINE_CONFIG_H])
1464
1465 WINE_CONFIG_EXTRA_DIR(controls)
1466 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/d3ddevice)
1467 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dclipper)
1468 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/ddraw)
1469 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/direct3d)
1470 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dpalette)
1471 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dsurface)
1472 WINE_CONFIG_EXTRA_DIR(dlls/gdi/enhmfdrv)
1473 WINE_CONFIG_EXTRA_DIR(dlls/gdi/mfdrv)
1474 WINE_CONFIG_EXTRA_DIR(dlls/kernel/messages)
1475 WINE_CONFIG_EXTRA_DIR(dlls/user/dde)
1476 WINE_CONFIG_EXTRA_DIR(dlls/user/resources)
1477 WINE_CONFIG_EXTRA_DIR(dlls/wineps/data)
1478 WINE_CONFIG_EXTRA_DIR(include/wine)
1479 WINE_CONFIG_EXTRA_DIR(misc)
1480 WINE_CONFIG_EXTRA_DIR(programs/regedit/tests)
1481 WINE_CONFIG_EXTRA_DIR(windows)
1482
1483 MAKE_RULES=Make.rules
1484 AC_SUBST_FILE(MAKE_RULES)
1485
1486 MAKE_DLL_RULES=dlls/Makedll.rules
1487 AC_SUBST_FILE(MAKE_DLL_RULES)
1488
1489 MAKE_TEST_RULES=dlls/Maketest.rules
1490 AC_SUBST_FILE(MAKE_TEST_RULES)
1491
1492 MAKE_LIB_RULES=libs/Makelib.rules
1493 AC_SUBST_FILE(MAKE_LIB_RULES)
1494
1495 MAKE_PROG_RULES=programs/Makeprog.rules
1496 AC_SUBST_FILE(MAKE_PROG_RULES)
1497
1498 AC_CONFIG_FILES([
1499 Make.rules
1500 dlls/Makedll.rules
1501 dlls/Maketest.rules
1502 libs/Makelib.rules
1503 programs/Makeprog.rules
1504 Makefile
1505 dlls/Makefile
1506 dlls/advapi32/Makefile
1507 dlls/advapi32/tests/Makefile
1508 dlls/amstream/Makefile
1509 dlls/atl/Makefile
1510 dlls/avicap32/Makefile
1511 dlls/avifil32/Makefile
1512 dlls/cabinet/Makefile
1513 dlls/capi2032/Makefile
1514 dlls/cards/Makefile
1515 dlls/cfgmgr32/Makefile
1516 dlls/comcat/Makefile
1517 dlls/comctl32/Makefile
1518 dlls/comctl32/tests/Makefile
1519 dlls/commdlg/Makefile
1520 dlls/crtdll/Makefile
1521 dlls/crypt32/Makefile
1522 dlls/ctl3d/Makefile
1523 dlls/d3d8/Makefile
1524 dlls/d3d9/Makefile
1525 dlls/d3dim/Makefile
1526 dlls/d3drm/Makefile
1527 dlls/d3dx8/Makefile
1528 dlls/d3dxof/Makefile
1529 dlls/dbghelp/Makefile
1530 dlls/dciman32/Makefile
1531 dlls/ddraw/Makefile
1532 dlls/ddraw/tests/Makefile
1533 dlls/devenum/Makefile
1534 dlls/dinput/Makefile
1535 dlls/dinput8/Makefile
1536 dlls/dmband/Makefile
1537 dlls/dmcompos/Makefile
1538 dlls/dmime/Makefile
1539 dlls/dmloader/Makefile
1540 dlls/dmscript/Makefile
1541 dlls/dmstyle/Makefile
1542 dlls/dmsynth/Makefile
1543 dlls/dmusic/Makefile
1544 dlls/dmusic32/Makefile
1545 dlls/dplay/Makefile
1546 dlls/dplayx/Makefile
1547 dlls/dpnet/Makefile
1548 dlls/dpnhpast/Makefile
1549 dlls/dsound/Makefile
1550 dlls/dsound/tests/Makefile
1551 dlls/dswave/Makefile
1552 dlls/dxdiagn/Makefile
1553 dlls/dxerr8/Makefile
1554 dlls/dxerr9/Makefile
1555 dlls/dxguid/Makefile
1556 dlls/gdi/Makefile
1557 dlls/gdi/tests/Makefile
1558 dlls/glu32/Makefile
1559 dlls/glut32/Makefile
1560 dlls/hhctrl.ocx/Makefile
1561 dlls/iccvid/Makefile
1562 dlls/icmp/Makefile
1563 dlls/ifsmgr.vxd/Makefile
1564 dlls/imagehlp/Makefile
1565 dlls/imm32/Makefile
1566 dlls/iphlpapi/Makefile
1567 dlls/iphlpapi/tests/Makefile
1568 dlls/kernel/Makefile
1569 dlls/kernel/tests/Makefile
1570 dlls/lzexpand/Makefile
1571 dlls/mapi32/Makefile
1572 dlls/mapi32/tests/Makefile
1573 dlls/mlang/Makefile
1574 dlls/mlang/tests/Makefile
1575 dlls/mmdevldr.vxd/Makefile
1576 dlls/monodebg.vxd/Makefile
1577 dlls/mpr/Makefile
1578 dlls/msacm/Makefile
1579 dlls/msacm/imaadp32/Makefile
1580 dlls/msacm/msadp32/Makefile
1581 dlls/msacm/msg711/Makefile
1582 dlls/msacm/winemp3/Makefile
1583 dlls/msacm/tests/Makefile
1584 dlls/msdmo/Makefile
1585 dlls/mshtml/Makefile
1586 dlls/msi/Makefile
1587 dlls/msimg32/Makefile
1588 dlls/msisys/Makefile
1589 dlls/msnet32/Makefile
1590 dlls/msrle32/Makefile
1591 dlls/msvcrt/Makefile
1592 dlls/msvcrt/tests/Makefile
1593 dlls/msvcrt20/Makefile
1594 dlls/msvcrt40/Makefile
1595 dlls/msvcrtd/Makefile
1596 dlls/msvcrtd/tests/Makefile
1597 dlls/msvidc32/Makefile
1598 dlls/msvideo/Makefile
1599 dlls/mswsock/Makefile
1600 dlls/netapi32/Makefile
1601 dlls/netapi32/tests/Makefile
1602 dlls/newdev/Makefile
1603 dlls/ntdll/Makefile
1604 dlls/ntdll/tests/Makefile
1605 dlls/odbc32/Makefile
1606 dlls/ole32/Makefile
1607 dlls/oleacc/Makefile
1608 dlls/oleaut32/Makefile
1609 dlls/oleaut32/tests/Makefile
1610 dlls/olecli/Makefile
1611 dlls/oledlg/Makefile
1612 dlls/olepro32/Makefile
1613 dlls/olesvr/Makefile
1614 dlls/opengl32/Makefile
1615 dlls/psapi/Makefile
1616 dlls/psapi/tests/Makefile
1617 dlls/qcap/Makefile
1618 dlls/quartz/Makefile
1619 dlls/rasapi32/Makefile
1620 dlls/richedit/Makefile
1621 dlls/rpcrt4/Makefile
1622 dlls/rpcrt4/tests/Makefile
1623 dlls/rsabase/Makefile
1624 dlls/rsabase/tests/Makefile
1625 dlls/secur32/Makefile
1626 dlls/serialui/Makefile
1627 dlls/setupapi/Makefile
1628 dlls/shdocvw/Makefile
1629 dlls/shell32/Makefile
1630 dlls/shell32/tests/Makefile
1631 dlls/shfolder/Makefile
1632 dlls/shlwapi/Makefile
1633 dlls/shlwapi/tests/Makefile
1634 dlls/snmpapi/Makefile
1635 dlls/sti/Makefile
1636 dlls/tapi32/Makefile
1637 dlls/ttydrv/Makefile
1638 dlls/twain/Makefile
1639 dlls/unicows/Makefile
1640 dlls/url/Makefile
1641 dlls/urlmon/Makefile
1642 dlls/urlmon/tests/Makefile
1643 dlls/user/Makefile
1644 dlls/user/tests/Makefile
1645 dlls/uuid/Makefile
1646 dlls/uxtheme/Makefile
1647 dlls/vdhcp.vxd/Makefile
1648 dlls/vdmdbg/Makefile
1649 dlls/version/Makefile
1650 dlls/version/tests/Makefile
1651 dlls/vmm.vxd/Makefile
1652 dlls/vnbt.vxd/Makefile
1653 dlls/vnetbios.vxd/Makefile
1654 dlls/vtdapi.vxd/Makefile
1655 dlls/vwin32.vxd/Makefile
1656 dlls/win32s/Makefile
1657 dlls/winaspi/Makefile
1658 dlls/wined3d/Makefile
1659 dlls/winedos/Makefile
1660 dlls/wineps/Makefile
1661 dlls/wininet/Makefile
1662 dlls/wininet/tests/Makefile
1663 dlls/winmm/Makefile
1664 dlls/winmm/joystick/Makefile
1665 dlls/winmm/mcianim/Makefile
1666 dlls/winmm/mciavi/Makefile
1667 dlls/winmm/mcicda/Makefile
1668 dlls/winmm/mciseq/Makefile
1669 dlls/winmm/mciwave/Makefile
1670 dlls/winmm/midimap/Makefile
1671 dlls/winmm/tests/Makefile
1672 dlls/winmm/wavemap/Makefile
1673 dlls/winmm/winealsa/Makefile
1674 dlls/winmm/winearts/Makefile
1675 dlls/winmm/wineaudioio/Makefile
1676 dlls/winmm/winejack/Makefile
1677 dlls/winmm/winenas/Makefile
1678 dlls/winmm/wineoss/Makefile
1679 dlls/winnls/Makefile
1680 dlls/winsock/Makefile
1681 dlls/winsock/tests/Makefile
1682 dlls/winspool/Makefile
1683 dlls/winspool/tests/Makefile
1684 dlls/wintab32/Makefile
1685 dlls/wintrust/Makefile
1686 dlls/wow32/Makefile
1687 dlls/wsock32/Makefile
1688 dlls/x11drv/Makefile
1689 documentation/Makefile
1690 include/Makefile
1691 libs/Makefile
1692 libs/port/Makefile
1693 libs/unicode/Makefile
1694 libs/wine/Makefile
1695 libs/wpp/Makefile
1696 loader/Makefile
1697 programs/Makefile
1698 programs/avitools/Makefile
1699 programs/clock/Makefile
1700 programs/cmdlgtst/Makefile
1701 programs/control/Makefile
1702 programs/expand/Makefile
1703 programs/msiexec/Makefile
1704 programs/notepad/Makefile
1705 programs/progman/Makefile
1706 programs/regedit/Makefile
1707 programs/regsvr32/Makefile
1708 programs/rpcss/Makefile
1709 programs/rundll32/Makefile
1710 programs/start/Makefile
1711 programs/taskmgr/Makefile
1712 programs/uninstaller/Makefile
1713 programs/view/Makefile
1714 programs/wcmd/Makefile
1715 programs/wineboot/Makefile
1716 programs/winebrowser/Makefile
1717 programs/winecfg/Makefile
1718 programs/wineconsole/Makefile
1719 programs/winedbg/Makefile
1720 programs/winefile/Makefile
1721 programs/winemenubuilder/Makefile
1722 programs/winemine/Makefile
1723 programs/winepath/Makefile
1724 programs/winetest/Makefile
1725 programs/winevdm/Makefile
1726 programs/winhelp/Makefile
1727 programs/winver/Makefile
1728 server/Makefile
1729 tools/Makefile
1730 tools/widl/Makefile
1731 tools/winapi/Makefile
1732 tools/winebuild/Makefile
1733 tools/winedump/Makefile
1734 tools/winegcc/Makefile
1735 tools/wmc/Makefile
1736 tools/wrc/Makefile])
1737
1738 AC_OUTPUT
1739
1740 if test "$have_x" = "no"
1741 then
1742   echo
1743   echo "*** Warning: X development files not found. Wine will be built without"
1744   echo "*** X support, which currently does not work, and would probably not be"
1745   echo "*** what you want anyway. You will need to install devel packages of"
1746   echo "*** Xlib/Xfree86 at the very least."
1747 fi
1748
1749 if test "$wine_cv_opengl_version_OK" = "no"
1750 then
1751   echo
1752   echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
1753   echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)."
1754 fi
1755
1756 if test "$wine_cv_msg_freetype" = "yes"
1757 then
1758   echo
1759   echo "*** Note: Your system appears to have the FreeType 2 runtime libraries"
1760   echo "*** installed, but 'freetype-config' is not in your PATH. Install the"
1761   echo "*** freetype-devel package (or its equivalent on your distribution) to"
1762   echo "*** enable Wine to use TrueType fonts."
1763 fi
1764
1765 echo
1766 echo "Configure finished.  Do 'make depend && make' to compile Wine."
1767 echo
1768
1769 dnl Local Variables:
1770 dnl comment-start: "dnl "
1771 dnl comment-end: ""
1772 dnl comment-start-skip: "\\bdnl\\b\\s *"
1773 dnl compile-command: "autoconf"
1774 dnl End: