git.oblomov.eu Git - wine/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Original author: Michael Patra
   3 dnl See ChangeLog file for detailed change history.
   4
   5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
   6
   7 AC_PREREQ(2.53)
   8 AC_INIT([Wine],WINE_VERSION,[wine-devel@winehq.org])
   9 AC_CONFIG_SRCDIR(server/atom.c)
  10 AC_CONFIG_HEADERS(include/config.h)
  11 AC_CONFIG_AUX_DIR(tools)
  12
  13 dnl **** Command-line arguments ****
  14
  15 AC_ARG_ENABLE(win16, AC_HELP_STRING([--disable-win16],[do not include Win16 support]))
  16 AC_ARG_ENABLE(debug, AC_HELP_STRING([--disable-debug],[compile out all debugging messages]))
  17 AC_ARG_ENABLE(trace, AC_HELP_STRING([--disable-trace],[compile out TRACE messages]))
  18
  19 AC_ARG_WITH(opengl,    AC_HELP_STRING([--without-opengl],[do not use OpenGL]))
  20 AC_ARG_WITH(curses,    AC_HELP_STRING([--without-curses],[do not use curses]))
  21 AC_ARG_WITH(wine-tools,AC_HELP_STRING([--with-wine-tools=<dir>],[use Wine tools from directory <dir>]))
  22
  23 AC_SUBST(WIN16_FILES,"\$(WIN16_FILES)")
  24 AC_SUBST(WIN16_INSTALL,"\$(WIN16_INSTALL)")
  25 if test "x$enable_win16" = "xno"
  26 then
  27   WIN16_FILES=""
  28   WIN16_INSTALL=""
  29 fi
  30 if test "x$enable_debug" = "xno"
  31 then
  32     AC_DEFINE(NO_DEBUG_MSGS,1,[Define to disable all debug messages.])
  33 fi
  34 if test "x$enable_trace" = "xno" -o "x$enable_debug" = "xno"
  35 then
  36     AC_DEFINE(NO_TRACE_MSGS,1,[Define to disable trace messages.])
  37 fi
  38
  39 dnl **** Check for some programs ****
  40
  41 AC_CANONICAL_HOST
  42 AC_PROG_MAKE_SET
  43 AC_PROG_CC
  44 AC_PROG_CXX
  45 dnl We can't use AC_PROG_CPP for winegcc, it uses by default $(CC) -E
  46 AC_CHECK_TOOL(CPPBIN,cpp,cpp)
  47
  48 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
  49   [if test -z "$with_wine_tools"; then
  50      if test "$cross_compiling" = "yes"; then
  51        AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
  52      else
  53        wine_cv_toolsdir="\$(TOPOBJDIR)"
  54      fi
  55    elif test -d "$with_wine_tools/tools/winebuild"; then
  56      case $with_wine_tools in
  57        /*) wine_cv_toolsdir="$with_wine_tools" ;;
  58        *)  wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
  59      esac
  60    else
  61      AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
  62    fi])
  63 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
  64
  65 AC_PATH_XTRA
  66 AC_PROG_LEX
  67
  68 dnl **** Just additional warning checks, since AC_PROG just sets 'lex' even
  69 dnl **** without one present.
  70 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
  71 if test "$XLEX" = "none"
  72 then
  73   AC_MSG_ERROR([no suitable lex found. Please install the 'flex' package.])
  74 fi
  75
  76 dnl Check for bison
  77 AC_CHECK_PROGS(BISON,bison,none)
  78 if test "$BISON" = "none"
  79 then
  80   AC_MSG_ERROR([no suitable bison found. Please install the 'bison' package.])
  81 fi
  82
  83 AC_CHECK_TOOLS(AS,[gas as],as)
  84 AC_CHECK_TOOL(LD,ld,ld)
  85 AC_CHECK_TOOL(AR,ar,ar)
  86 AC_PROG_RANLIB
  87 AC_CHECK_TOOL(STRIP,strip,strip)
  88 AC_CHECK_TOOL(WINDRES,windres,false)
  89 AC_PROG_LN_S
  90 WINE_PROG_LN
  91 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
  92 AC_PROG_INSTALL
  93 dnl Prepend src dir to install path dir if it's a relative path
  94 case "$INSTALL" in
  95   [[\\/$]]* | ?:[[\\/]]* ) ;;
  96   *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
  97 esac
  98
  99 dnl Check for lint
 100 AC_CHECK_PROGS(LINT, lclint lint)
 101 if test "$LINT" = "lint"
 102 then
 103   LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
 104   dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
 105 fi
 106 AC_SUBST(LINT)
 107 AC_SUBST(LINTFLAGS)
 108
 109 dnl Check for db2html
 110 AC_CHECK_PROGS(DB2HTML, docbook2html db2html, false)
 111 AC_SUBST(DB2HTML)
 112
 113 dnl Check for db2pdf
 114 AC_CHECK_PROGS(DB2PDF, docbook2pdf db2pdf, false)
 115 AC_SUBST(DB2PDF)
 116
 117 dnl Check for db2ps
 118 AC_CHECK_PROGS(DB2PS, docbook2ps db2ps, false)
 119 AC_SUBST(DB2PS)
 120
 121 dnl Check for db2txt
 122 AC_CHECK_PROGS(DB2TXT, docbook2txt db2txt, false)
 123 AC_SUBST(DB2TXT)
 124
 125 dnl **** Check for some libraries ****
 126
 127 dnl Check for -li386 for NetBSD and OpenBSD
 128 AC_CHECK_LIB(i386,i386_set_ldt)
 129 dnl Check for -lossaudio for NetBSD
 130 AC_CHECK_LIB(ossaudio,_oss_ioctl)
 131 dnl Check for -lw for Solaris
 132 AC_CHECK_FUNCS(iswalnum,,AC_CHECK_LIB(w,iswalnum))
 133 dnl Check for -lnsl for Solaris
 134 AC_CHECK_FUNCS(gethostbyname,,AC_CHECK_LIB(nsl,gethostbyname))
 135 dnl Check for -lsocket for Solaris
 136 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
 137 dnl Check for -lresolv for Solaris
 138 AC_CHECK_FUNCS(inet_aton,,AC_CHECK_LIB(resolv,inet_aton))
 139 dnl Check for -lxpg4 for FreeBSD
 140 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
 141 dnl Check for -lpoll for Mac OS X/Darwin
 142 AC_CHECK_LIB(poll,poll)
 143 dnl Check for -lresolv for Mac OS X/Darwin
 144 AC_CHECK_LIB(resolv,res_9_init)
 145 dnl Check for -lpthread
 146 AC_CHECK_LIB(pthread,pthread_create,AC_SUBST(LIBPTHREAD,"-lpthread"))
 147
 148 AC_SUBST(XLIB)
 149 AC_SUBST(XFILES)
 150 XFILES=""
 151 AC_SUBST(OPENGLFILES)
 152 OPENGLFILES=""
 153 AC_SUBST(GLU32FILES)
 154 GLU32FILES=""
 155 AC_SUBST(OPENGL_LIBS)
 156 OPENGL_LIBS=""
 157 if test "$have_x" = "yes"
 158 then
 159     XLIB="-lXext -lX11"
 160     ac_save_CPPFLAGS="$CPPFLAGS"
 161     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 162
 163     dnl *** All of the following tests require X11/Xlib.h
 164     AC_CHECK_HEADERS(X11/Xlib.h,
 165       [
 166         AC_CHECK_HEADERS([X11/XKBlib.h \
 167                           X11/Xutil.h \
 168                           X11/extensions/shape.h \
 169                           X11/extensions/XInput.h \
 170                           X11/extensions/XShm.h \
 171                           X11/extensions/Xrandr.h \
 172                           X11/extensions/Xrender.h \
 173                           X11/extensions/Xvlib.h \
 174                           X11/extensions/xf86dga.h \
 175                           X11/extensions/xf86vmode.h],,,
 176                          [#include <X11/Xlib.h>
 177                           #ifdef HAVE_X11_XUTIL_H
 178                           # include <X11/Xutil.h>
 179                           #endif])
 180
 181         dnl *** Check for X keyboard extension
 182         if test "$ac_cv_header_X11_XKBlib_h" = "yes"
 183         then
 184               AC_CHECK_LIB(X11, XkbQueryExtension,
 185               AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
 186               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 187         fi
 188
 189         dnl *** Check for X Shm extension
 190         if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
 191         then
 192               AC_CHECK_LIB(Xext, XShmQueryExtension,
 193               AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
 194               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 195         fi
 196
 197         dnl *** Check for X shape extension
 198         if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
 199         then
 200               AC_CHECK_LIB(Xext,XShapeQueryExtension,
 201               AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
 202               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 203         fi
 204
 205         dnl *** Check for XFree86 DGA / DGA 2.0 extension
 206         if test "$ac_cv_header_X11_extensions_xf86dga_h" = "yes"
 207         then
 208               AC_CHECK_LIB(Xxf86dga, XDGAQueryExtension,
 209                 [ dnl *** If found...
 210                   AC_DEFINE(HAVE_LIBXXF86DGA2, 1,
 211                             [Define if you have the Xxf86dga library version 2])
 212                   X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
 213                ],
 214                 [ dnl *** If not found, look for XF86DGAQueryExtension()
 215                   dnl *** instead (DGA 2.0 not found)...
 216                   AC_CHECK_LIB(Xxf86dga, XF86DGAQueryExtension,
 217                     [ AC_DEFINE(HAVE_LIBXXF86DGA, 1,
 218                                 [Define if you have the Xxf86dga library version 1])
 219                       X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
 220                     ],,
 221                     $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 222                   )
 223                 ],
 224                 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 225         fi
 226
 227         dnl *** Check for XFree86 VMODE extension
 228         if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
 229         then
 230                 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
 231                   [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
 232                      X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
 233                   ],,
 234                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 235         fi
 236
 237         dnl *** Check for X RandR extension
 238         if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes"
 239         then
 240                 AC_TRY_COMPILE([#include <X11/Xlib.h>
 241 #include <X11/extensions/Xrandr.h>],[static typeof(XRRSetScreenConfigAndRate) * func;],
 242                   [AC_DEFINE(HAVE_LIBXRANDR, 1, [Define if you have the Xrandr library])])
 243         fi
 244
 245         dnl *** Check for XVideo extension supporting XvImages
 246         if test "$ac_cv_header_X11_extensions_Xvlib_h" = "yes"
 247         then
 248                 AC_CHECK_LIB(Xv, XvShmCreateImage,
 249                   [ AC_DEFINE(HAVE_XVIDEO, 1, [Define if the X libraries support XVideo])
 250                      X_PRE_LIBS="$X_PRE_LIBS -lXv"
 251                   ],,
 252                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 253         fi
 254       ]
 255     ) dnl *** End of X11/Xlib.h check
 256
 257     dnl Check for the presence of OpenGL
 258     if test "x$with_opengl" != "xno"
 259     then
 260         if test -f /usr/X11R6/lib/libGL.a -a ! -f /usr/X11R6/lib/libGL.so
 261         then
 262             AC_MSG_ERROR([/usr/X11R6/lib/libGL.a is present on your system.
 263 This prevents linking to OpenGL. Delete the file and restart configure.])
 264         fi
 265
 266         AC_CHECK_HEADERS(GL/gl.h GL/glx.h)
 267         if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
 268         then
 269             AC_CHECK_HEADERS(GL/glext.h,,,[#include <GL/glx.h>])
 270             dnl Check for some problems due to old Mesa versions
 271             AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_version_OK,
 272               AC_TRY_COMPILE(
 273                 [#include <GL/gl.h>],
 274                 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
 275                 [wine_cv_opengl_version_OK="yes"],
 276                 [wine_cv_opengl_version_OK="no"]
 277               )
 278             )
 279
 280             if test "$wine_cv_opengl_version_OK" = "yes"
 281             then
 282                 dnl Check for the presence of the library
 283                 AC_CHECK_LIB(GL,glXCreateContext,
 284                              OPENGL_LIBS="-lGL"
 285                              ,,
 286                              $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 287
 288                 if test "$ac_cv_lib_GL_glXCreateContext" = "yes"
 289                 then
 290                         OPENGLFILES='$(OPENGLFILES)'
 291                         AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])
 292
 293                         AC_CHECK_LIB(GL,glXGetProcAddressARB,
 294                                      AC_DEFINE(HAVE_GLX_GETPROCADDRESS, 1,
 295                                                [Define if the OpenGL library supports the glXGetProcAddressARB call]),,
 296                                      $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 297
 298                         if test "$ac_cv_lib_GL_glXGetProcAddressARB" = "yes"
 299                         then
 300                                AC_CACHE_CHECK([for OpenGL extension functions prototypes], wine_cv_extension_prototypes,
 301                                   [AC_TRY_COMPILE([#include <GL/gl.h>
 302                                                   #ifdef HAVE_GL_GLEXT_H
 303                                                   # include <GL/glext.h>
 304                                                   #endif
 305                                                   ],
 306                                                  [PFNGLCOLORTABLEEXTPROC test_proc;],
 307                                                  [wine_cv_extension_prototypes="yes"],
 308                                                  [wine_cv_extension_prototypes="no"]
 309                                   )]
 310                                 )
 311                                 if test "$wine_cv_extension_prototypes" = "yes"
 312                                 then
 313                                     AC_DEFINE(HAVE_GLEXT_PROTOTYPES, 1,
 314                                               [Define if the OpenGL headers define extension typedefs])
 315                                 fi
 316                         fi
 317
 318                 fi
 319                 dnl Check for GLU32 library.
 320                 AC_CHECK_LIB(GLU,gluLookAt,
 321                              [OPENGL_LIBS="$OPENGL_LIBS -lGLU"
 322                              GLU32FILES='$(GLU32FILES)']
 323                              ,,
 324                              $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
 325                 )
 326              fi
 327
 328              dnl Check for glut32 library.
 329              AC_CHECK_LIB(glut,glutMainLoop,
 330                        [AC_SUBST(GLUT_LIBS,"-lglut -lXmu -lXi")
 331                         AC_SUBST(GLUT32FILES,'$(GLUT32FILES)')],,
 332                         $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXmu -lXi -lX11 $X_EXTRA_LIBS)
 333          fi
 334     fi
 335
 336     dnl **** Check for NAS ****
 337     AC_SUBST(NASLIBS,"")
 338     AC_CHECK_HEADERS(audio/audiolib.h,
 339          [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
 340           AC_CHECK_LIB(audio,AuCreateFlow,
 341                        [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
 342                         NASLIBS="-laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],,
 343                        [-lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
 344
 345     CPPFLAGS="$ac_save_CPPFLAGS"
 346     XFILES='$(XFILES)'
 347 else
 348     XLIB=""
 349     X_CFLAGS=""
 350     X_LIBS=""
 351 fi
 352
 353 dnl **** Check which curses lib to use ***
 354 CURSESLIBS=""
 355 if test "x$with_curses" != "xno"
 356 then
 357     AC_CHECK_HEADERS(ncurses.h,
 358         [AC_CHECK_LIB(ncurses,waddch,
 359             [AC_DEFINE(HAVE_LIBNCURSES, 1, [Define if you have the ncurses library (-lncurses)])
 360              CURSESLIBS="-lncurses"],
 361              [AC_CHECK_HEADERS(curses.h,
 362                  [AC_CHECK_LIB(curses,waddch,
 363                      [AC_DEFINE(HAVE_LIBCURSES, 1, [Define if you have the curses library (-lcurses)])
 364                       CURSESLIBS="-lcurses"])])])])
 365     saved_libs="$LIBS"
 366     LIBS="$CURSESLIBS $LIBS"
 367     AC_CHECK_FUNCS(getbkgd resizeterm)
 368     LIBS="$saved_libs"
 369 fi
 370 AC_SUBST(CURSESLIBS)
 371
 372 dnl **** Check for SANE ****
 373 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
 374 if test "$sane_devel" = "no"
 375 then
 376     SANELIBS=""
 377     SANEINCL=""
 378 else
 379     SANELIBS="`$sane_devel --libs`"
 380     SANEINCL="`$sane_devel --cflags`"
 381     ac_save_CPPFLAGS="$CPPFLAGS"
 382     ac_save_LIBS="$LIBS"
 383     CPPFLAGS="$CPPFLAGS $SANEINCL"
 384     LIBS="$LIBS $SANELIBS"
 385     AC_CHECK_HEADER(sane/sane.h,
 386                     [AC_CHECK_LIB(sane,sane_open,
 387                                   [AC_DEFINE(HAVE_SANE, 1, [Define if we have SANE development environment])],
 388                                   [SANELIBS=""
 389                                   SANEINCL=""])],
 390                     [SANELIBS=""
 391                     SANEINCL=""])
 392     LIBS="$ac_save_LIBS"
 393     CPPFLAGS="$ac_save_CPPFLAGS"
 394 fi
 395 AC_SUBST(SANELIBS)
 396 AC_SUBST(SANEINCL)
 397
 398 dnl **** Check for the ICU library ****
 399 AC_CHECK_HEADERS(unicode/ubidi.h)
 400 if test "$ac_cv_header_unicode_ubidi_h" = "yes"
 401 then
 402     saved_libs="$LIBS"
 403     ICU_LIB_DIR="${ICU_LIB_DIR-/usr/lib}"
 404     ICUUC_LIB="${ICUUC_LIB-$ICU_LIB_DIR/libsicuuc.a}"
 405     ICUDATA_LIB="${ICUDATA_LIB-$ICU_LIB_DIR/libsicudata.a}"
 406     AC_MSG_CHECKING(whether can link with ICU libraries $ICUUC_LIB and $ICUDATA_LIB)
 407     LIBS="$LIBS $ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s"
 408     AC_TRY_LINK([#include <unicode/ubidi.h>],[ubidi_open()],
 409                 [AC_DEFINE(HAVE_ICU,1,[Define to 1 if the ICU libraries are installed])
 410                  AC_SUBST(ICULIBS,"$ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s")
 411                  AC_MSG_RESULT(yes)],
 412                 [AC_MSG_RESULT(no)])
 413     LIBS="$saved_libs"
 414 fi
 415
 416 dnl **** Check for FreeType 2 ****
 417 AC_CHECK_LIB(freetype,FT_Init_FreeType,ft_lib=yes,ft_lib=no,$X_LIBS)
 418 if test "$ft_lib" = "no"
 419 then
 420     FREETYPEINCL=""
 421     wine_cv_msg_freetype=no
 422 else
 423     AC_CHECK_PROG(ft_devel,freetype-config,freetype-config,no)
 424     if test "$ft_devel" = "no"
 425     then
 426         AC_CHECK_PROG(ft_devel2,freetype2-config,freetype2-config,no)
 427         if test "$ft_devel2" = "freetype2-config"
 428         then
 429                 ft_devel=$ft_devel2
 430         fi
 431     fi
 432     if test "$ft_devel" = "no"
 433     then
 434         FREETYPEINCL=""
 435         wine_cv_msg_freetype=yes
 436     else
 437         FREETYPEINCL=`$ft_devel --cflags`
 438         ac_save_CPPFLAGS="$CPPFLAGS"
 439         CPPFLAGS="$FREETYPEINCL $CPPFLAGS"
 440         AC_CHECK_HEADERS(ft2build.h \
 441                          freetype/freetype.h \
 442                          freetype/ftglyph.h \
 443                          freetype/tttables.h \
 444                          freetype/ftnames.h \
 445                          freetype/ftsnames.h \
 446                          freetype/ttnameid.h \
 447                          freetype/ftoutln.h \
 448                          freetype/ftwinfnt.h \
 449                          freetype/internal/sfnt.h,,,
 450                          [#if HAVE_FT2BUILD_H
 451                           #include <ft2build.h>
 452                           #endif])
 453         AC_TRY_CPP([#include <ft2build.h>
 454                     #include <freetype/fttrigon.h>],
 455                     [AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
 456           [Define if you have the <freetype/fttrigon.h> header file.])
 457                     wine_cv_fttrigon=yes],
 458                     wine_cv_fttrigon=no)
 459         CPPFLAGS="$ac_save_CPPFLAGS"
 460         dnl Check that we have at least freetype/freetype.h
 461         if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
 462         then
 463             AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
 464             wine_cv_msg_freetype=no
 465         else
 466             FREETYPEINCL=""
 467             wine_cv_msg_freetype=yes
 468         fi
 469     fi
 470 fi
 471 AC_SUBST(FREETYPEINCL)
 472
 473 dnl **** Check for parport (currently Linux only) ****
 474 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
 475  AC_TRY_COMPILE(
 476    [#include <linux/ppdev.h>],
 477    [ioctl (1,PPCLAIM,0)],
 478    [ac_cv_c_ppdev="yes"],
 479    [ac_cv_c_ppdev="no"])
 480  )
 481 if test "$ac_cv_c_ppdev" = "yes"
 482 then
 483     AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
 484 fi
 485
 486 dnl **** Check for va_copy ****
 487 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
 488  AC_TRY_LINK(
 489    [#include <stdarg.h>],
 490    [va_list ap1, ap2;
 491     va_copy(ap1,ap2);
 492    ],
 493    [ac_cv_c_va_copy="yes"],
 494    [ac_cv_c_va_copy="no"])
 495  )
 496 if test "$ac_cv_c_va_copy" = "yes"
 497 then
 498     AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
 499 fi
 500 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
 501  AC_TRY_LINK(
 502    [#include <stdarg.h>],
 503    [va_list ap1, ap2;
 504     __va_copy(ap1,ap2);
 505    ],
 506    [ac_cv_c___va_copy="yes"],
 507    [ac_cv_c___va_copy="no"])
 508  )
 509 if test "$ac_cv_c___va_copy" = "yes"
 510 then
 511     AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
 512 fi
 513
 514 dnl **** Check for sigsetjmp ****
 515 AC_CACHE_CHECK([for sigsetjmp], ac_cv_c_sigsetjmp,
 516  AC_TRY_LINK(
 517    [#include <setjmp.h>],
 518    [sigjmp_buf buf;
 519     sigsetjmp( buf, 1 );
 520     siglongjmp( buf, 1 );],
 521    [ac_cv_c_sigsetjmp="yes"],
 522    [ac_cv_c_sigsetjmp="no"])
 523  )
 524 if test "$ac_cv_c_sigsetjmp" = "yes"
 525 then
 526     AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have the sigsetjmp (and siglongjmp) function])
 527 fi
 528
 529 dnl **** Check for pthread_rwlock_t ****
 530 AC_CHECK_TYPES([pthread_rwlock_t, pthread_rwlockattr_t],,,[#define _GNU_SOURCE
 531 #include <pthread.h>])
 532
 533 dnl **** Check for pthread functions ****
 534 ac_save_LIBS="$LIBS"
 535 LIBS="$LIBS $LIBPTHREAD"
 536 AC_CHECK_FUNCS(\
 537         pthread_getattr_np \
 538         pthread_get_stackaddr_np \
 539         pthread_get_stacksize_np \
 540 )
 541 LIBS="$ac_save_LIBS"
 542
 543 dnl **** Check for Open Sound System ****
 544 AC_CHECK_HEADERS(sys/soundcard.h machine/soundcard.h soundcard.h, break)
 545
 546 AC_CACHE_CHECK([for Open Sound System],
 547         ac_cv_c_opensoundsystem,
 548         AC_TRY_COMPILE([
 549         #if defined(HAVE_SYS_SOUNDCARD_H)
 550                 #include <sys/soundcard.h>
 551         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 552                 #include <machine/soundcard.h>
 553         #elif defined(HAVE_SOUNDCARD_H)
 554                 #include <soundcard.h>
 555         #endif
 556         ],[
 557
 558 /* check for one of the Open Sound System specific SNDCTL_ defines */
 559 #if !defined(SNDCTL_DSP_STEREO)
 560 #error No open sound system
 561 #endif
 562 ],ac_cv_c_opensoundsystem="yes",ac_cv_c_opensoundsystem="no"))
 563
 564 if test "$ac_cv_c_opensoundsystem" = "yes"
 565 then
 566     AC_DEFINE(HAVE_OSS, 1, [Define if you have the Open Sound system])
 567 fi
 568
 569 AC_CACHE_CHECK([for Open Sound System/MIDI interface],
 570         ac_cv_c_opensoundsystem_midi,
 571         AC_TRY_COMPILE([
 572         #if defined(HAVE_SYS_SOUNDCARD_H)
 573                 #include <sys/soundcard.h>
 574         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 575                 #include <machine/soundcard.h>
 576         #elif defined(HAVE_SOUNDCARD_H)
 577                 #include <soundcard.h>
 578         #endif
 579         ],[
 580
 581 /* check for one of the Open Sound System specific SNDCTL_SEQ defines */
 582 #if !defined(SNDCTL_SEQ_SYNC)
 583 #error No open sound system MIDI interface
 584 #endif
 585 ],ac_cv_c_opensoundsystem_midi="yes",ac_cv_c_opensoundsystem_midi="no"))
 586
 587 if test "$ac_cv_c_opensoundsystem_midi" = "yes"
 588 then
 589     AC_DEFINE(HAVE_OSS_MIDI, 1, [Define if you have the Open Sound system (MIDI interface)])
 590 fi
 591
 592 dnl **** Check for aRts Sound Server ****
 593 AC_PATH_PROG(ARTSCCONFIG, artsc-config)
 594 if test x$ARTSCCONFIG != x -a x$ARTSCCONFIG != x'"$ARTSCCONFIG"';
 595 then
 596     ARTSC_CFLAGS=""
 597     for i in `$ARTSCCONFIG --cflags`
 598     do
 599       case "$i" in
 600         -I*) ARTSC_CFLAGS="$ARTSC_CFLAGS $i";;
 601       esac
 602     done
 603     ARTSC_LIBS=`$ARTSCCONFIG --libs`
 604     save_CFLAGS="$CFLAGS"
 605     CFLAGS="$CFLAGS $ARTSC_CFLAGS"
 606     AC_TRY_COMPILE([#include <artsc.h>],[arts_stream_t stream;],
 607         [AC_SUBST(ARTSLIBS, $ARTSC_LIBS)
 608          AC_SUBST(ARTSINCL, $ARTSC_CFLAGS)
 609          AC_DEFINE(HAVE_ARTS, 1, [Define if you have ARTS sound server])])
 610     CFLAGS="$save_CFLAGS"
 611 fi
 612
 613 dnl **** Check for ALSA ****
 614 AC_SUBST(ALSALIBS,"")
 615 AC_CHECK_HEADERS(alsa/asoundlib.h sys/asoundlib.h, break)
 616 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
 617 then
 618     AC_CHECK_LIB(asound,snd_pcm_open,
 619         AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA including devel headers])
 620         ALSALIBS="-lasound")
 621 fi
 622
 623 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
 624
 625 AC_SUBST(AUDIOIOLIBS,"")
 626 AC_CHECK_HEADERS(libaudioio.h,
 627     [AC_CHECK_LIB(audioio,AudioIOGetVersion,
 628                   [AUDIOIOLIBS="-laudioio"
 629                    AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])])
 630
 631 dnl **** Check for capi4linux ****
 632
 633 AC_CHECK_HEADERS(capi20.h,[
 634         AC_CHECK_HEADERS(linux/capi.h,[
 635                 AC_CHECK_LIB(capi20,capi20_register,[
 636                         AC_DEFINE(HAVE_CAPI4LINUX,1,[Define if you have capi4linux libs and headers])
 637                         AC_SUBST(CAPI4LINUXLIBS,"-lcapi20")
 638                 ])
 639         ])
 640 ])
 641
 642 dnl **** Check for broken glibc mmap64 ****
 643
 644 AC_CACHE_CHECK( [whether mmap64 works defined as mmap], ac_cv_mmap64_works,
 645         AC_TRY_RUN([
 646                 #define _FILE_OFFSET_BITS 64
 647                 #include <stdio.h>
 648                 #include <unistd.h>
 649                 #include <fcntl.h>
 650                 #include <sys/mman.h>
 651                 #include <errno.h>
 652
 653                 int main(int argc,char **argv) {
 654                         int fd = open("conftest.map",O_CREAT|O_RDWR,0600);
 655                         if (fd == -1) exit(1);
 656
 657                         unlink("conftest.map");
 658
 659                         write(fd,"test",4);
 660
 661                         if ((-1 == mmap(0,4,PROT_READ|PROT_WRITE,MAP_SHARED,fd,0)) &&
 662                             (errno == EINVAL)
 663                         ) {
 664                                 exit(1);
 665                         }
 666                         close(fd);
 667                         fprintf(stderr,"success!\n");
 668                         exit(0);
 669                 }
 670
 671         ],
 672     ac_cv_mmap64_works="yes",
 673     ac_cv_mmap64_works="no",
 674     ac_cv_mmap64_works="no") )
 675
 676 if test "$ac_cv_mmap64_works" = "yes"
 677 then
 678     AC_DEFINE(_FILE_OFFSET_BITS, 64, [Set this to 64 to enable 64-bit file support on Linux])
 679 fi
 680
 681 dnl **** Check for gcc specific options ****
 682
 683 AC_SUBST(EXTRACFLAGS,"")
 684 if test "x${GCC}" = "xyes"
 685 then
 686   EXTRACFLAGS="-Wall -pipe"
 687
 688   dnl Check for strength-reduce bug
 689   AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
 690                   AC_TRY_RUN([
 691 int     L[[4]] = {0,1,2,3};
 692 int main(void) {
 693   static int Array[[3]];
 694   unsigned int B = 3;
 695   int i;
 696   for(i=0; i<B; i++) Array[[i]] = i - 3;
 697   for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
 698   L[[i]] = 4;
 699
 700   exit( Array[[1]] != -2 || L[[2]] != 3);
 701 }],
 702     ac_cv_c_gcc_strength_bug="no",
 703     ac_cv_c_gcc_strength_bug="yes",
 704     ac_cv_c_gcc_strength_bug="yes") )
 705   if test "$ac_cv_c_gcc_strength_bug" = "yes"
 706   then
 707     EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
 708   fi
 709
 710   dnl Check for -fshort-wchar
 711   AC_CACHE_CHECK([for gcc -fshort-wchar support], ac_cv_c_gcc_fshort_wchar,
 712       [WINE_TRY_CFLAGS([-fshort-wchar],
 713                       ac_cv_c_gcc_fshort_wchar="yes",ac_cv_c_gcc_fshort_wchar="no")])
 714   if test "$ac_cv_c_gcc_fshort_wchar" = "yes"
 715   then
 716       AC_DEFINE(CC_FLAG_SHORT_WCHAR, "-fshort-wchar", [Specifies the compiler flag that forces a short wchar_t])
 717   fi
 718
 719   dnl Check for -mpreferred-stack-boundary
 720   AC_CACHE_CHECK([for gcc -mpreferred-stack-boundary=2 support], ac_cv_c_gcc_stack_boundary,
 721       [WINE_TRY_CFLAGS([-mpreferred-stack-boundary=2],
 722                       ac_cv_c_gcc_stack_boundary="yes",ac_cv_c_gcc_stack_boundary="no")])
 723   if test "$ac_cv_c_gcc_stack_boundary" = "yes"
 724   then
 725     EXTRACFLAGS="$EXTRACFLAGS -mpreferred-stack-boundary=2"
 726   fi
 727
 728   dnl Check for -fno-strict-aliasing
 729   AC_CACHE_CHECK([for gcc -fno-strict-aliasing support], ac_cv_c_gcc_no_strict_aliasing,
 730       [WINE_TRY_CFLAGS([-fno-strict-aliasing],
 731                       ac_cv_c_gcc_no_strict_aliasing="yes",ac_cv_c_gcc_no_strict_aliasing="no")])
 732   if test "$ac_cv_c_gcc_no_strict_aliasing" = "yes"
 733   then
 734     EXTRACFLAGS="$EXTRACFLAGS -fno-strict-aliasing"
 735   fi
 736
 737   dnl Check for -gstabs+ option
 738   AC_CACHE_CHECK([for gcc -gstabs+ support], ac_cv_c_gcc_gstabs,
 739       [WINE_TRY_CFLAGS([-gstabs+],ac_cv_c_gcc_gstabs="yes", ac_cv_c_gcc_gstabs="no")])
 740   if test "$ac_cv_c_gcc_gstabs" = "yes"
 741   then
 742     EXTRACFLAGS="$EXTRACFLAGS -gstabs+"
 743   fi
 744
 745   dnl Check for noisy string.h
 746   saved_CFLAGS="$CFLAGS"
 747   CFLAGS="$CFLAGS -Wpointer-arith -Werror"
 748   AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
 749       AC_TRY_COMPILE([#include <string.h>],[],
 750                      [ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
 751   CFLAGS="$saved_CFLAGS"
 752   if test "$ac_cv_c_string_h_warnings" = "no"
 753   then
 754     EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
 755   fi
 756 fi
 757
 758 dnl **** Check how to define a function in assembly code ****
 759
 760 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
 761   WINE_TRY_ASM_LINK(
 762       ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
 763       ac_cv_asm_func_def=".def",
 764     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
 765       ac_cv_asm_func_def=".type @function",
 766     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
 767       ac_cv_asm_func_def=".type 2",
 768       ac_cv_asm_func_def="unknown")])]))
 769
 770 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
 771 case "$ac_cv_asm_func_def" in
 772   ".def")
 773      AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
 774   ".type @function")
 775      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
 776   ".type 2")
 777      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
 778   *)
 779      AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
 780 esac
 781
 782 dnl **** Check for underscore on external symbols ****
 783
 784 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
 785     WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
 786                       [extern int ac_test;],
 787                       [if (ac_test) return 1],
 788                       ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
 789
 790 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
 791 if test "$ac_cv_c_extern_prefix" = "yes"
 792 then
 793   AC_DEFINE([__ASM_NAME(name)], ["_" name])
 794 else
 795   AC_DEFINE([__ASM_NAME(name)], [name])
 796 fi
 797
 798 dnl **** Check how to do strings in assembler ****
 799
 800 AC_CACHE_CHECK([for assembler keyword for ASCII strings], ac_cv_c_asm_string,
 801     WINE_TRY_ASM_LINK([".data\\n\\t.string \\"test\\"\\n\\t.text"],,,ac_cv_c_asm_string=".string",
 802       WINE_TRY_ASM_LINK([".data\\n\\t.asciz \\"test\\"\\n\\t.text"],,,ac_cv_c_asm_string=".asciz",
 803         WINE_TRY_ASM_LINK([".data\\n\\t.ascii \\"test\\"\\n\\t.text"],,,ac_cv_c_asm_string=".ascii",
 804           AC_MSG_ERROR([could not discover how to produce C strings with assembler.])))))
 805
 806 AC_DEFINE_UNQUOTED(__ASM_STRING, ["$ac_cv_c_asm_string"],
 807                    [Define to the assembler keyword used to specify an ASCII string])
 808
 809 dnl **** Check for .short in assembler ****
 810
 811 AC_CACHE_CHECK([for assembler keyword for word values], ac_cv_c_asm_short,
 812     WINE_TRY_ASM_LINK([".data\\n\\t.short 1\\n\\t.text"],,,ac_cv_c_asm_short=".short",
 813       WINE_TRY_ASM_LINK([".data\\n\\t.half 1\\n\\t.text"],,,ac_cv_c_asm_short=".half",
 814         AC_MSG_ERROR([could not discover how to specify word values with assembler.]))))
 815
 816 AC_DEFINE_UNQUOTED(__ASM_SHORT, ["$ac_cv_c_asm_short"],
 817                    [Define to the assembler keyword used to specify a word value])
 818
 819 dnl **** Check for .size in assembler ****
 820
 821 AC_CACHE_CHECK([for .size in assembler], ac_cv_c_asm_size,
 822     WINE_TRY_ASM_LINK([".globl _ac_test\n.size _ac_test, . - _ac_test"],,,
 823                       ac_cv_c_asm_size="yes",ac_cv_c_asm_size="no"))
 824
 825 if test "$ac_cv_c_asm_size" = "yes"
 826 then
 827   AC_DEFINE(HAVE_ASM_DOT_SIZE, 1, [Define if the assembler keyword .size is accepted])
 828 fi
 829
 830 dnl **** Check for working dll ****
 831
 832 AC_SUBST(DLLEXT,"")
 833 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
 834 AC_SUBST(DLLIBS,"")
 835 AC_SUBST(LDSHARED,"")
 836 AC_SUBST(LDDLLFLAGS,"")
 837 AC_SUBST(LIBEXT,"so")
 838 AC_SUBST(IMPLIBEXT,"def")
 839
 840 case $host_os in
 841   cygwin*|mingw32*)
 842     AC_CHECK_TOOL(DLLTOOL,dlltool,false)
 843     AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
 844     if test "$DLLWRAP" = "false"; then
 845       LIBEXT="a"
 846     else
 847       dnl FIXME - check whether dllwrap works correctly...
 848       LIBEXT="dll"
 849     fi
 850     IMPLIBEXT="a"
 851     dnl We can't build 16-bit NE dlls
 852     WIN16_FILES=""
 853     WIN16_INSTALL=""
 854     ;;
 855   *)
 856     AC_CHECK_HEADERS(dlfcn.h,
 857         [AC_CHECK_FUNCS(dlopen,,
 858             [AC_CHECK_LIB(dl,dlopen,
 859                          [AC_DEFINE(HAVE_DLOPEN,1,[Define if you have dlopen])
 860                           DLLIBS="-ldl"],
 861                          [LIBEXT="a"])])],
 862         [LIBEXT="a"])
 863
 864     if test "$LIBEXT" = "so"
 865     then
 866       DLLFLAGS="$DLLFLAGS -fPIC"
 867       DLLEXT=".so"
 868       AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
 869           [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-soname,conftest.so.1.0,-Bsymbolic],
 870                            ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
 871       if test "$ac_cv_c_dll_gnuelf" = "yes"
 872       then
 873         LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"
 874         LDDLLFLAGS="-shared -Wl,-Bsymbolic"
 875         AC_CACHE_CHECK([whether the linker accepts -z defs], ac_cv_c_dll_zdefs,
 876           [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs],
 877                            ac_cv_c_dll_zdefs="yes",ac_cv_c_dll_zdefs="no")])
 878         if test "$ac_cv_c_dll_zdefs" = "yes"
 879         then
 880           LDDLLFLAGS="$LDDLLFLAGS,-z,defs"
 881         fi
 882
 883         AC_CACHE_CHECK([whether the linker accepts -init and -fini], ac_cv_c_dll_init_fini,
 884           [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-init,__wine_spec_init,-fini,__wine_spec_fini],
 885                            ac_cv_c_dll_init_fini="yes",ac_cv_c_dll_init_fini="no")])
 886         if test "$ac_cv_c_dll_init_fini" = "yes"
 887         then
 888           LDDLLFLAGS="$LDDLLFLAGS,-init,__wine_spec_init,-fini,__wine_spec_fini"
 889         fi
 890
 891         AC_CACHE_CHECK([whether the linker accepts version scripts], ac_cv_c_ld_version_scripts,
 892           [echo '{ global: *; };' >conftest.map
 893            WINE_TRY_CFLAGS([-fPIC -shared -Wl,--version-script=conftest.map],
 894                            ac_cv_c_ld_version_scripts="yes",ac_cv_c_ld_version_scripts="no")
 895            rm -f conftest.map])
 896         if test "$ac_cv_c_ld_version_scripts" = "yes"
 897         then
 898           LDSHARED="$LDSHARED \$(VERSCRIPT:%=-Wl,--version-script=%)"
 899         fi
 900
 901         AC_CACHE_CHECK([whether the linker accepts --export-dynamic], ac_cv_c_export_dynamic,
 902           [WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
 903                            ac_cv_c_export_dynamic="yes",ac_cv_c_export_dynamic="no")])
 904         if test "$ac_cv_c_export_dynamic" = "yes"
 905         then
 906           AC_SUBST(LDEXECFLAGS,["-Wl,--export-dynamic"])
 907         fi
 908
 909         case $host_cpu in
 910           *i[[3456789]]86*)
 911             AC_CACHE_CHECK([whether we can relocate the executable to 0x77f00000], ac_cv_ld_reloc_exec,
 912               [WINE_TRY_CFLAGS([-Wl,--section-start,.interp=0x77f00400],
 913                                ac_cv_ld_reloc_exec="yes", ac_cv_ld_reloc_exec="no")])
 914             if test "$ac_cv_ld_reloc_exec" = "yes"
 915             then
 916               LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x77f00400"
 917             fi
 918             ;;
 919         esac
 920
 921       else
 922         AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
 923             [WINE_TRY_CFLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
 924                              ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
 925         if test "$ac_cv_c_dll_unixware" = "yes"
 926         then
 927           LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
 928           LDDLLFLAGS="-Wl,-G,-B,symbolic"
 929
 930         else
 931           AC_CACHE_CHECK(whether we can build a Mach-O (Mac OS X/Darwin) dll, ac_cv_c_dll_macho,
 932             [WINE_TRY_CFLAGS([-bundle], ac_cv_c_dll_macho="yes", ac_cv_c_dll_macho="no")])
 933           if test "$ac_cv_c_dll_macho" = "yes"
 934           then
 935             LIBEXT="dylib"
 936             LDDLLFLAGS="-bundle -flat_namespace -undefined suppress"
 937             LDSHARED="\$(CC) -dynamiclib"
 938             CFLAGS="$CFLAGS -ffixed-r13 -no-cpp-precomp"
 939             STRIP="$STRIP -u -r"
 940             dnl Relocate wine executable
 941             AC_SUBST(LDEXECFLAGS,"-seg1addr 0x120000")
 942             dnl Relocate libwine.dyld too
 943             AC_SUBST(LDLIBWINEFLAGS,"-seg1addr 0x140000")
 944           fi
 945         fi
 946       fi
 947     fi
 948
 949     dnl Check for cross compiler to build test programs
 950     AC_SUBST(CROSSTEST,"")
 951     if test "$cross_compiling" = "no"
 952     then
 953       AC_CHECK_PROGS(CROSSCC,i586-mingw32msvc-gcc i386-mingw32msvc-gcc i386-mingw32-gcc mingw-gcc,false)
 954       AC_CHECK_PROGS(DLLTOOL,i586-mingw32msvc-dlltool i386-mingw32msvc-dlltool i386-mingw32-dlltool mingw-dlltool,false)
 955       AC_CHECK_PROGS(CROSSWINDRES,i586-mingw32msvc-windres i386-mingw32msvc-windres i386-mingw32-windres mingw-windres,false)
 956       if test "$CROSSCC" != "false"; then CROSSTEST="\$(CROSSTEST)"; fi
 957     fi
 958     ;;
 959 esac
 960
 961 if test "$LIBEXT" = "a"; then
 962   AC_MSG_ERROR(
 963 [could not find a way to build shared libraries.
 964 It is currently not possible to build Wine without shared library
 965 (.so) support to allow transparent switch between .so and .dll files.
 966 If you are using Linux, you will need a newer binutils.]
 967 )
 968 fi
 969
 970 case $build_os in
 971   cygwin*|mingw32*)
 972     AC_SUBST(LDPATH,"PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$PATH\"") ;;
 973   darwin*|macosx*)
 974     AC_SUBST(LDPATH,"DYLD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$DYLD_LIBRARY_PATH\"") ;;
 975   *)
 976     AC_SUBST(LDPATH,"LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$LD_LIBRARY_PATH\"") ;;
 977 esac
 978
 979 dnl Mingw needs explicit msvcrt for linking libwine
 980 case $host_os in
 981   mingw32*)
 982     AC_SUBST(CRTLIBS,"-lmsvcrt") ;;
 983 esac
 984
 985 case $host_os in
 986   linux*)
 987     AC_SUBST(WINE_BINARIES,"wine-glibc wine-kthread wine-pthread wine-preloader")
 988     AC_SUBST(MAIN_BINARY,"wine-glibc")
 989     ;;
 990   darwin*)
 991     AC_SUBST(WINE_BINARIES,"wine-pthread")
 992     AC_SUBST(MAIN_BINARY,"wine-pthread")
 993     ;;
 994   *)
 995     AC_SUBST(WINE_BINARIES,"wine-kthread")
 996     AC_SUBST(MAIN_BINARY,"wine-kthread")
 997     ;;
 998 esac
 999
1000 dnl **** Get the soname for libraries that we load dynamically ****
1001
1002 if test "$LIBEXT" = "so" -o "$LIBEXT" = "dylib"
1003 then
1004   WINE_GET_SONAME(X11,XCreateWindow,[$X_LIBS $X_EXTRA_LIBS])
1005   WINE_GET_SONAME(Xext,XextCreateExtension,[$X_LIBS -lX11 $X_EXTRA_LIBS])
1006   WINE_GET_SONAME(Xi,XOpenDevice,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1007   WINE_GET_SONAME(Xrender,XRenderQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1008   WINE_GET_SONAME(Xrandr,XRRQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1009   WINE_GET_SONAME(freetype,FT_Init_FreeType,[$X_LIBS])
1010   WINE_GET_SONAME(GL,glXQueryExtension,[$X_LIBS $X_EXTRA_LIBS])
1011   WINE_GET_SONAME(txc_dxtn,fetch_2d_texel_rgba_dxt1)
1012   WINE_GET_SONAME(cups,cupsGetDefault)
1013   WINE_GET_SONAME(jack,jack_client_new)
1014   WINE_GET_SONAME(fontconfig,FcInit)
1015   WINE_GET_SONAME(ssl,SSL_library_init)
1016   WINE_GET_SONAME(crypto,BIO_new_socket)
1017   WINE_GET_SONAME(ncurses,waddch)
1018   WINE_GET_SONAME(curses,waddch)
1019   WINE_GET_SONAME(jpeg,jpeg_start_decompress)
1020   WINE_GET_SONAME(ungif,DGifOpen)
1021 fi
1022
1023
1024 dnl **** Check for functions ****
1025
1026 AC_FUNC_ALLOCA()
1027 AC_CHECK_FUNCS(\
1028         _lwp_create \
1029         _lwp_self \
1030         _pclose \
1031         _popen \
1032         _snprintf \
1033         _spawnvp \
1034         _stricmp \
1035         _strnicmp \
1036         _vsnprintf \
1037         chsize \
1038         clone \
1039         finite \
1040         fpclass \
1041         fstatfs \
1042         fstatvfs \
1043         ftruncate \
1044         ftruncate64 \
1045         futimes \
1046         getnetbyaddr \
1047         getnetbyname \
1048         getopt_long \
1049         getpagesize \
1050         getprotobyname \
1051         getprotobynumber \
1052         getpwuid \
1053         getservbyport \
1054         gettid \
1055         gettimeofday \
1056         inet_network \
1057         lseek64 \
1058         lstat \
1059         memmove \
1060         mmap \
1061         pclose \
1062         popen \
1063         pread \
1064         pwrite \
1065         readlink \
1066         rfork \
1067         select \
1068         sendmsg \
1069         settimeofday \
1070         sigaltstack \
1071         snprintf \
1072         spawnvp \
1073         statfs \
1074         statvfs \
1075         strcasecmp \
1076         strerror \
1077         strncasecmp \
1078         tcgetattr \
1079         timegm \
1080         usleep \
1081         vfscanf \
1082         vsnprintf \
1083         wait4 \
1084         waitpid \
1085 )
1086
1087 dnl **** Check for header files ****
1088
1089 AC_CHECK_HEADERS(\
1090         arpa/inet.h \
1091         arpa/nameser.h \
1092         cups/cups.h \
1093         direct.h \
1094         elf.h \
1095         float.h \
1096         fontconfig/fontconfig.h \
1097         getopt.h \
1098         gif_lib.h \
1099         ieeefp.h \
1100         io.h \
1101         jack/jack.h \
1102         jpeglib.h \
1103         libio.h \
1104         libutil.h \
1105         link.h \
1106         linux/cdrom.h \
1107         linux/hdreg.h \
1108         linux/input.h \
1109         linux/ioctl.h \
1110         linux/joystick.h \
1111         linux/major.h \
1112         linux/param.h \
1113         linux/serial.h \
1114         linux/ucdrom.h \
1115         machine/cpu.h \
1116         mntent.h \
1117         netdb.h \
1118         netinet/in.h \
1119         netinet/in_systm.h \
1120         netinet/tcp.h \
1121         netinet/tcp_fsm.h \
1122         openssl/ssl.h \
1123         process.h \
1124         pthread.h \
1125         pty.h \
1126         pwd.h \
1127         regex.h \
1128         sched.h \
1129         scsi/sg.h \
1130         scsi/scsi.h \
1131         scsi/scsi_ioctl.h \
1132         socket.h \
1133         stdint.h \
1134         strings.h \
1135         sys/cdio.h \
1136         sys/elf32.h \
1137         sys/errno.h \
1138         sys/exec_elf.h \
1139         sys/file.h \
1140         sys/filio.h \
1141         sys/inttypes.h \
1142         sys/ioctl.h \
1143         sys/ipc.h \
1144         sys/link.h \
1145         sys/lwp.h \
1146         sys/mman.h \
1147         sys/modem.h \
1148         sys/msg.h \
1149         sys/param.h \
1150         sys/poll.h \
1151         sys/ptrace.h \
1152         sys/reg.h \
1153         sys/scsiio.h \
1154         sys/shm.h \
1155         sys/signal.h \
1156         sys/socket.h \
1157         sys/sockio.h \
1158         sys/statfs.h \
1159         sys/statvfs.h \
1160         sys/strtio.h \
1161         sys/syscall.h \
1162         sys/sysctl.h \
1163         sys/time.h \
1164         sys/times.h \
1165         sys/uio.h \
1166         sys/un.h \
1167         sys/v86.h \
1168         sys/v86intr.h \
1169         sys/vfs.h \
1170         sys/vm86.h \
1171         sys/wait.h \
1172         syscall.h \
1173         termios.h \
1174         unistd.h \
1175         utime.h \
1176         valgrind/memcheck.h
1177 )
1178 AC_HEADER_STAT()
1179
1180 dnl **** Checks for headers that depend on other ones ****
1181
1182 AC_CHECK_HEADERS(sys/mount.h sys/user.h,,,
1183     [#include <sys/types.h>
1184      #if HAVE_SYS_PARAM_H
1185      # include <sys/param.h>
1186      #endif])
1187
1188 AC_CHECK_HEADERS([net/if.h net/if_arp.h net/if_dl.h net/if_types.h net/route.h],,,
1189     [#include <sys/types.h>
1190      #if HAVE_SYS_SOCKET_H
1191      # include <sys/socket.h>
1192      #endif])
1193
1194 AC_CHECK_HEADERS([resolv.h],,,
1195     [#include <sys/types.h>
1196      #if HAVE_SYS_SOCKET_H
1197      # include <sys/socket.h>
1198      #endif
1199      #if HAVE_NETINET_IN_H
1200      # include <netinet/in.h>
1201      #endif
1202      #if HAVE_ARPA_NAMESER_H
1203      # include <arpa/nameser.h>
1204      #endif])
1205
1206 AC_CHECK_HEADERS(netinet/ip.h,,,
1207     [#include <sys/types.h>
1208      #if HAVE_SYS_SOCKET_H
1209      # include <sys/socket.h>
1210      #endif
1211      #if HAVE_NETINET_IN_SYSTM_H
1212      # include <netinet/in_systm.h>
1213      #endif])
1214
1215 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
1216
1217 dnl **** Check for IPX headers (currently Linux only) ****
1218
1219 AC_CACHE_CHECK([for GNU style IPX support], ac_cv_c_ipx_gnu,
1220  AC_TRY_COMPILE(
1221    [#include <sys/types.h>
1222     #ifdef HAVE_SYS_SOCKET_H
1223     # include <sys/socket.h>
1224     #endif
1225     #include <netipx/ipx.h>],
1226    [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
1227    [ac_cv_c_ipx_gnu="yes"],
1228    [ac_cv_c_ipx_gnu="no"])
1229  )
1230 if test "$ac_cv_c_ipx_gnu" = "yes"
1231 then
1232     AC_DEFINE(HAVE_IPX_GNU, 1, [Define if IPX should use netipx/ipx.h from libc])
1233 fi
1234
1235 if test "$ac_cv_c_ipx_gnu" = "no"
1236 then
1237  AC_CACHE_CHECK([for linux style IPX support], ac_cv_c_ipx_linux,
1238   AC_TRY_COMPILE(
1239     [#include <sys/types.h>
1240      #ifdef HAVE_SYS_SOCKET_H
1241      # include <sys/socket.h>
1242      #endif
1243      #include <asm/types.h>
1244      #include <linux/ipx.h>],
1245     [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
1246     [ac_cv_c_ipx_linux="yes"],
1247     [ac_cv_c_ipx_linux="no"])
1248   )
1249   if test "$ac_cv_c_ipx_linux" = "yes"
1250   then
1251       AC_DEFINE(HAVE_IPX_LINUX, 1, [Define if IPX includes are taken from Linux kernel])
1252   fi
1253 fi
1254
1255 dnl **** Check for types ****
1256
1257 AC_C_CONST
1258 AC_C_INLINE
1259 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t, long long, fsblkcnt_t, fsfilcnt_t])
1260
1261 AC_CACHE_CHECK([whether linux/input.h is for real],
1262         wine_cv_linux_input_h,
1263         AC_TRY_COMPILE([
1264             #include <linux/input.h>
1265         ] , [
1266             int foo = EVIOCGBIT(EV_ABS,42);
1267             int bar = BTN_PINKIE;
1268             int fortytwo = 42;
1269         ],
1270         wine_cv_linux_input_h=yes,
1271         wine_cv_linux_input_h=no,
1272         no
1273         )
1274     )
1275     if test "$wine_cv_linux_input_h" = "yes"
1276     then
1277         AC_DEFINE(HAVE_CORRECT_LINUXINPUT_H, 1,
1278                   [Define if we have linux/input.h AND it contains the INPUT event API])
1279     fi
1280
1281
1282 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1283         wine_cv_linux_gethostbyname_r_6,
1284         AC_TRY_LINK([
1285 #include <netdb.h>
1286         ], [
1287     char *name=NULL;
1288     struct hostent he;
1289     struct hostent *result;
1290     char *buf=NULL;
1291     int bufsize=0;
1292     int res,errnr;
1293     char *addr=NULL;
1294     int addrlen=0;
1295     int addrtype=0;
1296     res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1297     res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1298     ],
1299         wine_cv_linux_gethostbyname_r_6=yes,
1300         wine_cv_linux_gethostbyname_r_6=no
1301         )
1302    )
1303    if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1304    then
1305       AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1306                 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1307    fi
1308
1309 if test "$ac_cv_header_linux_joystick_h" = "yes"
1310 then
1311    AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1312         wine_cv_linux_joystick_22_api,
1313         AC_TRY_COMPILE([
1314         #include <sys/ioctl.h>
1315         #include <linux/joystick.h>
1316
1317         struct js_event blub;
1318         #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1319         #error "no 2.2 header"
1320         #endif
1321         ],/*empty*/,
1322         wine_cv_linux_joystick_22_api=yes,
1323         wine_cv_linux_joystick_22_api=no,
1324         wine_cv_linux_joystick_22_api=no
1325         )
1326    )
1327    if test "$wine_cv_linux_joystick_22_api" = "yes"
1328    then
1329       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1330                 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1331    fi
1332 fi
1333
1334 dnl **** statfs checks ****
1335
1336 if test "$ac_cv_header_sys_vfs_h" = "yes"
1337 then
1338     AC_CACHE_CHECK( [whether sys/vfs.h defines statfs],
1339                     wine_cv_sys_vfs_has_statfs,
1340         AC_TRY_COMPILE([
1341         #include <sys/types.h>
1342         #ifdef HAVE_SYS_PARAM_H
1343         # include <sys/param.h>
1344         #endif
1345         #include <sys/vfs.h>
1346         ],[
1347                 struct statfs stfs;
1348
1349                 memset(&stfs,0,sizeof(stfs));
1350         ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
1351         )
1352     )
1353     if test "$wine_cv_sys_vfs_has_statfs" = "yes"
1354     then
1355       AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS, 1,
1356                 [Define if the struct statfs is defined by <sys/vfs.h>])
1357     fi
1358 fi
1359
1360 if test "$ac_cv_header_sys_statfs_h" = "yes"
1361 then
1362     AC_CACHE_CHECK( [whether sys/statfs.h defines statfs],
1363                     wine_cv_sys_statfs_has_statfs,
1364         AC_TRY_COMPILE([
1365         #include <sys/types.h>
1366         #ifdef HAVE_SYS_PARAM_H
1367         # include <sys/param.h>
1368         #endif
1369         #include <sys/statfs.h>
1370         ],[
1371                 struct statfs stfs;
1372         ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
1373         )
1374     )
1375     if test "$wine_cv_sys_statfs_has_statfs" = "yes"
1376     then
1377       AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS, 1,
1378                 [Define if the struct statfs is defined by <sys/statfs.h>])
1379     fi
1380 fi
1381
1382 if test "$ac_cv_header_sys_mount_h" = "yes"
1383 then
1384     AC_CACHE_CHECK( [whether sys/mount.h defines statfs],
1385                     wine_cv_sys_mount_has_statfs,
1386         AC_TRY_COMPILE([
1387         #include <sys/types.h>
1388         #ifdef HAVE_SYS_PARAM_H
1389         # include <sys/param.h>
1390         #endif
1391         #include <sys/mount.h>
1392         ],[
1393                 struct statfs stfs;
1394         ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
1395         )
1396     )
1397     if test "$wine_cv_sys_mount_has_statfs" = "yes"
1398     then
1399       AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT, 1,
1400                 [Define if the struct statfs is defined by <sys/mount.h>])
1401     fi
1402 fi
1403
1404 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1405
1406 dnl Check for statfs members
1407 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail, struct statfs.f_frsize, struct statfs.f_ffree, struct statfs.f_favail, struct statfs.f_namelen],,,
1408 [#include <sys/types.h>
1409 #ifdef HAVE_SYS_PARAM_H
1410 # include <sys/param.h>
1411 #endif
1412 #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1413 # include <sys/mount.h>
1414 #else
1415 # ifdef STATFS_DEFINED_BY_SYS_VFS
1416 #  include <sys/vfs.h>
1417 # else
1418 #  ifdef STATFS_DEFINED_BY_SYS_STATFS
1419 #   include <sys/statfs.h>
1420 #  endif
1421 # endif
1422 #endif])
1423
1424 AC_CHECK_MEMBERS([struct statvfs.f_blocks],,,
1425 [#ifdef HAVE_SYS_STATVFS_H
1426 #include <sys/statvfs.h>
1427 #endif])
1428
1429 dnl Check for socket structure members
1430 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
1431 [#include <sys/types.h>
1432 #ifdef HAVE_SYS_SOCKET_H
1433 # include <sys/socket.h>
1434 #endif
1435 #ifdef HAVE_SYS_UN_H
1436 # include <sys/un.h>
1437 #endif])
1438
1439 dnl Check for siginfo_t members
1440 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
1441
1442 dnl Check for struct option
1443 AC_CHECK_MEMBERS([struct option.name],,,
1444 [#ifdef HAVE_GETOPT_H
1445 #include <getopt.h>
1446 #endif])
1447
1448 dnl Check for stat.st_blocks
1449 AC_CHECK_MEMBERS([struct stat.st_blocks])
1450
1451 dnl *** check for the need to define platform-specific symbols
1452
1453 case $host_cpu in
1454   *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
1455   *alpha*)          WINE_CHECK_DEFINE([__ALPHA__]) ;;
1456   *sparc*)          WINE_CHECK_DEFINE([__sparc__]) ;;
1457   *powerpc*)        WINE_CHECK_DEFINE([__powerpc__]) ;;
1458 esac
1459
1460 case $host_vendor in
1461   *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
1462 esac
1463
1464 dnl **** Generate output files ****
1465
1466 AH_TOP([#define __WINE_CONFIG_H])
1467
1468 WINE_CONFIG_EXTRA_DIR(controls)
1469 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/d3ddevice)
1470 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dclipper)
1471 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/ddraw)
1472 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/direct3d)
1473 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dpalette)
1474 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dsurface)
1475 WINE_CONFIG_EXTRA_DIR(dlls/gdi/enhmfdrv)
1476 WINE_CONFIG_EXTRA_DIR(dlls/gdi/mfdrv)
1477 WINE_CONFIG_EXTRA_DIR(dlls/kernel/messages)
1478 WINE_CONFIG_EXTRA_DIR(dlls/user/dde)
1479 WINE_CONFIG_EXTRA_DIR(dlls/user/resources)
1480 WINE_CONFIG_EXTRA_DIR(dlls/wineps/data)
1481 WINE_CONFIG_EXTRA_DIR(include/wine)
1482 WINE_CONFIG_EXTRA_DIR(misc)
1483 WINE_CONFIG_EXTRA_DIR(programs/regedit/tests)
1484 WINE_CONFIG_EXTRA_DIR(windows)
1485
1486 MAKE_RULES=Make.rules
1487 AC_SUBST_FILE(MAKE_RULES)
1488
1489 MAKE_DLL_RULES=dlls/Makedll.rules
1490 AC_SUBST_FILE(MAKE_DLL_RULES)
1491
1492 MAKE_TEST_RULES=dlls/Maketest.rules
1493 AC_SUBST_FILE(MAKE_TEST_RULES)
1494
1495 MAKE_LIB_RULES=libs/Makelib.rules
1496 AC_SUBST_FILE(MAKE_LIB_RULES)
1497
1498 MAKE_PROG_RULES=programs/Makeprog.rules
1499 AC_SUBST_FILE(MAKE_PROG_RULES)
1500
1501 AC_CONFIG_FILES([
1502 Make.rules
1503 dlls/Makedll.rules
1504 dlls/Maketest.rules
1505 libs/Makelib.rules
1506 programs/Makeprog.rules
1507 Makefile
1508 dlls/Makefile
1509 dlls/advapi32/Makefile
1510 dlls/advapi32/tests/Makefile
1511 dlls/amstream/Makefile
1512 dlls/atl/Makefile
1513 dlls/avicap32/Makefile
1514 dlls/avifil32/Makefile
1515 dlls/cabinet/Makefile
1516 dlls/capi2032/Makefile
1517 dlls/cards/Makefile
1518 dlls/cfgmgr32/Makefile
1519 dlls/comcat/Makefile
1520 dlls/comctl32/Makefile
1521 dlls/comctl32/tests/Makefile
1522 dlls/commdlg/Makefile
1523 dlls/crtdll/Makefile
1524 dlls/crypt32/Makefile
1525 dlls/ctl3d/Makefile
1526 dlls/d3d8/Makefile
1527 dlls/d3d9/Makefile
1528 dlls/d3dim/Makefile
1529 dlls/d3drm/Makefile
1530 dlls/d3dx8/Makefile
1531 dlls/d3dxof/Makefile
1532 dlls/dbghelp/Makefile
1533 dlls/dciman32/Makefile
1534 dlls/ddraw/Makefile
1535 dlls/ddraw/tests/Makefile
1536 dlls/devenum/Makefile
1537 dlls/dinput/Makefile
1538 dlls/dinput8/Makefile
1539 dlls/dmband/Makefile
1540 dlls/dmcompos/Makefile
1541 dlls/dmime/Makefile
1542 dlls/dmloader/Makefile
1543 dlls/dmscript/Makefile
1544 dlls/dmstyle/Makefile
1545 dlls/dmsynth/Makefile
1546 dlls/dmusic/Makefile
1547 dlls/dmusic32/Makefile
1548 dlls/dplay/Makefile
1549 dlls/dplayx/Makefile
1550 dlls/dpnet/Makefile
1551 dlls/dpnhpast/Makefile
1552 dlls/dsound/Makefile
1553 dlls/dsound/tests/Makefile
1554 dlls/dswave/Makefile
1555 dlls/dxdiagn/Makefile
1556 dlls/dxerr8/Makefile
1557 dlls/dxerr9/Makefile
1558 dlls/dxguid/Makefile
1559 dlls/gdi/Makefile
1560 dlls/gdi/tests/Makefile
1561 dlls/glu32/Makefile
1562 dlls/glut32/Makefile
1563 dlls/hhctrl.ocx/Makefile
1564 dlls/iccvid/Makefile
1565 dlls/icmp/Makefile
1566 dlls/ifsmgr.vxd/Makefile
1567 dlls/imagehlp/Makefile
1568 dlls/imm32/Makefile
1569 dlls/iphlpapi/Makefile
1570 dlls/iphlpapi/tests/Makefile
1571 dlls/kernel/Makefile
1572 dlls/kernel/tests/Makefile
1573 dlls/lzexpand/Makefile
1574 dlls/mapi32/Makefile
1575 dlls/mapi32/tests/Makefile
1576 dlls/mlang/Makefile
1577 dlls/mlang/tests/Makefile
1578 dlls/mmdevldr.vxd/Makefile
1579 dlls/monodebg.vxd/Makefile
1580 dlls/mpr/Makefile
1581 dlls/msacm/Makefile
1582 dlls/msacm/imaadp32/Makefile
1583 dlls/msacm/msadp32/Makefile
1584 dlls/msacm/msg711/Makefile
1585 dlls/msacm/winemp3/Makefile
1586 dlls/msacm/tests/Makefile
1587 dlls/msdmo/Makefile
1588 dlls/mshtml/Makefile
1589 dlls/msi/Makefile
1590 dlls/msimg32/Makefile
1591 dlls/msisys/Makefile
1592 dlls/msnet32/Makefile
1593 dlls/msrle32/Makefile
1594 dlls/msvcrt/Makefile
1595 dlls/msvcrt/tests/Makefile
1596 dlls/msvcrt20/Makefile
1597 dlls/msvcrt40/Makefile
1598 dlls/msvcrtd/Makefile
1599 dlls/msvcrtd/tests/Makefile
1600 dlls/msvidc32/Makefile
1601 dlls/msvideo/Makefile
1602 dlls/mswsock/Makefile
1603 dlls/netapi32/Makefile
1604 dlls/netapi32/tests/Makefile
1605 dlls/newdev/Makefile
1606 dlls/ntdll/Makefile
1607 dlls/ntdll/tests/Makefile
1608 dlls/odbc32/Makefile
1609 dlls/ole32/Makefile
1610 dlls/ole32/tests/Makefile
1611 dlls/oleacc/Makefile
1612 dlls/oleaut32/Makefile
1613 dlls/oleaut32/tests/Makefile
1614 dlls/olecli/Makefile
1615 dlls/oledlg/Makefile
1616 dlls/olepro32/Makefile
1617 dlls/olesvr/Makefile
1618 dlls/opengl32/Makefile
1619 dlls/psapi/Makefile
1620 dlls/psapi/tests/Makefile
1621 dlls/qcap/Makefile
1622 dlls/quartz/Makefile
1623 dlls/rasapi32/Makefile
1624 dlls/richedit/Makefile
1625 dlls/rpcrt4/Makefile
1626 dlls/rpcrt4/tests/Makefile
1627 dlls/rsabase/Makefile
1628 dlls/rsabase/tests/Makefile
1629 dlls/secur32/Makefile
1630 dlls/serialui/Makefile
1631 dlls/setupapi/Makefile
1632 dlls/shdocvw/Makefile
1633 dlls/shell32/Makefile
1634 dlls/shell32/tests/Makefile
1635 dlls/shfolder/Makefile
1636 dlls/shlwapi/Makefile
1637 dlls/shlwapi/tests/Makefile
1638 dlls/snmpapi/Makefile
1639 dlls/sti/Makefile
1640 dlls/tapi32/Makefile
1641 dlls/ttydrv/Makefile
1642 dlls/twain/Makefile
1643 dlls/unicows/Makefile
1644 dlls/url/Makefile
1645 dlls/urlmon/Makefile
1646 dlls/urlmon/tests/Makefile
1647 dlls/user/Makefile
1648 dlls/user/tests/Makefile
1649 dlls/uuid/Makefile
1650 dlls/uxtheme/Makefile
1651 dlls/vdhcp.vxd/Makefile
1652 dlls/vdmdbg/Makefile
1653 dlls/version/Makefile
1654 dlls/version/tests/Makefile
1655 dlls/vmm.vxd/Makefile
1656 dlls/vnbt.vxd/Makefile
1657 dlls/vnetbios.vxd/Makefile
1658 dlls/vtdapi.vxd/Makefile
1659 dlls/vwin32.vxd/Makefile
1660 dlls/win32s/Makefile
1661 dlls/winaspi/Makefile
1662 dlls/wined3d/Makefile
1663 dlls/winedos/Makefile
1664 dlls/wineps/Makefile
1665 dlls/wininet/Makefile
1666 dlls/wininet/tests/Makefile
1667 dlls/winmm/Makefile
1668 dlls/winmm/joystick/Makefile
1669 dlls/winmm/mcianim/Makefile
1670 dlls/winmm/mciavi/Makefile
1671 dlls/winmm/mcicda/Makefile
1672 dlls/winmm/mciseq/Makefile
1673 dlls/winmm/mciwave/Makefile
1674 dlls/winmm/midimap/Makefile
1675 dlls/winmm/tests/Makefile
1676 dlls/winmm/wavemap/Makefile
1677 dlls/winmm/winealsa/Makefile
1678 dlls/winmm/winearts/Makefile
1679 dlls/winmm/wineaudioio/Makefile
1680 dlls/winmm/winejack/Makefile
1681 dlls/winmm/winenas/Makefile
1682 dlls/winmm/wineoss/Makefile
1683 dlls/winnls/Makefile
1684 dlls/winsock/Makefile
1685 dlls/winsock/tests/Makefile
1686 dlls/winspool/Makefile
1687 dlls/winspool/tests/Makefile
1688 dlls/wintab32/Makefile
1689 dlls/wintrust/Makefile
1690 dlls/wow32/Makefile
1691 dlls/wsock32/Makefile
1692 dlls/x11drv/Makefile
1693 documentation/Makefile
1694 include/Makefile
1695 libs/Makefile
1696 libs/port/Makefile
1697 libs/unicode/Makefile
1698 libs/wine/Makefile
1699 libs/wpp/Makefile
1700 loader/Makefile
1701 programs/Makefile
1702 programs/avitools/Makefile
1703 programs/clock/Makefile
1704 programs/cmdlgtst/Makefile
1705 programs/control/Makefile
1706 programs/expand/Makefile
1707 programs/msiexec/Makefile
1708 programs/notepad/Makefile
1709 programs/progman/Makefile
1710 programs/regedit/Makefile
1711 programs/regsvr32/Makefile
1712 programs/rpcss/Makefile
1713 programs/rundll32/Makefile
1714 programs/start/Makefile
1715 programs/taskmgr/Makefile
1716 programs/uninstaller/Makefile
1717 programs/view/Makefile
1718 programs/wcmd/Makefile
1719 programs/wineboot/Makefile
1720 programs/winebrowser/Makefile
1721 programs/winecfg/Makefile
1722 programs/wineconsole/Makefile
1723 programs/winedbg/Makefile
1724 programs/winefile/Makefile
1725 programs/winemenubuilder/Makefile
1726 programs/winemine/Makefile
1727 programs/winepath/Makefile
1728 programs/winetest/Makefile
1729 programs/winevdm/Makefile
1730 programs/winhelp/Makefile
1731 programs/winver/Makefile
1732 server/Makefile
1733 tools/Makefile
1734 tools/widl/Makefile
1735 tools/winapi/Makefile
1736 tools/winebuild/Makefile
1737 tools/winedump/Makefile
1738 tools/winegcc/Makefile
1739 tools/wmc/Makefile
1740 tools/wrc/Makefile])
1741
1742 AC_OUTPUT
1743
1744 if test "$have_x" = "no"
1745 then
1746   echo
1747   echo "*** Warning: X development files not found. Wine will be built without"
1748   echo "*** X support, which currently does not work, and would probably not be"
1749   echo "*** what you want anyway. You will need to install devel packages of"
1750   echo "*** Xlib/Xfree86 at the very least."
1751 fi
1752
1753 if test "$wine_cv_opengl_version_OK" = "no"
1754 then
1755   echo
1756   echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
1757   echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)."
1758 fi
1759
1760 if test "$wine_cv_msg_freetype" = "yes"
1761 then
1762   echo
1763   echo "*** Note: Your system appears to have the FreeType 2 runtime libraries"
1764   echo "*** installed, but 'freetype-config' is not in your PATH. Install the"
1765   echo "*** freetype-devel package (or its equivalent on your distribution) to"
1766   echo "*** enable Wine to use TrueType fonts."
1767 fi
1768
1769 echo
1770 echo "Configure finished.  Do 'make depend && make' to compile Wine."
1771 echo
1772
1773 dnl Local Variables:
1774 dnl comment-start: "dnl "
1775 dnl comment-end: ""
1776 dnl comment-start-skip: "\\bdnl\\b\\s *"
1777 dnl compile-command: "autoconf"
1778 dnl End: