git.oblomov.eu Git - wine/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Author: Michael Patra   <micky@marie.physik.tu-berlin.de>
   3 dnl                         <patra@itp1.physik.tu-berlin.de>
   4 AC_REVISION([configure.in 1.00])
   5 AC_INIT(controls/edit.c)
   6 AC_CONFIG_HEADER(include/config.h)
   7 AC_CONFIG_AUX_DIR(tools)
   8
   9 # We want these before the checks, so the checks can modify their values.
  10 LIBS="$LIBS -lm"
  11 test -z "$PROGEXT" && PROGEXT="" AC_SUBST(PROGEXT)
  12
  13 dnl **** Command-line arguments ****
  14
  15 dnl Default values
  16 MAIN_TARGET=emu
  17 LIB_TARGET=libwine.a
  18 ALT_LINK=" "
  19 TRACE_MSGS=yes  # the TRACE() macro
  20 DEBUG_MSGS=yes  # the TRACE(), WARN(), and FIXME() macros.
  21
  22 AC_ARG_ENABLE(emulator,
  23 [  --disable-emulator      build only the Wine library, not the emulator],
  24 [if test "$enableval" = "no"; then MAIN_TARGET="lib"; fi])
  25
  26 AC_ARG_ENABLE(dll,
  27 [  --enable-dll            build the Wine library as a DLL],
  28 [if test "$enableval" = "no"; then : ; else LIB_TARGET="libwine.so.1.0"; fi])
  29
  30 AC_ARG_ENABLE(lib,
  31 [  --disable-lib           build the Wine without building libwine.a],
  32 [if test "$enableval" = "no"; then ALT_LINK="\$(LIBOBJS)"; LIB_TARGET=""; fi])
  33
  34 dnl AC_ARG_WITH(ipc,
  35 dnl [  --enable-ipc            use inter-process communication for DDE],
  36 dnl [if test "$enableval" = "no"; then : ; else OPTIONS="-DCONFIG_IPC"; fi])
  37
  38 AC_ARG_ENABLE(debug,
  39 [  --disable-debug         compile out all debugging messages],
  40 [if test "$enableval" = "no"; then DEBUG_MSGS="no"; fi])
  41
  42 AC_ARG_ENABLE(trace,
  43 [  --disable-trace         compile out TRACE messages],
  44 [if test "$enableval" = "no"; then TRACE_MSGS="no"; fi])
  45
  46 AC_ARG_WITH(reentrant-x,
  47 [  --without-reentrant-x   Compile for use with non-reentrant X libraries])
  48
  49 AC_SUBST(MAIN_TARGET)
  50 AC_SUBST(LIB_TARGET)
  51 AC_SUBST(ALT_LINK)
  52 AC_SUBST(OPTIONS)
  53
  54 if test "$DEBUG_MSGS" = "no"
  55 then
  56     AC_DEFINE(NO_DEBUG_MSGS)
  57     AC_DEFINE(NO_TRACE_MSGS)
  58 else
  59     if test "$TRACE_MSGS" = "no"
  60     then
  61         AC_DEFINE(NO_TRACE_MSGS)
  62     fi
  63 fi
  64
  65 dnl **** Check for some programs ****
  66
  67 AC_PROG_MAKE_SET
  68 AC_PROG_CC
  69 AC_PROG_CPP
  70 AC_PATH_XTRA
  71 AC_PROG_YACC
  72 AC_PROG_LEX
  73 AC_PROG_RANLIB
  74 AC_PROG_INSTALL
  75 AC_PROG_LN_S
  76 AC_CHECK_PROG(C2MAN,c2man,c2man,true)
  77
  78 dnl **** Check for some libraries ****
  79
  80 dnl Check for -li386 for NetBSD and OpenBSD
  81 AC_CHECK_LIB(i386,i386_set_ldt)
  82 dnl Check for -lw for Solaris
  83 AC_CHECK_LIB(w,iswalnum)
  84 dnl Check for -lnsl for Solaris
  85 AC_CHECK_FUNCS(gethostbyname)
  86 if test "$ac_cv_func_gethostbyname" = "no"
  87 then
  88     AC_CHECK_LIB(nsl,gethostbyname)
  89 fi
  90 dnl Check for -lxpg4 for FreeBSD
  91 AC_CHECK_LIB(xpg4,setrunelocale)
  92 dnl Check for -ldl
  93 AC_CHECK_LIB(dl,dlopen)
  94 AC_SUBST(XLIB)
  95 if test "$have_x" = "yes"
  96 then
  97     XLIB="-lXpm -lXext -lX11"
  98     dnl Check for -lXpm
  99     dnl FIXME: should be done once we can compile without -lXpm
 100     dnl AC_CHECK_LIB(Xpm,XpmCreatePixmapFromData,AC_DEFINE(HAVE_LIBXXPM) X_PRE_LIBS="$X_PRE_LIBS -lXpm",,$X_LIBS -lXext -lX11)
 101     dnl Check for X Shm extension
 102     AC_CHECK_LIB(Xext,XShmQueryExtension,AC_DEFINE(HAVE_LIBXXSHM),,$X_LIBS -lXext -lX11)
 103     dnl Check for XFree86 DGA extension
 104     AC_CHECK_LIB(Xxf86dga,XF86DGAQueryExtension,AC_DEFINE(HAVE_LIBXXF86DGA) X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga",,$X_LIBS -lXext -lX11)
 105 else
 106     XLIB=""
 107     X_CFLAGS=""
 108     X_LIBS=""
 109 fi
 110
 111 dnl **** Check for Open Sound System ****
 112 AC_CHECK_HEADERS(sys/soundcard.h machine/soundcard.h)
 113
 114 AC_CACHE_CHECK("for Open Sound System",
 115         ac_cv_c_opensoundsystem,
 116         AC_TRY_COMPILE([
 117         #ifdef HAVE_SYS_SOUNDCARD_H
 118                 #include <sys/soundcard.h>
 119         #endif
 120         #ifdef HAVE_MACHINE_SOUNDCARD_H
 121                 #include <machine/soundcard.h>
 122         #endif
 123         ],[
 124
 125 /* check for one of the Open Sound System specific SNDCTL_ defines */
 126 #if !defined(SNDCTL_DSP_STEREO)
 127 #error No open sound system
 128 #endif
 129 ],ac_cv_c_opensoundsystem="yes",ac_cv_c_opensoundsystem="no"))
 130
 131 if test "$ac_cv_c_opensoundsystem" = "yes"
 132 then
 133     AC_DEFINE(HAVE_OSS)
 134 fi
 135
 136 dnl **** Check for union semun ****
 137
 138 AC_CACHE_CHECK("for union semun", ac_cv_c_union_semun,
 139  AC_TRY_COMPILE([#include <sys/types.h>
 140 #include <sys/sem.h>],[union semun foo],
 141                 ac_cv_c_union_semun="yes", ac_cv_c_union_semun="no"))
 142 if test "$ac_cv_c_union_semun" = "yes"
 143 then
 144     AC_DEFINE(HAVE_UNION_SEMUN)
 145 fi
 146
 147 dnl **** If ln -s doesn't work, use cp instead ****
 148 if test "$ac_cv_prog_LN_S" = "ln -s"; then : ; else LN_S=cp ; fi
 149
 150 dnl **** Check for gcc strength-reduce bug ****
 151
 152 if test "x${GCC}" = "xyes"
 153 then
 154   CFLAGS="$CFLAGS -Wall"
 155   AC_CACHE_CHECK( "for gcc strength-reduce bug", ac_cv_c_gcc_strength_bug,
 156                   AC_TRY_RUN([
 157 int main(void) {
 158   static int Array[[3]];
 159   unsigned int B = 3;
 160   int i;
 161   for(i=0; i<B; i++) Array[[i]] = i - 3;
 162   exit( Array[[1]] != -2 );
 163 }],
 164     ac_cv_c_gcc_strength_bug="no",
 165     ac_cv_c_gcc_strength_bug="yes",
 166     ac_cv_c_gcc_strength_bug="yes") )
 167   if test "$ac_cv_c_gcc_strength_bug" = "yes"
 168   then
 169     CFLAGS="$CFLAGS -fno-strength-reduce"
 170   fi
 171 fi
 172
 173 dnl **** Check for underscore on external symbols ****
 174
 175 AC_CACHE_CHECK("whether external symbols need an underscore prefix",
 176                ac_cv_c_extern_prefix,
 177 [saved_libs=$LIBS
 178 LIBS="conftest_asm.s $LIBS"
 179 cat > conftest_asm.s <<EOF
 180         .globl _ac_test
 181 _ac_test:
 182         .long 0
 183 EOF
 184 AC_TRY_LINK([extern int ac_test;],[if (ac_test) return 1],
 185             ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no")
 186 LIBS=$saved_libs])
 187 if test "$ac_cv_c_extern_prefix" = "yes"
 188 then
 189   AC_DEFINE(NEED_UNDERSCORE_PREFIX)
 190 fi
 191
 192 dnl **** Check for .string in assembler ****
 193
 194 AC_CACHE_CHECK("whether assembler accepts .string",
 195                ac_cv_c_asm_string,
 196 [saved_libs=$LIBS
 197 LIBS="conftest_asm.s $LIBS"
 198 cat > conftest_asm.s <<EOF
 199         .string "test"
 200 EOF
 201 AC_TRY_LINK(,,ac_cv_c_asm_string="yes",ac_cv_c_asm_string="no")
 202 LIBS=$saved_libs])
 203 if test "$ac_cv_c_asm_string" = "yes"
 204 then
 205   AC_DEFINE(HAVE_ASM_STRING)
 206 fi
 207
 208 dnl **** Check for working dll ****
 209
 210 DLLFLAGS=""
 211 if test "$LIB_TARGET" = "libwine.so.1.0"
 212 then
 213   AC_CACHE_CHECK("whether we can build a dll",
 214                  ac_cv_c_dll,
 215   [saved_cflags=$CFLAGS
 216   CFLAGS="$CFLAGS -fPIC -shared -Wl,-soname,conftest.so.1.0"
 217   AC_TRY_LINK(,[return 1],ac_cv_c_dll="yes",ac_cv_c_dll="no")
 218   CFLAGS=$saved_cflags
 219   ])
 220   if test "$ac_cv_c_dll" = "yes"
 221   then
 222     DLLFLAGS="-fPIC"
 223   else
 224     LIB_TARGET="libwine.a"
 225   fi
 226 fi
 227 AC_SUBST(DLLFLAGS)
 228
 229 dnl **** Check for reentrant libc ****
 230 dnl
 231 dnl For cross-compiling we blindly assume that libc is reentrant. This is
 232 dnl ok since non-reentrant libc is quite rare (mostly old libc5 versions).
 233
 234 AC_CACHE_CHECK("for reentrant libc", wine_cv_libc_reentrant,
 235   [AC_TRY_RUN([int myerrno = 0;
 236 char buf[256];
 237 int *__errno_location(){return &myerrno;}
 238 main(){connect(0,buf,255); exit(!myerrno);}],
 239   wine_cv_libc_reentrant=yes, wine_cv_libc_reentrant=no,
 240   wine_cv_libc_reentrant=yes ) ] )
 241 if test "$wine_cv_libc_reentrant" = "no"
 242 then
 243   AC_DEFINE(NO_REENTRANT_LIBC)
 244 fi
 245
 246 dnl **** Check for reentrant X libraries ****
 247 dnl
 248 dnl This may fail to determine whether X libraries are reentrant if
 249 dnl AC_PATH_XTRA does not set x_libraries. In this case manual configuration
 250 dnl is possible with the --without-reentrant-x option.
 251
 252 AC_CACHE_CHECK( "for reentrant X libraries", wine_cv_x_reentrant,
 253   [ if test "x$with_reentrant_x" = "xno"
 254     then
 255         wine_cv_x_reentrant=no
 256     else
 257         libX11_ckeck=none
 258         for dir in "$x_libraries" /usr/lib /usr/local/lib /lib; do
 259             if test -r $dir/libX11.so; then
 260                 libX11_check="-D $dir/libX11.so"
 261                 break 1
 262             fi
 263             if test -r $dir/libX11.a; then
 264                 libX11_check="$dir/libX11.a"
 265                 break 1
 266             fi
 267         done
 268         if test "$libX11_check" != "none"; then
 269             if nm $libX11_check | grep __errno_location >/dev/null 2>&1
 270             then
 271                 wine_cv_x_reentrant=yes
 272             else
 273                 wine_cv_x_reentrant=no
 274             fi
 275         else
 276             wine_cv_x_reentrant=unknown
 277         fi
 278     fi ] )
 279 if test "$wine_cv_x_reentrant" = "no"
 280 then
 281   AC_DEFINE(NO_REENTRANT_X11)
 282 fi
 283
 284 dnl **** Check for functions and header files ****
 285
 286 AC_CHECK_FUNCS(clone getpagesize memmove sendmsg sigaltstack strerror stricmp tcgetattr timegm usleep wait4 waitpid vfscanf)
 287 AC_CHECK_HEADERS(wctype.h sys/syscall.h syscall.h sys/param.h sys/vfs.h sys/mount.h sys/statfs.h float.h linux/cdrom.h linux/ucdrom.h sys/cdio.h sys/filio.h sys/modem.h strings.h sys/strtio.h dlfcn.h)
 288 AC_HEADER_STAT()
 289 AC_C_CONST()
 290 AC_TYPE_SIZE_T()
 291 AC_CHECK_SIZEOF(long long,0)
 292
 293 dnl **** Check for sendmsg in -lsocket if not found above ****
 294
 295 if test $ac_cv_func_sendmsg = no; then
 296     AC_CHECK_LIB(socket,sendmsg)
 297 fi
 298
 299 dnl **** statfs checks ****
 300
 301 if test "$ac_cv_header_sys_vfs_h" = "yes"
 302 then
 303     AC_CACHE_CHECK( "whether sys/vfs.h defines statfs",
 304                     wine_cv_sys_vfs_has_statfs,
 305         AC_TRY_COMPILE([
 306         #include <sys/types.h>
 307         #ifdef HAVE_SYS_PARAM_H
 308         # include <sys/param.h>
 309         #endif
 310         #include <sys/vfs.h>
 311         ],[
 312                 struct statfs stfs;
 313
 314                 memset(&stfs,0,sizeof(stfs));
 315         ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
 316         )
 317     )
 318     if test "$wine_cv_sys_vfs_has_statfs" = "yes"
 319     then
 320       AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS)
 321     fi
 322 fi
 323
 324 if test "$ac_cv_header_sys_statfs_h" = "yes"
 325 then
 326     AC_CACHE_CHECK( "whether sys/statfs.h defines statfs",
 327                     wine_cv_sys_statfs_has_statfs,
 328         AC_TRY_COMPILE([
 329         #include <sys/types.h>
 330         #ifdef HAVE_SYS_PARAM_H
 331         # include <sys/param.h>
 332         #endif
 333         #include <sys/statfs.h>
 334         ],[
 335                 struct statfs stfs;
 336         ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
 337         )
 338     )
 339     if test "$wine_cv_sys_statfs_has_statfs" = "yes"
 340     then
 341       AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS)
 342     fi
 343 fi
 344
 345 if test "$ac_cv_header_sys_mount_h" = "yes"
 346 then
 347     AC_CACHE_CHECK( "whether sys/mount.h defines statfs",
 348                     wine_cv_sys_mount_has_statfs,
 349         AC_TRY_COMPILE([
 350         #include <sys/types.h>
 351         #ifdef HAVE_SYS_PARAM_H
 352         # include <sys/param.h>
 353         #endif
 354         #include <sys/mount.h>
 355         ],[
 356                 struct statfs stfs;
 357         ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
 358         )
 359     )
 360     if test "$wine_cv_sys_mount_has_statfs" = "yes"
 361     then
 362       AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT)
 363     fi
 364 fi
 365
 366 dnl **** FIXME: what about mixed cases, where we need two of them? ***
 367
 368 AC_CACHE_CHECK( "for statfs.f_bfree", wine_cv_statfs_bfree,
 369   [ if test "x$statfs_bfree" = "xno"
 370     then
 371         wine_cv_statfs_bfree=no
 372     else
 373         AC_TRY_COMPILE([
 374         #include <sys/types.h>
 375         #ifdef HAVE_SYS_PARAM_H
 376         # include <sys/param.h>
 377         #endif
 378         #ifdef STATFS_DEFINED_BY_SYS_MOUNT
 379         # include <sys/mount.h>
 380         #else
 381         # ifdef STATFS_DEFINED_BY_SYS_VFS
 382         #  include <sys/vfs.h>
 383         # else
 384         #  ifdef STATFS_DEFINED_BY_SYS_STATFS
 385         #   include <sys/statfs.h>
 386         #  endif
 387         # endif
 388         #endif
 389         ],[
 390                 struct statfs stfs;
 391
 392                 stfs.f_bfree++;
 393         ],wine_cv_statfs_bfree=yes,wine_cv_statfs_bfree=no
 394         )
 395     fi ] )
 396 if test "$wine_cv_statfs_bfree" = "yes"
 397 then
 398   AC_DEFINE(STATFS_HAS_BFREE)
 399 fi
 400
 401 AC_CACHE_CHECK( "for statfs.f_bavail", wine_cv_statfs_bavail,
 402   [ if test "x$statfs_bavail" = "xno"
 403     then
 404         wine_cv_statfs_bavail=no
 405     else
 406         AC_TRY_COMPILE([
 407         #include <sys/types.h>
 408         #ifdef HAVE_SYS_PARAM_H
 409         # include <sys/param.h>
 410         #endif
 411         #ifdef STATFS_DEFINED_BY_SYS_MOUNT
 412         # include <sys/mount.h>
 413         #else
 414         # ifdef STATFS_DEFINED_BY_SYS_VFS
 415         #  include <sys/vfs.h>
 416         # else
 417         #  ifdef STATFS_DEFINED_BY_SYS_STATFS
 418         #   include <sys/statfs.h>
 419         #  endif
 420         # endif
 421         #endif
 422         ],[
 423                 struct statfs stfs;
 424
 425                 stfs.f_bavail++;
 426         ],wine_cv_statfs_bavail=yes,wine_cv_statfs_bavail=no
 427         )
 428     fi ] )
 429 if test "$wine_cv_statfs_bavail" = "yes"
 430 then
 431   AC_DEFINE(STATFS_HAS_BAVAIL)
 432 fi
 433
 434 dnl *** check for working sigaltstack
 435 dnl glibc 2.0x defines it, but it always fails... so it is useless for us.
 436
 437 AC_CACHE_CHECK("for working sigaltstack",
 438         ac_cv_c_working_sigaltstack,
 439         AC_TRY_RUN([
 440         #include <stdio.h>
 441         #include <time.h> /* <sys/time.h> ? bad magic without end */
 442         #include <sys/types.h>
 443         #include <sys/signal.h>
 444         #ifdef HAVE_SYS_PARAM_H
 445         # include <sys/param.h>
 446         #endif
 447         #ifdef HAVE_SYSCALL_H
 448         # include <syscall.h>
 449         #else
 450         # ifdef HAVE_SYS_SYSCALL_H
 451         #  include <sys/syscall.h>
 452         # endif
 453         #endif
 454
 455         unsigned char *xaltstack;
 456
 457         int
 458         main(int argc,char **argv) {
 459             struct sigaltstack  ss;
 460
 461             xaltstack = malloc(16384);
 462             ss.ss_sp    = xaltstack;
 463             ss.ss_size  = 16384;
 464             ss.ss_flags = 0;
 465             if (sigaltstack(&ss, NULL) < 0) {
 466                 /* this catches the glibc case */
 467                 perror("sigaltstack");
 468                 return (1); /* aka exit(1) aka fail */
 469             }
 470             /* assume it works. */
 471             return 0; /* OK */
 472         }
 473         ],
 474         ac_cv_c_working_sigaltstack="yes",
 475         ac_cv_c_working_sigaltstack="no",
 476         ac_cv_c_working_sigaltstack="no"
 477 ))
 478
 479 if test "$ac_cv_c_working_sigaltstack" = "yes"
 480 then
 481     AC_DEFINE(HAVE_WORKING_SIGALTSTACK)
 482 fi
 483
 484
 485 dnl *** check for file descriptor passing with msg_accrights
 486
 487 AC_CACHE_CHECK("for msg_accrights in struct msghdr", ac_cv_c_msg_accrights,
 488  AC_TRY_COMPILE([#include <sys/types.h>
 489 #include <sys/socket.h>],[struct msghdr hdr; hdr.msg_accrights=0],
 490                 ac_cv_c_msg_accrights="yes", ac_cv_c_msg_accrights="no"))
 491 if test "$ac_cv_c_msg_accrights" = "yes"
 492 then
 493     AC_DEFINE(HAVE_MSGHDR_ACCRIGHTS)
 494 fi
 495
 496 dnl **** Generate output files ****
 497
 498 MAKE_RULES=Make.rules
 499 AC_SUBST_FILE(MAKE_RULES)
 500
 501 AC_OUTPUT([
 502 Make.rules
 503 Makefile
 504 controls/Makefile
 505 debugger/Makefile
 506 dlls/Makefile
 507 dlls/comctl32/Makefile
 508 dlls/imagehlp/Makefile
 509 dlls/msacm/Makefile
 510 dlls/msacm32/Makefile
 511 dlls/ntdll/Makefile
 512 dlls/psapi/Makefile
 513 dlls/shell32/Makefile
 514 dlls/winaspi/Makefile
 515 dlls/wnaspi32/Makefile
 516 documentation/Makefile
 517 files/Makefile
 518 graphics/Makefile
 519 graphics/metafiledrv/Makefile
 520 graphics/psdrv/Makefile
 521 graphics/win16drv/Makefile
 522 graphics/x11drv/Makefile
 523 if1632/Makefile
 524 ipc/Makefile
 525 library/Makefile
 526 libtest/Makefile
 527 loader/Makefile
 528 loader/ne/Makefile
 529 loader/dos/Makefile
 530 memory/Makefile
 531 misc/Makefile
 532 miscemu/Makefile
 533 msdos/Makefile
 534 multimedia/Makefile
 535 objects/Makefile
 536 ole/Makefile
 537 programs/Makefile
 538 programs/clock/Makefile
 539 programs/control/Makefile
 540 programs/notepad/Makefile
 541 programs/progman/Makefile
 542 programs/regtest/Makefile
 543 programs/view/Makefile
 544 programs/winhelp/Makefile
 545 programs/winver/Makefile
 546 rc/Makefile
 547 relay32/Makefile
 548 resources/Makefile
 549 scheduler/Makefile
 550 server/Makefile
 551 tools/Makefile
 552 tools/wrc/Makefile
 553 tsx11/Makefile
 554 win32/Makefile
 555 windows/Makefile
 556 windows/x11drv/Makefile ])
 557
 558 if test "$wine_cv_libc_reentrant" = "no"
 559 then
 560   echo
 561   echo "*** Warning: non-reentrant libc detected. Wine will be build without"
 562   echo "*** thread support. Consider upgrading libc to a more recent"
 563   echo "*** reentrant version of libc."
 564   echo
 565 fi
 566
 567 echo
 568 echo "Configure finished.  Do 'make depend; make' to compile Wine."
 569 echo
 570
 571 dnl Local Variables:
 572 dnl comment-start: "dnl "
 573 dnl comment-end: ""
 574 dnl comment-start-skip: "\\bdnl\\b\\s *"
 575 dnl compile-command: "autoconf"
 576 dnl End: