git.oblomov.eu Git - wine/blob - tools/widl/parser.y

   1 %{
   2 /*
   3  * IDL Compiler
   4  *
   5  * Copyright 2002 Ove Kaaven
   6  *
   7  * This library is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU Lesser General Public
   9  * License as published by the Free Software Foundation; either
  10  * version 2.1 of the License, or (at your option) any later version.
  11  *
  12  * This library is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  15  * Lesser General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU Lesser General Public
  18  * License along with this library; if not, write to the Free Software
  19  * Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA
  20  */
  21
  22 #include "config.h"
  23
  24 #include <stdio.h>
  25 #include <stdlib.h>
  26 #include <stdarg.h>
  27 #include <assert.h>
  28 #include <ctype.h>
  29 #include <string.h>
  30 #ifdef HAVE_ALLOCA_H
  31 #include <alloca.h>
  32 #endif
  33
  34 #include "windef.h"
  35
  36 #include "widl.h"
  37 #include "utils.h"
  38 #include "parser.h"
  39 #include "header.h"
  40 #include "typelib.h"
  41 #include "typegen.h"
  42
  43 #if defined(YYBYACC)
  44         /* Berkeley yacc (byacc) doesn't seem to know about these */
  45         /* Some *BSD supplied versions do define these though */
  46 # ifndef YYEMPTY
  47 #  define YYEMPTY       (-1)    /* Empty lookahead value of yychar */
  48 # endif
  49 # ifndef YYLEX
  50 #  define YYLEX         yylex()
  51 # endif
  52
  53 #elif defined(YYBISON)
  54         /* Bison was used for original development */
  55         /* #define YYEMPTY -2 */
  56         /* #define YYLEX   yylex() */
  57
  58 #else
  59         /* No yacc we know yet */
  60 # if !defined(YYEMPTY) || !defined(YYLEX)
  61 #  error Yacc version/type unknown. This version needs to be verified for settings of YYEMPTY and YYLEX.
  62 # elif defined(__GNUC__)        /* gcc defines the #warning directive */
  63 #  warning Yacc version/type unknown. It defines YYEMPTY and YYLEX, but is not tested
  64   /* #else we just take a chance that it works... */
  65 # endif
  66 #endif
  67
  68 unsigned char pointer_default = RPC_FC_UP;
  69
  70 typedef struct list typelist_t;
  71 struct typenode {
  72   type_t *type;
  73   struct list entry;
  74 };
  75
  76 typelist_t incomplete_types = LIST_INIT(incomplete_types);
  77
  78 static void add_incomplete(type_t *t);
  79 static void fix_incomplete(void);
  80
  81 static str_list_t *append_str(str_list_t *list, char *str);
  82 static attr_list_t *append_attr(attr_list_t *list, attr_t *attr);
  83 static attr_t *make_attr(enum attr_type type);
  84 static attr_t *make_attrv(enum attr_type type, unsigned long val);
  85 static attr_t *make_attrp(enum attr_type type, void *val);
  86 static expr_t *make_expr(enum expr_type type);
  87 static expr_t *make_exprl(enum expr_type type, long val);
  88 static expr_t *make_exprd(enum expr_type type, double val);
  89 static expr_t *make_exprs(enum expr_type type, char *val);
  90 static expr_t *make_exprt(enum expr_type type, type_t *tref, expr_t *expr);
  91 static expr_t *make_expr1(enum expr_type type, expr_t *expr);
  92 static expr_t *make_expr2(enum expr_type type, expr_t *exp1, expr_t *exp2);
  93 static expr_t *make_expr3(enum expr_type type, expr_t *expr1, expr_t *expr2, expr_t *expr3);
  94 static type_t *make_type(unsigned char type, type_t *ref);
  95 static expr_list_t *append_expr(expr_list_t *list, expr_t *expr);
  96 static array_dims_t *append_array(array_dims_t *list, expr_t *expr);
  97 static void set_type(var_t *v, type_t *type, int ptr_level, array_dims_t *arr, int top);
  98 static ifref_list_t *append_ifref(ifref_list_t *list, ifref_t *iface);
  99 static ifref_t *make_ifref(type_t *iface);
 100 static var_list_t *append_var(var_list_t *list, var_t *var);
 101 static var_t *make_var(char *name);
 102 static pident_list_t *append_pident(pident_list_t *list, pident_t *p);
 103 static pident_t *make_pident(var_t *var);
 104 static func_list_t *append_func(func_list_t *list, func_t *func);
 105 static func_t *make_func(var_t *def, var_list_t *args);
 106 static type_t *make_class(char *name);
 107 static type_t *make_safearray(type_t *type);
 108 static type_t *make_builtin(char *name);
 109 static type_t *make_int(int sign);
 110
 111 static type_t *reg_type(type_t *type, const char *name, int t);
 112 static type_t *reg_typedefs(type_t *type, var_list_t *names, attr_list_t *attrs);
 113 static type_t *find_type(const char *name, int t);
 114 static type_t *find_type2(char *name, int t);
 115 static type_t *get_type(unsigned char type, char *name, int t);
 116 static type_t *get_typev(unsigned char type, var_t *name, int t);
 117 static int get_struct_type(var_list_t *fields);
 118
 119 static var_t *reg_const(var_t *var);
 120 static var_t *find_const(char *name, int f);
 121
 122 static void write_libid(const char *name, const attr_list_t *attr);
 123 static void write_clsid(type_t *cls);
 124 static void write_diid(type_t *iface);
 125 static void write_iid(type_t *iface);
 126
 127 static int compute_method_indexes(type_t *iface);
 128 static char *gen_name(void);
 129 static void process_typedefs(var_list_t *names);
 130 static void check_arg(var_t *arg);
 131 static void check_all_user_types(ifref_list_t *ifaces);
 132
 133 #define tsENUM   1
 134 #define tsSTRUCT 2
 135 #define tsUNION  3
 136
 137 %}
 138 %union {
 139         attr_t *attr;
 140         attr_list_t *attr_list;
 141         str_list_t *str_list;
 142         expr_t *expr;
 143         expr_list_t *expr_list;
 144         array_dims_t *array_dims;
 145         type_t *type;
 146         var_t *var;
 147         var_list_t *var_list;
 148         pident_t *pident;
 149         pident_list_t *pident_list;
 150         func_t *func;
 151         func_list_t *func_list;
 152         ifref_t *ifref;
 153         ifref_list_t *ifref_list;
 154         char *str;
 155         UUID *uuid;
 156         unsigned int num;
 157         double dbl;
 158         interface_info_t ifinfo;
 159 }
 160
 161 %token <str> aIDENTIFIER
 162 %token <str> aKNOWNTYPE
 163 %token <num> aNUM aHEXNUM
 164 %token <dbl> aDOUBLE
 165 %token <str> aSTRING
 166 %token <uuid> aUUID
 167 %token aEOF
 168 %token SHL SHR
 169 %token tAGGREGATABLE tALLOCATE tAPPOBJECT tASYNC tASYNCUUID
 170 %token tAUTOHANDLE tBINDABLE tBOOLEAN tBROADCAST tBYTE tBYTECOUNT
 171 %token tCALLAS tCALLBACK tCASE tCDECL tCHAR tCOCLASS tCODE tCOMMSTATUS
 172 %token tCONST tCONTEXTHANDLE tCONTEXTHANDLENOSERIALIZE
 173 %token tCONTEXTHANDLESERIALIZE tCONTROL tCPPQUOTE
 174 %token tDEFAULT
 175 %token tDEFAULTCOLLELEM
 176 %token tDEFAULTVALUE
 177 %token tDEFAULTVTABLE
 178 %token tDISPLAYBIND
 179 %token tDISPINTERFACE
 180 %token tDLLNAME tDOUBLE tDUAL
 181 %token tENDPOINT
 182 %token tENTRY tENUM tERRORSTATUST
 183 %token tEXPLICITHANDLE tEXTERN
 184 %token tFALSE
 185 %token tFLOAT
 186 %token tHANDLE
 187 %token tHANDLET
 188 %token tHELPCONTEXT tHELPFILE
 189 %token tHELPSTRING tHELPSTRINGCONTEXT tHELPSTRINGDLL
 190 %token tHIDDEN
 191 %token tHYPER tID tIDEMPOTENT
 192 %token tIIDIS
 193 %token tIMMEDIATEBIND
 194 %token tIMPLICITHANDLE
 195 %token tIMPORT tIMPORTLIB
 196 %token tIN tINLINE
 197 %token tINPUTSYNC
 198 %token tINT tINT64
 199 %token tINTERFACE
 200 %token tLCID
 201 %token tLENGTHIS tLIBRARY
 202 %token tLOCAL
 203 %token tLONG
 204 %token tMETHODS
 205 %token tMODULE
 206 %token tNONBROWSABLE
 207 %token tNONCREATABLE
 208 %token tNONEXTENSIBLE
 209 %token tOBJECT tODL tOLEAUTOMATION
 210 %token tOPTIONAL
 211 %token tOUT
 212 %token tPOINTERDEFAULT
 213 %token tPROPERTIES
 214 %token tPROPGET tPROPPUT tPROPPUTREF
 215 %token tPTR
 216 %token tPUBLIC
 217 %token tRANGE
 218 %token tREADONLY tREF
 219 %token tREQUESTEDIT
 220 %token tRESTRICTED
 221 %token tRETVAL
 222 %token tSAFEARRAY
 223 %token tSHORT
 224 %token tSIGNED
 225 %token tSINGLE
 226 %token tSIZEIS tSIZEOF
 227 %token tSMALL
 228 %token tSOURCE
 229 %token tSTDCALL
 230 %token tSTRING tSTRUCT
 231 %token tSWITCH tSWITCHIS tSWITCHTYPE
 232 %token tTRANSMITAS
 233 %token tTRUE
 234 %token tTYPEDEF
 235 %token tUNION
 236 %token tUNIQUE
 237 %token tUNSIGNED
 238 %token tUUID
 239 %token tV1ENUM
 240 %token tVARARG
 241 %token tVERSION
 242 %token tVOID
 243 %token tWCHAR tWIREMARSHAL
 244
 245 %type <attr> attribute
 246 %type <attr_list> m_attributes attributes attrib_list
 247 %type <str_list> str_list
 248 %type <expr> m_expr expr expr_const
 249 %type <expr_list> m_exprs /* exprs expr_list */ expr_list_const
 250 %type <array_dims> array array_list
 251 %type <ifinfo> interfacehdr
 252 %type <type> inherit interface interfacedef interfacedec
 253 %type <type> dispinterface dispinterfacehdr dispinterfacedef
 254 %type <type> module modulehdr moduledef
 255 %type <type> base_type int_std
 256 %type <type> enumdef structdef uniondef
 257 %type <type> type
 258 %type <ifref> coclass_int
 259 %type <ifref_list> gbl_statements coclass_ints
 260 %type <var> arg field s_field case enum constdef externdef
 261 %type <var_list> m_args no_args args fields cases enums enum_list dispint_props
 262 %type <var> m_ident t_ident ident
 263 %type <pident> p_ident pident
 264 %type <pident_list> pident_list
 265 %type <func> funcdef
 266 %type <func_list> int_statements dispint_meths
 267 %type <type> coclass coclasshdr coclassdef
 268 %type <num> pointer_type version
 269 %type <str> libraryhdr
 270 %type <uuid> uuid_string
 271
 272 %left ','
 273 %right '?' ':'
 274 %left '|'
 275 %left '&'
 276 %left '-' '+'
 277 %left '*' '/'
 278 %left SHL SHR
 279 %right '~'
 280 %right CAST
 281 %right PPTR
 282 %right NEG
 283
 284 %%
 285
 286 input:   gbl_statements                         { fix_incomplete();
 287                                                   check_all_user_types($1);
 288                                                   write_proxies($1);
 289                                                   write_client($1);
 290                                                   write_server($1);
 291                                                   write_dlldata($1);
 292                                                 }
 293         ;
 294
 295 gbl_statements:                                 { $$ = NULL; }
 296         | gbl_statements interfacedec           { $$ = $1; }
 297         | gbl_statements interfacedef           { $$ = append_ifref( $1, make_ifref($2) ); }
 298         | gbl_statements coclass ';'            { $$ = $1;
 299                                                   reg_type($2, $2->name, 0);
 300                                                   if (!parse_only && do_header) write_coclass_forward($2);
 301                                                 }
 302         | gbl_statements coclassdef             { $$ = $1;
 303                                                   add_typelib_entry($2);
 304                                                   reg_type($2, $2->name, 0);
 305                                                   if (!parse_only && do_header) write_coclass_forward($2);
 306                                                 }
 307         | gbl_statements moduledef              { $$ = $1; add_typelib_entry($2); }
 308         | gbl_statements librarydef             { $$ = $1; }
 309         | gbl_statements statement              { $$ = $1; }
 310         ;
 311
 312 imp_statements:                                 {}
 313         | imp_statements interfacedec           { if (!parse_only) add_typelib_entry($2); }
 314         | imp_statements interfacedef           { if (!parse_only) add_typelib_entry($2); }
 315         | imp_statements coclass ';'            { reg_type($2, $2->name, 0); if (!parse_only && do_header) write_coclass_forward($2); }
 316         | imp_statements coclassdef             { if (!parse_only) add_typelib_entry($2);
 317                                                   reg_type($2, $2->name, 0);
 318                                                   if (!parse_only && do_header) write_coclass_forward($2);
 319                                                 }
 320         | imp_statements moduledef              { if (!parse_only) add_typelib_entry($2); }
 321         | imp_statements statement              {}
 322         | imp_statements importlib              {}
 323         ;
 324
 325 int_statements:                                 { $$ = NULL; }
 326         | int_statements funcdef ';'            { $$ = append_func( $1, $2 ); }
 327         | int_statements statement              { $$ = $1; }
 328         ;
 329
 330 statement: ';'                                  {}
 331         | constdef ';'                          { if (!parse_only && do_header) { write_constdef($1); } }
 332         | cppquote                              {}
 333         | enumdef ';'                           { if (!parse_only && do_header) {
 334                                                     write_type_def_or_decl(header, $1, FALSE, NULL);
 335                                                     fprintf(header, ";\n\n");
 336                                                   }
 337                                                 }
 338         | externdef ';'                         { if (!parse_only && do_header) { write_externdef($1); } }
 339         | import                                {}
 340         | structdef ';'                         { if (!parse_only && do_header) {
 341                                                     write_type_def_or_decl(header, $1, FALSE, NULL);
 342                                                     fprintf(header, ";\n\n");
 343                                                   }
 344                                                 }
 345         | typedef ';'                           {}
 346         | uniondef ';'                          { if (!parse_only && do_header) {
 347                                                     write_type_def_or_decl(header, $1, FALSE, NULL);
 348                                                     fprintf(header, ";\n\n");
 349                                                   }
 350                                                 }
 351         ;
 352
 353 cppquote: tCPPQUOTE '(' aSTRING ')'             { if (!parse_only && do_header) fprintf(header, "%s\n", $3); }
 354         ;
 355 import_start: tIMPORT aSTRING ';'               { assert(yychar == YYEMPTY);
 356                                                   if (!do_import($2)) yychar = aEOF; }
 357         ;
 358 import:   import_start imp_statements aEOF      {}
 359         ;
 360
 361 importlib: tIMPORTLIB '(' aSTRING ')'           { if(!parse_only) add_importlib($3); }
 362         ;
 363
 364 libraryhdr: tLIBRARY aIDENTIFIER                { $$ = $2; }
 365         ;
 366 library_start: attributes libraryhdr '{'        { start_typelib($2, $1);
 367                                                   if (!parse_only && do_header) write_library($2, $1);
 368                                                   if (!parse_only && do_idfile) write_libid($2, $1);
 369                                                 }
 370         ;
 371 librarydef: library_start imp_statements '}'    { end_typelib(); }
 372         ;
 373
 374 m_args:                                         { $$ = NULL; }
 375         | args
 376         ;
 377
 378 no_args:  tVOID                                 { $$ = NULL; }
 379         ;
 380
 381 args:     arg                                   { check_arg($1); $$ = append_var( NULL, $1 ); }
 382         | args ',' arg                          { check_arg($3); $$ = append_var( $1, $3); }
 383         | no_args
 384         ;
 385
 386 /* split into two rules to get bison to resolve a tVOID conflict */
 387 arg:      attributes type pident array          { $$ = $3->var;
 388                                                   $$->attrs = $1;
 389                                                   set_type($$, $2, $3->ptr_level, $4, TRUE);
 390                                                   free($3);
 391                                                 }
 392         | type pident array                     { $$ = $2->var;
 393                                                   set_type($$, $1, $2->ptr_level, $3, TRUE);
 394                                                   free($2);
 395                                                 }
 396         | attributes type pident '(' m_args ')' { $$ = $3->var;
 397                                                   $$->attrs = $1;
 398                                                   set_type($$, $2, $3->ptr_level - 1, NULL, TRUE);
 399                                                   free($3);
 400                                                   $$->args = $5;
 401                                                 }
 402         | type pident '(' m_args ')'            { $$ = $2->var;
 403                                                   set_type($$, $1, $2->ptr_level - 1, NULL, TRUE);
 404                                                   free($2);
 405                                                   $$->args = $4;
 406                                                 }
 407         ;
 408
 409 array:                                          { $$ = NULL; }
 410         | '[' array_list ']'                    { $$ = $2; }
 411         | '[' '*' ']'                           { $$ = append_array( NULL, make_expr(EXPR_VOID) ); }
 412         ;
 413
 414 array_list: m_expr /* size of first dimension is optional */ { $$ = append_array( NULL, $1 ); }
 415         | array_list ',' expr                   { $$ = append_array( $1, $3 ); }
 416         | array_list ']' '[' expr               { $$ = append_array( $1, $4 ); }
 417         ;
 418
 419 m_attributes:                                   { $$ = NULL; }
 420         | attributes
 421         ;
 422
 423 attributes:
 424           '[' attrib_list ']'                   { $$ = $2;
 425                                                   if (!$$)
 426                                                     error_loc("empty attribute lists unsupported\n");
 427                                                 }
 428         ;
 429
 430 attrib_list: attribute                          { $$ = append_attr( NULL, $1 ); }
 431         | attrib_list ',' attribute             { $$ = append_attr( $1, $3 ); }
 432         | attrib_list ']' '[' attribute         { $$ = append_attr( $1, $4 ); }
 433         ;
 434
 435 str_list: aSTRING                               { $$ = append_str( NULL, $1 ); }
 436         | str_list ',' aSTRING                  { $$ = append_str( $1, $3 ); }
 437         ;
 438
 439 attribute:                                      { $$ = NULL; }
 440         | tAGGREGATABLE                         { $$ = make_attr(ATTR_AGGREGATABLE); }
 441         | tAPPOBJECT                            { $$ = make_attr(ATTR_APPOBJECT); }
 442         | tASYNC                                { $$ = make_attr(ATTR_ASYNC); }
 443         | tAUTOHANDLE                           { $$ = make_attr(ATTR_AUTO_HANDLE); }
 444         | tBINDABLE                             { $$ = make_attr(ATTR_BINDABLE); }
 445         | tCALLAS '(' ident ')'                 { $$ = make_attrp(ATTR_CALLAS, $3); }
 446         | tCASE '(' expr_list_const ')'         { $$ = make_attrp(ATTR_CASE, $3); }
 447         | tCONTEXTHANDLE                        { $$ = make_attrv(ATTR_CONTEXTHANDLE, 0); }
 448         | tCONTEXTHANDLENOSERIALIZE             { $$ = make_attrv(ATTR_CONTEXTHANDLE, 0); /* RPC_CONTEXT_HANDLE_DONT_SERIALIZE */ }
 449         | tCONTEXTHANDLESERIALIZE               { $$ = make_attrv(ATTR_CONTEXTHANDLE, 0); /* RPC_CONTEXT_HANDLE_SERIALIZE */ }
 450         | tCONTROL                              { $$ = make_attr(ATTR_CONTROL); }
 451         | tDEFAULT                              { $$ = make_attr(ATTR_DEFAULT); }
 452         | tDEFAULTCOLLELEM                      { $$ = make_attr(ATTR_DEFAULTCOLLELEM); }
 453         | tDEFAULTVALUE '(' expr_const ')'      { $$ = make_attrp(ATTR_DEFAULTVALUE_EXPR, $3); }
 454         | tDEFAULTVALUE '(' aSTRING ')'         { $$ = make_attrp(ATTR_DEFAULTVALUE_STRING, $3); }
 455         | tDEFAULTVTABLE                        { $$ = make_attr(ATTR_DEFAULTVTABLE); }
 456         | tDISPLAYBIND                          { $$ = make_attr(ATTR_DISPLAYBIND); }
 457         | tDLLNAME '(' aSTRING ')'              { $$ = make_attrp(ATTR_DLLNAME, $3); }
 458         | tDUAL                                 { $$ = make_attr(ATTR_DUAL); }
 459         | tENDPOINT '(' str_list ')'            { $$ = make_attrp(ATTR_ENDPOINT, $3); }
 460         | tENTRY '(' aSTRING ')'                { $$ = make_attrp(ATTR_ENTRY_STRING, $3); }
 461         | tENTRY '(' expr_const ')'             { $$ = make_attrp(ATTR_ENTRY_ORDINAL, $3); }
 462         | tEXPLICITHANDLE                       { $$ = make_attr(ATTR_EXPLICIT_HANDLE); }
 463         | tHANDLE                               { $$ = make_attr(ATTR_HANDLE); }
 464         | tHELPCONTEXT '(' expr_const ')'       { $$ = make_attrp(ATTR_HELPCONTEXT, $3); }
 465         | tHELPFILE '(' aSTRING ')'             { $$ = make_attrp(ATTR_HELPFILE, $3); }
 466         | tHELPSTRING '(' aSTRING ')'           { $$ = make_attrp(ATTR_HELPSTRING, $3); }
 467         | tHELPSTRINGCONTEXT '(' expr_const ')' { $$ = make_attrp(ATTR_HELPSTRINGCONTEXT, $3); }
 468         | tHELPSTRINGDLL '(' aSTRING ')'        { $$ = make_attrp(ATTR_HELPSTRINGDLL, $3); }
 469         | tHIDDEN                               { $$ = make_attr(ATTR_HIDDEN); }
 470         | tID '(' expr_const ')'                { $$ = make_attrp(ATTR_ID, $3); }
 471         | tIDEMPOTENT                           { $$ = make_attr(ATTR_IDEMPOTENT); }
 472         | tIIDIS '(' ident ')'                  { $$ = make_attrp(ATTR_IIDIS, $3); }
 473         | tIMMEDIATEBIND                        { $$ = make_attr(ATTR_IMMEDIATEBIND); }
 474         | tIMPLICITHANDLE '(' tHANDLET aIDENTIFIER ')'  { $$ = make_attrp(ATTR_IMPLICIT_HANDLE, $4); }
 475         | tIN                                   { $$ = make_attr(ATTR_IN); }
 476         | tINPUTSYNC                            { $$ = make_attr(ATTR_INPUTSYNC); }
 477         | tLENGTHIS '(' m_exprs ')'             { $$ = make_attrp(ATTR_LENGTHIS, $3); }
 478         | tLOCAL                                { $$ = make_attr(ATTR_LOCAL); }
 479         | tNONBROWSABLE                         { $$ = make_attr(ATTR_NONBROWSABLE); }
 480         | tNONCREATABLE                         { $$ = make_attr(ATTR_NONCREATABLE); }
 481         | tNONEXTENSIBLE                        { $$ = make_attr(ATTR_NONEXTENSIBLE); }
 482         | tOBJECT                               { $$ = make_attr(ATTR_OBJECT); }
 483         | tODL                                  { $$ = make_attr(ATTR_ODL); }
 484         | tOLEAUTOMATION                        { $$ = make_attr(ATTR_OLEAUTOMATION); }
 485         | tOPTIONAL                             { $$ = make_attr(ATTR_OPTIONAL); }
 486         | tOUT                                  { $$ = make_attr(ATTR_OUT); }
 487         | tPOINTERDEFAULT '(' pointer_type ')'  { $$ = make_attrv(ATTR_POINTERDEFAULT, $3); }
 488         | tPROPGET                              { $$ = make_attr(ATTR_PROPGET); }
 489         | tPROPPUT                              { $$ = make_attr(ATTR_PROPPUT); }
 490         | tPROPPUTREF                           { $$ = make_attr(ATTR_PROPPUTREF); }
 491         | tPUBLIC                               { $$ = make_attr(ATTR_PUBLIC); }
 492         | tRANGE '(' expr_const ',' expr_const ')' { expr_list_t *list = append_expr( NULL, $3 );
 493                                                      list = append_expr( list, $5 );
 494                                                      $$ = make_attrp(ATTR_RANGE, list); }
 495         | tREADONLY                             { $$ = make_attr(ATTR_READONLY); }
 496         | tREQUESTEDIT                          { $$ = make_attr(ATTR_REQUESTEDIT); }
 497         | tRESTRICTED                           { $$ = make_attr(ATTR_RESTRICTED); }
 498         | tRETVAL                               { $$ = make_attr(ATTR_RETVAL); }
 499         | tSIZEIS '(' m_exprs ')'               { $$ = make_attrp(ATTR_SIZEIS, $3); }
 500         | tSOURCE                               { $$ = make_attr(ATTR_SOURCE); }
 501         | tSTRING                               { $$ = make_attr(ATTR_STRING); }
 502         | tSWITCHIS '(' expr ')'                { $$ = make_attrp(ATTR_SWITCHIS, $3); }
 503         | tSWITCHTYPE '(' type ')'              { $$ = make_attrp(ATTR_SWITCHTYPE, $3); }
 504         | tTRANSMITAS '(' type ')'              { $$ = make_attrp(ATTR_TRANSMITAS, $3); }
 505         | tUUID '(' uuid_string ')'             { $$ = make_attrp(ATTR_UUID, $3); }
 506         | tV1ENUM                               { $$ = make_attr(ATTR_V1ENUM); }
 507         | tVARARG                               { $$ = make_attr(ATTR_VARARG); }
 508         | tVERSION '(' version ')'              { $$ = make_attrv(ATTR_VERSION, $3); }
 509         | tWIREMARSHAL '(' type ')'             { $$ = make_attrp(ATTR_WIREMARSHAL, $3); }
 510         | pointer_type                          { $$ = make_attrv(ATTR_POINTERTYPE, $1); }
 511         ;
 512
 513 uuid_string:
 514           aUUID
 515         | aSTRING                               { if (!is_valid_uuid($1))
 516                                                     error_loc("invalid UUID: %s\n", $1);
 517                                                   $$ = parse_uuid($1); }
 518         ;
 519
 520 callconv:
 521         | tSTDCALL
 522         ;
 523
 524 cases:                                          { $$ = NULL; }
 525         | cases case                            { $$ = append_var( $1, $2 ); }
 526         ;
 527
 528 case:     tCASE expr ':' field                  { attr_t *a = make_attrp(ATTR_CASE, append_expr( NULL, $2 ));
 529                                                   $$ = $4; if (!$$) $$ = make_var(NULL);
 530                                                   $$->attrs = append_attr( $$->attrs, a );
 531                                                 }
 532         | tDEFAULT ':' field                    { attr_t *a = make_attr(ATTR_DEFAULT);
 533                                                   $$ = $3; if (!$$) $$ = make_var(NULL);
 534                                                   $$->attrs = append_attr( $$->attrs, a );
 535                                                 }
 536         ;
 537
 538 constdef: tCONST type ident '=' expr_const      { $$ = reg_const($3);
 539                                                   set_type($$, $2, 0, NULL, FALSE);
 540                                                   $$->eval = $5;
 541                                                 }
 542         ;
 543
 544 enums:                                          { $$ = NULL; }
 545         | enum_list ','                         { $$ = $1; }
 546         | enum_list
 547         ;
 548
 549 enum_list: enum                                 { if (!$1->eval)
 550                                                     $1->eval = make_exprl(EXPR_NUM, 0 /* default for first enum entry */);
 551                                                   $$ = append_var( NULL, $1 );
 552                                                 }
 553         | enum_list ',' enum                    { if (!$3->eval)
 554                                                   {
 555                                                     var_t *last = LIST_ENTRY( list_tail($$), var_t, entry );
 556                                                     $3->eval = make_exprl(EXPR_NUM, last->eval->cval + 1);
 557                                                   }
 558                                                   $$ = append_var( $1, $3 );
 559                                                 }
 560         ;
 561
 562 enum:     ident '=' expr_const                  { $$ = reg_const($1);
 563                                                   $$->eval = $3;
 564                                                   $$->type = make_int(0);
 565                                                 }
 566         | ident                                 { $$ = reg_const($1);
 567                                                   $$->type = make_int(0);
 568                                                 }
 569         ;
 570
 571 enumdef: tENUM t_ident '{' enums '}'            { $$ = get_typev(RPC_FC_ENUM16, $2, tsENUM);
 572                                                   $$->kind = TKIND_ENUM;
 573                                                   $$->fields = $4;
 574                                                   $$->defined = TRUE;
 575                                                   if(in_typelib)
 576                                                       add_typelib_entry($$);
 577                                                 }
 578         ;
 579
 580 m_exprs:  m_expr                                { $$ = append_expr( NULL, $1 ); }
 581         | m_exprs ',' m_expr                    { $$ = append_expr( $1, $3 ); }
 582         ;
 583
 584 /*
 585 exprs:                                          { $$ = make_expr(EXPR_VOID); }
 586         | expr_list
 587         ;
 588
 589 expr_list: expr
 590         | expr_list ',' expr                    { LINK($3, $1); $$ = $3; }
 591         ;
 592 */
 593
 594 m_expr:                                         { $$ = make_expr(EXPR_VOID); }
 595         | expr
 596         ;
 597
 598 expr:     aNUM                                  { $$ = make_exprl(EXPR_NUM, $1); }
 599         | aHEXNUM                               { $$ = make_exprl(EXPR_HEXNUM, $1); }
 600         | aDOUBLE                               { $$ = make_exprd(EXPR_DOUBLE, $1); }
 601         | tFALSE                                { $$ = make_exprl(EXPR_TRUEFALSE, 0); }
 602         | tTRUE                                 { $$ = make_exprl(EXPR_TRUEFALSE, 1); }
 603         | aIDENTIFIER                           { $$ = make_exprs(EXPR_IDENTIFIER, $1); }
 604         | expr '?' expr ':' expr                { $$ = make_expr3(EXPR_COND, $1, $3, $5); }
 605         | expr '|' expr                         { $$ = make_expr2(EXPR_OR , $1, $3); }
 606         | expr '&' expr                         { $$ = make_expr2(EXPR_AND, $1, $3); }
 607         | expr '+' expr                         { $$ = make_expr2(EXPR_ADD, $1, $3); }
 608         | expr '-' expr                         { $$ = make_expr2(EXPR_SUB, $1, $3); }
 609         | expr '*' expr                         { $$ = make_expr2(EXPR_MUL, $1, $3); }
 610         | expr '/' expr                         { $$ = make_expr2(EXPR_DIV, $1, $3); }
 611         | expr SHL expr                         { $$ = make_expr2(EXPR_SHL, $1, $3); }
 612         | expr SHR expr                         { $$ = make_expr2(EXPR_SHR, $1, $3); }
 613         | '~' expr                              { $$ = make_expr1(EXPR_NOT, $2); }
 614         | '-' expr %prec NEG                    { $$ = make_expr1(EXPR_NEG, $2); }
 615         | '*' expr %prec PPTR                   { $$ = make_expr1(EXPR_PPTR, $2); }
 616         | '(' type ')' expr %prec CAST          { $$ = make_exprt(EXPR_CAST, $2, $4); }
 617         | tSIZEOF '(' type ')'                  { $$ = make_exprt(EXPR_SIZEOF, $3, NULL); }
 618         | '(' expr ')'                          { $$ = $2; }
 619         ;
 620
 621 expr_list_const: expr_const                     { $$ = append_expr( NULL, $1 ); }
 622         | expr_list_const ',' expr_const        { $$ = append_expr( $1, $3 ); }
 623         ;
 624
 625 expr_const: expr                                { $$ = $1;
 626                                                   if (!$$->is_const)
 627                                                       error_loc("expression is not constant\n");
 628                                                 }
 629         ;
 630
 631 externdef: tEXTERN tCONST type ident            { $$ = $4;
 632                                                   set_type($$, $3, 0, NULL, FALSE);
 633                                                 }
 634         ;
 635
 636 fields:                                         { $$ = NULL; }
 637         | fields field                          { $$ = append_var( $1, $2 ); }
 638         ;
 639
 640 field:    s_field ';'                           { $$ = $1; }
 641         | m_attributes uniondef ';'             { $$ = make_var(NULL); $$->type = $2; $$->attrs = $1; }
 642         | attributes ';'                        { $$ = make_var(NULL); $$->attrs = $1; }
 643         | ';'                                   { $$ = NULL; }
 644         ;
 645
 646 s_field:  m_attributes type pident array        { $$ = $3->var;
 647                                                   $$->attrs = $1;
 648                                                   set_type($$, $2, $3->ptr_level, $4, FALSE);
 649                                                   free($3);
 650                                                 }
 651         ;
 652
 653 funcdef:
 654           m_attributes type callconv pident
 655           '(' m_args ')'                        { var_t *v = $4->var;
 656                                                   v->attrs = $1;
 657                                                   set_type(v, $2, $4->ptr_level, NULL, FALSE);
 658                                                   free($4);
 659                                                   $$ = make_func(v, $6);
 660                                                   if (is_attr(v->attrs, ATTR_IN)) {
 661                                                     error_loc("inapplicable attribute [in] for function '%s'\n",$$->def->name);
 662                                                   }
 663                                                 }
 664         ;
 665
 666 m_ident:                                        { $$ = NULL; }
 667         | ident
 668         ;
 669
 670 t_ident:                                        { $$ = NULL; }
 671         | aIDENTIFIER                           { $$ = make_var($1); }
 672         | aKNOWNTYPE                            { $$ = make_var($1); }
 673         ;
 674
 675 ident:    aIDENTIFIER                           { $$ = make_var($1); }
 676 /* some "reserved words" used in attributes are also used as field names in some MS IDL files */
 677         | aKNOWNTYPE                            { $$ = make_var($<str>1); }
 678         ;
 679
 680 base_type: tBYTE                                { $$ = make_builtin($<str>1); }
 681         | tWCHAR                                { $$ = make_builtin($<str>1); }
 682         | int_std
 683         | tSIGNED int_std                       { $$ = $2; $$->sign = 1; }
 684         | tUNSIGNED int_std                     { $$ = $2; $$->sign = -1;
 685                                                   switch ($$->type) {
 686                                                   case RPC_FC_CHAR:  break;
 687                                                   case RPC_FC_SMALL: $$->type = RPC_FC_USMALL; break;
 688                                                   case RPC_FC_SHORT: $$->type = RPC_FC_USHORT; break;
 689                                                   case RPC_FC_LONG:  $$->type = RPC_FC_ULONG;  break;
 690                                                   case RPC_FC_HYPER:
 691                                                     if ($$->name[0] == 'h') /* hyper, as opposed to __int64 */
 692                                                     {
 693                                                       $$ = alias($$, "MIDL_uhyper");
 694                                                       $$->sign = 0;
 695                                                     }
 696                                                     break;
 697                                                   default: break;
 698                                                   }
 699                                                 }
 700         | tUNSIGNED                             { $$ = make_int(-1); }
 701         | tFLOAT                                { $$ = make_builtin($<str>1); }
 702         | tSINGLE                               { $$ = duptype(find_type("float", 0), 1); }
 703         | tDOUBLE                               { $$ = make_builtin($<str>1); }
 704         | tBOOLEAN                              { $$ = make_builtin($<str>1); }
 705         | tERRORSTATUST                         { $$ = make_builtin($<str>1); }
 706         | tHANDLET                              { $$ = make_builtin($<str>1); }
 707         ;
 708
 709 m_int:
 710         | tINT
 711         ;
 712
 713 int_std:  tINT                                  { $$ = make_builtin($<str>1); }
 714         | tSHORT m_int                          { $$ = make_builtin($<str>1); }
 715         | tSMALL                                { $$ = make_builtin($<str>1); }
 716         | tLONG m_int                           { $$ = make_builtin($<str>1); }
 717         | tHYPER m_int                          { $$ = make_builtin($<str>1); }
 718         | tINT64                                { $$ = make_builtin($<str>1); }
 719         | tCHAR                                 { $$ = make_builtin($<str>1); }
 720         ;
 721
 722 coclass:  tCOCLASS aIDENTIFIER                  { $$ = make_class($2); }
 723         | tCOCLASS aKNOWNTYPE                   { $$ = find_type($2, 0);
 724                                                   if ($$->defined) error_loc("multiple definition error\n");
 725                                                   if ($$->kind != TKIND_COCLASS) error_loc("%s was not declared a coclass\n", $2);
 726                                                 }
 727         ;
 728
 729 coclasshdr: attributes coclass                  { $$ = $2;
 730                                                   $$->attrs = $1;
 731                                                   if (!parse_only && do_header)
 732                                                     write_coclass($$);
 733                                                   if (!parse_only && do_idfile)
 734                                                     write_clsid($$);
 735                                                 }
 736         ;
 737
 738 coclassdef: coclasshdr '{' coclass_ints '}'     { $$ = $1;
 739                                                   $$->ifaces = $3;
 740                                                   $$->defined = TRUE;
 741                                                 }
 742         ;
 743
 744 coclass_ints:                                   { $$ = NULL; }
 745         | coclass_ints coclass_int              { $$ = append_ifref( $1, $2 ); }
 746         ;
 747
 748 coclass_int:
 749           m_attributes interfacedec             { $$ = make_ifref($2); $$->attrs = $1; }
 750         ;
 751
 752 dispinterface: tDISPINTERFACE aIDENTIFIER       { $$ = get_type(0, $2, 0); $$->kind = TKIND_DISPATCH; }
 753         |      tDISPINTERFACE aKNOWNTYPE        { $$ = get_type(0, $2, 0); $$->kind = TKIND_DISPATCH; }
 754         ;
 755
 756 dispinterfacehdr: attributes dispinterface      { attr_t *attrs;
 757                                                   $$ = $2;
 758                                                   if ($$->defined) error_loc("multiple definition error\n");
 759                                                   attrs = make_attr(ATTR_DISPINTERFACE);
 760                                                   $$->attrs = append_attr( $1, attrs );
 761                                                   $$->ref = find_type("IDispatch", 0);
 762                                                   if (!$$->ref) error_loc("IDispatch is undefined\n");
 763                                                   $$->defined = TRUE;
 764                                                   if (!parse_only && do_header) write_forward($$);
 765                                                 }
 766         ;
 767
 768 dispint_props: tPROPERTIES ':'                  { $$ = NULL; }
 769         | dispint_props s_field ';'             { $$ = append_var( $1, $2 ); }
 770         ;
 771
 772 dispint_meths: tMETHODS ':'                     { $$ = NULL; }
 773         | dispint_meths funcdef ';'             { $$ = append_func( $1, $2 ); }
 774         ;
 775
 776 dispinterfacedef: dispinterfacehdr '{'
 777           dispint_props
 778           dispint_meths
 779           '}'                                   { $$ = $1;
 780                                                   $$->fields = $3;
 781                                                   $$->funcs = $4;
 782                                                   if (!parse_only && do_header) write_dispinterface($$);
 783                                                   if (!parse_only && do_idfile) write_diid($$);
 784                                                 }
 785         | dispinterfacehdr
 786          '{' interface ';' '}'                  { $$ = $1;
 787                                                   $$->fields = $3->fields;
 788                                                   $$->funcs = $3->funcs;
 789                                                   if (!parse_only && do_header) write_dispinterface($$);
 790                                                   if (!parse_only && do_idfile) write_diid($$);
 791                                                 }
 792         ;
 793
 794 inherit:                                        { $$ = NULL; }
 795         | ':' aKNOWNTYPE                        { $$ = find_type2($2, 0); }
 796         ;
 797
 798 interface: tINTERFACE aIDENTIFIER               { $$ = get_type(RPC_FC_IP, $2, 0); $$->kind = TKIND_INTERFACE; }
 799         |  tINTERFACE aKNOWNTYPE                { $$ = get_type(RPC_FC_IP, $2, 0); $$->kind = TKIND_INTERFACE; }
 800         ;
 801
 802 interfacehdr: attributes interface              { $$.interface = $2;
 803                                                   $$.old_pointer_default = pointer_default;
 804                                                   if (is_attr($1, ATTR_POINTERDEFAULT))
 805                                                     pointer_default = get_attrv($1, ATTR_POINTERDEFAULT);
 806                                                   if ($2->defined) error_loc("multiple definition error\n");
 807                                                   $2->attrs = $1;
 808                                                   $2->defined = TRUE;
 809                                                   if (!parse_only && do_header) write_forward($2);
 810                                                 }
 811         ;
 812
 813 interfacedef: interfacehdr inherit
 814           '{' int_statements '}'                { $$ = $1.interface;
 815                                                   $$->ref = $2;
 816                                                   $$->funcs = $4;
 817                                                   compute_method_indexes($$);
 818                                                   if (!parse_only && do_header) write_interface($$);
 819                                                   if (!parse_only && local_stubs) write_locals(local_stubs, $$, TRUE);
 820                                                   if (!parse_only && do_idfile) write_iid($$);
 821                                                   pointer_default = $1.old_pointer_default;
 822                                                 }
 823 /* MIDL is able to import the definition of a base class from inside the
 824  * definition of a derived class, I'll try to support it with this rule */
 825         | interfacehdr ':' aIDENTIFIER
 826           '{' import int_statements '}'         { $$ = $1.interface;
 827                                                   $$->ref = find_type2($3, 0);
 828                                                   if (!$$->ref) error_loc("base class '%s' not found in import\n", $3);
 829                                                   $$->funcs = $6;
 830                                                   compute_method_indexes($$);
 831                                                   if (!parse_only && do_header) write_interface($$);
 832                                                   if (!parse_only && local_stubs) write_locals(local_stubs, $$, TRUE);
 833                                                   if (!parse_only && do_idfile) write_iid($$);
 834                                                   pointer_default = $1.old_pointer_default;
 835                                                 }
 836         | dispinterfacedef                      { $$ = $1; }
 837         ;
 838
 839 interfacedec:
 840           interface ';'                         { $$ = $1; if (!parse_only && do_header) write_forward($$); }
 841         | dispinterface ';'                     { $$ = $1; if (!parse_only && do_header) write_forward($$); }
 842         ;
 843
 844 module:   tMODULE aIDENTIFIER                   { $$ = make_type(0, NULL); $$->name = $2; $$->kind = TKIND_MODULE; }
 845         | tMODULE aKNOWNTYPE                    { $$ = make_type(0, NULL); $$->name = $2; $$->kind = TKIND_MODULE; }
 846         ;
 847
 848 modulehdr: attributes module                    { $$ = $2;
 849                                                   $$->attrs = $1;
 850                                                 }
 851         ;
 852
 853 moduledef: modulehdr '{' int_statements '}'     { $$ = $1;
 854                                                   $$->funcs = $3;
 855                                                   /* FIXME: if (!parse_only && do_header) write_module($$); */
 856                                                 }
 857         ;
 858
 859 p_ident:  '*' pident %prec PPTR                 { $$ = $2; $$->ptr_level++; }
 860         | tCONST p_ident                        { $$ = $2; /* FIXME */ }
 861         ;
 862
 863 pident:   ident                                 { $$ = make_pident($1); }
 864         | p_ident
 865         | '(' pident ')'                        { $$ = $2; }
 866         ;
 867
 868 pident_list:
 869         pident                                  { $$ = append_pident( NULL, $1 ); }
 870         | pident_list ',' pident                { $$ = append_pident( $1, $3 ); }
 871         ;
 872
 873 pointer_type:
 874           tREF                                  { $$ = RPC_FC_RP; }
 875         | tUNIQUE                               { $$ = RPC_FC_UP; }
 876         | tPTR                                  { $$ = RPC_FC_FP; }
 877         ;
 878
 879 structdef: tSTRUCT t_ident '{' fields '}'       { $$ = get_typev(RPC_FC_STRUCT, $2, tsSTRUCT);
 880                                                   /* overwrite RPC_FC_STRUCT with a more exact type */
 881                                                   $$->type = get_struct_type( $4 );
 882                                                   $$->kind = TKIND_RECORD;
 883                                                   $$->fields = $4;
 884                                                   $$->defined = TRUE;
 885                                                   if(in_typelib)
 886                                                       add_typelib_entry($$);
 887                                                 }
 888         ;
 889
 890 type:     tVOID                                 { $$ = duptype(find_type("void", 0), 1); }
 891         | aKNOWNTYPE                            { $$ = find_type($1, 0); }
 892         | base_type                             { $$ = $1; }
 893         | tCONST type                           { $$ = duptype($2, 1); $$->is_const = TRUE; }
 894         | enumdef                               { $$ = $1; }
 895         | tENUM aIDENTIFIER                     { $$ = find_type2($2, tsENUM); }
 896         | structdef                             { $$ = $1; }
 897         | tSTRUCT aIDENTIFIER                   { $$ = get_type(RPC_FC_STRUCT, $2, tsSTRUCT); }
 898         | uniondef                              { $$ = $1; }
 899         | tUNION aIDENTIFIER                    { $$ = find_type2($2, tsUNION); }
 900         | tSAFEARRAY '(' type ')'               { $$ = make_safearray($3); }
 901         ;
 902
 903 typedef: tTYPEDEF m_attributes type pident_list { reg_typedefs($3, $4, $2);
 904                                                   process_typedefs($4);
 905                                                 }
 906         ;
 907
 908 uniondef: tUNION t_ident '{' fields '}'         { $$ = get_typev(RPC_FC_NON_ENCAPSULATED_UNION, $2, tsUNION);
 909                                                   $$->kind = TKIND_UNION;
 910                                                   $$->fields = $4;
 911                                                   $$->defined = TRUE;
 912                                                 }
 913         | tUNION t_ident
 914           tSWITCH '(' s_field ')'
 915           m_ident '{' cases '}'                 { var_t *u = $7;
 916                                                   $$ = get_typev(RPC_FC_ENCAPSULATED_UNION, $2, tsUNION);
 917                                                   $$->kind = TKIND_UNION;
 918                                                   if (!u) u = make_var( xstrdup("tagged_union") );
 919                                                   u->type = make_type(RPC_FC_NON_ENCAPSULATED_UNION, NULL);
 920                                                   u->type->kind = TKIND_UNION;
 921                                                   u->type->fields = $9;
 922                                                   u->type->defined = TRUE;
 923                                                   $$->fields = append_var( $$->fields, $5 );
 924                                                   $$->fields = append_var( $$->fields, u );
 925                                                   $$->defined = TRUE;
 926                                                 }
 927         ;
 928
 929 version:
 930           aNUM                                  { $$ = MAKELONG($1, 0); }
 931         | aNUM '.' aNUM                         { $$ = MAKELONG($1, $3); }
 932         ;
 933
 934 %%
 935
 936 static void decl_builtin(const char *name, unsigned char type)
 937 {
 938   type_t *t = make_type(type, NULL);
 939   t->name = xstrdup(name);
 940   reg_type(t, name, 0);
 941 }
 942
 943 static type_t *make_builtin(char *name)
 944 {
 945   /* NAME is strdup'd in the lexer */
 946   type_t *t = duptype(find_type(name, 0), 0);
 947   t->name = name;
 948   return t;
 949 }
 950
 951 static type_t *make_int(int sign)
 952 {
 953   type_t *t = duptype(find_type("int", 0), 1);
 954
 955   t->sign = sign;
 956   if (sign < 0)
 957     t->type = t->type == RPC_FC_LONG ? RPC_FC_ULONG : RPC_FC_USHORT;
 958
 959   return t;
 960 }
 961
 962 void init_types(void)
 963 {
 964   decl_builtin("void", 0);
 965   decl_builtin("byte", RPC_FC_BYTE);
 966   decl_builtin("wchar_t", RPC_FC_WCHAR);
 967   decl_builtin("int", RPC_FC_LONG);     /* win32 */
 968   decl_builtin("short", RPC_FC_SHORT);
 969   decl_builtin("small", RPC_FC_SMALL);
 970   decl_builtin("long", RPC_FC_LONG);
 971   decl_builtin("hyper", RPC_FC_HYPER);
 972   decl_builtin("__int64", RPC_FC_HYPER);
 973   decl_builtin("char", RPC_FC_CHAR);
 974   decl_builtin("float", RPC_FC_FLOAT);
 975   decl_builtin("double", RPC_FC_DOUBLE);
 976   decl_builtin("boolean", RPC_FC_BYTE);
 977   decl_builtin("error_status_t", RPC_FC_ERROR_STATUS_T);
 978   decl_builtin("handle_t", RPC_FC_BIND_PRIMITIVE);
 979 }
 980
 981 static str_list_t *append_str(str_list_t *list, char *str)
 982 {
 983     struct str_list_entry_t *entry;
 984
 985     if (!str) return list;
 986     if (!list)
 987     {
 988         list = xmalloc( sizeof(*list) );
 989         list_init( list );
 990     }
 991     entry = xmalloc( sizeof(*entry) );
 992     entry->str = str;
 993     list_add_tail( list, &entry->entry );
 994     return list;
 995 }
 996
 997 static attr_list_t *append_attr(attr_list_t *list, attr_t *attr)
 998 {
 999     if (!attr) return list;
1000     if (!list)
1001     {
1002         list = xmalloc( sizeof(*list) );
1003         list_init( list );
1004     }
1005     list_add_tail( list, &attr->entry );
1006     return list;
1007 }
1008
1009 static attr_t *make_attr(enum attr_type type)
1010 {
1011   attr_t *a = xmalloc(sizeof(attr_t));
1012   a->type = type;
1013   a->u.ival = 0;
1014   return a;
1015 }
1016
1017 static attr_t *make_attrv(enum attr_type type, unsigned long val)
1018 {
1019   attr_t *a = xmalloc(sizeof(attr_t));
1020   a->type = type;
1021   a->u.ival = val;
1022   return a;
1023 }
1024
1025 static attr_t *make_attrp(enum attr_type type, void *val)
1026 {
1027   attr_t *a = xmalloc(sizeof(attr_t));
1028   a->type = type;
1029   a->u.pval = val;
1030   return a;
1031 }
1032
1033 static expr_t *make_expr(enum expr_type type)
1034 {
1035   expr_t *e = xmalloc(sizeof(expr_t));
1036   e->type = type;
1037   e->ref = NULL;
1038   e->u.lval = 0;
1039   e->is_const = FALSE;
1040   e->cval = 0;
1041   return e;
1042 }
1043
1044 static expr_t *make_exprl(enum expr_type type, long val)
1045 {
1046   expr_t *e = xmalloc(sizeof(expr_t));
1047   e->type = type;
1048   e->ref = NULL;
1049   e->u.lval = val;
1050   e->is_const = FALSE;
1051   /* check for numeric constant */
1052   if (type == EXPR_NUM || type == EXPR_HEXNUM || type == EXPR_TRUEFALSE) {
1053     /* make sure true/false value is valid */
1054     assert(type != EXPR_TRUEFALSE || val == 0 || val == 1);
1055     e->is_const = TRUE;
1056     e->cval = val;
1057   }
1058   return e;
1059 }
1060
1061 static expr_t *make_exprd(enum expr_type type, double val)
1062 {
1063   expr_t *e = xmalloc(sizeof(expr_t));
1064   e->type = type;
1065   e->ref = NULL;
1066   e->u.dval = val;
1067   e->is_const = TRUE;
1068   e->cval = val;
1069   return e;
1070 }
1071
1072 static expr_t *make_exprs(enum expr_type type, char *val)
1073 {
1074   expr_t *e;
1075   e = xmalloc(sizeof(expr_t));
1076   e->type = type;
1077   e->ref = NULL;
1078   e->u.sval = val;
1079   e->is_const = FALSE;
1080   /* check for predefined constants */
1081   if (type == EXPR_IDENTIFIER) {
1082     var_t *c = find_const(val, 0);
1083     if (c) {
1084       e->u.sval = c->name;
1085       free(val);
1086       e->is_const = TRUE;
1087       e->cval = c->eval->cval;
1088     }
1089   }
1090   return e;
1091 }
1092
1093 static expr_t *make_exprt(enum expr_type type, type_t *tref, expr_t *expr)
1094 {
1095   expr_t *e;
1096   e = xmalloc(sizeof(expr_t));
1097   e->type = type;
1098   e->ref = expr;
1099   e->u.tref = tref;
1100   e->is_const = FALSE;
1101   /* check for cast of constant expression */
1102   if (type == EXPR_SIZEOF) {
1103     switch (tref->type) {
1104       case RPC_FC_BYTE:
1105       case RPC_FC_CHAR:
1106       case RPC_FC_SMALL:
1107       case RPC_FC_USMALL:
1108         e->is_const = TRUE;
1109         e->cval = 1;
1110         break;
1111       case RPC_FC_WCHAR:
1112       case RPC_FC_USHORT:
1113       case RPC_FC_SHORT:
1114         e->is_const = TRUE;
1115         e->cval = 2;
1116         break;
1117       case RPC_FC_LONG:
1118       case RPC_FC_ULONG:
1119       case RPC_FC_FLOAT:
1120       case RPC_FC_ERROR_STATUS_T:
1121         e->is_const = TRUE;
1122         e->cval = 4;
1123         break;
1124       case RPC_FC_HYPER:
1125       case RPC_FC_DOUBLE:
1126         e->is_const = TRUE;
1127         e->cval = 8;
1128         break;
1129     }
1130   }
1131   if (type == EXPR_CAST && expr->is_const) {
1132     e->is_const = TRUE;
1133     e->cval = expr->cval;
1134   }
1135   return e;
1136 }
1137
1138 static expr_t *make_expr1(enum expr_type type, expr_t *expr)
1139 {
1140   expr_t *e;
1141   e = xmalloc(sizeof(expr_t));
1142   e->type = type;
1143   e->ref = expr;
1144   e->u.lval = 0;
1145   e->is_const = FALSE;
1146   /* check for compile-time optimization */
1147   if (expr->is_const) {
1148     e->is_const = TRUE;
1149     switch (type) {
1150     case EXPR_NEG:
1151       e->cval = -expr->cval;
1152       break;
1153     case EXPR_NOT:
1154       e->cval = ~expr->cval;
1155       break;
1156     default:
1157       e->is_const = FALSE;
1158       break;
1159     }
1160   }
1161   return e;
1162 }
1163
1164 static expr_t *make_expr2(enum expr_type type, expr_t *expr1, expr_t *expr2)
1165 {
1166   expr_t *e;
1167   e = xmalloc(sizeof(expr_t));
1168   e->type = type;
1169   e->ref = expr1;
1170   e->u.ext = expr2;
1171   e->is_const = FALSE;
1172   /* check for compile-time optimization */
1173   if (expr1->is_const && expr2->is_const) {
1174     e->is_const = TRUE;
1175     switch (type) {
1176     case EXPR_ADD:
1177       e->cval = expr1->cval + expr2->cval;
1178       break;
1179     case EXPR_SUB:
1180       e->cval = expr1->cval - expr2->cval;
1181       break;
1182     case EXPR_MUL:
1183       e->cval = expr1->cval * expr2->cval;
1184       break;
1185     case EXPR_DIV:
1186       e->cval = expr1->cval / expr2->cval;
1187       break;
1188     case EXPR_OR:
1189       e->cval = expr1->cval | expr2->cval;
1190       break;
1191     case EXPR_AND:
1192       e->cval = expr1->cval & expr2->cval;
1193       break;
1194     case EXPR_SHL:
1195       e->cval = expr1->cval << expr2->cval;
1196       break;
1197     case EXPR_SHR:
1198       e->cval = expr1->cval >> expr2->cval;
1199       break;
1200     default:
1201       e->is_const = FALSE;
1202       break;
1203     }
1204   }
1205   return e;
1206 }
1207
1208 static expr_t *make_expr3(enum expr_type type, expr_t *expr1, expr_t *expr2, expr_t *expr3)
1209 {
1210   expr_t *e;
1211   e = xmalloc(sizeof(expr_t));
1212   e->type = type;
1213   e->ref = expr1;
1214   e->u.ext = expr2;
1215   e->ext2 = expr3;
1216   e->is_const = FALSE;
1217   /* check for compile-time optimization */
1218   if (expr1->is_const && expr2->is_const && expr3->is_const) {
1219     e->is_const = TRUE;
1220     switch (type) {
1221     case EXPR_COND:
1222       e->cval = expr1->cval ? expr2->cval : expr3->cval;
1223       break;
1224     default:
1225       e->is_const = FALSE;
1226       break;
1227     }
1228   }
1229   return e;
1230 }
1231
1232 static expr_list_t *append_expr(expr_list_t *list, expr_t *expr)
1233 {
1234     if (!expr) return list;
1235     if (!list)
1236     {
1237         list = xmalloc( sizeof(*list) );
1238         list_init( list );
1239     }
1240     list_add_tail( list, &expr->entry );
1241     return list;
1242 }
1243
1244 static array_dims_t *append_array(array_dims_t *list, expr_t *expr)
1245 {
1246     if (!expr) return list;
1247     if (!list)
1248     {
1249         list = xmalloc( sizeof(*list) );
1250         list_init( list );
1251     }
1252     list_add_tail( list, &expr->entry );
1253     return list;
1254 }
1255
1256 static struct list type_pool = LIST_INIT(type_pool);
1257 typedef struct
1258 {
1259   type_t data;
1260   struct list link;
1261 } type_pool_node_t;
1262
1263 type_t *alloc_type(void)
1264 {
1265   type_pool_node_t *node = xmalloc(sizeof *node);
1266   list_add_tail(&type_pool, &node->link);
1267   return &node->data;
1268 }
1269
1270 void set_all_tfswrite(int val)
1271 {
1272   type_pool_node_t *node;
1273   LIST_FOR_EACH_ENTRY(node, &type_pool, type_pool_node_t, link)
1274     node->data.tfswrite = val;
1275 }
1276
1277 static type_t *make_type(unsigned char type, type_t *ref)
1278 {
1279   type_t *t = alloc_type();
1280   t->name = NULL;
1281   t->kind = TKIND_PRIMITIVE;
1282   t->type = type;
1283   t->ref = ref;
1284   t->attrs = NULL;
1285   t->orig = NULL;
1286   t->funcs = NULL;
1287   t->fields = NULL;
1288   t->ifaces = NULL;
1289   t->dim = 0;
1290   t->size_is = NULL;
1291   t->length_is = NULL;
1292   t->typestring_offset = 0;
1293   t->ptrdesc = 0;
1294   t->declarray = FALSE;
1295   t->ignore = (parse_only != 0);
1296   t->is_const = FALSE;
1297   t->sign = 0;
1298   t->defined = FALSE;
1299   t->written = FALSE;
1300   t->user_types_registered = FALSE;
1301   t->tfswrite = FALSE;
1302   t->typelib_idx = -1;
1303   return t;
1304 }
1305
1306 static void set_type(var_t *v, type_t *type, int ptr_level, array_dims_t *arr,
1307                      int top)
1308 {
1309   expr_list_t *sizes = get_attrp(v->attrs, ATTR_SIZEIS);
1310   expr_list_t *lengs = get_attrp(v->attrs, ATTR_LENGTHIS);
1311   int ptr_attr = get_attrv(v->attrs, ATTR_POINTERTYPE);
1312   int ptr_type = ptr_attr;
1313   int sizeless, has_varconf;
1314   expr_t *dim;
1315   type_t *atype, **ptype;
1316
1317   v->type = type;
1318
1319   if (!ptr_type && top)
1320     ptr_type = RPC_FC_RP;
1321
1322   for ( ; 0 < ptr_level; --ptr_level)
1323   {
1324     v->type = make_type(pointer_default, v->type);
1325     if (ptr_level == 1 && ptr_type && !arr)
1326     {
1327       v->type->type = ptr_type;
1328       ptr_type = 0;
1329     }
1330   }
1331
1332   if (ptr_type)
1333   {
1334     if (is_ptr(v->type))
1335     {
1336       if (v->type->type != ptr_type)
1337       {
1338         v->type = duptype(v->type, 1);
1339         v->type->type = ptr_type;
1340       }
1341     }
1342     else if (!arr && ptr_attr)
1343       error("%s: pointer attribute applied to non-pointer type\n", v->name);
1344   }
1345
1346   sizeless = FALSE;
1347   if (arr) LIST_FOR_EACH_ENTRY_REV(dim, arr, expr_t, entry)
1348   {
1349     if (sizeless)
1350       error("%s: only the first array dimension can be unspecified\n", v->name);
1351
1352     if (dim->is_const)
1353     {
1354       unsigned int align = 0;
1355       size_t size = type_memsize(v->type, &align);
1356
1357       if (dim->cval <= 0)
1358         error("%s: array dimension must be positive\n", v->name);
1359
1360       if (0xffffffffuL / size < (unsigned long) dim->cval)
1361         error("%s: total array size is too large\n", v->name);
1362       else if (0xffffuL < size * dim->cval)
1363         v->type = make_type(RPC_FC_LGFARRAY, v->type);
1364       else
1365         v->type = make_type(RPC_FC_SMFARRAY, v->type);
1366     }
1367     else
1368     {
1369       sizeless = TRUE;
1370       v->type = make_type(RPC_FC_CARRAY, v->type);
1371     }
1372
1373     v->type->declarray = TRUE;
1374     v->type->dim = dim->cval;
1375   }
1376
1377   ptype = &v->type;
1378   has_varconf = FALSE;
1379   if (sizes) LIST_FOR_EACH_ENTRY(dim, sizes, expr_t, entry)
1380   {
1381     if (dim->type != EXPR_VOID)
1382     {
1383       has_varconf = TRUE;
1384       atype = *ptype = duptype(*ptype, 0);
1385
1386       if (atype->type == RPC_FC_SMFARRAY || atype->type == RPC_FC_LGFARRAY)
1387         error("%s: cannot specify size_is for a fixed sized array\n", v->name);
1388
1389       if (atype->type != RPC_FC_CARRAY && !is_ptr(atype))
1390         error("%s: size_is attribute applied to illegal type\n", v->name);
1391
1392       atype->type = RPC_FC_CARRAY;
1393       atype->size_is = dim;
1394     }
1395
1396     ptype = &(*ptype)->ref;
1397     if (*ptype == NULL)
1398       error("%s: too many expressions in size_is attribute\n", v->name);
1399   }
1400
1401   ptype = &v->type;
1402   if (lengs) LIST_FOR_EACH_ENTRY(dim, lengs, expr_t, entry)
1403   {
1404     if (dim->type != EXPR_VOID)
1405     {
1406       has_varconf = TRUE;
1407       atype = *ptype = duptype(*ptype, 0);
1408
1409       if (atype->type == RPC_FC_SMFARRAY)
1410         atype->type = RPC_FC_SMVARRAY;
1411       else if (atype->type == RPC_FC_LGFARRAY)
1412         atype->type = RPC_FC_LGVARRAY;
1413       else if (atype->type == RPC_FC_CARRAY)
1414         atype->type = RPC_FC_CVARRAY;
1415       else
1416         error("%s: length_is attribute applied to illegal type\n", v->name);
1417
1418       atype->length_is = dim;
1419     }
1420
1421     ptype = &(*ptype)->ref;
1422     if (*ptype == NULL)
1423       error("%s: too many expressions in length_is attribute\n", v->name);
1424   }
1425
1426   if (has_varconf && !last_array(v->type))
1427   {
1428     ptype = &v->type;
1429     for (ptype = &v->type; is_array(*ptype); ptype = &(*ptype)->ref)
1430     {
1431       *ptype = duptype(*ptype, 0);
1432       (*ptype)->type = RPC_FC_BOGUS_ARRAY;
1433     }
1434   }
1435
1436   if (is_array(v->type))
1437   {
1438     const type_t *rt = v->type->ref;
1439     if (is_user_type(rt))
1440       v->type->type = RPC_FC_BOGUS_ARRAY;
1441     else
1442       switch (rt->type)
1443         {
1444         case RPC_FC_BOGUS_STRUCT:
1445         case RPC_FC_NON_ENCAPSULATED_UNION:
1446         case RPC_FC_ENCAPSULATED_UNION:
1447         case RPC_FC_ENUM16:
1448           v->type->type = RPC_FC_BOGUS_ARRAY;
1449           break;
1450           /* FC_RP should be above, but widl overuses these, and will break things.  */
1451         case RPC_FC_UP:
1452         case RPC_FC_RP:
1453           if (rt->ref->type == RPC_FC_IP)
1454             v->type->type = RPC_FC_BOGUS_ARRAY;
1455           break;
1456         }
1457   }
1458 }
1459
1460 static ifref_list_t *append_ifref(ifref_list_t *list, ifref_t *iface)
1461 {
1462     if (!iface) return list;
1463     if (!list)
1464     {
1465         list = xmalloc( sizeof(*list) );
1466         list_init( list );
1467     }
1468     list_add_tail( list, &iface->entry );
1469     return list;
1470 }
1471
1472 static ifref_t *make_ifref(type_t *iface)
1473 {
1474   ifref_t *l = xmalloc(sizeof(ifref_t));
1475   l->iface = iface;
1476   l->attrs = NULL;
1477   return l;
1478 }
1479
1480 static var_list_t *append_var(var_list_t *list, var_t *var)
1481 {
1482     if (!var) return list;
1483     if (!list)
1484     {
1485         list = xmalloc( sizeof(*list) );
1486         list_init( list );
1487     }
1488     list_add_tail( list, &var->entry );
1489     return list;
1490 }
1491
1492 static var_t *make_var(char *name)
1493 {
1494   var_t *v = xmalloc(sizeof(var_t));
1495   v->name = name;
1496   v->type = NULL;
1497   v->args = NULL;
1498   v->attrs = NULL;
1499   v->eval = NULL;
1500   return v;
1501 }
1502
1503 static pident_list_t *append_pident(pident_list_t *list, pident_t *p)
1504 {
1505   if (!p) return list;
1506   if (!list) {
1507     list = xmalloc(sizeof(*list));
1508     list_init(list);
1509   }
1510   list_add_tail(list, &p->entry);
1511   return list;
1512 }
1513
1514 static pident_t *make_pident(var_t *var)
1515 {
1516   pident_t *p = xmalloc(sizeof(*p));
1517   p->var = var;
1518   p->ptr_level = 0;
1519   return p;
1520 }
1521
1522 static func_list_t *append_func(func_list_t *list, func_t *func)
1523 {
1524     if (!func) return list;
1525     if (!list)
1526     {
1527         list = xmalloc( sizeof(*list) );
1528         list_init( list );
1529     }
1530     list_add_tail( list, &func->entry );
1531     return list;
1532 }
1533
1534 static func_t *make_func(var_t *def, var_list_t *args)
1535 {
1536   func_t *f = xmalloc(sizeof(func_t));
1537   f->def = def;
1538   f->args = args;
1539   f->ignore = parse_only;
1540   f->idx = -1;
1541   return f;
1542 }
1543
1544 static type_t *make_class(char *name)
1545 {
1546   type_t *c = make_type(0, NULL);
1547   c->name = name;
1548   c->kind = TKIND_COCLASS;
1549   return c;
1550 }
1551
1552 static type_t *make_safearray(type_t *type)
1553 {
1554   type_t *sa = duptype(find_type("SAFEARRAY", 0), 1);
1555   sa->ref = type;
1556   return make_type(pointer_default, sa);
1557 }
1558
1559 #define HASHMAX 64
1560
1561 static int hash_ident(const char *name)
1562 {
1563   const char *p = name;
1564   int sum = 0;
1565   /* a simple sum hash is probably good enough */
1566   while (*p) {
1567     sum += *p;
1568     p++;
1569   }
1570   return sum & (HASHMAX-1);
1571 }
1572
1573 /***** type repository *****/
1574
1575 struct rtype {
1576   const char *name;
1577   type_t *type;
1578   int t;
1579   struct rtype *next;
1580 };
1581
1582 struct rtype *type_hash[HASHMAX];
1583
1584 static type_t *reg_type(type_t *type, const char *name, int t)
1585 {
1586   struct rtype *nt;
1587   int hash;
1588   if (!name) {
1589     error_loc("registering named type without name\n");
1590     return type;
1591   }
1592   hash = hash_ident(name);
1593   nt = xmalloc(sizeof(struct rtype));
1594   nt->name = name;
1595   nt->type = type;
1596   nt->t = t;
1597   nt->next = type_hash[hash];
1598   type_hash[hash] = nt;
1599   return type;
1600 }
1601
1602 static int is_incomplete(const type_t *t)
1603 {
1604   return !t->defined && (is_struct(t->type) || is_union(t->type));
1605 }
1606
1607 static void add_incomplete(type_t *t)
1608 {
1609   struct typenode *tn = xmalloc(sizeof *tn);
1610   tn->type = t;
1611   list_add_tail(&incomplete_types, &tn->entry);
1612 }
1613
1614 static void fix_type(type_t *t)
1615 {
1616   if (t->kind == TKIND_ALIAS && is_incomplete(t)) {
1617     type_t *ot = t->orig;
1618     fix_type(ot);
1619     t->fields = ot->fields;
1620     t->defined = ot->defined;
1621   }
1622 }
1623
1624 static void fix_incomplete(void)
1625 {
1626   struct typenode *tn, *next;
1627
1628   LIST_FOR_EACH_ENTRY_SAFE(tn, next, &incomplete_types, struct typenode, entry) {
1629     fix_type(tn->type);
1630     free(tn);
1631   }
1632 }
1633
1634 static type_t *reg_typedefs(type_t *type, pident_list_t *pidents, attr_list_t *attrs)
1635 {
1636   type_t *ptr = type;
1637   const pident_t *pident;
1638   int ptrc = 0;
1639   int is_str = is_attr(attrs, ATTR_STRING);
1640   unsigned char ptr_type = get_attrv(attrs, ATTR_POINTERTYPE);
1641
1642   if (is_str)
1643   {
1644     type_t *t = type;
1645     unsigned char c;
1646
1647     while (is_ptr(t))
1648       t = t->ref;
1649
1650     c = t->type;
1651     if (c != RPC_FC_CHAR && c != RPC_FC_BYTE && c != RPC_FC_WCHAR)
1652     {
1653       pident = LIST_ENTRY( list_head( pidents ), const pident_t, entry );
1654       error_loc("'%s': [string] attribute is only valid on 'char', 'byte', or 'wchar_t' pointers and arrays\n",
1655               pident->var->name);
1656     }
1657   }
1658
1659   /* We must generate names for tagless enum, struct or union.
1660      Typedef-ing a tagless enum, struct or union means we want the typedef
1661      to be included in a library whether it has other attributes or not,
1662      hence the public attribute.  */
1663   if ((type->kind == TKIND_ENUM || type->kind == TKIND_RECORD
1664        || type->kind == TKIND_UNION) && ! type->name && ! parse_only)
1665   {
1666     if (! is_attr(attrs, ATTR_PUBLIC))
1667       attrs = append_attr( attrs, make_attr(ATTR_PUBLIC) );
1668     type->name = gen_name();
1669   }
1670
1671   LIST_FOR_EACH_ENTRY( pident, pidents, const pident_t, entry )
1672   {
1673     var_t *name = pident->var;
1674
1675     if (name->name) {
1676       type_t *cur = ptr;
1677       int cptr = pident->ptr_level;
1678       if (cptr > ptrc) {
1679         while (cptr > ptrc) {
1680           cur = ptr = make_type(pointer_default, cur);
1681           ptrc++;
1682         }
1683       } else {
1684         while (cptr < ptrc) {
1685           cur = cur->ref;
1686           cptr++;
1687         }
1688       }
1689       cur = alias(cur, name->name);
1690       cur->attrs = attrs;
1691       if (ptr_type)
1692       {
1693         if (is_ptr(cur))
1694           cur->type = ptr_type;
1695         else
1696           error_loc("'%s': pointer attribute applied to non-pointer type\n",
1697                   cur->name);
1698       }
1699       else if (is_str && ! is_ptr(cur))
1700         error_loc("'%s': [string] attribute applied to non-pointer type\n",
1701                 cur->name);
1702
1703       if (is_incomplete(cur))
1704         add_incomplete(cur);
1705       reg_type(cur, cur->name, 0);
1706     }
1707   }
1708   return type;
1709 }
1710
1711 static type_t *find_type(const char *name, int t)
1712 {
1713   struct rtype *cur = type_hash[hash_ident(name)];
1714   while (cur && (cur->t != t || strcmp(cur->name, name)))
1715     cur = cur->next;
1716   if (!cur) {
1717     error_loc("type '%s' not found\n", name);
1718     return NULL;
1719   }
1720   return cur->type;
1721 }
1722
1723 static type_t *find_type2(char *name, int t)
1724 {
1725   type_t *tp = find_type(name, t);
1726   free(name);
1727   return tp;
1728 }
1729
1730 int is_type(const char *name)
1731 {
1732   struct rtype *cur = type_hash[hash_ident(name)];
1733   while (cur && (cur->t || strcmp(cur->name, name)))
1734     cur = cur->next;
1735   if (cur) return TRUE;
1736   return FALSE;
1737 }
1738
1739 static type_t *get_type(unsigned char type, char *name, int t)
1740 {
1741   struct rtype *cur = NULL;
1742   type_t *tp;
1743   if (name) {
1744     cur = type_hash[hash_ident(name)];
1745     while (cur && (cur->t != t || strcmp(cur->name, name)))
1746       cur = cur->next;
1747   }
1748   if (cur) {
1749     free(name);
1750     return cur->type;
1751   }
1752   tp = make_type(type, NULL);
1753   tp->name = name;
1754   if (!name) return tp;
1755   return reg_type(tp, name, t);
1756 }
1757
1758 static type_t *get_typev(unsigned char type, var_t *name, int t)
1759 {
1760   char *sname = NULL;
1761   if (name) {
1762     sname = name->name;
1763     free(name);
1764   }
1765   return get_type(type, sname, t);
1766 }
1767
1768 static int get_struct_type(var_list_t *fields)
1769 {
1770   int has_pointer = 0;
1771   int has_conformance = 0;
1772   int has_variance = 0;
1773   var_t *field;
1774
1775   if (get_padding(fields))
1776     return RPC_FC_BOGUS_STRUCT;
1777
1778   if (fields) LIST_FOR_EACH_ENTRY( field, fields, var_t, entry )
1779   {
1780     type_t *t = field->type;
1781
1782     if (is_user_type(t))
1783       return RPC_FC_BOGUS_STRUCT;
1784
1785     if (is_ptr(t))
1786     {
1787         do
1788             t = t->ref;
1789         while (is_ptr(t));
1790
1791         switch (t->type)
1792         {
1793         case RPC_FC_IP:
1794         case RPC_FC_ENCAPSULATED_UNION:
1795         case RPC_FC_NON_ENCAPSULATED_UNION:
1796         case RPC_FC_BOGUS_STRUCT:
1797             return RPC_FC_BOGUS_STRUCT;
1798         }
1799
1800         has_pointer = 1;
1801         continue;
1802     }
1803
1804     if (field->type->declarray)
1805     {
1806         if (is_string_type(field->attrs, field->type))
1807         {
1808             if (is_conformant_array(field->type))
1809                 has_conformance = 1;
1810             has_variance = 1;
1811             continue;
1812         }
1813
1814         if (is_array(field->type->ref))
1815             return RPC_FC_BOGUS_STRUCT;
1816
1817         if (is_conformant_array(field->type))
1818         {
1819             has_conformance = 1;
1820             if (field->type->declarray && list_next(fields, &field->entry))
1821                 error_loc("field '%s' deriving from a conformant array must be the last field in the structure\n",
1822                         field->name);
1823         }
1824         if (field->type->length_is)
1825             has_variance = 1;
1826
1827         t = field->type->ref;
1828     }
1829
1830     switch (t->type)
1831     {
1832     /*
1833      * RPC_FC_BYTE, RPC_FC_STRUCT, etc
1834      *  Simple types don't effect the type of struct.
1835      *  A struct containing a simple struct is still a simple struct.
1836      *  So long as we can block copy the data, we return RPC_FC_STRUCT.
1837      */
1838     case 0: /* void pointer */
1839     case RPC_FC_BYTE:
1840     case RPC_FC_CHAR:
1841     case RPC_FC_SMALL:
1842     case RPC_FC_USMALL:
1843     case RPC_FC_WCHAR:
1844     case RPC_FC_SHORT:
1845     case RPC_FC_USHORT:
1846     case RPC_FC_LONG:
1847     case RPC_FC_ULONG:
1848     case RPC_FC_INT3264:
1849     case RPC_FC_UINT3264:
1850     case RPC_FC_HYPER:
1851     case RPC_FC_FLOAT:
1852     case RPC_FC_DOUBLE:
1853     case RPC_FC_STRUCT:
1854     case RPC_FC_ENUM16:
1855     case RPC_FC_ENUM32:
1856       break;
1857
1858     case RPC_FC_RP:
1859     case RPC_FC_UP:
1860     case RPC_FC_FP:
1861     case RPC_FC_OP:
1862     case RPC_FC_CARRAY:
1863     case RPC_FC_CVARRAY:
1864     case RPC_FC_BOGUS_ARRAY:
1865       has_pointer = 1;
1866       break;
1867
1868     /*
1869      * Propagate member attributes
1870      *  a struct should be at least as complex as its member
1871      */
1872     case RPC_FC_CVSTRUCT:
1873       has_conformance = 1;
1874       has_variance = 1;
1875       has_pointer = 1;
1876       break;
1877
1878     case RPC_FC_CPSTRUCT:
1879       has_conformance = 1;
1880       if (list_next( fields, &field->entry ))
1881           error_loc("field '%s' deriving from a conformant array must be the last field in the structure\n",
1882                   field->name);
1883       has_pointer = 1;
1884       break;
1885
1886     case RPC_FC_CSTRUCT:
1887       has_conformance = 1;
1888       if (list_next( fields, &field->entry ))
1889           error_loc("field '%s' deriving from a conformant array must be the last field in the structure\n",
1890                   field->name);
1891       break;
1892
1893     case RPC_FC_PSTRUCT:
1894       has_pointer = 1;
1895       break;
1896
1897     default:
1898       error_loc("Unknown struct member %s with type (0x%02x)\n", field->name, t->type);
1899       /* fallthru - treat it as complex */
1900
1901     /* as soon as we see one of these these members, it's bogus... */
1902     case RPC_FC_ENCAPSULATED_UNION:
1903     case RPC_FC_NON_ENCAPSULATED_UNION:
1904     case RPC_FC_BOGUS_STRUCT:
1905       return RPC_FC_BOGUS_STRUCT;
1906     }
1907   }
1908
1909   if( has_variance )
1910   {
1911     if ( has_conformance )
1912       return RPC_FC_CVSTRUCT;
1913     else
1914       return RPC_FC_BOGUS_STRUCT;
1915   }
1916   if( has_conformance && has_pointer )
1917     return RPC_FC_CPSTRUCT;
1918   if( has_conformance )
1919     return RPC_FC_CSTRUCT;
1920   if( has_pointer )
1921     return RPC_FC_PSTRUCT;
1922   return RPC_FC_STRUCT;
1923 }
1924
1925 /***** constant repository *****/
1926
1927 struct rconst {
1928   char *name;
1929   var_t *var;
1930   struct rconst *next;
1931 };
1932
1933 struct rconst *const_hash[HASHMAX];
1934
1935 static var_t *reg_const(var_t *var)
1936 {
1937   struct rconst *nc;
1938   int hash;
1939   if (!var->name) {
1940     error_loc("registering constant without name\n");
1941     return var;
1942   }
1943   hash = hash_ident(var->name);
1944   nc = xmalloc(sizeof(struct rconst));
1945   nc->name = var->name;
1946   nc->var = var;
1947   nc->next = const_hash[hash];
1948   const_hash[hash] = nc;
1949   return var;
1950 }
1951
1952 static var_t *find_const(char *name, int f)
1953 {
1954   struct rconst *cur = const_hash[hash_ident(name)];
1955   while (cur && strcmp(cur->name, name))
1956     cur = cur->next;
1957   if (!cur) {
1958     if (f) error_loc("constant '%s' not found\n", name);
1959     return NULL;
1960   }
1961   return cur->var;
1962 }
1963
1964 static void write_libid(const char *name, const attr_list_t *attr)
1965 {
1966   const UUID *uuid = get_attrp(attr, ATTR_UUID);
1967   write_guid(idfile, "LIBID", name, uuid);
1968 }
1969
1970 static void write_clsid(type_t *cls)
1971 {
1972   const UUID *uuid = get_attrp(cls->attrs, ATTR_UUID);
1973   write_guid(idfile, "CLSID", cls->name, uuid);
1974 }
1975
1976 static void write_diid(type_t *iface)
1977 {
1978   const UUID *uuid = get_attrp(iface->attrs, ATTR_UUID);
1979   write_guid(idfile, "DIID", iface->name, uuid);
1980 }
1981
1982 static void write_iid(type_t *iface)
1983 {
1984   const UUID *uuid = get_attrp(iface->attrs, ATTR_UUID);
1985   write_guid(idfile, "IID", iface->name, uuid);
1986 }
1987
1988 static int compute_method_indexes(type_t *iface)
1989 {
1990   int idx;
1991   func_t *f;
1992
1993   if (iface->ref)
1994     idx = compute_method_indexes(iface->ref);
1995   else
1996     idx = 0;
1997
1998   if (!iface->funcs)
1999     return idx;
2000
2001   LIST_FOR_EACH_ENTRY( f, iface->funcs, func_t, entry )
2002     if (! is_callas(f->def->attrs))
2003       f->idx = idx++;
2004
2005   return idx;
2006 }
2007
2008 static char *gen_name(void)
2009 {
2010   static const char format[] = "__WIDL_%s_generated_name_%08lX";
2011   static unsigned long n = 0;
2012   static const char *file_id;
2013   static size_t size;
2014   char *name;
2015
2016   if (! file_id)
2017   {
2018     char *dst = dup_basename(input_name, ".idl");
2019     file_id = dst;
2020
2021     for (; *dst; ++dst)
2022       if (! isalnum((unsigned char) *dst))
2023         *dst = '_';
2024
2025     size = sizeof format - 7 + strlen(file_id) + 8;
2026   }
2027
2028   name = xmalloc(size);
2029   sprintf(name, format, file_id, n++);
2030   return name;
2031 }
2032
2033 static void process_typedefs(pident_list_t *pidents)
2034 {
2035   pident_t *pident, *next;
2036
2037   if (!pidents) return;
2038   LIST_FOR_EACH_ENTRY_SAFE( pident, next, pidents, pident_t, entry )
2039   {
2040     var_t *var = pident->var;
2041     type_t *type = find_type(var->name, 0);
2042
2043     if (! parse_only && do_header)
2044       write_typedef(type);
2045     if (in_typelib && type->attrs)
2046       add_typelib_entry(type);
2047
2048     free(pident);
2049     free(var);
2050   }
2051 }
2052
2053 static void check_arg(var_t *arg)
2054 {
2055   type_t *t = arg->type;
2056
2057   if (t->type == 0 && ! is_var_ptr(arg))
2058     error_loc("argument '%s' has void type\n", arg->name);
2059 }
2060
2061 static void check_all_user_types(ifref_list_t *ifrefs)
2062 {
2063   const ifref_t *ifref;
2064   const func_t *f;
2065
2066   if (ifrefs) LIST_FOR_EACH_ENTRY(ifref, ifrefs, const ifref_t, entry)
2067   {
2068     const func_list_t *fs = ifref->iface->funcs;
2069     if (fs) LIST_FOR_EACH_ENTRY(f, fs, const func_t, entry)
2070       check_for_user_types_and_context_handles(f->args);
2071   }
2072 }
2073
2074 int is_valid_uuid(const char *s)
2075 {
2076   int i;
2077
2078   for (i = 0; i < 36; ++i)
2079     if (i == 8 || i == 13 || i == 18 || i == 23)
2080     {
2081       if (s[i] != '-')
2082         return FALSE;
2083     }
2084     else
2085       if (!isxdigit(s[i]))
2086         return FALSE;
2087
2088   return s[i] == '\0';
2089 }