git.oblomov.eu Git - wine/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Author: Michael Patra   <micky@marie.physik.tu-berlin.de>
   3 dnl                         <patra@itp1.physik.tu-berlin.de>
   4 AC_REVISION([configure.in 1.00])
   5 AC_INIT(controls/edit.c)
   6 AC_CONFIG_HEADER(include/config.h)
   7 AC_CONFIG_AUX_DIR(tools)
   8
   9 dnl **** Command-line arguments ****
  10
  11 dnl Default values
  12 LIBEXT=so       # library type .so or .a
  13 TRACE_MSGS=yes  # the TRACE() macro
  14 DEBUG_MSGS=yes  # the TRACE(), WARN(), and FIXME() macros.
  15 CURSES=yes
  16 OPENGL=normal
  17
  18 AC_ARG_ENABLE(debug,
  19 [  --disable-debug         compile out all debugging messages],
  20 [if test "$enableval" = "no"; then DEBUG_MSGS="no"; fi])
  21
  22 AC_ARG_ENABLE(opengl,
  23 [  --enable-opengl         force usage of OpenGL even if the latter is thread-safe via pthread],
  24 [if test "$enableval" = "no"; then OPENGL="no"; elif test "$enableval" = "yes"; then OPENGL="yes"; fi])
  25
  26 AC_ARG_ENABLE(trace,
  27 [  --disable-trace         compile out TRACE messages],
  28 [if test "$enableval" = "no"; then TRACE_MSGS="no"; fi])
  29
  30 AC_ARG_WITH(curses,
  31 [  --without-curses        do not use curses],
  32 [if test "$withval" = "no"; then CURSES="no"; fi])
  33
  34 AC_ARG_WITH(reentrant-x,
  35 [  --without-reentrant-x   compile for use with non-reentrant X libraries])
  36
  37 AC_SUBST(OPTIONS)
  38
  39 if test "$DEBUG_MSGS" = "no"
  40 then
  41     AC_DEFINE(NO_DEBUG_MSGS, 1, [Define if all debug messages are to be compiled out])
  42 fi
  43
  44 if test "$TRACE_MSGS" = "no" -o "$DEBUG_MSGS" = "no"
  45 then
  46     AC_DEFINE(NO_TRACE_MSGS, 1, [Define if TRACE messages are to be compiled out])
  47 fi
  48
  49 dnl **** Check for some programs ****
  50
  51 AC_PROG_MAKE_SET
  52 AC_PROG_CC
  53 AC_PROG_CPP
  54 AC_PATH_XTRA
  55 AC_PROG_YACC
  56 AC_PROG_LEX
  57 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
  58 if test "$XLEX" = "none"
  59 then
  60         echo "*** Error: No suitable lex found. ***"
  61         echo "    Please install the 'flex' package."
  62         exit 1
  63 fi
  64 AC_PROG_RANLIB
  65 AC_PROG_INSTALL
  66 AC_PROG_LN_S
  67 AC_CHECK_PROG(C2MAN,c2man,c2man,\$(TOPSRCDIR)/tools/c2man.pl)
  68 AC_PATH_PROG(LDCONFIG, ldconfig, true, /sbin:/usr/sbin:$PATH)
  69 AC_CYGWIN
  70 AC_CHECK_PROG(DLLWRAP,dllwrap,dllwrap,false)
  71
  72 dnl Check for lint
  73 AC_CHECK_PROGS(LINT, lclint lint)
  74 if test "$LINT" = "lint"
  75 then
  76   LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
  77   dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
  78 fi
  79 AC_SUBST(LINT)
  80 AC_SUBST(LINTFLAGS)
  81
  82 if test "$CYGWIN" = "yes"
  83 then
  84     LDCOMBINE="ld -r --enable-stdcall-fixup"
  85 else
  86     LDCOMBINE="ld -r"
  87 fi
  88 AC_SUBST(LDCOMBINE)
  89
  90 dnl **** Check for some libraries ****
  91
  92 dnl Check for -lm
  93 AC_CHECK_LIB(m,sqrt)
  94 dnl Check for -li386 for NetBSD and OpenBSD
  95 AC_CHECK_LIB(i386,i386_set_ldt)
  96 dnl Check for -lossaudio for NetBSD
  97 AC_CHECK_LIB(ossaudio,_oss_ioctl)
  98 dnl Check for -lw for Solaris
  99 AC_CHECK_FUNCS(iswalnum,,AC_CHECK_LIB(w,iswalnum))
 100 dnl Check for -lnsl for Solaris
 101 AC_CHECK_FUNCS(gethostbyname,,AC_CHECK_LIB(nsl,gethostbyname))
 102 dnl Check for -lsocket for Solaris
 103 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
 104 dnl Check for -lxpg4 for FreeBSD
 105 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
 106 dnl Check for -lmmap for OS/2
 107 AC_CHECK_LIB(mmap,mmap)
 108 dnl Check for openpty
 109 AC_CHECK_FUNCS(openpty,,
 110         AC_CHECK_LIB(util,openpty,
 111                 AC_DEFINE(HAVE_OPENPTY)
 112                 LIBS="$LIBS -lutil"
 113         ))
 114
 115 AC_CHECK_HEADERS(dlfcn.h,
 116     AC_CHECK_FUNCS(dlopen,,
 117         AC_CHECK_LIB(dl,dlopen,
 118                      AC_DEFINE(HAVE_DLOPEN)
 119                      LIBS="$LIBS -ldl",
 120                      LIBEXT="a")
 121         ),
 122         LIBEXT="a"
 123     )
 124
 125 AC_SUBST(XLIB)
 126 AC_SUBST(X_DLLS)
 127 X_DLLS=""
 128 AC_SUBST(XFILES)
 129 XFILES=""
 130 AC_SUBST(OPENGLFILES)
 131 OPENGLFILES=""
 132 AC_SUBST(OPENGL32_DLL)
 133 OPENGL32_DLL=""
 134 GLU32FILES=""
 135 AC_SUBST(GLU32FILES)
 136 GLU32_DLL=""
 137 AC_SUBST(GLU32_DLL)
 138 if test "$have_x" = "yes"
 139 then
 140     XLIB="-lXext -lX11"
 141     ac_save_CPPFLAGS="$CPPFLAGS"
 142     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 143
 144     dnl *** Check for -lXpm
 145     AC_CHECK_HEADERS(X11/xpm.h,
 146       [ dnl *** If X11/xpm.h exists...
 147         AC_CHECK_LIB(Xpm, XpmCreatePixmapFromData,
 148           [ AC_DEFINE(HAVE_LIBXXPM, 1, [Define if you have the Xpm library])
 149             X_PRE_LIBS="$X_PRE_LIBS -lXpm"],,
 150           $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 151         )
 152       ],
 153       [ dnl *** If X11/xpm.h does not exist...
 154         dnl NOTE: autoconf does not allow commas inside the third
 155         dnl       parameter to AC_CHECK_HEADERS, due to some quoting
 156         dnl       magic it does.
 157         echo "Redhat            :       xpm xpm-devel"
 158         echo "Caldera OpenLinux :       xpm xpm-devel xpm-devel-static"
 159         echo "SuSE              :       xpm"
 160         echo "Debian/Corel Linux:       xpm4g xpm4g-dev"
 161         echo
 162         echo "Or get the sources from ftp.x.org and all its mirror sites from "
 163         echo "the directory /contrib/libraries."
 164         echo
 165         exit 1
 166       ]
 167     )
 168
 169     dnl *** All three of the following tests require X11/Xlib.h
 170     AC_CHECK_HEADERS(X11/Xlib.h,
 171       [
 172         dnl *** Check for X keyboard extension
 173         AC_CHECK_HEADERS(X11/XKBlib.h,
 174             [ dnl *** If X11/XKBlib.h exists...
 175               AC_CHECK_LIB(X11, XkbQueryExtension,
 176               AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
 177               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 178             ],
 179             AC_MSG_WARN([XKB extension not found!!])
 180         )
 181
 182         dnl *** Check for X Shm extension
 183         AC_CHECK_HEADERS(X11/extensions/XShm.h,
 184             [ dnl *** If X11/extensions/XShm.h exists...
 185               AC_CHECK_LIB(Xext, XShmQueryExtension,
 186               AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
 187               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 188             ],
 189             AC_MSG_WARN([Xshm extension not found!!])
 190         )
 191
 192         dnl *** Check for X shape extension
 193         AC_CHECK_HEADERS(X11/extensions/shape.h,
 194             [ dnl *** If X11/extensions/shape.h exists...
 195               AC_CHECK_LIB(Xext,XShapeQueryExtension,
 196               AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
 197               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 198             ],
 199             AC_MSG_WARN([XShape extension not found!!])
 200         )
 201
 202         dnl *** Check for XFree86 DGA / DGA 2.0 extension
 203         AC_CHECK_HEADERS(X11/extensions/xf86dga.h,
 204             [ dnl *** If X11/extensions/xf86dga.h exists, check
 205               dnl *** for XDGAQueryExtension()...
 206               AC_CHECK_LIB(Xxf86dga, XDGAQueryExtension,
 207                 [ dnl *** If found...
 208                   AC_DEFINE(HAVE_LIBXXF86DGA2, 1,
 209                             [Define if you have the Xxf86dga library version 2])
 210                   X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
 211                ],
 212                 [ dnl *** If not found, look for XF86DGAQueryExtension()
 213                   dnl *** instead (DGA 2.0 not found)...
 214                   AC_CHECK_LIB(Xxf86dga, XF86DGAQueryExtension,
 215                     [ AC_DEFINE(HAVE_LIBXXF86DGA, 1,
 216                                 [Define if you have the Xxf86dga library version 1])
 217                       X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
 218                     ],,
 219                     $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 220                   )
 221                 ],
 222                 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 223               )
 224             ],
 225             AC_MSG_WARN([DGA extension not found!!])
 226         )
 227
 228         dnl *** Check for XFree86 VMODE extension
 229         AC_CHECK_HEADERS(X11/extensions/xf86vmode.h,
 230             [ dnl *** If X11/extensions/xf86vmode.h exists...
 231                 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
 232                   [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
 233                      X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
 234                   ],,
 235                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 236                 )
 237             ],
 238             AC_MSG_WARN([XFree86 VMODE extension not found!!])
 239         )
 240
 241         dnl *** Check for XVideo extension supporting XvImages
 242         AC_CHECK_HEADERS(X11/extensions/Xvlib.h,
 243             [ dnl *** If X11/extensions/Xvlib.h exists...
 244                 AC_CHECK_LIB(Xv, XvShmCreateImage,
 245                   [ AC_DEFINE(HAVE_XVIDEO, 1, [Define if the X libraries support XVideo])
 246                      X_PRE_LIBS="$X_PRE_LIBS -lXv"
 247                   ],,
 248                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 249                 )
 250             ],
 251             AC_MSG_WARN([XVideo extension not found !!])
 252         )
 253
 254       ]
 255     ) dnl *** End of X11/Xlib.h check
 256
 257     dnl Check for the presence of OpenGL
 258     if test $OPENGL = "yes" -o $OPENGL = "normal"
 259     then
 260         AC_CHECK_HEADERS(GL/gl.h GL/glx.h GL/glext.h)
 261         if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
 262         then
 263             dnl Check for some problems due to old Mesa versions
 264             AC_CACHE_CHECK("for up-to-date OpenGL version", wine_cv_opengl_version_OK,
 265               AC_TRY_COMPILE(
 266                 [#include <GL/gl.h>],
 267                 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
 268                 [wine_cv_opengl_version_OK="yes"],
 269                 [wine_cv_opengl_version_OK="no"]
 270               )
 271             )
 272
 273             dnl Check for the thread-safety of the OpenGL library
 274             AC_CACHE_CHECK("for thread-safe OpenGL version",
 275                            wine_cv_opengl_version_threadsafe,
 276               [saved_libs=$LIBS
 277                LIBS="$X_LIBS -lGL"
 278                AC_TRY_LINK([],[pthread_getspecific();],
 279                               [wine_cv_opengl_version_threadsafe="yes"],
 280                               [wine_cv_opengl_version_threadsafe="no"])
 281                LIBS=$saved_libs]
 282             )
 283
 284             if test "$wine_cv_opengl_version_OK" = "yes" -a \( "$wine_cv_opengl_version_threadsafe" = "no" -o $OPENGL = "yes" \)
 285             then
 286                 dnl Check for the presence of the library
 287                 AC_CHECK_LIB(GL,glXCreateContext,
 288                              X_PRE_LIBS="$X_PRE_LIBS -lGL"
 289                              ,,
 290                              $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 291
 292                 if test $ac_cv_lib_GL_glXCreateContext = "yes"
 293                 then
 294
 295                         OPENGLFILES='$(OPENGLFILES)'
 296                         AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])
 297
 298                         AC_CHECK_LIB(GL,glXGetProcAddressARB,
 299                                      AC_DEFINE(HAVE_GLX_GETPROCADDRESS, 1,
 300                                                [Define if the OpenGL library supports the glXGetProcAddressARB call]),,
 301                                      $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 302
 303                         if test $ac_cv_lib_GL_glXGetProcAddressARB = "yes"
 304                         then
 305                                AC_CACHE_CHECK("for OpenGL extension functions prototypes", wine_cv_extension_prototypes,
 306                                   AC_TRY_COMPILE([#include <GL/gl.h>
 307                                                   #ifdef HAVE_GL_GLEXT_H
 308                                                   # include <GL/glext.h>
 309                                                   #endif
 310                                                   ],
 311                                                  [PFNGLCOLORTABLEEXTPROC test_proc;],
 312                                                  [wine_cv_extension_prototypes="yes"],
 313                                                  [wine_cv_extension_prototypes="no"]
 314                                   )
 315                                 )
 316                                 if test $wine_cv_extension_prototypes = "yes"
 317                                 then
 318                                     AC_DEFINE(HAVE_GLEXT_PROTOTYPES, 1,
 319                                               [Define if the OpenGL headers define extension typedefs])
 320                                 fi
 321
 322                                 OPENGL32_DLL=opengl32
 323                         fi
 324
 325                         AC_CHECK_HEADERS(GL/osmesa.h,
 326                             [ dnl *** If GL/osmesa.h exists...
 327                                 AC_CHECK_LIB(GL, OSMesaCreateContext,,
 328                                   AC_CHECK_LIB(OSMesa, OSMesaCreateContext,
 329                                                X_PRE_LIBS="$X_PRE_LIBS -lOSMesa",,
 330                                                -lGL $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS),
 331                                   $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
 332                                 )
 333                             ]
 334                         )
 335                 fi
 336                 dnl Check for GLU32 library.
 337                 AC_CHECK_LIB(GLU,glBegin,
 338                              X_PRE_LIBS="$X_PRE_LIBS -lGLU"
 339                              GLU32FILES='$(GLU32FILES)'
 340                              GLU32_DLL=glu32
 341                              ,,
 342                              $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
 343                 )
 344              fi
 345          fi
 346     fi
 347
 348     CPPFLAGS="$ac_save_CPPFLAGS"
 349     X_DLLS='$(X_DLLS)'
 350     XFILES='$(XFILES)'
 351 else
 352     XLIB=""
 353     X_CFLAGS=""
 354     X_LIBS=""
 355 fi
 356
 357 dnl **** Check which curses lib to use ***
 358 if test "$CURSES" = "yes"
 359 then
 360     AC_CHECK_HEADERS(ncurses.h,
 361         AC_CHECK_LIB(ncurses,waddch),
 362         AC_CHECK_HEADERS(curses.h,AC_CHECK_LIB(curses,waddch)))
 363     AC_CHECK_FUNCS(getbkgd resizeterm)
 364 fi
 365
 366 CUPSLIBS=""
 367 dnl **** Check for CUPS ****
 368 wine_cv_warn_cups_h=no
 369 AC_CHECK_LIB(cups,cupsGetPPD,
 370         AC_CHECK_HEADER(cups/cups.h,
 371             AC_DEFINE(HAVE_CUPS, 1, [Define if we have CUPS])
 372             CUPSLIBS="-lcups",
 373             wine_cv_warn_cups_h=yes)
 374 )
 375 AC_SUBST(CUPSLIBS)
 376
 377 dnl **** Check for FreeType 2 ****
 378 AC_CHECK_LIB(freetype,FT_Init_FreeType,ft_lib=yes,ft_lib=no)
 379 if test "$ft_lib" = "no"
 380 then
 381     FREETYPELIBS=""
 382     FREETYPEINCL=""
 383     wine_cv_msg_freetype=no
 384 else
 385     AC_CHECK_PROG(ft_devel,freetype-config,freetype-config,no)
 386     if test "$ft_devel" = "no"
 387     then
 388         AC_CHECK_PROG(ft_devel2,freetype2-config,freetype2-config,no)
 389         if test "$ft_devel2" = "freetype2-config"
 390         then
 391                 ft_devel=$ft_devel2
 392         fi
 393     fi
 394     if test "$ft_devel" = "no"
 395     then
 396         FREETYPELIBS=""
 397         FREETYPEINCL=""
 398         wine_cv_msg_freetype=yes
 399     else
 400         AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
 401         FREETYPELIBS=`$ft_devel --libs`
 402         FREETYPEINCL=`$ft_devel --cflags`
 403         ac_save_CPPFLAGS="$CPPFLAGS"
 404         CPPFLAGS="$FREETYPEINCL $CPPFLAGS"
 405         AC_CHECK_HEADERS(freetype/freetype.h \
 406                          freetype/ftglyph.h \
 407                          freetype/tttables.h \
 408                          freetype/ftnames.h \
 409                          freetype/ftsnames.h \
 410                          freetype/ttnameid.h)
 411         CPPFLAGS="$ac_save_CPPFLAGS"
 412         wine_cv_msg_freetype=no
 413     fi
 414 fi
 415 AC_SUBST(FREETYPELIBS)
 416 AC_SUBST(FREETYPEINCL)
 417
 418 dnl **** Check for parport (currently Linux only) ****
 419 AC_CACHE_CHECK("for parport header/ppdev.h", ac_cv_c_ppdev,
 420  AC_TRY_COMPILE(
 421    [#include <linux/ppdev.h>],
 422    [ioctl (1,PPCLAIM,0)],
 423    [ac_cv_c_ppdev="yes"],
 424    [ac_cv_c_ppdev="no"])
 425  )
 426 if test "$ac_cv_c_ppdev" = "yes"
 427 then
 428     AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
 429 fi
 430
 431 dnl **** Check for IPX (currently Linux only) ****
 432 AC_CACHE_CHECK("for GNU style IPX support", ac_cv_c_ipx_gnu,
 433  AC_TRY_COMPILE(
 434    [#include <sys/socket.h>
 435     #include <netipx/ipx.h>],
 436    [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
 437    [ac_cv_c_ipx_gnu="yes"],
 438    [ac_cv_c_ipx_gnu="no"])
 439  )
 440 if test "$ac_cv_c_ipx_gnu" = "yes"
 441 then
 442     AC_DEFINE(HAVE_IPX_GNU, 1, [Define if IPX should use netipx/ipx.h from libc])
 443 fi
 444
 445 if test "$ac_cv_c_ipx_gnu" = "no"
 446 then
 447  AC_CACHE_CHECK("for linux style IPX support", ac_cv_c_ipx_linux,
 448   AC_TRY_COMPILE(
 449     [#include <sys/socket.h>
 450      #include <asm/types.h>
 451      #include <linux/ipx.h>],
 452     [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
 453     [ac_cv_c_ipx_linux="yes"],
 454     [ac_cv_c_ipx_linux="no"])
 455   )
 456   if test "$ac_cv_c_ipx_linux" = "yes"
 457   then
 458       AC_DEFINE(HAVE_IPX_LINUX, 1, [Define if IPX includes are taken from Linux kernel])
 459   fi
 460 fi
 461
 462 dnl **** Check for Open Sound System ****
 463 AC_CHECK_HEADERS(sys/soundcard.h machine/soundcard.h soundcard.h, break)
 464
 465 AC_CACHE_CHECK("for Open Sound System",
 466         ac_cv_c_opensoundsystem,
 467         AC_TRY_COMPILE([
 468         #if defined(HAVE_SYS_SOUNDCARD_H)
 469                 #include <sys/soundcard.h>
 470         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 471                 #include <machine/soundcard.h>
 472         #elif defined(HAVE_SOUNDCARD_H)
 473                 #include <soundcard.h>
 474         #endif
 475         ],[
 476
 477 /* check for one of the Open Sound System specific SNDCTL_ defines */
 478 #if !defined(SNDCTL_DSP_STEREO)
 479 #error No open sound system
 480 #endif
 481 ],ac_cv_c_opensoundsystem="yes",ac_cv_c_opensoundsystem="no"))
 482
 483 if test "$ac_cv_c_opensoundsystem" = "yes"
 484 then
 485     AC_DEFINE(HAVE_OSS, 1, [Define if you have the Open Sound system])
 486 fi
 487
 488 AC_CACHE_CHECK("for Open Sound System/MIDI interface",
 489         ac_cv_c_opensoundsystem_midi,
 490         AC_TRY_COMPILE([
 491         #if defined(HAVE_SYS_SOUNDCARD_H)
 492                 #include <sys/soundcard.h>
 493         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 494                 #include <machine/soundcard.h>
 495         #elif defined(HAVE_SOUNDCARD_H)
 496                 #include <soundcard.h>
 497         #endif
 498         ],[
 499
 500 /* check for one of the Open Sound System specific SNDCTL_SEQ defines */
 501 #if !defined(SNDCTL_SEQ_SYNC)
 502 #error No open sound system MIDI interface
 503 #endif
 504 ],ac_cv_c_opensoundsystem_midi="yes",ac_cv_c_opensoundsystem_midi="no"))
 505
 506 if test "$ac_cv_c_opensoundsystem_midi" = "yes"
 507 then
 508     AC_DEFINE(HAVE_OSS_MIDI, 1, [Define if you have the Open Sound system (MIDI interface)])
 509 fi
 510
 511 dnl **** If ln -s doesn't work, use cp instead ****
 512 if test "$ac_cv_prog_LN_S" = "ln -s"; then : ; else LN_S=cp ; fi
 513
 514 dnl **** Check for broken glibc mmap64 ****
 515
 516 AC_CACHE_CHECK( "whether mmap64 works defined as mmap", ac_cv_mmap64_works,
 517         AC_TRY_RUN([
 518                 #define _FILE_OFFSET_BITS 64
 519                 #include <stdio.h>
 520                 #include <unistd.h>
 521                 #include <fcntl.h>
 522                 #include <sys/mman.h>
 523                 #include <errno.h>
 524
 525                 int main(int argc,char **argv) {
 526                         int fd = open("conftest.map",O_CREAT|O_RDWR,0600);
 527                         if (fd == -1) exit(1);
 528
 529                         unlink("conftest.map");
 530
 531                         write(fd,"test",4);
 532
 533                         if ((-1 == mmap(0,4,PROT_READ|PROT_WRITE,MAP_SHARED,fd,0)) &&
 534                             (errno == EINVAL)
 535                         ) {
 536                                 exit(1);
 537                         }
 538                         close(fd);
 539                         fprintf(stderr,"success!\n");
 540                         exit(0);
 541                 }
 542
 543         ],
 544     ac_cv_mmap64_works="yes",
 545     ac_cv_mmap64_works="no",
 546     ac_cv_mmap64_works="no") )
 547
 548 if test "$ac_cv_mmap64_works" = "yes"
 549 then
 550     AC_DEFINE(_FILE_OFFSET_BITS, 64, [Set this to 64 to enable 64-bit file support on Linux])
 551 fi
 552
 553 dnl **** Check for gcc strength-reduce bug ****
 554
 555 if test "x${GCC}" = "xyes"
 556 then
 557   CFLAGS="$CFLAGS -Wall"
 558   AC_CACHE_CHECK( "for gcc strength-reduce bug", ac_cv_c_gcc_strength_bug,
 559                   AC_TRY_RUN([
 560 int     L[[4]] = {0,1,2,3};
 561 int main(void) {
 562   static int Array[[3]];
 563   unsigned int B = 3;
 564   int i;
 565   for(i=0; i<B; i++) Array[[i]] = i - 3;
 566   for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
 567   L[[i]] = 4;
 568
 569   exit( Array[[1]] != -2 || L[[2]] != 3);
 570 }],
 571     ac_cv_c_gcc_strength_bug="no",
 572     ac_cv_c_gcc_strength_bug="yes",
 573     ac_cv_c_gcc_strength_bug="yes") )
 574   if test "$ac_cv_c_gcc_strength_bug" = "yes"
 575   then
 576     CFLAGS="$CFLAGS -fno-strength-reduce"
 577   fi
 578
 579   dnl Check for -mpreferred-stack-boundary
 580   AC_CACHE_CHECK("for gcc -mpreferred-stack-boundary=2 support",
 581                  ac_cv_c_gcc_stack_boundary,
 582   [saved_cflags=$CFLAGS
 583   CFLAGS="$CFLAGS -mpreferred-stack-boundary=2"
 584   AC_TRY_COMPILE(,[return 0],ac_cv_c_gcc_stack_boundary="yes",ac_cv_c_gcc_stack_boundary="no")
 585   CFLAGS=$saved_cflags
 586   ])
 587   if test "$ac_cv_c_gcc_stack_boundary" = "yes"
 588   then
 589     CFLAGS="$CFLAGS -mpreferred-stack-boundary=2"
 590   fi
 591 fi
 592
 593 dnl **** Check if we need to place .type inside a .def directive ****
 594
 595 AC_CACHE_CHECK("whether .type must sit inside a .def directive",
 596                ac_cv_c_type_in_def,
 597 [saved_libs=$LIBS
 598 LIBS="conftest_asm.s $LIBS"
 599 cat > conftest_asm.s <<EOF
 600         .globl _ac_test
 601         .def _ac_test; .scl 2; .type 32; .endef
 602 _ac_test:
 603         .long 0
 604 EOF
 605 AC_TRY_LINK(,,ac_cv_c_type_in_def="yes",ac_cv_c_type_in_def="no")
 606 LIBS=$saved_libs])
 607 if test "$ac_cv_c_type_in_def" = "yes"
 608 then
 609   AC_DEFINE(NEED_TYPE_IN_DEF, 1, [Define if .type asm directive must be inside a .def directive])
 610 fi
 611
 612 dnl **** Check for underscore on external symbols ****
 613
 614 AC_CACHE_CHECK("whether external symbols need an underscore prefix",
 615                ac_cv_c_extern_prefix,
 616 [saved_libs=$LIBS
 617 LIBS="conftest_asm.s $LIBS"
 618 cat > conftest_asm.s <<EOF
 619         .globl _ac_test
 620 _ac_test:
 621         .long 0
 622 EOF
 623 AC_TRY_LINK([extern int ac_test;],[if (ac_test) return 1],
 624             ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no")
 625 LIBS=$saved_libs])
 626 if test "$ac_cv_c_extern_prefix" = "yes"
 627 then
 628   AC_DEFINE(NEED_UNDERSCORE_PREFIX, 1,
 629             [Define if symbols declared in assembly code need an underscore prefix])
 630 fi
 631
 632 dnl **** Check for .string in assembler ****
 633
 634 AC_CACHE_CHECK("whether assembler accepts .string",
 635                ac_cv_c_asm_string,
 636 [saved_libs=$LIBS
 637 LIBS="conftest_asm.s $LIBS"
 638 cat > conftest_asm.s <<EOF
 639         .string "test"
 640 EOF
 641 AC_TRY_LINK(,,ac_cv_c_asm_string="yes",ac_cv_c_asm_string="no")
 642 LIBS=$saved_libs])
 643 if test "$ac_cv_c_asm_string" = "yes"
 644 then
 645   AC_DEFINE(HAVE_ASM_STRING, 1, [Define to use .string instead of .ascii])
 646 fi
 647
 648 dnl **** Check for working dll ****
 649
 650 LDSHARED=""
 651 LDDLLFLAGS=""
 652 if test "$LIBEXT" = "so"
 653 then
 654   AC_CACHE_CHECK("whether we can build a GNU style ELF dll",
 655                  ac_cv_c_dll_gnuelf,
 656   [saved_cflags=$CFLAGS
 657   CFLAGS="$CFLAGS -fPIC -shared -Wl,-soname,conftest.so.1.0,-Bsymbolic"
 658   AC_TRY_LINK(,[return 1],ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")
 659   CFLAGS=$saved_cflags
 660   ])
 661   if test "$ac_cv_c_dll_gnuelf" = "yes"
 662   then
 663     LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%) -Wl,-rpath,\$(libdir)"
 664     LDDLLFLAGS="-Wl,-Bsymbolic"
 665   else
 666     AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll,
 667                  ac_cv_c_dll_unixware,
 668     [saved_cflags=$CFLAGS
 669     CFLAGS="$CFLAGS -fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic"
 670     AC_TRY_LINK(,[return 1],ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")
 671     CFLAGS=$saved_cflags
 672     ])
 673     if test "$ac_cv_c_dll_unixware" = "yes"
 674     then
 675       LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,\$(libdir)/%)"
 676       LDDLLFLAGS="-Wl,-B,symbolic"
 677     fi
 678   fi
 679   if test "$ac_cv_c_dll_gnuelf" = "no" -a "$ac_cv_c_dll_unixware" = "no"
 680   then
 681     LIBEXT="a"
 682     if test "$DLLWRAP" = "dllwrap"; then
 683       dnl FIXME - check whether dllwrap works correctly...
 684       if test "$CYGWIN" = "yes"; then
 685         echo "*** use dllwrap for building shared library."
 686         LIBEXT="dll"
 687       fi
 688     fi
 689   fi
 690 fi
 691
 692 if test "$LIBEXT" = "a"; then
 693   echo "*** It is currently not possible to build WINE without shared"
 694   echo "*** library (.so) support to allow transparent switch between .so"
 695   echo "*** and .dll files."
 696   echo "*** If you are using Linux, you will need a newer binutils."
 697   exit 1
 698 fi
 699
 700 DLLFLAGS=""
 701 LDPATH=""
 702
 703 if test "$LIBEXT" = "so"; then
 704     DLLFLAGS="-fPIC"
 705     DLL_LINK="-L\$(DLLDIR) \$(IMPORTS:%=-l%) \$(LIBWINE) \$(LIBUNICODE)"
 706     LDPATH="LD_LIBRARY_PATH=\"\$(TOPOBJDIR)/unicode:\$\$LD_LIBRARY_PATH\""
 707 elif test "$LIBEXT" = "dll"; then
 708     #DLLFLAGS="-fPIC" # -fPIC doesn't work(at least in cygwin-b20) - FIXME
 709     DLL_LINK="-L\$(DLLDIR) \$(IMPORTS:%=-l%) \$(LIBWINE) \$(LIBUNICODE)"
 710     LDPATH="PATH=\"\$(TOPOBJDIR)/unicode:\$\$PATH\""
 711 else
 712     DLL_LINK="-L\$(DLLDIR) \$(DLLS:%=-l%) \$(LIBWINE) \$(LIBUNICODE) \$(X_LIBS) \$(XLIB)"
 713     AC_CACHE_CHECK([whether the linker supports --[[no]]-whole-archive (Linux)],
 714                    ac_cv_c_whole_archive,
 715             [saved_cflags=$CFLAGS
 716             CFLAGS="$CFLAGS -Wl,--whole-archive -Wl,--no-whole-archive"
 717             AC_TRY_LINK(,[return 1],ac_cv_c_whole_archive="yes",ac_cv_c_whole_archive="no")
 718             CFLAGS=$saved_cflags
 719             ])
 720     if test "$ac_cv_c_whole_archive" = "yes"
 721     then
 722         DLL_LINK="-Wl,--whole-archive $DLL_LINK -Wl,--no-whole-archive"
 723     else
 724         AC_CACHE_CHECK([whether the linker supports -z {all,default}extract (Linux)],
 725                        ac_cv_c_allextract,
 726                 [saved_cflags=$CFLAGS
 727                 CFLAGS="$CFLAGS -Wl,-z,allextract -Wl,-z,defaultextract"
 728                 AC_TRY_LINK(,[return 1],ac_cv_c_allextract="yes",ac_cv_c_allextract="no")
 729                 CFLAGS=$saved_cflags
 730                 ])
 731         if test "$ac_cv_c_allextract" = "yes"
 732         then
 733             DLL_LINK="-Wl,-z,allextract $DLL_LINK -Wl,-z,defaultextract"
 734         fi
 735     fi
 736 fi
 737
 738 AC_SUBST(DLL_LINK)
 739 AC_SUBST(DLLFLAGS)
 740 AC_SUBST(LDSHARED)
 741 AC_SUBST(LDDLLFLAGS)
 742 AC_SUBST(LIBEXT)
 743 AC_SUBST(LDPATH)
 744
 745 dnl **** Check for reentrant libc ****
 746 dnl
 747 dnl For cross-compiling we blindly assume that libc is reentrant. This is
 748 dnl ok since non-reentrant libc is quite rare (mostly old libc5 versions).
 749
 750 AC_DEFUN(WINE_CHECK_ERRNO,
 751 [
 752   AC_CACHE_CHECK(for reentrant libc: $1, wine_cv_libc_r_$1,
 753   [AC_TRY_RUN([int myerrno = 0;
 754 char buf[256];
 755 int *$1(){return &myerrno;}
 756 main(){connect(0,buf,255); exit(!myerrno);}],
 757   wine_cv_libc_r_$1=yes, wine_cv_libc_r_$1=no,
 758   wine_cv_libc_r_$1=yes )
 759 ])
 760 if test "$wine_cv_libc_r_$1" = "yes"
 761 then
 762     wine_cv_libc_reentrant=$1
 763 fi
 764 ])
 765
 766 wine_cv_libc_reentrant=no
 767 dnl Linux style errno location
 768 WINE_CHECK_ERRNO(__errno_location)
 769 dnl FreeBSD style errno location
 770 WINE_CHECK_ERRNO(__error)
 771 dnl Solaris style errno location
 772 WINE_CHECK_ERRNO(___errno)
 773 dnl UnixWare style errno location
 774 WINE_CHECK_ERRNO(__thr_errno)
 775 dnl NetBSD style errno location
 776 WINE_CHECK_ERRNO(__errno)
 777
 778 if test "$wine_cv_libc_reentrant" != "no"
 779 then
 780   AC_DEFINE_UNQUOTED(ERRNO_LOCATION,$wine_cv_libc_reentrant,
 781                      [Define to the name of the function returning errno for reentrant libc])
 782 fi
 783
 784 dnl **** Check for reentrant X libraries ****
 785 dnl
 786 dnl This may fail to determine whether X libraries are reentrant if
 787 dnl AC_PATH_XTRA does not set x_libraries. In this case manual configuration
 788 dnl is possible with the --without-reentrant-x option.
 789
 790 if test "$have_x" = "yes" -a "$wine_cv_libc_reentrant" != "no"
 791 then
 792 AC_CACHE_CHECK( "for reentrant X libraries", wine_cv_x_reentrant,
 793   [ if test "x$with_reentrant_x" = "xno"
 794     then
 795         wine_cv_x_reentrant=no
 796     else
 797         libX11_check=none
 798         for dir in "$x_libraries" /usr/lib /usr/local/lib /lib; do
 799             if test -r $dir/libX11.so; then
 800                 libX11_check="-D $dir/libX11.so"
 801                 break 1
 802             fi
 803             if test -r $dir/libX11.a; then
 804                 libX11_check="$dir/libX11.a"
 805                 break 1
 806             fi
 807         done
 808         if test "$libX11_check" != "none"; then
 809             if nm $libX11_check | grep $wine_cv_libc_reentrant >/dev/null 2>&1
 810             then
 811                 wine_cv_x_reentrant=yes
 812             else
 813                 wine_cv_x_reentrant=no
 814             fi
 815         else
 816             wine_cv_x_reentrant=unknown
 817         fi
 818     fi ] )
 819 else
 820     wine_cv_x_reentrant=no
 821 fi
 822 if test "$wine_cv_x_reentrant" = "no"
 823 then
 824   AC_DEFINE(NO_REENTRANT_X11, 1,
 825             [Define if X libraries are not reentrant (compiled without -D_REENTRANT)])
 826 fi
 827
 828
 829 dnl **** Check for functions ****
 830
 831 AC_FUNC_ALLOCA()
 832 AC_CHECK_FUNCS(\
 833         __libc_fork \
 834         _lwp_create \
 835         clone \
 836         ecvt \
 837         finite \
 838         fpclass \
 839         ftruncate64 \
 840         getnetbyaddr \
 841         getnetbyname \
 842         getpagesize \
 843         getprotobyname \
 844         getprotobynumber \
 845         getrlimit \
 846         getservbyport \
 847         getsockopt \
 848         inet_network \
 849         lseek64 \
 850         lstat \
 851         memmove \
 852         mmap \
 853         rfork \
 854         select \
 855         sendmsg \
 856         settimeofday \
 857         sigaltstack \
 858         statfs \
 859         strcasecmp \
 860         strerror \
 861         strncasecmp \
 862         tcgetattr \
 863         timegm \
 864         usleep \
 865         vfscanf \
 866         wait4 \
 867         waitpid \
 868 )
 869
 870 dnl **** Check for header files ****
 871
 872 AC_CHECK_HEADERS(\
 873         arpa/inet.h \
 874         arpa/nameser.h \
 875         elf.h \
 876         float.h \
 877         ieeefp.h \
 878         libio.h \
 879         libutil.h \
 880         link.h \
 881         linux/cdrom.h \
 882         linux/input.h \
 883         linux/joystick.h \
 884         linux/ucdrom.h \
 885         net/if.h \
 886         netdb.h \
 887         netinet/in.h \
 888         netinet/in_systm.h \
 889         netinet/ip.h \
 890         netinet/tcp.h \
 891         pty.h \
 892         resolv.h \
 893         sched.h \
 894         socket.h \
 895         strings.h \
 896         sys/cdio.h \
 897         sys/errno.h \
 898         sys/file.h \
 899         sys/filio.h \
 900         sys/ipc.h \
 901         sys/lwp.h \
 902         sys/mman.h \
 903         sys/modem.h \
 904         sys/mount.h \
 905         sys/msg.h \
 906         sys/param.h \
 907         sys/ptrace.h \
 908         sys/reg.h \
 909         sys/signal.h \
 910         sys/shm.h \
 911         sys/socket.h \
 912         sys/sockio.h \
 913         sys/statfs.h \
 914         sys/strtio.h \
 915         sys/syscall.h \
 916         sys/user.h \
 917         sys/wait.h \
 918         sys/v86.h \
 919         sys/v86intr.h \
 920         sys/vfs.h \
 921         sys/vm86.h \
 922         syscall.h \
 923         ucontext.h \
 924 )
 925 AC_HEADER_STAT()
 926
 927 dnl **** Check for types ****
 928
 929 AC_C_CONST()
 930 AC_C_INLINE()
 931 AC_TYPE_SIZE_T()
 932 AC_CHECK_SIZEOF(long long,0)
 933
 934 AC_CACHE_CHECK("whether linux/input.h is for real",
 935         wine_cv_linux_input_h,
 936         AC_TRY_COMPILE([
 937             #include <linux/input.h>
 938         ] , [
 939             int foo = EVIOCGBIT(EV_ABS,42);
 940             int bar = BTN_PINKIE;
 941             int fortytwo = 42;
 942         ],
 943         wine_cv_linux_input_h=yes,
 944         wine_cv_linux_input_h=no,
 945         no
 946         )
 947     )
 948     if test "$wine_cv_linux_input_h" = "yes"
 949     then
 950         AC_DEFINE(HAVE_CORRECT_LINUXINPUT_H, 1,
 951                   [Define if we have linux/input.h AND it contains the INPUT event API])
 952     fi
 953
 954
 955 AC_CACHE_CHECK("whether we can use re-entrant gethostbyname_r Linux style",
 956         wine_cv_linux_gethostbyname_r_6,
 957         AC_TRY_COMPILE([
 958 #include <netdb.h>
 959         ], [
 960     char *name=NULL;
 961     struct hostent he;
 962     struct hostent *result;
 963     char *buf=NULL;
 964     int bufsize=0;
 965     int res,errnr;
 966     char *addr=NULL;
 967     int addrlen=0;
 968     int addrtype=0;
 969     res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
 970     res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
 971     ],
 972         wine_cv_linux_gethostbyname_r_6=yes,
 973         wine_cv_linux_gethostbyname_r_6=no
 974         )
 975    )
 976    if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
 977    then
 978       AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
 979                 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
 980    fi
 981
 982 if test "$ac_cv_header_linux_joystick_h" = "yes"
 983 then
 984    AC_CACHE_CHECK("whether linux/joystick.h uses the Linux 2.2+ API",
 985         wine_cv_linux_joystick_22_api,
 986         AC_TRY_COMPILE([
 987         #include <sys/ioctl.h>
 988         #include <linux/joystick.h>
 989
 990         struct js_event blub;
 991         #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
 992         #error "no 2.2 header"
 993         #endif
 994         ],/*empty*/,
 995         wine_cv_linux_joystick_22_api=yes,
 996         wine_cv_linux_joystick_22_api=no,
 997         wine_cv_linux_joystick_22_api=no
 998         )
 999    )
1000    if test "$wine_cv_linux_joystick_22_api" = "yes"
1001    then
1002       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1003                 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1004    fi
1005 fi
1006
1007 dnl **** statfs checks ****
1008
1009 if test "$ac_cv_header_sys_vfs_h" = "yes"
1010 then
1011     AC_CACHE_CHECK( "whether sys/vfs.h defines statfs",
1012                     wine_cv_sys_vfs_has_statfs,
1013         AC_TRY_COMPILE([
1014         #include <sys/types.h>
1015         #ifdef HAVE_SYS_PARAM_H
1016         # include <sys/param.h>
1017         #endif
1018         #include <sys/vfs.h>
1019         ],[
1020                 struct statfs stfs;
1021
1022                 memset(&stfs,0,sizeof(stfs));
1023         ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
1024         )
1025     )
1026     if test "$wine_cv_sys_vfs_has_statfs" = "yes"
1027     then
1028       AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS, 1,
1029                 [Define if the struct statfs is defined by <sys/vfs.h>])
1030     fi
1031 fi
1032
1033 if test "$ac_cv_header_sys_statfs_h" = "yes"
1034 then
1035     AC_CACHE_CHECK( "whether sys/statfs.h defines statfs",
1036                     wine_cv_sys_statfs_has_statfs,
1037         AC_TRY_COMPILE([
1038         #include <sys/types.h>
1039         #ifdef HAVE_SYS_PARAM_H
1040         # include <sys/param.h>
1041         #endif
1042         #include <sys/statfs.h>
1043         ],[
1044                 struct statfs stfs;
1045         ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
1046         )
1047     )
1048     if test "$wine_cv_sys_statfs_has_statfs" = "yes"
1049     then
1050       AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS, 1,
1051                 [Define if the struct statfs is defined by <sys/statfs.h>])
1052     fi
1053 fi
1054
1055 if test "$ac_cv_header_sys_mount_h" = "yes"
1056 then
1057     AC_CACHE_CHECK( "whether sys/mount.h defines statfs",
1058                     wine_cv_sys_mount_has_statfs,
1059         AC_TRY_COMPILE([
1060         #include <sys/types.h>
1061         #ifdef HAVE_SYS_PARAM_H
1062         # include <sys/param.h>
1063         #endif
1064         #include <sys/mount.h>
1065         ],[
1066                 struct statfs stfs;
1067         ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
1068         )
1069     )
1070     if test "$wine_cv_sys_mount_has_statfs" = "yes"
1071     then
1072       AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT, 1,
1073                 [Define if the struct statfs is defined by <sys/mount.h>])
1074     fi
1075 fi
1076
1077 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1078
1079 AC_CACHE_CHECK( "for statfs.f_bfree", wine_cv_statfs_bfree,
1080   [ if test "x$statfs_bfree" = "xno"
1081     then
1082         wine_cv_statfs_bfree=no
1083     else
1084         AC_TRY_COMPILE([
1085         #include <sys/types.h>
1086         #ifdef HAVE_SYS_PARAM_H
1087         # include <sys/param.h>
1088         #endif
1089         #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1090         # include <sys/mount.h>
1091         #else
1092         # ifdef STATFS_DEFINED_BY_SYS_VFS
1093         #  include <sys/vfs.h>
1094         # else
1095         #  ifdef STATFS_DEFINED_BY_SYS_STATFS
1096         #   include <sys/statfs.h>
1097         #  endif
1098         # endif
1099         #endif
1100         ],[
1101                 struct statfs stfs;
1102
1103                 stfs.f_bfree++;
1104         ],wine_cv_statfs_bfree=yes,wine_cv_statfs_bfree=no
1105         )
1106     fi ] )
1107 if test "$wine_cv_statfs_bfree" = "yes"
1108 then
1109   AC_DEFINE(STATFS_HAS_BFREE, 1, [Define if the struct statfs has the member bfree])
1110 fi
1111
1112 AC_CACHE_CHECK( "for statfs.f_bavail", wine_cv_statfs_bavail,
1113   [ if test "x$statfs_bavail" = "xno"
1114     then
1115         wine_cv_statfs_bavail=no
1116     else
1117         AC_TRY_COMPILE([
1118         #include <sys/types.h>
1119         #ifdef HAVE_SYS_PARAM_H
1120         # include <sys/param.h>
1121         #endif
1122         #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1123         # include <sys/mount.h>
1124         #else
1125         # ifdef STATFS_DEFINED_BY_SYS_VFS
1126         #  include <sys/vfs.h>
1127         # else
1128         #  ifdef STATFS_DEFINED_BY_SYS_STATFS
1129         #   include <sys/statfs.h>
1130         #  endif
1131         # endif
1132         #endif
1133         ],[
1134                 struct statfs stfs;
1135
1136                 stfs.f_bavail++;
1137         ],wine_cv_statfs_bavail=yes,wine_cv_statfs_bavail=no
1138         )
1139     fi ] )
1140 if test "$wine_cv_statfs_bavail" = "yes"
1141 then
1142   AC_DEFINE(STATFS_HAS_BAVAIL, 1, [Define if the struct statfs has the member bavail])
1143 fi
1144
1145 dnl *** check for file descriptor passing with msg_accrights
1146
1147 AC_CACHE_CHECK("for msg_accrights in struct msghdr", ac_cv_c_msg_accrights,
1148  AC_TRY_COMPILE([#include <sys/types.h>
1149 #include <sys/socket.h>],[struct msghdr hdr; hdr.msg_accrights=0],
1150                 ac_cv_c_msg_accrights="yes", ac_cv_c_msg_accrights="no"))
1151 if test "$ac_cv_c_msg_accrights" = "yes"
1152 then
1153     AC_DEFINE(HAVE_MSGHDR_ACCRIGHTS, 1, [Define if struct msghdr contains msg_accrights])
1154 fi
1155
1156 dnl *** Check for the sun_len member in struct sockaddr_un
1157
1158 AC_CACHE_CHECK("for sun_len in struct sockaddr_un", ac_cv_c_sun_len,
1159  AC_TRY_COMPILE([#include <sys/types.h>
1160 #include <sys/socket.h>
1161 #include <sys/un.h>], [static struct sockaddr_un addr; addr.sun_len = 1],
1162                 ac_cv_c_sun_len="yes", ac_cv_c_sun_len="no"))
1163 if test "$ac_cv_c_sun_len" = "yes"
1164 then
1165     AC_DEFINE(HAVE_SOCKADDR_SUN_LEN, 1, [Define if struct sockaddr_un contains sun_len])
1166 fi
1167
1168 dnl *** check for the need to define __i386__
1169
1170 AC_CACHE_CHECK("whether we need to define __i386__",ac_cv_cpp_def_i386,
1171  AC_EGREP_CPP(yes,[#if (defined(i386) || defined(__i386)) && !defined(__i386__)
1172 yes
1173 #endif],
1174  ac_cv_cpp_def_i386="yes", ac_cv_cpp_def_i386="no"))
1175 if test "$ac_cv_cpp_def_i386" = "yes"
1176 then
1177     CFLAGS="$CFLAGS -D__i386__"
1178     LINTFLAGS="$LINTFLAGS -D__i386__"
1179 fi
1180
1181 dnl $GCC is set by autoconf
1182 GCC_NO_BUILTIN=""
1183 if test "$GCC" = "yes"
1184 then
1185     GCC_NO_BUILTIN="-fno-builtin"
1186 fi
1187 AC_SUBST(GCC_NO_BUILTIN)
1188
1189 dnl **** Generate output files ****
1190
1191 AC_OUTPUT_COMMANDS([
1192 extra_subdirs="\
1193 dlls/ddraw/d3ddevice \
1194 dlls/ddraw/dclipper \
1195 dlls/ddraw/ddraw \
1196 dlls/ddraw/direct3d \
1197 dlls/ddraw/dpalette \
1198 dlls/ddraw/dsurface \
1199 dlls/dinput/joystick \
1200 dlls/dinput/keyboard \
1201 dlls/dinput/mouse \
1202 dlls/kernel/messages \
1203 dlls/user/resources \
1204 dlls/wineps/data \
1205 "
1206 for i in $extra_subdirs; do [ -d $i ] || (echo "creating $i" && mkdir $i); done ])
1207
1208 MAKE_RULES=Make.rules
1209 AC_SUBST_FILE(MAKE_RULES)
1210
1211 MAKE_DLL_RULES=dlls/Makedll.rules
1212 AC_SUBST_FILE(MAKE_DLL_RULES)
1213
1214 MAKE_PROG_RULES=programs/Makeprog.rules
1215 AC_SUBST_FILE(MAKE_PROG_RULES)
1216
1217 AC_OUTPUT([
1218 Make.rules
1219 dlls/Makedll.rules
1220 programs/Makeprog.rules
1221 Makefile
1222 console/Makefile
1223 controls/Makefile
1224 debugger/Makefile
1225 dlls/Makefile
1226 dlls/advapi32/Makefile
1227 dlls/avifil32/Makefile
1228 dlls/comctl32/Makefile
1229 dlls/commdlg/Makefile
1230 dlls/crtdll/Makefile
1231 dlls/dciman32/Makefile
1232 dlls/ddraw/Makefile
1233 dlls/dinput/Makefile
1234 dlls/dplay/Makefile
1235 dlls/dplayx/Makefile
1236 dlls/dsound/Makefile
1237 dlls/gdi/Makefile
1238 dlls/glu32/Makefile
1239 dlls/icmp/Makefile
1240 dlls/imagehlp/Makefile
1241 dlls/imm32/Makefile
1242 dlls/kernel/Makefile
1243 dlls/lzexpand/Makefile
1244 dlls/mpr/Makefile
1245 dlls/msacm/Makefile
1246 dlls/msnet32/Makefile
1247 dlls/msvcrt/Makefile
1248 dlls/msvideo/Makefile
1249 dlls/ntdll/Makefile
1250 dlls/odbc32/Makefile
1251 dlls/ole32/Makefile
1252 dlls/oleaut32/Makefile
1253 dlls/olecli/Makefile
1254 dlls/oledlg/Makefile
1255 dlls/olepro32/Makefile
1256 dlls/olesvr/Makefile
1257 dlls/opengl32/Makefile
1258 dlls/psapi/Makefile
1259 dlls/rasapi32/Makefile
1260 dlls/richedit/Makefile
1261 dlls/rpcrt4/Makefile
1262 dlls/serialui/Makefile
1263 dlls/setupapi/Makefile
1264 dlls/shdocvw/Makefile
1265 dlls/shell32/Makefile
1266 dlls/shfolder/Makefile
1267 dlls/shlwapi/Makefile
1268 dlls/tapi32/Makefile
1269 dlls/ttydrv/Makefile
1270 dlls/urlmon/Makefile
1271 dlls/user/Makefile
1272 dlls/version/Makefile
1273 dlls/win32s/Makefile
1274 dlls/winaspi/Makefile
1275 dlls/winedos/Makefile
1276 dlls/wineps/Makefile
1277 dlls/wininet/Makefile
1278 dlls/winmm/Makefile
1279 dlls/winmm/joystick/Makefile
1280 dlls/winmm/mcianim/Makefile
1281 dlls/winmm/mciavi/Makefile
1282 dlls/winmm/mcicda/Makefile
1283 dlls/winmm/mciseq/Makefile
1284 dlls/winmm/mciwave/Makefile
1285 dlls/winmm/midimap/Makefile
1286 dlls/winmm/wavemap/Makefile
1287 dlls/winmm/wineoss/Makefile
1288 dlls/winnls/Makefile
1289 dlls/winsock/Makefile
1290 dlls/winspool/Makefile
1291 dlls/wintrust/Makefile
1292 dlls/wow32/Makefile
1293 dlls/wsock32/Makefile
1294 dlls/x11drv/Makefile
1295 documentation/Makefile
1296 documentation/wine.conf.man
1297 documentation/wine.man
1298 files/Makefile
1299 graphics/Makefile
1300 graphics/enhmetafiledrv/Makefile
1301 graphics/metafiledrv/Makefile
1302 graphics/win16drv/Makefile
1303 graphics/x11drv/Makefile
1304 if1632/Makefile
1305 include/Makefile
1306 library/Makefile
1307 libtest/Makefile
1308 loader/Makefile
1309 loader/dos/Makefile
1310 loader/ne/Makefile
1311 memory/Makefile
1312 misc/Makefile
1313 miscemu/Makefile
1314 msdos/Makefile
1315 objects/Makefile
1316 ole/Makefile
1317 programs/Makefile
1318 programs/avitools/Makefile
1319 programs/clock/Makefile
1320 programs/cmdlgtst/Makefile
1321 programs/control/Makefile
1322 programs/notepad/Makefile
1323 programs/osversioncheck/Makefile
1324 programs/progman/Makefile
1325 programs/regapi/Makefile
1326 programs/regtest/Makefile
1327 programs/uninstaller/Makefile
1328 programs/view/Makefile
1329 programs/wcmd/Makefile
1330 programs/winemine/Makefile
1331 programs/winetest/Makefile
1332 programs/winhelp/Makefile
1333 programs/winver/Makefile
1334 relay32/Makefile
1335 scheduler/Makefile
1336 server/Makefile
1337 tools/Makefile
1338 tools/cvdump/Makefile
1339 tools/specmaker/Makefile
1340 tools/winebuild/Makefile
1341 tools/winelauncher
1342 tools/wmc/Makefile
1343 tools/wrc/Makefile
1344 tsx11/Makefile
1345 unicode/Makefile
1346 win32/Makefile
1347 windows/Makefile
1348 windows/x11drv/Makefile ])
1349
1350 if test "$have_x" = "no"
1351 then
1352   echo
1353   echo "*** Warning: X development files not found. Wine will be built without"
1354   echo "*** X support, which currently does not work, and would probably not be"
1355   echo "*** what you want anyway. You will need to install devel packages of"
1356   echo "*** Xlib/Xfree86 and Xpm at the very least."
1357 elif test "$ac_cv_lib_Xpm_XpmCreatePixmapFromData" = "no"
1358 then
1359   echo
1360   echo "*** Warning: Xpm development files not found. Wine will be built without"
1361   echo "*** Xpm support, which currently does not work. You will need to install"
1362   echo "*** devel packages of Xpm."
1363 fi
1364
1365 if test "$ac_cv_lib_ncurses_resizeterm" = "no" -a "$ac_cv_lib_ncurses_waddch" = "yes"
1366 then
1367   echo
1368   echo "*** Warning: resizeterm not found in ncurses. Wine will be built without"
1369   echo "*** terminal resize support. Consider upgrading ncurses."
1370 fi
1371
1372 if test "$wine_cv_libc_reentrant" = "no"
1373 then
1374   echo
1375   echo "*** Warning: non-reentrant libc detected. Wine will be build without"
1376   echo "*** thread support. Consider upgrading libc to a more recent"
1377   echo "*** reentrant version of libc."
1378 fi
1379
1380 if test "$wine_cv_opengl_version_OK" = "no"
1381 then
1382   echo
1383   echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
1384   echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)."
1385 fi
1386
1387 if test "$wine_cv_opengl_version_threadsafe" = "yes" -a $OPENGL = "normal"
1388 then
1389   echo
1390   echo "*** Warning: the OpenGL version you have installed relies on libpthread for"
1391   echo "*** thread-safety. To prevent crashes, OpenGL support has been removed."
1392   echo "*** A fix for glibc 2.1.3 that seems to work is included in this version of Wine,"
1393   echo "*** start configure with '--enable-opengl' to force OpenGL support."
1394 fi
1395
1396 if test "$wine_cv_opengl_version_threadsafe" = "yes" -a $OPENGL = "yes"
1397 then
1398   echo
1399   echo "*** Warning: you explicitly linked in a thread-safe OpenGL version. If you"
1400   echo "*** experience unusual crashes on DirectDraw games, try first to disable OpenGL"
1401   echo "*** support before reporting bugs."
1402 fi
1403
1404 if test "$wine_cv_warn_cups_h" = "yes"
1405 then
1406   echo
1407   echo "*** Note: You have cups runtime libraries, but no development"
1408   echo "*** libraries. Install the cups-devel package or whichever package"
1409   echo "*** contains cups.h to enable CUPS support in WINE."
1410 fi
1411
1412 if test "$wine_cv_msg_freetype" = "yes"
1413 then
1414   echo
1415   echo "*** Note: Your system appears to have the FreeType 2 runtime libraries"
1416   echo "*** installed, but 'freetype-config' is not in your PATH. Install the"
1417   echo "*** freetype-devel package (or its equivalent on your distribution) to"
1418   echo "*** enable Wine to use TrueType fonts."
1419 fi
1420
1421 echo
1422 echo "Configure finished.  Do 'make depend && make' to compile Wine."
1423 echo
1424
1425 dnl Local Variables:
1426 dnl comment-start: "dnl "
1427 dnl comment-end: ""
1428 dnl comment-start-skip: "\\bdnl\\b\\s *"
1429 dnl compile-command: "autoconf"
1430 dnl End: