git.oblomov.eu Git - wine/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Original author: Michael Patra
   3 dnl See ChangeLog file for detailed change history.
   4
   5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
   6
   7 AC_PREREQ(2.53b)
   8 AC_INIT([Wine],WINE_VERSION,[wine-devel@winehq.org])
   9 AC_CONFIG_SRCDIR(server/atom.c)
  10 AC_CONFIG_HEADERS(include/config.h)
  11 AC_CONFIG_AUX_DIR(tools)
  12
  13 dnl **** Command-line arguments ****
  14
  15 AC_ARG_ENABLE(win16, AC_HELP_STRING([--disable-win16],[do not include Win16 support]))
  16 AC_ARG_ENABLE(win64, AC_HELP_STRING([--enable-win64], [build a Win64 emulator on AMD64 (won't run Win32 binaries)]))
  17
  18 AC_ARG_WITH(opengl,    AC_HELP_STRING([--without-opengl],[do not use OpenGL]))
  19 AC_ARG_WITH(curses,    AC_HELP_STRING([--without-curses],[do not use curses]))
  20 AC_ARG_WITH(wine-tools,AC_HELP_STRING([--with-wine-tools=<dir>],[use Wine tools from directory <dir>]))
  21
  22 AC_CANONICAL_HOST
  23 case $host in
  24   x86_64*linux*)
  25     if test "x$enable_win64" != "xyes"
  26     then
  27       test -n "$CC" || CC="gcc -m32"
  28       test -n "$LD" || LD="ld -m elf_i386"
  29       test -n "$AS" || AS="as --32"
  30       host_cpu="i386"
  31     fi
  32     ;;
  33 esac
  34
  35 dnl enable_win16 defaults to yes on x86, to no on other CPUs
  36 case $host_cpu in
  37   *i[[3456789]]86*)
  38     if test "x$enable_win16" != "xno"
  39     then
  40       enable_win16="yes"
  41     fi
  42     ;;
  43 esac
  44
  45 AC_SUBST(WIN16_FILES,"\$(WIN16_FILES)")
  46 AC_SUBST(WIN16_INSTALL,"\$(WIN16_INSTALL)")
  47 if test "x$enable_win16" != "xyes"
  48 then
  49   WIN16_FILES=""
  50   WIN16_INSTALL=""
  51 fi
  52
  53 dnl **** Check for some programs ****
  54
  55 AC_PROG_MAKE_SET
  56 AC_PROG_CC
  57 AC_PROG_CXX
  58 dnl We can't use AC_PROG_CPP for winegcc, it uses by default $(CC) -E
  59 AC_CHECK_TOOL(CPPBIN,cpp,cpp)
  60
  61 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
  62   [if test -z "$with_wine_tools"; then
  63      if test "$cross_compiling" = "yes"; then
  64        AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
  65      else
  66        wine_cv_toolsdir="\$(TOPOBJDIR)"
  67      fi
  68    elif test -d "$with_wine_tools/tools/winebuild"; then
  69      case $with_wine_tools in
  70        /*) wine_cv_toolsdir="$with_wine_tools" ;;
  71        *)  wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
  72      esac
  73    else
  74      AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
  75    fi])
  76 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
  77
  78 AC_PATH_XTRA
  79 AC_PROG_LEX
  80
  81 dnl **** Just additional warning checks, since AC_PROG just sets 'lex' even
  82 dnl **** without one present.
  83 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
  84 if test "$XLEX" = "none"
  85 then
  86   AC_MSG_ERROR([no suitable lex found. Please install the 'flex' package.])
  87 fi
  88
  89 dnl Check for bison
  90 AC_CHECK_PROGS(BISON,bison,none)
  91 if test "$BISON" = "none"
  92 then
  93   AC_MSG_ERROR([no suitable bison found. Please install the 'bison' package.])
  94 fi
  95
  96 AC_CHECK_TOOLS(AS,[gas as],as)
  97 AC_CHECK_TOOL(LD,ld,ld)
  98 AC_CHECK_TOOL(AR,ar,ar)
  99 AC_PROG_RANLIB
 100 AC_CHECK_TOOL(STRIP,strip,strip)
 101 AC_CHECK_TOOL(WINDRES,windres,false)
 102 AC_PROG_LN_S
 103 WINE_PROG_LN
 104 AC_PROG_EGREP
 105 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
 106 AC_PROG_INSTALL
 107 dnl Prepend src dir to install path dir if it's a relative path
 108 case "$INSTALL" in
 109   [[\\/$]]* | ?:[[\\/]]* ) ;;
 110   *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
 111 esac
 112
 113 dnl Check for lint
 114 AC_CHECK_PROGS(LINT, lclint lint)
 115 if test "$LINT" = "lint"
 116 then
 117   LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
 118   dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
 119 fi
 120 AC_SUBST(LINT)
 121 AC_SUBST(LINTFLAGS)
 122
 123 dnl Check for various programs
 124 AC_CHECK_PROGS(FONTFORGE, fontforge, false)
 125 AC_CHECK_PROGS(PKG_CONFIG, pkg-config, false)
 126
 127 case $host_cpu in
 128   *i[[3456789]]86*)
 129     AC_PATH_PROG(PRELINK, prelink, false, [/sbin /usr/sbin $PATH])
 130     ;;
 131 esac
 132
 133 dnl **** Check for some libraries ****
 134
 135 dnl Check for -li386 for NetBSD and OpenBSD
 136 AC_CHECK_LIB(i386,i386_set_ldt)
 137 dnl Check for -lossaudio for NetBSD
 138 AC_CHECK_LIB(ossaudio,_oss_ioctl)
 139 dnl Check for -lnsl for Solaris
 140 AC_CHECK_FUNCS(gethostbyname,,AC_CHECK_LIB(nsl,gethostbyname))
 141 dnl Check for -lsocket for Solaris
 142 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
 143 dnl Check for -lresolv for Solaris
 144 AC_CHECK_FUNCS(inet_aton,,AC_CHECK_LIB(resolv,inet_aton))
 145 dnl Check for -lxpg4 for FreeBSD
 146 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
 147 dnl Check for -lpoll for Mac OS X/Darwin
 148 AC_CHECK_LIB(poll,poll)
 149 dnl Check for -lpthread
 150 AC_CHECK_LIB(pthread,pthread_create,AC_SUBST(LIBPTHREAD,"-lpthread"))
 151
 152 AC_SUBST(XLIB,"")
 153 AC_SUBST(XFILES,"")
 154 AC_SUBST(OPENGLFILES,"")
 155 AC_SUBST(GLU32FILES,"")
 156 AC_SUBST(OPENGL_LIBS,"")
 157
 158 dnl **** Check for header files ****
 159
 160 AC_CHECK_HEADERS(\
 161         AudioUnit/AudioUnit.h \
 162         CoreAudio/CoreAudio.h \
 163         IOKit/IOKitLib.h \
 164         alsa/asoundlib.h \
 165         arpa/inet.h \
 166         arpa/nameser.h \
 167         asm/types.h \
 168         capi20.h \
 169         cups/cups.h \
 170         curses.h \
 171         direct.h \
 172         dlfcn.h \
 173         elf.h \
 174         float.h \
 175         fontconfig/fontconfig.h \
 176         getopt.h \
 177         gif_lib.h \
 178         ieeefp.h \
 179         io.h \
 180         jack/jack.h \
 181         jpeglib.h \
 182         lber.h \
 183         lcms.h \
 184         lcms/lcms.h \
 185         ldap.h \
 186         libaudioio.h \
 187         link.h \
 188         linux/cdrom.h \
 189         linux/compiler.h \
 190         linux/hdreg.h \
 191         linux/input.h \
 192         linux/ioctl.h \
 193         linux/joystick.h \
 194         linux/major.h \
 195         linux/param.h \
 196         linux/serial.h \
 197         linux/ucdrom.h \
 198         mach/machine.h \
 199         machine/cpu.h \
 200         machine/limits.h \
 201         machine/soundcard.h \
 202         mntent.h \
 203         ncurses.h \
 204         netdb.h \
 205         netinet/in.h \
 206         netinet/in_systm.h \
 207         netinet/tcp.h \
 208         netinet/tcp_fsm.h \
 209         openssl/err.h \
 210         openssl/ssl.h \
 211         poll.h \
 212         process.h \
 213         pthread.h \
 214         pwd.h \
 215         regex.h \
 216         sched.h \
 217         scsi/scsi.h \
 218         scsi/scsi_ioctl.h \
 219         scsi/sg.h \
 220         soundcard.h \
 221         stdint.h \
 222         strings.h \
 223         sys/asoundlib.h \
 224         sys/cdio.h \
 225         sys/elf32.h \
 226         sys/epoll.h \
 227         sys/errno.h \
 228         sys/event.h \
 229         sys/exec_elf.h \
 230         sys/filio.h \
 231         sys/ioctl.h \
 232         sys/ipc.h \
 233         sys/limits.h \
 234         sys/link.h \
 235         sys/lwp.h \
 236         sys/mman.h \
 237         sys/modem.h \
 238         sys/msg.h \
 239         sys/mtio.h \
 240         sys/param.h \
 241         sys/poll.h \
 242         sys/prctl.h \
 243         sys/ptrace.h \
 244         sys/reg.h \
 245         sys/resource.h \
 246         sys/scsiio.h \
 247         sys/shm.h \
 248         sys/signal.h \
 249         sys/socket.h \
 250         sys/sockio.h \
 251         sys/soundcard.h \
 252         sys/statvfs.h \
 253         sys/strtio.h \
 254         sys/syscall.h \
 255         sys/sysctl.h \
 256         sys/time.h \
 257         sys/times.h \
 258         sys/uio.h \
 259         sys/un.h \
 260         sys/vm86.h \
 261         sys/wait.h \
 262         syscall.h \
 263         termios.h \
 264         unicode/ubidi.h \
 265         unistd.h \
 266         utime.h \
 267         valgrind/memcheck.h
 268 )
 269 AC_HEADER_STAT()
 270
 271 dnl **** Checks for headers that depend on other ones ****
 272
 273 AC_CHECK_HEADERS([sys/mount.h sys/statfs.h sys/user.h sys/vfs.h],,,
 274     [#include <sys/types.h>
 275      #if HAVE_SYS_PARAM_H
 276      # include <sys/param.h>
 277      #endif])
 278
 279 AC_CHECK_HEADERS([net/if.h net/if_arp.h net/if_dl.h net/if_types.h net/route.h netipx/ipx.h],,,
 280     [#include <sys/types.h>
 281      #if HAVE_SYS_SOCKET_H
 282      # include <sys/socket.h>
 283      #endif])
 284
 285 AC_CHECK_HEADERS([resolv.h],,,
 286     [#include <sys/types.h>
 287      #if HAVE_SYS_SOCKET_H
 288      # include <sys/socket.h>
 289      #endif
 290      #if HAVE_NETINET_IN_H
 291      # include <netinet/in.h>
 292      #endif
 293      #if HAVE_ARPA_NAMESER_H
 294      # include <arpa/nameser.h>
 295      #endif])
 296
 297 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
 298
 299 AC_CHECK_HEADERS([linux/ipx.h linux/videodev.h],,,
 300 [#ifdef HAVE_SYS_TIME_H
 301 #include <sys/time.h>
 302 #endif
 303 #include <sys/types.h>
 304 #ifdef HAVE_ASM_TYPES_H
 305 #include <asm/types.h>
 306 #endif])
 307
 308 dnl Check for broken kernel header that doesn't define __user
 309 AC_CHECK_HEADERS([linux/capi.h],,,[#define __user])
 310
 311 dnl **** Check for X11 ****
 312
 313 if test "$have_x" = "yes"
 314 then
 315     XLIB="-lXext -lX11"
 316     ac_save_CPPFLAGS="$CPPFLAGS"
 317     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 318
 319     dnl *** All of the following tests require X11/Xlib.h
 320     AC_CHECK_HEADERS([X11/Xlib.h \
 321                       X11/XKBlib.h \
 322                       X11/Xutil.h \
 323                       X11/extensions/shape.h \
 324                       X11/extensions/XInput.h \
 325                       X11/extensions/XShm.h \
 326                       X11/extensions/Xrandr.h \
 327                       X11/extensions/Xrender.h \
 328                       X11/extensions/xf86vmode.h],,,
 329 [#ifdef HAVE_X11_XLIB_H
 330 # include <X11/Xlib.h>
 331 #endif
 332 #ifdef HAVE_X11_XUTIL_H
 333 # include <X11/Xutil.h>
 334 #endif])
 335
 336         dnl *** Check for X keyboard extension
 337         if test "$ac_cv_header_X11_XKBlib_h" = "yes"
 338         then
 339               AC_CHECK_LIB(X11, XkbQueryExtension,
 340               AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
 341               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 342         fi
 343
 344         dnl *** Check for X Shm extension
 345         if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
 346         then
 347               AC_CHECK_LIB(Xext, XShmQueryExtension,
 348               AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
 349               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 350         fi
 351
 352         dnl *** Check for X shape extension
 353         if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
 354         then
 355               AC_CHECK_LIB(Xext,XShapeQueryExtension,
 356               AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
 357               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 358         fi
 359
 360         dnl *** Check for XFree86 VMODE extension
 361         if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
 362         then
 363                 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
 364                   [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
 365                      X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
 366                   ],,
 367                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 368         fi
 369
 370         dnl *** Check for X RandR extension
 371         if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes"
 372         then
 373                 AC_TRY_COMPILE([#include <X11/Xlib.h>
 374 #include <X11/extensions/Xrandr.h>],[static typeof(XRRSetScreenConfigAndRate) * func;],
 375                   [AC_DEFINE(HAVE_LIBXRANDR, 1, [Define if you have the Xrandr library])])
 376         fi
 377
 378         dnl *** Check for Transform functions in Xrender
 379         if test "$ac_cv_header_X11_extensions_Xrender_h" = "yes"
 380         then
 381               AC_CHECK_LIB(Xrender, XRenderSetPictureTransform,
 382                 [AC_DEFINE(HAVE_XRENDERSETPICTURETRANSFORM, 1,
 383                  [Define if Xrender has the XRenderSetPictureTransform function])],,
 384                 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 385         fi
 386     dnl *** End of X11/Xlib.h check
 387
 388     dnl Check for the presence of OpenGL
 389     if test "x$with_opengl" != "xno"
 390     then
 391         AC_CHECK_HEADERS(GL/gl.h GL/glx.h GL/glext.h GL/glu.h,,,
 392 [#ifdef HAVE_GL_GLX_H
 393 # include <GL/glx.h>
 394 #endif])
 395         if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
 396         then
 397             dnl Check for some problems due to old Mesa versions
 398             AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_version_OK,
 399               AC_TRY_COMPILE(
 400                 [#include <GL/gl.h>],
 401                 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
 402                 [wine_cv_opengl_version_OK="yes"],
 403                 [wine_cv_opengl_version_OK="no"]
 404               )
 405             )
 406
 407             if test "$wine_cv_opengl_version_OK" = "yes"
 408             then
 409                 dnl Check for the presence of the library
 410                 AC_CHECK_LIB(GL,glXCreateContext,
 411                              OPENGL_LIBS="-lGL"
 412                              ,,
 413                              $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 414
 415                 if test "$ac_cv_lib_GL_glXCreateContext" = "yes"
 416                 then
 417                         OPENGLFILES='$(OPENGLFILES)'
 418                         AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])
 419                 else
 420                     if test -f /usr/X11R6/lib/libGL.a
 421                     then
 422                        AC_MSG_ERROR([/usr/X11R6/lib/libGL.a is present on your system.
 423 This prevents linking to OpenGL. Delete the file and restart configure.])
 424                     fi
 425                 fi
 426
 427                 dnl Check for GLU32 library.
 428                 AC_CHECK_LIB(GLU,gluLookAt,
 429                              [OPENGL_LIBS="$OPENGL_LIBS -lGLU"
 430                              GLU32FILES='$(GLU32FILES)']
 431                              ,,
 432                              $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
 433                 )
 434              fi
 435
 436              dnl Check for glut32 library.
 437              AC_CHECK_LIB(glut,glutMainLoop,
 438                        [AC_SUBST(GLUT_LIBS,"-lglut -lXmu -lXi")
 439                         AC_SUBST(GLUT32FILES,'$(GLUT32FILES)')],,
 440                         $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXmu -lXi -lX11 $X_EXTRA_LIBS)
 441          fi
 442     fi
 443
 444     dnl **** Check for NAS ****
 445     AC_SUBST(NASLIBS,"")
 446     AC_CHECK_HEADERS(audio/audiolib.h,
 447          [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
 448           AC_CHECK_LIB(audio,AuCreateFlow,
 449                        [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
 450                         NASLIBS="-laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],,
 451                        [-lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
 452
 453     CPPFLAGS="$ac_save_CPPFLAGS"
 454     XFILES='$(XFILES)'
 455 else
 456     XLIB=""
 457     X_CFLAGS=""
 458     X_LIBS=""
 459 fi
 460
 461 dnl **** Check for libxml2 ****
 462
 463 AC_SUBST(XML2LIBS,"")
 464 AC_SUBST(XML2INCL,"")
 465 AC_SUBST(XSLTLIBS,"")
 466 AC_SUBST(XSLTINCL,"")
 467 if test "$PKG_CONFIG" != "false"
 468 then
 469     ac_save_CPPFLAGS="$CPPFLAGS"
 470     ac_xml_libs="`$PKG_CONFIG --libs libxml-2.0 2>/dev/null`"
 471     ac_xml_cflags="`$PKG_CONFIG --cflags libxml-2.0 2>/dev/null`"
 472     CPPFLAGS="$CPPFLAGS $ac_xml_cflags"
 473     AC_CHECK_HEADERS(libxml/parser.h,
 474         [AC_CHECK_LIB(xml2, xmlParseMemory,
 475             [AC_DEFINE(HAVE_LIBXML2, 1, [Define if you have the libxml2 library])
 476              XML2LIBS="$ac_xml_libs"
 477              XML2INCL="$ac_xml_cflags"],,$ac_xml_libs)
 478          AC_CHECK_LIB(xml2, xmlReadMemory,
 479             [AC_DEFINE(HAVE_XMLREADMEMORY,1,[Define if libxml2 has the xmlReadMemory function])],,$ac_xml_libs)
 480         ])
 481     CPPFLAGS="$ac_save_CPPFLAGS"
 482     ac_xslt_libs="`$PKG_CONFIG --libs libxslt 2>/dev/null`"
 483     ac_xslt_cflags="`$PKG_CONFIG --cflags libxslt 2>/dev/null`"
 484     CPPFLAGS="$CPPFLAGS $ac_xslt_cflags"
 485     AC_CHECK_HEADERS([libxslt/pattern.h libxslt/transform.h],
 486         [AC_CHECK_LIB(xslt, xsltCompilePattern,
 487             [AC_DEFINE(HAVE_LIBXSLT, 1, [Define if you have the libxslt library])
 488              XSLTLIBS="$ac_xslt_libs"
 489              XSLTINCL="$ac_xslt_cflags"],,$ac_xslt_libs)
 490         ],,
 491 [#ifdef HAVE_LIBXSLT_PATTERN_H
 492 # include <libxslt/pattern.h>
 493 #endif])
 494     CPPFLAGS="$ac_save_CPPFLAGS"
 495 fi
 496
 497 dnl **** Check for libhal ****
 498 AC_SUBST(HALINCL,"")
 499 if test "$PKG_CONFIG" != "false"
 500 then
 501     ac_save_CPPFLAGS="$CPPFLAGS"
 502     ac_hal_libs="`$PKG_CONFIG --libs hal 2>/dev/null`"
 503     ac_hal_cflags="`$PKG_CONFIG --cflags hal 2>/dev/null`"
 504     CPPFLAGS="$CPPFLAGS $ac_hal_cflags"
 505     AC_CHECK_HEADERS([dbus/dbus.h hal/libhal.h])
 506     if test "$ac_cv_header_dbus_dbus_h" = "yes" -a "$ac_cv_header_hal_libhal_h" = "yes"
 507     then
 508         AC_CHECK_LIB(hal, libhal_ctx_new,
 509           [AC_CHECK_LIB(dbus-1, dbus_connection_close,
 510             [AC_DEFINE(HAVE_LIBHAL, 1, [Define if you have the hal library])
 511              HALINCL="$ac_hal_cflags"],,$ac_hal_libs)])
 512     fi
 513     CPPFLAGS="$ac_save_CPPFLAGS"
 514 fi
 515
 516 dnl **** Check which curses lib to use ***
 517 CURSESLIBS=""
 518 if test "x$with_curses" != "xno"
 519 then
 520     if test "$ac_cv_header_ncurses_h" = "yes"
 521     then
 522         AC_CHECK_LIB(ncurses,waddch,
 523             [AC_DEFINE(HAVE_LIBNCURSES, 1, [Define if you have the ncurses library (-lncurses)])
 524              CURSESLIBS="-lncurses"])
 525     elif test "$ac_cv_header_curses_h" = "yes"
 526     then
 527         AC_CHECK_LIB(curses,waddch,
 528             [AC_DEFINE(HAVE_LIBCURSES, 1, [Define if you have the curses library (-lcurses)])
 529              CURSESLIBS="-lcurses"])
 530     fi
 531     ac_save_LIBS="$LIBS"
 532     LIBS="$LIBS $CURSESLIBS"
 533     AC_CHECK_FUNCS(mousemask)
 534     LIBS="$ac_save_LIBS"
 535 fi
 536 AC_SUBST(CURSESLIBS)
 537
 538 dnl **** Check for SANE ****
 539 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
 540 AC_SUBST(SANELIBS,"")
 541 AC_SUBST(SANEINCL,"")
 542 if test "$sane_devel" != "no"
 543 then
 544     SANELIBS="`$sane_devel --libs`"
 545     SANEINCL="`$sane_devel --cflags`"
 546     ac_save_CPPFLAGS="$CPPFLAGS"
 547     ac_save_LIBS="$LIBS"
 548     CPPFLAGS="$CPPFLAGS $SANEINCL"
 549     LIBS="$LIBS $SANELIBS"
 550     AC_CHECK_HEADER(sane/sane.h,
 551                     [AC_CHECK_LIB(sane,sane_open,
 552                                   [AC_DEFINE(HAVE_SANE, 1, [Define if we have SANE development environment])],
 553                                   [SANELIBS=""
 554                                   SANEINCL=""])],
 555                     [SANELIBS=""
 556                     SANEINCL=""])
 557     LIBS="$ac_save_LIBS"
 558     CPPFLAGS="$ac_save_CPPFLAGS"
 559 fi
 560
 561 dnl **** Check for libgphoto2 ****
 562 AC_CHECK_PROG(gphoto2_devel,gphoto2-config,gphoto2-config,no)
 563 AC_CHECK_PROG(gphoto2port_devel,gphoto2-port-config,gphoto2-port-config,no)
 564 AC_SUBST(GPHOTO2LIBS,"")
 565 AC_SUBST(GPHOTO2INCL,"")
 566 if test "$gphoto2_devel" != "no" -a "$gphoto2port_devel" != "no"
 567 then
 568     GPHOTO2INCL="`$gphoto2_devel --cflags` `$gphoto2port_devel --cflags`"
 569     GPHOTO2LIBS=""
 570     for i in `$gphoto2_devel --libs` `$gphoto2port_devel --libs`
 571     do
 572       case "$i" in
 573         -L/usr/lib|-L/usr/lib64) ;;
 574         -L*|-l*) GPHOTO2LIBS="$GPHOTO2LIBS $i";;
 575       esac
 576     done
 577     ac_save_CPPFLAGS="$CPPFLAGS"
 578     ac_save_LIBS="$LIBS"
 579     CPPFLAGS="$CPPFLAGS $GPHOTO2INCL"
 580     LIBS="$LIBS $GPHOTO2LIBS"
 581     AC_CHECK_HEADER(gphoto2-camera.h,
 582                     [AC_CHECK_LIB(gphoto2,gp_camera_new,
 583                                   [AC_DEFINE(HAVE_GPHOTO2, 1, [Define if we have libgphoto2 development environment])],
 584                                   [GPHOTO2LIBS=""
 585                                   GPHOTO2INCL=""])],
 586                     [GPHOTO2LIBS=""
 587                     GPHOTO2INCL=""])
 588     LIBS="$ac_save_LIBS"
 589     CPPFLAGS="$ac_save_CPPFLAGS"
 590 fi
 591
 592 dnl **** Check for the ICU library ****
 593 if test "$ac_cv_header_unicode_ubidi_h" = "yes"
 594 then
 595     saved_libs="$LIBS"
 596     for i in ${ICU_LIB_DIR-/usr/lib}/libsicu ${ICU_LIB_DIR-/usr/lib}/libicu
 597     do
 598         TEST_ICUUC_LIB="${ICUUC_LIB-${i}uc.a}"
 599         TEST_ICUDATA_LIB="${ICUDATA_LIB-${i}data.a}"
 600         AC_MSG_CHECKING(whether can link with ICU libraries $TEST_ICUUC_LIB and $TEST_ICUDATA_LIB)
 601         LIBS="$saved_libs $TEST_ICUUC_LIB $TEST_ICUDATA_LIB -lstdc++ -lgcc_s"
 602         AC_TRY_LINK([#include <unicode/ubidi.h>],[ubidi_open()],
 603                     [AC_DEFINE(HAVE_ICU,1,[Define to 1 if the ICU libraries are installed])
 604                      AC_SUBST(ICULIBS,"$TEST_ICUUC_LIB $TEST_ICUDATA_LIB -lstdc++ -lgcc_s")
 605                      AC_MSG_RESULT(yes)],
 606                     [AC_MSG_RESULT(no)])
 607     done
 608     LIBS="$saved_libs"
 609 fi
 610
 611 dnl **** Check for resolver library ***
 612 AC_SUBST(RESOLVLIBS,"")
 613 if test "$ac_cv_header_resolv_h" = "yes"
 614 then
 615     AC_CHECK_LIB(resolv, res_query,
 616         [AC_DEFINE(HAVE_RESOLV, 1, [Define if you have the resolver library and header])
 617          RESOLVLIBS="-lresolv"])
 618 fi
 619
 620 dnl **** Check for LittleCMS ***
 621 AC_SUBST(LCMSLIBS,"")
 622 if test "$ac_cv_header_lcms_h" = "yes" -o "$ac_cv_header_lcms_lcms_h" = "yes"
 623 then
 624     AC_CHECK_LIB(lcms, cmsOpenProfileFromFile,
 625         [AC_DEFINE(HAVE_LCMS, 1, [Define if you have the LittleCMS development environment])
 626          LCMSLIBS="-llcms"])
 627 fi
 628
 629 dnl **** Check for OpenLDAP ***
 630 AC_SUBST(LDAPLIBS,"")
 631 if test "$ac_cv_header_ldap_h" = "yes" -a "$ac_cv_header_lber_h" = "yes"
 632 then
 633     AC_CHECK_LIB(ldap_r, ldap_initialize,
 634         [AC_CHECK_LIB(lber, ber_init,
 635             [AC_DEFINE(HAVE_LDAP, 1, [Define if you have the OpenLDAP development environment])
 636              LDAPLIBS="-lldap_r -llber"],,
 637              [$LIBPTHREAD])],,
 638              [$LIBPTHREAD])
 639     WINE_CHECK_LIB_FUNCS(\
 640         ldap_count_references \
 641         ldap_first_reference \
 642         ldap_next_reference \
 643         ldap_parse_reference,
 644         [$LDAPLIBS $LIBPTHREAD])
 645 fi
 646
 647 dnl **** Check for FreeType 2 ****
 648 AC_SUBST(FREETYPELIBS,"")
 649 AC_SUBST(FREETYPEINCL,"")
 650 AC_CHECK_PROG(ft_devel,freetype-config,freetype-config,no)
 651 if test "$ft_devel" = "no"
 652 then
 653     AC_CHECK_PROG(ft_devel2,freetype2-config,freetype2-config,no)
 654     if test "$ft_devel2" = "freetype2-config"
 655     then
 656         ft_devel=$ft_devel2
 657     fi
 658 fi
 659
 660 if test "$ft_devel" = "no"
 661 then
 662     wine_cv_msg_freetype=yes
 663 else
 664     FREETYPELIBS=`$ft_devel --libs`
 665     FREETYPEINCL=`$ft_devel --cflags`
 666     AC_CHECK_LIB(freetype,FT_Init_FreeType,ft_lib=yes,ft_lib=no,$FREETYPELIBS)
 667     if test "$ft_lib" = "no"
 668     then
 669         wine_cv_msg_freetype=yes
 670         FREETYPELIBS=""
 671         FREETYPEINCL=""
 672     else
 673         ac_save_CPPFLAGS="$CPPFLAGS"
 674         CPPFLAGS="$FREETYPEINCL $CPPFLAGS"
 675         AC_CHECK_HEADERS(ft2build.h \
 676                          freetype/freetype.h \
 677                          freetype/ftglyph.h \
 678                          freetype/tttables.h \
 679                          freetype/ftnames.h \
 680                          freetype/ftsnames.h \
 681                          freetype/ttnameid.h \
 682                          freetype/ftoutln.h \
 683                          freetype/ftwinfnt.h \
 684                          freetype/ftmodapi.h \
 685                          freetype/internal/sfnt.h,,,
 686                          [#if HAVE_FT2BUILD_H
 687                           #include <ft2build.h>
 688                           #endif])
 689         AC_TRY_CPP([#include <ft2build.h>
 690                     #include <freetype/fttrigon.h>],
 691                     [AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
 692           [Define if you have the <freetype/fttrigon.h> header file.])
 693                     wine_cv_fttrigon=yes],
 694                     wine_cv_fttrigon=no)
 695         AC_CHECK_TYPES(FT_TrueTypeEngineType,,,[#include <freetype/ftmodapi.h>])
 696         ac_save_CFLAGS="$CFLAGS"
 697         CFLAGS="$CFLAGS $FREETYPELIBS"
 698         AC_CHECK_FUNCS(FT_Load_Sfnt_Table)
 699         CFLAGS="$ac_save_CFLAGS"
 700         CPPFLAGS="$ac_save_CPPFLAGS"
 701         dnl Check that we have at least freetype/freetype.h
 702         if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
 703         then
 704             AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
 705             wine_cv_msg_freetype=no
 706         else
 707             FREETYPELIBS=""
 708             FREETYPEINCL=""
 709             wine_cv_msg_freetype=yes
 710         fi
 711     fi
 712 fi
 713
 714 dnl Only build the fonts dir if we have both freetype and fontforge
 715 if test "$FONTFORGE" != "false" -a -n "$FREETYPELIBS"
 716 then
 717   AC_SUBST(FONTSSUBDIRS,"fonts")
 718 fi
 719
 720 dnl **** Check for parport (currently Linux only) ****
 721 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
 722  AC_TRY_COMPILE(
 723    [#include <linux/ppdev.h>],
 724    [ioctl (1,PPCLAIM,0)],
 725    [ac_cv_c_ppdev="yes"],
 726    [ac_cv_c_ppdev="no"])
 727  )
 728 if test "$ac_cv_c_ppdev" = "yes"
 729 then
 730     AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
 731 fi
 732
 733 dnl **** Check for va_copy ****
 734 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
 735  AC_TRY_LINK(
 736    [#include <stdarg.h>],
 737    [va_list ap1, ap2;
 738     va_copy(ap1,ap2);
 739    ],
 740    [ac_cv_c_va_copy="yes"],
 741    [ac_cv_c_va_copy="no"])
 742  )
 743 if test "$ac_cv_c_va_copy" = "yes"
 744 then
 745     AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
 746 fi
 747 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
 748  AC_TRY_LINK(
 749    [#include <stdarg.h>],
 750    [va_list ap1, ap2;
 751     __va_copy(ap1,ap2);
 752    ],
 753    [ac_cv_c___va_copy="yes"],
 754    [ac_cv_c___va_copy="no"])
 755  )
 756 if test "$ac_cv_c___va_copy" = "yes"
 757 then
 758     AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
 759 fi
 760
 761 dnl **** Check for sigsetjmp ****
 762 AC_CACHE_CHECK([for sigsetjmp], ac_cv_c_sigsetjmp,
 763  AC_TRY_LINK(
 764    [#include <setjmp.h>],
 765    [sigjmp_buf buf;
 766     sigsetjmp( buf, 1 );
 767     siglongjmp( buf, 1 );],
 768    [ac_cv_c_sigsetjmp="yes"],
 769    [ac_cv_c_sigsetjmp="no"])
 770  )
 771 if test "$ac_cv_c_sigsetjmp" = "yes"
 772 then
 773     AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have the sigsetjmp (and siglongjmp) function])
 774 fi
 775
 776 dnl **** Check for pthread_rwlock_t ****
 777 AC_CHECK_TYPES([pthread_rwlock_t, pthread_rwlockattr_t],,,[#define _GNU_SOURCE
 778 #include <pthread.h>])
 779
 780 dnl **** Check for pthread functions ****
 781 WINE_CHECK_LIB_FUNCS(\
 782         pthread_getattr_np \
 783         pthread_get_stackaddr_np \
 784         pthread_get_stacksize_np,
 785         [$LIBPTHREAD])
 786
 787 dnl **** Check for aRts Sound Server ****
 788 AC_PATH_PROG(ARTSCCONFIG, artsc-config)
 789 if test x$ARTSCCONFIG != x -a x$ARTSCCONFIG != x'"$ARTSCCONFIG"';
 790 then
 791     ARTSC_CFLAGS=""
 792     for i in `$ARTSCCONFIG --cflags`
 793     do
 794       case "$i" in
 795         -I*) ARTSC_CFLAGS="$ARTSC_CFLAGS $i";;
 796       esac
 797     done
 798     ARTSC_LIBS=""
 799     for i in `$ARTSCCONFIG --libs`
 800     do
 801       case "$i" in
 802         -L/usr/lib|-L/usr/lib64) ;;
 803         -L*|-l*) ARTSC_LIBS="$ARTSC_LIBS $i";;
 804       esac
 805     done
 806     save_CFLAGS="$CFLAGS"
 807     CFLAGS="$CFLAGS $ARTSC_CFLAGS"
 808     AC_CHECK_LIB(artsc,arts_init,
 809         [AC_TRY_COMPILE([#include <artsc.h>],[arts_stream_t stream;],
 810             [AC_SUBST(ARTSLIBS, $ARTSC_LIBS)
 811             AC_SUBST(ARTSINCL, $ARTSC_CFLAGS)
 812             AC_DEFINE(HAVE_ARTS, 1, [Define if you have ARTS sound server])])],,
 813             $ARTSC_LIBS)
 814     CFLAGS="$save_CFLAGS"
 815 fi
 816
 817 dnl **** Check for EsounD ****
 818 AC_PATH_PROG(ESDCONFIG, esd-config)
 819 if test x$ESDCONFIG != x -a x$ESDCONFIG != x'"$ESDCONFIG"';
 820 then
 821     ESD_CFLAGS=""
 822     for i in `$ESDCONFIG --cflags`
 823     do
 824       case "$i" in
 825         -I*) ESD_CFLAGS="$ESD_CFLAGS $i";;
 826       esac
 827     done
 828     ESD_LIBS=`$ESDCONFIG --libs`
 829     save_CFLAGS="$CFLAGS"
 830     CFLAGS="$CFLAGS $ESD_CFLAGS"
 831     AC_CHECK_LIB(esd,esd_open_sound,
 832         [AC_SUBST(ESDLIBS, $ESD_LIBS)
 833          AC_SUBST(ESDINCL, $ESD_CFLAGS)
 834          AC_DEFINE(HAVE_ESD, 1, [Define if you have EsounD sound server])])
 835     CFLAGS="$save_CFLAGS"
 836 fi
 837
 838 dnl **** Check for ALSA 1.x ****
 839 AC_SUBST(ALSALIBS,"")
 840 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
 841 then
 842     AC_CHECK_LIB(asound,snd_pcm_hw_params_get_access,
 843         [AC_TRY_COMPILE([#ifdef HAVE_ALSA_ASOUNDLIB_H
 844 #include <alsa/asoundlib.h>
 845 #elif defined(HAVE_SYS_ASOUNDLIB_H)
 846 #include <sys/asoundlib.h>
 847 #endif],
 848                         [int ret = snd_pcm_hw_params_get_access(NULL, NULL)],
 849                         [AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA 1.x including devel headers])
 850                          ALSALIBS="-lasound"])])
 851 fi
 852
 853 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
 854
 855 AC_SUBST(AUDIOIOLIBS,"")
 856 if test "$ac_cv_header_libaudioio_h" = "yes"
 857 then
 858     AC_CHECK_LIB(audioio,AudioIOGetVersion,
 859                   [AUDIOIOLIBS="-laudioio"
 860                    AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])
 861 fi
 862
 863 dnl **** Check for capi4linux ****
 864
 865 if test "$ac_cv_header_capi20_h" = "yes" -a "$ac_cv_header_linux_capi_h" = "yes"
 866 then
 867     AC_CHECK_LIB(capi20,capi20_register,[AC_DEFINE(HAVE_CAPI4LINUX,1,[Define if you have capi4linux libs and headers])])
 868 fi
 869
 870 dnl **** Check for gif header usability ****
 871
 872 if test "$ac_cv_header_gif_lib_h" = "yes"
 873 then
 874     AC_TRY_COMPILE([#include <gif_lib.h>],[static typeof(DGifOpen) * func;],
 875         AC_DEFINE(HAVE_GIF, 1, [Define if you have usable GIF headers]))
 876 fi
 877
 878 dnl **** Check for gcc specific options ****
 879
 880 AC_SUBST(EXTRACFLAGS,"")
 881 if test "x${GCC}" = "xyes"
 882 then
 883   EXTRACFLAGS="-Wall -pipe"
 884
 885   dnl Check for strength-reduce bug
 886   AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
 887                   AC_TRY_RUN([
 888 int     L[[4]] = {0,1,2,3};
 889 int main(void) {
 890   static int Array[[3]];
 891   unsigned int B = 3;
 892   int i;
 893   for(i=0; i<B; i++) Array[[i]] = i - 3;
 894   for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
 895   L[[i]] = 4;
 896
 897   exit( Array[[1]] != -2 || L[[2]] != 3);
 898 }],
 899     ac_cv_c_gcc_strength_bug="no",
 900     ac_cv_c_gcc_strength_bug="yes",
 901     ac_cv_c_gcc_strength_bug="yes") )
 902   if test "$ac_cv_c_gcc_strength_bug" = "yes"
 903   then
 904     EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
 905   fi
 906
 907   dnl Check for -fshort-wchar
 908   AC_CACHE_CHECK([for gcc -fshort-wchar support], ac_cv_c_gcc_fshort_wchar,
 909       [WINE_TRY_CFLAGS([-fshort-wchar],
 910                       ac_cv_c_gcc_fshort_wchar="yes",ac_cv_c_gcc_fshort_wchar="no")])
 911   if test "$ac_cv_c_gcc_fshort_wchar" = "yes"
 912   then
 913       AC_DEFINE(CC_FLAG_SHORT_WCHAR, "-fshort-wchar", [Specifies the compiler flag that forces a short wchar_t])
 914   fi
 915
 916   dnl Check for -fno-strict-aliasing
 917   AC_CACHE_CHECK([for gcc -fno-strict-aliasing support], ac_cv_c_gcc_no_strict_aliasing,
 918       [WINE_TRY_CFLAGS([-fno-strict-aliasing],
 919                       ac_cv_c_gcc_no_strict_aliasing="yes",ac_cv_c_gcc_no_strict_aliasing="no")])
 920   if test "$ac_cv_c_gcc_no_strict_aliasing" = "yes"
 921   then
 922     EXTRACFLAGS="$EXTRACFLAGS -fno-strict-aliasing"
 923   fi
 924
 925   dnl Check for -gstabs+ option
 926   AC_CACHE_CHECK([for gcc -gstabs+ support], ac_cv_c_gcc_gstabs,
 927       [WINE_TRY_CFLAGS([-gstabs+],ac_cv_c_gcc_gstabs="yes", ac_cv_c_gcc_gstabs="no")])
 928   if test "$ac_cv_c_gcc_gstabs" = "yes"
 929   then
 930     EXTRACFLAGS="$EXTRACFLAGS -gstabs+"
 931   fi
 932
 933   dnl Check for -Wdeclaration-after-statement option
 934   AC_CACHE_CHECK([for gcc -Wdeclaration-after-statement support], ac_cv_c_gcc_decl_after_statement,
 935       [WINE_TRY_CFLAGS([-Wdeclaration-after-statement],ac_cv_c_gcc_decl_after_statement="yes", ac_cv_c_gcc_decl_after_statement="no")])
 936   if test "$ac_cv_c_gcc_decl_after_statement" = "yes"
 937   then
 938     EXTRACFLAGS="$EXTRACFLAGS -Wdeclaration-after-statement"
 939   fi
 940
 941   dnl Check for noisy string.h
 942   saved_CFLAGS="$CFLAGS"
 943   CFLAGS="$CFLAGS -Wpointer-arith -Werror"
 944   AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
 945       AC_TRY_COMPILE([#include <string.h>],[],
 946                      [ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
 947   CFLAGS="$saved_CFLAGS"
 948   if test "$ac_cv_c_string_h_warnings" = "no"
 949   then
 950     EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
 951   fi
 952
 953   AC_SUBST(BUILTINFLAG,"")
 954   saved_CFLAGS="$CFLAGS"
 955   CFLAGS="$CFLAGS -Werror"
 956   AC_CACHE_CHECK([for builtin wchar inlines], ac_cv_c_builtin_wchar_ctype,
 957       AC_TRY_COMPILE([],
 958                      [int iswlower(unsigned short);],
 959                      [ac_cv_c_builtin_wchar_ctype=no],[ac_cv_c_builtin_wchar_ctype=yes]))
 960   CFLAGS="$saved_CFLAGS"
 961   if test "$ac_cv_c_builtin_wchar_ctype" = "yes"
 962   then
 963     BUILTINFLAG="-fno-builtin"
 964   fi
 965 fi
 966
 967 dnl **** Check how to define a function in assembly code ****
 968
 969 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
 970   WINE_TRY_ASM_LINK(
 971       ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
 972       ac_cv_asm_func_def=".def",
 973     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
 974       ac_cv_asm_func_def=".type @function",
 975     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
 976       ac_cv_asm_func_def=".type 2",
 977       ac_cv_asm_func_def="unknown")])]))
 978
 979 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
 980 case "$ac_cv_asm_func_def" in
 981   ".def")
 982      AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
 983   ".type @function")
 984      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
 985   ".type 2")
 986      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
 987   *)
 988      AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
 989 esac
 990
 991 dnl **** Check for underscore on external symbols ****
 992
 993 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
 994     WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
 995                       [extern int ac_test;],
 996                       [if (ac_test) return 1],
 997                       ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
 998
 999 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
1000 if test "$ac_cv_c_extern_prefix" = "yes"
1001 then
1002   AC_DEFINE([__ASM_NAME(name)], ["_" name])
1003 else
1004   AC_DEFINE([__ASM_NAME(name)], [name])
1005 fi
1006
1007 dnl **** Check for working dll ****
1008
1009 AC_SUBST(DLLEXT,"")
1010 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
1011 AC_SUBST(DLLIBS,"")
1012 AC_SUBST(LDSHARED,"")
1013 AC_SUBST(LDDLLFLAGS,"")
1014 AC_SUBST(LIBEXT,"so")
1015 AC_SUBST(IMPLIBEXT,"def")
1016
1017 case $host_os in
1018   cygwin*|mingw32*)
1019     AC_CHECK_TOOL(DLLTOOL,dlltool,false)
1020     AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
1021     if test "$DLLWRAP" = "false"; then
1022       LIBEXT="a"
1023     else
1024       dnl FIXME - check whether dllwrap works correctly...
1025       LIBEXT="dll"
1026     fi
1027     IMPLIBEXT="a"
1028     dnl We can't build 16-bit NE dlls
1029     WIN16_FILES=""
1030     WIN16_INSTALL=""
1031     ;;
1032   *)
1033     if test "$ac_cv_header_dlfcn_h" = "yes"
1034     then
1035         AC_CHECK_FUNCS(dlopen,,
1036             [AC_CHECK_LIB(dl,dlopen,
1037                          [AC_DEFINE(HAVE_DLOPEN,1,[Define if you have dlopen])
1038                           DLLIBS="-ldl"],
1039                          [LIBEXT="a"])])
1040         WINE_CHECK_LIB_FUNCS(dladdr,[$DLLIBS])
1041     else
1042         LIBEXT="a"
1043     fi
1044
1045     if test "$LIBEXT" = "so"
1046     then
1047       DLLFLAGS="$DLLFLAGS -fPIC"
1048       DLLEXT=".so"
1049       AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
1050           [WINE_TRY_SHLIB_FLAGS([-fPIC -shared -Wl,-Bsymbolic],
1051                                 ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
1052       if test "$ac_cv_c_dll_gnuelf" = "yes"
1053       then
1054         LDSHARED="\$(CC) -shared"
1055         LDDLLFLAGS="-shared -Wl,-Bsymbolic"
1056         AC_CACHE_CHECK([whether the linker accepts soname], ac_cv_c_sonames,
1057           [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-soname,confest.so.1],
1058                            ac_cv_c_sonames="yes",ac_cv_c_sonames="no")])
1059         if test "$ac_cv_c_sonames" = "yes"
1060         then
1061           LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"
1062         else
1063           AC_CACHE_CHECK([check to see if -h soname is an alternate], ac_cv_c_h_sonames,
1064             [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-h,confest.so.1],
1065                              ac_cv_c_h_sonames="yes",ac_cv_c_h_sonames="no")])
1066           if test "$ac_cv_c_h_sonames" = "yes"
1067           then
1068             LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-h,%)"
1069           fi
1070         fi
1071
1072         AC_CACHE_CHECK([whether the linker accepts -z defs], ac_cv_c_dll_zdefs,
1073           [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs],
1074                            ac_cv_c_dll_zdefs="yes",ac_cv_c_dll_zdefs="no")])
1075         if test "$ac_cv_c_dll_zdefs" = "yes"
1076         then
1077           LDDLLFLAGS="$LDDLLFLAGS,-z,defs"
1078         fi
1079
1080         AC_CACHE_CHECK([whether the linker accepts -init and -fini], ac_cv_c_dll_init_fini,
1081           [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-init,__wine_spec_init,-fini,__wine_spec_fini],
1082                            ac_cv_c_dll_init_fini="yes",ac_cv_c_dll_init_fini="no")])
1083         if test "$ac_cv_c_dll_init_fini" = "yes"
1084         then
1085           LDDLLFLAGS="$LDDLLFLAGS,-init,__wine_spec_init,-fini,__wine_spec_fini"
1086         fi
1087
1088         AC_CACHE_CHECK([whether the linker accepts version scripts], ac_cv_c_ld_version_scripts,
1089           [echo '{ global: *; };' >conftest.map
1090            WINE_TRY_CFLAGS([-fPIC -shared -Wl,--version-script=conftest.map],
1091                            ac_cv_c_ld_version_scripts="yes",ac_cv_c_ld_version_scripts="no")
1092            rm -f conftest.map])
1093         if test "$ac_cv_c_ld_version_scripts" = "yes"
1094         then
1095           LDSHARED="$LDSHARED \$(VERSCRIPT:%=-Wl,--version-script=%)"
1096         fi
1097
1098         AC_CACHE_CHECK([whether the linker accepts --export-dynamic], ac_cv_c_export_dynamic,
1099           [WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
1100                            ac_cv_c_export_dynamic="yes",ac_cv_c_export_dynamic="no")])
1101         if test "$ac_cv_c_export_dynamic" = "yes"
1102         then
1103           AC_SUBST(LDEXECFLAGS,["-Wl,--export-dynamic"])
1104         fi
1105
1106         AC_CACHE_CHECK([whether the linker accepts --rpath], ac_cv_ld_rpath,
1107           [WINE_TRY_CFLAGS([-fPIC -Wl,--rpath,\$ORIGIN/../lib],
1108                            ac_cv_ld_rpath="yes",ac_cv_ld_rpath="no")])
1109         if test "$ac_cv_ld_rpath" = "yes"
1110         then
1111           AC_SUBST(LDEXERPATH,["-Wl,--rpath,\\\$\$ORIGIN/\`\$(RELPATH) \$(bindir) \$(libdir)\`"])
1112           AC_SUBST(LDDLLRPATH,["-Wl,--rpath,\\\$\$ORIGIN/\`\$(RELPATH) \$(dlldir) \$(libdir)\`"])
1113         fi
1114
1115         case $host_cpu in
1116           *i[[3456789]]86* | x86_64)
1117             AC_CACHE_CHECK([whether we can relocate the executable to 0x7bf00000], ac_cv_ld_reloc_exec,
1118               [WINE_TRY_CFLAGS([-Wl,--section-start,.interp=0x7bf00400],
1119                                ac_cv_ld_reloc_exec="yes", ac_cv_ld_reloc_exec="no")])
1120             if test "$ac_cv_ld_reloc_exec" = "yes"
1121             then
1122               LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x7bf00400"
1123             fi
1124             ;;
1125         esac
1126
1127       else
1128         AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
1129             [WINE_TRY_SHLIB_FLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
1130                                   ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
1131         if test "$ac_cv_c_dll_unixware" = "yes"
1132         then
1133           LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
1134           LDDLLFLAGS="-Wl,-G,-B,symbolic"
1135
1136         else
1137           AC_CACHE_CHECK(whether we can build a Mach-O (Mac OS X/Darwin) dll, ac_cv_c_dll_macho,
1138             [WINE_TRY_SHLIB_FLAGS([-bundle], ac_cv_c_dll_macho="yes", ac_cv_c_dll_macho="no")])
1139           if test "$ac_cv_c_dll_macho" = "yes"
1140           then
1141             LIBEXT="dylib"
1142             LDDLLFLAGS="-bundle"
1143             LDSHARED="\$(CC) -dynamiclib -install_name @executable_path/\`\$(RELPATH) \$(bindir) \$(libdir)\`/\$(DYNAME) \$(SOVERSION:%=-compatibility_version %)"
1144             STRIP="$STRIP -u -r"
1145             dnl declare needed frameworks
1146             AC_SUBST(COREFOUNDATIONLIB,"-framework CoreFoundation")
1147             AC_SUBST(IOKITLIB,"-framework IOKit -framework CoreFoundation")
1148             AC_SUBST(LDEXECFLAGS,["-image_base 0x7bf00000 -Wl,-segaddr,WINE_DOS,0x00000000,-segaddr,WINE_SHARED_HEAP,0x7f000000"])
1149             if test "$ac_cv_header_CoreAudio_CoreAudio_h" = "yes" -a "$ac_cv_header_AudioUnit_AudioUnit_h" = "yes"
1150             then
1151                 dnl CoreServices needed by AudioUnit
1152                 AC_SUBST(COREAUDIO,"-framework CoreAudio -framework AudioUnit -framework CoreServices")
1153             fi
1154             case $host_cpu in
1155               *powerpc*)
1156                 CFLAGS="$CFLAGS -ffixed-r13"
1157                 LDDLLFLAGS="$LDDLLFLAGS -read_only_relocs warning"
1158                 ;;
1159             esac
1160
1161           else
1162             AC_CACHE_CHECK(whether we can build an HP-UX dll, ac_cv_c_dll_hpux,
1163               [WINE_TRY_SHLIB_FLAGS([-shared], ac_cv_c_dll_hpux="yes", ac_cv_c_dll_hpux="no")])
1164             if test "$ac_cv_c_dll_hpux" = "yes"
1165             then
1166               LIBEXT="sl"
1167               DLLEXT=".sl"
1168               LDDLLFLAGS="-shared -fPIC"
1169               LDSHARED="\$(CC) -shared"
1170             fi
1171           fi
1172         fi
1173       fi
1174     fi
1175
1176     dnl Check for cross compiler to build test programs
1177     AC_SUBST(CROSSTEST,"")
1178     if test "$cross_compiling" = "no"
1179     then
1180       AC_CHECK_PROGS(CROSSCC,i586-mingw32msvc-gcc i386-mingw32msvc-gcc i386-mingw32-gcc mingw-gcc,false)
1181       AC_CHECK_PROGS(DLLTOOL,i586-mingw32msvc-dlltool i386-mingw32msvc-dlltool i386-mingw32-dlltool mingw-dlltool,false)
1182       AC_CHECK_PROGS(CROSSWINDRES,i586-mingw32msvc-windres i386-mingw32msvc-windres i386-mingw32-windres mingw-windres,false)
1183       if test "$CROSSCC" != "false"; then CROSSTEST="\$(CROSSTEST)"; fi
1184     fi
1185     ;;
1186 esac
1187
1188 if test "$LIBEXT" = "a"; then
1189   AC_MSG_ERROR(
1190 [could not find a way to build shared libraries.
1191 It is currently not possible to build Wine without shared library
1192 (.so) support to allow transparent switch between .so and .dll files.
1193 If you are using Linux, you will need a newer binutils.]
1194 )
1195 fi
1196
1197 case $build_os in
1198   cygwin*|mingw32*)
1199     AC_SUBST(LDPATH,"PATH=\"\$(TOOLSDIR)/libs/wine:\$\$PATH\"") ;;
1200   darwin*|macosx*)
1201     AC_SUBST(LDPATH,"DYLD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/wine:\$\$DYLD_LIBRARY_PATH\"") ;;
1202   *)
1203     AC_SUBST(LDPATH,"LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/wine:\$\$LD_LIBRARY_PATH\"") ;;
1204 esac
1205
1206 dnl Mingw needs explicit msvcrt for linking libwine and winsock for wininet
1207 case $host_os in
1208   mingw32*)
1209     AC_SUBST(CRTLIBS,"-lmsvcrt")
1210     AC_SUBST(SOCKETLIBS,"-lws2_32")
1211     ;;
1212 esac
1213
1214 AC_SUBST(MAIN_BINARY,"wine-pthread")  dnl Default value
1215 case $host_cpu in
1216   *i[[3456789]]86*)
1217     case $host_os in
1218       linux* | k*bsd*-gnu)
1219         AC_SUBST(MAIN_BINARY,"wine-glibc")
1220         AC_SUBST(EXTRA_BINARIES,"wine-kthread wine-pthread wine-preloader") ;;
1221     esac
1222     ;;
1223 esac
1224
1225 dnl **** Get the soname for libraries that we load dynamically ****
1226
1227 if test "$LIBEXT" = "so" -o "$LIBEXT" = "dylib"
1228 then
1229   WINE_GET_SONAME(X11,XCreateWindow,[$X_LIBS $X_EXTRA_LIBS])
1230   WINE_GET_SONAME(Xext,XextCreateExtension,[$X_LIBS -lX11 $X_EXTRA_LIBS])
1231   WINE_GET_SONAME(Xi,XOpenDevice,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1232   WINE_GET_SONAME(Xrender,XRenderQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1233   WINE_GET_SONAME(Xrandr,XRRQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1234   WINE_GET_SONAME(freetype,FT_Init_FreeType,[$X_LIBS])
1235   WINE_GET_SONAME(GL,glXQueryExtension,[$X_LIBS $X_EXTRA_LIBS])
1236   WINE_GET_SONAME(dbus-1,dbus_error_init)
1237   WINE_GET_SONAME(hal,libhal_ctx_new)
1238   WINE_GET_SONAME(txc_dxtn,fetch_2d_texel_rgba_dxt1)
1239   WINE_GET_SONAME(cups,cupsGetDefault)
1240   WINE_GET_SONAME(jack,jack_client_new)
1241   WINE_GET_SONAME(fontconfig,FcInit)
1242   WINE_GET_SONAME(ssl,SSL_library_init)
1243   WINE_GET_SONAME(crypto,BIO_new_socket)
1244   WINE_GET_SONAME(ncurses,waddch)
1245   WINE_GET_SONAME(curses,waddch)
1246   WINE_GET_SONAME(jpeg,jpeg_start_decompress)
1247   WINE_GET_SONAME(ungif,DGifOpen)
1248   WINE_GET_SONAME(gif,DGifOpen)
1249   WINE_GET_SONAME(capi20,capi20_isinstalled)
1250 fi
1251
1252
1253 dnl **** Check for functions ****
1254
1255 AC_CHECK_FUNCS(\
1256         _lwp_create \
1257         _lwp_self \
1258         _pclose \
1259         _popen \
1260         _snprintf \
1261         _spawnvp \
1262         _stricmp \
1263         _strnicmp \
1264         _vsnprintf \
1265         asctime_r \
1266         chsize \
1267         clone \
1268         epoll_create \
1269         ffs \
1270         finite \
1271         fork \
1272         fpclass \
1273         fstatfs \
1274         fstatvfs \
1275         ftruncate \
1276         futimes \
1277         futimesat \
1278         getaddrinfo \
1279         getnameinfo \
1280         getnetbyname \
1281         getopt_long \
1282         getpagesize \
1283         getprotobyname \
1284         getprotobynumber \
1285         getpwuid \
1286         getservbyport \
1287         gettid \
1288         gettimeofday \
1289         getuid \
1290         inet_network \
1291         kqueue \
1292         lstat \
1293         memmove \
1294         mmap \
1295         pclose \
1296         popen \
1297         prctl \
1298         pread \
1299         pwrite \
1300         readlink \
1301         rfork \
1302         sched_yield \
1303         select \
1304         sendmsg \
1305         setrlimit \
1306         settimeofday \
1307         sigaltstack \
1308         sigprocmask \
1309         snprintf \
1310         spawnvp \
1311         statfs \
1312         statvfs \
1313         strcasecmp \
1314         strerror \
1315         strncasecmp \
1316         tcgetattr \
1317         timegm \
1318         usleep \
1319         vsnprintf \
1320         wait4 \
1321         waitpid \
1322 )
1323
1324
1325 dnl **** Check for types ****
1326
1327 AC_C_CONST
1328 AC_C_INLINE
1329 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t, long long, fsblkcnt_t, fsfilcnt_t])
1330 AC_CHECK_TYPES([sigset_t],,,[#include <signal.h>])
1331 AC_CHECK_TYPES([request_sense],,,[#include <linux/cdrom.h>])
1332
1333 AC_CHECK_MEMBERS([struct ff_effect.direction],,,
1334 [#ifdef HAVE_LINUX_INPUT_H
1335 #include <linux/input.h>
1336 #endif])
1337
1338 AC_CACHE_CHECK([for sigaddset],wine_cv_have_sigaddset,
1339                AC_TRY_LINK([#include <signal.h>],[sigset_t set; sigaddset(&set,SIGTERM);],
1340                            wine_cv_have_sigaddset=yes,wine_cv_have_sigaddset=no))
1341 if test "$wine_cv_have_sigaddset" = "yes"
1342 then
1343   AC_DEFINE(HAVE_SIGADDSET, 1, [Define if sigaddset is supported])
1344 fi
1345
1346
1347 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1348         wine_cv_linux_gethostbyname_r_6,
1349         AC_TRY_LINK([
1350 #include <netdb.h>
1351         ], [
1352     char *name=NULL;
1353     struct hostent he;
1354     struct hostent *result;
1355     char *buf=NULL;
1356     int bufsize=0;
1357     int res,errnr;
1358     char *addr=NULL;
1359     int addrlen=0;
1360     int addrtype=0;
1361     res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1362     res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1363     ],
1364         wine_cv_linux_gethostbyname_r_6=yes,
1365         wine_cv_linux_gethostbyname_r_6=no
1366         )
1367    )
1368    if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1369    then
1370       AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1371                 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1372    fi
1373
1374 if test "$ac_cv_header_linux_joystick_h" = "yes"
1375 then
1376    AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1377         wine_cv_linux_joystick_22_api,
1378         AC_TRY_COMPILE([
1379         #include <sys/ioctl.h>
1380         #include <linux/joystick.h>
1381
1382         struct js_event blub;
1383         #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1384         #error "no 2.2 header"
1385         #endif
1386         ],/*empty*/,
1387         wine_cv_linux_joystick_22_api=yes,
1388         wine_cv_linux_joystick_22_api=no,
1389         wine_cv_linux_joystick_22_api=no
1390         )
1391    )
1392    if test "$wine_cv_linux_joystick_22_api" = "yes"
1393    then
1394       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1395                 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1396    fi
1397 fi
1398
1399 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1400
1401 dnl Check for statfs members
1402 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail, struct statfs.f_frsize, struct statfs.f_ffree, struct statfs.f_favail, struct statfs.f_namelen],,,
1403 [#include <sys/types.h>
1404 #ifdef HAVE_SYS_PARAM_H
1405 # include <sys/param.h>
1406 #endif
1407 #ifdef HAVE_SYS_MOUNT_H
1408 # include <sys/mount.h>
1409 #endif
1410 #ifdef HAVE_SYS_VFS_H
1411 # include <sys/vfs.h>
1412 #endif
1413 #ifdef HAVE_SYS_STATFS_H
1414 # include <sys/statfs.h>
1415 #endif])
1416
1417 AC_CHECK_MEMBERS([struct statvfs.f_blocks],,,
1418 [#ifdef HAVE_SYS_STATVFS_H
1419 #include <sys/statvfs.h>
1420 #endif])
1421
1422 dnl Check for socket structure members
1423 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
1424 [#include <sys/types.h>
1425 #ifdef HAVE_SYS_SOCKET_H
1426 # include <sys/socket.h>
1427 #endif
1428 #ifdef HAVE_SYS_UN_H
1429 # include <sys/un.h>
1430 #endif])
1431
1432 dnl Check for scsireq_t and sg_io_hdr_t members
1433 AC_CHECK_MEMBERS([scsireq_t.cmd, sg_io_hdr_t.interface_id],,,
1434 [#include <sys/types.h>
1435 #ifdef HAVE_SCSI_SG_H
1436 #include <scsi/sg.h>
1437 #endif])
1438
1439 dnl Check for siginfo_t members
1440 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
1441
1442 dnl Check for struct mtget members
1443 AC_CHECK_MEMBERS([struct mtget.mt_blksiz, struct mtget.mt_gstat, struct mtget.mt_blkno],,,
1444 [#include <sys/types.h>
1445 #ifdef HAVE_SYS_MTIO_H
1446 #include <sys/mtio.h>
1447 #endif])
1448
1449 dnl Check for struct option
1450 AC_CHECK_MEMBERS([struct option.name],,,
1451 [#ifdef HAVE_GETOPT_H
1452 #include <getopt.h>
1453 #endif])
1454
1455 dnl Check for stat.st_blocks
1456 AC_CHECK_MEMBERS([struct stat.st_blocks])
1457
1458 dnl Check for sin6_scope_id
1459 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_scope_id],,,
1460 [#ifdef HAVE_SYS_TYPES_H
1461 #include <sys/types.h>
1462 #endif
1463 #ifdef HAVE_NETINET_IN_H
1464 #include <netinet/in.h>
1465 #endif])
1466
1467 dnl Check for ns_msg ptr member
1468 AC_CHECK_MEMBERS([ns_msg._msg_ptr],,,
1469 [#ifdef HAVE_SYS_TYPES_H
1470 #include <sys/types.h>
1471 #endif
1472 #ifdef HAVE_NETINET_IN_H
1473 # include <netinet/in.h>
1474 #endif
1475 #ifdef HAVE_ARPA_NAMESER_H
1476 # include <arpa/nameser.h>
1477 #endif])
1478
1479 dnl Check for the external timezone variables timezone and daylight
1480 AC_CACHE_CHECK([for timezone variable], ac_cv_have_timezone,
1481                AC_TRY_LINK([#include <time.h>],[timezone;],
1482                            ac_cv_have_timezone="yes", ac_cv_have_timezone="no"))
1483 if test "$ac_cv_have_timezone" = "yes"
1484 then
1485     AC_DEFINE(HAVE_TIMEZONE, 1, [Define if you have the timezone variable])
1486 fi
1487 AC_CACHE_CHECK([for daylight variable], ac_cv_have_daylight,
1488                AC_TRY_LINK([#include <time.h>],[daylight;],
1489                            ac_cv_have_daylight="yes", ac_cv_have_daylight="no"))
1490 if test "$ac_cv_have_daylight" = "yes"
1491 then
1492     AC_DEFINE(HAVE_DAYLIGHT, 1, [Define if you have the daylight variable])
1493 fi
1494
1495 dnl *** check for the need to define platform-specific symbols
1496
1497 case $host_cpu in
1498   *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
1499   *x86_64*)         WINE_CHECK_DEFINE([__x86_64__])
1500                     WINE_CHECK_DEFINE([_WIN64]) ;;
1501   *alpha*)          WINE_CHECK_DEFINE([__ALPHA__]) ;;
1502   *sparc*)          WINE_CHECK_DEFINE([__sparc__]) ;;
1503   *powerpc*)        WINE_CHECK_DEFINE([__powerpc__]) ;;
1504 esac
1505
1506 case $host_vendor in
1507   *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
1508 esac
1509
1510 dnl **** Generate output files ****
1511
1512 AH_TOP([#define __WINE_CONFIG_H])
1513
1514 WINE_CONFIG_EXTRA_DIR(dlls/gdi/enhmfdrv)
1515 WINE_CONFIG_EXTRA_DIR(dlls/gdi/mfdrv)
1516 WINE_CONFIG_EXTRA_DIR(dlls/kernel/messages)
1517 WINE_CONFIG_EXTRA_DIR(dlls/user/resources)
1518 WINE_CONFIG_EXTRA_DIR(dlls/wineps.drv/data)
1519 WINE_CONFIG_EXTRA_DIR(include/wine)
1520
1521 MAKE_RULES=Make.rules
1522 AC_SUBST_FILE(MAKE_RULES)
1523
1524 MAKE_DLL_RULES=dlls/Makedll.rules
1525 AC_SUBST_FILE(MAKE_DLL_RULES)
1526
1527 MAKE_IMPLIB_RULES=dlls/Makeimplib.rules
1528 AC_SUBST_FILE(MAKE_IMPLIB_RULES)
1529
1530 MAKE_TEST_RULES=dlls/Maketest.rules
1531 AC_SUBST_FILE(MAKE_TEST_RULES)
1532
1533 MAKE_PROG_RULES=programs/Makeprog.rules
1534 AC_SUBST_FILE(MAKE_PROG_RULES)
1535
1536 AC_CONFIG_FILES([
1537 Make.rules
1538 dlls/Makedll.rules
1539 dlls/Makeimplib.rules
1540 dlls/Maketest.rules
1541 programs/Makeprog.rules
1542 Makefile
1543 dlls/Makefile
1544 dlls/activeds/Makefile
1545 dlls/advapi32/Makefile
1546 dlls/advapi32/tests/Makefile
1547 dlls/advpack/Makefile
1548 dlls/advpack/tests/Makefile
1549 dlls/amstream/Makefile
1550 dlls/atl/Makefile
1551 dlls/avicap32/Makefile
1552 dlls/avifil32/Makefile
1553 dlls/cabinet/Makefile
1554 dlls/cabinet/tests/Makefile
1555 dlls/capi2032/Makefile
1556 dlls/cards/Makefile
1557 dlls/cfgmgr32/Makefile
1558 dlls/comcat/Makefile
1559 dlls/comcat/tests/Makefile
1560 dlls/comctl32/Makefile
1561 dlls/comctl32/tests/Makefile
1562 dlls/comdlg32/Makefile
1563 dlls/comdlg32/tests/Makefile
1564 dlls/compstui/Makefile
1565 dlls/crtdll/Makefile
1566 dlls/crypt32/Makefile
1567 dlls/crypt32/tests/Makefile
1568 dlls/cryptdll/Makefile
1569 dlls/cryptnet/Makefile
1570 dlls/ctl3d32/Makefile
1571 dlls/d3d8/Makefile
1572 dlls/d3d8/tests/Makefile
1573 dlls/d3d9/Makefile
1574 dlls/d3d9/tests/Makefile
1575 dlls/d3dim/Makefile
1576 dlls/d3drm/Makefile
1577 dlls/d3dx8/Makefile
1578 dlls/d3dxof/Makefile
1579 dlls/dbghelp/Makefile
1580 dlls/dciman32/Makefile
1581 dlls/ddraw/Makefile
1582 dlls/ddraw/tests/Makefile
1583 dlls/devenum/Makefile
1584 dlls/dinput/Makefile
1585 dlls/dinput/tests/Makefile
1586 dlls/dinput8/Makefile
1587 dlls/dmband/Makefile
1588 dlls/dmcompos/Makefile
1589 dlls/dmime/Makefile
1590 dlls/dmloader/Makefile
1591 dlls/dmscript/Makefile
1592 dlls/dmstyle/Makefile
1593 dlls/dmsynth/Makefile
1594 dlls/dmusic/Makefile
1595 dlls/dmusic32/Makefile
1596 dlls/dnsapi/Makefile
1597 dlls/dnsapi/tests/Makefile
1598 dlls/dplay/Makefile
1599 dlls/dplayx/Makefile
1600 dlls/dpnet/Makefile
1601 dlls/dpnhpast/Makefile
1602 dlls/dsound/Makefile
1603 dlls/dsound/tests/Makefile
1604 dlls/dswave/Makefile
1605 dlls/dxdiagn/Makefile
1606 dlls/dxerr8/Makefile
1607 dlls/dxerr9/Makefile
1608 dlls/dxguid/Makefile
1609 dlls/gdi/Makefile
1610 dlls/gdi/tests/Makefile
1611 dlls/glu32/Makefile
1612 dlls/glut32/Makefile
1613 dlls/gphoto2.ds/Makefile
1614 dlls/hhctrl.ocx/Makefile
1615 dlls/hlink/Makefile
1616 dlls/hlink/tests/Makefile
1617 dlls/iccvid/Makefile
1618 dlls/icmp/Makefile
1619 dlls/ifsmgr.vxd/Makefile
1620 dlls/imaadp32.acm/Makefile
1621 dlls/imagehlp/Makefile
1622 dlls/imm32/Makefile
1623 dlls/infosoft/Makefile
1624 dlls/inseng/Makefile
1625 dlls/iphlpapi/Makefile
1626 dlls/iphlpapi/tests/Makefile
1627 dlls/itss/Makefile
1628 dlls/kernel/Makefile
1629 dlls/kernel/tests/Makefile
1630 dlls/lz32/Makefile
1631 dlls/lz32/tests/Makefile
1632 dlls/mapi32/Makefile
1633 dlls/mapi32/tests/Makefile
1634 dlls/mciavi32/Makefile
1635 dlls/mcicda/Makefile
1636 dlls/mciseq/Makefile
1637 dlls/mciwave/Makefile
1638 dlls/midimap/Makefile
1639 dlls/mlang/Makefile
1640 dlls/mlang/tests/Makefile
1641 dlls/mmdevldr.vxd/Makefile
1642 dlls/monodebg.vxd/Makefile
1643 dlls/mpr/Makefile
1644 dlls/mprapi/Makefile
1645 dlls/msacm32.drv/Makefile
1646 dlls/msacm32/Makefile
1647 dlls/msacm32/tests/Makefile
1648 dlls/msadp32.acm/Makefile
1649 dlls/mscms/Makefile
1650 dlls/mscms/tests/Makefile
1651 dlls/msdmo/Makefile
1652 dlls/msftedit/Makefile
1653 dlls/msg711.acm/Makefile
1654 dlls/mshtml/Makefile
1655 dlls/mshtml/tests/Makefile
1656 dlls/msi/Makefile
1657 dlls/msi/tests/Makefile
1658 dlls/msimg32/Makefile
1659 dlls/msisys.ocx/Makefile
1660 dlls/msnet32/Makefile
1661 dlls/msrle32/Makefile
1662 dlls/msvcrt/Makefile
1663 dlls/msvcrt/tests/Makefile
1664 dlls/msvcrt20/Makefile
1665 dlls/msvcrt40/Makefile
1666 dlls/msvcrtd/Makefile
1667 dlls/msvcrtd/tests/Makefile
1668 dlls/msvfw32/Makefile
1669 dlls/msvidc32/Makefile
1670 dlls/mswsock/Makefile
1671 dlls/msxml3/Makefile
1672 dlls/msxml3/tests/Makefile
1673 dlls/netapi32/Makefile
1674 dlls/netapi32/tests/Makefile
1675 dlls/newdev/Makefile
1676 dlls/ntdll/Makefile
1677 dlls/ntdll/tests/Makefile
1678 dlls/ntdsapi/Makefile
1679 dlls/objsel/Makefile
1680 dlls/odbc32/Makefile
1681 dlls/odbccp32/Makefile
1682 dlls/ole32/Makefile
1683 dlls/ole32/tests/Makefile
1684 dlls/oleacc/Makefile
1685 dlls/oleaut32/Makefile
1686 dlls/oleaut32/tests/Makefile
1687 dlls/olecli32/Makefile
1688 dlls/oledlg/Makefile
1689 dlls/olepro32/Makefile
1690 dlls/olesvr32/Makefile
1691 dlls/opengl32/Makefile
1692 dlls/powrprof/Makefile
1693 dlls/psapi/Makefile
1694 dlls/psapi/tests/Makefile
1695 dlls/qcap/Makefile
1696 dlls/quartz/Makefile
1697 dlls/quartz/tests/Makefile
1698 dlls/query/Makefile
1699 dlls/rasapi32/Makefile
1700 dlls/riched20/Makefile
1701 dlls/riched20/tests/Makefile
1702 dlls/riched32/Makefile
1703 dlls/rpcrt4/Makefile
1704 dlls/rpcrt4/tests/Makefile
1705 dlls/rsabase/Makefile
1706 dlls/rsabase/tests/Makefile
1707 dlls/rsaenh/Makefile
1708 dlls/rsaenh/tests/Makefile
1709 dlls/sane.ds/Makefile
1710 dlls/secur32/Makefile
1711 dlls/secur32/tests/Makefile
1712 dlls/security/Makefile
1713 dlls/sensapi/Makefile
1714 dlls/serialui/Makefile
1715 dlls/setupapi/Makefile
1716 dlls/setupapi/tests/Makefile
1717 dlls/sfc/Makefile
1718 dlls/shdocvw/Makefile
1719 dlls/shdocvw/tests/Makefile
1720 dlls/shell32/Makefile
1721 dlls/shell32/tests/Makefile
1722 dlls/shfolder/Makefile
1723 dlls/shlwapi/Makefile
1724 dlls/shlwapi/tests/Makefile
1725 dlls/snmpapi/Makefile
1726 dlls/spoolss/Makefile
1727 dlls/stdole2.tlb/Makefile
1728 dlls/stdole32.tlb/Makefile
1729 dlls/sti/Makefile
1730 dlls/strmiids/Makefile
1731 dlls/tapi32/Makefile
1732 dlls/twain_32/Makefile
1733 dlls/unicows/Makefile
1734 dlls/url/Makefile
1735 dlls/urlmon/Makefile
1736 dlls/urlmon/tests/Makefile
1737 dlls/user/Makefile
1738 dlls/user/tests/Makefile
1739 dlls/userenv/Makefile
1740 dlls/usp10/Makefile
1741 dlls/usp10/tests/Makefile
1742 dlls/uuid/Makefile
1743 dlls/uxtheme/Makefile
1744 dlls/uxtheme/tests/Makefile
1745 dlls/vdhcp.vxd/Makefile
1746 dlls/vdmdbg/Makefile
1747 dlls/version/Makefile
1748 dlls/version/tests/Makefile
1749 dlls/vmm.vxd/Makefile
1750 dlls/vnbt.vxd/Makefile
1751 dlls/vnetbios.vxd/Makefile
1752 dlls/vtdapi.vxd/Makefile
1753 dlls/vwin32.vxd/Makefile
1754 dlls/w32skrnl/Makefile
1755 dlls/winecrt0/Makefile
1756 dlls/wined3d/Makefile
1757 dlls/winedos/Makefile
1758 dlls/winemp3.acm/Makefile
1759 dlls/wineps.drv/Makefile
1760 dlls/winex11.drv/Makefile
1761 dlls/wininet/Makefile
1762 dlls/wininet/tests/Makefile
1763 dlls/winmm/Makefile
1764 dlls/winmm/joystick/Makefile
1765 dlls/winmm/tests/Makefile
1766 dlls/winmm/winealsa/Makefile
1767 dlls/winmm/winearts/Makefile
1768 dlls/winmm/wineaudioio/Makefile
1769 dlls/winmm/winecoreaudio/Makefile
1770 dlls/winmm/wineesd/Makefile
1771 dlls/winmm/winejack/Makefile
1772 dlls/winmm/winenas/Makefile
1773 dlls/winmm/wineoss/Makefile
1774 dlls/winnls32/Makefile
1775 dlls/winspool.drv/Makefile
1776 dlls/winspool.drv/tests/Makefile
1777 dlls/wintab32/Makefile
1778 dlls/wintrust/Makefile
1779 dlls/wldap32/Makefile
1780 dlls/wnaspi32/Makefile
1781 dlls/wow32/Makefile
1782 dlls/ws2_32/Makefile
1783 dlls/ws2_32/tests/Makefile
1784 dlls/wsock32/Makefile
1785 dlls/wtsapi32/Makefile
1786 documentation/Makefile
1787 fonts/Makefile
1788 include/Makefile
1789 libs/Makefile
1790 libs/port/Makefile
1791 libs/wine/Makefile
1792 libs/wpp/Makefile
1793 loader/Makefile
1794 programs/Makefile
1795 programs/clock/Makefile
1796 programs/cmdlgtst/Makefile
1797 programs/control/Makefile
1798 programs/eject/Makefile
1799 programs/expand/Makefile
1800 programs/explorer/Makefile
1801 programs/hh/Makefile
1802 programs/icinfo/Makefile
1803 programs/iexplore/Makefile
1804 programs/msiexec/Makefile
1805 programs/notepad/Makefile
1806 programs/oleview/Makefile
1807 programs/progman/Makefile
1808 programs/regedit/Makefile
1809 programs/regsvr32/Makefile
1810 programs/rpcss/Makefile
1811 programs/rundll32/Makefile
1812 programs/start/Makefile
1813 programs/taskmgr/Makefile
1814 programs/uninstaller/Makefile
1815 programs/view/Makefile
1816 programs/wcmd/Makefile
1817 programs/wineboot/Makefile
1818 programs/winebrowser/Makefile
1819 programs/winecfg/Makefile
1820 programs/wineconsole/Makefile
1821 programs/winedbg/Makefile
1822 programs/winefile/Makefile
1823 programs/winemenubuilder/Makefile
1824 programs/winemine/Makefile
1825 programs/winepath/Makefile
1826 programs/winetest/Makefile
1827 programs/winevdm/Makefile
1828 programs/winhelp/Makefile
1829 programs/winver/Makefile
1830 programs/wordpad/Makefile
1831 server/Makefile
1832 tools/Makefile
1833 tools/widl/Makefile
1834 tools/winapi/Makefile
1835 tools/winebuild/Makefile
1836 tools/winedump/Makefile
1837 tools/winegcc/Makefile
1838 tools/wmc/Makefile
1839 tools/wrc/Makefile])
1840
1841 AC_OUTPUT
1842
1843 if test "$have_x" = "no"
1844 then
1845   echo >&2
1846   AC_MSG_WARN([X development files not found. Wine will be built without])
1847   AC_MSG_WARN([X support, which currently does not work, and probably])
1848   AC_MSG_WARN([isn't what you want anyway. You will need to install devel])
1849   AC_MSG_WARN([ packages of Xlib/Xfree86 at the very least.])
1850 fi
1851
1852 if test "$wine_cv_opengl_version_OK" = "no"
1853 then
1854   echo >&2
1855   AC_MSG_WARN([Old Mesa headers detected. Wine will be built without Direct3D])
1856   AC_MSG_WARN([support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/).])
1857 fi
1858
1859 if test "$wine_cv_msg_freetype" = "yes"
1860 then
1861   echo >&2
1862   AC_MSG_WARN([Your system appears to have the FreeType 2 runtime libraries])
1863   AC_MSG_WARN([installed, but 'freetype-config' is not in your PATH. Install])
1864   AC_MSG_WARN([the freetype-devel package (or its equivalent on your distribution)])
1865   AC_MSG_WARN([to enable Wine to use TrueType fonts.])
1866 fi
1867
1868 if test -z "$FONTSSUBDIRS"
1869 then
1870   echo >&2
1871   if test "$FONTFORGE" = "false"
1872   then
1873     AC_MSG_WARN([FontForge is missing.])
1874   else
1875     AC_MSG_WARN([FreeType is missing.])
1876   fi
1877   AC_MSG_WARN([Fonts will not be built. Dialog text may be invisible or unaligned.])
1878 fi
1879
1880 if test -z "$ALSALIBS" -a \
1881         -z "$ARTSC_LIBS" -a \
1882         -z "$AUDIOIOLIBS" -a \
1883         -z "$NASLIBS" -a \
1884         -z "$ESD_LIBS" -a \
1885         -z "$ac_cv_lib_soname_jack" -a \
1886         "$ac_cv_header_sys_soundcard_h" != "yes" -a \
1887         "$ac_cv_header_machine_soundcard_h" != "yes" -a \
1888         "$ac_cv_header_soundcard_h" != "yes"
1889 then
1890   echo >&2
1891   AC_MSG_WARN([No sound system was found. Windows applications will be silent.])
1892   AC_MSG_WARN([The currently supported sound systems are:])
1893   AC_MSG_WARN([ALSA, ARTS, EsounD, AudioIO, Jack, NAS and OSS])
1894 fi
1895
1896 echo
1897 echo "Configure finished.  Do '${ac_make} depend && ${ac_make}' to compile Wine."
1898 echo
1899
1900 dnl Local Variables:
1901 dnl comment-start: "dnl "
1902 dnl comment-end: ""
1903 dnl comment-start-skip: "\\bdnl\\b\\s *"
1904 dnl compile-command: "autoconf && autoheader"
1905 dnl End: