git.oblomov.eu Git - wine/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Original author: Michael Patra
   3 dnl See ChangeLog file for detailed change history.
   4
   5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
   6
   7 AC_PREREQ(2.53b)
   8 AC_INIT([Wine],[WINE_VERSION],[wine-devel@winehq.org])
   9 AC_CONFIG_SRCDIR(server/atom.c)
  10 AC_CONFIG_HEADERS(include/config.h)
  11 AC_CONFIG_AUX_DIR(tools)
  12
  13 dnl **** Command-line arguments ****
  14
  15 AC_ARG_ENABLE(win16, AS_HELP_STRING([--disable-win16],[do not include Win16 support]))
  16 AC_ARG_ENABLE(win64, AS_HELP_STRING([--enable-win64],[build a Win64 emulator on AMD64 (won't run Win32 binaries)]))
  17
  18 AC_ARG_WITH(opengl,    AS_HELP_STRING([--without-opengl],[do not use OpenGL]))
  19 AC_ARG_WITH(wine-tools,AS_HELP_STRING([--with-wine-tools=<dir>],[use Wine tools from directory <dir>]))
  20
  21 AC_CANONICAL_HOST
  22 case $host in
  23   x86_64*linux*)
  24     if test "x$enable_win64" != "xyes"
  25     then
  26       test -n "$CC" || CC="gcc -m32"
  27       test -n "$CXX"|| CXX="g++ -m32"
  28       test -n "$LD" || LD="ld -m elf_i386"
  29       test -n "$AS" || AS="as --32"
  30       host_cpu="i386"
  31     fi
  32     ;;
  33 esac
  34
  35 dnl enable_win16 defaults to yes on x86, to no on other CPUs
  36 case $host_cpu in
  37   *i[[3456789]]86*)
  38     if test "x$enable_win16" != "xno"
  39     then
  40       enable_win16="yes"
  41     fi
  42     ;;
  43 esac
  44
  45 AC_SUBST(WIN16_FILES,"\$(WIN16_FILES)")
  46 AC_SUBST(WIN16_INSTALL,"\$(WIN16_INSTALL)")
  47 if test "x$enable_win16" != "xyes"
  48 then
  49   WIN16_FILES=""
  50   WIN16_INSTALL=""
  51 fi
  52
  53 dnl check for out of tree build with unclean source tree
  54 case "$srcdir" in
  55  .) ;;
  56  *) if test -f "$srcdir/Makefile" -o -f "$srcdir/include/config.h"; then
  57       AC_MSG_ERROR([you are building out of the source tree, but the source tree contains object files.
  58 You need to run 'make distclean' in the source tree first.])
  59     fi ;;
  60 esac
  61
  62 dnl **** Check for some programs ****
  63
  64 AC_PROG_MAKE_SET
  65 AC_PROG_CC
  66 AC_PROG_CXX
  67 dnl We can't use AC_PROG_CPP for winegcc, it uses by default $(CC) -E
  68 AC_CHECK_TOOL(CPPBIN,cpp,cpp)
  69
  70 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
  71   [if test -z "$with_wine_tools"; then
  72      if test "$cross_compiling" = "yes"; then
  73        AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
  74      else
  75        wine_cv_toolsdir="\$(TOPOBJDIR)"
  76      fi
  77    elif test -d "$with_wine_tools/tools/winebuild"; then
  78      case $with_wine_tools in
  79        /*) wine_cv_toolsdir="$with_wine_tools" ;;
  80        *)  wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
  81      esac
  82    else
  83      AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
  84    fi])
  85 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
  86
  87 AC_PATH_XTRA
  88
  89 dnl Check for flex
  90 AC_CHECK_PROGS(FLEX,flex,none)
  91 if test "$FLEX" = "none"
  92 then
  93   AC_MSG_ERROR([no suitable flex found. Please install the 'flex' package.])
  94 fi
  95
  96 dnl Check for bison
  97 AC_CHECK_PROGS(BISON,bison,none)
  98 if test "$BISON" = "none"
  99 then
 100   AC_MSG_ERROR([no suitable bison found. Please install the 'bison' package.])
 101 fi
 102
 103 AC_CHECK_TOOLS(AS,[gas as],as)
 104 AC_CHECK_TOOL(LD,ld,ld)
 105 AC_CHECK_TOOL(AR,ar,ar)
 106 AC_PROG_RANLIB
 107 AC_CHECK_TOOL(STRIP,strip,strip)
 108 AC_CHECK_TOOL(WINDRES,windres,false)
 109 AC_PROG_LN_S
 110 WINE_PROG_LN
 111 AC_PROG_EGREP
 112 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
 113 AC_PROG_INSTALL
 114 dnl Prepend src dir to install path dir if it's a relative path
 115 case "$INSTALL" in
 116   [[\\/$]]* | ?:[[\\/]]* ) ;;
 117   *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
 118 esac
 119
 120 dnl Check for lint
 121 AC_CHECK_PROGS(LINT, lclint lint)
 122 if test "$LINT" = "lint"
 123 then
 124   LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
 125   dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
 126 fi
 127 AC_SUBST(LINT)
 128 AC_SUBST(LINTFLAGS)
 129
 130 dnl Check for various programs
 131 AC_CHECK_PROGS(FONTFORGE, fontforge, false)
 132 AC_CHECK_PROGS(PKG_CONFIG, pkg-config, false)
 133
 134 case $host_cpu in
 135   *i[[3456789]]86*)
 136     AC_PATH_PROG(PRELINK, prelink, false, [/sbin /usr/sbin $PATH])
 137     ;;
 138 esac
 139
 140 dnl **** Check for some libraries ****
 141
 142 dnl Check for -li386 for NetBSD and OpenBSD
 143 AC_CHECK_LIB(i386,i386_set_ldt)
 144 dnl Check for -lossaudio for NetBSD
 145 AC_CHECK_LIB(ossaudio,_oss_ioctl)
 146 dnl Check for -lpthread
 147 AC_CHECK_LIB(pthread,pthread_create,AC_SUBST(LIBPTHREAD,"-lpthread"))
 148
 149 AC_SUBST(XLIB,"")
 150 AC_SUBST(XFILES,"")
 151 AC_SUBST(OPENGLFILES,"")
 152 AC_SUBST(GLU32FILES,"")
 153 AC_SUBST(OPENGL_LIBS,"")
 154 AC_SUBST(QUARTZFILES,"")
 155
 156 dnl **** Check for header files ****
 157
 158 AC_CHECK_HEADERS(\
 159         AudioUnit/AudioUnit.h \
 160         Carbon/Carbon.h \
 161         CoreAudio/CoreAudio.h \
 162         DiskArbitration/DiskArbitration.h \
 163         IOKit/IOKitLib.h \
 164         alsa/asoundlib.h \
 165         arpa/inet.h \
 166         arpa/nameser.h \
 167         asm/types.h \
 168         capi20.h \
 169         cups/cups.h \
 170         curses.h \
 171         direct.h \
 172         dlfcn.h \
 173         elf.h \
 174         float.h \
 175         fontconfig/fontconfig.h \
 176         getopt.h \
 177         ieeefp.h \
 178         io.h \
 179         jack/jack.h \
 180         jpeglib.h \
 181         lber.h \
 182         lcms.h \
 183         lcms/lcms.h \
 184         ldap.h \
 185         libaudioio.h \
 186         link.h \
 187         linux/cdrom.h \
 188         linux/compiler.h \
 189         linux/hdreg.h \
 190         linux/input.h \
 191         linux/ioctl.h \
 192         linux/joystick.h \
 193         linux/major.h \
 194         linux/param.h \
 195         linux/serial.h \
 196         linux/ucdrom.h \
 197         mach/mach.h \
 198         mach/machine.h \
 199         machine/cpu.h \
 200         machine/limits.h \
 201         machine/soundcard.h \
 202         mntent.h \
 203         ncurses.h \
 204         netdb.h \
 205         netinet/in.h \
 206         netinet/in_systm.h \
 207         netinet/tcp.h \
 208         netinet/tcp_fsm.h \
 209         openssl/err.h \
 210         openssl/ssl.h \
 211         png.h \
 212         poll.h \
 213         process.h \
 214         pthread.h \
 215         pwd.h \
 216         regex.h \
 217         sched.h \
 218         scsi/scsi.h \
 219         scsi/scsi_ioctl.h \
 220         scsi/sg.h \
 221         soundcard.h \
 222         stdint.h \
 223         strings.h \
 224         sys/asoundlib.h \
 225         sys/cdio.h \
 226         sys/elf32.h \
 227         sys/epoll.h \
 228         sys/errno.h \
 229         sys/event.h \
 230         sys/exec_elf.h \
 231         sys/filio.h \
 232         sys/ioctl.h \
 233         sys/ipc.h \
 234         sys/limits.h \
 235         sys/link.h \
 236         sys/lwp.h \
 237         sys/mman.h \
 238         sys/modem.h \
 239         sys/msg.h \
 240         sys/mtio.h \
 241         sys/param.h \
 242         sys/poll.h \
 243         sys/prctl.h \
 244         sys/ptrace.h \
 245         sys/reg.h \
 246         sys/resource.h \
 247         sys/scsiio.h \
 248         sys/shm.h \
 249         sys/signal.h \
 250         sys/socket.h \
 251         sys/socketvar.h \
 252         sys/sockio.h \
 253         sys/soundcard.h \
 254         sys/statvfs.h \
 255         sys/strtio.h \
 256         sys/syscall.h \
 257         sys/sysctl.h \
 258         sys/time.h \
 259         sys/times.h \
 260         sys/uio.h \
 261         sys/un.h \
 262         sys/vm86.h \
 263         sys/wait.h \
 264         syscall.h \
 265         termios.h \
 266         unistd.h \
 267         utime.h \
 268         valgrind/memcheck.h
 269 )
 270 AC_HEADER_STAT()
 271
 272 dnl **** Checks for headers that depend on other ones ****
 273
 274 AC_CHECK_HEADERS([sys/mount.h sys/statfs.h sys/user.h sys/vfs.h],,,
 275     [#include <sys/types.h>
 276      #if HAVE_SYS_PARAM_H
 277      # include <sys/param.h>
 278      #endif])
 279
 280 AC_CHECK_HEADERS([netinet/in_pcb.h netinet/ip_var.h net/if.h net/if_arp.h net/if_dl.h net/if_types.h net/route.h netipx/ipx.h],,,
 281     [#include <sys/types.h>
 282      #if HAVE_SYS_SOCKET_H
 283      # include <sys/socket.h>
 284      #endif
 285      #if HAVE_SYS_SOCKETVAR_H
 286      # include <sys/socketvar.h>
 287      #endif
 288      #if HAVE_NETINET_IN_H
 289      # include <netinet/in.h>
 290      #endif])
 291
 292 AC_CHECK_HEADERS([netinet/tcp_var.h],,,
 293     [#include <sys/types.h>
 294      #if HAVE_SYS_SOCKET_H
 295      # include <sys/socket.h>
 296      #endif
 297      #if HAVE_SYS_SOCKETVAR_H
 298      # include <sys/socketvar.h>
 299      #endif
 300      #if HAVE_NETINET_IN_H
 301      # include <netinet/in.h>
 302      #endif
 303      #ifdef HAVE_NETINET_TCP_H
 304      # include <netinet/tcp.h>
 305      #endif])
 306
 307 AC_CHECK_HEADERS([linux/ipx.h],,,
 308     [#include <sys/types.h>
 309      #ifdef HAVE_ASM_TYPES_H
 310      # include <asm/types.h>
 311      #endif
 312      #if HAVE_SYS_SOCKET_H
 313      # include <sys/socket.h>
 314      #endif])
 315
 316 AC_CHECK_HEADERS([resolv.h],,,
 317     [#include <sys/types.h>
 318      #if HAVE_SYS_SOCKET_H
 319      # include <sys/socket.h>
 320      #endif
 321      #if HAVE_NETINET_IN_H
 322      # include <netinet/in.h>
 323      #endif
 324      #if HAVE_ARPA_NAMESER_H
 325      # include <arpa/nameser.h>
 326      #endif])
 327
 328 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
 329
 330 AC_CHECK_HEADERS([sys/thr.h],,,
 331 [#include <sys/types.h>
 332 #if HAVE_UCONTEXT_H
 333 #include <ucontext.h>
 334 #endif])
 335
 336 AC_CHECK_HEADERS([pthread_np.h],,,
 337 [#ifdef HAVE_PTHREAD_H
 338 #include <pthread.h>
 339 #endif])
 340
 341 AC_CHECK_HEADERS([linux/videodev.h],,,
 342 [#ifdef HAVE_SYS_TIME_H
 343 #include <sys/time.h>
 344 #endif
 345 #include <sys/types.h>
 346 #ifdef HAVE_ASM_TYPES_H
 347 #include <asm/types.h>
 348 #endif])
 349
 350 dnl Check for broken kernel header that doesn't define __user
 351 AC_CHECK_HEADERS([linux/capi.h],,,[#define __user])
 352
 353 dnl **** Check for working dll ****
 354
 355 AC_SUBST(DLLEXT,"")
 356 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
 357 AC_SUBST(LDSHARED,"")
 358 AC_SUBST(LDDLLFLAGS,"")
 359 AC_SUBST(LIBEXT,"so")
 360 AC_SUBST(IMPLIBEXT,"def")
 361 AC_SUBST(LDRPATH_INSTALL,"")
 362 AC_SUBST(LDRPATH_LOCAL,"")
 363 WINE_PATH_LDD
 364
 365 case $host_os in
 366   cygwin*|mingw32*)
 367     AC_CHECK_TOOL(DLLTOOL,dlltool,false)
 368     AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
 369     AC_CHECK_TOOL(MINGWAR,ar,false)
 370     if test "$DLLWRAP" = "false"; then
 371       LIBEXT="a"
 372     else
 373       dnl FIXME - check whether dllwrap works correctly...
 374       LIBEXT="dll"
 375     fi
 376     IMPLIBEXT="a"
 377     dnl We can't build 16-bit NE dlls
 378     WIN16_FILES=""
 379     WIN16_INSTALL=""
 380     ;;
 381   darwin*|macosx*)
 382     DLLEXT=".so"
 383     LIBEXT="dylib"
 384     DLLFLAGS="$DLLFLAGS -fPIC"
 385     LDDLLFLAGS="-bundle -multiply_defined suppress"
 386     LIBWINE_LDFLAGS="-multiply_defined suppress"
 387     LDSHARED="\$(CC) -dynamiclib"
 388     STRIP="$STRIP -x"
 389     LDRPATH_LOCAL="&& install_name_tool -change @executable_path/\`\$(RELPATH) \$(bindir) \$(libdir)\`/libwine.1.dylib @executable_path/\$(TOPOBJDIR)/libs/wine/libwine.1.dylib \$@ || \$(RM) \$@"
 390     dnl declare needed frameworks
 391     AC_SUBST(SECURITYLIB,"-framework Security -framework CoreFoundation")
 392     AC_SUBST(COREFOUNDATIONLIB,"-framework CoreFoundation")
 393     AC_SUBST(IOKITLIB,"-framework IOKit -framework CoreFoundation")
 394     AC_SUBST(LDEXECFLAGS,["-image_base 0x7bf00000 -Wl,-segaddr,WINE_DOS,0x00000000,-segaddr,WINE_SHARED_HEAP,0x7f000000"])
 395     if test "$ac_cv_header_DiskArbitration_DiskArbitration_h" = "yes"
 396     then
 397         dnl DiskArbitration API is not public on Darwin < 8.0, use it only if header found
 398         AC_SUBST(DISKARBITRATIONLIB,"-framework DiskArbitration -framework CoreFoundation")
 399     fi
 400     if test "$ac_cv_header_CoreAudio_CoreAudio_h" = "yes" -a "$ac_cv_header_AudioUnit_AudioUnit_h" = "yes"
 401     then
 402         dnl CoreServices needed by AudioUnit
 403         AC_SUBST(COREAUDIO,"-framework CoreAudio -framework AudioUnit -framework CoreServices -framework AudioToolbox -framework CoreMIDI")
 404     fi
 405     case $host_cpu in
 406       *powerpc*)
 407         LDDLLFLAGS="$LDDLLFLAGS -read_only_relocs warning"  dnl FIXME
 408         ;;
 409     esac
 410     dnl Enable quartz driver on Mac OS X
 411     if test "$ac_cv_header_Carbon_Carbon_h" = "yes"
 412     then
 413         AC_SUBST(CARBONLIB,"-framework Carbon")
 414         QUARTZFILES='$(QUARTZFILES)'
 415     fi
 416     ;;
 417   *)
 418     DLLFLAGS="$DLLFLAGS -fPIC"
 419     DLLEXT=".so"
 420     AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
 421         [WINE_TRY_SHLIB_FLAGS([-fPIC -shared -Wl,-Bsymbolic],
 422                               ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
 423     if test "$ac_cv_c_dll_gnuelf" = "yes"
 424     then
 425       LDSHARED="\$(CC) -shared"
 426       LDDLLFLAGS="-shared -Wl,-Bsymbolic"
 427       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-soname,confest.so.1],
 428                       [LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"],
 429                       [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-h,confest.so.1],
 430                                        [LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-h,%)"])])
 431
 432       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs], [LDDLLFLAGS="$LDDLLFLAGS,-z,defs"])
 433
 434       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-init,__wine_spec_init,-fini,__wine_spec_fini],
 435                       [LDDLLFLAGS="$LDDLLFLAGS,-init,__wine_spec_init,-fini,__wine_spec_fini"])
 436
 437       echo '{ global: *; };' >conftest.map
 438       WINE_TRY_CFLAGS([-fPIC -shared -Wl,--version-script=conftest.map],
 439                       [LDSHARED="$LDSHARED \$(VERSCRIPT:%=-Wl,--version-script=%)"])
 440       rm -f conftest.map
 441
 442       WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
 443                       [AC_SUBST(LDEXECFLAGS,["-Wl,--export-dynamic"])])
 444
 445       WINE_TRY_CFLAGS([-fPIC -Wl,--rpath,\$ORIGIN/../lib],
 446                       [LDRPATH_INSTALL="-Wl,--rpath,\\\$\$ORIGIN/\`\$(RELPATH) \$(bindir) \$(libdir)\`"
 447                        LDRPATH_LOCAL="-Wl,--rpath,\\\$\$ORIGIN/\$(TOPOBJDIR)/libs/wine"],
 448           [WINE_TRY_CFLAGS([-fPIC -Wl,-R,\$ORIGIN/../lib],
 449                            [LDRPATH_INSTALL="-Wl,-R,\\\$\$ORIGIN/\`\$(RELPATH) \$(bindir) \$(libdir)\`"
 450                             LDRPATH_LOCAL="-Wl,-R,\\\$\$ORIGIN/\$(TOPOBJDIR)/libs/wine"])])
 451
 452       WINE_TRY_CFLAGS([-Wl,--enable-new-dtags],
 453                       [LDRPATH_INSTALL="$LDRPATH_INSTALL -Wl,--enable-new-dtags"])
 454
 455       case $host_cpu in
 456         *i[[3456789]]86* | x86_64)
 457           WINE_TRY_CFLAGS([-Wl,--section-start,.interp=0x7bf00400],
 458                           [LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x7bf00400"])
 459           ;;
 460       esac
 461
 462     else
 463       AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
 464           [WINE_TRY_SHLIB_FLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
 465                                 ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
 466       if test "$ac_cv_c_dll_unixware" = "yes"
 467       then
 468         LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
 469         LDDLLFLAGS="-Wl,-G,-B,symbolic"
 470
 471       else
 472         AC_CACHE_CHECK(whether we can build an HP-UX dll, ac_cv_c_dll_hpux,
 473           [WINE_TRY_SHLIB_FLAGS([-shared], ac_cv_c_dll_hpux="yes", ac_cv_c_dll_hpux="no")])
 474         if test "$ac_cv_c_dll_hpux" = "yes"
 475         then
 476           LIBEXT="sl"
 477           DLLEXT=".sl"
 478           LDDLLFLAGS="-shared -fPIC"
 479           LDSHARED="\$(CC) -shared"
 480         fi
 481       fi
 482     fi
 483
 484     dnl Check for cross compiler to build test programs
 485     AC_SUBST(CROSSTEST,"")
 486     if test "$cross_compiling" = "no"
 487     then
 488       WINE_CHECK_MINGW_PROG(CROSSCC,gcc,false)
 489       WINE_CHECK_MINGW_PROG(DLLTOOL,dlltool,false)
 490       WINE_CHECK_MINGW_PROG(CROSSWINDRES,windres,false)
 491       WINE_CHECK_MINGW_PROG(MINGWAR,ar,false)
 492       if test "$CROSSCC" != "false"; then CROSSTEST="\$(CROSSTEST)"; fi
 493     fi
 494     ;;
 495 esac
 496
 497 if test "$LIBEXT" = "a"; then
 498   AC_MSG_ERROR(
 499 [could not find a way to build shared libraries.
 500 It is currently not possible to build Wine without shared library
 501 (.so) support to allow transparent switch between .so and .dll files.
 502 If you are using Linux, you will need a newer binutils.]
 503 )
 504 fi
 505
 506 dnl **** Check for X11 ****
 507
 508 if test "$have_x" = "yes"
 509 then
 510     XLIB="-lXext -lX11"
 511     ac_save_CPPFLAGS="$CPPFLAGS"
 512     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 513
 514     WINE_CHECK_SONAME(X11,XCreateWindow,,,[$X_LIBS $X_EXTRA_LIBS])
 515     WINE_CHECK_SONAME(Xext,XextCreateExtension,,,[$X_LIBS -lX11 $X_EXTRA_LIBS])
 516
 517     dnl *** All of the following tests require X11/Xlib.h
 518     AC_CHECK_HEADERS([X11/Xlib.h \
 519                       X11/XKBlib.h \
 520                       X11/Xutil.h \
 521                       X11/Xcursor/Xcursor.h \
 522                       X11/extensions/shape.h \
 523                       X11/extensions/XInput.h \
 524                       X11/extensions/XShm.h \
 525                       X11/extensions/Xcomposite.h \
 526                       X11/extensions/Xinerama.h \
 527                       X11/extensions/Xrandr.h \
 528                       X11/extensions/Xrender.h \
 529                       X11/extensions/xf86vmode.h],,,
 530 [#ifdef HAVE_X11_XLIB_H
 531 # include <X11/Xlib.h>
 532 #endif
 533 #ifdef HAVE_X11_XUTIL_H
 534 # include <X11/Xutil.h>
 535 #endif])
 536
 537         dnl *** Check for X keyboard extension
 538         if test "$ac_cv_header_X11_XKBlib_h" = "yes"
 539         then
 540               AC_CHECK_LIB(X11, XkbQueryExtension,
 541               AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
 542               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 543         fi
 544
 545         dnl *** Check for X cursor
 546         if test "$ac_cv_header_X11_Xcursor_Xcursor_h" = "yes"
 547         then
 548             WINE_CHECK_SONAME(Xcursor,XcursorImageLoadCursor,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
 549         fi
 550
 551         dnl *** Check for X input extension
 552         if test "$ac_cv_header_X11_extensions_XInput_h" = "yes"
 553         then
 554             WINE_CHECK_SONAME(Xi,XOpenDevice,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
 555         fi
 556
 557         dnl *** Check for X Shm extension
 558         if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
 559         then
 560               AC_CHECK_LIB(Xext, XShmQueryExtension,
 561               AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
 562               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 563         fi
 564         WINE_NOTICE_IF([test "$ac_cv_lib_Xext_XShmQueryExtension" != "yes"],[XShm development files not found.
 565 Wine will be built without XShm support. (winex11.drv)])
 566
 567         dnl *** Check for X shape extension
 568         if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
 569         then
 570               AC_CHECK_LIB(Xext,XShapeQueryExtension,
 571               AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
 572               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 573         fi
 574         WINE_NOTICE_IF([test "$ac_cv_lib_Xext_XShapeQueryExtension" != "yes"],[XShape development files not found.
 575 Wine will be built without XShape support. (winex11.drv)])
 576
 577         dnl *** Check for XFree86 VMODE extension
 578         if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
 579         then
 580                 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
 581                   [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
 582                      X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
 583                   ],,
 584                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 585         fi
 586         WINE_NOTICE_IF([test "$ac_cv_lib_Xxf86vm_XF86VidModeQueryExtension" != "yes"],[Xxf86vm development files not found.
 587 Wine will be built without XF86 Vidmode support. (winex11.drv)])
 588
 589         dnl *** Check for Transform functions in Xrender
 590         if test "$ac_cv_header_X11_extensions_Xrender_h" = "yes" -a "x$ac_cv_lib_soname_X11" != "x" -a "x$ac_cv_lib_soname_Xext" != "x"
 591         then
 592             WINE_CHECK_SONAME(Xrender,XRenderQueryExtension,
 593               [AC_CHECK_LIB(Xrender,XRenderSetPictureTransform,
 594                 [AC_DEFINE(HAVE_XRENDERSETPICTURETRANSFORM, 1,
 595                  [Define if Xrender has the XRenderSetPictureTransform function])],,
 596                 [$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])],,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
 597
 598         fi
 599         WINE_NOTICE_IF([test "x$ac_cv_lib_soname_Xrender" = "x"],[XRender development files not found.
 600 Wine will be built without XRender support. (winex11.drv)])
 601
 602         dnl *** Check for X RandR extension
 603         if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes" -a "x$ac_cv_lib_soname_Xrender" != "x"
 604         then
 605                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
 606 #include <X11/extensions/Xrandr.h>]], [[static typeof(XRRSetScreenConfigAndRate) * func;]])],
 607                   [WINE_CHECK_SONAME(Xrandr,XRRQueryExtension,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
 608         fi
 609         WINE_NOTICE_IF([test "x$ac_cv_lib_soname_Xrandr" = "x"],[XRandr development files not found.
 610 Wine will be built without XRandr support. (winex11.drv)])
 611
 612         dnl *** Check for Xinerama extension
 613         if test "$ac_cv_header_X11_extensions_Xinerama_h" = "yes"
 614         then
 615                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
 616 #include <X11/extensions/Xinerama.h>]], [[static typeof(XineramaQueryScreens) * func;]])],
 617                   [WINE_CHECK_SONAME(Xinerama,XineramaQueryScreens,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
 618         fi
 619         WINE_NOTICE_IF([test "x$ac_cv_lib_soname_Xinerama" = "x"],[Xinerama development files not found.
 620 Wine will be built without Xinerama support. (winex11.drv)])
 621
 622         dnl *** Check for X Composite extension
 623         if test "$ac_cv_header_X11_extensions_Xcomposite_h" = "yes"
 624         then
 625             WINE_CHECK_SONAME(Xcomposite,XCompositeRedirectWindow,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
 626         fi
 627         WINE_NOTICE_IF([test "x$ac_cv_lib_soname_Xcomposite" = "x"],[XComposite development files not found.
 628 Wine will be built without XComposite support. (winex11.drv)])
 629
 630     dnl *** End of X11/Xlib.h check
 631
 632     dnl Check for the presence of OpenGL
 633     if test "x$with_opengl" != "xno"
 634     then
 635         AC_CHECK_HEADERS(GL/gl.h GL/glx.h GL/glext.h GL/glu.h,,,
 636 [#ifdef HAVE_GL_GLX_H
 637 # include <GL/glx.h>
 638 #endif])
 639         if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
 640         then
 641             dnl Check for some problems due to old Mesa versions
 642             AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_header_version_OK,
 643               AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GL/gl.h>]], [[GLenum test = GL_UNSIGNED_SHORT_5_6_5;]])],
 644                 [wine_cv_opengl_header_version_OK="yes"],
 645                 [wine_cv_opengl_header_version_OK="no"]))
 646
 647             if test "$wine_cv_opengl_header_version_OK" = "yes"
 648             then
 649                 dnl Check for the presence of the library
 650                 WINE_CHECK_SONAME(GL,glXCreateContext,
 651                              [OPENGL_LIBS="-lGL"
 652                              OPENGLFILES='$(OPENGLFILES)'
 653                              AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])],
 654                              [WINE_CHECK_SONAME(GL,glXCreateContext,
 655                                     [OPENGL_LIBS="-Xlinker -dylib_file -Xlinker /System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib:/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib -lGL"
 656                                     OPENGLFILES='$(OPENGLFILES)'
 657                                     AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])],
 658                                     [if test -f /usr/X11R6/lib/libGL.a
 659                                     then
 660                                         WINE_WARNING([/usr/X11R6/lib/libGL.a is present on your system.
 661 This probably prevents linking to OpenGL. Try deleting the file and restarting configure.])
 662                                     else
 663                                         WINE_WARNING([No OpenGL library found on this system.
 664 Wine will be built without OpenGL or Direct3D support.])
 665                                     fi],
 666                                     $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS -dylib_file /System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib:/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib)],
 667                              $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 668
 669                 dnl Check for GLU32 library.
 670                 AC_CHECK_LIB(GLU,gluLookAt,
 671                              [OPENGL_LIBS="$OPENGL_LIBS -lGLU"
 672                              GLU32FILES='$(GLU32FILES)']
 673                              ,,
 674                              $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 675              else
 676                  WINE_WARNING([Old Mesa headers detected. Consider upgrading your Mesa libraries (http://www.mesa3d.org/).
 677 Wine will be built without OpenGL or Direct3D support.])
 678              fi
 679          else
 680              WINE_WARNING([OpenGL development headers not found.
 681 Wine will be built without OpenGL or Direct3D support.])
 682          fi
 683     fi
 684
 685     dnl **** Check for NAS ****
 686     AC_SUBST(NASLIBS,"")
 687     AC_CHECK_HEADERS(audio/audiolib.h,
 688          [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
 689           AC_CHECK_LIB(audio,AuCreateFlow,
 690                        [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
 691                         AC_CHECK_LIB(Xau,XauGetBestAuthByAddr,
 692                           [NASLIBS="-lXau -laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],
 693                           [NASLIBS="-laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],
 694                           [$X_LIBS])
 695                        ],,
 696                        [-lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
 697
 698     CPPFLAGS="$ac_save_CPPFLAGS"
 699     XFILES='$(XFILES)'
 700 else
 701     XLIB=""
 702     X_CFLAGS=""
 703     X_LIBS=""
 704     WINE_WARNING([X development files not found. Wine will be built
 705 without X support, which probably isn't what you want. You will need to install
 706 development packages of Xlib/Xfree86 at the very least.])
 707 fi
 708
 709 dnl **** Check for libxml2 ****
 710
 711 AC_SUBST(XML2LIBS,"")
 712 AC_SUBST(XML2INCL,"")
 713 AC_SUBST(XSLTLIBS,"")
 714 AC_SUBST(XSLTINCL,"")
 715 ac_save_CPPFLAGS="$CPPFLAGS"
 716 if test "$PKG_CONFIG" != "false"
 717 then
 718     ac_xml_libs="`$PKG_CONFIG --libs libxml-2.0 2>/dev/null`"
 719     ac_xml_cflags="`$PKG_CONFIG --cflags libxml-2.0 2>/dev/null`"
 720 else
 721     ac_xml_libs="`xml2-config --libs 2>/dev/null`"
 722     ac_xml_cflags="`xml2-config --cflags  2>/dev/null`"
 723 fi
 724 CPPFLAGS="$CPPFLAGS $ac_xml_cflags"
 725 AC_CHECK_HEADERS(libxml/parser.h,
 726         [AC_CHECK_LIB(xml2, xmlParseMemory,
 727             [AC_DEFINE(HAVE_LIBXML2, 1, [Define if you have the libxml2 library])
 728              XML2LIBS="$ac_xml_libs"
 729              XML2INCL="$ac_xml_cflags"],,$ac_xml_libs)
 730          AC_CHECK_LIB(xml2, xmlReadMemory,
 731             [AC_DEFINE(HAVE_XMLREADMEMORY,1,[Define if libxml2 has the xmlReadMemory function])],,$ac_xml_libs)
 732          AC_CHECK_LIB(xml2, xmlNewDocPI,
 733             [AC_DEFINE(HAVE_XMLNEWDOCPI,1,[Define if libxml2 has the xmlNewDocPI function])],,$ac_xml_libs)
 734     ])
 735 CPPFLAGS="$ac_save_CPPFLAGS"
 736 WINE_NOTICE_IF([test "$ac_cv_lib_xml2_xmlParseMemory" != "yes"],[libxml2 development files not found.
 737 Wine will be built without XML support. (msxml.dll)])
 738
 739 if test "$PKG_CONFIG" != "false"
 740 then
 741     ac_xslt_libs="`$PKG_CONFIG --libs libxslt 2>/dev/null`"
 742     ac_xslt_cflags="`$PKG_CONFIG --cflags libxslt 2>/dev/null`"
 743 else
 744     ac_xslt_libs="`xslt-config --libs 2>/dev/null`"
 745     ac_xslt_cflags="`xslt-config --cflags 2>/dev/null`"
 746 fi
 747 CPPFLAGS="$CPPFLAGS $ac_xslt_cflags"
 748 AC_CHECK_HEADERS([libxslt/pattern.h libxslt/transform.h],
 749         [AC_CHECK_LIB(xslt, xsltCompilePattern,
 750             [AC_DEFINE(HAVE_LIBXSLT, 1, [Define if you have the libxslt library])
 751              XSLTLIBS="$ac_xslt_libs"
 752              XSLTINCL="$ac_xslt_cflags"],,$ac_xslt_libs)
 753         ],,
 754 [#ifdef HAVE_LIBXSLT_PATTERN_H
 755 # include <libxslt/pattern.h>
 756 #endif])
 757 CPPFLAGS="$ac_save_CPPFLAGS"
 758 WINE_NOTICE_IF([test "$ac_cv_lib_xslt_xsltCompilePattern" != "yes"],[libxslt development files not found.
 759 Wine will be built without xslt support. (msxml.dll)])
 760
 761 dnl **** Check for libhal ****
 762 AC_SUBST(HALINCL,"")
 763 if test "$PKG_CONFIG" != "false"
 764 then
 765     ac_save_CPPFLAGS="$CPPFLAGS"
 766     ac_hal_libs="`$PKG_CONFIG --libs hal 2>/dev/null`"
 767     ac_hal_cflags="`$PKG_CONFIG --cflags hal 2>/dev/null`"
 768     CPPFLAGS="$CPPFLAGS $ac_hal_cflags"
 769     AC_CHECK_HEADERS([dbus/dbus.h hal/libhal.h])
 770     if test "$ac_cv_header_dbus_dbus_h" = "yes" -a "$ac_cv_header_hal_libhal_h" = "yes"
 771     then
 772         AC_CHECK_LIB(dbus-1, dbus_connection_close,
 773           [WINE_CHECK_SONAME(hal, libhal_ctx_new,
 774             [HALINCL="$ac_hal_cflags"],,[$ac_hal_libs])],,[$ac_hal_libs])
 775     fi
 776     CPPFLAGS="$ac_save_CPPFLAGS"
 777 fi
 778 WINE_NOTICE_IF([test "x$ac_cv_lib_soname_hal" = "x"],[libhal development files not found.
 779 Wine will be built without dynamic device support. (explorer.exe)])
 780
 781 dnl **** Check which curses lib to use ***
 782 CURSESLIBS=""
 783 if test "$ac_cv_header_ncurses_h" = "yes"
 784 then
 785     WINE_CHECK_SONAME(ncurses,waddch,[CURSESLIBS="-lncurses"])
 786 elif test "$ac_cv_header_curses_h" = "yes"
 787 then
 788     WINE_CHECK_SONAME(curses,waddch,[CURSESLIBS="-lcurses"])
 789 fi
 790 ac_save_LIBS="$LIBS"
 791 LIBS="$LIBS $CURSESLIBS"
 792 AC_CHECK_FUNCS(mousemask)
 793 LIBS="$ac_save_LIBS"
 794 WINE_NOTICE_IF([test "x$ac_cv_lib_soname_curses$ac_cv_lib_soname_ncurses" = "x"],[lib(n)curses development files not found.
 795 Wine will be built without (n)curses support. (wineconsole.exe)])
 796
 797 dnl **** Check for SANE ****
 798 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
 799 if test "$sane_devel" != "no"
 800 then
 801     ac_sane_incl="`$sane_devel --cflags`"
 802     ac_save_CPPFLAGS="$CPPFLAGS"
 803     CPPFLAGS="$CPPFLAGS $ac_sane_incl"
 804     AC_CHECK_HEADER(sane/sane.h,
 805         [WINE_CHECK_SONAME(sane,sane_init,[AC_SUBST(SANEINCL,"$ac_sane_incl")])])
 806     CPPFLAGS="$ac_save_CPPFLAGS"
 807 fi
 808 WINE_NOTICE_IF([test "x$ac_cv_lib_soname_sane" = "x"],[libsane development files not found.
 809 Wine will be built without scanner support. (sane.ds/twain_32.dll)])
 810
 811 dnl **** Check for libgphoto2 ****
 812 AC_CHECK_PROG(gphoto2_devel,gphoto2-config,gphoto2-config,no)
 813 AC_CHECK_PROG(gphoto2port_devel,gphoto2-port-config,gphoto2-port-config,no)
 814 if test "$gphoto2_devel" != "no" -a "$gphoto2port_devel" != "no"
 815 then
 816     ac_gphoto2_incl="`$gphoto2_devel --cflags` `$gphoto2port_devel --cflags`"
 817     ac_gphoto2_libs=""
 818     for i in `$gphoto2_devel --libs` `$gphoto2port_devel --libs`
 819     do
 820       case "$i" in
 821         -L/usr/lib|-L/usr/lib64) ;;
 822         -L*|-l*) ac_gphoto2_libs="$ac_gphoto2_libs $i";;
 823       esac
 824     done
 825     ac_save_CPPFLAGS="$CPPFLAGS"
 826     CPPFLAGS="$CPPFLAGS $ac_gphoto2_incl"
 827     AC_CHECK_HEADER(gphoto2-camera.h,
 828                     [AC_CHECK_LIB(gphoto2,gp_camera_new,
 829                                   [AC_DEFINE(HAVE_GPHOTO2, 1, [Define if we have libgphoto2 development environment])
 830                                    AC_SUBST(GPHOTO2LIBS,"$ac_gphoto2_libs")
 831                                    AC_SUBST(GPHOTO2INCL,"$ac_gphoto2_incl")],,
 832                                   [$GPHOTO2LIBS])])
 833     CPPFLAGS="$ac_save_CPPFLAGS"
 834 fi
 835 WINE_NOTICE_IF([test "$ac_cv_lib_gphoto2_gp_camera_new" != "yes"],[libgphoto2 development files not found.
 836 Wine will be built without Digital Camera support. (gphoto2.ds/twain_32.dll)])
 837
 838
 839 dnl **** Check for resolver library ***
 840 AC_SUBST(RESOLVLIBS,"")
 841 if test "$ac_cv_header_resolv_h" = "yes"
 842 then
 843     AC_CHECK_LIB(resolv, res_query,
 844         [AC_DEFINE(HAVE_RESOLV, 1, [Define if you have the resolver library and header])
 845          RESOLVLIBS="-lresolv"])
 846 fi
 847
 848 dnl **** Check for LittleCMS ***
 849 AC_SUBST(LCMSLIBS,"")
 850 if test "$ac_cv_header_lcms_h" = "yes" -o "$ac_cv_header_lcms_lcms_h" = "yes"
 851 then
 852     AC_CHECK_LIB(lcms, cmsOpenProfileFromFile,
 853         [AC_DEFINE(HAVE_LCMS, 1, [Define if you have the LittleCMS development environment])
 854          LCMSLIBS="-llcms"])
 855 fi
 856 WINE_NOTICE_IF([test "$ac_cv_lib_lcms_cmsOpenProfileFromFile" != "yes"],[liblcms development files not found.
 857 Wine will be built without Color Management support. (mscms.dll)])
 858
 859 dnl **** Check for OpenLDAP ***
 860 AC_SUBST(LDAPLIBS,"")
 861 if test "$ac_cv_header_ldap_h" = "yes" -a "$ac_cv_header_lber_h" = "yes"
 862 then
 863     AC_CHECK_LIB(ldap_r, ldap_initialize,
 864         [AC_CHECK_LIB(lber, ber_init,
 865             [AC_DEFINE(HAVE_LDAP, 1, [Define if you have the OpenLDAP development environment])
 866              LDAPLIBS="-lldap_r -llber"],,
 867              [$LIBPTHREAD])],,
 868              [$LIBPTHREAD])
 869     WINE_CHECK_LIB_FUNCS(\
 870         ldap_count_references \
 871         ldap_first_reference \
 872         ldap_next_reference \
 873         ldap_parse_reference \
 874         ldap_parse_sort_control \
 875         ldap_parse_sortresponse_control \
 876         ldap_parse_vlv_control \
 877         ldap_parse_vlvresponse_control,
 878         [$LDAPLIBS $LIBPTHREAD])
 879 fi
 880 WINE_NOTICE_IF([test "x$LDAPLIBS" = "x"],[libldap (OpenLDAP) development files not found.
 881 Wine will be built without LDAP support. (wldap32.dll)])
 882
 883 dnl **** Check for FreeType 2 ****
 884 AC_CHECK_PROGS(ft_devel,[freetype-config freetype2-config],false)
 885 if test "$ft_devel" != "false"
 886 then
 887     ac_freetype_libs=`$ft_devel --libs`
 888     ac_freetype_incl=`$ft_devel --cflags`
 889     WINE_CHECK_SONAME(freetype,FT_Init_FreeType,[ft_lib=yes],[ft_lib=no],[$ac_freetype_libs])
 890     if test "$ft_lib" = "yes"
 891     then
 892         ac_save_CPPFLAGS="$CPPFLAGS"
 893         CPPFLAGS="$ac_freetype_incl $CPPFLAGS"
 894         AC_CHECK_HEADERS(ft2build.h \
 895                          freetype/freetype.h \
 896                          freetype/ftglyph.h \
 897                          freetype/fttypes.h \
 898                          freetype/tttables.h \
 899                          freetype/ftnames.h \
 900                          freetype/ftsnames.h \
 901                          freetype/ttnameid.h \
 902                          freetype/ftoutln.h \
 903                          freetype/ftwinfnt.h \
 904                          freetype/ftmodapi.h \
 905                          freetype/internal/sfnt.h,,,
 906                          [#if HAVE_FT2BUILD_H
 907                           #include <ft2build.h>
 908                           #endif])
 909         AC_PREPROC_IFELSE([AC_LANG_SOURCE([[#include <ft2build.h>
 910                     #include <freetype/fttrigon.h>]])],[AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
 911           [Define if you have the <freetype/fttrigon.h> header file.])
 912                     wine_cv_fttrigon=yes],[wine_cv_fttrigon=no])
 913         AC_CHECK_TYPES(FT_TrueTypeEngineType,,,[#include <freetype/ftmodapi.h>])
 914         ac_save_CFLAGS="$CFLAGS"
 915         CFLAGS="$CFLAGS $ac_freetype_libs"
 916         AC_CHECK_FUNCS(FT_Load_Sfnt_Table)
 917         CFLAGS="$ac_save_CFLAGS"
 918         CPPFLAGS="$ac_save_CPPFLAGS"
 919         dnl Check that we have at least freetype/freetype.h
 920         if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
 921         then
 922             AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
 923             AC_SUBST(FREETYPELIBS,"$ac_freetype_libs")
 924             AC_SUBST(FREETYPEINCL,"$ac_freetype_incl")
 925         fi
 926     fi
 927 fi
 928
 929 dnl Only build the fonts dir if we have both freetype and fontforge
 930 if test "$FONTFORGE" = "false"
 931 then
 932     WINE_WARNING([FontForge is missing.
 933 Fonts will not be built. Dialog text may be invisible or unaligned.])
 934 elif test "x$FREETYPELIBS" = "x"
 935 then
 936     WINE_WARNING([FreeType development files not found.
 937 Fonts will not be built. Dialog text may be invisible or unaligned.])
 938 else
 939   AC_SUBST(FONTSSUBDIRS,"fonts")
 940 fi
 941
 942 dnl **** Check for parport (currently Linux only) ****
 943 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
 944  AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <linux/ppdev.h>]], [[ioctl (1,PPCLAIM,0)]])],
 945     [ac_cv_c_ppdev="yes"],[ac_cv_c_ppdev="no"]))
 946 if test "$ac_cv_c_ppdev" = "yes"
 947 then
 948     AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
 949 fi
 950
 951 dnl **** Check for va_copy ****
 952 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
 953  AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdarg.h>]], [[va_list ap1, ap2; va_copy(ap1,ap2);]])],
 954     [ac_cv_c_va_copy="yes"],[ac_cv_c_va_copy="no"])
 955  )
 956 if test "$ac_cv_c_va_copy" = "yes"
 957 then
 958     AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
 959 fi
 960 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
 961  AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdarg.h>]], [[va_list ap1, ap2; __va_copy(ap1,ap2);]])],
 962     [ac_cv_c___va_copy="yes"],[ac_cv_c___va_copy="no"])
 963  )
 964 if test "$ac_cv_c___va_copy" = "yes"
 965 then
 966     AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
 967 fi
 968
 969 dnl **** Check for sigsetjmp ****
 970 AC_CACHE_CHECK([for sigsetjmp], ac_cv_c_sigsetjmp,
 971  AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <setjmp.h>]], [[sigjmp_buf buf;
 972     sigsetjmp( buf, 1 );
 973     siglongjmp( buf, 1 );]])],[ac_cv_c_sigsetjmp="yes"],[ac_cv_c_sigsetjmp="no"])
 974  )
 975 if test "$ac_cv_c_sigsetjmp" = "yes"
 976 then
 977     AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have the sigsetjmp (and siglongjmp) function])
 978 fi
 979
 980 dnl **** Check for pthread_rwlock_t ****
 981 AC_CHECK_TYPES([pthread_rwlock_t, pthread_rwlockattr_t],,,[#define _GNU_SOURCE
 982 #include <pthread.h>])
 983
 984 dnl **** Check for pthread functions ****
 985 WINE_CHECK_LIB_FUNCS(\
 986         pthread_attr_get_np \
 987         pthread_getattr_np \
 988         pthread_get_stackaddr_np \
 989         pthread_get_stacksize_np,
 990         [$LIBPTHREAD])
 991
 992 dnl **** Check for EsounD ****
 993 AC_PATH_PROG(ESDCONFIG, esd-config)
 994 if test x$ESDCONFIG != x -a x$ESDCONFIG != x'"$ESDCONFIG"';
 995 then
 996     ESD_CFLAGS=""
 997     for i in `$ESDCONFIG --cflags`
 998     do
 999       case "$i" in
1000         -I*) ESD_CFLAGS="$ESD_CFLAGS $i";;
1001       esac
1002     done
1003     ESD_LIBS=`$ESDCONFIG --libs`
1004     save_CFLAGS="$CFLAGS"
1005     CFLAGS="$CFLAGS $ESD_CFLAGS"
1006     AC_CHECK_LIB(esd,esd_open_sound,
1007         [AC_SUBST(ESDLIBS, $ESD_LIBS)
1008          AC_SUBST(ESDINCL, $ESD_CFLAGS)
1009          AC_DEFINE(HAVE_ESD, 1, [Define if you have EsounD sound server])])
1010     CFLAGS="$save_CFLAGS"
1011 fi
1012
1013 dnl **** Check for ALSA 1.x ****
1014 AC_SUBST(ALSALIBS,"")
1015 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
1016 then
1017     AC_CHECK_LIB(asound,snd_pcm_hw_params_get_access,
1018         [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef HAVE_ALSA_ASOUNDLIB_H
1019 #include <alsa/asoundlib.h>
1020 #elif defined(HAVE_SYS_ASOUNDLIB_H)
1021 #include <sys/asoundlib.h>
1022 #endif]], [[int ret = snd_pcm_hw_params_get_access(NULL, NULL)]])],
1023                         [AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA 1.x including devel headers])
1024                          ALSALIBS="-lasound"],[])])
1025 fi
1026
1027 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
1028 AC_SUBST(AUDIOIOLIBS,"")
1029 if test "$ac_cv_header_libaudioio_h" = "yes"
1030 then
1031     AC_CHECK_LIB(audioio,AudioIOGetVersion,
1032                   [AUDIOIOLIBS="-laudioio"
1033                    AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])
1034 fi
1035
1036 dnl **** Check for capi4linux ****
1037
1038 if test "$ac_cv_header_capi20_h" = "yes" -a "$ac_cv_header_linux_capi_h" = "yes"
1039 then
1040     WINE_CHECK_SONAME(capi20,capi20_register)
1041 fi
1042 WINE_NOTICE_IF([test "x$ac_cv_lib_soname_capi20" = "x"],[libcapi20 development files not found.
1043 Wine will be built without ISDN support. (capi2032.dll)])
1044
1045 dnl **** Check for cups ****
1046 if test "$ac_cv_header_cups_cups_h" = "yes"
1047 then
1048     WINE_CHECK_SONAME(cups,cupsGetDefault)
1049 fi
1050 WINE_NOTICE_IF([test "x$ac_cv_lib_soname_cups" = "x"],[libcups development files not found.
1051 Wine will be built without CUPS support.])
1052
1053 dnl **** Check for jack ****
1054 if test "$ac_cv_header_jack_jack_h" = "yes"
1055 then
1056     WINE_CHECK_SONAME(jack,jack_client_new)
1057 fi
1058
1059 dnl **** Check for fontconfig ****
1060 if test "$ac_cv_header_fontconfig_fontconfig_h" = "yes"
1061 then
1062     WINE_CHECK_SONAME(fontconfig,FcInit)
1063 elif test -n "$X_CFLAGS"
1064 then
1065     dnl fontconfig is in the X directory on Mac OS X
1066     ac_save_CPPFLAGS="$CPPFLAGS"
1067     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
1068     $as_unset ac_cv_header_fontconfig_fontconfig_h
1069     AC_CHECK_HEADERS([fontconfig/fontconfig.h])
1070     CPPFLAGS="$ac_save_CPPFLAGS"
1071     if test "$ac_cv_header_fontconfig_fontconfig_h" = "yes"
1072     then
1073         AC_SUBST(FONTCONFIGINCL,"$X_CFLAGS")
1074         WINE_CHECK_SONAME(fontconfig,FcInit,,,[$X_LIBS])
1075     fi
1076 fi
1077 WINE_NOTICE_IF([test "x$ac_cv_lib_soname_fontconfig" = "x"],[fontconfig development files not found.
1078 Wine will be built without fontconfig support.])
1079
1080 dnl **** Check for SSL ****
1081 if test "$ac_cv_header_openssl_err_h" = "yes" -a "$ac_cv_header_openssl_ssl_h" = "yes"
1082 then
1083     WINE_CHECK_SONAME(ssl,SSL_library_init)
1084     WINE_CHECK_SONAME(crypto,BIO_new_socket)
1085 fi
1086 WINE_NOTICE_IF([test "x$ac_cv_lib_soname_ssl" = "x"],[OpenSSL development files not found.
1087 Wine will be built without SSL support. (wininet.dll)])
1088
1089 dnl **** Check for libjpeg ****
1090 if test "$ac_cv_header_jpeglib_h" = "yes"
1091 then
1092     WINE_CHECK_SONAME(jpeg,jpeg_start_decompress)
1093 fi
1094 WINE_NOTICE_IF([test "x$ac_cv_lib_soname_jpeg" = "x"],[libjpeg development files not found.
1095 Wine will be built without JPEG support. (oleaut32.dll)])
1096
1097 dnl **** Check for libpng ****
1098 if test "$ac_cv_header_png_h" = "yes"
1099 then
1100     WINE_CHECK_SONAME(png,png_create_read_struct,,,,[[libpng[[0-9]]*]])
1101 fi
1102 WINE_NOTICE_IF([test "x$ac_cv_lib_soname_png" = "x"],[libpng development files not found.
1103 Wine will be built without PNG support. (oleaut32.dll)])
1104
1105 dnl **** Check for any sound system ****
1106 WINE_WARNING_IF([test "x$ALSALIBS$AUDIOIOLIBS$COREAUDIO$NASLIBS$ESD_LIBS$ac_cv_lib_soname_jack" = "x" -a \
1107                  "$ac_cv_header_sys_soundcard_h" != "yes" -a \
1108                  "$ac_cv_header_machine_soundcard_h" != "yes" -a \
1109                  "$ac_cv_header_soundcard_h" != "yes"],
1110 [No sound system was found. Windows applications will be silent.])
1111
1112 dnl **** Check for gcc specific options ****
1113
1114 AC_SUBST(EXTRACFLAGS,"")
1115 if test "x${GCC}" = "xyes"
1116 then
1117   EXTRACFLAGS="-Wall -pipe"
1118
1119   dnl Check for strength-reduce bug
1120   AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
1121                   AC_RUN_IFELSE([AC_LANG_PROGRAM([[int L[[4]] = {0,1,2,3};]],
1122 [[static int Array[[3]];
1123   unsigned int B = 3;
1124   int i;
1125   for(i=0; i<B; i++) Array[[i]] = i - 3;
1126   for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
1127   L[[i]] = 4;
1128   exit( Array[[1]] != -2 || L[[2]] != 3)]])],
1129     [ac_cv_c_gcc_strength_bug="no"],[ac_cv_c_gcc_strength_bug="yes"],[ac_cv_c_gcc_strength_bug="yes"]) )
1130   if test "$ac_cv_c_gcc_strength_bug" = "yes"
1131   then
1132     EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
1133   fi
1134
1135   dnl Check for some compiler flags
1136
1137   WINE_TRY_CFLAGS([-fshort-wchar],
1138                   [AC_DEFINE(CC_FLAG_SHORT_WCHAR, "-fshort-wchar",
1139                              [Specifies the compiler flag that forces a short wchar_t])])
1140   WINE_TRY_CFLAGS([-fno-strict-aliasing])
1141   WINE_TRY_CFLAGS([-Wdeclaration-after-statement])
1142   WINE_TRY_CFLAGS([-Wwrite-strings])
1143
1144   dnl Check for noisy string.h
1145   saved_CFLAGS="$CFLAGS"
1146   CFLAGS="$CFLAGS -Wpointer-arith -Werror"
1147   AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
1148       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string.h>]], [[]])],[ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
1149   CFLAGS="$saved_CFLAGS"
1150   if test "$ac_cv_c_string_h_warnings" = "no"
1151   then
1152     EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
1153   fi
1154
1155   AC_SUBST(BUILTINFLAG,"")
1156   saved_CFLAGS="$CFLAGS"
1157   CFLAGS="$CFLAGS -Werror"
1158   AC_CACHE_CHECK([for builtin wchar inlines], ac_cv_c_builtin_wchar_ctype,
1159       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[int iswlower(unsigned short);]])],[ac_cv_c_builtin_wchar_ctype=no],[ac_cv_c_builtin_wchar_ctype=yes]))
1160   CFLAGS="$saved_CFLAGS"
1161   if test "$ac_cv_c_builtin_wchar_ctype" = "yes"
1162   then
1163     BUILTINFLAG="-fno-builtin"
1164   fi
1165 fi
1166
1167 dnl **** Check how to define a function in assembly code ****
1168
1169 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
1170   WINE_TRY_ASM_LINK(
1171       ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
1172       ac_cv_asm_func_def=".def",
1173     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
1174       ac_cv_asm_func_def=".type @function",
1175     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
1176       ac_cv_asm_func_def=".type 2",
1177       ac_cv_asm_func_def="unknown")])]))
1178
1179 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
1180 case "$ac_cv_asm_func_def" in
1181   ".def")
1182      AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
1183   ".type @function")
1184      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
1185   ".type 2")
1186      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
1187   *)
1188      AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
1189 esac
1190
1191 dnl **** Check for underscore on external symbols ****
1192
1193 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
1194     WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
1195                       [extern int ac_test;],
1196                       [if (ac_test) return 1],
1197                       ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
1198
1199 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
1200 if test "$ac_cv_c_extern_prefix" = "yes"
1201 then
1202   AC_DEFINE([__ASM_NAME(name)], ["_" name])
1203 else
1204   AC_DEFINE([__ASM_NAME(name)], [name])
1205 fi
1206
1207 dnl **** Platform-specific checks ****
1208
1209 AC_SUBST(LDPATH,"")
1210 case $build_os in
1211   cygwin*|mingw32*)
1212     LDPATH="PATH=\"\$(TOOLSDIR)/libs/wine:\$\$PATH\""
1213     ;;
1214   darwin*|macosx*)
1215     ;;
1216   linux*|solaris*)  dnl FIXME: What other platforms support $ORIGIN?
1217     if test -z "$LDRPATH_LOCAL"
1218     then
1219       LDPATH="LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/wine:\$\$LD_LIBRARY_PATH\""
1220     fi
1221     ;;
1222   *)
1223     LDPATH="LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/wine:\$\$LD_LIBRARY_PATH\""
1224     ;;
1225 esac
1226
1227 dnl Mingw needs explicit msvcrt for linking libwine and winsock for wininet
1228 case $host_os in
1229   mingw32*)
1230     AC_SUBST(CRTLIBS,"-lmsvcrt")
1231     AC_SUBST(SOCKETLIBS,"-lws2_32")
1232     ;;
1233 esac
1234
1235 AC_SUBST(MAIN_BINARY,"wine-pthread")  dnl Default value
1236 case $host_cpu in
1237   *i[[3456789]]86*)
1238     case $host_os in
1239       linux* | k*bsd*-gnu)
1240         AC_SUBST(MAIN_BINARY,"wine-glibc")
1241         AC_SUBST(EXTRA_BINARIES,"wine-kthread wine-pthread wine-preloader") ;;
1242       freebsd*)
1243         AC_SUBST(MAIN_BINARY,"wine-freebsd")
1244         AC_SUBST(EXTRA_BINARIES,"wine-pthread") ;;
1245     esac
1246     ;;
1247 esac
1248
1249 dnl **** Check for functions ****
1250
1251 AC_CHECK_FUNCS(\
1252         _pclose \
1253         _popen \
1254         _snprintf \
1255         _spawnvp \
1256         _strdup \
1257         _stricmp \
1258         _strnicmp \
1259         _vsnprintf \
1260         asctime_r \
1261         chsize \
1262         clone \
1263         dlopen \
1264         epoll_create \
1265         ffs \
1266         finite \
1267         fork \
1268         fpclass \
1269         fstatfs \
1270         fstatvfs \
1271         ftruncate \
1272         futimes \
1273         futimesat \
1274         getdirentries \
1275         getopt_long \
1276         getpagesize \
1277         getpwuid \
1278         gettid \
1279         gettimeofday \
1280         getuid \
1281         inet_pton \
1282         kqueue \
1283         lstat \
1284         memmove \
1285         mmap \
1286         pclose \
1287         poll \
1288         popen \
1289         prctl \
1290         pread \
1291         pwrite \
1292         readlink \
1293         rfork \
1294         sched_yield \
1295         select \
1296         setrlimit \
1297         settimeofday \
1298         sigaltstack \
1299         sigprocmask \
1300         snprintf \
1301         spawnvp \
1302         statfs \
1303         statvfs \
1304         strcasecmp \
1305         strdup \
1306         strerror \
1307         strncasecmp \
1308         strtold \
1309         tcgetattr \
1310         thr_kill2 \
1311         timegm \
1312         usleep \
1313         vsnprintf \
1314         wait4 \
1315         waitpid \
1316 )
1317
1318 dnl Check for -ldl
1319 if test "$ac_cv_func_dlopen" = no
1320 then
1321     AC_CHECK_LIB(dl,dlopen,[AC_DEFINE(HAVE_DLOPEN,1) AC_SUBST(LIBDL,"-ldl")])
1322 fi
1323 WINE_CHECK_LIB_FUNCS(dladdr,[$LIBDL])
1324
1325 dnl Check for -lpoll for Mac OS X/Darwin
1326 if test "$ac_cv_func_poll" = no
1327 then
1328     AC_CHECK_LIB(poll,poll,[AC_DEFINE(HAVE_POLL,1) AC_SUBST(LIBPOLL,"-lpoll")])
1329 fi
1330
1331 dnl Check for -lnsl for Solaris
1332 AC_SEARCH_LIBS(gethostbyname, nsl)
1333
1334 dnl Check for -lsocket for Solaris
1335 AC_SEARCH_LIBS(connect, socket)
1336
1337 dnl Check for -lresolv for Solaris
1338 AC_SEARCH_LIBS(inet_aton, resolv)
1339
1340 dnl **** Check for functions which may rely on -lsocket on Solaris.
1341 AC_CHECK_FUNCS(\
1342         getaddrinfo \
1343         getnameinfo \
1344         getnetbyname \
1345         getprotobyname \
1346         getprotobynumber \
1347         getservbyport \
1348         inet_network \
1349         sendmsg \
1350 )
1351
1352 dnl **** Check for types ****
1353
1354 AC_C_CONST
1355 AC_C_INLINE
1356 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t, long long, fsblkcnt_t, fsfilcnt_t])
1357 AC_CHECK_TYPES([sigset_t],,,[#include <signal.h>])
1358 AC_CHECK_TYPES([request_sense],,,[#include <linux/cdrom.h>])
1359
1360 AC_CHECK_MEMBERS([struct ff_effect.direction],,,
1361 [#ifdef HAVE_LINUX_INPUT_H
1362 #include <linux/input.h>
1363 #endif])
1364
1365 AC_CACHE_CHECK([for sigaddset],wine_cv_have_sigaddset,
1366                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <signal.h>]], [[sigset_t set; sigaddset(&set,SIGTERM);]])],[wine_cv_have_sigaddset=yes],[wine_cv_have_sigaddset=no]))
1367 if test "$wine_cv_have_sigaddset" = "yes"
1368 then
1369   AC_DEFINE(HAVE_SIGADDSET, 1, [Define if sigaddset is supported])
1370 fi
1371
1372
1373 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1374         wine_cv_linux_gethostbyname_r_6,
1375         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],[[
1376     char *name=0;
1377     struct hostent he;
1378     struct hostent *result;
1379     char *buf=0;
1380     int bufsize=0;
1381     int res,errnr;
1382     char *addr=0;
1383     int addrlen=0;
1384     int addrtype=0;
1385     res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1386     res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1387     ]])],[wine_cv_linux_gethostbyname_r_6=yes],[wine_cv_linux_gethostbyname_r_6=no
1388         ])
1389    )
1390    if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1391    then
1392       AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1393                 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1394    fi
1395
1396 if test "$ac_cv_header_linux_joystick_h" = "yes"
1397 then
1398    AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1399         wine_cv_linux_joystick_22_api,
1400         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1401         #include <sys/ioctl.h>
1402         #include <sys/types.h>
1403         #include <linux/joystick.h>
1404
1405         struct js_event blub;
1406         #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1407         #error "no 2.2 header"
1408         #endif
1409         ]], [[/*empty*/]])],[wine_cv_linux_joystick_22_api=yes],[wine_cv_linux_joystick_22_api=no])
1410    )
1411    if test "$wine_cv_linux_joystick_22_api" = "yes"
1412    then
1413       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1414                 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1415    fi
1416 fi
1417
1418 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1419
1420 dnl Check for statfs members
1421 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail, struct statfs.f_frsize, struct statfs.f_ffree, struct statfs.f_favail, struct statfs.f_namelen],,,
1422 [#include <sys/types.h>
1423 #ifdef HAVE_SYS_PARAM_H
1424 # include <sys/param.h>
1425 #endif
1426 #ifdef HAVE_SYS_MOUNT_H
1427 # include <sys/mount.h>
1428 #endif
1429 #ifdef HAVE_SYS_VFS_H
1430 # include <sys/vfs.h>
1431 #endif
1432 #ifdef HAVE_SYS_STATFS_H
1433 # include <sys/statfs.h>
1434 #endif])
1435
1436 AC_CHECK_MEMBERS([struct statvfs.f_blocks],,,
1437 [#ifdef HAVE_SYS_STATVFS_H
1438 #include <sys/statvfs.h>
1439 #endif])
1440
1441 dnl Check for socket structure members
1442 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
1443 [#include <sys/types.h>
1444 #ifdef HAVE_SYS_SOCKET_H
1445 # include <sys/socket.h>
1446 #endif
1447 #ifdef HAVE_SYS_UN_H
1448 # include <sys/un.h>
1449 #endif])
1450
1451 dnl Check for scsireq_t and sg_io_hdr_t members
1452 AC_CHECK_MEMBERS([scsireq_t.cmd, sg_io_hdr_t.interface_id],,,
1453 [#include <sys/types.h>
1454 #ifdef HAVE_SCSI_SG_H
1455 #include <scsi/sg.h>
1456 #endif])
1457
1458 dnl Check for siginfo_t members
1459 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
1460
1461 dnl Check for struct mtget members
1462 AC_CHECK_MEMBERS([struct mtget.mt_blksiz, struct mtget.mt_gstat, struct mtget.mt_blkno],,,
1463 [#include <sys/types.h>
1464 #ifdef HAVE_SYS_MTIO_H
1465 #include <sys/mtio.h>
1466 #endif])
1467
1468 dnl Check for struct option
1469 AC_CHECK_MEMBERS([struct option.name],,,
1470 [#ifdef HAVE_GETOPT_H
1471 #include <getopt.h>
1472 #endif])
1473
1474 dnl Check for stat.st_blocks
1475 AC_CHECK_MEMBERS([struct stat.st_blocks])
1476
1477 dnl Check for sin6_scope_id
1478 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_scope_id],,,
1479 [#ifdef HAVE_SYS_TYPES_H
1480 #include <sys/types.h>
1481 #endif
1482 #ifdef HAVE_NETINET_IN_H
1483 #include <netinet/in.h>
1484 #endif])
1485
1486 dnl Check for ns_msg ptr member
1487 AC_CHECK_MEMBERS([ns_msg._msg_ptr],,,
1488 [#ifdef HAVE_SYS_TYPES_H
1489 #include <sys/types.h>
1490 #endif
1491 #ifdef HAVE_NETINET_IN_H
1492 # include <netinet/in.h>
1493 #endif
1494 #ifdef HAVE_ARPA_NAMESER_H
1495 # include <arpa/nameser.h>
1496 #endif])
1497
1498 dnl Check for the external timezone variables timezone and daylight
1499 AC_CACHE_CHECK([for timezone variable], ac_cv_have_timezone,
1500                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[timezone = 1]])],[ac_cv_have_timezone="yes"],[ac_cv_have_timezone="no"]))
1501 if test "$ac_cv_have_timezone" = "yes"
1502 then
1503     AC_DEFINE(HAVE_TIMEZONE, 1, [Define if you have the timezone variable])
1504 fi
1505 AC_CACHE_CHECK([for daylight variable], ac_cv_have_daylight,
1506                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[daylight = 1]])],[ac_cv_have_daylight="yes"],[ac_cv_have_daylight="no"]))
1507 if test "$ac_cv_have_daylight" = "yes"
1508 then
1509     AC_DEFINE(HAVE_DAYLIGHT, 1, [Define if you have the daylight variable])
1510 fi
1511
1512 dnl *** check for the need to define platform-specific symbols
1513
1514 case $host_cpu in
1515   *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
1516   *x86_64*)         WINE_CHECK_DEFINE([__x86_64__]) ;;
1517   *alpha*)          WINE_CHECK_DEFINE([__ALPHA__]) ;;
1518   *sparc*)          WINE_CHECK_DEFINE([__sparc__]) ;;
1519   *powerpc*)        WINE_CHECK_DEFINE([__powerpc__]) ;;
1520 esac
1521
1522 case $host_vendor in
1523   *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
1524 esac
1525
1526 dnl **** Generate output files ****
1527
1528 dnl autoconf versions before 2.59d need backslashes to escape newlines in subst variables
1529 AC_SUBST(DEPENDENCIES,m4_if(m4_version_compare(m4_defn([m4_PACKAGE_VERSION]), [2.59d]), -1,
1530 ["### Dependencies:\\
1531 \\
1532 .INIT: Makefile\\
1533 .BEGIN: Makefile\\
1534 Makefile: dummy\\
1535         -\$(MAKEDEP) -C\$(SRCDIR) -S\$(TOPSRCDIR) -T\$(TOPOBJDIR) \$(EXTRAINCL) \$(DEPEND_SRCS)\\
1536 \\
1537 \$(OBJS): \$(IDL_GEN_HEADERS)\\
1538 \$(IDL_GEN_C_SRCS:.c=.o): \$(IDL_GEN_C_SRCS)\\
1539 \$(LEX_SRCS:.l=.yy.o): \$(LEX_SRCS:.l=.yy.c)\\
1540 \$(BISON_SRCS:.y=.tab.o): \$(BISON_SRCS:.y=.tab.c)"],
1541 ["### Dependencies:
1542
1543 .INIT: Makefile
1544 .BEGIN: Makefile
1545 Makefile: dummy
1546         -\$(MAKEDEP) -C\$(SRCDIR) -S\$(TOPSRCDIR) -T\$(TOPOBJDIR) \$(EXTRAINCL) \$(DEPEND_SRCS)
1547
1548 \$(OBJS): \$(IDL_GEN_HEADERS)
1549 \$(IDL_GEN_C_SRCS:.c=.o): \$(IDL_GEN_C_SRCS)
1550 \$(LEX_SRCS:.l=.yy.o): \$(LEX_SRCS:.l=.yy.c)
1551 \$(BISON_SRCS:.y=.tab.o): \$(BISON_SRCS:.y=.tab.c)"]))
1552
1553 AH_TOP([#define __WINE_CONFIG_H])
1554
1555 AC_CONFIG_COMMANDS([include/stamp-h], [echo timestamp > include/stamp-h])
1556
1557 WINE_CONFIG_EXTRA_DIR(dlls/gdi32/enhmfdrv)
1558 WINE_CONFIG_EXTRA_DIR(dlls/gdi32/mfdrv)
1559 WINE_CONFIG_EXTRA_DIR(dlls/kernel32/nls)
1560 WINE_CONFIG_EXTRA_DIR(dlls/user32/resources)
1561 WINE_CONFIG_EXTRA_DIR(dlls/wineps.drv/data)
1562 WINE_CONFIG_EXTRA_DIR(include/wine)
1563
1564 MAKE_RULES=Make.rules
1565 AC_SUBST_FILE(MAKE_RULES)
1566
1567 MAKE_DLL_RULES=dlls/Makedll.rules
1568 AC_SUBST_FILE(MAKE_DLL_RULES)
1569
1570 MAKE_IMPLIB_RULES=dlls/Makeimplib.rules
1571 AC_SUBST_FILE(MAKE_IMPLIB_RULES)
1572
1573 MAKE_TEST_RULES=dlls/Maketest.rules
1574 AC_SUBST_FILE(MAKE_TEST_RULES)
1575
1576 MAKE_PROG_RULES=programs/Makeprog.rules
1577 AC_SUBST_FILE(MAKE_PROG_RULES)
1578
1579 AC_CONFIG_FILES([Make.rules])
1580 AC_CONFIG_FILES([dlls/Makedll.rules])
1581 AC_CONFIG_FILES([dlls/Makeimplib.rules])
1582 AC_CONFIG_FILES([dlls/Maketest.rules])
1583 AC_CONFIG_FILES([programs/Makeprog.rules])
1584 AC_CONFIG_FILES([Makefile])
1585 AC_CONFIG_FILES([dlls/Makefile])
1586 AC_CONFIG_FILES([dlls/acledit/Makefile])
1587 AC_CONFIG_FILES([dlls/activeds/Makefile])
1588 AC_CONFIG_FILES([dlls/actxprxy/Makefile])
1589 AC_CONFIG_FILES([dlls/advapi32/Makefile])
1590 AC_CONFIG_FILES([dlls/advapi32/tests/Makefile])
1591 AC_CONFIG_FILES([dlls/advpack/Makefile])
1592 AC_CONFIG_FILES([dlls/advpack/tests/Makefile])
1593 AC_CONFIG_FILES([dlls/amstream/Makefile])
1594 AC_CONFIG_FILES([dlls/atl/Makefile])
1595 AC_CONFIG_FILES([dlls/avicap32/Makefile])
1596 AC_CONFIG_FILES([dlls/avifil32/Makefile])
1597 AC_CONFIG_FILES([dlls/browseui/Makefile])
1598 AC_CONFIG_FILES([dlls/browseui/tests/Makefile])
1599 AC_CONFIG_FILES([dlls/cabinet/Makefile])
1600 AC_CONFIG_FILES([dlls/cabinet/tests/Makefile])
1601 AC_CONFIG_FILES([dlls/capi2032/Makefile])
1602 AC_CONFIG_FILES([dlls/cards/Makefile])
1603 AC_CONFIG_FILES([dlls/cfgmgr32/Makefile])
1604 AC_CONFIG_FILES([dlls/clusapi/Makefile])
1605 AC_CONFIG_FILES([dlls/comcat/Makefile])
1606 AC_CONFIG_FILES([dlls/comcat/tests/Makefile])
1607 AC_CONFIG_FILES([dlls/comctl32/Makefile])
1608 AC_CONFIG_FILES([dlls/comctl32/tests/Makefile])
1609 AC_CONFIG_FILES([dlls/comdlg32/Makefile])
1610 AC_CONFIG_FILES([dlls/comdlg32/tests/Makefile])
1611 AC_CONFIG_FILES([dlls/compstui/Makefile])
1612 AC_CONFIG_FILES([dlls/credui/Makefile])
1613 AC_CONFIG_FILES([dlls/credui/tests/Makefile])
1614 AC_CONFIG_FILES([dlls/crtdll/Makefile])
1615 AC_CONFIG_FILES([dlls/crypt32/Makefile])
1616 AC_CONFIG_FILES([dlls/crypt32/tests/Makefile])
1617 AC_CONFIG_FILES([dlls/cryptdll/Makefile])
1618 AC_CONFIG_FILES([dlls/cryptnet/Makefile])
1619 AC_CONFIG_FILES([dlls/cryptnet/tests/Makefile])
1620 AC_CONFIG_FILES([dlls/ctapi32/Makefile])
1621 AC_CONFIG_FILES([dlls/ctl3d32/Makefile])
1622 AC_CONFIG_FILES([dlls/d3d10/Makefile])
1623 AC_CONFIG_FILES([dlls/d3d8/Makefile])
1624 AC_CONFIG_FILES([dlls/d3d8/tests/Makefile])
1625 AC_CONFIG_FILES([dlls/d3d9/Makefile])
1626 AC_CONFIG_FILES([dlls/d3d9/tests/Makefile])
1627 AC_CONFIG_FILES([dlls/d3dim/Makefile])
1628 AC_CONFIG_FILES([dlls/d3drm/Makefile])
1629 AC_CONFIG_FILES([dlls/d3drm/tests/Makefile])
1630 AC_CONFIG_FILES([dlls/d3dx8/Makefile])
1631 AC_CONFIG_FILES([dlls/d3dx8/tests/Makefile])
1632 AC_CONFIG_FILES([dlls/d3dxof/Makefile])
1633 AC_CONFIG_FILES([dlls/dbghelp/Makefile])
1634 AC_CONFIG_FILES([dlls/dciman32/Makefile])
1635 AC_CONFIG_FILES([dlls/ddraw/Makefile])
1636 AC_CONFIG_FILES([dlls/ddraw/tests/Makefile])
1637 AC_CONFIG_FILES([dlls/ddrawex/Makefile])
1638 AC_CONFIG_FILES([dlls/devenum/Makefile])
1639 AC_CONFIG_FILES([dlls/dinput/Makefile])
1640 AC_CONFIG_FILES([dlls/dinput/tests/Makefile])
1641 AC_CONFIG_FILES([dlls/dinput8/Makefile])
1642 AC_CONFIG_FILES([dlls/dmband/Makefile])
1643 AC_CONFIG_FILES([dlls/dmcompos/Makefile])
1644 AC_CONFIG_FILES([dlls/dmime/Makefile])
1645 AC_CONFIG_FILES([dlls/dmloader/Makefile])
1646 AC_CONFIG_FILES([dlls/dmscript/Makefile])
1647 AC_CONFIG_FILES([dlls/dmstyle/Makefile])
1648 AC_CONFIG_FILES([dlls/dmsynth/Makefile])
1649 AC_CONFIG_FILES([dlls/dmusic/Makefile])
1650 AC_CONFIG_FILES([dlls/dmusic32/Makefile])
1651 AC_CONFIG_FILES([dlls/dnsapi/Makefile])
1652 AC_CONFIG_FILES([dlls/dnsapi/tests/Makefile])
1653 AC_CONFIG_FILES([dlls/dplay/Makefile])
1654 AC_CONFIG_FILES([dlls/dplayx/Makefile])
1655 AC_CONFIG_FILES([dlls/dplayx/tests/Makefile])
1656 AC_CONFIG_FILES([dlls/dpnaddr/Makefile])
1657 AC_CONFIG_FILES([dlls/dpnet/Makefile])
1658 AC_CONFIG_FILES([dlls/dpnhpast/Makefile])
1659 AC_CONFIG_FILES([dlls/dpnlobby/Makefile])
1660 AC_CONFIG_FILES([dlls/dsound/Makefile])
1661 AC_CONFIG_FILES([dlls/dsound/tests/Makefile])
1662 AC_CONFIG_FILES([dlls/dswave/Makefile])
1663 AC_CONFIG_FILES([dlls/dwmapi/Makefile])
1664 AC_CONFIG_FILES([dlls/dxdiagn/Makefile])
1665 AC_CONFIG_FILES([dlls/dxerr8/Makefile])
1666 AC_CONFIG_FILES([dlls/dxerr9/Makefile])
1667 AC_CONFIG_FILES([dlls/dxguid/Makefile])
1668 AC_CONFIG_FILES([dlls/faultrep/Makefile])
1669 AC_CONFIG_FILES([dlls/gdi32/Makefile])
1670 AC_CONFIG_FILES([dlls/gdi32/tests/Makefile])
1671 AC_CONFIG_FILES([dlls/gdiplus/Makefile])
1672 AC_CONFIG_FILES([dlls/gdiplus/tests/Makefile])
1673 AC_CONFIG_FILES([dlls/glu32/Makefile])
1674 AC_CONFIG_FILES([dlls/gphoto2.ds/Makefile])
1675 AC_CONFIG_FILES([dlls/hal/Makefile])
1676 AC_CONFIG_FILES([dlls/hhctrl.ocx/Makefile])
1677 AC_CONFIG_FILES([dlls/hid/Makefile])
1678 AC_CONFIG_FILES([dlls/hlink/Makefile])
1679 AC_CONFIG_FILES([dlls/hlink/tests/Makefile])
1680 AC_CONFIG_FILES([dlls/hnetcfg/Makefile])
1681 AC_CONFIG_FILES([dlls/iccvid/Makefile])
1682 AC_CONFIG_FILES([dlls/icmp/Makefile])
1683 AC_CONFIG_FILES([dlls/ifsmgr.vxd/Makefile])
1684 AC_CONFIG_FILES([dlls/imaadp32.acm/Makefile])
1685 AC_CONFIG_FILES([dlls/imagehlp/Makefile])
1686 AC_CONFIG_FILES([dlls/imm32/Makefile])
1687 AC_CONFIG_FILES([dlls/inetcomm/Makefile])
1688 AC_CONFIG_FILES([dlls/inetcomm/tests/Makefile])
1689 AC_CONFIG_FILES([dlls/infosoft/Makefile])
1690 AC_CONFIG_FILES([dlls/infosoft/tests/Makefile])
1691 AC_CONFIG_FILES([dlls/inkobj/Makefile])
1692 AC_CONFIG_FILES([dlls/inseng/Makefile])
1693 AC_CONFIG_FILES([dlls/iphlpapi/Makefile])
1694 AC_CONFIG_FILES([dlls/iphlpapi/tests/Makefile])
1695 AC_CONFIG_FILES([dlls/itss/Makefile])
1696 AC_CONFIG_FILES([dlls/itss/tests/Makefile])
1697 AC_CONFIG_FILES([dlls/kernel32/Makefile])
1698 AC_CONFIG_FILES([dlls/kernel32/tests/Makefile])
1699 AC_CONFIG_FILES([dlls/localspl/Makefile])
1700 AC_CONFIG_FILES([dlls/localspl/tests/Makefile])
1701 AC_CONFIG_FILES([dlls/localui/Makefile])
1702 AC_CONFIG_FILES([dlls/localui/tests/Makefile])
1703 AC_CONFIG_FILES([dlls/lz32/Makefile])
1704 AC_CONFIG_FILES([dlls/lz32/tests/Makefile])
1705 AC_CONFIG_FILES([dlls/mapi32/Makefile])
1706 AC_CONFIG_FILES([dlls/mapi32/tests/Makefile])
1707 AC_CONFIG_FILES([dlls/mciavi32/Makefile])
1708 AC_CONFIG_FILES([dlls/mcicda/Makefile])
1709 AC_CONFIG_FILES([dlls/mciseq/Makefile])
1710 AC_CONFIG_FILES([dlls/mciwave/Makefile])
1711 AC_CONFIG_FILES([dlls/midimap/Makefile])
1712 AC_CONFIG_FILES([dlls/mlang/Makefile])
1713 AC_CONFIG_FILES([dlls/mlang/tests/Makefile])
1714 AC_CONFIG_FILES([dlls/mmdevldr.vxd/Makefile])
1715 AC_CONFIG_FILES([dlls/monodebg.vxd/Makefile])
1716 AC_CONFIG_FILES([dlls/mpr/Makefile])
1717 AC_CONFIG_FILES([dlls/mprapi/Makefile])
1718 AC_CONFIG_FILES([dlls/msacm32.drv/Makefile])
1719 AC_CONFIG_FILES([dlls/msacm32/Makefile])
1720 AC_CONFIG_FILES([dlls/msacm32/tests/Makefile])
1721 AC_CONFIG_FILES([dlls/msadp32.acm/Makefile])
1722 AC_CONFIG_FILES([dlls/mscat32/Makefile])
1723 AC_CONFIG_FILES([dlls/mscms/Makefile])
1724 AC_CONFIG_FILES([dlls/mscms/tests/Makefile])
1725 AC_CONFIG_FILES([dlls/mscoree/Makefile])
1726 AC_CONFIG_FILES([dlls/msdmo/Makefile])
1727 AC_CONFIG_FILES([dlls/msftedit/Makefile])
1728 AC_CONFIG_FILES([dlls/msg711.acm/Makefile])
1729 AC_CONFIG_FILES([dlls/mshtml.tlb/Makefile])
1730 AC_CONFIG_FILES([dlls/mshtml/Makefile])
1731 AC_CONFIG_FILES([dlls/mshtml/tests/Makefile])
1732 AC_CONFIG_FILES([dlls/msi/Makefile])
1733 AC_CONFIG_FILES([dlls/msi/tests/Makefile])
1734 AC_CONFIG_FILES([dlls/msimg32/Makefile])
1735 AC_CONFIG_FILES([dlls/msimtf/Makefile])
1736 AC_CONFIG_FILES([dlls/msisys.ocx/Makefile])
1737 AC_CONFIG_FILES([dlls/msnet32/Makefile])
1738 AC_CONFIG_FILES([dlls/msrle32/Makefile])
1739 AC_CONFIG_FILES([dlls/msvcirt/Makefile])
1740 AC_CONFIG_FILES([dlls/msvcrt/Makefile])
1741 AC_CONFIG_FILES([dlls/msvcrt/tests/Makefile])
1742 AC_CONFIG_FILES([dlls/msvcrt20/Makefile])
1743 AC_CONFIG_FILES([dlls/msvcrt40/Makefile])
1744 AC_CONFIG_FILES([dlls/msvcrtd/Makefile])
1745 AC_CONFIG_FILES([dlls/msvcrtd/tests/Makefile])
1746 AC_CONFIG_FILES([dlls/msvfw32/Makefile])
1747 AC_CONFIG_FILES([dlls/msvidc32/Makefile])
1748 AC_CONFIG_FILES([dlls/mswsock/Makefile])
1749 AC_CONFIG_FILES([dlls/msxml3/Makefile])
1750 AC_CONFIG_FILES([dlls/msxml3/tests/Makefile])
1751 AC_CONFIG_FILES([dlls/nddeapi/Makefile])
1752 AC_CONFIG_FILES([dlls/netapi32/Makefile])
1753 AC_CONFIG_FILES([dlls/netapi32/tests/Makefile])
1754 AC_CONFIG_FILES([dlls/newdev/Makefile])
1755 AC_CONFIG_FILES([dlls/ntdll/Makefile])
1756 AC_CONFIG_FILES([dlls/ntdll/tests/Makefile])
1757 AC_CONFIG_FILES([dlls/ntdsapi/Makefile])
1758 AC_CONFIG_FILES([dlls/ntoskrnl.exe/Makefile])
1759 AC_CONFIG_FILES([dlls/ntprint/Makefile])
1760 AC_CONFIG_FILES([dlls/ntprint/tests/Makefile])
1761 AC_CONFIG_FILES([dlls/objsel/Makefile])
1762 AC_CONFIG_FILES([dlls/odbc32/Makefile])
1763 AC_CONFIG_FILES([dlls/odbccp32/Makefile])
1764 AC_CONFIG_FILES([dlls/odbccp32/tests/Makefile])
1765 AC_CONFIG_FILES([dlls/ole32/Makefile])
1766 AC_CONFIG_FILES([dlls/ole32/tests/Makefile])
1767 AC_CONFIG_FILES([dlls/oleacc/Makefile])
1768 AC_CONFIG_FILES([dlls/oleaut32/Makefile])
1769 AC_CONFIG_FILES([dlls/oleaut32/tests/Makefile])
1770 AC_CONFIG_FILES([dlls/olecli32/Makefile])
1771 AC_CONFIG_FILES([dlls/oledlg/Makefile])
1772 AC_CONFIG_FILES([dlls/olepro32/Makefile])
1773 AC_CONFIG_FILES([dlls/olesvr32/Makefile])
1774 AC_CONFIG_FILES([dlls/olethk32/Makefile])
1775 AC_CONFIG_FILES([dlls/opengl32/Makefile])
1776 AC_CONFIG_FILES([dlls/opengl32/tests/Makefile])
1777 AC_CONFIG_FILES([dlls/pdh/Makefile])
1778 AC_CONFIG_FILES([dlls/pdh/tests/Makefile])
1779 AC_CONFIG_FILES([dlls/powrprof/Makefile])
1780 AC_CONFIG_FILES([dlls/printui/Makefile])
1781 AC_CONFIG_FILES([dlls/psapi/Makefile])
1782 AC_CONFIG_FILES([dlls/psapi/tests/Makefile])
1783 AC_CONFIG_FILES([dlls/pstorec/Makefile])
1784 AC_CONFIG_FILES([dlls/qcap/Makefile])
1785 AC_CONFIG_FILES([dlls/qmgr/Makefile])
1786 AC_CONFIG_FILES([dlls/qmgrprxy/Makefile])
1787 AC_CONFIG_FILES([dlls/quartz/Makefile])
1788 AC_CONFIG_FILES([dlls/quartz/tests/Makefile])
1789 AC_CONFIG_FILES([dlls/query/Makefile])
1790 AC_CONFIG_FILES([dlls/rasapi32/Makefile])
1791 AC_CONFIG_FILES([dlls/resutils/Makefile])
1792 AC_CONFIG_FILES([dlls/riched20/Makefile])
1793 AC_CONFIG_FILES([dlls/riched20/tests/Makefile])
1794 AC_CONFIG_FILES([dlls/riched32/Makefile])
1795 AC_CONFIG_FILES([dlls/riched32/tests/Makefile])
1796 AC_CONFIG_FILES([dlls/rpcrt4/Makefile])
1797 AC_CONFIG_FILES([dlls/rpcrt4/tests/Makefile])
1798 AC_CONFIG_FILES([dlls/rsabase/Makefile])
1799 AC_CONFIG_FILES([dlls/rsabase/tests/Makefile])
1800 AC_CONFIG_FILES([dlls/rsaenh/Makefile])
1801 AC_CONFIG_FILES([dlls/rsaenh/tests/Makefile])
1802 AC_CONFIG_FILES([dlls/sane.ds/Makefile])
1803 AC_CONFIG_FILES([dlls/schannel/Makefile])
1804 AC_CONFIG_FILES([dlls/schannel/tests/Makefile])
1805 AC_CONFIG_FILES([dlls/secur32/Makefile])
1806 AC_CONFIG_FILES([dlls/secur32/tests/Makefile])
1807 AC_CONFIG_FILES([dlls/security/Makefile])
1808 AC_CONFIG_FILES([dlls/sensapi/Makefile])
1809 AC_CONFIG_FILES([dlls/serialui/Makefile])
1810 AC_CONFIG_FILES([dlls/serialui/tests/Makefile])
1811 AC_CONFIG_FILES([dlls/setupapi/Makefile])
1812 AC_CONFIG_FILES([dlls/setupapi/tests/Makefile])
1813 AC_CONFIG_FILES([dlls/sfc/Makefile])
1814 AC_CONFIG_FILES([dlls/sfc_os/Makefile])
1815 AC_CONFIG_FILES([dlls/shdoclc/Makefile])
1816 AC_CONFIG_FILES([dlls/shdocvw/Makefile])
1817 AC_CONFIG_FILES([dlls/shdocvw/tests/Makefile])
1818 AC_CONFIG_FILES([dlls/shell32/Makefile])
1819 AC_CONFIG_FILES([dlls/shell32/tests/Makefile])
1820 AC_CONFIG_FILES([dlls/shfolder/Makefile])
1821 AC_CONFIG_FILES([dlls/shlwapi/Makefile])
1822 AC_CONFIG_FILES([dlls/shlwapi/tests/Makefile])
1823 AC_CONFIG_FILES([dlls/snmpapi/Makefile])
1824 AC_CONFIG_FILES([dlls/snmpapi/tests/Makefile])
1825 AC_CONFIG_FILES([dlls/spoolss/Makefile])
1826 AC_CONFIG_FILES([dlls/spoolss/tests/Makefile])
1827 AC_CONFIG_FILES([dlls/stdole2.tlb/Makefile])
1828 AC_CONFIG_FILES([dlls/stdole32.tlb/Makefile])
1829 AC_CONFIG_FILES([dlls/sti/Makefile])
1830 AC_CONFIG_FILES([dlls/strmiids/Makefile])
1831 AC_CONFIG_FILES([dlls/svrapi/Makefile])
1832 AC_CONFIG_FILES([dlls/sxs/Makefile])
1833 AC_CONFIG_FILES([dlls/tapi32/Makefile])
1834 AC_CONFIG_FILES([dlls/twain_32/Makefile])
1835 AC_CONFIG_FILES([dlls/unicows/Makefile])
1836 AC_CONFIG_FILES([dlls/url/Makefile])
1837 AC_CONFIG_FILES([dlls/urlmon/Makefile])
1838 AC_CONFIG_FILES([dlls/urlmon/tests/Makefile])
1839 AC_CONFIG_FILES([dlls/user32/Makefile])
1840 AC_CONFIG_FILES([dlls/user32/tests/Makefile])
1841 AC_CONFIG_FILES([dlls/userenv/Makefile])
1842 AC_CONFIG_FILES([dlls/usp10/Makefile])
1843 AC_CONFIG_FILES([dlls/usp10/tests/Makefile])
1844 AC_CONFIG_FILES([dlls/uuid/Makefile])
1845 AC_CONFIG_FILES([dlls/uxtheme/Makefile])
1846 AC_CONFIG_FILES([dlls/uxtheme/tests/Makefile])
1847 AC_CONFIG_FILES([dlls/vdhcp.vxd/Makefile])
1848 AC_CONFIG_FILES([dlls/vdmdbg/Makefile])
1849 AC_CONFIG_FILES([dlls/version/Makefile])
1850 AC_CONFIG_FILES([dlls/version/tests/Makefile])
1851 AC_CONFIG_FILES([dlls/vmm.vxd/Makefile])
1852 AC_CONFIG_FILES([dlls/vnbt.vxd/Makefile])
1853 AC_CONFIG_FILES([dlls/vnetbios.vxd/Makefile])
1854 AC_CONFIG_FILES([dlls/vtdapi.vxd/Makefile])
1855 AC_CONFIG_FILES([dlls/vwin32.vxd/Makefile])
1856 AC_CONFIG_FILES([dlls/w32skrnl/Makefile])
1857 AC_CONFIG_FILES([dlls/winealsa.drv/Makefile])
1858 AC_CONFIG_FILES([dlls/wineaudioio.drv/Makefile])
1859 AC_CONFIG_FILES([dlls/winecoreaudio.drv/Makefile])
1860 AC_CONFIG_FILES([dlls/winecrt0/Makefile])
1861 AC_CONFIG_FILES([dlls/wined3d/Makefile])
1862 AC_CONFIG_FILES([dlls/winedos/Makefile])
1863 AC_CONFIG_FILES([dlls/wineesd.drv/Makefile])
1864 AC_CONFIG_FILES([dlls/winejack.drv/Makefile])
1865 AC_CONFIG_FILES([dlls/winejoystick.drv/Makefile])
1866 AC_CONFIG_FILES([dlls/winemp3.acm/Makefile])
1867 AC_CONFIG_FILES([dlls/winenas.drv/Makefile])
1868 AC_CONFIG_FILES([dlls/wineoss.drv/Makefile])
1869 AC_CONFIG_FILES([dlls/wineps.drv/Makefile])
1870 AC_CONFIG_FILES([dlls/winequartz.drv/Makefile])
1871 AC_CONFIG_FILES([dlls/winex11.drv/Makefile])
1872 AC_CONFIG_FILES([dlls/wing32/Makefile])
1873 AC_CONFIG_FILES([dlls/winhttp/Makefile])
1874 AC_CONFIG_FILES([dlls/wininet/Makefile])
1875 AC_CONFIG_FILES([dlls/wininet/tests/Makefile])
1876 AC_CONFIG_FILES([dlls/winmm/Makefile])
1877 AC_CONFIG_FILES([dlls/winmm/tests/Makefile])
1878 AC_CONFIG_FILES([dlls/winnls32/Makefile])
1879 AC_CONFIG_FILES([dlls/winscard/Makefile])
1880 AC_CONFIG_FILES([dlls/winspool.drv/Makefile])
1881 AC_CONFIG_FILES([dlls/winspool.drv/tests/Makefile])
1882 AC_CONFIG_FILES([dlls/wintab32/Makefile])
1883 AC_CONFIG_FILES([dlls/wintrust/Makefile])
1884 AC_CONFIG_FILES([dlls/wintrust/tests/Makefile])
1885 AC_CONFIG_FILES([dlls/wldap32/Makefile])
1886 AC_CONFIG_FILES([dlls/wnaspi32/Makefile])
1887 AC_CONFIG_FILES([dlls/wow32/Makefile])
1888 AC_CONFIG_FILES([dlls/ws2_32/Makefile])
1889 AC_CONFIG_FILES([dlls/ws2_32/tests/Makefile])
1890 AC_CONFIG_FILES([dlls/wsock32/Makefile])
1891 AC_CONFIG_FILES([dlls/wtsapi32/Makefile])
1892 AC_CONFIG_FILES([documentation/Makefile])
1893 AC_CONFIG_FILES([fonts/Makefile])
1894 AC_CONFIG_FILES([include/Makefile])
1895 AC_CONFIG_FILES([libs/Makefile])
1896 AC_CONFIG_FILES([libs/port/Makefile])
1897 AC_CONFIG_FILES([libs/wine/Makefile])
1898 AC_CONFIG_FILES([libs/wpp/Makefile])
1899 AC_CONFIG_FILES([loader/Makefile])
1900 AC_CONFIG_FILES([programs/Makefile])
1901 AC_CONFIG_FILES([programs/clock/Makefile])
1902 AC_CONFIG_FILES([programs/cmd/Makefile])
1903 AC_CONFIG_FILES([programs/cmdlgtst/Makefile])
1904 AC_CONFIG_FILES([programs/control/Makefile])
1905 AC_CONFIG_FILES([programs/eject/Makefile])
1906 AC_CONFIG_FILES([programs/expand/Makefile])
1907 AC_CONFIG_FILES([programs/explorer/Makefile])
1908 AC_CONFIG_FILES([programs/hh/Makefile])
1909 AC_CONFIG_FILES([programs/icinfo/Makefile])
1910 AC_CONFIG_FILES([programs/iexplore/Makefile])
1911 AC_CONFIG_FILES([programs/msiexec/Makefile])
1912 AC_CONFIG_FILES([programs/net/Makefile])
1913 AC_CONFIG_FILES([programs/notepad/Makefile])
1914 AC_CONFIG_FILES([programs/oleview/Makefile])
1915 AC_CONFIG_FILES([programs/progman/Makefile])
1916 AC_CONFIG_FILES([programs/regedit/Makefile])
1917 AC_CONFIG_FILES([programs/regsvr32/Makefile])
1918 AC_CONFIG_FILES([programs/rpcss/Makefile])
1919 AC_CONFIG_FILES([programs/rundll32/Makefile])
1920 AC_CONFIG_FILES([programs/spoolsv/Makefile])
1921 AC_CONFIG_FILES([programs/start/Makefile])
1922 AC_CONFIG_FILES([programs/svchost/Makefile])
1923 AC_CONFIG_FILES([programs/taskmgr/Makefile])
1924 AC_CONFIG_FILES([programs/uninstaller/Makefile])
1925 AC_CONFIG_FILES([programs/view/Makefile])
1926 AC_CONFIG_FILES([programs/wineboot/Makefile])
1927 AC_CONFIG_FILES([programs/winebrowser/Makefile])
1928 AC_CONFIG_FILES([programs/winecfg/Makefile])
1929 AC_CONFIG_FILES([programs/wineconsole/Makefile])
1930 AC_CONFIG_FILES([programs/winedbg/Makefile])
1931 AC_CONFIG_FILES([programs/winedevice/Makefile])
1932 AC_CONFIG_FILES([programs/winefile/Makefile])
1933 AC_CONFIG_FILES([programs/winemenubuilder/Makefile])
1934 AC_CONFIG_FILES([programs/winemine/Makefile])
1935 AC_CONFIG_FILES([programs/winepath/Makefile])
1936 AC_CONFIG_FILES([programs/winetest/Makefile])
1937 AC_CONFIG_FILES([programs/winevdm/Makefile])
1938 AC_CONFIG_FILES([programs/winhelp/Makefile])
1939 AC_CONFIG_FILES([programs/winver/Makefile])
1940 AC_CONFIG_FILES([programs/wordpad/Makefile])
1941 AC_CONFIG_FILES([programs/write/Makefile])
1942 AC_CONFIG_FILES([programs/xcopy/Makefile])
1943 AC_CONFIG_FILES([server/Makefile])
1944 AC_CONFIG_FILES([tools/Makefile])
1945 AC_CONFIG_FILES([tools/widl/Makefile])
1946 AC_CONFIG_FILES([tools/winebuild/Makefile])
1947 AC_CONFIG_FILES([tools/winedump/Makefile])
1948 AC_CONFIG_FILES([tools/winegcc/Makefile])
1949 AC_CONFIG_FILES([tools/wmc/Makefile])
1950 AC_CONFIG_FILES([tools/wrc/Makefile])
1951
1952 AC_OUTPUT
1953
1954 if test "$no_create" = "yes"
1955 then
1956   exit 0
1957 fi
1958
1959 WINE_PRINT_MESSAGES
1960
1961 echo
1962 echo "Configure finished.  Do '${ac_make} depend && ${ac_make}' to compile Wine."
1963 echo
1964
1965 dnl Local Variables:
1966 dnl comment-start: "dnl "
1967 dnl comment-end: ""
1968 dnl comment-start-skip: "\\bdnl\\b\\s *"
1969 dnl compile-command: "autoreconf --warnings=all"
1970 dnl End: