git.oblomov.eu Git - wine/blob - programs/winedbg/dbg.y

   1 %{
   2 /*
   3  * Parser for command lines in the Wine debugger
   4  *
   5  * Copyright 1993 Eric Youngdale
   6  * Copyright 1995 Morten Welinder
   7  * Copyright 2000 Eric Pouech
   8  *
   9  * This library is free software; you can redistribute it and/or
  10  * modify it under the terms of the GNU Lesser General Public
  11  * License as published by the Free Software Foundation; either
  12  * version 2.1 of the License, or (at your option) any later version.
  13  *
  14  * This library is distributed in the hope that it will be useful,
  15  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  16  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  17  * Lesser General Public License for more details.
  18  *
  19  * You should have received a copy of the GNU Lesser General Public
  20  * License along with this library; if not, write to the Free Software
  21  * Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA
  22  */
  23
  24 #include "config.h"
  25 #include "wine/port.h"
  26
  27 #include <stdlib.h>
  28 #include <string.h>
  29 #ifdef HAVE_UNISTD_H
  30 # include <unistd.h>
  31 #endif
  32
  33 #include "debugger.h"
  34 #include "wine/exception.h"
  35 #include "expr.h"
  36
  37 int yylex(void);
  38 int yyerror(const char*);
  39
  40 %}
  41
  42 %union
  43 {
  44     struct dbg_lvalue   lvalue;
  45     char*               string;
  46     int                 integer;
  47     IMAGEHLP_LINE       listing;
  48     struct expr*        expression;
  49     struct type_expr_t  type;
  50 }
  51
  52 %token tCONT tPASS tSTEP tLIST tNEXT tQUIT tHELP tBACKTRACE tALL tINFO tUP tDOWN
  53 %token tENABLE tDISABLE tBREAK tHBREAK tWATCH tDELETE tSET tPRINT tEXAM
  54 %token tABORT tECHO
  55 %token tCLASS tMAPS tSTACK tSEGMENTS tSYMBOL tREGS tALLREGS tWND tQUEUE tLOCAL tEXCEPTION
  56 %token tPROCESS tTHREAD tMODREF tEOL tEOF
  57 %token tFRAME tSHARE tCOND tDISPLAY tUNDISPLAY tDISASSEMBLE
  58 %token tSTEPI tNEXTI tFINISH tSHOW tDIR tWHATIS tSOURCE
  59 %token <string> tPATH tIDENTIFIER tSTRING tDEBUGSTR tINTVAR
  60 %token <integer> tNUM tFORMAT
  61 %token tSYMBOLFILE tRUN tATTACH tDETACH tMAINTENANCE tTYPE tMINIDUMP
  62 %token tNOPROCESS
  63
  64 %token tCHAR tSHORT tINT tLONG tFLOAT tDOUBLE tUNSIGNED tSIGNED
  65 %token tSTRUCT tUNION tENUM
  66
  67 /* %left ',' */
  68 /* %left '=' OP_OR_EQUAL OP_XOR_EQUAL OP_AND_EQUAL OP_SHL_EQUAL \
  69          OP_SHR_EQUAL OP_PLUS_EQUAL OP_MINUS_EQUAL \
  70          OP_TIMES_EQUAL OP_DIVIDE_EQUAL OP_MODULO_EQUAL */
  71 /* %left OP_COND */ /* ... ? ... : ... */
  72 %left OP_LOR
  73 %left OP_LAND
  74 %left '|'
  75 %left '^'
  76 %left '&'
  77 %left OP_EQ OP_NE
  78 %left '<' '>' OP_LE OP_GE
  79 %left OP_SHL OP_SHR
  80 %left '+' '-'
  81 %left '*' '/' '%'
  82 %left OP_SIGN '!' '~' OP_DEREF /* OP_INC OP_DEC OP_ADDR */
  83 %left '.' '[' OP_DRF OP_SCOPE
  84 %nonassoc ':'
  85
  86 %type <expression> expr lvalue
  87 %type <lvalue> expr_lvalue lvalue_addr
  88 %type <integer> expr_rvalue
  89 %type <string> pathname identifier cpp_identifier
  90 %type <listing> list_arg
  91 %type <type> type_expr
  92
  93 %%
  94
  95 input:
  96       line
  97     | input line
  98     ;
  99
 100 line:
 101       command tEOL              { expr_free_all(); }
 102     | tEOL
 103     | tEOF                      { return 1; }
 104     | error tEOL                { yyerrok; expr_free_all(); }
 105     ;
 106
 107 command:
 108       tQUIT                     { return 1; }
 109     | tHELP                     { print_help(); }
 110     | tHELP tINFO               { info_help(); }
 111     | tPASS                     { dbg_wait_next_exception(DBG_EXCEPTION_NOT_HANDLED, 0, 0); }
 112     | tCONT                     { dbg_wait_next_exception(DBG_CONTINUE, 1,  dbg_exec_cont); }
 113     | tCONT tNUM                { dbg_wait_next_exception(DBG_CONTINUE, $2, dbg_exec_cont); }
 114     | tSTEP                     { dbg_wait_next_exception(DBG_CONTINUE, 1,  dbg_exec_step_into_line); }
 115     | tSTEP tNUM                { dbg_wait_next_exception(DBG_CONTINUE, $2, dbg_exec_step_into_line); }
 116     | tNEXT                     { dbg_wait_next_exception(DBG_CONTINUE, 1,  dbg_exec_step_over_line); }
 117     | tNEXT tNUM                { dbg_wait_next_exception(DBG_CONTINUE, $2, dbg_exec_step_over_line); }
 118     | tSTEPI                    { dbg_wait_next_exception(DBG_CONTINUE, 1,  dbg_exec_step_into_insn); }
 119     | tSTEPI tNUM               { dbg_wait_next_exception(DBG_CONTINUE, $2, dbg_exec_step_into_insn); }
 120     | tNEXTI                    { dbg_wait_next_exception(DBG_CONTINUE, 1,  dbg_exec_step_over_insn); }
 121     | tNEXTI tNUM               { dbg_wait_next_exception(DBG_CONTINUE, $2, dbg_exec_step_over_insn); }
 122     | tFINISH                   { dbg_wait_next_exception(DBG_CONTINUE, 0,  dbg_exec_finish); }
 123     | tABORT                    { abort(); }
 124     | tBACKTRACE                { stack_backtrace(dbg_curr_tid); }
 125     | tBACKTRACE tNUM           { stack_backtrace($2); }
 126     | tBACKTRACE tALL           { stack_backtrace(-1); }
 127     | tUP                       { stack_set_frame(dbg_curr_thread->curr_frame + 1);  }
 128     | tUP tNUM                  { stack_set_frame(dbg_curr_thread->curr_frame + $2); }
 129     | tDOWN                     { stack_set_frame(dbg_curr_thread->curr_frame - 1);  }
 130     | tDOWN tNUM                { stack_set_frame(dbg_curr_thread->curr_frame - $2); }
 131     | tFRAME tNUM               { stack_set_frame($2); }
 132     | tSHOW tDIR                { source_show_path(); }
 133     | tDIR pathname             { source_add_path($2); }
 134     | tDIR                      { source_nuke_path(); }
 135     | tCOND tNUM                { break_add_condition($2, NULL); }
 136     | tCOND tNUM expr           { break_add_condition($2, $3); }
 137     | tSOURCE pathname          { parser($2); }
 138     | tSYMBOLFILE pathname      { symbol_read_symtable($2, 0); }
 139     | tSYMBOLFILE pathname expr_rvalue { symbol_read_symtable($2, $3); }
 140     | tWHATIS expr_lvalue       { dbg_printf("type = "); types_print_type(&$2.type, FALSE); dbg_printf("\n"); }
 141     | tATTACH tNUM              { dbg_attach_debuggee($2, FALSE, TRUE); }
 142     | tDETACH                   { dbg_curr_process->process_io->close_process(dbg_curr_process, FALSE); }
 143     | tMINIDUMP pathname        { minidump_write($2, (dbg_curr_thread && dbg_curr_thread->in_exception) ? &dbg_curr_thread->excpt_record : NULL);}
 144     | tECHO tSTRING             { dbg_printf("%s\n", $2); }
 145     | run_command
 146     | list_command
 147     | disassemble_command
 148     | set_command
 149     | x_command
 150     | print_command
 151     | break_command
 152     | watch_command
 153     | display_command
 154     | info_command
 155     | maintenance_command
 156     | noprocess_state
 157     ;
 158
 159 pathname:
 160       identifier                { $$ = $1; }
 161     | tSTRING                   { $$ = $1; }
 162     | tPATH                     { $$ = $1; }
 163     ;
 164
 165 cpp_identifier:
 166       tIDENTIFIER               { $$ = $1; }
 167     | identifier OP_SCOPE tIDENTIFIER { $$ = lexeme_alloc_size(strlen($1) + 2 + strlen($3) + 1);
 168                                        sprintf($$, "%s::%s", $1, $3); }
 169     ;
 170
 171 identifier:
 172       cpp_identifier            { $$ = $1; }
 173     | tIDENTIFIER '!' cpp_identifier { $$ = lexeme_alloc_size(strlen($1) + 1 + strlen($3) + 1);
 174                                        sprintf($$, "%s!%s", $1, $3); }
 175     ;
 176
 177 list_arg:
 178       tNUM                      { $$.FileName = NULL; $$.LineNumber = $1; }
 179     | pathname ':' tNUM         { $$.FileName = $1; $$.LineNumber = $3; }
 180     | identifier                { symbol_get_line(NULL, $1, &$$); }
 181     | pathname ':' identifier   { symbol_get_line($3, $1, &$$); }
 182     | '*' expr_lvalue           { DWORD disp; $$.SizeOfStruct = sizeof($$);
 183                                   SymGetLineFromAddr(dbg_curr_process->handle, (unsigned long)memory_to_linear_addr(& $2.addr), &disp, & $$); }
 184     ;
 185
 186 run_command:
 187       tRUN                      { dbg_run_debuggee(NULL); }
 188     | tRUN tSTRING              { dbg_run_debuggee($2); }
 189     ;
 190
 191 list_command:
 192       tLIST                     { source_list(NULL, NULL, 10); }
 193     | tLIST '-'                 { source_list(NULL,  NULL, -10); }
 194     | tLIST list_arg            { source_list(& $2, NULL, 10); }
 195     | tLIST ',' list_arg        { source_list(NULL, & $3, -10); }
 196     | tLIST list_arg ',' list_arg      { source_list(& $2, & $4, 0); }
 197     ;
 198
 199 disassemble_command:
 200       tDISASSEMBLE              { memory_disassemble(NULL, NULL, 10); }
 201     | tDISASSEMBLE expr_lvalue  { memory_disassemble(&$2, NULL, 10); }
 202     | tDISASSEMBLE expr_lvalue ',' expr_lvalue { memory_disassemble(&$2, &$4, 0); }
 203     ;
 204
 205 set_command:
 206       tSET lvalue_addr '=' expr_rvalue { memory_write_value(&$2, sizeof(int), &$4); }
 207     | tSET '+' tIDENTIFIER      { info_wine_dbg_channel(TRUE, NULL, $3); }
 208     | tSET '-' tIDENTIFIER      { info_wine_dbg_channel(FALSE, NULL, $3); }
 209     | tSET tIDENTIFIER '+' tIDENTIFIER { info_wine_dbg_channel(TRUE, $2, $4); }
 210     | tSET tIDENTIFIER '-' tIDENTIFIER { info_wine_dbg_channel(FALSE, $2, $4); }
 211     ;
 212
 213 x_command:
 214       tEXAM expr_lvalue         { memory_examine(&$2, 1, 'x'); }
 215     | tEXAM tFORMAT expr_lvalue { memory_examine(&$3, $2 >> 8, $2 & 0xff); }
 216     ;
 217
 218 print_command:
 219       tPRINT expr_lvalue         { print_value(&$2, 0, 0); }
 220     | tPRINT tFORMAT expr_lvalue { if (($2 >> 8) == 1) print_value(&$3, $2 & 0xff, 0); else dbg_printf("Count is meaningless in print command\n"); }
 221     ;
 222
 223 break_command:
 224       tBREAK '*' expr_lvalue    { break_add_break_from_lvalue(&$3, TRUE); }
 225     | tBREAK identifier         { break_add_break_from_id($2, -1, TRUE); }
 226     | tBREAK identifier ':' tNUM { break_add_break_from_id($2, $4, TRUE); }
 227     | tBREAK tNUM               { break_add_break_from_lineno($2, TRUE); }
 228     | tBREAK                    { break_add_break_from_lineno(-1, TRUE); }
 229     | tHBREAK '*' expr_lvalue   { break_add_break_from_lvalue(&$3, FALSE); }
 230     | tHBREAK identifier        { break_add_break_from_id($2, -1, FALSE); }
 231     | tHBREAK identifier ':' tNUM { break_add_break_from_id($2, $4, FALSE); }
 232     | tHBREAK tNUM              { break_add_break_from_lineno($2, FALSE); }
 233     | tHBREAK                   { break_add_break_from_lineno(-1, FALSE); }
 234     | tENABLE tNUM              { break_enable_xpoint($2, TRUE); }
 235     | tENABLE tBREAK tNUM       { break_enable_xpoint($3, TRUE); }
 236     | tDISABLE tNUM             { break_enable_xpoint($2, FALSE); }
 237     | tDISABLE tBREAK tNUM      { break_enable_xpoint($3, FALSE); }
 238     | tDELETE tNUM              { break_delete_xpoint($2); }
 239     | tDELETE tBREAK tNUM       { break_delete_xpoint($3); }
 240     ;
 241
 242 watch_command:
 243       tWATCH '*' expr_lvalue    { break_add_watch_from_lvalue(&$3); }
 244     | tWATCH identifier         { break_add_watch_from_id($2); }
 245     ;
 246
 247 display_command:
 248       tDISPLAY                  { display_print(); }
 249     | tDISPLAY expr             { display_add($2, 1, 0); }
 250     | tDISPLAY tFORMAT expr     { display_add($3, $2 >> 8, $2 & 0xff); }
 251     | tENABLE tDISPLAY tNUM     { display_enable($3, TRUE); }
 252     | tDISABLE tDISPLAY tNUM    { display_enable($3, FALSE); }
 253     | tDELETE tDISPLAY tNUM     { display_delete($3); }
 254     | tDELETE tDISPLAY          { display_delete(-1); }
 255     | tUNDISPLAY tNUM           { display_delete($2); }
 256     | tUNDISPLAY                { display_delete(-1); }
 257     ;
 258
 259 info_command:
 260       tINFO tBREAK              { break_info(); }
 261     | tINFO tSHARE              { info_win32_module(0); }
 262     | tINFO tSHARE expr_rvalue  { info_win32_module($3); }
 263     | tINFO tREGS               { be_cpu->print_context(dbg_curr_thread->handle, &dbg_context, 0); }
 264     | tINFO tALLREGS            { be_cpu->print_context(dbg_curr_thread->handle, &dbg_context, 1); }
 265     | tINFO tSEGMENTS expr_rvalue { info_win32_segments($3 >> 3, 1); }
 266     | tINFO tSEGMENTS           { info_win32_segments(0, -1); }
 267     | tINFO tSTACK              { stack_info(); }
 268     | tINFO tSYMBOL tSTRING     { symbol_info($3); }
 269     | tINFO tLOCAL              { symbol_info_locals(); }
 270     | tINFO tDISPLAY            { display_info(); }
 271     | tINFO tCLASS              { info_win32_class(NULL, NULL); }
 272     | tINFO tCLASS tSTRING      { info_win32_class(NULL, $3); }
 273     | tINFO tWND                { info_win32_window(NULL, FALSE); }
 274     | tINFO tWND expr_rvalue    { info_win32_window((HWND)$3, FALSE); }
 275     | tINFO '*' tWND            { info_win32_window(NULL, TRUE); }
 276     | tINFO '*' tWND expr_rvalue { info_win32_window((HWND)$4, TRUE); }
 277     | tINFO tPROCESS            { info_win32_processes(); }
 278     | tINFO tTHREAD             { info_win32_threads(); }
 279     | tINFO tEXCEPTION          { info_win32_exceptions(dbg_curr_tid); }
 280     | tINFO tEXCEPTION expr_rvalue { info_win32_exceptions($3); }
 281     | tINFO tMAPS               { info_win32_virtual(dbg_curr_pid); }
 282     | tINFO tMAPS expr_rvalue   { info_win32_virtual($3); }
 283     ;
 284
 285 maintenance_command:
 286       tMAINTENANCE tTYPE        { print_types(); }
 287     ;
 288
 289 noprocess_state:
 290       tNOPROCESS                 {} /* <CR> shall not barf anything */
 291     | tNOPROCESS tBACKTRACE tALL { stack_backtrace(-1); } /* can backtrace all threads with no attached process */
 292     | tNOPROCESS tSTRING         { dbg_printf("No process loaded, cannot execute '%s'\n", $2); }
 293     ;
 294
 295 type_expr:
 296       tCHAR                     { $$.type = type_expr_type_id; $$.deref_count = 0; $$.u.type.module = 0; $$.u.type.id = dbg_itype_char; }
 297     | tINT                      { $$.type = type_expr_type_id; $$.deref_count = 0; $$.u.type.module = 0; $$.u.type.id = dbg_itype_signed_int; }
 298     | tLONG tINT                { $$.type = type_expr_type_id; $$.deref_count = 0; $$.u.type.module = 0; $$.u.type.id = dbg_itype_signed_long_int; }
 299     | tLONG                     { $$.type = type_expr_type_id; $$.deref_count = 0; $$.u.type.module = 0; $$.u.type.id = dbg_itype_signed_long_int; }
 300     | tUNSIGNED tINT            { $$.type = type_expr_type_id; $$.deref_count = 0; $$.u.type.module = 0; $$.u.type.id = dbg_itype_unsigned_int; }
 301     | tUNSIGNED                 { $$.type = type_expr_type_id; $$.deref_count = 0; $$.u.type.module = 0; $$.u.type.id = dbg_itype_unsigned_int; }
 302     | tLONG tUNSIGNED tINT      { $$.type = type_expr_type_id; $$.deref_count = 0; $$.u.type.module = 0; $$.u.type.id = dbg_itype_unsigned_long_int; }
 303     | tLONG tUNSIGNED           { $$.type = type_expr_type_id; $$.deref_count = 0; $$.u.type.module = 0; $$.u.type.id = dbg_itype_unsigned_long_int; }
 304     | tSHORT tINT               { $$.type = type_expr_type_id; $$.deref_count = 0; $$.u.type.module = 0; $$.u.type.id = dbg_itype_signed_short_int; }
 305     | tSHORT                    { $$.type = type_expr_type_id; $$.deref_count = 0; $$.u.type.module = 0; $$.u.type.id = dbg_itype_signed_short_int; }
 306     | tSHORT tUNSIGNED tINT     { $$.type = type_expr_type_id; $$.deref_count = 0; $$.u.type.module = 0; $$.u.type.id = dbg_itype_unsigned_short_int; }
 307     | tSHORT tUNSIGNED          { $$.type = type_expr_type_id; $$.deref_count = 0; $$.u.type.module = 0; $$.u.type.id = dbg_itype_unsigned_short_int; }
 308     | tSIGNED tCHAR             { $$.type = type_expr_type_id; $$.deref_count = 0; $$.u.type.module = 0; $$.u.type.id = dbg_itype_signed_char_int; }
 309     | tUNSIGNED tCHAR           { $$.type = type_expr_type_id; $$.deref_count = 0; $$.u.type.module = 0; $$.u.type.id = dbg_itype_unsigned_char_int; }
 310     | tLONG tLONG tUNSIGNED tINT{ $$.type = type_expr_type_id; $$.deref_count = 0; $$.u.type.module = 0; $$.u.type.id = dbg_itype_unsigned_longlong_int; }
 311     | tLONG tLONG tUNSIGNED     { $$.type = type_expr_type_id; $$.deref_count = 0; $$.u.type.module = 0; $$.u.type.id = dbg_itype_unsigned_longlong_int; }
 312     | tLONG tLONG tINT          { $$.type = type_expr_type_id; $$.deref_count = 0; $$.u.type.module = 0; $$.u.type.id = dbg_itype_signed_longlong_int; }
 313     | tLONG tLONG               { $$.type = type_expr_type_id; $$.deref_count = 0; $$.u.type.module = 0; $$.u.type.id = dbg_itype_signed_longlong_int; }
 314     | tFLOAT                    { $$.type = type_expr_type_id; $$.deref_count = 0; $$.u.type.module = 0; $$.u.type.id = dbg_itype_short_real; }
 315     | tDOUBLE                   { $$.type = type_expr_type_id; $$.deref_count = 0; $$.u.type.module = 0; $$.u.type.id = dbg_itype_real; }
 316     | tLONG tDOUBLE             { $$.type = type_expr_type_id; $$.deref_count = 0; $$.u.type.module = 0; $$.u.type.id = dbg_itype_long_real; }
 317     | type_expr '*'             { $$ = $1; $$.deref_count++; }
 318     | tCLASS identifier         { $$.type = type_expr_udt_class; $$.deref_count = 0; $$.u.name = $2; }
 319     | tSTRUCT identifier        { $$.type = type_expr_udt_struct; $$.deref_count = 0; $$.u.name = $2; }
 320     | tUNION identifier         { $$.type = type_expr_udt_union; $$.deref_count = 0; $$.u.name = $2; }
 321     | tENUM identifier          { $$.type = type_expr_enumeration; $$.deref_count = 0; $$.u.name = $2; }
 322     ;
 323
 324 expr_lvalue:
 325       expr                      { $$ = expr_eval($1); }
 326     ;
 327
 328 expr_rvalue:
 329       expr_lvalue               { $$ = types_extract_as_integer(&$1); }
 330     ;
 331
 332 /*
 333  * The expr rule builds an expression tree.  When we are done, we call
 334  * EvalExpr to evaluate the value of the expression.  The advantage of
 335  * the two-step approach is that it is possible to save expressions for
 336  * use in 'display' commands, and in conditional watchpoints.
 337  */
 338 expr:
 339       tNUM                      { $$ = expr_alloc_sconstant($1); }
 340     | tSTRING                   { $$ = expr_alloc_string($1); }
 341     | tINTVAR                   { $$ = expr_alloc_internal_var($1); }
 342     | identifier                { $$ = expr_alloc_symbol($1); }
 343     | expr OP_DRF tIDENTIFIER   { $$ = expr_alloc_pstruct($1, $3); }
 344     | expr '.' tIDENTIFIER      { $$ = expr_alloc_struct($1, $3); }
 345     | identifier '(' ')'        { $$ = expr_alloc_func_call($1, 0); }
 346     | identifier '(' expr ')'   { $$ = expr_alloc_func_call($1, 1, $3); }
 347     | identifier '(' expr ',' expr ')' { $$ = expr_alloc_func_call($1, 2, $3, $5); }
 348     | identifier '(' expr ',' expr ',' expr ')' { $$ = expr_alloc_func_call($1, 3, $3, $5, $7); }
 349     | identifier '(' expr ',' expr ',' expr ',' expr ')' { $$ = expr_alloc_func_call($1, 4, $3, $5, $7, $9); }
 350     | identifier '(' expr ',' expr ',' expr ',' expr ',' expr ')' { $$ = expr_alloc_func_call($1, 5, $3, $5, $7, $9, $11); }
 351     | expr '[' expr ']'          { $$ = expr_alloc_binary_op(EXP_OP_ARR, $1, $3); }
 352     | expr ':' expr              { $$ = expr_alloc_binary_op(EXP_OP_SEG, $1, $3); }
 353     | expr OP_LOR expr           { $$ = expr_alloc_binary_op(EXP_OP_LOR, $1, $3); }
 354     | expr OP_LAND expr          { $$ = expr_alloc_binary_op(EXP_OP_LAND, $1, $3); }
 355     | expr '|' expr              { $$ = expr_alloc_binary_op(EXP_OP_OR, $1, $3); }
 356     | expr '&' expr              { $$ = expr_alloc_binary_op(EXP_OP_AND, $1, $3); }
 357     | expr '^' expr              { $$ = expr_alloc_binary_op(EXP_OP_XOR, $1, $3); }
 358     | expr OP_EQ expr            { $$ = expr_alloc_binary_op(EXP_OP_EQ, $1, $3); }
 359     | expr '>' expr              { $$ = expr_alloc_binary_op(EXP_OP_GT, $1, $3); }
 360     | expr '<' expr              { $$ = expr_alloc_binary_op(EXP_OP_LT, $1, $3); }
 361     | expr OP_GE expr            { $$ = expr_alloc_binary_op(EXP_OP_GE, $1, $3); }
 362     | expr OP_LE expr            { $$ = expr_alloc_binary_op(EXP_OP_LE, $1, $3); }
 363     | expr OP_NE expr            { $$ = expr_alloc_binary_op(EXP_OP_NE, $1, $3); }
 364     | expr OP_SHL expr           { $$ = expr_alloc_binary_op(EXP_OP_SHL, $1, $3); }
 365     | expr OP_SHR expr           { $$ = expr_alloc_binary_op(EXP_OP_SHR, $1, $3); }
 366     | expr '+' expr              { $$ = expr_alloc_binary_op(EXP_OP_ADD, $1, $3); }
 367     | expr '-' expr              { $$ = expr_alloc_binary_op(EXP_OP_SUB, $1, $3); }
 368     | expr '*' expr              { $$ = expr_alloc_binary_op(EXP_OP_MUL, $1, $3); }
 369     | expr '/' expr              { $$ = expr_alloc_binary_op(EXP_OP_DIV, $1, $3); }
 370     | expr '%' expr              { $$ = expr_alloc_binary_op(EXP_OP_REM, $1, $3); }
 371     | '-' expr %prec OP_SIGN     { $$ = expr_alloc_unary_op(EXP_OP_NEG, $2); }
 372     | '+' expr %prec OP_SIGN     { $$ = $2; }
 373     | '!' expr                   { $$ = expr_alloc_unary_op(EXP_OP_NOT, $2); }
 374     | '~' expr                   { $$ = expr_alloc_unary_op(EXP_OP_LNOT, $2); }
 375     | '(' expr ')'               { $$ = $2; }
 376     | '*' expr %prec OP_DEREF    { $$ = expr_alloc_unary_op(EXP_OP_DEREF, $2); }
 377     | '&' expr %prec OP_DEREF    { $$ = expr_alloc_unary_op(EXP_OP_ADDR, $2); }
 378     | '(' type_expr ')' expr %prec OP_DEREF { $$ = expr_alloc_typecast(&$2, $4); }
 379     ;
 380
 381 /*
 382  * The lvalue rule builds an expression tree.  This is a limited form
 383  * of expression that is suitable to be used as an lvalue.
 384  */
 385 lvalue_addr:
 386       lvalue                     { $$ = expr_eval($1); }
 387     ;
 388
 389 lvalue:
 390       tNUM                       { $$ = expr_alloc_sconstant($1); }
 391     | tINTVAR                    { $$ = expr_alloc_internal_var($1); }
 392     | identifier                 { $$ = expr_alloc_symbol($1); }
 393     | lvalue OP_DRF tIDENTIFIER  { $$ = expr_alloc_pstruct($1, $3); }
 394     | lvalue '.' tIDENTIFIER     { $$ = expr_alloc_struct($1, $3); }
 395     | lvalue '[' expr ']'        { $$ = expr_alloc_binary_op(EXP_OP_ARR, $1, $3); }
 396     | '*' expr                   { $$ = expr_alloc_unary_op(EXP_OP_FORCE_DEREF, $2); }
 397     ;
 398
 399 %%
 400
 401 static WINE_EXCEPTION_FILTER(wine_dbg_cmd)
 402 {
 403     switch (GetExceptionCode())
 404     {
 405     case DEBUG_STATUS_INTERNAL_ERROR:
 406         dbg_printf("\nWineDbg internal error\n");
 407         break;
 408     case DEBUG_STATUS_NO_SYMBOL:
 409         dbg_printf("\nUndefined symbol\n");
 410         break;
 411     case DEBUG_STATUS_DIV_BY_ZERO:
 412         dbg_printf("\nDivision by zero\n");
 413         break;
 414     case DEBUG_STATUS_BAD_TYPE:
 415         dbg_printf("\nNo type or type mismatch\n");
 416         break;
 417     case DEBUG_STATUS_NO_FIELD:
 418         dbg_printf("\nNo such field in structure or union\n");
 419         break;
 420     case DEBUG_STATUS_CANT_DEREF:
 421         dbg_printf("\nDereference failed (not a pointer, or out of array bounds)\n");
 422         break;
 423     case DEBUG_STATUS_ABORT:
 424         break;
 425     case DEBUG_STATUS_NOT_AN_INTEGER:
 426         dbg_printf("\nNeeding an integral value\n");
 427         break;
 428     case CONTROL_C_EXIT:
 429         /* this is generally sent by a ctrl-c when we run winedbg outside of wineconsole */
 430         /* stop the debuggee, and continue debugger execution, we will be reentered by the
 431          * debug events generated by stopping
 432          */
 433         dbg_interrupt_debuggee();
 434         return EXCEPTION_CONTINUE_EXECUTION;
 435     default:
 436         dbg_printf("\nException %lx\n", GetExceptionCode());
 437         break;
 438     }
 439
 440     return EXCEPTION_EXECUTE_HANDLER;
 441 }
 442
 443 static HANDLE dbg_parser_input;
 444 static HANDLE dbg_parser_output;
 445
 446 int      input_fetch_entire_line(const char* pfx, char** line)
 447 {
 448     char        ch;
 449     DWORD       nread;
 450     size_t      len, alloc;
 451
 452     /* as of today, console handles can be file handles... so better use file APIs rather than
 453      * console's
 454      */
 455     WriteFile(dbg_parser_output, pfx, strlen(pfx), &nread, NULL);
 456
 457     if (*line)
 458     {
 459         alloc = HeapSize(GetProcessHeap(), 0, *line);
 460         assert(alloc);
 461     }
 462     else
 463     {
 464         *line = HeapAlloc(GetProcessHeap(), 0, alloc = 16);
 465         assert(*line);
 466     }
 467
 468     len = 0;
 469     do
 470     {
 471         if (!ReadFile(dbg_parser_input, &ch, 1, &nread, NULL) || nread == 0)
 472             break;
 473         if (len + 2 > alloc)
 474         {
 475             while (len + 2 > alloc) alloc *= 2;
 476             *line = dbg_heap_realloc(*line, alloc);
 477         }
 478         (*line)[len++] = ch;
 479     }
 480     while (ch != '\n');
 481     (*line)[len] = '\0';
 482
 483     return len;
 484 }
 485
 486 int input_read_line(const char* pfx, char* buf, int size)
 487 {
 488     char*       line = NULL;
 489     size_t      len = 0;
 490
 491     len = input_fetch_entire_line(pfx, &line);
 492     /* remove trailing \n */
 493     if (len > 0 && line[len - 1] == '\n') len--;
 494     len = min(size - 1, len);
 495     memcpy(buf, line, len);
 496     buf[len] = '\0';
 497     HeapFree(GetProcessHeap(), 0, line);
 498     return 1;
 499 }
 500
 501 /***********************************************************************
 502  *           parser_handle
 503  *
 504  * Debugger command line parser
 505  */
 506 void    parser_handle(HANDLE input)
 507 {
 508     BOOL                ret_ok;
 509     HANDLE              in_copy  = dbg_parser_input;
 510     HANDLE              out_copy = dbg_parser_output;
 511
 512 #ifdef YYDEBUG
 513     yydebug = 0;
 514 #endif
 515
 516     ret_ok = FALSE;
 517
 518     if (input != INVALID_HANDLE_VALUE)
 519     {
 520         dbg_parser_output = INVALID_HANDLE_VALUE;
 521         dbg_parser_input  = input;
 522     }
 523     else
 524     {
 525         dbg_parser_output = GetStdHandle(STD_OUTPUT_HANDLE);
 526         dbg_parser_input  = GetStdHandle(STD_INPUT_HANDLE);
 527     }
 528
 529     do
 530     {
 531        __TRY
 532        {
 533           ret_ok = TRUE;
 534           yyparse();
 535        }
 536        __EXCEPT(wine_dbg_cmd)
 537        {
 538           ret_ok = FALSE;
 539        }
 540        __ENDTRY;
 541        lexeme_flush();
 542     } while (!ret_ok);
 543
 544     dbg_parser_input  = in_copy;
 545     dbg_parser_output = out_copy;
 546 }
 547
 548 void parser(const char* filename)
 549 {
 550     HANDLE h = CreateFile(filename, GENERIC_READ, FILE_SHARE_READ, NULL, OPEN_EXISTING, 0L, 0);
 551     if (h != INVALID_HANDLE_VALUE)
 552     {
 553         parser_handle(h);
 554         CloseHandle(h);
 555     }
 556 }
 557
 558 int yyerror(const char* s)
 559 {
 560     dbg_printf("%s\n", s);
 561     return 0;
 562 }
 563
 564 HANDLE parser_generate_command_file(const char* pmt, ...)
 565 {
 566     HANDLE      hFile;
 567     char        path[MAX_PATH], file[MAX_PATH];
 568     DWORD       w;
 569     const char* p;
 570
 571     GetTempPath(sizeof(path), path);
 572     GetTempFileName(path, "WD", 0, file);
 573     hFile = CreateFileA(file, GENERIC_READ|GENERIC_WRITE|DELETE, FILE_SHARE_DELETE,
 574                         NULL, CREATE_ALWAYS, FILE_ATTRIBUTE_NORMAL | FILE_FLAG_DELETE_ON_CLOSE, 0);
 575     if (hFile != INVALID_HANDLE_VALUE)
 576     {
 577         va_list ap;
 578
 579         WriteFile(hFile, pmt, strlen(pmt), &w, 0);
 580         va_start(ap, pmt);
 581         while ((p = va_arg(ap, const char*)) != NULL)
 582         {
 583             WriteFile(hFile, "\n", 1, &w, 0);
 584             WriteFile(hFile, p, strlen(p), &w, 0);
 585         }
 586         va_end(ap);
 587         WriteFile(hFile, "\nquit\n", 6, &w, 0);
 588         SetFilePointer(hFile, 0, NULL, FILE_BEGIN);
 589     }
 590     return hFile;
 591 }