git.oblomov.eu Git - wine/blob - tools/make_requests

   1 #! /usr/bin/perl -w
   2 #
   3 # Build the server/trace.c and server/request.h files
   4 # from the contents of include/wine/server.h.
   5 #
   6 # Copyright (C) 1998 Alexandre Julliard
   7 #
   8 # This library is free software; you can redistribute it and/or
   9 # modify it under the terms of the GNU Lesser General Public
  10 # License as published by the Free Software Foundation; either
  11 # version 2.1 of the License, or (at your option) any later version.
  12 #
  13 # This library is distributed in the hope that it will be useful,
  14 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  15 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  16 # Lesser General Public License for more details.
  17 #
  18 # You should have received a copy of the GNU Lesser General Public
  19 # License along with this library; if not, write to the Free Software
  20 # Foundation, Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301, USA
  21 #
  22 use strict;
  23
  24 my %formats =
  25 (
  26     "int"           => "%d",
  27     "short int"     => "%d",
  28     "char"          => "%c",
  29     "unsigned char" => "%02x",
  30     "unsigned short"=> "%04x",
  31     "unsigned int"  => "%08x",
  32     "unsigned long" => "%lx",
  33     "void*"         => "%p",
  34     "time_t"        => "%ld (long)",
  35     "size_t"        => "%lu (unsigned long)",
  36     "data_size_t"   => "%u",
  37     "obj_handle_t"  => "%p",
  38     "atom_t"        => "%04x",
  39     "user_handle_t" => "%p",
  40     "process_id_t"  => "%04x",
  41     "thread_id_t"   => "%04x",
  42     "abs_time_t"    => "&dump_abs_time",
  43     "rectangle_t"   => "&dump_rectangle",
  44     "char_info_t"   => "&dump_char_info",
  45     "apc_call_t"    => "&dump_apc_call",
  46 );
  47
  48 my @requests = ();
  49 my %replies = ();
  50
  51 my @trace_lines = ();
  52
  53
  54
  55 ### Generate a dumping function
  56
  57 sub DO_DUMP_FUNC($$@)
  58 {
  59     my $name = shift;
  60     my $req = shift;
  61     push @trace_lines, "static void dump_${name}_$req( const struct ${name}_$req *req )\n{\n";
  62     while ($#_ >= 0)
  63     {
  64         my $type = shift;
  65         my $var = shift;
  66         if (defined($formats{$type}))
  67         {
  68             if ($formats{$type} =~ /^&(.*)/)
  69             {
  70                 my $func = $1;
  71                 push @trace_lines, "    fprintf( stderr, \" $var=\" );\n";
  72                 push @trace_lines, "    $func( &req->$var );\n";
  73                 push @trace_lines, "    fprintf( stderr, \",\" );\n" if ($#_ > 0);
  74             }
  75             elsif ($formats{$type} =~ /^(%.*)\s+\((.*)\)/)
  76             {
  77                 my ($format, $cast) = ($1, $2);
  78                 push @trace_lines, "    fprintf( stderr, \" $var=$format";
  79                 push @trace_lines, "," if ($#_ > 0);
  80                 push @trace_lines, "\", ($cast)req->$var );\n";
  81             }
  82             else
  83             {
  84                 push @trace_lines, "    fprintf( stderr, \" $var=$formats{$type}";
  85                 push @trace_lines, "," if ($#_ > 0);
  86                 push @trace_lines, "\", req->$var );\n";
  87             }
  88         }
  89         else  # must be some varargs format
  90         {
  91             my $func = $type;
  92             push @trace_lines, "    fprintf( stderr, \" $var=\" );\n";
  93             push @trace_lines, "    $func;\n";
  94             push @trace_lines, "    fputc( ',', stderr );\n" if ($#_ > 0);
  95         }
  96     }
  97     push @trace_lines, "}\n\n";
  98 }
  99
 100 ### Parse the request definitions
 101
 102 sub PARSE_REQUESTS()
 103 {
 104     # states: 0 = header 1 = declarations 2 = inside @REQ 3 = inside @REPLY
 105     my $state = 0;
 106     my $name = "";
 107     my @in_struct = ();
 108     my @out_struct = ();
 109
 110     open(PROTOCOL,"server/protocol.def") or die "Can't open server/protocol.def";
 111
 112     while (<PROTOCOL>)
 113     {
 114         my ($type, $var);
 115         # strip comments
 116         s!/\*.*\*/!!g;
 117         # strip white space at end of line
 118         s/\s+$//;
 119
 120         if (/^\@HEADER/)
 121         {
 122             die "Misplaced \@HEADER" unless $state == 0;
 123             $state++;
 124             next;
 125         }
 126
 127         # ignore everything while in state 0
 128         next if $state == 0;
 129
 130         if (/^\@REQ\(\s*(\w+)\s*\)/)
 131         {
 132             $name = $1;
 133             die "Misplaced \@REQ" unless $state == 1;
 134             # start a new request
 135             @in_struct = ();
 136             @out_struct = ();
 137             print SERVER_PROT "struct ${name}_request\n{\n";
 138             print SERVER_PROT "    struct request_header __header;\n";
 139             $state++;
 140             next;
 141         }
 142
 143         if (/^\@REPLY/)
 144         {
 145             die "Misplaced \@REPLY" unless $state == 2;
 146             print SERVER_PROT "};\n";
 147             print SERVER_PROT "struct ${name}_reply\n{\n";
 148             print SERVER_PROT "    struct reply_header __header;\n";
 149             $state++;
 150             next;
 151         }
 152
 153         if (/^\@END/)
 154         {
 155             die "Misplaced \@END" unless ($state == 2 || $state == 3);
 156             print SERVER_PROT "};\n";
 157
 158             if ($state == 2)  # build dummy reply struct
 159             {
 160                 print SERVER_PROT "struct ${name}_reply\n{\n";
 161                 print SERVER_PROT "    struct reply_header __header;\n";
 162                 print SERVER_PROT "};\n";
 163             }
 164
 165             # got a complete request
 166             push @requests, $name;
 167             DO_DUMP_FUNC( $name, "request", @in_struct);
 168             if ($#out_struct >= 0)
 169             {
 170                 $replies{$name} = 1;
 171                 DO_DUMP_FUNC( $name, "reply", @out_struct);
 172             }
 173             $state = 1;
 174             next;
 175         }
 176
 177         if ($state != 1)
 178         {
 179             # skip empty lines (but keep them in output file)
 180             if (/^$/)
 181             {
 182                 print SERVER_PROT "\n";
 183                 next;
 184             }
 185
 186             if (/^\s*VARARG\((\w+),(\w+),(\w+)\)/)
 187             {
 188                 $var = $1;
 189                 $type = "dump_varargs_" . $2 . "( min(cur_size,req->" . $3 . ") )";
 190                 s!(VARARG\(.*\)\s*;)!/* $1 */!;
 191             }
 192             elsif (/^\s*VARARG\((\w+),(\w+)\)/)
 193             {
 194                 $var = $1;
 195                 $type = "dump_varargs_" . $2 . "( cur_size )";
 196                 s!(VARARG\(.*\)\s*;)!/* $1 */!;
 197             }
 198             elsif (/^\s*(\w+\**(\s+\w+\**)*)\s+(\w+);/)
 199             {
 200                 $type = $1;
 201                 $var = $3;
 202                 die "Unrecognized type $type" unless defined($formats{$type});
 203             }
 204             else
 205             {
 206                 die "Unrecognized syntax $_";
 207             }
 208             if ($state == 2) { push @in_struct, $type, $var; }
 209             if ($state == 3) { push @out_struct, $type, $var; }
 210         }
 211
 212         # Pass it through into the output file
 213         print SERVER_PROT $_ . "\n";
 214     }
 215     close PROTOCOL;
 216 }
 217
 218 ### Retrieve the server protocol version from the existing server_protocol.h file
 219
 220 sub GET_PROTOCOL_VERSION()
 221 {
 222     my $protocol = 0;
 223     open SERVER_PROT, "include/wine/server_protocol.h" or return 0;
 224     while (<SERVER_PROT>)
 225     {
 226         if (/^\#define SERVER_PROTOCOL_VERSION (\d+)/) { $protocol = $1; last; }
 227     }
 228     close SERVER_PROT;
 229     return $protocol;
 230 }
 231
 232 ### Retrieve the list of status and errors used in the server
 233
 234 sub GET_ERROR_NAMES()
 235 {
 236     my %errors = ();
 237     foreach my $f (glob "server/*.c")
 238     {
 239         open FILE, $f or die "Can't open $f";
 240         while (<FILE>)
 241         {
 242             if (/set_error\s*\(\s*STATUS_(\w+)\s*\)/)
 243             {
 244                 $errors{$1} = "STATUS_$1" unless $1 eq "SUCCESS";
 245             }
 246             elsif (/async_terminate_\w+\s*\(.*,\s*STATUS_(\w+)\s*\)/)
 247             {
 248                 $errors{$1} = "STATUS_$1" unless $1 eq "SUCCESS";
 249             }
 250             elsif (/set_win32_error\s*\(\s*(\w+)\s*\)/)
 251             {
 252                 $errors{$1} = "0xc0010000 | $1";
 253             }
 254         }
 255         close FILE;
 256     }
 257     return %errors;
 258 }
 259
 260 ### Replace the contents of a file between ### make_requests ### marks
 261
 262 sub REPLACE_IN_FILE($@)
 263 {
 264     my $name = shift;
 265     my @data = @_;
 266     my @lines = ();
 267     open(FILE,$name) or die "Can't open $name";
 268     while (<FILE>)
 269     {
 270         push @lines, $_;
 271         last if /\#\#\# make_requests begin \#\#\#/;
 272     }
 273     push @lines, "\n", @data;
 274     while (<FILE>)
 275     {
 276         if (/\#\#\# make_requests end \#\#\#/) { push @lines, "\n", $_; last; }
 277     }
 278     push @lines, <FILE>;
 279     open(FILE,">$name") or die "Can't modify $name";
 280     print FILE @lines;
 281     close(FILE);
 282 }
 283
 284 ### Main
 285
 286 # Get the server protocol version
 287 my $protocol = GET_PROTOCOL_VERSION();
 288
 289 my %errors = GET_ERROR_NAMES();
 290
 291 ### Create server_protocol.h and print header
 292
 293 open SERVER_PROT, ">include/wine/server_protocol.h" or die "Cannot create include/wine/server_protocol.h";
 294 print SERVER_PROT "/*\n * Wine server protocol definitions\n *\n";
 295 print SERVER_PROT " * This file is automatically generated; DO NO EDIT!\n";
 296 print SERVER_PROT " * Edit server/protocol.def instead and re-run tools/make_requests\n";
 297 print SERVER_PROT " */\n\n";
 298 print SERVER_PROT "#ifndef __WINE_WINE_SERVER_PROTOCOL_H\n";
 299 print SERVER_PROT "#define __WINE_WINE_SERVER_PROTOCOL_H\n";
 300
 301 ### Parse requests to find request/reply structure definitions
 302
 303 PARSE_REQUESTS();
 304
 305 ### Build the request list and structures
 306
 307 print SERVER_PROT "\n\nenum request\n{\n";
 308 foreach my $req (@requests) { print SERVER_PROT "    REQ_$req,\n"; }
 309 print SERVER_PROT "    REQ_NB_REQUESTS\n};\n\n";
 310
 311 print SERVER_PROT "union generic_request\n{\n";
 312 print SERVER_PROT "    struct request_max_size max_size;\n";
 313 print SERVER_PROT "    struct request_header request_header;\n";
 314 foreach my $req (@requests) { print SERVER_PROT "    struct ${req}_request ${req}_request;\n"; }
 315 print SERVER_PROT "};\n";
 316
 317 print SERVER_PROT "union generic_reply\n{\n";
 318 print SERVER_PROT "    struct request_max_size max_size;\n";
 319 print SERVER_PROT "    struct reply_header reply_header;\n";
 320 foreach my $req (@requests) { print SERVER_PROT "    struct ${req}_reply ${req}_reply;\n"; }
 321 print SERVER_PROT "};\n\n";
 322
 323 printf SERVER_PROT "#define SERVER_PROTOCOL_VERSION %d\n\n", $protocol + 1;
 324 print SERVER_PROT "#endif /* __WINE_WINE_SERVER_PROTOCOL_H */\n";
 325 close SERVER_PROT;
 326
 327 ### Output the dumping function tables
 328
 329 push @trace_lines, "static const dump_func req_dumpers[REQ_NB_REQUESTS] = {\n";
 330 foreach my $req (@requests)
 331 {
 332     push @trace_lines, "    (dump_func)dump_${req}_request,\n";
 333 }
 334 push @trace_lines, "};\n\n";
 335
 336 push @trace_lines, "static const dump_func reply_dumpers[REQ_NB_REQUESTS] = {\n";
 337 foreach my $req (@requests)
 338 {
 339     push @trace_lines, "    (dump_func)", $replies{$req} ? "dump_${req}_reply,\n" : "0,\n";
 340 }
 341 push @trace_lines, "};\n\n";
 342
 343 push @trace_lines, "static const char * const req_names[REQ_NB_REQUESTS] = {\n";
 344 foreach my $req (@requests)
 345 {
 346     push @trace_lines, "    \"$req\",\n";
 347 }
 348 push @trace_lines, "};\n\n";
 349
 350 push @trace_lines, "static const struct\n{\n";
 351 push @trace_lines, "    const char  *name;\n";
 352 push @trace_lines, "    unsigned int value;\n";
 353 push @trace_lines, "} status_names[] =\n{\n";
 354
 355 foreach my $err (sort keys %errors)
 356 {
 357     push @trace_lines, sprintf("    { %-30s %s },\n", "\"$err\",", $errors{$err});
 358 }
 359 push @trace_lines, "    { NULL, 0 }\n";
 360 push @trace_lines, "};\n";
 361
 362 REPLACE_IN_FILE( "server/trace.c", @trace_lines );
 363
 364 ### Output the request handlers list
 365
 366 my @request_lines = ();
 367
 368 foreach my $req (@requests) { push @request_lines, "DECL_HANDLER($req);\n"; }
 369 push @request_lines, "\n#ifdef WANT_REQUEST_HANDLERS\n\n";
 370 push @request_lines, "typedef void (*req_handler)( const void *req, void *reply );\n";
 371 push @request_lines, "static const req_handler req_handlers[REQ_NB_REQUESTS] =\n{\n";
 372 foreach my $req (@requests)
 373 {
 374     push @request_lines, "    (req_handler)req_$req,\n";
 375 }
 376 push @request_lines, "};\n#endif  /* WANT_REQUEST_HANDLERS */\n";
 377
 378 REPLACE_IN_FILE( "server/request.h", @request_lines );