git.oblomov.eu Git - wine/blob - tools/winapi_check/winapi_documentation.pm

   1 #
   2 # Copyright 1999, 2000, 2001 Patrik Stridvall
   3 #
   4 # This library is free software; you can redistribute it and/or
   5 # modify it under the terms of the GNU Lesser General Public
   6 # License as published by the Free Software Foundation; either
   7 # version 2.1 of the License, or (at your option) any later version.
   8 #
   9 # This library is distributed in the hope that it will be useful,
  10 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  11 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU
  12 # Lesser General Public License for more details.
  13 #
  14 # You should have received a copy of the GNU Lesser General Public
  15 # License along with this library; if not, write to the Free Software
  16 # Foundation, Inc., 59 Temple Place, Suite 330, Boston, MA  02111-1307  USA
  17 #
  18
  19 package winapi_documentation;
  20
  21 use strict;
  22
  23 use config qw($current_dir $wine_dir);
  24 use modules qw($modules);
  25 use nativeapi qw($nativeapi);
  26 use options qw($options);
  27 use output qw($output);
  28 use winapi qw($win16api $win32api @winapis);
  29
  30 my %comment_width;
  31 my %comment_indent;
  32 my %comment_spacing;
  33
  34 sub check_documentation {
  35     local $_;
  36
  37     my $function = shift;
  38
  39     my $file = $function->file;
  40     my $external_name16 = $function->external_name16;
  41     my $external_name32 = $function->external_name32;
  42     my $internal_name = $function->internal_name;
  43     my $module16 = $function->module16;
  44     my $module32 = $function->module32;
  45     my $ordinal16 = $function->ordinal16;
  46     my $ordinal32 = $function->ordinal32;
  47     my $documentation = $function->documentation;
  48     my $documentation_line = $function->documentation_line;
  49
  50     my $documentation_error = 0;
  51     my $documentation_warning = 0;
  52     if($options->documentation_name ||
  53        $options->documentation_ordinal ||
  54        $options->documentation_pedantic)
  55     {
  56         my @winapis = ($win16api, $win32api);
  57         my @modules = ($module16, $module32);
  58         my @external_names = ($external_name16, $external_name32);
  59         my @ordinals = ($ordinal16, $ordinal32);
  60         while(
  61               defined(my $winapi = shift @winapis) &&
  62               defined(my $external_name = shift @external_names) &&
  63               defined(my $module = shift @modules) &&
  64               defined(my $ordinal = shift @ordinals))
  65         {
  66             if($winapi->is_function_stub_in_module($module, $internal_name)) { next; }
  67
  68             my @external_name = split(/\s*\&\s*/, $external_name);
  69             my @modules = split(/\s*\&\s*/, $module);
  70             my @ordinals = split(/\s*\&\s*/, $ordinal);
  71
  72             my $pedantic_failed = 0;
  73             while(defined(my $external_name = shift @external_name) &&
  74                   defined(my $module = shift @modules) &&
  75                   defined(my $ordinal = shift @ordinals))
  76             {
  77                 my $found_name = 0;
  78                 my $found_ordinal = 0;
  79                 foreach (split(/\n/, $documentation)) {
  80                     if(/^(\s*)\*(\s*)(\@|\S+)(\s*)([\(\[])(\w+)\.(\@|\d+)([\)\]])/) {
  81                         my $external_name2 = $3;
  82                         my $module2 = $6;
  83                         my $ordinal2 = $7;
  84
  85                         if(length($1) != 1 || length($2) < 1 ||
  86                            length($4) < 1 || $5 ne "(" || $8 ne ")")
  87                         {
  88                             $pedantic_failed = 1;
  89                         }
  90
  91                         if($external_name eq $external_name2) {
  92                             $found_name = 1;
  93                             if("\U$module\E" eq $module2 &&
  94                                $ordinal eq $ordinal2)
  95                             {
  96                                 $found_ordinal = 1;
  97                             }
  98                         }
  99                     }
 100                 }
 101                 if(($options->documentation_name && !$found_name) ||
 102                    ($options->documentation_ordinal && !$found_ordinal))
 103                 {
 104                     $documentation_error = 1;
 105                     $output->write("documentation: expected $external_name (\U$module\E.$ordinal): \\\n$documentation\n");
 106                 }
 107
 108             }
 109             if($options->documentation_pedantic && $pedantic_failed) {
 110                 $documentation_warning = 1;
 111                 $output->write("documentation: pedantic failed: \\\n$documentation\n");
 112             }
 113         }
 114     }
 115
 116     if(!$documentation_error && $options->documentation_wrong) {
 117         foreach (split(/\n/, $documentation)) {
 118             if(/^\s*\*\s*(\S+)\s*[\(\[]\s*(\w+)\s*\.\s*([^\s\)\]]*)\s*[\)\]].*?$/) {
 119                 my $external_name = $1;
 120                 my $module = $2;
 121                 my $ordinal = $3;
 122
 123                 my $found = 0;
 124                 foreach my $entry2 (winapi::get_all_module_internal_ordinal($internal_name)) {
 125                     (my $external_name2, my $module2, my $ordinal2) = @$entry2;
 126
 127                     if($external_name eq $external_name2 &&
 128                        lc($module) eq $module2 &&
 129                        $ordinal eq $ordinal2 &&
 130                        ($external_name2 eq "@" ||
 131                         ($win16api->is_module($module2) && !$win16api->is_function_stub_in_module($module2, $external_name2)) ||
 132                         ($win32api->is_module($module2) && !$win32api->is_function_stub_in_module($module2, $external_name2))) &&
 133                         $modules->is_allowed_module_in_file($module2, "$current_dir/$file"))
 134                     {
 135                         $found = 1;
 136                     }
 137                 }
 138                 if(!$found) {
 139                     $output->write("documentation: $external_name (\U$module\E.$ordinal) wrong\n");
 140                 }
 141             }
 142         }
 143     }
 144
 145     if($options->documentation_comment_indent) {
 146         foreach (split(/\n/, $documentation)) {
 147             if(/^\s*\*(\s*)\S+(\s*)[\(\[]\s*\w+\s*\.\s*[^\s\)\]]*\s*[\)\]].*?$/) {
 148                 my $indent = $1;
 149                 my $spacing = $2;
 150
 151                 $indent =~ s/\t/        /g;
 152                 $indent = length($indent);
 153
 154                 $spacing =~ s/\t/        /g;
 155                 $spacing = length($spacing);
 156
 157                 $comment_indent{$indent}++;
 158                 if($indent >= 20) {
 159                     $output->write("documentation: comment indent is $indent\n");
 160                 }
 161                 $comment_spacing{$spacing}++;
 162             }
 163         }
 164     }
 165
 166     if($options->documentation_comment_width) {
 167         if($documentation =~ /(^\/\*\*+)/) {
 168             my $width = length($1);
 169
 170             $comment_width{$width}++;
 171             if($width <= 65 || $width >= 81) {
 172                 $output->write("comment is $width columns wide\n");
 173             }
 174         }
 175     }
 176
 177     if($options->documentation_arguments) {
 178         my $refargument_documentations = $function->argument_documentations;
 179
 180         if(defined($refargument_documentations)) {
 181             my $n = 0;
 182             for my $argument_documentation (@$refargument_documentations) {
 183                 $n++;
 184                 if($argument_documentation ne "") {
 185                     if($argument_documentation !~ /^\/\*\s+\[(?:in|out|in\/out|\?\?\?)\].*?\*\/$/s) {
 186                         $output->write("argument $n documentation: \\\n$argument_documentation\n");
 187                     }
 188                 }
 189             }
 190         }
 191     }
 192 }
 193
 194 sub report_documentation {
 195     if($options->documentation_comment_indent) {
 196         foreach my $indent (sort(keys(%comment_indent))) {
 197             my $count = $comment_indent{$indent};
 198             $output->write("*.c: $count functions have comment that is indented $indent\n");
 199         }
 200     }
 201
 202     if($options->documentation_comment_width) {
 203         foreach my $width (sort(keys(%comment_width))) {
 204             my $count = $comment_width{$width};
 205             $output->write("*.c: $count functions have comments of width $width\n");
 206         }
 207     }
 208 }
 209
 210 1;