git.oblomov.eu Git - wine/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Original author: Michael Patra
   3 dnl See ChangeLog file for detailed change history.
   4
   5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
   6
   7 AC_PREREQ(2.53b)
   8 AC_INIT([Wine],WINE_VERSION,[wine-devel@winehq.org])
   9 AC_CONFIG_SRCDIR(server/atom.c)
  10 AC_CONFIG_HEADERS(include/config.h)
  11 AC_CONFIG_AUX_DIR(tools)
  12
  13 dnl **** Command-line arguments ****
  14
  15 AC_ARG_ENABLE(win16, AC_HELP_STRING([--disable-win16],[do not include Win16 support]))
  16 AC_ARG_ENABLE(win64, AC_HELP_STRING([--enable-win64], [build a Win64 emulator on AMD64 (won't run Win32 binaries)]))
  17
  18 AC_ARG_WITH(opengl,    AC_HELP_STRING([--without-opengl],[do not use OpenGL]))
  19 AC_ARG_WITH(wine-tools,AC_HELP_STRING([--with-wine-tools=<dir>],[use Wine tools from directory <dir>]))
  20
  21 AC_CANONICAL_HOST
  22 case $host in
  23   x86_64*linux*)
  24     if test "x$enable_win64" != "xyes"
  25     then
  26       test -n "$CC" || CC="gcc -m32"
  27       test -n "$LD" || LD="ld -m elf_i386"
  28       test -n "$AS" || AS="as --32"
  29       host_cpu="i386"
  30     fi
  31     ;;
  32 esac
  33
  34 dnl enable_win16 defaults to yes on x86, to no on other CPUs
  35 case $host_cpu in
  36   *i[[3456789]]86*)
  37     if test "x$enable_win16" != "xno"
  38     then
  39       enable_win16="yes"
  40     fi
  41     ;;
  42 esac
  43
  44 AC_SUBST(WIN16_FILES,"\$(WIN16_FILES)")
  45 AC_SUBST(WIN16_INSTALL,"\$(WIN16_INSTALL)")
  46 if test "x$enable_win16" != "xyes"
  47 then
  48   WIN16_FILES=""
  49   WIN16_INSTALL=""
  50 fi
  51
  52 dnl check for out of tree build with unclean source tree
  53 case "$srcdir" in
  54  .) ;;
  55  *) if test -f "$srcdir/Makefile" -o -f "$srcdir/include/config.h"; then
  56       AC_MSG_ERROR([you are building out of the source tree, but the source tree contains object files.
  57 You need to run 'make distclean' in the source tree first.])
  58     fi ;;
  59 esac
  60
  61 dnl **** Check for some programs ****
  62
  63 AC_PROG_MAKE_SET
  64 AC_PROG_CC
  65 AC_PROG_CXX
  66 dnl We can't use AC_PROG_CPP for winegcc, it uses by default $(CC) -E
  67 AC_CHECK_TOOL(CPPBIN,cpp,cpp)
  68
  69 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
  70   [if test -z "$with_wine_tools"; then
  71      if test "$cross_compiling" = "yes"; then
  72        AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
  73      else
  74        wine_cv_toolsdir="\$(TOPOBJDIR)"
  75      fi
  76    elif test -d "$with_wine_tools/tools/winebuild"; then
  77      case $with_wine_tools in
  78        /*) wine_cv_toolsdir="$with_wine_tools" ;;
  79        *)  wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
  80      esac
  81    else
  82      AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
  83    fi])
  84 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
  85
  86 AC_PATH_XTRA
  87
  88 dnl Check for flex
  89 AC_CHECK_PROGS(FLEX,flex,none)
  90 if test "$FLEX" = "none"
  91 then
  92   AC_MSG_ERROR([no suitable flex found. Please install the 'flex' package.])
  93 fi
  94
  95 dnl Check for bison
  96 AC_CHECK_PROGS(BISON,bison,none)
  97 if test "$BISON" = "none"
  98 then
  99   AC_MSG_ERROR([no suitable bison found. Please install the 'bison' package.])
 100 fi
 101
 102 AC_CHECK_TOOLS(AS,[gas as],as)
 103 AC_CHECK_TOOL(LD,ld,ld)
 104 AC_CHECK_TOOL(AR,ar,ar)
 105 AC_PROG_RANLIB
 106 AC_CHECK_TOOL(STRIP,strip,strip)
 107 AC_CHECK_TOOL(WINDRES,windres,false)
 108 AC_PROG_LN_S
 109 WINE_PROG_LN
 110 AC_PROG_EGREP
 111 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
 112 AC_PROG_INSTALL
 113 dnl Prepend src dir to install path dir if it's a relative path
 114 case "$INSTALL" in
 115   [[\\/$]]* | ?:[[\\/]]* ) ;;
 116   *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
 117 esac
 118
 119 dnl Check for lint
 120 AC_CHECK_PROGS(LINT, lclint lint)
 121 if test "$LINT" = "lint"
 122 then
 123   LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
 124   dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
 125 fi
 126 AC_SUBST(LINT)
 127 AC_SUBST(LINTFLAGS)
 128
 129 dnl Check for various programs
 130 AC_CHECK_PROGS(FONTFORGE, fontforge, false)
 131 AC_CHECK_PROGS(PKG_CONFIG, pkg-config, false)
 132
 133 case $host_cpu in
 134   *i[[3456789]]86*)
 135     AC_PATH_PROG(PRELINK, prelink, false, [/sbin /usr/sbin $PATH])
 136     ;;
 137 esac
 138
 139 dnl **** Check for some libraries ****
 140
 141 dnl Check for -li386 for NetBSD and OpenBSD
 142 AC_CHECK_LIB(i386,i386_set_ldt)
 143 dnl Check for -lossaudio for NetBSD
 144 AC_CHECK_LIB(ossaudio,_oss_ioctl)
 145 dnl Check for -lxpg4 for FreeBSD
 146 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
 147 dnl Check for -lpthread
 148 AC_CHECK_LIB(pthread,pthread_create,AC_SUBST(LIBPTHREAD,"-lpthread"))
 149
 150 AC_SUBST(XLIB,"")
 151 AC_SUBST(XFILES,"")
 152 AC_SUBST(OPENGLFILES,"")
 153 AC_SUBST(GLU32FILES,"")
 154 AC_SUBST(OPENGL_LIBS,"")
 155 AC_SUBST(QUARTZFILES,"")
 156
 157 dnl **** Check for header files ****
 158
 159 AC_CHECK_HEADERS(\
 160         AudioUnit/AudioUnit.h \
 161         Carbon/Carbon.h \
 162         CoreAudio/CoreAudio.h \
 163         DiskArbitration/DiskArbitration.h \
 164         IOKit/IOKitLib.h \
 165         alsa/asoundlib.h \
 166         arpa/inet.h \
 167         arpa/nameser.h \
 168         asm/types.h \
 169         capi20.h \
 170         cups/cups.h \
 171         curses.h \
 172         direct.h \
 173         dlfcn.h \
 174         elf.h \
 175         float.h \
 176         fontconfig/fontconfig.h \
 177         getopt.h \
 178         ieeefp.h \
 179         io.h \
 180         jack/jack.h \
 181         jpeglib.h \
 182         lber.h \
 183         lcms.h \
 184         lcms/lcms.h \
 185         ldap.h \
 186         libaudioio.h \
 187         link.h \
 188         linux/cdrom.h \
 189         linux/compiler.h \
 190         linux/hdreg.h \
 191         linux/input.h \
 192         linux/ioctl.h \
 193         linux/joystick.h \
 194         linux/major.h \
 195         linux/param.h \
 196         linux/serial.h \
 197         linux/ucdrom.h \
 198         mach/mach.h \
 199         mach/machine.h \
 200         machine/cpu.h \
 201         machine/limits.h \
 202         machine/soundcard.h \
 203         mntent.h \
 204         ncurses.h \
 205         netdb.h \
 206         netinet/in.h \
 207         netinet/in_systm.h \
 208         netinet/tcp.h \
 209         netinet/tcp_fsm.h \
 210         openssl/err.h \
 211         openssl/ssl.h \
 212         poll.h \
 213         process.h \
 214         pthread.h \
 215         pwd.h \
 216         regex.h \
 217         sched.h \
 218         scsi/scsi.h \
 219         scsi/scsi_ioctl.h \
 220         scsi/sg.h \
 221         soundcard.h \
 222         stdint.h \
 223         strings.h \
 224         sys/asoundlib.h \
 225         sys/cdio.h \
 226         sys/elf32.h \
 227         sys/epoll.h \
 228         sys/errno.h \
 229         sys/event.h \
 230         sys/exec_elf.h \
 231         sys/filio.h \
 232         sys/ioctl.h \
 233         sys/ipc.h \
 234         sys/limits.h \
 235         sys/link.h \
 236         sys/lwp.h \
 237         sys/mman.h \
 238         sys/modem.h \
 239         sys/msg.h \
 240         sys/mtio.h \
 241         sys/param.h \
 242         sys/poll.h \
 243         sys/prctl.h \
 244         sys/ptrace.h \
 245         sys/reg.h \
 246         sys/resource.h \
 247         sys/scsiio.h \
 248         sys/shm.h \
 249         sys/signal.h \
 250         sys/socket.h \
 251         sys/sockio.h \
 252         sys/soundcard.h \
 253         sys/statvfs.h \
 254         sys/strtio.h \
 255         sys/syscall.h \
 256         sys/sysctl.h \
 257         sys/time.h \
 258         sys/times.h \
 259         sys/uio.h \
 260         sys/un.h \
 261         sys/vm86.h \
 262         sys/wait.h \
 263         syscall.h \
 264         termios.h \
 265         unicode/ubidi.h \
 266         unistd.h \
 267         utime.h \
 268         valgrind/memcheck.h
 269 )
 270 AC_HEADER_STAT()
 271
 272 dnl **** Checks for headers that depend on other ones ****
 273
 274 AC_CHECK_HEADERS([sys/mount.h sys/statfs.h sys/user.h sys/vfs.h],,,
 275     [#include <sys/types.h>
 276      #if HAVE_SYS_PARAM_H
 277      # include <sys/param.h>
 278      #endif])
 279
 280 AC_CHECK_HEADERS([net/if.h net/if_arp.h net/if_dl.h net/if_types.h net/route.h netipx/ipx.h],,,
 281     [#include <sys/types.h>
 282      #if HAVE_SYS_SOCKET_H
 283      # include <sys/socket.h>
 284      #endif])
 285
 286 AC_CHECK_HEADERS([linux/ipx.h],,,
 287     [#include <sys/types.h>
 288      #ifdef HAVE_ASM_TYPES_H
 289      # include <asm/types.h>
 290      #endif
 291      #if HAVE_SYS_SOCKET_H
 292      # include <sys/socket.h>
 293      #endif])
 294
 295 AC_CHECK_HEADERS([resolv.h],,,
 296     [#include <sys/types.h>
 297      #if HAVE_SYS_SOCKET_H
 298      # include <sys/socket.h>
 299      #endif
 300      #if HAVE_NETINET_IN_H
 301      # include <netinet/in.h>
 302      #endif
 303      #if HAVE_ARPA_NAMESER_H
 304      # include <arpa/nameser.h>
 305      #endif])
 306
 307 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
 308
 309 AC_CHECK_HEADERS([pthread_np.h],,,
 310 [#ifdef HAVE_PTHREAD_H
 311 #include <pthread.h>
 312 #endif])
 313
 314 AC_CHECK_HEADERS([linux/videodev.h],,,
 315 [#ifdef HAVE_SYS_TIME_H
 316 #include <sys/time.h>
 317 #endif
 318 #include <sys/types.h>
 319 #ifdef HAVE_ASM_TYPES_H
 320 #include <asm/types.h>
 321 #endif])
 322
 323 dnl Check for broken kernel header that doesn't define __user
 324 AC_CHECK_HEADERS([linux/capi.h],,,[#define __user])
 325
 326 dnl **** Check for X11 ****
 327
 328 if test "$have_x" = "yes"
 329 then
 330     XLIB="-lXext -lX11"
 331     ac_save_CPPFLAGS="$CPPFLAGS"
 332     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 333
 334     dnl *** All of the following tests require X11/Xlib.h
 335     AC_CHECK_HEADERS([X11/Xlib.h \
 336                       X11/XKBlib.h \
 337                       X11/Xutil.h \
 338                       X11/Xcursor/Xcursor.h \
 339                       X11/extensions/shape.h \
 340                       X11/extensions/XInput.h \
 341                       X11/extensions/XShm.h \
 342                       X11/extensions/Xinerama.h \
 343                       X11/extensions/Xrandr.h \
 344                       X11/extensions/Xrender.h \
 345                       X11/extensions/xf86vmode.h],,,
 346 [#ifdef HAVE_X11_XLIB_H
 347 # include <X11/Xlib.h>
 348 #endif
 349 #ifdef HAVE_X11_XUTIL_H
 350 # include <X11/Xutil.h>
 351 #endif])
 352
 353         dnl *** Check for X keyboard extension
 354         if test "$ac_cv_header_X11_XKBlib_h" = "yes"
 355         then
 356               AC_CHECK_LIB(X11, XkbQueryExtension,
 357               AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
 358               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 359         fi
 360
 361         dnl *** Check for X Shm extension
 362         if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
 363         then
 364               AC_CHECK_LIB(Xext, XShmQueryExtension,
 365               AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
 366               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 367         fi
 368
 369         dnl *** Check for X shape extension
 370         if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
 371         then
 372               AC_CHECK_LIB(Xext,XShapeQueryExtension,
 373               AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
 374               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 375         fi
 376
 377         dnl *** Check for XFree86 VMODE extension
 378         if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
 379         then
 380                 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
 381                   [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
 382                      X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
 383                   ],,
 384                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 385         fi
 386
 387         dnl *** Check for X RandR extension
 388         if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes"
 389         then
 390                 AC_TRY_COMPILE([#include <X11/Xlib.h>
 391 #include <X11/extensions/Xrandr.h>],[static typeof(XRRSetScreenConfigAndRate) * func;],
 392                   [AC_DEFINE(HAVE_LIBXRANDR, 1, [Define if you have the Xrandr library])])
 393         fi
 394
 395         dnl *** Check for Transform functions in Xrender
 396         if test "$ac_cv_header_X11_extensions_Xrender_h" = "yes"
 397         then
 398               AC_CHECK_LIB(Xrender, XRenderSetPictureTransform,
 399                 [AC_DEFINE(HAVE_XRENDERSETPICTURETRANSFORM, 1,
 400                  [Define if Xrender has the XRenderSetPictureTransform function])],,
 401                 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 402         fi
 403
 404         dnl *** Check for Xinerama extension
 405         if test "$ac_cv_header_X11_extensions_Xinerama_h" = "yes"
 406         then
 407                 AC_TRY_COMPILE([#include <X11/Xlib.h>
 408 #include <X11/extensions/Xinerama.h>],[static typeof(XineramaQueryScreens) * func;],
 409                   [AC_DEFINE(HAVE_LIBXINERAMA, 1, [Define if you have the Xinerama library])])
 410         fi
 411
 412     dnl *** End of X11/Xlib.h check
 413
 414     dnl Check for the presence of OpenGL
 415     if test "x$with_opengl" != "xno"
 416     then
 417         AC_CHECK_HEADERS(GL/gl.h GL/glx.h GL/glext.h GL/glu.h,,,
 418 [#ifdef HAVE_GL_GLX_H
 419 # include <GL/glx.h>
 420 #endif])
 421         if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
 422         then
 423             dnl Check for some problems due to old Mesa versions
 424             AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_header_version_OK,
 425               AC_TRY_COMPILE(
 426                 [#include <GL/gl.h>],
 427                 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
 428                 [wine_cv_opengl_header_version_OK="yes"],
 429                 [wine_cv_opengl_header_version_OK="no"]
 430               )
 431             )
 432
 433             if test "$wine_cv_opengl_header_version_OK" = "yes"
 434             then
 435                 dnl Check for the presence of the library
 436                 AC_CHECK_LIB(GL,glXCreateContext,
 437                              [OPENGL_LIBS="-lGL"
 438                              OPENGLFILES='$(OPENGLFILES)'
 439                              AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])]
 440                              ,,
 441                              $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 442
 443                 dnl Check for GLU32 library.
 444                 AC_CHECK_LIB(GLU,gluLookAt,
 445                              [OPENGL_LIBS="$OPENGL_LIBS -lGLU"
 446                              GLU32FILES='$(GLU32FILES)']
 447                              ,,
 448                              $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
 449                 )
 450              fi
 451          else
 452              wine_cv_opengl_headers_found="no"
 453          fi
 454     fi
 455     dnl **** Check for NAS ****
 456     AC_SUBST(NASLIBS,"")
 457     AC_CHECK_HEADERS(audio/audiolib.h,
 458          [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
 459           AC_CHECK_LIB(audio,AuCreateFlow,
 460                        [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
 461                         AC_CHECK_LIB(Xau,XauGetBestAuthByAddr,
 462                           [NASLIBS="-lXau -laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],
 463                           [NASLIBS="-laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],
 464                           [$X_LIBS])
 465                        ],,
 466                        [-lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
 467
 468     CPPFLAGS="$ac_save_CPPFLAGS"
 469     XFILES='$(XFILES)'
 470 else
 471     XLIB=""
 472     X_CFLAGS=""
 473     X_LIBS=""
 474 fi
 475
 476 dnl **** Check for libxml2 ****
 477
 478 AC_SUBST(XML2LIBS,"")
 479 AC_SUBST(XML2INCL,"")
 480 AC_SUBST(XSLTLIBS,"")
 481 AC_SUBST(XSLTINCL,"")
 482 if test "$PKG_CONFIG" != "false"
 483 then
 484     ac_save_CPPFLAGS="$CPPFLAGS"
 485     ac_xml_libs="`$PKG_CONFIG --libs libxml-2.0 2>/dev/null`"
 486     ac_xml_cflags="`$PKG_CONFIG --cflags libxml-2.0 2>/dev/null`"
 487     CPPFLAGS="$CPPFLAGS $ac_xml_cflags"
 488     AC_CHECK_HEADERS(libxml/parser.h,
 489         [AC_CHECK_LIB(xml2, xmlParseMemory,
 490             [AC_DEFINE(HAVE_LIBXML2, 1, [Define if you have the libxml2 library])
 491              XML2LIBS="$ac_xml_libs"
 492              XML2INCL="$ac_xml_cflags"],,$ac_xml_libs)
 493          AC_CHECK_LIB(xml2, xmlReadMemory,
 494             [AC_DEFINE(HAVE_XMLREADMEMORY,1,[Define if libxml2 has the xmlReadMemory function])],,$ac_xml_libs)
 495          AC_CHECK_LIB(xml2, xmlNewDocPI,
 496             [AC_DEFINE(HAVE_XMLNEWDOCPI,1,[Define if libxml2 has the xmlNewDocPI function])],,$ac_xml_libs)
 497         ])
 498     CPPFLAGS="$ac_save_CPPFLAGS"
 499     ac_xslt_libs="`$PKG_CONFIG --libs libxslt 2>/dev/null`"
 500     ac_xslt_cflags="`$PKG_CONFIG --cflags libxslt 2>/dev/null`"
 501     CPPFLAGS="$CPPFLAGS $ac_xslt_cflags"
 502     AC_CHECK_HEADERS([libxslt/pattern.h libxslt/transform.h],
 503         [AC_CHECK_LIB(xslt, xsltCompilePattern,
 504             [AC_DEFINE(HAVE_LIBXSLT, 1, [Define if you have the libxslt library])
 505              XSLTLIBS="$ac_xslt_libs"
 506              XSLTINCL="$ac_xslt_cflags"],,$ac_xslt_libs)
 507         ],,
 508 [#ifdef HAVE_LIBXSLT_PATTERN_H
 509 # include <libxslt/pattern.h>
 510 #endif])
 511     CPPFLAGS="$ac_save_CPPFLAGS"
 512 fi
 513
 514 dnl **** Check for libhal ****
 515 AC_SUBST(HALINCL,"")
 516 if test "$PKG_CONFIG" != "false"
 517 then
 518     ac_save_CPPFLAGS="$CPPFLAGS"
 519     ac_hal_libs="`$PKG_CONFIG --libs hal 2>/dev/null`"
 520     ac_hal_cflags="`$PKG_CONFIG --cflags hal 2>/dev/null`"
 521     CPPFLAGS="$CPPFLAGS $ac_hal_cflags"
 522     AC_CHECK_HEADERS([dbus/dbus.h hal/libhal.h])
 523     if test "$ac_cv_header_dbus_dbus_h" = "yes" -a "$ac_cv_header_hal_libhal_h" = "yes"
 524     then
 525         AC_CHECK_LIB(hal, libhal_ctx_new,
 526           [AC_CHECK_LIB(dbus-1, dbus_connection_close,
 527             [AC_DEFINE(HAVE_LIBHAL, 1, [Define if you have the hal library])
 528              HALINCL="$ac_hal_cflags"],,$ac_hal_libs)])
 529     fi
 530     CPPFLAGS="$ac_save_CPPFLAGS"
 531 fi
 532
 533 dnl **** Check which curses lib to use ***
 534 CURSESLIBS=""
 535 if test "$ac_cv_header_ncurses_h" = "yes"
 536 then
 537     AC_CHECK_LIB(ncurses,waddch,[CURSESLIBS="-lncurses"])
 538 elif test "$ac_cv_header_curses_h" = "yes"
 539 then
 540     AC_CHECK_LIB(curses,waddch,[CURSESLIBS="-lcurses"])
 541 fi
 542 ac_save_LIBS="$LIBS"
 543 LIBS="$LIBS $CURSESLIBS"
 544 AC_CHECK_FUNCS(mousemask)
 545 LIBS="$ac_save_LIBS"
 546
 547 dnl **** Check for SANE ****
 548 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
 549 AC_SUBST(SANEINCL,"")
 550 if test "$sane_devel" != "no"
 551 then
 552     SANEINCL="`$sane_devel --cflags`"
 553     ac_save_CPPFLAGS="$CPPFLAGS"
 554     CPPFLAGS="$CPPFLAGS $SANEINCL"
 555     AC_CHECK_HEADER(sane/sane.h,
 556                     [AC_DEFINE(HAVE_SANE, 1, [Define if we have SANE development environment])],
 557                     [SANEINCL=""])
 558     CPPFLAGS="$ac_save_CPPFLAGS"
 559 fi
 560
 561 dnl **** Check for libgphoto2 ****
 562 AC_CHECK_PROG(gphoto2_devel,gphoto2-config,gphoto2-config,no)
 563 AC_CHECK_PROG(gphoto2port_devel,gphoto2-port-config,gphoto2-port-config,no)
 564 AC_SUBST(GPHOTO2LIBS,"")
 565 AC_SUBST(GPHOTO2INCL,"")
 566 if test "$gphoto2_devel" != "no" -a "$gphoto2port_devel" != "no"
 567 then
 568     GPHOTO2INCL="`$gphoto2_devel --cflags` `$gphoto2port_devel --cflags`"
 569     GPHOTO2LIBS=""
 570     for i in `$gphoto2_devel --libs` `$gphoto2port_devel --libs`
 571     do
 572       case "$i" in
 573         -L/usr/lib|-L/usr/lib64) ;;
 574         -L*|-l*) GPHOTO2LIBS="$GPHOTO2LIBS $i";;
 575       esac
 576     done
 577     ac_save_CPPFLAGS="$CPPFLAGS"
 578     ac_save_LIBS="$LIBS"
 579     CPPFLAGS="$CPPFLAGS $GPHOTO2INCL"
 580     LIBS="$LIBS $GPHOTO2LIBS"
 581     AC_CHECK_HEADER(gphoto2-camera.h,
 582                     [AC_CHECK_LIB(gphoto2,gp_camera_new,
 583                                   [AC_DEFINE(HAVE_GPHOTO2, 1, [Define if we have libgphoto2 development environment])],
 584                                   [GPHOTO2LIBS=""
 585                                   GPHOTO2INCL=""])],
 586                     [GPHOTO2LIBS=""
 587                     GPHOTO2INCL=""])
 588     LIBS="$ac_save_LIBS"
 589     CPPFLAGS="$ac_save_CPPFLAGS"
 590 fi
 591
 592 dnl **** Check for the ICU library ****
 593 if test "$ac_cv_header_unicode_ubidi_h" = "yes"
 594 then
 595     saved_libs="$LIBS"
 596     icu_libs="-lsicuuc -lsicudata -lstdc++ -lgcc_s"
 597     if test -n "$ICU_LIB_DIR"
 598     then
 599         icu_libs="-L$ICU_LIB_DIR $icu_libs"
 600     fi
 601     AC_MSG_CHECKING(whether can link with ICU libraries)
 602     LIBS="$saved_libs $icu_libs"
 603     AC_TRY_RUN([#include <unicode/ubidi.h>
 604 main () { ubidi_open(); return 0; }],
 605                 [AC_DEFINE(HAVE_ICU,1,[Define to 1 if the ICU libraries are installed])
 606                  AC_SUBST(ICULIBS,"$icu_libs")
 607                  AC_MSG_RESULT(yes)],
 608                 [AC_MSG_RESULT(no)],[AC_MSG_RESULT(no)])
 609     LIBS="$saved_libs"
 610 fi
 611
 612 dnl **** Check for resolver library ***
 613 AC_SUBST(RESOLVLIBS,"")
 614 if test "$ac_cv_header_resolv_h" = "yes"
 615 then
 616     AC_CHECK_LIB(resolv, res_query,
 617         [AC_DEFINE(HAVE_RESOLV, 1, [Define if you have the resolver library and header])
 618          RESOLVLIBS="-lresolv"])
 619 fi
 620
 621 dnl **** Check for LittleCMS ***
 622 AC_SUBST(LCMSLIBS,"")
 623 if test "$ac_cv_header_lcms_h" = "yes" -o "$ac_cv_header_lcms_lcms_h" = "yes"
 624 then
 625     AC_CHECK_LIB(lcms, cmsOpenProfileFromFile,
 626         [AC_DEFINE(HAVE_LCMS, 1, [Define if you have the LittleCMS development environment])
 627          LCMSLIBS="-llcms"])
 628 fi
 629
 630 dnl **** Check for OpenLDAP ***
 631 AC_SUBST(LDAPLIBS,"")
 632 if test "$ac_cv_header_ldap_h" = "yes" -a "$ac_cv_header_lber_h" = "yes"
 633 then
 634     AC_CHECK_LIB(ldap_r, ldap_initialize,
 635         [AC_CHECK_LIB(lber, ber_init,
 636             [AC_DEFINE(HAVE_LDAP, 1, [Define if you have the OpenLDAP development environment])
 637              LDAPLIBS="-lldap_r -llber"],,
 638              [$LIBPTHREAD])],,
 639              [$LIBPTHREAD])
 640     WINE_CHECK_LIB_FUNCS(\
 641         ldap_count_references \
 642         ldap_first_reference \
 643         ldap_next_reference \
 644         ldap_parse_reference,
 645         [$LDAPLIBS $LIBPTHREAD])
 646 fi
 647
 648 dnl **** Check for FreeType 2 ****
 649 AC_SUBST(FREETYPELIBS,"")
 650 AC_SUBST(FREETYPEINCL,"")
 651 AC_CHECK_PROG(ft_devel,freetype-config,freetype-config,no)
 652 if test "$ft_devel" = "no"
 653 then
 654     AC_CHECK_PROG(ft_devel2,freetype2-config,freetype2-config,no)
 655     if test "$ft_devel2" = "freetype2-config"
 656     then
 657         ft_devel=$ft_devel2
 658     fi
 659 fi
 660
 661 if test "$ft_devel" = "no"
 662 then
 663     wine_cv_msg_freetype=yes
 664 else
 665     FREETYPELIBS=`$ft_devel --libs`
 666     FREETYPEINCL=`$ft_devel --cflags`
 667     AC_CHECK_LIB(freetype,FT_Init_FreeType,ft_lib=yes,ft_lib=no,$FREETYPELIBS)
 668     if test "$ft_lib" = "no"
 669     then
 670         wine_cv_msg_freetype=yes
 671         FREETYPELIBS=""
 672         FREETYPEINCL=""
 673     else
 674         ac_save_CPPFLAGS="$CPPFLAGS"
 675         CPPFLAGS="$FREETYPEINCL $CPPFLAGS"
 676         AC_CHECK_HEADERS(ft2build.h \
 677                          freetype/freetype.h \
 678                          freetype/ftglyph.h \
 679                          freetype/tttables.h \
 680                          freetype/ftnames.h \
 681                          freetype/ftsnames.h \
 682                          freetype/ttnameid.h \
 683                          freetype/ftoutln.h \
 684                          freetype/ftwinfnt.h \
 685                          freetype/ftmodapi.h \
 686                          freetype/internal/sfnt.h,,,
 687                          [#if HAVE_FT2BUILD_H
 688                           #include <ft2build.h>
 689                           #endif])
 690         AC_TRY_CPP([#include <ft2build.h>
 691                     #include <freetype/fttrigon.h>],
 692                     [AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
 693           [Define if you have the <freetype/fttrigon.h> header file.])
 694                     wine_cv_fttrigon=yes],
 695                     wine_cv_fttrigon=no)
 696         AC_CHECK_TYPES(FT_TrueTypeEngineType,,,[#include <freetype/ftmodapi.h>])
 697         ac_save_CFLAGS="$CFLAGS"
 698         CFLAGS="$CFLAGS $FREETYPELIBS"
 699         AC_CHECK_FUNCS(FT_Load_Sfnt_Table)
 700         CFLAGS="$ac_save_CFLAGS"
 701         CPPFLAGS="$ac_save_CPPFLAGS"
 702         dnl Check that we have at least freetype/freetype.h
 703         if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
 704         then
 705             AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
 706             wine_cv_msg_freetype=no
 707         else
 708             FREETYPELIBS=""
 709             FREETYPEINCL=""
 710             wine_cv_msg_freetype=yes
 711         fi
 712     fi
 713 fi
 714
 715 dnl Only build the fonts dir if we have both freetype and fontforge
 716 if test "$FONTFORGE" != "false" -a -n "$FREETYPELIBS"
 717 then
 718   AC_SUBST(FONTSSUBDIRS,"fonts")
 719 fi
 720
 721 dnl **** Check for parport (currently Linux only) ****
 722 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
 723  AC_TRY_COMPILE(
 724    [#include <linux/ppdev.h>],
 725    [ioctl (1,PPCLAIM,0)],
 726    [ac_cv_c_ppdev="yes"],
 727    [ac_cv_c_ppdev="no"])
 728  )
 729 if test "$ac_cv_c_ppdev" = "yes"
 730 then
 731     AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
 732 fi
 733
 734 dnl **** Check for va_copy ****
 735 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
 736  AC_TRY_LINK(
 737    [#include <stdarg.h>],
 738    [va_list ap1, ap2;
 739     va_copy(ap1,ap2);
 740    ],
 741    [ac_cv_c_va_copy="yes"],
 742    [ac_cv_c_va_copy="no"])
 743  )
 744 if test "$ac_cv_c_va_copy" = "yes"
 745 then
 746     AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
 747 fi
 748 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
 749  AC_TRY_LINK(
 750    [#include <stdarg.h>],
 751    [va_list ap1, ap2;
 752     __va_copy(ap1,ap2);
 753    ],
 754    [ac_cv_c___va_copy="yes"],
 755    [ac_cv_c___va_copy="no"])
 756  )
 757 if test "$ac_cv_c___va_copy" = "yes"
 758 then
 759     AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
 760 fi
 761
 762 dnl **** Check for sigsetjmp ****
 763 AC_CACHE_CHECK([for sigsetjmp], ac_cv_c_sigsetjmp,
 764  AC_TRY_LINK(
 765    [#include <setjmp.h>],
 766    [sigjmp_buf buf;
 767     sigsetjmp( buf, 1 );
 768     siglongjmp( buf, 1 );],
 769    [ac_cv_c_sigsetjmp="yes"],
 770    [ac_cv_c_sigsetjmp="no"])
 771  )
 772 if test "$ac_cv_c_sigsetjmp" = "yes"
 773 then
 774     AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have the sigsetjmp (and siglongjmp) function])
 775 fi
 776
 777 dnl **** Check for pthread_rwlock_t ****
 778 AC_CHECK_TYPES([pthread_rwlock_t, pthread_rwlockattr_t],,,[#define _GNU_SOURCE
 779 #include <pthread.h>])
 780
 781 dnl **** Check for pthread functions ****
 782 WINE_CHECK_LIB_FUNCS(\
 783         pthread_attr_get_np \
 784         pthread_getattr_np \
 785         pthread_get_stackaddr_np \
 786         pthread_get_stacksize_np,
 787         [$LIBPTHREAD])
 788
 789 dnl **** Check for EsounD ****
 790 AC_PATH_PROG(ESDCONFIG, esd-config)
 791 if test x$ESDCONFIG != x -a x$ESDCONFIG != x'"$ESDCONFIG"';
 792 then
 793     ESD_CFLAGS=""
 794     for i in `$ESDCONFIG --cflags`
 795     do
 796       case "$i" in
 797         -I*) ESD_CFLAGS="$ESD_CFLAGS $i";;
 798       esac
 799     done
 800     ESD_LIBS=`$ESDCONFIG --libs`
 801     save_CFLAGS="$CFLAGS"
 802     CFLAGS="$CFLAGS $ESD_CFLAGS"
 803     AC_CHECK_LIB(esd,esd_open_sound,
 804         [AC_SUBST(ESDLIBS, $ESD_LIBS)
 805          AC_SUBST(ESDINCL, $ESD_CFLAGS)
 806          AC_DEFINE(HAVE_ESD, 1, [Define if you have EsounD sound server])])
 807     CFLAGS="$save_CFLAGS"
 808 fi
 809
 810 dnl **** Check for ALSA 1.x ****
 811 AC_SUBST(ALSALIBS,"")
 812 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
 813 then
 814     AC_CHECK_LIB(asound,snd_pcm_hw_params_get_access,
 815         [AC_TRY_COMPILE([#ifdef HAVE_ALSA_ASOUNDLIB_H
 816 #include <alsa/asoundlib.h>
 817 #elif defined(HAVE_SYS_ASOUNDLIB_H)
 818 #include <sys/asoundlib.h>
 819 #endif],
 820                         [int ret = snd_pcm_hw_params_get_access(NULL, NULL)],
 821                         [AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA 1.x including devel headers])
 822                          ALSALIBS="-lasound"])])
 823 fi
 824
 825 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
 826
 827 AC_SUBST(AUDIOIOLIBS,"")
 828 if test "$ac_cv_header_libaudioio_h" = "yes"
 829 then
 830     AC_CHECK_LIB(audioio,AudioIOGetVersion,
 831                   [AUDIOIOLIBS="-laudioio"
 832                    AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])
 833 fi
 834
 835 dnl **** Check for capi4linux ****
 836
 837 if test "$ac_cv_header_capi20_h" = "yes" -a "$ac_cv_header_linux_capi_h" = "yes"
 838 then
 839     AC_CHECK_LIB(capi20,capi20_register,[AC_DEFINE(HAVE_CAPI4LINUX,1,[Define if you have capi4linux libs and headers])])
 840 fi
 841
 842 dnl **** Check for gcc specific options ****
 843
 844 AC_SUBST(EXTRACFLAGS,"")
 845 if test "x${GCC}" = "xyes"
 846 then
 847   EXTRACFLAGS="-Wall -pipe"
 848
 849   dnl Check for strength-reduce bug
 850   AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
 851                   AC_TRY_RUN([
 852 int     L[[4]] = {0,1,2,3};
 853 int main(void) {
 854   static int Array[[3]];
 855   unsigned int B = 3;
 856   int i;
 857   for(i=0; i<B; i++) Array[[i]] = i - 3;
 858   for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
 859   L[[i]] = 4;
 860
 861   exit( Array[[1]] != -2 || L[[2]] != 3);
 862 }],
 863     ac_cv_c_gcc_strength_bug="no",
 864     ac_cv_c_gcc_strength_bug="yes",
 865     ac_cv_c_gcc_strength_bug="yes") )
 866   if test "$ac_cv_c_gcc_strength_bug" = "yes"
 867   then
 868     EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
 869   fi
 870
 871   dnl Check for some compiler flags
 872
 873   WINE_TRY_CFLAGS([-fshort-wchar],
 874                   [AC_DEFINE(CC_FLAG_SHORT_WCHAR, "-fshort-wchar",
 875                              [Specifies the compiler flag that forces a short wchar_t])])
 876   WINE_TRY_CFLAGS([-fno-strict-aliasing])
 877   WINE_TRY_CFLAGS([-Wdeclaration-after-statement])
 878   WINE_TRY_CFLAGS([-Wwrite-strings])
 879
 880   dnl Check for noisy string.h
 881   saved_CFLAGS="$CFLAGS"
 882   CFLAGS="$CFLAGS -Wpointer-arith -Werror"
 883   AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
 884       AC_TRY_COMPILE([#include <string.h>],[],
 885                      [ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
 886   CFLAGS="$saved_CFLAGS"
 887   if test "$ac_cv_c_string_h_warnings" = "no"
 888   then
 889     EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
 890   fi
 891
 892   AC_SUBST(BUILTINFLAG,"")
 893   saved_CFLAGS="$CFLAGS"
 894   CFLAGS="$CFLAGS -Werror"
 895   AC_CACHE_CHECK([for builtin wchar inlines], ac_cv_c_builtin_wchar_ctype,
 896       AC_TRY_COMPILE([],
 897                      [int iswlower(unsigned short);],
 898                      [ac_cv_c_builtin_wchar_ctype=no],[ac_cv_c_builtin_wchar_ctype=yes]))
 899   CFLAGS="$saved_CFLAGS"
 900   if test "$ac_cv_c_builtin_wchar_ctype" = "yes"
 901   then
 902     BUILTINFLAG="-fno-builtin"
 903   fi
 904 fi
 905
 906 dnl **** Check how to define a function in assembly code ****
 907
 908 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
 909   WINE_TRY_ASM_LINK(
 910       ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
 911       ac_cv_asm_func_def=".def",
 912     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
 913       ac_cv_asm_func_def=".type @function",
 914     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
 915       ac_cv_asm_func_def=".type 2",
 916       ac_cv_asm_func_def="unknown")])]))
 917
 918 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
 919 case "$ac_cv_asm_func_def" in
 920   ".def")
 921      AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
 922   ".type @function")
 923      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
 924   ".type 2")
 925      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
 926   *)
 927      AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
 928 esac
 929
 930 dnl **** Check for underscore on external symbols ****
 931
 932 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
 933     WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
 934                       [extern int ac_test;],
 935                       [if (ac_test) return 1],
 936                       ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
 937
 938 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
 939 if test "$ac_cv_c_extern_prefix" = "yes"
 940 then
 941   AC_DEFINE([__ASM_NAME(name)], ["_" name])
 942 else
 943   AC_DEFINE([__ASM_NAME(name)], [name])
 944 fi
 945
 946 dnl **** Check for working dll ****
 947
 948 AC_SUBST(DLLEXT,"")
 949 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
 950 AC_SUBST(LDSHARED,"")
 951 AC_SUBST(LDDLLFLAGS,"")
 952 AC_SUBST(LIBEXT,"so")
 953 AC_SUBST(IMPLIBEXT,"def")
 954 AC_SUBST(LIBWINE_LDFLAGS,"")
 955
 956 case $host_os in
 957   cygwin*|mingw32*)
 958     AC_CHECK_TOOL(DLLTOOL,dlltool,false)
 959     AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
 960     AC_CHECK_TOOL(MINGWAR,ar,false)
 961     if test "$DLLWRAP" = "false"; then
 962       LIBEXT="a"
 963     else
 964       dnl FIXME - check whether dllwrap works correctly...
 965       LIBEXT="dll"
 966     fi
 967     IMPLIBEXT="a"
 968     dnl We can't build 16-bit NE dlls
 969     WIN16_FILES=""
 970     WIN16_INSTALL=""
 971     ;;
 972   darwin*|macosx*)
 973     DLLEXT=".so"
 974     LIBEXT="dylib"
 975     DLLFLAGS="$DLLFLAGS -fPIC"
 976     LDDLLFLAGS="-bundle -multiply_defined suppress"
 977     LIBWINE_LDFLAGS="-multiply_defined suppress"
 978     LDSHARED="\$(CC) -dynamiclib -install_name @executable_path/\`\$(RELPATH) \$(bindir) \$(libdir)\`/\$(DYNAME)"
 979     STRIP="$STRIP -u -r"
 980     dnl declare needed frameworks
 981     AC_SUBST(COREFOUNDATIONLIB,"-framework CoreFoundation")
 982     AC_SUBST(IOKITLIB,"-framework IOKit -framework CoreFoundation")
 983     AC_SUBST(LDEXECFLAGS,["-image_base 0x7bf00000 -Wl,-segaddr,WINE_DOS,0x00000000,-segaddr,WINE_SHARED_HEAP,0x7f000000"])
 984     if test "$ac_cv_header_DiskArbitration_DiskArbitration_h" = "yes"
 985     then
 986         dnl DiskArbitration API is not public on Darwin < 8.0, use it only if header found
 987         AC_SUBST(DISKARBITRATIONLIB,"-framework DiskArbitration -framework CoreFoundation")
 988     fi
 989     if test "$ac_cv_header_CoreAudio_CoreAudio_h" = "yes" -a "$ac_cv_header_AudioUnit_AudioUnit_h" = "yes"
 990     then
 991         dnl CoreServices needed by AudioUnit
 992         AC_SUBST(COREAUDIO,"-framework CoreAudio -framework AudioUnit -framework CoreServices -framework AudioToolbox -framework CoreMIDI")
 993     fi
 994     case $host_cpu in
 995       *powerpc*)
 996         LDDLLFLAGS="$LDDLLFLAGS -read_only_relocs warning"  dnl FIXME
 997         ;;
 998     esac
 999     dnl Enable quartz driver on Mac OS X
1000     if test "$ac_cv_header_Carbon_Carbon_h" = "yes"
1001     then
1002         AC_SUBST(CARBONLIB,"-framework Carbon")
1003         QUARTZFILES='$(QUARTZFILES)'
1004     fi
1005     ;;
1006   *)
1007     DLLFLAGS="$DLLFLAGS -fPIC"
1008     DLLEXT=".so"
1009     AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
1010         [WINE_TRY_SHLIB_FLAGS([-fPIC -shared -Wl,-Bsymbolic],
1011                               ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
1012     if test "$ac_cv_c_dll_gnuelf" = "yes"
1013     then
1014       LDSHARED="\$(CC) -shared"
1015       LDDLLFLAGS="-shared -Wl,-Bsymbolic"
1016       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-soname,confest.so.1],
1017                       [LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"],
1018                       [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-h,confest.so.1],
1019                                        [LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-h,%)"])])
1020
1021       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs], [LDDLLFLAGS="$LDDLLFLAGS,-z,defs"])
1022
1023       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-init,__wine_spec_init,-fini,__wine_spec_fini],
1024                       [LDDLLFLAGS="$LDDLLFLAGS,-init,__wine_spec_init,-fini,__wine_spec_fini"])
1025
1026       echo '{ global: *; };' >conftest.map
1027       WINE_TRY_CFLAGS([-fPIC -shared -Wl,--version-script=conftest.map],
1028                       [LDSHARED="$LDSHARED \$(VERSCRIPT:%=-Wl,--version-script=%)"])
1029       rm -f conftest.map
1030
1031       WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
1032                       [AC_SUBST(LDEXECFLAGS,["-Wl,--export-dynamic"])])
1033
1034       WINE_TRY_CFLAGS([-fPIC -Wl,--rpath,\$ORIGIN/../lib],
1035                       [LIBWINE_LDFLAGS="-Wl,--rpath,\\\$\$ORIGIN/\`\$(RELPATH) \$(bindir) \$(libdir)\`"],
1036           [WINE_TRY_CFLAGS([-fPIC -Wl,-R,\$ORIGIN/../lib],
1037                            [LIBWINE_LDFLAGS="-Wl,-R,\\\$\$ORIGIN/\`\$(RELPATH) \$(bindir) \$(libdir)\`"])])
1038
1039       case $host_cpu in
1040         *i[[3456789]]86* | x86_64)
1041           WINE_TRY_CFLAGS([-Wl,--section-start,.interp=0x7bf00400],
1042                           [LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x7bf00400"])
1043           ;;
1044       esac
1045
1046     else
1047       AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
1048           [WINE_TRY_SHLIB_FLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
1049                                 ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
1050       if test "$ac_cv_c_dll_unixware" = "yes"
1051       then
1052         LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
1053         LDDLLFLAGS="-Wl,-G,-B,symbolic"
1054
1055       else
1056         AC_CACHE_CHECK(whether we can build an HP-UX dll, ac_cv_c_dll_hpux,
1057           [WINE_TRY_SHLIB_FLAGS([-shared], ac_cv_c_dll_hpux="yes", ac_cv_c_dll_hpux="no")])
1058         if test "$ac_cv_c_dll_hpux" = "yes"
1059         then
1060           LIBEXT="sl"
1061           DLLEXT=".sl"
1062           LDDLLFLAGS="-shared -fPIC"
1063           LDSHARED="\$(CC) -shared"
1064         fi
1065       fi
1066     fi
1067
1068     dnl Check for cross compiler to build test programs
1069     AC_SUBST(CROSSTEST,"")
1070     if test "$cross_compiling" = "no"
1071     then
1072       WINE_CHECK_MINGW_PROG(CROSSCC,gcc,false)
1073       WINE_CHECK_MINGW_PROG(DLLTOOL,dlltool,false)
1074       WINE_CHECK_MINGW_PROG(CROSSWINDRES,windres,false)
1075       WINE_CHECK_MINGW_PROG(MINGWAR,ar,false)
1076       if test "$CROSSCC" != "false"; then CROSSTEST="\$(CROSSTEST)"; fi
1077     fi
1078     ;;
1079 esac
1080
1081 if test "$LIBEXT" = "a"; then
1082   AC_MSG_ERROR(
1083 [could not find a way to build shared libraries.
1084 It is currently not possible to build Wine without shared library
1085 (.so) support to allow transparent switch between .so and .dll files.
1086 If you are using Linux, you will need a newer binutils.]
1087 )
1088 fi
1089
1090 case $build_os in
1091   cygwin*|mingw32*)
1092     AC_SUBST(LDPATH,"PATH=\"\$(TOOLSDIR)/libs/wine:\$\$PATH\"") ;;
1093   darwin*|macosx*)
1094     AC_SUBST(LDPATH,"DYLD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/wine:\$\$DYLD_LIBRARY_PATH\"") ;;
1095   *)
1096     AC_SUBST(LDPATH,"LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/wine:\$\$LD_LIBRARY_PATH\"") ;;
1097 esac
1098
1099 dnl Mingw needs explicit msvcrt for linking libwine and winsock for wininet
1100 case $host_os in
1101   mingw32*)
1102     AC_SUBST(CRTLIBS,"-lmsvcrt")
1103     AC_SUBST(SOCKETLIBS,"-lws2_32")
1104     ;;
1105 esac
1106
1107 AC_SUBST(MAIN_BINARY,"wine-pthread")  dnl Default value
1108 case $host_cpu in
1109   *i[[3456789]]86*)
1110     case $host_os in
1111       linux* | k*bsd*-gnu)
1112         AC_SUBST(MAIN_BINARY,"wine-glibc")
1113         AC_SUBST(EXTRA_BINARIES,"wine-kthread wine-pthread wine-preloader") ;;
1114     esac
1115     ;;
1116 esac
1117
1118 dnl **** Get the soname for libraries that we load dynamically ****
1119
1120 if test "$LIBEXT" = "so" -o "$LIBEXT" = "dylib"
1121 then
1122   WINE_GET_SONAME(X11,XCreateWindow,[$X_LIBS $X_EXTRA_LIBS])
1123   WINE_GET_SONAME(Xext,XextCreateExtension,[$X_LIBS -lX11 $X_EXTRA_LIBS])
1124   WINE_GET_SONAME(Xi,XOpenDevice,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1125   WINE_GET_SONAME(Xinerama,XineramaQueryScreens,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1126   WINE_GET_SONAME(Xrender,XRenderQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1127   WINE_GET_SONAME(Xrandr,XRRQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1128   WINE_GET_SONAME(Xcursor,XcursorImageLoadCursor,[$X_LIBS -lX11 $X_EXTRA_LIBS])
1129   WINE_GET_SONAME(freetype,FT_Init_FreeType,[$X_LIBS])
1130   WINE_GET_SONAME(GL,glXQueryExtension,[$X_LIBS $X_EXTRA_LIBS])
1131   WINE_GET_SONAME(hal,libhal_ctx_new)
1132   WINE_GET_SONAME(txc_dxtn,fetch_2d_texel_rgba_dxt1)
1133   WINE_GET_SONAME(cups,cupsGetDefault)
1134   WINE_GET_SONAME(jack,jack_client_new)
1135   WINE_GET_SONAME(fontconfig,FcInit)
1136   WINE_GET_SONAME(ssl,SSL_library_init)
1137   WINE_GET_SONAME(crypto,BIO_new_socket)
1138   WINE_GET_SONAME(ncurses,waddch)
1139   WINE_GET_SONAME(curses,waddch)
1140   WINE_GET_SONAME(jpeg,jpeg_start_decompress)
1141   WINE_GET_SONAME(capi20,capi20_isinstalled)
1142   WINE_GET_SONAME(sane,sane_init)
1143 fi
1144
1145
1146 dnl **** Check for functions ****
1147
1148 AC_CHECK_FUNCS(\
1149         _pclose \
1150         _popen \
1151         _snprintf \
1152         _spawnvp \
1153         _stricmp \
1154         _strnicmp \
1155         _vsnprintf \
1156         asctime_r \
1157         chsize \
1158         clone \
1159         dlopen \
1160         epoll_create \
1161         ffs \
1162         finite \
1163         fork \
1164         fpclass \
1165         fstatfs \
1166         fstatvfs \
1167         ftruncate \
1168         futimes \
1169         futimesat \
1170         getdirentries \
1171         getopt_long \
1172         getpagesize \
1173         getpwuid \
1174         gettid \
1175         gettimeofday \
1176         getuid \
1177         kqueue \
1178         lstat \
1179         memmove \
1180         mmap \
1181         pclose \
1182         poll \
1183         popen \
1184         prctl \
1185         pread \
1186         pwrite \
1187         readlink \
1188         rfork \
1189         sched_yield \
1190         select \
1191         setrlimit \
1192         settimeofday \
1193         sigaltstack \
1194         sigprocmask \
1195         snprintf \
1196         spawnvp \
1197         statfs \
1198         statvfs \
1199         strcasecmp \
1200         strerror \
1201         strncasecmp \
1202         strtold \
1203         tcgetattr \
1204         timegm \
1205         usleep \
1206         vsnprintf \
1207         wait4 \
1208         waitpid \
1209 )
1210
1211 dnl Check for -ldl
1212 if test "$ac_cv_func_dlopen" = no
1213 then
1214     AC_CHECK_LIB(dl,dlopen,[AC_DEFINE(HAVE_DLOPEN,1) AC_SUBST(LIBDL,"-ldl")])
1215 fi
1216 WINE_CHECK_LIB_FUNCS(dladdr,[$LIBDL])
1217
1218 dnl Check for -lpoll for Mac OS X/Darwin
1219 if test "$ac_cv_func_poll" = no
1220 then
1221     AC_CHECK_LIB(poll,poll,[AC_DEFINE(HAVE_POLL,1) AC_SUBST(LIBPOLL,"-lpoll")])
1222 fi
1223
1224 dnl Check for -lnsl for Solaris
1225 AC_SEARCH_LIBS(gethostbyname, nsl)
1226
1227 dnl Check for -lsocket for Solaris
1228 AC_SEARCH_LIBS(connect, socket)
1229
1230 dnl Check for -lresolv for Solaris
1231 AC_SEARCH_LIBS(inet_aton, resolv)
1232
1233 dnl **** Check for functions which may rely on -lsocket on Solaris.
1234 AC_CHECK_FUNCS(\
1235         getaddrinfo \
1236         getnameinfo \
1237         getnetbyname \
1238         getprotobyname \
1239         getprotobynumber \
1240         getservbyport \
1241         inet_network \
1242         sendmsg \
1243 )
1244
1245 dnl **** Check for types ****
1246
1247 AC_C_CONST
1248 AC_C_INLINE
1249 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t, long long, fsblkcnt_t, fsfilcnt_t])
1250 AC_CHECK_TYPES([sigset_t],,,[#include <signal.h>])
1251 AC_CHECK_TYPES([request_sense],,,[#include <linux/cdrom.h>])
1252
1253 AC_CHECK_MEMBERS([struct ff_effect.direction],,,
1254 [#ifdef HAVE_LINUX_INPUT_H
1255 #include <linux/input.h>
1256 #endif])
1257
1258 AC_CACHE_CHECK([for sigaddset],wine_cv_have_sigaddset,
1259                AC_TRY_LINK([#include <signal.h>],[sigset_t set; sigaddset(&set,SIGTERM);],
1260                            wine_cv_have_sigaddset=yes,wine_cv_have_sigaddset=no))
1261 if test "$wine_cv_have_sigaddset" = "yes"
1262 then
1263   AC_DEFINE(HAVE_SIGADDSET, 1, [Define if sigaddset is supported])
1264 fi
1265
1266
1267 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1268         wine_cv_linux_gethostbyname_r_6,
1269         AC_TRY_LINK([
1270 #include <netdb.h>
1271         ], [
1272     char *name=NULL;
1273     struct hostent he;
1274     struct hostent *result;
1275     char *buf=NULL;
1276     int bufsize=0;
1277     int res,errnr;
1278     char *addr=NULL;
1279     int addrlen=0;
1280     int addrtype=0;
1281     res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1282     res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1283     ],
1284         wine_cv_linux_gethostbyname_r_6=yes,
1285         wine_cv_linux_gethostbyname_r_6=no
1286         )
1287    )
1288    if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1289    then
1290       AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1291                 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1292    fi
1293
1294 if test "$ac_cv_header_linux_joystick_h" = "yes"
1295 then
1296    AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1297         wine_cv_linux_joystick_22_api,
1298         AC_TRY_COMPILE([
1299         #include <sys/ioctl.h>
1300         #include <sys/types.h>
1301         #include <linux/joystick.h>
1302
1303         struct js_event blub;
1304         #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1305         #error "no 2.2 header"
1306         #endif
1307         ],/*empty*/,
1308         wine_cv_linux_joystick_22_api=yes,
1309         wine_cv_linux_joystick_22_api=no,
1310         wine_cv_linux_joystick_22_api=no
1311         )
1312    )
1313    if test "$wine_cv_linux_joystick_22_api" = "yes"
1314    then
1315       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1316                 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1317    fi
1318 fi
1319
1320 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1321
1322 dnl Check for statfs members
1323 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail, struct statfs.f_frsize, struct statfs.f_ffree, struct statfs.f_favail, struct statfs.f_namelen],,,
1324 [#include <sys/types.h>
1325 #ifdef HAVE_SYS_PARAM_H
1326 # include <sys/param.h>
1327 #endif
1328 #ifdef HAVE_SYS_MOUNT_H
1329 # include <sys/mount.h>
1330 #endif
1331 #ifdef HAVE_SYS_VFS_H
1332 # include <sys/vfs.h>
1333 #endif
1334 #ifdef HAVE_SYS_STATFS_H
1335 # include <sys/statfs.h>
1336 #endif])
1337
1338 AC_CHECK_MEMBERS([struct statvfs.f_blocks],,,
1339 [#ifdef HAVE_SYS_STATVFS_H
1340 #include <sys/statvfs.h>
1341 #endif])
1342
1343 dnl Check for socket structure members
1344 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
1345 [#include <sys/types.h>
1346 #ifdef HAVE_SYS_SOCKET_H
1347 # include <sys/socket.h>
1348 #endif
1349 #ifdef HAVE_SYS_UN_H
1350 # include <sys/un.h>
1351 #endif])
1352
1353 dnl Check for scsireq_t and sg_io_hdr_t members
1354 AC_CHECK_MEMBERS([scsireq_t.cmd, sg_io_hdr_t.interface_id],,,
1355 [#include <sys/types.h>
1356 #ifdef HAVE_SCSI_SG_H
1357 #include <scsi/sg.h>
1358 #endif])
1359
1360 dnl Check for siginfo_t members
1361 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
1362
1363 dnl Check for struct mtget members
1364 AC_CHECK_MEMBERS([struct mtget.mt_blksiz, struct mtget.mt_gstat, struct mtget.mt_blkno],,,
1365 [#include <sys/types.h>
1366 #ifdef HAVE_SYS_MTIO_H
1367 #include <sys/mtio.h>
1368 #endif])
1369
1370 dnl Check for struct option
1371 AC_CHECK_MEMBERS([struct option.name],,,
1372 [#ifdef HAVE_GETOPT_H
1373 #include <getopt.h>
1374 #endif])
1375
1376 dnl Check for stat.st_blocks
1377 AC_CHECK_MEMBERS([struct stat.st_blocks])
1378
1379 dnl Check for sin6_scope_id
1380 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_scope_id],,,
1381 [#ifdef HAVE_SYS_TYPES_H
1382 #include <sys/types.h>
1383 #endif
1384 #ifdef HAVE_NETINET_IN_H
1385 #include <netinet/in.h>
1386 #endif])
1387
1388 dnl Check for ns_msg ptr member
1389 AC_CHECK_MEMBERS([ns_msg._msg_ptr],,,
1390 [#ifdef HAVE_SYS_TYPES_H
1391 #include <sys/types.h>
1392 #endif
1393 #ifdef HAVE_NETINET_IN_H
1394 # include <netinet/in.h>
1395 #endif
1396 #ifdef HAVE_ARPA_NAMESER_H
1397 # include <arpa/nameser.h>
1398 #endif])
1399
1400 dnl Check for the external timezone variables timezone and daylight
1401 AC_CACHE_CHECK([for timezone variable], ac_cv_have_timezone,
1402                AC_TRY_LINK([#include <time.h>],[timezone = 1],
1403                            ac_cv_have_timezone="yes", ac_cv_have_timezone="no"))
1404 if test "$ac_cv_have_timezone" = "yes"
1405 then
1406     AC_DEFINE(HAVE_TIMEZONE, 1, [Define if you have the timezone variable])
1407 fi
1408 AC_CACHE_CHECK([for daylight variable], ac_cv_have_daylight,
1409                AC_TRY_LINK([#include <time.h>],[daylight = 1],
1410                            ac_cv_have_daylight="yes", ac_cv_have_daylight="no"))
1411 if test "$ac_cv_have_daylight" = "yes"
1412 then
1413     AC_DEFINE(HAVE_DAYLIGHT, 1, [Define if you have the daylight variable])
1414 fi
1415
1416 dnl *** check for the need to define platform-specific symbols
1417
1418 case $host_cpu in
1419   *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
1420   *x86_64*)         WINE_CHECK_DEFINE([__x86_64__]) ;;
1421   *alpha*)          WINE_CHECK_DEFINE([__ALPHA__]) ;;
1422   *sparc*)          WINE_CHECK_DEFINE([__sparc__]) ;;
1423   *powerpc*)        WINE_CHECK_DEFINE([__powerpc__]) ;;
1424 esac
1425
1426 case $host_vendor in
1427   *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
1428 esac
1429
1430 dnl **** Generate output files ****
1431
1432 dnl autoconf versions before 2.59d need backslashes to escape newlines in subst variables
1433 AC_SUBST(DEPENDENCIES,m4_if(m4_version_compare(m4_defn([m4_PACKAGE_VERSION]), [2.59d]), -1,
1434 ["### Dependencies:\\
1435 \\
1436 .INIT: Makefile\\
1437 .BEGIN: Makefile\\
1438 Makefile: dummy\\
1439         -\$(MAKEDEP) -C\$(SRCDIR) -S\$(TOPSRCDIR) -T\$(TOPOBJDIR) \$(EXTRAINCL) \$(DEPEND_SRCS)\\
1440 \\
1441 \$(OBJS): \$(IDL_GEN_HEADERS)\\
1442 \$(IDL_GEN_C_SRCS:.c=.o): \$(IDL_GEN_C_SRCS)\\
1443 \$(LEX_SRCS:.l=.yy.o): \$(LEX_SRCS:.l=.yy.c)\\
1444 \$(BISON_SRCS:.y=.tab.o): \$(BISON_SRCS:.y=.tab.c)"],
1445 ["### Dependencies:
1446
1447 .INIT: Makefile
1448 .BEGIN: Makefile
1449 Makefile: dummy
1450         -\$(MAKEDEP) -C\$(SRCDIR) -S\$(TOPSRCDIR) -T\$(TOPOBJDIR) \$(EXTRAINCL) \$(DEPEND_SRCS)
1451
1452 \$(OBJS): \$(IDL_GEN_HEADERS)
1453 \$(IDL_GEN_C_SRCS:.c=.o): \$(IDL_GEN_C_SRCS)
1454 \$(LEX_SRCS:.l=.yy.o): \$(LEX_SRCS:.l=.yy.c)
1455 \$(BISON_SRCS:.y=.tab.o): \$(BISON_SRCS:.y=.tab.c)"]))
1456
1457 AH_TOP([#define __WINE_CONFIG_H])
1458
1459 AC_CONFIG_COMMANDS([include/stamp-h], [echo timestamp > include/stamp-h])
1460
1461 WINE_CONFIG_EXTRA_DIR(dlls/gdi32/enhmfdrv)
1462 WINE_CONFIG_EXTRA_DIR(dlls/gdi32/mfdrv)
1463 WINE_CONFIG_EXTRA_DIR(dlls/kernel32/nls)
1464 WINE_CONFIG_EXTRA_DIR(dlls/user32/resources)
1465 WINE_CONFIG_EXTRA_DIR(dlls/wineps.drv/data)
1466 WINE_CONFIG_EXTRA_DIR(include/wine)
1467
1468 MAKE_RULES=Make.rules
1469 AC_SUBST_FILE(MAKE_RULES)
1470
1471 MAKE_DLL_RULES=dlls/Makedll.rules
1472 AC_SUBST_FILE(MAKE_DLL_RULES)
1473
1474 MAKE_IMPLIB_RULES=dlls/Makeimplib.rules
1475 AC_SUBST_FILE(MAKE_IMPLIB_RULES)
1476
1477 MAKE_TEST_RULES=dlls/Maketest.rules
1478 AC_SUBST_FILE(MAKE_TEST_RULES)
1479
1480 MAKE_PROG_RULES=programs/Makeprog.rules
1481 AC_SUBST_FILE(MAKE_PROG_RULES)
1482
1483 AC_CONFIG_FILES([Make.rules])
1484 AC_CONFIG_FILES([dlls/Makedll.rules])
1485 AC_CONFIG_FILES([dlls/Makeimplib.rules])
1486 AC_CONFIG_FILES([dlls/Maketest.rules])
1487 AC_CONFIG_FILES([programs/Makeprog.rules])
1488 AC_CONFIG_FILES([Makefile])
1489 AC_CONFIG_FILES([dlls/Makefile])
1490 AC_CONFIG_FILES([dlls/acledit/Makefile])
1491 AC_CONFIG_FILES([dlls/activeds/Makefile])
1492 AC_CONFIG_FILES([dlls/advapi32/Makefile])
1493 AC_CONFIG_FILES([dlls/advapi32/tests/Makefile])
1494 AC_CONFIG_FILES([dlls/advpack/Makefile])
1495 AC_CONFIG_FILES([dlls/advpack/tests/Makefile])
1496 AC_CONFIG_FILES([dlls/amstream/Makefile])
1497 AC_CONFIG_FILES([dlls/atl/Makefile])
1498 AC_CONFIG_FILES([dlls/avicap32/Makefile])
1499 AC_CONFIG_FILES([dlls/avifil32/Makefile])
1500 AC_CONFIG_FILES([dlls/browseui/Makefile])
1501 AC_CONFIG_FILES([dlls/browseui/tests/Makefile])
1502 AC_CONFIG_FILES([dlls/cabinet/Makefile])
1503 AC_CONFIG_FILES([dlls/cabinet/tests/Makefile])
1504 AC_CONFIG_FILES([dlls/capi2032/Makefile])
1505 AC_CONFIG_FILES([dlls/cards/Makefile])
1506 AC_CONFIG_FILES([dlls/cfgmgr32/Makefile])
1507 AC_CONFIG_FILES([dlls/clusapi/Makefile])
1508 AC_CONFIG_FILES([dlls/comcat/Makefile])
1509 AC_CONFIG_FILES([dlls/comcat/tests/Makefile])
1510 AC_CONFIG_FILES([dlls/comctl32/Makefile])
1511 AC_CONFIG_FILES([dlls/comctl32/tests/Makefile])
1512 AC_CONFIG_FILES([dlls/comdlg32/Makefile])
1513 AC_CONFIG_FILES([dlls/comdlg32/tests/Makefile])
1514 AC_CONFIG_FILES([dlls/compstui/Makefile])
1515 AC_CONFIG_FILES([dlls/credui/Makefile])
1516 AC_CONFIG_FILES([dlls/crtdll/Makefile])
1517 AC_CONFIG_FILES([dlls/crypt32/Makefile])
1518 AC_CONFIG_FILES([dlls/crypt32/tests/Makefile])
1519 AC_CONFIG_FILES([dlls/cryptdll/Makefile])
1520 AC_CONFIG_FILES([dlls/cryptnet/Makefile])
1521 AC_CONFIG_FILES([dlls/ctl3d32/Makefile])
1522 AC_CONFIG_FILES([dlls/d3d8/Makefile])
1523 AC_CONFIG_FILES([dlls/d3d8/tests/Makefile])
1524 AC_CONFIG_FILES([dlls/d3d9/Makefile])
1525 AC_CONFIG_FILES([dlls/d3d9/tests/Makefile])
1526 AC_CONFIG_FILES([dlls/d3dim/Makefile])
1527 AC_CONFIG_FILES([dlls/d3drm/Makefile])
1528 AC_CONFIG_FILES([dlls/d3drm/tests/Makefile])
1529 AC_CONFIG_FILES([dlls/d3dx8/Makefile])
1530 AC_CONFIG_FILES([dlls/d3dxof/Makefile])
1531 AC_CONFIG_FILES([dlls/dbghelp/Makefile])
1532 AC_CONFIG_FILES([dlls/dciman32/Makefile])
1533 AC_CONFIG_FILES([dlls/ddraw/Makefile])
1534 AC_CONFIG_FILES([dlls/ddraw/tests/Makefile])
1535 AC_CONFIG_FILES([dlls/ddrawex/Makefile])
1536 AC_CONFIG_FILES([dlls/devenum/Makefile])
1537 AC_CONFIG_FILES([dlls/dinput/Makefile])
1538 AC_CONFIG_FILES([dlls/dinput/tests/Makefile])
1539 AC_CONFIG_FILES([dlls/dinput8/Makefile])
1540 AC_CONFIG_FILES([dlls/dmband/Makefile])
1541 AC_CONFIG_FILES([dlls/dmcompos/Makefile])
1542 AC_CONFIG_FILES([dlls/dmime/Makefile])
1543 AC_CONFIG_FILES([dlls/dmloader/Makefile])
1544 AC_CONFIG_FILES([dlls/dmscript/Makefile])
1545 AC_CONFIG_FILES([dlls/dmstyle/Makefile])
1546 AC_CONFIG_FILES([dlls/dmsynth/Makefile])
1547 AC_CONFIG_FILES([dlls/dmusic/Makefile])
1548 AC_CONFIG_FILES([dlls/dmusic32/Makefile])
1549 AC_CONFIG_FILES([dlls/dnsapi/Makefile])
1550 AC_CONFIG_FILES([dlls/dnsapi/tests/Makefile])
1551 AC_CONFIG_FILES([dlls/dplay/Makefile])
1552 AC_CONFIG_FILES([dlls/dplayx/Makefile])
1553 AC_CONFIG_FILES([dlls/dplayx/tests/Makefile])
1554 AC_CONFIG_FILES([dlls/dpnaddr/Makefile])
1555 AC_CONFIG_FILES([dlls/dpnet/Makefile])
1556 AC_CONFIG_FILES([dlls/dpnhpast/Makefile])
1557 AC_CONFIG_FILES([dlls/dsound/Makefile])
1558 AC_CONFIG_FILES([dlls/dsound/tests/Makefile])
1559 AC_CONFIG_FILES([dlls/dswave/Makefile])
1560 AC_CONFIG_FILES([dlls/dxdiagn/Makefile])
1561 AC_CONFIG_FILES([dlls/dxerr8/Makefile])
1562 AC_CONFIG_FILES([dlls/dxerr9/Makefile])
1563 AC_CONFIG_FILES([dlls/dxguid/Makefile])
1564 AC_CONFIG_FILES([dlls/gdi32/Makefile])
1565 AC_CONFIG_FILES([dlls/gdi32/tests/Makefile])
1566 AC_CONFIG_FILES([dlls/gdiplus/Makefile])
1567 AC_CONFIG_FILES([dlls/glu32/Makefile])
1568 AC_CONFIG_FILES([dlls/gphoto2.ds/Makefile])
1569 AC_CONFIG_FILES([dlls/hal/Makefile])
1570 AC_CONFIG_FILES([dlls/hhctrl.ocx/Makefile])
1571 AC_CONFIG_FILES([dlls/hid/Makefile])
1572 AC_CONFIG_FILES([dlls/hlink/Makefile])
1573 AC_CONFIG_FILES([dlls/hlink/tests/Makefile])
1574 AC_CONFIG_FILES([dlls/iccvid/Makefile])
1575 AC_CONFIG_FILES([dlls/icmp/Makefile])
1576 AC_CONFIG_FILES([dlls/ifsmgr.vxd/Makefile])
1577 AC_CONFIG_FILES([dlls/imaadp32.acm/Makefile])
1578 AC_CONFIG_FILES([dlls/imagehlp/Makefile])
1579 AC_CONFIG_FILES([dlls/imm32/Makefile])
1580 AC_CONFIG_FILES([dlls/infosoft/Makefile])
1581 AC_CONFIG_FILES([dlls/infosoft/tests/Makefile])
1582 AC_CONFIG_FILES([dlls/inseng/Makefile])
1583 AC_CONFIG_FILES([dlls/iphlpapi/Makefile])
1584 AC_CONFIG_FILES([dlls/iphlpapi/tests/Makefile])
1585 AC_CONFIG_FILES([dlls/itss/Makefile])
1586 AC_CONFIG_FILES([dlls/itss/tests/Makefile])
1587 AC_CONFIG_FILES([dlls/kernel32/Makefile])
1588 AC_CONFIG_FILES([dlls/kernel32/tests/Makefile])
1589 AC_CONFIG_FILES([dlls/localspl/Makefile])
1590 AC_CONFIG_FILES([dlls/localspl/tests/Makefile])
1591 AC_CONFIG_FILES([dlls/localui/Makefile])
1592 AC_CONFIG_FILES([dlls/localui/tests/Makefile])
1593 AC_CONFIG_FILES([dlls/lz32/Makefile])
1594 AC_CONFIG_FILES([dlls/lz32/tests/Makefile])
1595 AC_CONFIG_FILES([dlls/mapi32/Makefile])
1596 AC_CONFIG_FILES([dlls/mapi32/tests/Makefile])
1597 AC_CONFIG_FILES([dlls/mciavi32/Makefile])
1598 AC_CONFIG_FILES([dlls/mcicda/Makefile])
1599 AC_CONFIG_FILES([dlls/mciseq/Makefile])
1600 AC_CONFIG_FILES([dlls/mciwave/Makefile])
1601 AC_CONFIG_FILES([dlls/midimap/Makefile])
1602 AC_CONFIG_FILES([dlls/mlang/Makefile])
1603 AC_CONFIG_FILES([dlls/mlang/tests/Makefile])
1604 AC_CONFIG_FILES([dlls/mmdevldr.vxd/Makefile])
1605 AC_CONFIG_FILES([dlls/monodebg.vxd/Makefile])
1606 AC_CONFIG_FILES([dlls/mpr/Makefile])
1607 AC_CONFIG_FILES([dlls/mprapi/Makefile])
1608 AC_CONFIG_FILES([dlls/msacm32.drv/Makefile])
1609 AC_CONFIG_FILES([dlls/msacm32/Makefile])
1610 AC_CONFIG_FILES([dlls/msacm32/tests/Makefile])
1611 AC_CONFIG_FILES([dlls/msadp32.acm/Makefile])
1612 AC_CONFIG_FILES([dlls/mscms/Makefile])
1613 AC_CONFIG_FILES([dlls/mscms/tests/Makefile])
1614 AC_CONFIG_FILES([dlls/mscoree/Makefile])
1615 AC_CONFIG_FILES([dlls/msdmo/Makefile])
1616 AC_CONFIG_FILES([dlls/msftedit/Makefile])
1617 AC_CONFIG_FILES([dlls/msg711.acm/Makefile])
1618 AC_CONFIG_FILES([dlls/mshtml/Makefile])
1619 AC_CONFIG_FILES([dlls/mshtml/tests/Makefile])
1620 AC_CONFIG_FILES([dlls/msi/Makefile])
1621 AC_CONFIG_FILES([dlls/msi/tests/Makefile])
1622 AC_CONFIG_FILES([dlls/msimg32/Makefile])
1623 AC_CONFIG_FILES([dlls/msisys.ocx/Makefile])
1624 AC_CONFIG_FILES([dlls/msnet32/Makefile])
1625 AC_CONFIG_FILES([dlls/msrle32/Makefile])
1626 AC_CONFIG_FILES([dlls/msvcrt/Makefile])
1627 AC_CONFIG_FILES([dlls/msvcrt/tests/Makefile])
1628 AC_CONFIG_FILES([dlls/msvcrt20/Makefile])
1629 AC_CONFIG_FILES([dlls/msvcrt40/Makefile])
1630 AC_CONFIG_FILES([dlls/msvcrtd/Makefile])
1631 AC_CONFIG_FILES([dlls/msvcrtd/tests/Makefile])
1632 AC_CONFIG_FILES([dlls/msvfw32/Makefile])
1633 AC_CONFIG_FILES([dlls/msvidc32/Makefile])
1634 AC_CONFIG_FILES([dlls/mswsock/Makefile])
1635 AC_CONFIG_FILES([dlls/msxml3/Makefile])
1636 AC_CONFIG_FILES([dlls/msxml3/tests/Makefile])
1637 AC_CONFIG_FILES([dlls/nddeapi/Makefile])
1638 AC_CONFIG_FILES([dlls/netapi32/Makefile])
1639 AC_CONFIG_FILES([dlls/netapi32/tests/Makefile])
1640 AC_CONFIG_FILES([dlls/newdev/Makefile])
1641 AC_CONFIG_FILES([dlls/ntdll/Makefile])
1642 AC_CONFIG_FILES([dlls/ntdll/tests/Makefile])
1643 AC_CONFIG_FILES([dlls/ntdsapi/Makefile])
1644 AC_CONFIG_FILES([dlls/ntoskrnl.exe/Makefile])
1645 AC_CONFIG_FILES([dlls/objsel/Makefile])
1646 AC_CONFIG_FILES([dlls/odbc32/Makefile])
1647 AC_CONFIG_FILES([dlls/odbccp32/Makefile])
1648 AC_CONFIG_FILES([dlls/odbccp32/tests/Makefile])
1649 AC_CONFIG_FILES([dlls/ole32/Makefile])
1650 AC_CONFIG_FILES([dlls/ole32/tests/Makefile])
1651 AC_CONFIG_FILES([dlls/oleacc/Makefile])
1652 AC_CONFIG_FILES([dlls/oleaut32/Makefile])
1653 AC_CONFIG_FILES([dlls/oleaut32/tests/Makefile])
1654 AC_CONFIG_FILES([dlls/olecli32/Makefile])
1655 AC_CONFIG_FILES([dlls/oledlg/Makefile])
1656 AC_CONFIG_FILES([dlls/olepro32/Makefile])
1657 AC_CONFIG_FILES([dlls/olesvr32/Makefile])
1658 AC_CONFIG_FILES([dlls/opengl32/Makefile])
1659 AC_CONFIG_FILES([dlls/powrprof/Makefile])
1660 AC_CONFIG_FILES([dlls/psapi/Makefile])
1661 AC_CONFIG_FILES([dlls/psapi/tests/Makefile])
1662 AC_CONFIG_FILES([dlls/pstorec/Makefile])
1663 AC_CONFIG_FILES([dlls/qcap/Makefile])
1664 AC_CONFIG_FILES([dlls/quartz/Makefile])
1665 AC_CONFIG_FILES([dlls/quartz/tests/Makefile])
1666 AC_CONFIG_FILES([dlls/query/Makefile])
1667 AC_CONFIG_FILES([dlls/rasapi32/Makefile])
1668 AC_CONFIG_FILES([dlls/resutils/Makefile])
1669 AC_CONFIG_FILES([dlls/riched20/Makefile])
1670 AC_CONFIG_FILES([dlls/riched20/tests/Makefile])
1671 AC_CONFIG_FILES([dlls/riched32/Makefile])
1672 AC_CONFIG_FILES([dlls/rpcrt4/Makefile])
1673 AC_CONFIG_FILES([dlls/rpcrt4/tests/Makefile])
1674 AC_CONFIG_FILES([dlls/rsabase/Makefile])
1675 AC_CONFIG_FILES([dlls/rsabase/tests/Makefile])
1676 AC_CONFIG_FILES([dlls/rsaenh/Makefile])
1677 AC_CONFIG_FILES([dlls/rsaenh/tests/Makefile])
1678 AC_CONFIG_FILES([dlls/sane.ds/Makefile])
1679 AC_CONFIG_FILES([dlls/schannel/Makefile])
1680 AC_CONFIG_FILES([dlls/schannel/tests/Makefile])
1681 AC_CONFIG_FILES([dlls/secur32/Makefile])
1682 AC_CONFIG_FILES([dlls/secur32/tests/Makefile])
1683 AC_CONFIG_FILES([dlls/security/Makefile])
1684 AC_CONFIG_FILES([dlls/sensapi/Makefile])
1685 AC_CONFIG_FILES([dlls/serialui/Makefile])
1686 AC_CONFIG_FILES([dlls/serialui/tests/Makefile])
1687 AC_CONFIG_FILES([dlls/setupapi/Makefile])
1688 AC_CONFIG_FILES([dlls/setupapi/tests/Makefile])
1689 AC_CONFIG_FILES([dlls/sfc/Makefile])
1690 AC_CONFIG_FILES([dlls/sfc_os/Makefile])
1691 AC_CONFIG_FILES([dlls/shdoclc/Makefile])
1692 AC_CONFIG_FILES([dlls/shdocvw/Makefile])
1693 AC_CONFIG_FILES([dlls/shdocvw/tests/Makefile])
1694 AC_CONFIG_FILES([dlls/shell32/Makefile])
1695 AC_CONFIG_FILES([dlls/shell32/tests/Makefile])
1696 AC_CONFIG_FILES([dlls/shfolder/Makefile])
1697 AC_CONFIG_FILES([dlls/shlwapi/Makefile])
1698 AC_CONFIG_FILES([dlls/shlwapi/tests/Makefile])
1699 AC_CONFIG_FILES([dlls/snmpapi/Makefile])
1700 AC_CONFIG_FILES([dlls/snmpapi/tests/Makefile])
1701 AC_CONFIG_FILES([dlls/spoolss/Makefile])
1702 AC_CONFIG_FILES([dlls/stdole2.tlb/Makefile])
1703 AC_CONFIG_FILES([dlls/stdole32.tlb/Makefile])
1704 AC_CONFIG_FILES([dlls/sti/Makefile])
1705 AC_CONFIG_FILES([dlls/strmiids/Makefile])
1706 AC_CONFIG_FILES([dlls/svrapi/Makefile])
1707 AC_CONFIG_FILES([dlls/sxs/Makefile])
1708 AC_CONFIG_FILES([dlls/tapi32/Makefile])
1709 AC_CONFIG_FILES([dlls/twain_32/Makefile])
1710 AC_CONFIG_FILES([dlls/unicows/Makefile])
1711 AC_CONFIG_FILES([dlls/url/Makefile])
1712 AC_CONFIG_FILES([dlls/urlmon/Makefile])
1713 AC_CONFIG_FILES([dlls/urlmon/tests/Makefile])
1714 AC_CONFIG_FILES([dlls/user32/Makefile])
1715 AC_CONFIG_FILES([dlls/user32/tests/Makefile])
1716 AC_CONFIG_FILES([dlls/userenv/Makefile])
1717 AC_CONFIG_FILES([dlls/usp10/Makefile])
1718 AC_CONFIG_FILES([dlls/usp10/tests/Makefile])
1719 AC_CONFIG_FILES([dlls/uuid/Makefile])
1720 AC_CONFIG_FILES([dlls/uxtheme/Makefile])
1721 AC_CONFIG_FILES([dlls/uxtheme/tests/Makefile])
1722 AC_CONFIG_FILES([dlls/vdhcp.vxd/Makefile])
1723 AC_CONFIG_FILES([dlls/vdmdbg/Makefile])
1724 AC_CONFIG_FILES([dlls/version/Makefile])
1725 AC_CONFIG_FILES([dlls/version/tests/Makefile])
1726 AC_CONFIG_FILES([dlls/vmm.vxd/Makefile])
1727 AC_CONFIG_FILES([dlls/vnbt.vxd/Makefile])
1728 AC_CONFIG_FILES([dlls/vnetbios.vxd/Makefile])
1729 AC_CONFIG_FILES([dlls/vtdapi.vxd/Makefile])
1730 AC_CONFIG_FILES([dlls/vwin32.vxd/Makefile])
1731 AC_CONFIG_FILES([dlls/w32skrnl/Makefile])
1732 AC_CONFIG_FILES([dlls/winealsa.drv/Makefile])
1733 AC_CONFIG_FILES([dlls/wineaudioio.drv/Makefile])
1734 AC_CONFIG_FILES([dlls/winecoreaudio.drv/Makefile])
1735 AC_CONFIG_FILES([dlls/winecrt0/Makefile])
1736 AC_CONFIG_FILES([dlls/wined3d/Makefile])
1737 AC_CONFIG_FILES([dlls/winedos/Makefile])
1738 AC_CONFIG_FILES([dlls/wineesd.drv/Makefile])
1739 AC_CONFIG_FILES([dlls/winejack.drv/Makefile])
1740 AC_CONFIG_FILES([dlls/winejoystick.drv/Makefile])
1741 AC_CONFIG_FILES([dlls/winemp3.acm/Makefile])
1742 AC_CONFIG_FILES([dlls/winenas.drv/Makefile])
1743 AC_CONFIG_FILES([dlls/wineoss.drv/Makefile])
1744 AC_CONFIG_FILES([dlls/wineps.drv/Makefile])
1745 AC_CONFIG_FILES([dlls/winequartz.drv/Makefile])
1746 AC_CONFIG_FILES([dlls/winex11.drv/Makefile])
1747 AC_CONFIG_FILES([dlls/wing32/Makefile])
1748 AC_CONFIG_FILES([dlls/wininet/Makefile])
1749 AC_CONFIG_FILES([dlls/wininet/tests/Makefile])
1750 AC_CONFIG_FILES([dlls/winmm/Makefile])
1751 AC_CONFIG_FILES([dlls/winmm/tests/Makefile])
1752 AC_CONFIG_FILES([dlls/winnls32/Makefile])
1753 AC_CONFIG_FILES([dlls/winscard/Makefile])
1754 AC_CONFIG_FILES([dlls/winspool.drv/Makefile])
1755 AC_CONFIG_FILES([dlls/winspool.drv/tests/Makefile])
1756 AC_CONFIG_FILES([dlls/wintab32/Makefile])
1757 AC_CONFIG_FILES([dlls/wintrust/Makefile])
1758 AC_CONFIG_FILES([dlls/wintrust/tests/Makefile])
1759 AC_CONFIG_FILES([dlls/wldap32/Makefile])
1760 AC_CONFIG_FILES([dlls/wnaspi32/Makefile])
1761 AC_CONFIG_FILES([dlls/wow32/Makefile])
1762 AC_CONFIG_FILES([dlls/ws2_32/Makefile])
1763 AC_CONFIG_FILES([dlls/ws2_32/tests/Makefile])
1764 AC_CONFIG_FILES([dlls/wsock32/Makefile])
1765 AC_CONFIG_FILES([dlls/wtsapi32/Makefile])
1766 AC_CONFIG_FILES([documentation/Makefile])
1767 AC_CONFIG_FILES([fonts/Makefile])
1768 AC_CONFIG_FILES([include/Makefile])
1769 AC_CONFIG_FILES([libs/Makefile])
1770 AC_CONFIG_FILES([libs/port/Makefile])
1771 AC_CONFIG_FILES([libs/wine/Makefile])
1772 AC_CONFIG_FILES([libs/wpp/Makefile])
1773 AC_CONFIG_FILES([loader/Makefile])
1774 AC_CONFIG_FILES([programs/Makefile])
1775 AC_CONFIG_FILES([programs/clock/Makefile])
1776 AC_CONFIG_FILES([programs/cmd/Makefile])
1777 AC_CONFIG_FILES([programs/cmdlgtst/Makefile])
1778 AC_CONFIG_FILES([programs/control/Makefile])
1779 AC_CONFIG_FILES([programs/eject/Makefile])
1780 AC_CONFIG_FILES([programs/expand/Makefile])
1781 AC_CONFIG_FILES([programs/explorer/Makefile])
1782 AC_CONFIG_FILES([programs/hh/Makefile])
1783 AC_CONFIG_FILES([programs/icinfo/Makefile])
1784 AC_CONFIG_FILES([programs/iexplore/Makefile])
1785 AC_CONFIG_FILES([programs/msiexec/Makefile])
1786 AC_CONFIG_FILES([programs/net/Makefile])
1787 AC_CONFIG_FILES([programs/notepad/Makefile])
1788 AC_CONFIG_FILES([programs/oleview/Makefile])
1789 AC_CONFIG_FILES([programs/progman/Makefile])
1790 AC_CONFIG_FILES([programs/regedit/Makefile])
1791 AC_CONFIG_FILES([programs/regsvr32/Makefile])
1792 AC_CONFIG_FILES([programs/rpcss/Makefile])
1793 AC_CONFIG_FILES([programs/rundll32/Makefile])
1794 AC_CONFIG_FILES([programs/spoolsv/Makefile])
1795 AC_CONFIG_FILES([programs/start/Makefile])
1796 AC_CONFIG_FILES([programs/taskmgr/Makefile])
1797 AC_CONFIG_FILES([programs/uninstaller/Makefile])
1798 AC_CONFIG_FILES([programs/view/Makefile])
1799 AC_CONFIG_FILES([programs/wineboot/Makefile])
1800 AC_CONFIG_FILES([programs/winebrowser/Makefile])
1801 AC_CONFIG_FILES([programs/winecfg/Makefile])
1802 AC_CONFIG_FILES([programs/wineconsole/Makefile])
1803 AC_CONFIG_FILES([programs/winedbg/Makefile])
1804 AC_CONFIG_FILES([programs/winedevice/Makefile])
1805 AC_CONFIG_FILES([programs/winefile/Makefile])
1806 AC_CONFIG_FILES([programs/winemenubuilder/Makefile])
1807 AC_CONFIG_FILES([programs/winemine/Makefile])
1808 AC_CONFIG_FILES([programs/winepath/Makefile])
1809 AC_CONFIG_FILES([programs/winetest/Makefile])
1810 AC_CONFIG_FILES([programs/winevdm/Makefile])
1811 AC_CONFIG_FILES([programs/winhelp/Makefile])
1812 AC_CONFIG_FILES([programs/winver/Makefile])
1813 AC_CONFIG_FILES([programs/wordpad/Makefile])
1814 AC_CONFIG_FILES([programs/xcopy/Makefile])
1815 AC_CONFIG_FILES([server/Makefile])
1816 AC_CONFIG_FILES([tools/Makefile])
1817 AC_CONFIG_FILES([tools/widl/Makefile])
1818 AC_CONFIG_FILES([tools/winebuild/Makefile])
1819 AC_CONFIG_FILES([tools/winedump/Makefile])
1820 AC_CONFIG_FILES([tools/winegcc/Makefile])
1821 AC_CONFIG_FILES([tools/wmc/Makefile])
1822 AC_CONFIG_FILES([tools/wrc/Makefile])
1823
1824 AC_OUTPUT
1825
1826 dnl **** Display messages about additional packages ***
1827
1828 if test "$no_create" = "yes"
1829 then
1830   exit 0
1831 fi
1832
1833 if test "$verbose" = "yes"
1834 then
1835   dnl **** libcapi20-dev devel package ***
1836   if test "$ac_cv_header_capi20_h" != "yes" -o "$ac_cv_header_linux_capi_h" != "yes"
1837   then
1838     echo >&2
1839     AC_MSG_NOTICE([libcapi20 development files not found.])
1840     AC_MSG_NOTICE([Wine will be built without ISDN support. (capi2032.dll)])
1841   fi
1842
1843   dnl **** libcupsys-dev devel package ***
1844   if test "$ac_cv_header_cups_cups_h" != "yes"
1845   then
1846     echo >&2
1847     AC_MSG_NOTICE([libcups development files not found.])
1848     AC_MSG_NOTICE([Wine will be built without CUPS support.])
1849   fi
1850
1851   dnl **** libcurses devel package: see libncurses ***
1852   dnl **** libdbus-1 devel package ***
1853   dnl **** libdbus-1-dev is required for libhal-dev ***
1854
1855   dnl **** libgphoto2 devel package ***
1856   if test "$ac_cv_header_gphoto2_camera_h" != "yes"
1857   then
1858     echo >&2
1859     AC_MSG_NOTICE([libgphoto2 development files not found.])
1860     if test "$ac_cv_header_sane_sane_h" = "yes"
1861     then
1862       AC_MSG_NOTICE([Wine will be built with limited Digital Camera support. (twain_32.dll)])
1863     else
1864       AC_MSG_NOTICE([Wine will be built without Digital Camera support. (gphoto2.ds/twain_32.dll)])
1865     fi
1866   fi
1867
1868   dnl **** libhal devel package ***
1869   dnl **** libhal-dev depends on libdbus-1-dev ***
1870   if test "$ac_cv_header_hal_libhal_h" != "yes"
1871   then
1872     echo >&2
1873     AC_MSG_NOTICE([libhal development files not found.])
1874     AC_MSG_NOTICE([Wine will be built without dynamic device support. (explorer.exe)])
1875   fi
1876
1877   dnl **** libicu devel package ****
1878   if test "$ac_cv_header_unicode_ubidi_h" != "yes"
1879   then
1880     echo >&2
1881     AC_MSG_NOTICE([libicu development files not found.])
1882     AC_MSG_NOTICE([Wine will be built without bidi (Right to Left) support. (gdi32.dll)])
1883   fi
1884
1885   dnl **** liblcms devel package ****
1886   if test "$ac_cv_header_lcms_h" != "yes" -a "$ac_cv_header_lcms_lcms_h" != "yes"
1887   then
1888     echo >&2
1889     AC_MSG_NOTICE([liblcms development files not found.])
1890     AC_MSG_NOTICE([Wine will be built without Color Management support. (mscms.dll)])
1891   fi
1892
1893   dnl **** libldap devel package ****
1894   if test "$ac_cv_header_ldap_h" != "yes" -o "$ac_cv_header_lber_h" != "yes"
1895   then
1896     echo >&2
1897     AC_MSG_NOTICE([libldap (OpenLDAP) development files not found.])
1898     AC_MSG_NOTICE([Wine will be built without LDAP support. (wldap32.dll)])
1899   fi
1900
1901   dnl **** libncurses / libcurses devel package ***
1902   if test "x$with_curses" != "xno" -a "$ac_cv_header_ncurses_h" != "yes" -a "$ac_cv_header_curses_h" != "yes"
1903   then
1904     echo >&2
1905     AC_MSG_NOTICE([lib(n)curses development files not found.])
1906     AC_MSG_NOTICE([Wine will be built without (n)curses support. (wineconsole.exe)])
1907   fi
1908
1909   dnl **** libsane devel package ***
1910   if test "$ac_cv_header_sane_sane_h" != "yes"
1911   then
1912     echo >&2
1913     AC_MSG_NOTICE([libsane development files not found.])
1914     AC_MSG_NOTICE([Wine will be built without Scanner support. (sane.ds/twain_32.dll)])
1915   fi
1916
1917   dnl **** libX11-dev includes Xlib.h and Xutil.h and depends on ***
1918   dnl **** x11proto-input-dev (extensions/XInput.h) and x11proto-kb-dev (XKBlib.h) ***
1919   if test "$have_x" = "yes"
1920   then
1921     dnl **** libX11 - extension: Xext ***
1922     if test "$ac_cv_header_X11_extensions_shape_h" != "yes" -o "$ac_cv_header_X11_extensions_XShm_h" != "yes"
1923     then
1924       echo >&2
1925       AC_MSG_NOTICE([libxext development files not found.])
1926       AC_MSG_NOTICE([Wine will be built without Shm / Shape support. (winex11.drv)])
1927     fi
1928
1929     dnl **** libX11 - extension: Xrandr ***
1930     if test "$ac_cv_header_X11_extensions_Xrandr_h" != "yes"
1931     then
1932       echo >&2
1933       AC_MSG_NOTICE([libXrandr development files not found.])
1934       AC_MSG_NOTICE([Wine will be built without Xrandr support. (winex11.drv)])
1935     fi
1936
1937     dnl **** libX11 - extension: Xrender ***
1938     if test "$ac_cv_header_X11_extensions_Xrender_h" != "yes"
1939     then
1940       echo >&2
1941       AC_MSG_NOTICE([libXrender development files not found.])
1942       AC_MSG_NOTICE([Wine will be built without Xrender support. (winex11.drv)])
1943     fi
1944
1945     dnl **** libX11 - extension: Xxf86vm ***
1946     if test "$ac_cv_header_X11_extensions_xf86vmode_h" != "yes"
1947     then
1948       echo >&2
1949       AC_MSG_NOTICE([libXxf86vm development files not found.])
1950       AC_MSG_NOTICE([Wine will be built without XFree86-VidMode support. (winex11.drv)])
1951     fi
1952   fi
1953
1954   dnl **** libxml2 devel package ***
1955   if test "$ac_cv_header_libxml_parser_h" != "yes"
1956   then
1957     echo >&2
1958     AC_MSG_NOTICE([libxml2 development files not found.])
1959     AC_MSG_NOTICE([Wine will be built without XML support. (msxml.dll)])
1960   fi
1961
1962   dnl **** libxslt devel package ***
1963   if test "$ac_cv_header_libxslt_pattern_h" != "yes" -o "$ac_cv_header_libxslt_transform_h" != "yes"
1964   then
1965     echo >&2
1966     AC_MSG_NOTICE([libxslt development files not found.])
1967     AC_MSG_NOTICE([Wine will be built without xslt support. (msxml.dll)])
1968   fi
1969 fi
1970
1971
1972 dnl **** Display warnings about important packages ***
1973 if test "$have_x" = "no"
1974 then
1975   echo >&2
1976   AC_MSG_WARN([X development files not found. Wine will be built without])
1977   AC_MSG_WARN([X support, which currently does not work, and probably])
1978   AC_MSG_WARN([isn't what you want anyway. You will need to install devel])
1979   AC_MSG_WARN([ packages of Xlib/Xfree86 at the very least.])
1980 fi
1981
1982 if test -z "$OPENGLFILES"
1983 then
1984   echo >&2
1985   AC_MSG_WARN([Wine will be build without OpenGL or Direct3D support])
1986   AC_MSG_WARN([because something is wrong with the OpenGL setup:])
1987   if test "$wine_cv_opengl_headers_found" = "no"
1988   then
1989     AC_MSG_WARN([No OpenGL development headers were found])
1990   fi
1991   if test "$wine_cv_opengl_header_version_OK" = "no"
1992   then
1993     AC_MSG_WARN([Old Mesa headers detected. Consider upgrading your Mesa libraries (http://www.mesa3d.org/).])
1994   elif test "$ac_cv_lib_GL_glXCreateContext" = "no"
1995   then
1996      if test -f /usr/X11R6/lib/libGL.a
1997      then
1998         AC_MSG_WARN([/usr/X11R6/lib/libGL.a is present on your system.
1999 This probably prevents linking to OpenGL. Try deleting the file and restarting configure.])
2000      else
2001         AC_MSG_WARN([No OpenGL library found on this system.])
2002      fi
2003   fi
2004 fi
2005
2006 if test "$wine_cv_msg_freetype" = "yes"
2007 then
2008   echo >&2
2009   AC_MSG_WARN([Your system appears to have the FreeType 2 runtime libraries])
2010   AC_MSG_WARN([installed, but 'freetype-config' is not in your PATH. Install])
2011   AC_MSG_WARN([the freetype-devel package (or its equivalent on your distribution)])
2012   AC_MSG_WARN([to enable Wine to use TrueType fonts.])
2013 fi
2014
2015 if test -z "$FONTSSUBDIRS"
2016 then
2017   echo >&2
2018   if test "$FONTFORGE" = "false"
2019   then
2020     AC_MSG_WARN([FontForge is missing.])
2021   else
2022     AC_MSG_WARN([FreeType is missing.])
2023   fi
2024   AC_MSG_WARN([Fonts will not be built. Dialog text may be invisible or unaligned.])
2025 fi
2026
2027 if test -z "$ALSALIBS" -a \
2028         -z "$AUDIOIOLIBS" -a \
2029         -z "$NASLIBS" -a \
2030         -z "$ESD_LIBS" -a \
2031         -z "$ac_cv_lib_soname_jack" -a \
2032         "$ac_cv_header_sys_soundcard_h" != "yes" -a \
2033         "$ac_cv_header_machine_soundcard_h" != "yes" -a \
2034         "$ac_cv_header_soundcard_h" != "yes"
2035 then
2036   echo >&2
2037   AC_MSG_WARN([No sound system was found. Windows applications will be silent.])
2038   AC_MSG_WARN([The currently supported sound systems are:])
2039   AC_MSG_WARN([ALSA, EsounD, AudioIO, Jack, NAS and OSS])
2040 fi
2041
2042 echo
2043 echo "Configure finished.  Do '${ac_make} depend && ${ac_make}' to compile Wine."
2044 echo
2045
2046 dnl Local Variables:
2047 dnl comment-start: "dnl "
2048 dnl comment-end: ""
2049 dnl comment-start-skip: "\\bdnl\\b\\s *"
2050 dnl compile-command: "autoconf && autoheader"
2051 dnl End: