git.oblomov.eu Git - wine/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Original author: Michael Patra
   3 dnl See ChangeLog file for detailed change history.
   4
   5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
   6
   7 dnl autoconf versions before 2.62 don't handle source dir symlinks correctly
   8 AC_PREREQ(2.62)
   9 AC_INIT([Wine],[WINE_VERSION],[wine-devel@winehq.org],[wine],[http://www.winehq.org])
  10 AC_CONFIG_SRCDIR(server/atom.c)
  11 AC_CONFIG_HEADERS(include/config.h)
  12 AC_CONFIG_AUX_DIR(tools)
  13
  14 dnl autoconf versions before 2.63b don't have AS_VAR_APPEND or AS_VAR_IF
  15 m4_ifdef([AS_VAR_APPEND],,[as_fn_append () { eval $[1]=\$$[1]\$[2]; }
  16 AC_DEFUN([AS_VAR_APPEND],[as_fn_append $1 $2])])dnl
  17 m4_ifdef([AS_VAR_IF],,[AC_DEFUN([AS_VAR_IF],
  18 [AS_LITERAL_IF([$1],
  19   [AS_IF([test "x$$1" = x""$2], [$3], [$4])],
  20   [eval as_val=\$$1
  21    AS_IF([test "x$as_val" = x""$2], [$3], [$4])])])])dnl
  22 dnl autoconf versions before 2.64 don't have AC_PACKAGE_URL
  23 m4_ifdef([AC_PACKAGE_URL],,
  24   [AC_DEFINE([PACKAGE_URL], ["http://www.winehq.org"], [Define to the home page for this package.])
  25    AC_SUBST([PACKAGE_URL], ["http://www.winehq.org"])])dnl
  26
  27 dnl **** Command-line arguments ****
  28
  29 AC_ARG_ENABLE(win16, AS_HELP_STRING([--disable-win16],[do not include Win16 support]))
  30 AC_ARG_ENABLE(win64, AS_HELP_STRING([--enable-win64],[build a Win64 emulator on AMD64 (won't run Win32 binaries)]))
  31 AC_ARG_ENABLE(tests, AS_HELP_STRING([--disable-tests],[do not build the regression tests]))
  32 AC_ARG_ENABLE(maintainer-mode, AS_HELP_STRING([--enable-maintainer-mode],[enable maintainer-specific build rules]))
  33
  34 AC_ARG_WITH(alsa,      AS_HELP_STRING([--without-alsa],[do not use the Alsa sound support]),
  35             [if test "x$withval" = "xno"; then ac_cv_header_sys_asoundlib_h=no; ac_cv_header_alsa_asoundlib_h=no; fi])
  36 AC_ARG_WITH(capi,      AS_HELP_STRING([--without-capi],[do not use CAPI (ISDN support)]),
  37             [if test "x$withval" = "xno"; then ac_cv_header_capi20_h=no; ac_cv_header_linux_capi_h=no; fi])
  38 AC_ARG_WITH(cms,       AS_HELP_STRING([--without-cms],[do not use CMS (color management support)]),
  39             [if test "x$withval" = "xno"; then ac_cv_header_lcms_h=no; ac_cv_header_lcms_lcms_h=no; fi])
  40 AC_ARG_WITH(coreaudio, AS_HELP_STRING([--without-coreaudio],[do not use the CoreAudio sound support]),
  41             [if test "x$withval" = "xno"; then ac_cv_header_CoreAudio_CoreAudio_h=no; fi])
  42 AC_ARG_WITH(cups,      AS_HELP_STRING([--without-cups],[do not use CUPS]))
  43 AC_ARG_WITH(curses,    AS_HELP_STRING([--without-curses],[do not use (n)curses]),
  44             [if test "x$withval" = "xno"; then ac_cv_header_ncurses_h=no; ac_cv_header_curses_h=no; fi])
  45 AC_ARG_WITH(dbus,      AS_HELP_STRING([--without-dbus],[do not use DBus (dynamic device support)]))
  46 AC_ARG_WITH(fontconfig,AS_HELP_STRING([--without-fontconfig],[do not use fontconfig]))
  47 AC_ARG_WITH(freetype,  AS_HELP_STRING([--without-freetype],[do not use the FreeType library]))
  48 AC_ARG_WITH(gettext,   AS_HELP_STRING([--without-gettext],[do not use gettext]))
  49 AC_ARG_WITH(gettextpo, AS_HELP_STRING([--with-gettextpo],[use the GetTextPO library to rebuild po files]),
  50             [if test "x$withval" = "xno"; then ac_cv_header_gettext_po_h=no; fi])
  51 AC_ARG_WITH(gphoto,    AS_HELP_STRING([--without-gphoto],[do not use gphoto (Digital Camera support)]))
  52 AC_ARG_WITH(glu,       AS_HELP_STRING([--without-glu],[do not use the GLU library]))
  53 AC_ARG_WITH(gnutls,    AS_HELP_STRING([--without-gnutls],[do not use GnuTLS (schannel support)]))
  54 AC_ARG_WITH(gsm,       AS_HELP_STRING([--without-gsm],[do not use libgsm (GSM 06.10 codec support)]),
  55             [if test "x$withval" = "xno"; then ac_cv_header_gsm_h=no; ac_cv_header_gsm_gsm_h=no; fi])
  56 AC_ARG_WITH(gstreamer, AS_HELP_STRING([--without-gstreamer],[do not use GStreamer (codecs support)]))
  57 AC_ARG_WITH(hal,       AS_HELP_STRING([--without-hal],[do not use HAL (dynamic device support)]))
  58 AC_ARG_WITH(jpeg,      AS_HELP_STRING([--without-jpeg],[do not use JPEG]),
  59             [if test "x$withval" = "xno"; then ac_cv_header_jpeglib_h=no; fi])
  60 AC_ARG_WITH(ldap,      AS_HELP_STRING([--without-ldap],[do not use LDAP]),
  61             [if test "x$withval" = "xno"; then ac_cv_header_ldap_h=no; ac_cv_header_lber_h=no; fi])
  62 AC_ARG_WITH(mpg123,    AS_HELP_STRING([--without-mpg123],[do not use the mpg123 library]),
  63             [if test "x$withval" = "xno"; then ac_cv_header_mpg123_h=no; fi])
  64 AC_ARG_WITH(openal,    AS_HELP_STRING([--without-openal],[do not use OpenAL]),
  65             [if test "x$withval" = "xno"; then ac_cv_header_AL_al_h=no; ac_cv_header_OpenAL_al_h=no; fi])
  66 AC_ARG_WITH(opencl,    AS_HELP_STRING([--without-opencl],[do not use OpenCL]),
  67             [if test "x$withval" = "xno"; then ac_cv_header_CL_cl_h=no; ac_cv_header_OpenCL_opencl_h=no; fi])
  68 AC_ARG_WITH(opengl,    AS_HELP_STRING([--without-opengl],[do not use OpenGL]))
  69 AC_ARG_WITH(openssl,   AS_HELP_STRING([--without-openssl],[do not use OpenSSL]),
  70             [if test "x$withval" = "xno"; then ac_cv_header_openssl_err_h=no; ac_cv_header_openssl_ssl_h=no; fi])
  71 AC_ARG_WITH(osmesa,     AS_HELP_STRING([--without-osmesa],[do not use the OSMesa library]))
  72 AC_ARG_WITH(oss,       AS_HELP_STRING([--without-oss],[do not use the OSS sound support]))
  73 AC_ARG_WITH(png,       AS_HELP_STRING([--without-png],[do not use PNG]),
  74             [if test "x$withval" = "xno"; then ac_cv_header_png_h=no; fi])
  75 AC_ARG_WITH(pthread,   AS_HELP_STRING([--without-pthread],[do not use the pthread library]),
  76             [if test "x$withval" = "xno"; then ac_cv_header_pthread_h=no; fi])
  77 AC_ARG_WITH(sane,      AS_HELP_STRING([--without-sane],[do not use SANE (scanner support)]))
  78 AC_ARG_WITH(tiff,       AS_HELP_STRING([--without-tiff],[do not use TIFF]),
  79             [if test "x$withval" = "xno"; then ac_cv_header_tiffio_h=no; fi])
  80 AC_ARG_WITH(v4l,       AS_HELP_STRING([--without-v4l],[do not use v4l1 (v4l support)]))
  81 AC_ARG_WITH(xcomposite,AS_HELP_STRING([--without-xcomposite],[do not use the Xcomposite extension]),
  82             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_Xcomposite_h=no; fi])
  83 AC_ARG_WITH(xcursor,   AS_HELP_STRING([--without-xcursor],[do not use the Xcursor extension]),
  84             [if test "x$withval" = "xno"; then ac_cv_header_X11_Xcursor_Xcursor_h=no; fi])
  85 AC_ARG_WITH(xinerama,  AS_HELP_STRING([--without-xinerama],[do not use Xinerama (multi-monitor support)]),
  86             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_Xinerama_h=no; fi])
  87 AC_ARG_WITH(xinput,    AS_HELP_STRING([--without-xinput],[do not use the Xinput extension]),
  88             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_XInput_h=no; fi])
  89 AC_ARG_WITH(xinput2,   AS_HELP_STRING([--without-xinput2],[do not use the Xinput 2 extension]),
  90             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_XInput2_h=no; fi])
  91 AC_ARG_WITH(xml,       AS_HELP_STRING([--without-xml],[do not use XML]))
  92 AC_ARG_WITH(xrandr,    AS_HELP_STRING([--without-xrandr],[do not use Xrandr (resolution changes)]),
  93             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_Xrandr_h=no; fi])
  94 AC_ARG_WITH(xrender,   AS_HELP_STRING([--without-xrender],[do not use the Xrender extension]),
  95             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_Xrender_h=no; fi])
  96 AC_ARG_WITH(xshape,    AS_HELP_STRING([--without-xshape],[do not use the Xshape extension]),
  97             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_shape_h=no; fi])
  98 AC_ARG_WITH(xshm,      AS_HELP_STRING([--without-xshm],[do not use XShm (shared memory extension)]),
  99             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_XShm_h=no; fi])
 100 AC_ARG_WITH(xslt,      AS_HELP_STRING([--without-xslt],[do not use XSLT]))
 101 AC_ARG_WITH(xxf86vm,   AS_HELP_STRING([--without-xxf86vm],[do not use XFree video mode extension]),
 102             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_xf86vmode_h=no; ac_cv_header_X11_extensions_xf86vmproto_h=no; fi])
 103 AC_ARG_WITH(zlib,      AS_HELP_STRING([--without-zlib],[do not use Zlib (data compression)]),
 104             [if test "x$withval" = "xno"; then ac_cv_header_zlib_h=no; fi])
 105
 106 AC_ARG_WITH(wine-tools,AS_HELP_STRING([--with-wine-tools=DIR],[use Wine tools from directory DIR]))
 107 AC_ARG_WITH(wine64,    AS_HELP_STRING([--with-wine64=DIR],[use the 64-bit Wine in DIR for a Wow64 build]))
 108
 109 AC_CANONICAL_HOST
 110
 111 dnl check for out of tree build with unclean source tree
 112 case "$srcdir" in
 113  .) ;;
 114  *) if test -f "$srcdir/Makefile" -o -f "$srcdir/include/config.h"; then
 115       AC_MSG_ERROR([you are building out of the source tree, but the source tree contains object files.
 116 You need to run 'make distclean' in the source tree first.])
 117     fi ;;
 118 esac
 119
 120 dnl **** Check for some programs ****
 121
 122 AC_PROG_MAKE_SET
 123 AC_PROG_CC
 124 AC_PROG_CXX
 125 dnl We can't use AC_PROG_CPP for winegcc, it uses by default $(CC) -E
 126 AC_CHECK_TOOL(CPPBIN,cpp,cpp)
 127 AC_DEFINE_UNQUOTED(EXEEXT,["$ac_exeext"],[Define to the file extension for executables.])
 128
 129 case $host in
 130   *-darwin*)
 131     if test "x$enable_win64" = "xyes"
 132     then
 133       CC="$CC -m64"
 134       CXX="$CXX -m64"
 135       host_cpu="x86_64"
 136       notice_platform="64-bit "
 137       AC_SUBST(TARGETFLAGS,"-m64")
 138     else
 139       CC="$CC -m32"
 140       CXX="$CXX -m32"
 141       host_cpu="i386"
 142       notice_platform="32-bit "
 143       AC_SUBST(TARGETFLAGS,"-m32")
 144       enable_win16=${enable_win16:-yes}
 145     fi
 146     with_fontconfig=${with_fontconfig:-no}
 147     ;;
 148   x86_64*)
 149     if test "x$enable_win64" != "xyes" -a "$cross_compiling" != "yes"
 150     then
 151       CC="$CC -m32"
 152       CXX="$CXX -m32"
 153       AC_MSG_CHECKING([whether $CC works])
 154       AC_LINK_IFELSE([AC_LANG_PROGRAM()],AC_MSG_RESULT([yes]),
 155                      [AC_MSG_RESULT([no])
 156                       AC_MSG_ERROR([Cannot build a 32-bit program, you need to install 32-bit development libraries.])])
 157       host_cpu="i386"
 158       notice_platform="32-bit "
 159       AC_SUBST(TARGETFLAGS,"-m32")
 160       enable_win16=${enable_win16:-yes}
 161     else
 162       if test "x${GCC}" = "xyes"
 163       then
 164         AC_MSG_CHECKING([whether $CC supports __builtin_ms_va_list])
 165         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <stdarg.h>]], [[void func(__builtin_ms_va_list *args);]])],
 166                           [AC_MSG_RESULT([yes])],
 167                           [AC_MSG_RESULT([no])
 168                            AC_MSG_ERROR([You need gcc >= 4.4 to build Wine as 64-bit.])])
 169       fi
 170       AC_SUBST(TARGETFLAGS,"-m64")
 171     fi
 172     ;;
 173   arm*)
 174     AC_MSG_CHECKING([whether $CC supports Thumb])
 175     WINE_TRY_ASM_LINK([".thumb\nblx ac_test\n.arm"],[int ac_test(int i) { return i; }], [if (ac_test(1)) return 1],
 176                       [AC_MSG_RESULT([yes])],
 177                       [AC_MSG_RESULT([no])
 178                        AC_MSG_ERROR([You need a target with Thumb support to build Wine for ARM.])])
 179     CFLAGS="$CFLAGS -marm"
 180     ;;
 181   *-mingw32*|*-cygwin*)
 182     enable_win16=${enable_win16:-no}
 183     CFLAGS="$CFLAGS -D_WIN32"
 184     ;;
 185   i[[3456789]]86*)
 186     enable_win16=${enable_win16:-yes}
 187     ;;
 188 esac
 189
 190 dnl enable_win16 defaults to yes on x86, to no on other CPUs
 191 enable_win16=${enable_win16:-no}
 192 enable_win64=${enable_win64:-no}
 193
 194 dnl Disable winetest too if tests are disabled
 195 enable_winetest=${enable_winetest:-$enable_tests}
 196
 197 dnl Some special cases for the wow64 build
 198 if test -n "$with_wine64"
 199 then
 200     if test "x$enable_win64" = "xyes"
 201     then
 202         AC_MSG_ERROR([--enable-win64 and --with-wine64 are mutually exclusive.
 203 --enable-win64 should be used in the 64-bit build tree, --with-wine64 in the 32-bit Wow64 build tree.])
 204     fi
 205     AC_SUBST([WOW64_DISABLE],[\#])
 206     enable_fonts=${enable_fonts:-no}
 207     enable_server=${enable_server:-no}
 208     enable_tools=${enable_tools:-no}
 209 elif test "x$enable_win64" = "xyes"
 210 then
 211     test "x$libdir" != "x\${exec_prefix}/lib" || libdir="\${exec_prefix}/lib64"
 212 fi
 213
 214 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
 215   [wine_cv_toolsdir="$with_wine_tools"
 216    if test -z "$with_wine_tools"; then
 217      if test "$cross_compiling" = "yes"; then
 218        AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
 219      elif test -n "$with_wine64"; then
 220        wine_cv_toolsdir="$with_wine64"
 221      fi
 222    fi
 223    if test -z "$wine_cv_toolsdir"; then
 224      wine_cv_toolsdir="\$(top_builddir)"
 225    elif test -d "$wine_cv_toolsdir/tools/winebuild"; then
 226      case "$wine_cv_toolsdir" in
 227        /*) ;;
 228        *)  wine_cv_toolsdir="\$(top_builddir)/$wine_cv_toolsdir" ;;
 229      esac
 230    else
 231      AC_MSG_ERROR([could not find Wine tools in $wine_cv_toolsdir])
 232    fi])
 233 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
 234 if test -n "$host_alias" -a "$host_alias" != "$build_alias"
 235 then
 236     AC_SUBST(TARGETFLAGS,"-b $host_alias $TARGETFLAGS")
 237 fi
 238
 239 dnl Check for flex
 240 AC_CHECK_PROGS(FLEX,flex,none)
 241 if test "$FLEX" = "none"
 242 then
 243   AC_MSG_ERROR([no suitable flex found. Please install the 'flex' package.])
 244 fi
 245 AC_MSG_CHECKING([whether flex is recent enough])
 246 cat >conftest.l <<EOF
 247 %top{
 248 #include "prediluvian.h"
 249 }
 250 %%
 251 EOF
 252 if $FLEX -t conftest.l >/dev/null 2>&AS_MESSAGE_LOG_FD
 253 then
 254   AC_MSG_RESULT([yes])
 255 else
 256   AC_MSG_RESULT([no])
 257   AC_MSG_ERROR([Your flex version is too old. Please install flex version 2.5.33 or newer.])
 258 fi
 259
 260 dnl Check for bison
 261 AC_CHECK_PROGS(BISON,bison,none)
 262 if test "$BISON" = "none"
 263 then
 264   AC_MSG_ERROR([no suitable bison found. Please install the 'bison' package.])
 265 fi
 266
 267 AC_CHECK_TOOLS(AR,[ar gar],ar)
 268 AC_SUBST(ARFLAGS,rc)
 269 AC_PROG_RANLIB
 270 AC_PROG_LN_S
 271 AC_PROG_EGREP
 272 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
 273 AC_PROG_INSTALL
 274 dnl Prepend src dir to install path dir if it's a relative path
 275 case "$INSTALL" in
 276   [[\\/$]]* | ?:[[\\/]]* ) ;;
 277   *)  INSTALL="\\\$(top_srcdir)/$INSTALL" ;;
 278 esac
 279
 280 dnl Check for lint
 281 AC_CHECK_PROGS(LINT, lclint lint)
 282 if test "$LINT" = "lint"
 283 then
 284   LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
 285   dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
 286 fi
 287 AC_SUBST(LINTFLAGS)
 288
 289 dnl Check for various programs
 290 AC_CHECK_PROGS(FONTFORGE, fontforge, false)
 291 AC_CHECK_PROGS(PKG_CONFIG, pkg-config, false)
 292 AC_CHECK_PROGS(RSVG, rsvg, false)
 293 AC_CHECK_PROGS(CONVERT, convert, false)
 294 AC_CHECK_PROGS(ICOTOOL, icotool, false)
 295 AC_CHECK_PROGS(MSGFMT, msgfmt, false)
 296
 297 if test "x$enable_maintainer_mode" != "xyes"
 298 then
 299   AC_SUBST([MAINTAINER_MODE],[\#])
 300 else
 301   if test "$FONTFORGE" = "false"; then AC_MSG_ERROR([You need fontforge to rebuild fonts in maintainer mode.]); fi
 302   if test "$RSVG" = "false"; then AC_MSG_ERROR([You need rsvg to rebuild icons in maintainer mode.]); fi
 303
 304   dnl Check the imagemagick version
 305   if test "$CONVERT" = false
 306   then
 307     AC_MSG_ERROR([You need imagemagick to rebuild icons in maintainer mode.])
 308   else
 309     AC_MSG_CHECKING([for recent enough imagemagick])
 310     convert_version=`convert --version | head -n1`
 311     if test "x$convert_version" != "x"
 312     then
 313       convert_version_major=`expr "$convert_version" : '.* \([[0-9]]*\)\.[[0-9]]*'`
 314       convert_version_minor=`expr "$convert_version" : '.* [[0-9]]*\.\([[0-9]]*\)'`
 315       if test "$convert_version_major" -eq 6 -a "$convert_version_minor" -lt 6
 316       then
 317         CONVERT=false
 318       fi
 319     fi
 320     if test "$CONVERT" = false
 321     then
 322       AC_MSG_RESULT([no ($convert_version_major.$convert_version_minor)])
 323       AC_MSG_ERROR([You need imagemagick version 6.6 or newer to rebuild icons in maintainer mode.])
 324     else
 325       AC_MSG_RESULT([yes ($convert_version_major.$convert_version_minor)])
 326     fi
 327   fi
 328
 329   dnl Check the icotool version
 330   if test "$ICOTOOL" = false
 331   then
 332     AC_MSG_ERROR([You need icotool to rebuild icons in maintainer mode.])
 333   else
 334     AC_MSG_CHECKING([for recent enough icotool])
 335     icotool_version=`icotool --version | head -n1`
 336     if test "x$icotool_version" != "x"
 337     then
 338       icotool_version_major=`expr "$icotool_version" : '.* \([[0-9]]*\)\.[[0-9]]*'`
 339       icotool_version_minor=`expr "$icotool_version" : '.* [[0-9]]*\.\([[0-9]]*\)'`
 340       if test "$icotool_version_major" -eq 0 -a "$icotool_version_minor" -lt 29
 341       then
 342         ICOTOOL=false
 343         WINE_WARNING([icotool version 0.29.0 or newer is needed to rebuild icons.])
 344       fi
 345     fi
 346     if test "$ICOTOOL" = false
 347     then
 348       AC_MSG_RESULT([no ($icotool_version_major.$icotool_version_minor)])
 349       AC_MSG_ERROR([You need icotool version 0.29.0 or newer to rebuild icons in maintainer mode.])
 350     else
 351       AC_MSG_RESULT([yes ($icotool_version_major.$icotool_version_minor)])
 352     fi
 353   fi
 354
 355   dnl Maintainer mode requires gettext
 356   with_gettext=yes
 357   with_gettextpo=yes
 358   AS_UNSET(ac_cv_header_gettext_po_h)
 359 fi
 360
 361 test "x$with_gettext" != xno || MSGFMT=false
 362 if test "$MSGFMT" != "false"
 363 then
 364   AC_MSG_CHECKING([whether msgfmt supports contexts])
 365   cat >conftest.po <<EOF
 366 # comment
 367 msgctxt "ctxt"
 368 msgid "id"
 369 msgstr "str"
 370 EOF
 371   if $MSGFMT -o /dev/null conftest.po 2>&AS_MESSAGE_LOG_FD
 372   then
 373     AC_MSG_RESULT([yes])
 374   else
 375     AC_MSG_RESULT([no])
 376     MSGFMT=false
 377   fi
 378 fi
 379 WINE_WARNING_WITH(gettext,[test "$MSGFMT" = false],
 380                   [gettext tools not found (or too old), translations won't be built.])
 381
 382 dnl **** Check for some libraries ****
 383
 384 dnl Check for -li386 for NetBSD and OpenBSD
 385 AC_CHECK_LIB(i386,i386_set_ldt)
 386 dnl Check for -lossaudio for NetBSD
 387 AC_CHECK_LIB(ossaudio,_oss_ioctl)
 388
 389 AC_SUBST(XLIB,"")
 390 AC_SUBST(OPENGL_LIBS,"")
 391
 392 dnl **** Check for header files ****
 393
 394 test "x$with_fontconfig" != "xno" || ac_cv_header_fontconfig_fontconfig_h=no
 395
 396 AC_SYS_LARGEFILE()
 397
 398 AC_CHECK_HEADERS(\
 399         AL/al.h \
 400         ApplicationServices/ApplicationServices.h \
 401         AudioToolbox/AudioConverter.h \
 402         AudioUnit/AudioUnit.h \
 403         AudioUnit/AudioComponent.h \
 404         CL/cl.h \
 405         Carbon/Carbon.h \
 406         CoreAudio/CoreAudio.h \
 407         CoreServices/CoreServices.h \
 408         DiskArbitration/DiskArbitration.h \
 409         IOKit/IOKitLib.h \
 410         IOKit/hid/IOHIDLib.h \
 411         OpenAL/al.h \
 412         OpenCL/opencl.h \
 413         QuickTime/ImageCompression.h \
 414         Security/Security.h \
 415         alias.h \
 416         alsa/asoundlib.h \
 417         arpa/inet.h \
 418         arpa/nameser.h \
 419         asm/types.h \
 420         capi20.h \
 421         curses.h \
 422         direct.h \
 423         dirent.h \
 424         dlfcn.h \
 425         elf.h \
 426         float.h \
 427         fnmatch.h \
 428         fontconfig/fontconfig.h \
 429         getopt.h \
 430         gettext-po.h \
 431         grp.h \
 432         gsm.h \
 433         gsm/gsm.h \
 434         ieeefp.h \
 435         inet/mib2.h \
 436         io.h \
 437         jpeglib.h \
 438         kstat.h \
 439         lber.h \
 440         lcms.h \
 441         lcms/lcms.h \
 442         ldap.h \
 443         link.h \
 444         linux/cdrom.h \
 445         linux/compiler.h \
 446         linux/filter.h \
 447         linux/hdreg.h \
 448         linux/input.h \
 449         linux/ioctl.h \
 450         linux/joystick.h \
 451         linux/major.h \
 452         linux/param.h \
 453         linux/serial.h \
 454         linux/types.h \
 455         linux/ucdrom.h \
 456         lwp.h \
 457         mach-o/nlist.h \
 458         mach-o/loader.h \
 459         mach/mach.h \
 460         mach/machine.h \
 461         machine/cpu.h \
 462         machine/limits.h \
 463         machine/sysarch.h \
 464         mntent.h \
 465         mpg123.h \
 466         ncurses.h \
 467         netdb.h \
 468         netinet/in.h \
 469         netinet/in_systm.h \
 470         netinet/tcp.h \
 471         netinet/tcp_fsm.h \
 472         openssl/err.h \
 473         openssl/ssl.h \
 474         png.h \
 475         poll.h \
 476         port.h \
 477         process.h \
 478         pthread.h \
 479         pwd.h \
 480         sched.h \
 481         scsi/scsi.h \
 482         scsi/scsi_ioctl.h \
 483         scsi/sg.h \
 484         stdbool.h \
 485         stdint.h \
 486         stropts.h \
 487         sys/asoundlib.h \
 488         sys/attr.h \
 489         sys/cdio.h \
 490         sys/elf32.h \
 491         sys/epoll.h \
 492         sys/event.h \
 493         sys/exec_elf.h \
 494         sys/filio.h \
 495         sys/inotify.h \
 496         sys/ioctl.h \
 497         sys/ipc.h \
 498         sys/limits.h \
 499         sys/link.h \
 500         sys/mman.h \
 501         sys/modem.h \
 502         sys/msg.h \
 503         sys/mtio.h \
 504         sys/param.h \
 505         sys/poll.h \
 506         sys/prctl.h \
 507         sys/protosw.h \
 508         sys/ptrace.h \
 509         sys/resource.h \
 510         sys/scsiio.h \
 511         sys/shm.h \
 512         sys/signal.h \
 513         sys/socket.h \
 514         sys/socketvar.h \
 515         sys/sockio.h \
 516         sys/statvfs.h \
 517         sys/strtio.h \
 518         sys/syscall.h \
 519         sys/tihdr.h \
 520         sys/time.h \
 521         sys/timeout.h \
 522         sys/times.h \
 523         sys/uio.h \
 524         sys/utsname.h \
 525         sys/vm86.h \
 526         sys/wait.h \
 527         syscall.h \
 528         termios.h \
 529         tiffio.h \
 530         unistd.h \
 531         utime.h \
 532         valgrind/memcheck.h \
 533         valgrind/valgrind.h \
 534         zlib.h
 535 )
 536 AC_HEADER_STAT()
 537
 538 dnl **** Checks for headers that depend on other ones ****
 539
 540 AC_CHECK_HEADERS([sys/mount.h sys/statfs.h sys/sysctl.h sys/user.h sys/vfs.h],,,
 541     [#include <sys/types.h>
 542      #ifdef HAVE_SYS_PARAM_H
 543      # include <sys/param.h>
 544      #endif])
 545
 546 AC_CHECK_HEADERS(\
 547         netinet/ip.h \
 548         net/if.h \
 549         net/if_arp.h \
 550         net/if_dl.h \
 551         net/if_types.h \
 552         net/route.h \
 553         netinet/if_ether.h \
 554         netinet/if_inarp.h \
 555         netinet/in_pcb.h \
 556         netinet/ip_icmp.h \
 557         netinet/ip_var.h \
 558         netinet/udp.h \
 559         netipx/ipx.h \
 560         sys/un.h \
 561 ,,,[#include <sys/types.h>
 562      #ifdef HAVE_SYS_SOCKET_H
 563      # include <sys/socket.h>
 564      #endif
 565      #ifdef HAVE_SYS_SOCKETVAR_H
 566      # include <sys/socketvar.h>
 567      #endif
 568      #ifdef HAVE_NET_ROUTE_H
 569      # include <net/route.h>
 570      #endif
 571      #ifdef HAVE_NETINET_IN_H
 572      # include <netinet/in.h>
 573      #endif
 574      #ifdef HAVE_NETINET_IN_SYSTM_H
 575      # include <netinet/in_systm.h>
 576      #endif
 577      #ifdef HAVE_NET_IF_H
 578      # include <net/if.h>
 579      #endif
 580      #ifdef HAVE_NETINET_IP_H
 581      # include <netinet/ip.h>
 582      #endif])
 583
 584 AC_CHECK_HEADERS([netinet/tcp_timer.h netinet/udp_var.h netinet/icmp_var.h netinet/tcp_var.h ],,,
 585     [#include <sys/types.h>
 586      #ifdef HAVE_ALIAS_H
 587      # include <alias.h>
 588      #endif
 589      #ifdef HAVE_SYS_SOCKET_H
 590      # include <sys/socket.h>
 591      #endif
 592      #ifdef HAVE_SYS_SOCKETVAR_H
 593      # include <sys/socketvar.h>
 594      #endif
 595      #ifdef HAVE_SYS_TIMEOUT_H
 596      # include <sys/timeout.h>
 597      #endif
 598      #ifdef HAVE_NETINET_IN_H
 599      # include <netinet/in.h>
 600      #endif
 601      #ifdef HAVE_NETINET_IN_SYSTM_H
 602      # include <netinet/in_systm.h>
 603      #endif
 604      #ifdef HAVE_NETINET_IP_H
 605      # include <netinet/ip.h>
 606      #endif
 607      #ifdef HAVE_NETINET_IP_VAR_H
 608      # include <netinet/ip_var.h>
 609      #endif
 610      #ifdef HAVE_NETINET_IP_ICMP_H
 611      # include <netinet/ip_icmp.h>
 612      #endif
 613      #ifdef HAVE_NETINET_UDP_H
 614      # include <netinet/udp.h>
 615      #endif
 616      #ifdef HAVE_NETINET_TCP_H
 617      # include <netinet/tcp.h>
 618      #endif
 619      #ifdef HAVE_NETINET_TCP_TIMER_H
 620      #include <netinet/tcp_timer.h>
 621      #endif])
 622
 623 AC_CHECK_HEADERS([linux/ipx.h linux/irda.h],,,
 624     [#include <sys/types.h>
 625      #ifdef HAVE_ASM_TYPES_H
 626      # include <asm/types.h>
 627      #endif
 628      #ifdef HAVE_SYS_SOCKET_H
 629      # include <sys/socket.h>
 630      #endif
 631      #ifdef HAVE_LINUX_TYPES_H
 632      # include <linux/types.h>
 633      #endif])
 634
 635 AC_CHECK_HEADERS([mach-o/dyld_images.h],,,
 636     [#ifdef HAVE_STDBOOL_H
 637      # include <stdbool.h>
 638      #endif
 639      #ifdef HAVE_STDINT_H
 640      # include <stdint.h>
 641      #endif])
 642
 643 AC_CHECK_HEADERS([resolv.h],,,
 644     [#include <sys/types.h>
 645      #ifdef HAVE_SYS_SOCKET_H
 646      # include <sys/socket.h>
 647      #endif
 648      #ifdef HAVE_NETINET_IN_H
 649      # include <netinet/in.h>
 650      #endif
 651      #ifdef HAVE_ARPA_NAMESER_H
 652      # include <arpa/nameser.h>
 653      #endif])
 654
 655 AC_CHECK_HEADERS([ifaddrs.h],,,[#include <sys/types.h>])
 656
 657 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
 658
 659 AC_CHECK_HEADERS([sys/thr.h],,,
 660 [#include <sys/types.h>
 661 #ifdef HAVE_UCONTEXT_H
 662 #include <ucontext.h>
 663 #endif])
 664
 665 AC_CHECK_HEADERS([pthread_np.h],,,
 666 [#ifdef HAVE_PTHREAD_H
 667 #include <pthread.h>
 668 #endif])
 669
 670 AC_CHECK_HEADERS([linux/videodev.h linux/videodev2.h libv4l1.h],,,
 671 [#ifdef HAVE_SYS_TIME_H
 672 #include <sys/time.h>
 673 #endif
 674 #include <sys/types.h>
 675 #ifdef HAVE_ASM_TYPES_H
 676 #include <asm/types.h>
 677 #endif])
 678
 679 dnl Check for broken kernel header that doesn't define __user
 680 AC_CHECK_HEADERS([linux/capi.h],,,[#define __user])
 681
 682 dnl **** Check for working dll ****
 683
 684 AC_SUBST(DLLEXT,"")
 685 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
 686 AC_SUBST(LDSHARED,"")
 687 AC_SUBST(LDDLLFLAGS,"")
 688 AC_SUBST(LIBEXT,"so")
 689 AC_SUBST(IMPLIBEXT,"def")
 690 AC_SUBST(LDRPATH_INSTALL,"")
 691 AC_SUBST(LDRPATH_LOCAL,"")
 692 STATIC_IMPLIBEXT="def.a"
 693 WINE_PATH_SONAME_TOOLS
 694
 695 case $host_os in
 696   cygwin*|mingw32*)
 697     AC_CHECK_TOOL(DLLTOOL,dlltool,false)
 698     AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
 699     if test "$DLLWRAP" = "false"; then
 700       LIBEXT="a"
 701     else
 702       dnl FIXME - check whether dllwrap works correctly...
 703       LIBEXT="dll"
 704     fi
 705     IMPLIBEXT="a"
 706     STATIC_IMPLIBEXT="a"
 707     dnl Disable modules that can't be used on Windows
 708     enable_iphlpapi=${enable_iphlpapi:-no}
 709     enable_kernel32=${enable_kernel32:-no}
 710     enable_msvcrt=${enable_msvcrt:-no}
 711     enable_ntdll=${enable_ntdll:-no}
 712     enable_ws2_32=${enable_ws2_32:-no}
 713     enable_loader=${enable_loader:-no}
 714     enable_server=${enable_server:-no}
 715     dnl Disable dependencies that are not useful on Windows
 716     with_x=${with_x:-no}
 717     with_pthread=${with_pthread:-no}
 718     ;;
 719   darwin*|macosx*)
 720     DLLEXT=".so"
 721     LIBEXT="dylib"
 722     DLLFLAGS="$DLLFLAGS -fPIC"
 723     LDDLLFLAGS="-bundle -multiply_defined suppress"
 724     LIBWINE_LDFLAGS="-multiply_defined suppress"
 725     LDSHARED="\$(CC) -dynamiclib"
 726     LDRPATH_INSTALL="-Wl,-rpath,@loader_path/\`\$(RELPATH) \$(bindir) \$(libdir)\`"
 727     LDRPATH_LOCAL="-Wl,-rpath,@loader_path/\$(top_builddir)/libs/wine"
 728     dnl declare needed frameworks
 729     AC_SUBST(COREFOUNDATIONLIB,"-framework CoreFoundation")
 730     AC_SUBST(IOKITLIB,"-framework IOKit -framework CoreFoundation")
 731     AC_SUBST(APPLICATIONSERVICESLIB,"-framework ApplicationServices")
 732     AC_SUBST(CORESERVICESLIB,"-framework CoreServices")
 733     case $host_os in
 734       darwin11*)
 735         AC_SUBST(LDEXECFLAGS,["-image_base 0x7bf00000 -Wl,-macosx_version_min,10.6,-segaddr,WINE_DOS,0x00001000,-segaddr,WINE_SHAREDHEAP,0x7f000000,-sectcreate,__TEXT,__info_plist,wine_info.plist"]) ;;
 736       *)
 737         AC_SUBST(LDEXECFLAGS,["-image_base 0x7bf00000 -Wl,-segaddr,WINE_DOS,0x00001000,-segaddr,WINE_SHAREDHEAP,0x7f000000,-sectcreate,__TEXT,__info_plist,wine_info.plist"]) ;;
 738     esac
 739     if test "$ac_cv_header_DiskArbitration_DiskArbitration_h" = "yes"
 740     then
 741         dnl DiskArbitration API is not public on Darwin < 8.0, use it only if header found
 742         AC_SUBST(DISKARBITRATIONLIB,"-framework DiskArbitration -framework CoreFoundation")
 743     fi
 744     if test "$ac_cv_header_Security_Security_h" = "yes"
 745     then
 746         AC_SUBST(SECURITYLIB,"-framework Security -framework CoreFoundation")
 747         dnl Check for the SSLCopyPeerCertificates function
 748         ac_save_LIBS="$LIBS"
 749         LIBS="$LIBS $SECURITYLIB"
 750         AC_CHECK_FUNCS(SSLCopyPeerCertificates)
 751         LIBS="$ac_save_LIBS"
 752         with_gnutls=${with_gnutls:-no}
 753     fi
 754     if test "$ac_cv_header_CoreAudio_CoreAudio_h" = "yes" -a "$ac_cv_header_AudioUnit_AudioUnit_h" = "yes"
 755     then
 756         if test "$ac_cv_header_AudioUnit_AudioComponent_h" = "yes"
 757         then
 758             AC_SUBST(COREAUDIO,"-framework CoreFoundation -framework CoreAudio -framework AudioUnit -framework AudioToolbox -framework CoreMIDI")
 759         else
 760             dnl CoreServices needed by AudioUnit
 761             AC_SUBST(COREAUDIO,"-framework CoreAudio -framework AudioUnit -framework CoreServices -framework AudioToolbox -framework CoreMIDI")
 762         fi
 763         dnl Check for the AUGraphAddNode function
 764         ac_save_LIBS="$LIBS"
 765         LIBS="$LIBS $COREAUDIO"
 766         AC_CHECK_FUNCS(AUGraphAddNode)
 767         LIBS="$ac_save_LIBS"
 768     fi
 769     if test "$ac_cv_header_OpenAL_al_h" = "yes"
 770     then
 771         AC_SUBST(FRAMEWORK_OPENAL,"-framework OpenAL")
 772         AC_DEFINE_UNQUOTED(HAVE_OPENAL,1,[Define to 1 if OpenAL is available])
 773         ac_cv_lib_openal=yes
 774     fi
 775     if test "$ac_cv_header_OpenCL_opencl_h" = "yes"
 776     then
 777         AC_SUBST(LIBOPENCL,"-framework OpenCL")
 778         ac_cv_lib_OpenCL_clGetPlatformInfo=yes
 779     fi
 780     if test "$ac_cv_header_IOKit_hid_IOHIDLib_h" = "yes"
 781     then
 782         ac_save_LIBS="$LIBS"
 783         LIBS="$LIBS $IOKITLIB"
 784         AC_CHECK_FUNCS(IOHIDManagerCreate)
 785         LIBS="$ac_save_LIBS"
 786     fi
 787     case $host_cpu in
 788       *powerpc*)
 789         LDDLLFLAGS="$LDDLLFLAGS -read_only_relocs warning"  dnl FIXME
 790         ;;
 791     esac
 792     if test "$ac_cv_header_QuickTime_ImageCompression_h" = "yes"
 793     then
 794         AC_SUBST(QUICKTIMELIB,"-framework QuickTime -framework ApplicationServices -framework CoreVideo")
 795         enable_wineqtdecoder=${enable_wineqtdecoder:-yes}
 796     else
 797         WINE_NOTICE([QuickTime ${notice_platform}development files not found, video decoding won't be supported.])
 798     fi
 799     if test "$ac_cv_header_Carbon_Carbon_h" = "yes"
 800     then
 801         AC_SUBST(CARBONLIB,"-framework Carbon")
 802     fi
 803
 804     dnl Enable Mac driver on Mac OS X 10.6 or later
 805     if test "$ac_cv_header_ApplicationServices_ApplicationServices_h" = "yes"
 806     then
 807         ac_save_LIBS="$LIBS"
 808         LIBS="$LIBS $APPLICATIONSERVICESLIB"
 809         AC_CHECK_FUNC(CGDisplayModeGetWidth,enable_winemac_drv=${enable_winemac_drv:-yes})
 810         LIBS="$ac_save_LIBS"
 811     fi
 812
 813     dnl Check for Xcode 3.x broken 16-bit support
 814     if test "x$enable_win16" = "xyes"
 815     then
 816         AC_MSG_CHECKING([whether 16-bit code can be built correctly])
 817         AC_RUN_IFELSE([AC_LANG_PROGRAM([[asm(".text\n"
 818                                             "bad:\tnop;nop\n"
 819                                             "good:\tnop;nop\n\t"
 820                                             ".globl _testfunc\n"
 821                                             "_testfunc:\tcallw good");
 822                                         extern void testfunc();]],
 823                                       [[unsigned short *p = (unsigned short *)testfunc;
 824                                         return p[0] != 0xe866 || p[1] != 0xfffa]])],
 825                                       AC_MSG_RESULT(yes),
 826                                       [AC_MSG_RESULT(no)
 827                                        AC_MSG_ERROR([Xcode 3.x cannot build 16-bit code correctly. Use --disable-win16 if you don't need 16-bit support.])],
 828                                        AC_MSG_RESULT([[cross-compiling, assuming yes]]))
 829     fi
 830     ;;
 831   *)
 832     DLLFLAGS="$DLLFLAGS -fPIC"
 833     DLLEXT=".so"
 834     AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
 835         [WINE_TRY_SHLIB_FLAGS([-fPIC -shared -Wl,-Bsymbolic],
 836                               ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
 837     if test "$ac_cv_c_dll_gnuelf" = "yes"
 838     then
 839       LDSHARED="\$(CC) -shared"
 840       LDDLLFLAGS="-shared -Wl,-Bsymbolic"
 841       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-soname,confest.so.1],
 842                       [LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"],
 843                       [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-h,confest.so.1],
 844                                        [LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-h,%)"])])
 845
 846       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs], [LDDLLFLAGS="$LDDLLFLAGS,-z,defs"])
 847
 848       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-init,__wine_spec_init,-fini,__wine_spec_fini],
 849                       [LDDLLFLAGS="$LDDLLFLAGS,-init,__wine_spec_init,-fini,__wine_spec_fini"])
 850
 851       echo '{ global: *; };' >conftest.map
 852       WINE_TRY_CFLAGS([-fPIC -shared -Wl,--version-script=conftest.map],
 853                       [LDSHARED="$LDSHARED \$(VERSCRIPT:%=-Wl,--version-script=%)"])
 854       rm -f conftest.map
 855
 856       WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
 857                       [AC_SUBST(LDEXECFLAGS,["-Wl,--export-dynamic"])])
 858
 859       WINE_TRY_CFLAGS([-fPIC -Wl,--rpath,\$ORIGIN/../lib],
 860                       [LDRPATH_INSTALL="-Wl,--rpath,\\\$\$ORIGIN/\`\$(RELPATH) \$(bindir) \$(libdir)\`"
 861                        LDRPATH_LOCAL="-Wl,--rpath,\\\$\$ORIGIN/\$(top_builddir)/libs/wine"],
 862           [WINE_TRY_CFLAGS([-fPIC -Wl,-R,\$ORIGIN/../lib],
 863                            [LDRPATH_INSTALL="-Wl,-R,\\\$\$ORIGIN/\`\$(RELPATH) \$(bindir) \$(libdir)\`"
 864                             LDRPATH_LOCAL="-Wl,-R,\\\$\$ORIGIN/\$(top_builddir)/libs/wine"])])
 865
 866       WINE_TRY_CFLAGS([-Wl,--enable-new-dtags],
 867                       [LDRPATH_INSTALL="$LDRPATH_INSTALL -Wl,--enable-new-dtags"])
 868
 869       case $host_cpu in
 870         *i[[3456789]]86* | x86_64)
 871           WINE_TRY_CFLAGS([-Wl,--section-start,.interp=0x7bf00400],
 872                           [case $host_os in
 873                            freebsd* | kfreebsd*-gnu) LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x60000400" ;;
 874                            *) LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x7bf00400" ;;
 875                            esac
 876                           ])
 877           AC_PATH_PROG(PRELINK, prelink, false, [/sbin /usr/sbin $PATH])
 878           if test "x$PRELINK" = xfalse
 879           then
 880               WINE_WARNING([prelink not found, base address of core dlls won't be set correctly.])
 881           fi
 882           ;;
 883       esac
 884
 885     else
 886       AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
 887           [WINE_TRY_SHLIB_FLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
 888                                 ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
 889       if test "$ac_cv_c_dll_unixware" = "yes"
 890       then
 891         LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
 892         LDDLLFLAGS="-Wl,-G,-B,symbolic"
 893
 894       else
 895         AC_CACHE_CHECK(whether we can build an HP-UX dll, ac_cv_c_dll_hpux,
 896           [WINE_TRY_SHLIB_FLAGS([-shared], ac_cv_c_dll_hpux="yes", ac_cv_c_dll_hpux="no")])
 897         if test "$ac_cv_c_dll_hpux" = "yes"
 898         then
 899           LIBEXT="sl"
 900           DLLEXT=".sl"
 901           LDDLLFLAGS="-shared -fPIC"
 902           LDSHARED="\$(CC) -shared"
 903         fi
 904       fi
 905     fi
 906     ;;
 907 esac
 908
 909 enable_wineqtdecoder=${enable_wineqtdecoder:-no}
 910 enable_winemac_drv=${enable_winemac_drv:-no}
 911
 912 if test "$LIBEXT" = "a"; then
 913   AC_MSG_ERROR(
 914 [could not find a way to build shared libraries.
 915 It is currently not possible to build Wine without shared library
 916 (.so) support to allow transparent switch between .so and .dll files.
 917 If you are using Linux, you will need a newer binutils.]
 918 )
 919 fi
 920
 921 dnl Check for cross compiler to build test programs
 922 AC_SUBST([CROSSTEST_DISABLE],[\#])
 923 if test "$cross_compiling" = "no" -a "x$enable_tests" != xno -a "$LIBEXT" != "dll"
 924 then
 925     WINE_CHECK_MINGW_PROG(CROSSCC,gcc,false)
 926     if test "$CROSSCC" != "false"
 927     then
 928         ac_save_CC="$CC"
 929         CC="$CROSSCC"
 930         AC_MSG_CHECKING([whether $CROSSCC works])
 931         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([])],
 932                           [AC_MSG_RESULT([yes])
 933                            set x $CROSSCC
 934                            shift
 935                            target=""
 936                            while test $# -ge 1
 937                            do
 938                                case "$1" in
 939                                  *-gcc) target=`expr "$1" : '\(.*\)-gcc'` ;;
 940                                esac
 941                                shift
 942                            done
 943                            if test -n "$target"
 944                            then
 945                                CROSSTEST_DISABLE=""
 946                                AC_SUBST(CROSSTARGET,"$target")
 947                            fi],
 948                           [AC_MSG_RESULT([no])])
 949         CC="$ac_save_CC"
 950     fi
 951 fi
 952
 953 dnl **** Check for pthread ****
 954
 955 if test "$ac_cv_header_pthread_h" = "yes"
 956 then
 957     AC_CHECK_FUNC(pthread_create,,[AC_CHECK_LIB(pthread,pthread_create,[AC_SUBST(LIBPTHREAD,"-lpthread")])])
 958 fi
 959 WINE_ERROR_WITH(pthread,[test "x$ac_cv_func_pthread_create" != xyes -a "x$LIBPTHREAD" = x],
 960 [pthread ${notice_platform}development files not found.
 961 Wine cannot support threads without libpthread.])
 962
 963 dnl **** Check for X11 ****
 964
 965 AC_PATH_XTRA
 966
 967 if test "$have_x" = "yes"
 968 then
 969     XLIB="-lX11"
 970     ac_save_CPPFLAGS="$CPPFLAGS"
 971     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 972
 973     WINE_CHECK_SONAME(X11,XCreateWindow,,,[$X_LIBS $X_EXTRA_LIBS])
 974     WINE_CHECK_SONAME(Xext,XextCreateExtension,[XLIB="-lXext $XLIB"],,[$X_LIBS -lX11 $X_EXTRA_LIBS])
 975
 976     dnl *** All of the following tests require X11/Xlib.h
 977     AC_CHECK_HEADERS([X11/Xlib.h \
 978                       X11/XKBlib.h \
 979                       X11/Xutil.h \
 980                       X11/Xcursor/Xcursor.h \
 981                       X11/extensions/shape.h \
 982                       X11/extensions/XInput.h \
 983                       X11/extensions/XInput2.h \
 984                       X11/extensions/XShm.h \
 985                       X11/extensions/Xcomposite.h \
 986                       X11/extensions/Xinerama.h \
 987                       X11/extensions/Xrandr.h \
 988                       X11/extensions/Xrender.h \
 989                       X11/extensions/xf86vmode.h \
 990                       X11/extensions/xf86vmproto.h],,,
 991 [#ifdef HAVE_X11_XLIB_H
 992 # include <X11/Xlib.h>
 993 #endif
 994 #ifdef HAVE_X11_XUTIL_H
 995 # include <X11/Xutil.h>
 996 #endif])
 997
 998         dnl *** Check for X keyboard extension
 999         if test "$ac_cv_header_X11_XKBlib_h" = "yes"
1000         then
1001               AC_CHECK_LIB(X11, XkbQueryExtension,
1002               AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
1003               $X_LIBS $XLIB $X_EXTRA_LIBS)
1004         fi
1005
1006         dnl *** Check for X cursor
1007         if test "$ac_cv_header_X11_Xcursor_Xcursor_h" = "yes"
1008         then
1009             WINE_CHECK_SONAME(Xcursor,XcursorImageLoadCursor,,,[$X_LIBS $XLIB $X_EXTRA_LIBS])
1010         fi
1011         WINE_NOTICE_WITH(xcursor,[test "x$ac_cv_lib_soname_Xcursor" = "x"],
1012                          [libxcursor ${notice_platform}development files not found, the Xcursor extension won't be supported.])
1013
1014         dnl *** Check for X input extension
1015         if test "$ac_cv_header_X11_extensions_XInput_h" = "yes"
1016         then
1017             WINE_CHECK_SONAME(Xi,XOpenDevice,,,[$X_LIBS $XLIB $X_EXTRA_LIBS])
1018         fi
1019         WINE_NOTICE_WITH(xinput,[test "x$ac_cv_lib_soname_Xi" = "x"],
1020                          [libxi ${notice_platform}development files not found, the Xinput extension won't be supported.])
1021
1022         dnl *** Check for X input 2 extension
1023         if test "x$ac_cv_lib_soname_Xi" != x
1024         then
1025             WINE_NOTICE_WITH(xinput2,[test "$ac_cv_header_X11_extensions_XInput2_h" != "yes"],
1026                              [XInput2 headers not found, the XInput 2 extension won't be supported.])
1027         fi
1028
1029         dnl *** Check for X Shm extension
1030         if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
1031         then
1032               AC_CHECK_LIB(Xext, XShmQueryExtension,
1033               AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
1034               $X_LIBS $XLIB $X_EXTRA_LIBS)
1035         fi
1036         WINE_NOTICE_WITH(xshm,[test "$ac_cv_lib_Xext_XShmQueryExtension" != "yes"],
1037                          [XShm ${notice_platform}development files not found, X Shared Memory won't be supported.])
1038
1039         dnl *** Check for X shape extension
1040         if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
1041         then
1042               AC_CHECK_LIB(Xext,XShapeQueryExtension,
1043               AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
1044               $X_LIBS $XLIB $X_EXTRA_LIBS)
1045         fi
1046         WINE_NOTICE_WITH(xshape,[test "$ac_cv_lib_Xext_XShapeQueryExtension" != "yes"],
1047                          [XShape ${notice_platform}development files not found, XShape won't be supported.])
1048
1049         dnl *** Check for XFree86 VMODE extension
1050         if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes" -o "$ac_cv_header_X11_extensions_xf86vmproto_h" = "yes"
1051         then
1052             WINE_CHECK_SONAME(Xxf86vm,XF86VidModeQueryExtension,,,[$X_LIBS $XLIB $X_EXTRA_LIBS])
1053         fi
1054         WINE_NOTICE_WITH(xxf86vm,[test "x$ac_cv_lib_soname_Xxf86vm" = "x"],
1055                          [libXxf86vm ${notice_platform}development files not found, XFree86 Vidmode won't be supported.])
1056
1057         dnl *** Check for Transform functions in Xrender
1058         if test "$ac_cv_header_X11_extensions_Xrender_h" = "yes" -a "x$ac_cv_lib_soname_X11" != "x" -a "x$ac_cv_lib_soname_Xext" != "x"
1059         then
1060             WINE_CHECK_SONAME(Xrender,XRenderQueryExtension,
1061               [AC_CHECK_LIB(Xrender,XRenderSetPictureTransform,
1062                 [AC_DEFINE(HAVE_XRENDERSETPICTURETRANSFORM, 1,
1063                  [Define if Xrender has the XRenderSetPictureTransform function])],,[$X_LIBS $XLIB $X_EXTRA_LIBS])
1064                AC_CHECK_LIB(Xrender,XRenderCreateLinearGradient,
1065                 [AC_DEFINE(HAVE_XRENDERCREATELINEARGRADIENT, 1,
1066                  [Define if Xrender has the XRenderCreateLinearGradient function])],,[$X_LIBS $XLIB $X_EXTRA_LIBS])],,
1067               [$X_LIBS $XLIB $X_EXTRA_LIBS])
1068
1069         fi
1070         WINE_WARNING_WITH(xrender,[test "x$ac_cv_lib_soname_Xrender" = "x"],
1071                          [libxrender ${notice_platform}development files not found, XRender won't be supported.])
1072
1073         dnl *** Check for X RandR extension
1074         if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes" -a "x$ac_cv_lib_soname_Xrender" != "x"
1075         then
1076                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
1077 #include <X11/extensions/Xrandr.h>]], [[static typeof(XRRSetScreenConfigAndRate) * func; if (func) return 0;]])],
1078                   [WINE_CHECK_SONAME(Xrandr,XRRQueryExtension,
1079                     [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/extensions/Xrandr.h>]],
1080                         [[static typeof(XRRGetScreenResources) *f; if (f) return 0;]])],
1081                       [AC_DEFINE(HAVE_XRRGETSCREENRESOURCES, 1,
1082                         [Define if Xrandr has the XRRGetScreenResources function])])],,
1083                     [$X_LIBS $XLIB $X_EXTRA_LIBS])])
1084         fi
1085         WINE_NOTICE_WITH(xrandr,[test "x$ac_cv_lib_soname_Xrandr" = "x"],
1086                          [libxrandr ${notice_platform}development files not found, XRandr won't be supported.])
1087
1088         dnl *** Check for Xinerama extension
1089         if test "$ac_cv_header_X11_extensions_Xinerama_h" = "yes"
1090         then
1091                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
1092 #include <X11/extensions/Xinerama.h>]], [[static typeof(XineramaQueryScreens) * func; if (func) return 0;]])],
1093                   [WINE_CHECK_SONAME(Xinerama,XineramaQueryScreens,,,[$X_LIBS $XLIB $X_EXTRA_LIBS])])
1094         fi
1095         WINE_NOTICE_WITH(xinerama,[test "x$ac_cv_lib_soname_Xinerama" = "x"],
1096                          [libxinerama ${notice_platform}development files not found, multi-monitor setups won't be supported.])
1097
1098         dnl *** Check for X Composite extension
1099         if test "$ac_cv_header_X11_extensions_Xcomposite_h" = "yes"
1100         then
1101             WINE_CHECK_SONAME(Xcomposite,XCompositeRedirectWindow,,,[$X_LIBS $XLIB $X_EXTRA_LIBS])
1102         fi
1103         WINE_NOTICE_WITH(xcomposite,[test "x$ac_cv_lib_soname_Xcomposite" = "x"],
1104                          [libxcomposite ${notice_platform}development files not found, Xcomposite won't be supported.])
1105
1106         dnl *** Check for XICCallback struct
1107         AC_CHECK_MEMBERS([XICCallback.callback, XEvent.xcookie],,,
1108 [#ifdef HAVE_X11_XLIB_H
1109 #include <X11/Xlib.h>
1110 #endif])
1111
1112     dnl *** End of X11/Xlib.h check
1113
1114     dnl Check for the presence of OpenGL
1115     opengl_msg=""
1116     if test "x$with_opengl" != "xno"
1117     then
1118         WINE_CHECK_SONAME(GL,glXCreateContext,
1119                      [OPENGL_LIBS="-lGL"],
1120                      [WINE_CHECK_SONAME(GL,glXCreateContext,
1121                             [OPENGL_LIBS="-Xlinker -dylib_file -Xlinker /System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib:/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib -lGL"],
1122                             [if test -f /usr/X11R6/lib/libGL.a
1123                             then
1124                                 opengl_msg="/usr/X11R6/lib/libGL.a is present on your system.
1125 This probably prevents linking to OpenGL. Try deleting the file and restarting configure."
1126                             else
1127                                 opengl_msg="No OpenGL library found on this system."
1128                             fi],
1129                             $X_LIBS $XLIB -lm $X_EXTRA_LIBS -dylib_file /System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib:/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib)],
1130                      $X_LIBS $XLIB -lm $X_EXTRA_LIBS)
1131         if test "x$with_glu" != "xno"
1132         then
1133             AC_CHECK_LIB(GLU,gluLookAt,[:],,[$OPENGL_LIBS $X_LIBS $X_PRE_LIBS $XLIB -lm $X_EXTRA_LIBS])
1134             WINE_NOTICE_WITH(glu,[test "x$ac_cv_lib_GLU_gluLookAt" != xyes],
1135                              [libGLU ${notice_platform}development files not found, GLU won't be supported.])
1136         fi
1137
1138         if test "x$with_osmesa" != "xno"
1139         then
1140             WINE_CHECK_SONAME(OSMesa,glAccum,,,[$X_LIBS $X_PRE_LIBS $XLIB -lm $X_EXTRA_LIBS])
1141             WINE_NOTICE_WITH(osmesa,[test "x$ac_cv_lib_soname_OSMesa" = "x"],
1142                              [libOSMesa ${notice_platform}development files not found (or too old), OpenGL rendering in bitmaps won't be supported.])
1143         fi
1144     fi
1145     WINE_WARNING_WITH(opengl,[test -n "$opengl_msg"],[$opengl_msg
1146 OpenGL and Direct3D won't be supported.])
1147
1148     CPPFLAGS="$ac_save_CPPFLAGS"
1149 else
1150     XLIB=""
1151     X_CFLAGS=""
1152     X_LIBS=""
1153     enable_winex11_drv=${enable_winex11_drv:-no}
1154 fi
1155 WINE_ERROR_WITH(x,[test "x$XLIB" = "x"],[X ${notice_platform}development files not found. Wine will be built
1156 without X support, which probably isn't what you want. You will need
1157 to install ${notice_platform}development packages of Xlib/Xfree86 at the very least.])
1158
1159 test "x$ac_cv_lib_GLU_gluLookAt" != xyes && enable_glu32=${enable_glu32:-no}
1160
1161 dnl **** Check for OpenCL ****
1162 if test "$ac_cv_header_CL_cl_h" = "yes"
1163 then
1164     AC_CHECK_LIB(OpenCL,clGetPlatformInfo,[AC_SUBST(LIBOPENCL,["-lOpenCL"])])
1165 fi
1166 WINE_NOTICE_WITH(opencl,[test "x$ac_cv_lib_OpenCL_clGetPlatformInfo" != xyes],
1167                  [OpenCL ${notice_platform}development files not found, OpenCL won't be supported.])
1168 test "x$ac_cv_lib_OpenCL_clGetPlatformInfo" != xyes && enable_opencl=${enable_opencl:-no}
1169
1170 dnl **** Check for libxml2 ****
1171
1172 AC_SUBST(XML2LIBS,"")
1173 AC_SUBST(XML2INCL,"")
1174 AC_SUBST(XSLTINCL,"")
1175 if test "x$with_xml" != "xno"
1176 then
1177     ac_save_CPPFLAGS="$CPPFLAGS"
1178     if test "$PKG_CONFIG" != "false"
1179     then
1180         ac_xml_libs="`$PKG_CONFIG --libs libxml-2.0 2>/dev/null`"
1181         ac_xml_cflags="`$PKG_CONFIG --cflags libxml-2.0 2>/dev/null`"
1182     else
1183         ac_xml_libs="`xml2-config --libs 2>/dev/null`"
1184         ac_xml_cflags="`xml2-config --cflags  2>/dev/null`"
1185     fi
1186     CPPFLAGS="$CPPFLAGS $ac_xml_cflags"
1187     AC_CHECK_HEADERS([libxml/parser.h libxml/xmlsave.h libxml/SAX2.h])
1188     if test "$ac_cv_header_libxml_parser_h" = "yes" -a "$ac_cv_header_libxml_xmlsave_h" = "yes" -a "$ac_cv_header_libxml_SAX2_h" = "yes"
1189     then
1190         AC_CHECK_LIB(xml2, xmlParseMemory,
1191             [AC_DEFINE(HAVE_LIBXML2, 1, [Define if you have the libxml2 library])
1192              XML2LIBS="$ac_xml_libs"
1193              XML2INCL="$ac_xml_cflags"],,$ac_xml_libs)
1194         AC_CHECK_LIB(xml2, xmlReadMemory,
1195             [AC_DEFINE(HAVE_XMLREADMEMORY,1,[Define if libxml2 has the xmlReadMemory function])],,$ac_xml_libs)
1196         AC_CHECK_LIB(xml2, xmlNewDocPI,
1197             [AC_DEFINE(HAVE_XMLNEWDOCPI,1,[Define if libxml2 has the xmlNewDocPI function])],,$ac_xml_libs)
1198         AC_CHECK_LIB(xml2, xmlSchemaSetParserStructuredErrors,
1199             [AC_DEFINE(HAVE_XMLSCHEMASSETPARSERSTRUCTUREDERRORS,1,[Define if libxml2 has the xmlSchemaSetParserStructuredErrors function])],,$ac_xml_libs)
1200         AC_CHECK_LIB(xml2, xmlSchemaSetValidStructuredErrors,
1201             [AC_DEFINE(HAVE_XMLSCHEMASSETVALIDSTRUCTUREDERRORS,1,[Define if libxml2 has the xmlSchemaSetValidStructuredErrors function])],,$ac_xml_libs)
1202         AC_CHECK_LIB(xml2, xmlFirstElementChild,
1203             [AC_DEFINE(HAVE_XMLFIRSTELEMENTCHILD,1,[Define if libxml2 has the xmlFirstElementChild function])],,$ac_xml_libs)
1204         AC_CHECK_TYPE([xmlDocProperties],
1205             [AC_DEFINE(HAVE_XMLDOC_PROPERTIES,1,[Define if libxml2 has the xmlDocProperties enum])],,[[#include <libxml/tree.h>]])
1206     fi
1207     CPPFLAGS="$ac_save_CPPFLAGS"
1208 fi
1209 WINE_WARNING_WITH(xml,[test "$ac_cv_lib_xml2_xmlParseMemory" != "yes"],
1210                  [libxml2 ${notice_platform}development files not found (or too old), XML won't be supported.])
1211
1212 if test "x$with_xslt" != "xno"
1213 then
1214     if test "$PKG_CONFIG" != "false"
1215     then
1216         ac_xslt_libs="`$PKG_CONFIG --libs libxslt 2>/dev/null`"
1217         ac_xslt_cflags="`$PKG_CONFIG --cflags libxslt 2>/dev/null`"
1218     else
1219         ac_xslt_libs="`xslt-config --libs 2>/dev/null`"
1220         ac_xslt_cflags="`xslt-config --cflags 2>/dev/null`"
1221     fi
1222     ac_save_CPPFLAGS="$CPPFLAGS"
1223     CPPFLAGS="$CPPFLAGS $ac_xslt_cflags"
1224     AC_CHECK_HEADERS([libxslt/pattern.h libxslt/transform.h],,,
1225     [#ifdef HAVE_LIBXSLT_PATTERN_H
1226 # include <libxslt/pattern.h>
1227 #endif])
1228     CPPFLAGS="$ac_save_CPPFLAGS"
1229     if test "$ac_cv_header_libxslt_transform_h" = "yes"
1230     then
1231         WINE_CHECK_SONAME(xslt,xsltCompilePattern,
1232                          [XSLTINCL="$ac_xslt_cflags"],,[$ac_xslt_libs])
1233     fi
1234 fi
1235 WINE_WARNING_WITH(xslt,[test "x$ac_cv_lib_soname_xslt" = "x"],
1236                  [libxslt ${notice_platform}development files not found, xslt won't be supported.])
1237
1238 dnl **** Check for libdbus ****
1239 if test "x$with_dbus" != "xno"
1240 then
1241     ac_save_CPPFLAGS="$CPPFLAGS"
1242     if test "$PKG_CONFIG" != "false"
1243     then
1244         ac_dbus_libs="`$PKG_CONFIG --libs dbus-1 2>/dev/null`"
1245         ac_dbus_cflags="`$PKG_CONFIG --cflags dbus-1 2>/dev/null`"
1246         CPPFLAGS="$CPPFLAGS $ac_dbus_cflags"
1247     fi
1248     AC_CHECK_HEADER([dbus/dbus.h],
1249         [WINE_CHECK_SONAME(dbus-1, dbus_connection_close,
1250             [AC_SUBST(DBUSINCL,"$ac_dbus_cflags")],,[$ac_dbus_libs])])
1251     CPPFLAGS="$ac_save_CPPFLAGS"
1252 fi
1253 WINE_NOTICE_WITH(dbus,[test "x$ac_cv_lib_soname_dbus_1" = "x" -a \
1254                             "x$ac_cv_header_DiskArbitration_DiskArbitration_h" != "xyes"],
1255                  [libdbus ${notice_platform}development files not found, no dynamic device support.])
1256
1257 dnl **** Check for libhal ****
1258 if test "x$with_hal" != "xno" -a "x$ac_cv_lib_soname_dbus_1" != x
1259 then
1260     ac_save_CPPFLAGS="$CPPFLAGS"
1261     if test "$PKG_CONFIG" != "false"
1262     then
1263         ac_hal_libs="`$PKG_CONFIG --libs hal 2>/dev/null`"
1264         ac_hal_cflags="`$PKG_CONFIG --cflags hal 2>/dev/null`"
1265         CPPFLAGS="$CPPFLAGS $ac_hal_cflags"
1266     fi
1267     AC_CHECK_HEADER([hal/libhal.h],
1268         [WINE_CHECK_SONAME(hal, libhal_ctx_new,
1269             [AC_SUBST(HALINCL,"$ac_hal_cflags")],,[$ac_hal_libs])])
1270     CPPFLAGS="$ac_save_CPPFLAGS"
1271     WINE_NOTICE_WITH(hal,[test "x$ac_cv_lib_soname_hal" = "x" -a \
1272                                "x$ac_cv_header_DiskArbitration_DiskArbitration_h" != "xyes"],
1273                      [libhal ${notice_platform}development files not found, no legacy dynamic device support.])
1274 fi
1275
1276 dnl **** Check for libgnutls ****
1277 if test "x$with_gnutls" != "xno"
1278 then
1279     ac_save_CPPFLAGS="$CPPFLAGS"
1280     if test "$PKG_CONFIG" != "false"
1281     then
1282         ac_gnutls_libs="`$PKG_CONFIG --libs gnutls 2>/dev/null`"
1283         ac_gnutls_cflags="`$PKG_CONFIG --cflags gnutls 2>/dev/null`"
1284         CPPFLAGS="$CPPFLAGS $ac_gnutls_cflags"
1285     fi
1286     AC_CHECK_HEADER(gnutls/gnutls.h,
1287         [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <gnutls/gnutls.h>]], [[static typeof(gnutls_mac_get_key_size) *func; if (func) return 0;]])],
1288             [WINE_CHECK_SONAME(gnutls,gnutls_global_init,
1289                 [AC_SUBST(GNUTLSINCL,"$ac_gnutls_cflags")],,[$ac_gnutls_libs])])])
1290     CPPFLAGS="$ac_save_CPPFLAGS"
1291 fi
1292 WINE_NOTICE_WITH(gnutls,[test "x$ac_cv_lib_soname_gnutls" = "x"],
1293                  [libgnutls ${notice_platform}development files not found, no schannel support.])
1294
1295 dnl **** Check which curses lib to use ***
1296 CURSESLIBS=""
1297 if test "$ac_cv_header_ncurses_h" = "yes"
1298 then
1299     WINE_CHECK_SONAME(ncurses,waddch,[CURSESLIBS="-lncurses"])
1300 elif test "$ac_cv_header_curses_h" = "yes"
1301 then
1302     WINE_CHECK_SONAME(curses,waddch,[CURSESLIBS="-lcurses"])
1303 fi
1304 ac_save_LIBS="$LIBS"
1305 LIBS="$LIBS $CURSESLIBS"
1306 AC_CHECK_FUNCS(mousemask)
1307 LIBS="$ac_save_LIBS"
1308 WINE_NOTICE_WITH(curses,[test "x$ac_cv_lib_soname_curses$ac_cv_lib_soname_ncurses" = "x"],
1309                  [lib(n)curses ${notice_platform}development files not found, curses won't be supported.])
1310
1311 dnl **** Check for SANE ****
1312 if test "x$with_sane" != "xno"
1313 then
1314     ac_save_CPPFLAGS="$CPPFLAGS"
1315     AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
1316     if test "$sane_devel" != "no"
1317     then
1318         ac_sane_incl="`$sane_devel --cflags`"
1319         ac_sane_libs="`$sane_devel --ldflags`"
1320         CPPFLAGS="$CPPFLAGS $ac_sane_incl"
1321     fi
1322     AC_CHECK_HEADER(sane/sane.h,
1323         [WINE_CHECK_SONAME(sane,sane_init,[AC_SUBST(SANEINCL,"$ac_sane_incl")],,[$ac_sane_libs])])
1324     CPPFLAGS="$ac_save_CPPFLAGS"
1325 fi
1326 WINE_NOTICE_WITH(sane,[test "x$ac_cv_lib_soname_sane" = "x"],
1327                  [libsane ${notice_platform}development files not found, scanners won't be supported.])
1328
1329 dnl **** Check for libv4l1 ****
1330 if test "x$with_v4l" != "xno"
1331 then
1332     WINE_CHECK_SONAME(v4l1,v4l1_open,,,)
1333 fi
1334 WINE_NOTICE_WITH(v4l,[test "x$ac_cv_lib_soname_v4l1" = "x"],
1335                  [libv4l ${notice_platform}development files not found.])
1336
1337 dnl **** Check for libgphoto2 ****
1338 if test "x$with_gphoto" != "xno"
1339 then
1340     ac_save_CPPFLAGS="$CPPFLAGS"
1341     AC_CHECK_PROG(gphoto2_devel,gphoto2-config,gphoto2-config,no)
1342     AC_CHECK_PROG(gphoto2port_devel,gphoto2-port-config,gphoto2-port-config,no)
1343     if test "$gphoto2_devel" != "no" -a "$gphoto2port_devel" != "no"
1344     then
1345         ac_gphoto2_incl="`$gphoto2_devel --cflags` `$gphoto2port_devel --cflags`"
1346         ac_gphoto2_libs=""
1347         for i in `$gphoto2_devel --libs` `$gphoto2port_devel --libs`
1348         do
1349             case "$i" in
1350             -L/usr/lib|-L/usr/lib64) ;;
1351             -L*|-l*) ac_gphoto2_libs="$ac_gphoto2_libs $i";;
1352             esac
1353         done
1354         CPPFLAGS="$CPPFLAGS $ac_gphoto2_incl"
1355     fi
1356     ac_gphoto2_libs=${ac_gphoto2_libs:-"-lgphoto2"}
1357     AC_CHECK_HEADER(gphoto2-camera.h,
1358                     [AC_CHECK_LIB(gphoto2,gp_camera_new,
1359                                   [AC_DEFINE(HAVE_GPHOTO2, 1, [Define if we have libgphoto2 development environment])
1360                                    AC_SUBST(GPHOTO2LIBS,"$ac_gphoto2_libs")
1361                                    AC_SUBST(GPHOTO2INCL,"$ac_gphoto2_incl")],,
1362                                   [$ac_gphoto2_libs])])
1363     CPPFLAGS="$ac_save_CPPFLAGS"
1364 fi
1365 WINE_NOTICE_WITH(gphoto,[test "$ac_cv_lib_gphoto2_gp_camera_new" != "yes"],
1366                  [libgphoto2 ${notice_platform}development files not found, digital cameras won't be supported.])
1367
1368
1369 dnl **** Check for resolver library ***
1370 if test "$ac_cv_header_resolv_h" = "yes"
1371 then
1372     ac_save_LIBS="$LIBS"
1373     for lib in '' -lresolv
1374     do
1375       LIBS="$lib $ac_save_LIBS"
1376       AC_LINK_IFELSE([AC_LANG_PROGRAM([[#ifdef HAVE_NETINET_IN_H
1377 #include <netinet/in.h>
1378 #endif
1379 #include <resolv.h>]],[[res_query("foo",ns_c_in,0,0,0);]])],
1380         [AC_DEFINE(HAVE_RESOLV, 1, [Define if you have the resolver library and header])
1381          AC_SUBST(RESOLVLIBS,"$lib")])
1382       if test "${RESOLVLIBS+set}" = set; then
1383         break
1384       fi
1385     done
1386     LIBS="$ac_save_LIBS"
1387 fi
1388
1389 dnl **** Check for LittleCMS ***
1390 AC_SUBST(LCMSLIBS,"")
1391 if test "$ac_cv_header_lcms_h" = "yes" -o "$ac_cv_header_lcms_lcms_h" = "yes"
1392 then
1393     AC_CHECK_LIB(lcms, cmsOpenProfileFromFile,
1394         [AC_DEFINE(HAVE_LCMS, 1, [Define if you have the LittleCMS development environment])
1395          LCMSLIBS="-llcms"])
1396 fi
1397 WINE_NOTICE_WITH(cms,[test "$ac_cv_lib_lcms_cmsOpenProfileFromFile" != "yes"],
1398                  [liblcms ${notice_platform}development files not found, Color Management won't be supported.])
1399
1400 dnl **** Check for FreeType 2 ****
1401 if test "x$with_freetype" != "xno"
1402 then
1403     if test "$PKG_CONFIG" != "false"
1404     then
1405         ac_freetype_incl="`$PKG_CONFIG --cflags freetype2 2>/dev/null`"
1406         ac_freetype_libs="`$PKG_CONFIG --libs freetype2 2>/dev/null`"
1407     else
1408         AC_CHECK_PROGS(ft_devel,[freetype-config freetype2-config],no)
1409         if test "$ft_devel" != "no"
1410         then
1411             ac_freetype_incl=`$ft_devel --cflags`
1412             ac_freetype_libs=`$ft_devel --libs`
1413         fi
1414     fi
1415     ac_freetype_libs=${ac_freetype_libs:-"-lfreetype"}
1416     WINE_CHECK_SONAME(freetype,FT_Init_FreeType,[ft_lib=yes],[ft_lib=no],[$ac_freetype_libs])
1417     if test "$ft_lib" = "yes"
1418     then
1419         ac_save_CPPFLAGS="$CPPFLAGS"
1420         CPPFLAGS="$ac_freetype_incl $CPPFLAGS"
1421         AC_CHECK_HEADERS(ft2build.h \
1422                          freetype/freetype.h \
1423                          freetype/ftglyph.h \
1424                          freetype/fttypes.h \
1425                          freetype/tttables.h \
1426                          freetype/ftsnames.h \
1427                          freetype/ttnameid.h \
1428                          freetype/ftoutln.h \
1429                          freetype/ftwinfnt.h \
1430                          freetype/ftmodapi.h \
1431                          freetype/ftlcdfil.h,,,
1432                          [#ifdef HAVE_FT2BUILD_H
1433                           # include <ft2build.h>
1434                           #endif])
1435         AC_PREPROC_IFELSE([AC_LANG_SOURCE([[#include <ft2build.h>
1436                     #include <freetype/fttrigon.h>]])],[AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
1437           [Define if you have the <freetype/fttrigon.h> header file.])
1438                     wine_cv_fttrigon=yes],[wine_cv_fttrigon=no])
1439         AC_CHECK_TYPES(FT_TrueTypeEngineType,,,[#include <freetype/ftmodapi.h>])
1440         dnl Check that we have at least freetype/freetype.h
1441         if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
1442         then
1443             AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
1444             AC_SUBST(FREETYPELIBS,"$ac_freetype_libs")
1445             AC_SUBST(FREETYPEINCL,"$ac_freetype_incl")
1446         fi
1447     fi
1448 fi
1449 WINE_ERROR_WITH(freetype,[test "x$FREETYPELIBS" = "x"],[FreeType ${notice_platform}development files not found. Fonts will not be built.])
1450 test "x$FREETYPELIBS" = "x" && enable_fonts=${enable_fonts:-no}
1451
1452 dnl **** Check for parport (currently Linux only) ****
1453 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
1454  AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef HAVE_SYS_IOCTL_H
1455 # include <sys/ioctl.h>
1456 #endif
1457 #include <linux/ppdev.h>]], [[ioctl (1,PPCLAIM,0)]])],
1458     [ac_cv_c_ppdev="yes"],[ac_cv_c_ppdev="no"]))
1459 if test "$ac_cv_c_ppdev" = "yes"
1460 then
1461     AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
1462 fi
1463
1464 dnl **** Check for pthread functions ****
1465 WINE_CHECK_LIB_FUNCS(\
1466         pthread_attr_get_np \
1467         pthread_getattr_np \
1468         pthread_getthreadid_np \
1469         pthread_get_stackaddr_np \
1470         pthread_get_stacksize_np,
1471         [$LIBPTHREAD])
1472
1473 dnl **** Check for zlib ****
1474 if test "$ac_cv_header_zlib_h" = "yes"
1475 then
1476     AC_CHECK_LIB(z,inflate,[AC_DEFINE(HAVE_ZLIB,1,[Define to 1 if you have the `z' library (-lz).])
1477                             AC_SUBST(ZLIB,"-lz")])
1478 fi
1479 WINE_NOTICE_WITH(zlib,[test "x$ZLIB" = "x"],[libz ${notice_platform}development files not found, data compression won't be supported.])
1480
1481 dnl **** Check for gettextpo ****
1482 if test "x$enable_tools" != xno
1483 then
1484     if test "$ac_cv_header_gettext_po_h" = "yes"
1485     then
1486         AC_CHECK_LIB(gettextpo,po_message_msgctxt,
1487                      [AC_DEFINE(HAVE_LIBGETTEXTPO,1,[Define to 1 if you have the `gettextpo' library (-lgettextpo).])
1488                       AC_SUBST(LIBGETTEXTPO,"-lgettextpo")])
1489     fi
1490     test "x$with_gettextpo" != xyes || WINE_NOTICE_WITH(gettextpo,[test "x$LIBGETTEXTPO" = "x"],
1491           [GetText ${notice_platform}development files not found (or too old), po files can't be rebuilt.])
1492 fi
1493
1494 dnl **** Check for gstreamer ****
1495 if test "x$with_gstreamer" != "xno"
1496 then
1497     ac_save_CPPFLAGS="$CPPFLAGS"
1498     if test "$PKG_CONFIG" != "false"; then
1499         ac_gst_incl=""
1500         for i in `$PKG_CONFIG --cflags gstreamer-app-0.10 2>/dev/null`
1501         do
1502             case "$i" in
1503                 -I*) ac_gst_incl="$ac_gst_incl $i";;
1504             esac
1505         done
1506         ac_gst_libs="`$PKG_CONFIG --libs gstreamer-app-0.10 2>/dev/null`"
1507         CPPFLAGS="$CPPFLAGS $ac_gst_incl"
1508         AC_CHECK_HEADER([gst/gstpad.h],
1509           [AC_CHECK_HEADER([gst/app/gstappsink.h],
1510              [AC_MSG_CHECKING([whether gint64 defined by gst/app/gstappsink.h is indeed 64-bit])
1511               AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <gst/app/gstappsink.h>]],
1512                                                  [[static int a[sizeof(gint64) > 4 ? 1 : -1]; if (a[0]) return 0;]])],
1513                 [AC_MSG_RESULT([yes])
1514                  AC_CHECK_LIB(gstreamer-0.10,gst_pad_get_caps_reffed,
1515                    [AC_CHECK_LIB(gstapp-0.10,gst_app_buffer_new,
1516                       [AC_SUBST(GSTREAMER_LIBS,"$ac_gst_libs")
1517                        AC_SUBST(GSTREAMER_INCL,"$ac_gst_incl")],,[$ac_gst_libs])])],
1518                 [AC_MSG_RESULT([no])])])])
1519     fi
1520     CPPFLAGS="$ac_save_CPPFLAGS"
1521 fi
1522 WINE_NOTICE_WITH(gstreamer,[test "x$ac_cv_lib_gstapp_0_10_gst_app_buffer_new" != xyes -a "x$ac_cv_header_QuickTime_ImageCompression_h" != xyes],
1523                  [gstreamer-0.10 base plugins ${notice_platform}development files not found, gstreamer support disabled])
1524 test "x$ac_cv_lib_gstapp_0_10_gst_app_buffer_new" = xyes || enable_winegstreamer=${enable_winegstreamer:-no}
1525
1526 dnl **** Check for ALSA 1.x ****
1527 AC_SUBST(ALSALIBS,"")
1528 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
1529 then
1530     AC_CHECK_LIB(asound,snd_pcm_hw_params_get_access_mask,
1531         [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef HAVE_ALSA_ASOUNDLIB_H
1532 #include <alsa/asoundlib.h>
1533 #elif defined(HAVE_SYS_ASOUNDLIB_H)
1534 #include <sys/asoundlib.h>
1535 #endif]], [[snd_pcm_hw_params_get_access_mask(NULL, NULL)]])],
1536                         [ALSALIBS="-lasound"])])
1537 fi
1538
1539 dnl **** Check for OSSv4 ****
1540 if test "x$with_oss" != xno
1541 then
1542     ac_save_CPPFLAGS="$CPPFLAGS"
1543     if test -f /etc/oss.conf
1544     then
1545         . /etc/oss.conf
1546     fi
1547     ac_oss_incl="-I${OSSLIBDIR:-/usr/lib/oss}/include"
1548     CPPFLAGS="$CPPFLAGS $ac_oss_incl"
1549     AC_CHECK_HEADER([sys/soundcard.h],
1550         [AC_CHECK_MEMBERS([oss_sysinfo.numaudioengines],
1551                           [AC_SUBST(OSS4INCL,"$ac_oss_incl")],,
1552                           [#include <sys/soundcard.h>])])
1553     CPPFLAGS="$ac_save_CPPFLAGS"
1554     if test "x$ac_cv_member_oss_sysinfo_numaudioengines" != xyes
1555     then
1556         WINE_NOTICE([OSS sound system found but too old (OSSv4 needed), OSS won't be supported.])
1557     fi
1558 fi
1559
1560 dnl **** Check for capi4linux ****
1561
1562 if test "$ac_cv_header_capi20_h" = "yes" -a "$ac_cv_header_linux_capi_h" = "yes"
1563 then
1564     WINE_CHECK_SONAME(capi20,capi20_register)
1565 fi
1566 WINE_NOTICE_WITH(capi,[test "x$ac_cv_lib_soname_capi20" = "x"],
1567                  [libcapi20 ${notice_platform}development files not found, ISDN won't be supported.])
1568
1569 dnl **** Check for cups ****
1570 AC_SUBST(CUPSINCL,"")
1571 if test "x$with_cups" != "xno"
1572 then
1573     ac_save_CPPFLAGS="$CPPFLAGS"
1574     ac_cups_cflags=`cups-config --cflags 2>/dev/null`
1575     ac_cups_libs=`cups-config --ldflags 2>/dev/null`
1576     CPPFLAGS="$CPPFLAGS $ac_cups_cflags"
1577     AC_CHECK_HEADERS(cups/cups.h,
1578             [WINE_CHECK_SONAME(cups,cupsGetDefault,
1579                        [CUPSINCL="$ac_cups_cflags"],,
1580                        [$ac_cups_libs])])
1581     CPPFLAGS="$ac_save_CPPFLAGS"
1582 fi
1583 WINE_NOTICE_WITH(cups,[test "x$ac_cv_lib_soname_cups" = "x"],
1584                  [libcups ${notice_platform}development files not found, CUPS won't be supported.])
1585
1586 dnl **** Check for fontconfig ****
1587 if test "$ac_cv_header_fontconfig_fontconfig_h" = "yes"
1588 then
1589     WINE_CHECK_SONAME(fontconfig,FcInit)
1590 elif test -n "$X_CFLAGS" -a "x$with_fontconfig" != "xno"
1591 then
1592     dnl fontconfig is in the X directory on Mac OS X
1593     ac_save_CPPFLAGS="$CPPFLAGS"
1594     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
1595     $as_unset ac_cv_header_fontconfig_fontconfig_h
1596     AC_CHECK_HEADERS([fontconfig/fontconfig.h])
1597     CPPFLAGS="$ac_save_CPPFLAGS"
1598     if test "$ac_cv_header_fontconfig_fontconfig_h" = "yes"
1599     then
1600         AC_SUBST(FONTCONFIGINCL,"$X_CFLAGS")
1601         WINE_CHECK_SONAME(fontconfig,FcInit,,,[$X_LIBS])
1602     fi
1603 fi
1604 WINE_NOTICE_WITH(fontconfig,[test "x$ac_cv_lib_soname_fontconfig" = "x"],
1605                  [fontconfig ${notice_platform}development files not found, fontconfig won't be supported.])
1606
1607 dnl **** Check for SSL ****
1608 if test "$ac_cv_header_openssl_err_h" = "yes" -a "$ac_cv_header_openssl_ssl_h" = "yes"
1609 then
1610     WINE_CHECK_SONAME(ssl,SSL_library_init)
1611     WINE_CHECK_SONAME(crypto,BIO_new_socket)
1612 fi
1613 WINE_WARNING_WITH(openssl,[test "x$ac_cv_lib_soname_ssl" = "x" -o "x$ac_cv_lib_soname_crypto" = "x"],
1614                  [OpenSSL ${notice_platform}development files not found, SSL won't be supported.])
1615
1616 dnl **** Check for gsm codec ****
1617 if test "$ac_cv_header_gsm_h" = "yes" -o "$ac_cv_header_gsm_gsm_h" = "yes"
1618 then
1619     WINE_CHECK_SONAME(gsm,gsm_create)
1620 fi
1621 WINE_NOTICE_WITH(gsm,[test "x$ac_cv_lib_soname_gsm" = "x"],
1622                  [libgsm ${notice_platform}development files not found, gsm 06.10 codec won't be supported.])
1623
1624 dnl **** Check for libjpeg ****
1625 if test "$ac_cv_header_jpeglib_h" = "yes"
1626 then
1627     WINE_CHECK_SONAME(jpeg,jpeg_start_decompress)
1628 fi
1629 WINE_WARNING_WITH(jpeg,[test "x$ac_cv_lib_soname_jpeg" = "x"],
1630                  [libjpeg ${notice_platform}development files not found, JPEG won't be supported.])
1631
1632 dnl **** Check for libpng ****
1633 if test "$ac_cv_header_png_h" = "yes"
1634 then
1635     WINE_CHECK_SONAME(png,png_create_read_struct,,,-lm -lz,[[libpng[[0-9]]*]])
1636     AC_CHECK_LIB(png,png_set_expand_gray_1_2_4_to_8,
1637         [AC_DEFINE(HAVE_PNG_SET_EXPAND_GRAY_1_2_4_TO_8,1,[Define to 1 if libpng has the png_set_expand_gray_1_2_4_to_8 function.])]
1638         ,,-lm -lz)
1639 elif test -n "$X_CFLAGS" -a "x$with_png" != "xno"
1640 then
1641     dnl libpng is in the X directory on Mac OS X
1642     ac_save_CPPFLAGS="$CPPFLAGS"
1643     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
1644     $as_unset ac_cv_header_png_h
1645     AC_CHECK_HEADERS([png.h])
1646     CPPFLAGS="$ac_save_CPPFLAGS"
1647     if test "$ac_cv_header_png_h" = "yes"
1648     then
1649         AC_SUBST(PNGINCL,"$X_CFLAGS")
1650         WINE_CHECK_SONAME(png,png_create_read_struct,,,[$X_LIBS -lm -lz],[[libpng[[0-9]]*]])
1651         AC_CHECK_LIB(png,png_set_expand_gray_1_2_4_to_8,
1652                 [AC_DEFINE(HAVE_PNG_SET_EXPAND_GRAY_1_2_4_TO_8,1)],,[$X_LIBS -lm -lz])
1653     fi
1654 fi
1655 WINE_WARNING_WITH(png,[test "x$ac_cv_lib_soname_png" = "x"],
1656                  [libpng ${notice_platform}development files not found, PNG won't be supported.])
1657
1658 dnl **** Check for libtiff ****
1659 if test "$ac_cv_header_tiffio_h" = "yes"
1660 then
1661     WINE_CHECK_SONAME(tiff,TIFFClientOpen)
1662 fi
1663 WINE_NOTICE_WITH(tiff,[test "x$ac_cv_lib_soname_tiff" = "x"],
1664                  [libtiff ${notice_platform}development files not found, TIFF won't be supported.])
1665
1666 dnl **** Check for mpg123 ****
1667 if test "$ac_cv_header_mpg123_h" = "yes"
1668 then
1669     AC_CHECK_LIB(mpg123,mpg123_feed,[AC_SUBST(LIBMPG123,"-lmpg123")])
1670 fi
1671 WINE_NOTICE_WITH(mpg123,[test "x$ac_cv_lib_mpg123_mpg123_feed" != xyes -a x"$ac_cv_header_CoreAudio_CoreAudio_h" != xyes],
1672                  [libmpg123 ${notice_platform}development files not found (or too old), mp3 codec won't be supported.])
1673 test "x$ac_cv_lib_mpg123_mpg123_feed" = xyes -o "x$ac_cv_header_AudioToolbox_AudioConverter_h" = xyes || enable_winemp3_acm=${enable_winemp3_acm:-no}
1674
1675 dnl **** Check for OpenAL 1.1 ****
1676 if test "$ac_cv_header_AL_al_h" = "yes"
1677 then
1678     WINE_CHECK_SONAME(openal,alGetSource3i,[AC_SUBST(LIBOPENAL,"-lopenal")
1679                       ac_cv_lib_openal=yes
1680                       AC_DEFINE_UNQUOTED(HAVE_OPENAL,1,[Define to 1 if OpenAL is available])],,)
1681 fi
1682 WINE_NOTICE_WITH(openal,[test "x$ac_cv_lib_openal" != xyes],
1683                  [libopenal ${notice_platform}development files not found (or too old), OpenAL won't be supported.])
1684 test "x$ac_cv_lib_openal" = xyes || enable_openal32=${enable_openal32:-no}
1685
1686 dnl **** Check for libkstat ****
1687 if test "$ac_cv_header_kstat_h" = "yes"
1688 then
1689     AC_CHECK_LIB(kstat,kstat_open,
1690                  [AC_DEFINE(HAVE_LIBKSTAT, 1, [Define to 1 if you have the `kstat' library (-lkstat).])
1691                   AC_SUBST(LIBKSTAT,"-lkstat")])
1692 fi
1693
1694 dnl **** Check for libodbc ****
1695 WINE_CHECK_SONAME(odbc,SQLConnect,,[AC_DEFINE_UNQUOTED(SONAME_LIBODBC,["libodbc.$LIBEXT"])])
1696
1697 dnl **** Disable unsupported winmm drivers ****
1698 test -n "$ALSALIBS" || enable_winealsa_drv=${enable_winealsa_drv:-no}
1699 test -n "$COREAUDIO" || enable_winecoreaudio_drv=${enable_winecoreaudio_drv:-no}
1700 test "x$ac_cv_member_oss_sysinfo_numaudioengines" = xyes || enable_wineoss_drv=${enable_wineoss_drv:-no}
1701 test "$ac_cv_header_linux_joystick_h" = "yes" || enable_winejoystick_drv=${enable_winejoystick_drv:-no}
1702
1703 dnl **** Check for any sound system ****
1704 if test "x$ALSALIBS$COREAUDIO" = "x" -a \
1705         "x$ac_cv_member_oss_sysinfo_numaudioengines" != xyes -a \
1706         "x$with_alsa$with_coreaudio$with_oss" != xnonono
1707 then
1708     WINE_WARNING([No sound system was found. Windows applications will be silent.])
1709 fi
1710
1711 dnl **** Check for gcc specific options ****
1712
1713 AC_SUBST(EXTRACFLAGS,"")
1714 if test "x${GCC}" = "xyes"
1715 then
1716   EXTRACFLAGS="-Wall -pipe"
1717
1718   dnl Check for strength-reduce bug
1719   AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
1720                   AC_RUN_IFELSE([AC_LANG_PROGRAM([[int L[[4]] = {0,1,2,3};]],
1721 [[static int Array[[3]];
1722   unsigned int B = 3;
1723   int i;
1724   for(i=0; i<B; i++) Array[[i]] = i - 3;
1725   for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
1726   L[[i]] = 4;
1727   return (Array[[1]] != -2 || L[[2]] != 3)]])],
1728     [ac_cv_c_gcc_strength_bug="no"],[ac_cv_c_gcc_strength_bug="yes"],[ac_cv_c_gcc_strength_bug="yes"]) )
1729   if test "$ac_cv_c_gcc_strength_bug" = "yes"
1730   then
1731     EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
1732   fi
1733
1734   dnl Check for some compiler flags
1735   WINE_TRY_CFLAGS([-fno-builtin],[AC_SUBST(BUILTINFLAG,"-fno-builtin")])
1736   WINE_TRY_CFLAGS([-fno-strict-aliasing])
1737   WINE_TRY_CFLAGS([-Wdeclaration-after-statement])
1738   WINE_TRY_CFLAGS([-Wempty-body])
1739   WINE_TRY_CFLAGS([-Wignored-qualifiers])
1740   WINE_TRY_CFLAGS([-Wstrict-prototypes])
1741   WINE_TRY_CFLAGS([-Wtype-limits])
1742   WINE_TRY_CFLAGS([-Wunused-but-set-parameter])
1743   WINE_TRY_CFLAGS([-Wwrite-strings])
1744
1745   dnl On Darwin, prefer stabs; everywhere else, default to dwarf-2 debug info
1746   for ac_flag in $CFLAGS; do
1747     case $ac_flag in
1748       -g) case $host_os in
1749             darwin*) WINE_TRY_CFLAGS([-gstabs+]) ;;
1750             *) WINE_TRY_CFLAGS([-gdwarf-2])
1751                WINE_TRY_CFLAGS([-gstrict-dwarf]) ;;
1752           esac ;;
1753     esac
1754   done
1755
1756   dnl gcc-4.6+ omits frame pointers by default, breaking some copy protections
1757   case $host_cpu in
1758     *i[[3456789]]86*) WINE_TRY_CFLAGS([-fno-omit-frame-pointer]) ;;
1759   esac
1760
1761   dnl mingw uses Windows 64-bit types, not Unix ones
1762   case $host in
1763     x86_64-*mingw32*|x86_64-*cygwin*) WINE_TRY_CFLAGS([-Wno-format]) ;;
1764   esac
1765
1766   dnl Check for noisy string.h
1767   saved_CFLAGS="$CFLAGS"
1768   CFLAGS="$CFLAGS -Wpointer-arith -Werror"
1769   AC_CACHE_CHECK([for broken string.h that generates warnings with -Wpointer-arith], ac_cv_c_string_h_warnings,
1770       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string.h>]], [[]])],[ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
1771   CFLAGS="$saved_CFLAGS"
1772   if test "$ac_cv_c_string_h_warnings" = "no"
1773   then
1774     EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
1775   fi
1776
1777   dnl Check for noisy string.h on logical ops
1778   saved_CFLAGS="$CFLAGS"
1779   CFLAGS="$CFLAGS -Wlogical-op -Werror"
1780   AC_CACHE_CHECK([for broken string.h that generates warnings with -Wlogical-op], ac_cv_c_logicalop_noisy,
1781       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string.h>]], [[char*f(const char *h,char n) {return strchr(h,n);}]])],[ac_cv_c_logicalop_noisy=no],[ac_cv_c_logicalop_noisy=yes]))
1782   CFLAGS="$saved_CFLAGS"
1783   if test "$ac_cv_c_logicalop_noisy" = "no"
1784   then
1785     EXTRACFLAGS="$EXTRACFLAGS -Wlogical-op"
1786   fi
1787
1788   dnl Enable -Werror for maintainer mode
1789   if test "x$enable_maintainer_mode" = "xyes"
1790   then
1791       WINE_TRY_CFLAGS([-Werror])
1792   fi
1793
1794   dnl Check for ms_hook_prologue support
1795   saved_CFLAGS="$CFLAGS"
1796   CFLAGS="$CFLAGS -Werror"
1797   AC_CACHE_CHECK([for ms_hook_prologue attribute], ac_cv_have_ms_hook_prologue,
1798                  AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[int __attribute__((__ms_hook_prologue__)) test(void) { return 0; }]])],
1799                                    [ac_cv_have_ms_hook_prologue="yes"],[ac_cv_have_ms_hook_prologue="no"]))
1800   CFLAGS="$saved_CFLAGS"
1801   if test "$ac_cv_have_ms_hook_prologue" = "yes"
1802   then
1803       AC_DEFINE(DECLSPEC_HOTPATCH, [__attribute__((__ms_hook_prologue__))],
1804                 [Define to a function attribute for Microsoft hotpatch assembly prefix.])
1805   else
1806       AC_DEFINE(DECLSPEC_HOTPATCH, [/* */])
1807   fi
1808 fi
1809
1810 dnl **** Disable Fortify, it has too many false positives
1811
1812 AC_CACHE_CHECK([for the need to disable Fortify], ac_cv_c_fortify_enabled,
1813     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string.h>]],
1814 [[#if defined(__USE_FORTIFY_LEVEL) && __USE_FORTIFY_LEVEL > 0
1815 #error Fortify enabled
1816 #endif]])],
1817         [ac_cv_c_fortify_enabled=no],[ac_cv_c_fortify_enabled=yes]))
1818 if test "$ac_cv_c_fortify_enabled" = yes
1819 then
1820     CFLAGS="$CFLAGS -U_FORTIFY_SOURCE -D_FORTIFY_SOURCE=0"
1821 fi
1822
1823 dnl **** Check for underscore on external symbols ****
1824
1825 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
1826     WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
1827                       [extern int ac_test;],
1828                       [if (ac_test) return 1],
1829                       ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
1830
1831 case $host_cpu in
1832   *i[[3456789]]86*)
1833     AC_CACHE_CHECK([whether external symbols need stdcall decoration], ac_cv_c_stdcall_suffix,
1834         WINE_TRY_ASM_LINK(["jmp _ac_test@4"],
1835 [#ifndef _MSC_VER
1836 #define __stdcall __attribute__((__stdcall__))
1837 #endif
1838 int __stdcall ac_test(int i) { return i; }],
1839                           [if (ac_test(1)) return 1],
1840                           ac_cv_c_stdcall_suffix="yes",ac_cv_c_stdcall_suffix="no")) ;;
1841   *) ac_cv_c_stdcall_suffix="no" ;;
1842 esac
1843
1844 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
1845 if test "$ac_cv_c_extern_prefix" = "yes"
1846 then
1847     AC_DEFINE([__ASM_NAME(name)], ["_" name])
1848     asm_name_prefix="_"
1849 else
1850     AC_DEFINE([__ASM_NAME(name)], [name])
1851     asm_name_prefix=""
1852 fi
1853
1854 AH_TEMPLATE(__ASM_STDCALL,[Define to a macro to generate an stdcall suffix])
1855 if test "$ac_cv_c_stdcall_suffix" = "yes"
1856 then
1857     AC_DEFINE([__ASM_STDCALL(args)],["@" #args])
1858 else
1859     AC_DEFINE([__ASM_STDCALL(args)],[""])
1860 fi
1861
1862 dnl **** Check how to define a function in assembly code ****
1863
1864 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
1865   WINE_TRY_ASM_LINK(
1866       ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
1867       ac_cv_asm_func_def=".def",
1868     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
1869       ac_cv_asm_func_def=".type @function",
1870     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
1871       ac_cv_asm_func_def=".type 2",
1872       ac_cv_asm_func_def="unknown")])]))
1873
1874 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
1875 case "$ac_cv_asm_func_def" in
1876   ".def")
1877      AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"])
1878      asm_func_header=".def $asm_name_prefix\" #name suffix \"; .scl 2; .type 32; .endef" ;;
1879   ".type @function")
1880      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"])
1881      asm_func_header=".type $asm_name_prefix\" #name suffix \",@function" ;;
1882   ".type 2")
1883      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"])
1884      asm_func_header=".type $asm_name_prefix\" #name suffix \",2" ;;
1885   *)
1886      AC_DEFINE([__ASM_FUNC(name)], [""])
1887      asm_func_header="" ;;
1888 esac
1889
1890 AC_CACHE_CHECK([whether asm() works outside of functions], ac_cv_c_asm_outside_funcs,
1891     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[asm(".text\n\t.long 0");]],)],
1892                       ac_cv_c_asm_outside_funcs="yes",ac_cv_c_asm_outside_funcs="no"))
1893
1894 AC_CACHE_CHECK([whether .previous is supported in assembly code], ac_cv_c_dot_previous,
1895     WINE_TRY_ASM_LINK([".text\nac_test:\t.long 0\n\t.previous"],,,
1896                       ac_cv_c_dot_previous="yes",ac_cv_c_dot_previous="no"))
1897
1898 AC_CACHE_CHECK([whether CFI directives are supported in assembly code], ac_cv_c_cfi_support,
1899     AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[asm(".text\nac_test:\t.cfi_startproc\n\t.long 0\n\t.cfi_endproc");]])],
1900                       ac_cv_c_cfi_support="yes",ac_cv_c_cfi_support="no"))
1901
1902 asm_func_header=".globl $asm_name_prefix\" #name suffix \"\\n\\t$asm_func_header\\n$asm_name_prefix\" #name suffix \":\\n\\t"
1903 asm_func_trailer=""
1904 if test "$ac_cv_c_dot_previous" = "yes"
1905 then
1906    asm_func_trailer="\\n\\t.previous"
1907 fi
1908 if test "$ac_cv_c_cfi_support" = "yes"
1909 then
1910    asm_func_header="$asm_func_header.cfi_startproc\\n\\t"
1911    asm_func_trailer="\\n\\t.cfi_endproc$asm_func_trailer"
1912    AC_DEFINE([__ASM_CFI(str)],[str],[Define to a macro to output a .cfi assembly pseudo-op])
1913    AC_SUBST([UNWINDFLAGS],[-fasynchronous-unwind-tables])
1914 else
1915    AC_DEFINE([__ASM_CFI(str)],[""])
1916 fi
1917
1918 asm_func_code="$asm_func_header\" code \"$asm_func_trailer"
1919
1920 AH_TEMPLATE(__ASM_DEFINE_FUNC,[Define to a macro to define an assembly function])
1921 if test "$ac_cv_c_asm_outside_funcs" = "yes"
1922 then
1923     AC_DEFINE_UNQUOTED([__ASM_DEFINE_FUNC(name,suffix,code)],[asm(".text\n\t.align 4\n\t$asm_func_code");])
1924 else
1925     AC_DEFINE_UNQUOTED([__ASM_DEFINE_FUNC(name,suffix,code)],[void __asm_dummy_##name(void) { asm(".text\n\t.align 4\n\t$asm_func_code"); }])
1926 fi
1927 AC_DEFINE([__ASM_GLOBAL_FUNC(name,code)],[__ASM_DEFINE_FUNC(name,"",code)],
1928           [Define to a macro to generate an assembly function with C calling convention])
1929 AC_DEFINE([__ASM_STDCALL_FUNC(name,args,code)],[__ASM_DEFINE_FUNC(name,__ASM_STDCALL(args),code)],
1930           [Define to a macro to generate an assembly function with stdcall calling convention])
1931
1932 dnl **** Platform-specific checks ****
1933
1934 AC_SUBST(LDPATH,"")
1935 case $build_os in
1936   cygwin*|mingw32*)
1937     AC_SUBST(TOOLSEXT,".exe")
1938     LDPATH="PATH=\"\$(TOOLSDIR)/libs/wine:\$\$PATH\""
1939     ;;
1940   darwin*|macosx*)
1941     ;;
1942   *)
1943     LDPATH="LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/wine:\$\$LD_LIBRARY_PATH\""
1944     ;;
1945 esac
1946
1947 dnl Mingw needs explicit msvcrt for linking libwine and winsock for wininet
1948 case $host_os in
1949   mingw32*)
1950     AC_SUBST(CRTLIBS,"-lmsvcrt")
1951     AC_SUBST(SOCKETLIBS,"-L\$(top_builddir)/dlls/ws2_32 -lws2_32")
1952     ;;
1953 esac
1954
1955 AC_SUBST(MAIN_BINARY,"wine")
1956 test "x$enable_win64" != "xyes" || MAIN_BINARY="wine64"
1957
1958 case $host_os in
1959   linux*)
1960     case $host_cpu in
1961       *i[[3456789]]86*) AC_SUBST(EXTRA_BINARIES,"wine-preloader") ;;
1962       x86_64*) AC_SUBST(EXTRA_BINARIES,"wine64-preloader") ;;
1963     esac
1964     ;;
1965 esac
1966
1967 dnl **** Check for functions ****
1968
1969 ac_save_CFLAGS="$CFLAGS"
1970 CFLAGS="$CFLAGS $BUILTINFLAG"
1971 AC_CHECK_FUNCS(\
1972         _finite \
1973         _isnan \
1974         _pclose \
1975         _popen \
1976         _snprintf \
1977         _spawnvp \
1978         _strdup \
1979         _stricmp \
1980         _strnicmp \
1981         _strtoi64 \
1982         _strtoui64 \
1983         _vsnprintf \
1984         asctime_r \
1985         chsize \
1986         dlopen \
1987         epoll_create \
1988         ffs \
1989         finite \
1990         fnmatch \
1991         fork \
1992         fpclass \
1993         fstatfs \
1994         fstatvfs \
1995         ftruncate \
1996         futimens \
1997         futimes \
1998         futimesat \
1999         getattrlist \
2000         getdirentries \
2001         getopt_long_only \
2002         getpwuid \
2003         gettimeofday \
2004         getuid \
2005         kqueue \
2006         lstat \
2007         memmove \
2008         mmap \
2009         pclose \
2010         pipe2 \
2011         poll \
2012         popen \
2013         port_create \
2014         prctl \
2015         pread \
2016         pwrite \
2017         readdir \
2018         readlink \
2019         sched_yield \
2020         select \
2021         setproctitle \
2022         setrlimit \
2023         settimeofday \
2024         sigaltstack \
2025         sigprocmask \
2026         snprintf \
2027         spawnvp \
2028         statfs \
2029         statvfs \
2030         strcasecmp \
2031         strdup \
2032         strerror \
2033         strncasecmp \
2034         strtold \
2035         strtoll \
2036         strtoull \
2037         symlink \
2038         tcgetattr \
2039         thr_kill2 \
2040         timegm \
2041         usleep \
2042         vsnprintf
2043 )
2044 CFLAGS="$ac_save_CFLAGS"
2045
2046 dnl Check for -ldl
2047 if test "$ac_cv_func_dlopen" = no
2048 then
2049     AC_CHECK_LIB(dl,dlopen,[AC_DEFINE(HAVE_DLOPEN,1) AC_SUBST(LIBDL,"-ldl")])
2050 fi
2051 WINE_CHECK_LIB_FUNCS(dladdr,[$LIBDL])
2052
2053 dnl Check for -lpoll for Mac OS X/Darwin
2054 if test "$ac_cv_func_poll" = no
2055 then
2056     AC_CHECK_LIB(poll,poll,[AC_DEFINE(HAVE_POLL,1) AC_SUBST(LIBPOLL,"-lpoll")])
2057 fi
2058
2059 dnl Check for -lnsl for Solaris
2060 AC_SEARCH_LIBS(gethostbyname, nsl)
2061
2062 dnl Check for -lsocket for Solaris
2063 AC_SEARCH_LIBS(connect, socket)
2064
2065 dnl Check for -lresolv for Solaris
2066 AC_SEARCH_LIBS(inet_aton, resolv)
2067
2068 dnl **** Check for functions which may rely on -lsocket on Solaris.
2069 AC_CHECK_FUNCS(\
2070         getaddrinfo \
2071         getnameinfo \
2072         getnetbyname \
2073         getprotobyname \
2074         getprotobynumber \
2075         getservbyport \
2076         inet_network \
2077         inet_ntop \
2078         inet_pton \
2079         sendmsg \
2080         socketpair \
2081 )
2082
2083 dnl **** Check for OpenLDAP ***
2084 AC_SUBST(LDAPLIBS,"")
2085 if test "$ac_cv_header_ldap_h" = "yes" -a "$ac_cv_header_lber_h" = "yes"
2086 then
2087     AC_CHECK_TYPE(LDAPSortKey,
2088         [AC_CHECK_LIB(ldap_r, ldap_initialize,
2089             [AC_CHECK_LIB(lber, ber_init,
2090                 [AC_DEFINE(HAVE_LDAP, 1, [Define if you have the OpenLDAP development environment])
2091                  LDAPLIBS="-lldap_r -llber"],,
2092                  [$LIBPTHREAD])],,
2093                  [$LIBPTHREAD])],,
2094         [#include <ldap.h>])
2095     WINE_CHECK_LIB_FUNCS(\
2096         ldap_count_references \
2097         ldap_first_reference \
2098         ldap_next_reference \
2099         ldap_parse_reference \
2100         ldap_parse_sort_control \
2101         ldap_parse_sortresponse_control \
2102         ldap_parse_vlv_control \
2103         ldap_parse_vlvresponse_control,
2104         [$LDAPLIBS $LIBPTHREAD])
2105 fi
2106 WINE_NOTICE_WITH(ldap,[test "x$LDAPLIBS" = "x"],
2107                  [libldap (OpenLDAP) ${notice_platform}development files not found, LDAP won't be supported.])
2108
2109 AC_CACHE_CHECK([whether mkdir takes only one argument],
2110         wine_cv_one_arg_mkdir,
2111         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <sys/stat.h>]],[[mkdir("foo");]])],
2112                           [wine_cv_one_arg_mkdir=yes],[wine_cv_one_arg_mkdir=no]))
2113 if test "$wine_cv_one_arg_mkdir" = "yes"
2114 then
2115   AC_DEFINE(HAVE_ONE_ARG_MKDIR, 1, [Define if mkdir takes only one argument])
2116 fi
2117
2118 AC_CACHE_CHECK([for sched_setaffinity],wine_cv_have_sched_setaffinity,
2119                 AC_LINK_IFELSE([AC_LANG_PROGRAM(
2120 [[#define _GNU_SOURCE
2121 #include <sched.h>]], [[sched_setaffinity(0, 0, 0);]])],[wine_cv_have_sched_setaffinity=yes],[wine_cv_have_sched_setaffinity=no]))
2122 if test "$wine_cv_have_sched_setaffinity" = "yes"
2123 then
2124   AC_DEFINE(HAVE_SCHED_SETAFFINITY, 1, [Define to 1 if you have the `sched_setaffinity' function.])
2125 fi
2126
2127 AC_CACHE_CHECK([for fallocate],wine_cv_have_fallocate,
2128                 AC_LINK_IFELSE([AC_LANG_PROGRAM(
2129 [[#define _GNU_SOURCE
2130 #include <fcntl.h>]], [[fallocate(-1, 0, 0, 0);]])],[wine_cv_have_fallocate=yes],[wine_cv_have_fallocate=no]))
2131 if test "$wine_cv_have_fallocate" = "yes"
2132 then
2133   AC_DEFINE(HAVE_FALLOCATE, 1, [Define to 1 if you have the `fallocate' function.])
2134 fi
2135
2136 dnl **** Check for types ****
2137
2138 AC_C_INLINE
2139 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t, long long, fsblkcnt_t, fsfilcnt_t])
2140 AC_CHECK_TYPES([sigset_t],,,[#include <sys/types.h>
2141 #include <signal.h>])
2142 AC_CHECK_TYPES([request_sense],,,[#include <linux/cdrom.h>])
2143
2144 AC_CHECK_TYPES([struct xinpgen],,,
2145 [#include <sys/types.h>
2146 #ifdef HAVE_SYS_SOCKET_H
2147 #include <sys/socket.h>
2148 #endif
2149 #ifdef HAVE_SYS_SOCKETVAR_H
2150 #include <sys/socketvar.h>
2151 #endif
2152 #ifdef HAVE_NET_ROUTE_H
2153 #include <net/route.h>
2154 #endif
2155 #ifdef HAVE_NETINET_IN_H
2156 #include <netinet/in.h>
2157 #endif
2158 #ifdef HAVE_NETINET_IN_SYSTM_H
2159 #include <netinet/in_systm.h>
2160 #endif
2161 #ifdef HAVE_NETINET_IP_H
2162 #include <netinet/ip.h>
2163 #endif
2164 #ifdef HAVE_NETINET_IN_PCB_H
2165 #include <netinet/in_pcb.h>
2166 #endif])
2167
2168 AC_CHECK_MEMBERS([struct ff_effect.direction],,,
2169 [#ifdef HAVE_LINUX_INPUT_H
2170 #include <linux/input.h>
2171 #endif])
2172
2173 AC_CACHE_CHECK([for sigaddset],wine_cv_have_sigaddset,
2174                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <signal.h>]], [[sigset_t set; sigaddset(&set,SIGTERM);]])],[wine_cv_have_sigaddset=yes],[wine_cv_have_sigaddset=no]))
2175 if test "$wine_cv_have_sigaddset" = "yes"
2176 then
2177   AC_DEFINE(HAVE_SIGADDSET, 1, [Define if sigaddset is supported])
2178 fi
2179
2180
2181 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
2182         wine_cv_linux_gethostbyname_r_6,
2183         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],[[
2184     char *name=0;
2185     struct hostent he;
2186     struct hostent *result;
2187     char *buf=0;
2188     int bufsize=0;
2189     int errnr;
2190     char *addr=0;
2191     int addrlen=0;
2192     int addrtype=0;
2193     gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
2194     gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
2195     ]])],[wine_cv_linux_gethostbyname_r_6=yes],[wine_cv_linux_gethostbyname_r_6=no
2196         ])
2197    )
2198    if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
2199    then
2200       AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
2201                 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
2202    fi
2203
2204 if test "$ac_cv_header_linux_joystick_h" = "yes"
2205 then
2206    AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
2207         wine_cv_linux_joystick_22_api,
2208         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
2209         #include <sys/ioctl.h>
2210         #include <sys/types.h>
2211         #include <linux/joystick.h>
2212
2213         struct js_event blub;
2214         #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
2215         #error "no 2.2 header"
2216         #endif
2217         ]], [[/*empty*/]])],[wine_cv_linux_joystick_22_api=yes],[wine_cv_linux_joystick_22_api=no])
2218    )
2219    if test "$wine_cv_linux_joystick_22_api" = "yes"
2220    then
2221       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
2222                 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
2223    fi
2224 fi
2225
2226 dnl **** FIXME: what about mixed cases, where we need two of them? ***
2227
2228 dnl Check for statfs members
2229 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail, struct statfs.f_frsize, struct statfs.f_ffree, struct statfs.f_favail, struct statfs.f_namelen],,,
2230 [#include <sys/types.h>
2231 #ifdef HAVE_SYS_PARAM_H
2232 # include <sys/param.h>
2233 #endif
2234 #ifdef HAVE_SYS_MOUNT_H
2235 # include <sys/mount.h>
2236 #endif
2237 #ifdef HAVE_SYS_VFS_H
2238 # include <sys/vfs.h>
2239 #endif
2240 #ifdef HAVE_SYS_STATFS_H
2241 # include <sys/statfs.h>
2242 #endif])
2243
2244 AC_CHECK_MEMBERS([struct statvfs.f_blocks],,,
2245 [#ifdef HAVE_SYS_STATVFS_H
2246 #include <sys/statvfs.h>
2247 #endif])
2248
2249 dnl Check for dirent.d_reclen
2250 AC_CHECK_MEMBERS([struct dirent.d_reclen],,,
2251 [#ifdef HAVE_DIRENT_H
2252 #include <dirent.h>
2253 #endif])
2254
2255 dnl Check for socket structure members
2256 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
2257 [#include <sys/types.h>
2258 #ifdef HAVE_SYS_SOCKET_H
2259 # include <sys/socket.h>
2260 #endif
2261 #ifdef HAVE_SYS_UN_H
2262 # include <sys/un.h>
2263 #endif])
2264
2265 dnl Check for scsireq_t and sg_io_hdr_t members
2266 AC_CHECK_MEMBERS([scsireq_t.cmd, sg_io_hdr_t.interface_id],,,
2267 [#include <sys/types.h>
2268 #ifdef HAVE_SCSI_SG_H
2269 #include <scsi/sg.h>
2270 #endif])
2271
2272 dnl Check for siginfo_t members
2273 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
2274
2275 dnl Check for struct mtget members
2276 AC_CHECK_MEMBERS([struct mtget.mt_blksiz, struct mtget.mt_gstat, struct mtget.mt_blkno],,,
2277 [#include <sys/types.h>
2278 #ifdef HAVE_SYS_MTIO_H
2279 #include <sys/mtio.h>
2280 #endif])
2281
2282 dnl Check for struct option
2283 AC_CHECK_MEMBERS([struct option.name],,,
2284 [#ifdef HAVE_GETOPT_H
2285 #include <getopt.h>
2286 #endif])
2287
2288 dnl Check for stat.st_blocks and ns-resolved times
2289 AC_CHECK_MEMBERS([
2290         struct stat.st_blocks,
2291         struct stat.st_mtim,
2292         struct stat.st_mtimespec,
2293         struct stat.st_ctim,
2294         struct stat.st_ctimespec,
2295         struct stat.st_atim,
2296         struct stat.st_atimespec,
2297         struct stat.st_birthtime,
2298         struct stat.st_birthtim,
2299         struct stat.st_birthtimespec,
2300         struct stat.__st_birthtime,
2301         struct stat.__st_birthtim])
2302
2303 dnl Check for sin6_scope_id
2304 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_scope_id],,,
2305 [#ifdef HAVE_SYS_TYPES_H
2306 #include <sys/types.h>
2307 #endif
2308 #ifdef HAVE_NETINET_IN_H
2309 #include <netinet/in.h>
2310 #endif])
2311
2312 dnl Check for ns_msg ptr member
2313 AC_CHECK_MEMBERS([ns_msg._msg_ptr],,,
2314 [#ifdef HAVE_SYS_TYPES_H
2315 #include <sys/types.h>
2316 #endif
2317 #ifdef HAVE_NETINET_IN_H
2318 # include <netinet/in.h>
2319 #endif
2320 #ifdef HAVE_ARPA_NAMESER_H
2321 # include <arpa/nameser.h>
2322 #endif])
2323
2324 dnl Check for struct icmpstat
2325 AC_CHECK_MEMBERS([struct icmpstat.icps_inhist],,,
2326 [#ifdef HAVE_SYS_TYPES_H
2327 #include <sys/types.h>
2328 #endif
2329 #ifdef HAVE_NETINET_IP_H
2330 #include <netinet/ip.h>
2331 #endif
2332 #ifdef HAVE_NETINET_IP_ICMP_H
2333 #include <netinet/ip_icmp.h>
2334 #endif
2335 #ifdef HAVE_NETINET_ICMP_VAR_H
2336 #include <netinet/icmp_var.h>
2337 #endif])
2338
2339 dnl Check for struct icmpstat.icps_outhist
2340 AC_CHECK_MEMBERS([struct icmpstat.icps_outhist],,,
2341 [#ifdef HAVE_SYS_TYPES_H
2342 #include <sys/types.h>
2343 #endif
2344 #ifdef HAVE_ALIAS_H
2345 #include <alias.h>
2346 #endif
2347 #ifdef HAVE_SYS_SOCKET_H
2348 #include <sys/socket.h>
2349 #endif
2350 #ifdef HAVE_SYS_SOCKETVAR_H
2351 #include <sys/socketvar.h>
2352 #endif
2353 #ifdef HAVE_SYS_TIMEOUT_H
2354 #include <sys/timeout.h>
2355 #endif
2356 #ifdef HAVE_NETINET_IN_H
2357 #include <netinet/in.h>
2358 #endif
2359 #ifdef HAVE_NETINET_IN_SYSTM_H
2360 #include <netinet/in_systm.h>
2361 #endif
2362 #ifdef HAVE_NETINET_IP_H
2363 #include <netinet/ip.h>
2364 #endif
2365 #ifdef HAVE_NETINET_IP_VAR_H
2366 #include <netinet/ip_var.h>
2367 #endif
2368 #ifdef HAVE_NETINET_IP_ICMP_H
2369 #include <netinet/ip_icmp.h>
2370 #endif
2371 #ifdef HAVE_NETINET_ICMP_VAR_H
2372 #include <netinet/icmp_var.h>
2373 #endif])
2374
2375 dnl Check for struct ipstat
2376 AC_CHECK_MEMBERS([struct ipstat.ips_total],,,
2377 [#ifdef HAVE_SYS_TYPES_H
2378 #include <sys/types.h>
2379 #endif
2380 #ifdef HAVE_SYS_SOCKETVAR_H
2381 #include <sys/socketvar.h>
2382 #endif
2383 #ifdef HAVE_NETINET_IN_H
2384 #include <netinet/in.h>
2385 #endif
2386 #ifdef HAVE_NETINET_IP_VAR_H
2387 #include <netinet/ip_var.h>
2388 #endif])
2389
2390 dnl Check for struct ip_stats
2391 AC_CHECK_MEMBERS([struct ip_stats.ips_total],,,
2392 [#ifdef HAVE_NETINET_IP_VAR_H
2393 #include <netinet/ip_var.h>
2394 #endif])
2395
2396 dnl Check for struct tcpstat
2397 AC_CHECK_MEMBERS([struct tcpstat.tcps_connattempt],,,
2398 [#ifdef HAVE_SYS_TYPES_H
2399 #include <sys/types.h>
2400 #endif
2401 #ifdef HAVE_SYS_SOCKETVAR_H
2402 #include <sys/socketvar.h>
2403 #endif
2404 #ifdef HAVE_NETINET_IN_H
2405 #include <netinet/in.h>
2406 #endif
2407 #ifdef HAVE_NETINET_TCP_H
2408 #include <netinet/tcp.h>
2409 #endif
2410 #ifdef HAVE_NETINET_TCP_VAR_H
2411 #include <netinet/tcp_var.h>
2412 #endif])
2413
2414 dnl Check for struct tcp_stats
2415 AC_CHECK_MEMBERS([struct tcp_stats.tcps_connattempt],,,
2416 [#ifdef HAVE_NETINET_TCP_VAR_H
2417 #include <netinet/tcp_var.h>
2418 #endif])
2419
2420 dnl Check for struct udpstat
2421 AC_CHECK_MEMBERS([struct udpstat.udps_ipackets],,,
2422 [#ifdef HAVE_SYS_TYPES_H
2423 #include <sys/types.h>
2424 #endif
2425 #ifdef HAVE_NETINET_IN_H
2426 #include <netinet/in.h>
2427 #endif
2428 #ifdef HAVE_NETINET_IP_VAR_H
2429 #include <netinet/ip_var.h>
2430 #endif
2431 #ifdef HAVE_NETINET_UDP_H
2432 #include <netinet/udp.h>
2433 #endif
2434 #ifdef HAVE_NETINET_UDP_VAR_H
2435 #include <netinet/udp_var.h>
2436 #endif])
2437
2438 dnl Check for struct ifreq.ifr_hwaddr
2439 AC_CHECK_MEMBERS([struct ifreq.ifr_hwaddr],,,
2440 [#ifdef HAVE_SYS_TYPES_H
2441 #include <sys/types.h>
2442 #endif
2443 #ifdef HAVE_NET_IF_H
2444 # include <net/if.h>
2445 #endif])
2446
2447 dnl Check for the external timezone variables timezone and daylight
2448 AC_CACHE_CHECK([for timezone variable], ac_cv_have_timezone,
2449                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[timezone = 1]])],[ac_cv_have_timezone="yes"],[ac_cv_have_timezone="no"]))
2450 if test "$ac_cv_have_timezone" = "yes"
2451 then
2452     AC_DEFINE(HAVE_TIMEZONE, 1, [Define if you have the timezone variable])
2453 fi
2454 AC_CACHE_CHECK([for daylight variable], ac_cv_have_daylight,
2455                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[daylight = 1]])],[ac_cv_have_daylight="yes"],[ac_cv_have_daylight="no"]))
2456 if test "$ac_cv_have_daylight" = "yes"
2457 then
2458     AC_DEFINE(HAVE_DAYLIGHT, 1, [Define if you have the daylight variable])
2459 fi
2460
2461 dnl Check for isinf
2462 ac_save_LIBS="$LIBS"
2463 LIBS="$LIBS -lm"
2464 AC_CACHE_CHECK([for isinf], ac_cv_have_isinf,
2465                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; return isinf(f)]])],[ac_cv_have_isinf="yes"],[ac_cv_have_isinf="no"]))
2466 if test "$ac_cv_have_isinf" = "yes"
2467 then
2468     AC_DEFINE(HAVE_ISINF, 1, [Define to 1 if you have the `isinf' function.])
2469 fi
2470
2471 dnl Check for isnan
2472 AC_CACHE_CHECK([for isnan], ac_cv_have_isnan,
2473                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <math.h>]], [[float f = 0.0; return isnan(f)]])],[ac_cv_have_isnan="yes"],[ac_cv_have_isnan="no"]))
2474 if test "$ac_cv_have_isnan" = "yes"
2475 then
2476     AC_DEFINE(HAVE_ISNAN, 1, [Define to 1 if you have the `isnan' function.])
2477 fi
2478 LIBS="$ac_save_LIBS"
2479
2480 dnl *** check for the need to define platform-specific symbols
2481
2482 case $host_cpu in
2483   *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
2484   *x86_64*)         WINE_CHECK_DEFINE([__x86_64__]) ;;
2485   *sparc64*)        WINE_CHECK_DEFINE([__sparc64__]) ;;
2486   *sparc*)          WINE_CHECK_DEFINE([__sparc__]) ;;
2487   *powerpc64*)      WINE_CHECK_DEFINE([__powerpc64__]) ;;
2488   *powerpc*)        WINE_CHECK_DEFINE([__powerpc__]) ;;
2489   *arm*)            WINE_CHECK_DEFINE([__arm__]) ;;
2490 esac
2491
2492 case $host_vendor in
2493   *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
2494 esac
2495
2496 dnl **** Generate output files ****
2497
2498 AH_TOP([#ifndef WINE_CROSSTEST
2499 #define __WINE_CONFIG_H])
2500 AH_BOTTOM([#endif /* WINE_CROSSTEST */])
2501
2502 AC_CONFIG_COMMANDS([include/stamp-h], [echo timestamp > include/stamp-h])
2503
2504 WINE_CONFIG_SYMLINK(dlls/shell32/AUTHORS,AUTHORS)
2505 WINE_CONFIG_SYMLINK(dlls/wineps.drv/generic.ppd)
2506 WINE_CONFIG_SYMLINK(fonts/marlett.ttf,,enable_fonts)
2507 WINE_CONFIG_SYMLINK(fonts/symbol.ttf,,enable_fonts)
2508 WINE_CONFIG_SYMLINK(fonts/tahoma.ttf,,enable_fonts)
2509 WINE_CONFIG_SYMLINK(fonts/tahomabd.ttf,,enable_fonts)
2510 WINE_CONFIG_SYMLINK(po/LINGUAS)
2511 WINE_CONFIG_SYMLINK(tools/l_intl.nls,,enable_tools)
2512 WINE_CONFIG_SYMLINK(wine,tools/winewrapper)
2513 WINE_CONFIG_SYMLINK(wine64,tools/winewrapper,enable_win64)
2514
2515 WINE_CONFIG_EXTRA_DIR(dlls/gdi32/dibdrv)
2516 WINE_CONFIG_EXTRA_DIR(dlls/gdi32/enhmfdrv)
2517 WINE_CONFIG_EXTRA_DIR(dlls/gdi32/mfdrv)
2518 WINE_CONFIG_EXTRA_DIR(dlls/kernel32/nls)
2519 WINE_CONFIG_EXTRA_DIR(dlls/user32/resources)
2520 WINE_CONFIG_EXTRA_DIR(dlls/wineps.drv/data)
2521 WINE_CONFIG_EXTRA_DIR(include/wine)
2522
2523 WINE_CONFIG_MAKERULES([Make.rules],[MAKE_RULES])
2524 WINE_CONFIG_MAKERULES([Maketest.rules],[MAKE_TEST_RULES],[Make.rules])
2525 WINE_CONFIG_MAKERULES([dlls/Makedll.rules],[MAKE_DLL_RULES],[Make.rules])
2526 WINE_CONFIG_MAKERULES([dlls/Makeimplib.rules],[MAKE_IMPLIB_RULES],[Make.rules])
2527 WINE_CONFIG_MAKERULES([programs/Makeprog.rules],[MAKE_PROG_RULES],[Make.rules])
2528
2529 WINE_CONFIG_DLL(acledit)
2530 WINE_CONFIG_DLL(aclui,,[implib])
2531 WINE_CONFIG_DLL(activeds,,[implib])
2532 WINE_CONFIG_DLL(actxprxy)
2533 WINE_CONFIG_LIB(adsiid)
2534 WINE_CONFIG_DLL(advapi32,,[implib])
2535 WINE_CONFIG_TEST(dlls/advapi32/tests)
2536 WINE_CONFIG_DLL(advpack,,[implib])
2537 WINE_CONFIG_TEST(dlls/advpack/tests)
2538 WINE_CONFIG_DLL(amstream)
2539 WINE_CONFIG_TEST(dlls/amstream/tests)
2540 WINE_CONFIG_DLL(api-ms-win-core-winrt-error-l1-1-0)
2541 WINE_CONFIG_DLL(api-ms-win-core-winrt-string-l1-1-0)
2542 WINE_CONFIG_DLL(api-ms-win-downlevel-advapi32-l1-1-0)
2543 WINE_CONFIG_DLL(api-ms-win-downlevel-advapi32-l2-1-0)
2544 WINE_CONFIG_DLL(api-ms-win-downlevel-normaliz-l1-1-0)
2545 WINE_CONFIG_DLL(api-ms-win-downlevel-ole32-l1-1-0)
2546 WINE_CONFIG_DLL(api-ms-win-downlevel-shell32-l1-1-0)
2547 WINE_CONFIG_DLL(api-ms-win-downlevel-shlwapi-l1-1-0)
2548 WINE_CONFIG_DLL(api-ms-win-downlevel-shlwapi-l2-1-0)
2549 WINE_CONFIG_DLL(api-ms-win-downlevel-user32-l1-1-0)
2550 WINE_CONFIG_DLL(api-ms-win-downlevel-version-l1-1-0)
2551 WINE_CONFIG_DLL(api-ms-win-security-base-l1-1-0)
2552 WINE_CONFIG_DLL(apphelp)
2553 WINE_CONFIG_TEST(dlls/apphelp/tests)
2554 WINE_CONFIG_DLL(appwiz.cpl,,[po])
2555 WINE_CONFIG_DLL(atl,,[implib])
2556 WINE_CONFIG_TEST(dlls/atl/tests)
2557 WINE_CONFIG_DLL(atl100,,[implib])
2558 WINE_CONFIG_TEST(dlls/atl100/tests)
2559 WINE_CONFIG_DLL(atl80,,[implib])
2560 WINE_CONFIG_DLL(authz)
2561 WINE_CONFIG_DLL(avicap32,,[implib])
2562 WINE_CONFIG_DLL(avifil32,,[implib,po])
2563 WINE_CONFIG_TEST(dlls/avifil32/tests)
2564 WINE_CONFIG_DLL(avifile.dll16,enable_win16)
2565 WINE_CONFIG_DLL(avrt,,[implib])
2566 WINE_CONFIG_DLL(bcrypt)
2567 WINE_CONFIG_DLL(browseui,,[po])
2568 WINE_CONFIG_TEST(dlls/browseui/tests)
2569 WINE_CONFIG_DLL(cabinet,,[implib])
2570 WINE_CONFIG_TEST(dlls/cabinet/tests)
2571 WINE_CONFIG_DLL(capi2032,,[implib])
2572 WINE_CONFIG_DLL(cards,,[implib])
2573 WINE_CONFIG_DLL(cfgmgr32,,[implib])
2574 WINE_CONFIG_DLL(clusapi,,[implib])
2575 WINE_CONFIG_DLL(comcat)
2576 WINE_CONFIG_TEST(dlls/comcat/tests)
2577 WINE_CONFIG_DLL(comctl32,,[implib,po])
2578 WINE_CONFIG_TEST(dlls/comctl32/tests)
2579 WINE_CONFIG_DLL(comdlg32,,[implib,po])
2580 WINE_CONFIG_TEST(dlls/comdlg32/tests)
2581 WINE_CONFIG_DLL(comm.drv16,enable_win16)
2582 WINE_CONFIG_DLL(commdlg.dll16,enable_win16)
2583 WINE_CONFIG_DLL(compobj.dll16,enable_win16)
2584 WINE_CONFIG_DLL(compstui,,[implib])
2585 WINE_CONFIG_DLL(credui,,[implib,po])
2586 WINE_CONFIG_TEST(dlls/credui/tests)
2587 WINE_CONFIG_DLL(crtdll,,[implib])
2588 WINE_CONFIG_DLL(crypt32,,[implib,po])
2589 WINE_CONFIG_TEST(dlls/crypt32/tests)
2590 WINE_CONFIG_DLL(cryptdlg,,[po])
2591 WINE_CONFIG_DLL(cryptdll,,[implib])
2592 WINE_CONFIG_DLL(cryptnet,,[implib])
2593 WINE_CONFIG_TEST(dlls/cryptnet/tests)
2594 WINE_CONFIG_DLL(cryptui,,[implib,po])
2595 WINE_CONFIG_TEST(dlls/cryptui/tests)
2596 WINE_CONFIG_DLL(ctapi32)
2597 WINE_CONFIG_DLL(ctl3d.dll16,enable_win16)
2598 WINE_CONFIG_DLL(ctl3d32,,[implib])
2599 WINE_CONFIG_DLL(ctl3dv2.dll16,enable_win16)
2600 WINE_CONFIG_DLL(d3d10,,[implib])
2601 WINE_CONFIG_TEST(dlls/d3d10/tests)
2602 WINE_CONFIG_DLL(d3d10core,,[implib])
2603 WINE_CONFIG_TEST(dlls/d3d10core/tests)
2604 WINE_CONFIG_DLL(d3d11)
2605 WINE_CONFIG_DLL(d3d8,,[implib])
2606 WINE_CONFIG_TEST(dlls/d3d8/tests)
2607 WINE_CONFIG_DLL(d3d9,,[implib])
2608 WINE_CONFIG_TEST(dlls/d3d9/tests)
2609 WINE_CONFIG_DLL(d3dcompiler_33)
2610 WINE_CONFIG_DLL(d3dcompiler_34)
2611 WINE_CONFIG_DLL(d3dcompiler_35)
2612 WINE_CONFIG_DLL(d3dcompiler_36)
2613 WINE_CONFIG_DLL(d3dcompiler_37)
2614 WINE_CONFIG_DLL(d3dcompiler_38)
2615 WINE_CONFIG_DLL(d3dcompiler_39)
2616 WINE_CONFIG_DLL(d3dcompiler_40)
2617 WINE_CONFIG_DLL(d3dcompiler_41)
2618 WINE_CONFIG_DLL(d3dcompiler_42)
2619 WINE_CONFIG_DLL(d3dcompiler_43,,[implib],[d3dcompiler])
2620 WINE_CONFIG_TEST(dlls/d3dcompiler_43/tests)
2621 WINE_CONFIG_DLL(d3dim,,[implib])
2622 WINE_CONFIG_DLL(d3drm,,[implib])
2623 WINE_CONFIG_TEST(dlls/d3drm/tests)
2624 WINE_CONFIG_DLL(d3dx10_33)
2625 WINE_CONFIG_DLL(d3dx10_34)
2626 WINE_CONFIG_DLL(d3dx10_35)
2627 WINE_CONFIG_DLL(d3dx10_36)
2628 WINE_CONFIG_DLL(d3dx10_37)
2629 WINE_CONFIG_DLL(d3dx10_38)
2630 WINE_CONFIG_DLL(d3dx10_39)
2631 WINE_CONFIG_DLL(d3dx10_40)
2632 WINE_CONFIG_DLL(d3dx10_41)
2633 WINE_CONFIG_DLL(d3dx10_42)
2634 WINE_CONFIG_DLL(d3dx10_43)
2635 WINE_CONFIG_DLL(d3dx9_24)
2636 WINE_CONFIG_DLL(d3dx9_25)
2637 WINE_CONFIG_DLL(d3dx9_26)
2638 WINE_CONFIG_DLL(d3dx9_27)
2639 WINE_CONFIG_DLL(d3dx9_28)
2640 WINE_CONFIG_DLL(d3dx9_29)
2641 WINE_CONFIG_DLL(d3dx9_30)
2642 WINE_CONFIG_DLL(d3dx9_31)
2643 WINE_CONFIG_DLL(d3dx9_32)
2644 WINE_CONFIG_DLL(d3dx9_33)
2645 WINE_CONFIG_DLL(d3dx9_34)
2646 WINE_CONFIG_DLL(d3dx9_35)
2647 WINE_CONFIG_DLL(d3dx9_36,,[implib],[d3dx9])
2648 WINE_CONFIG_TEST(dlls/d3dx9_36/tests)
2649 WINE_CONFIG_DLL(d3dx9_37)
2650 WINE_CONFIG_DLL(d3dx9_38)
2651 WINE_CONFIG_DLL(d3dx9_39)
2652 WINE_CONFIG_DLL(d3dx9_40)
2653 WINE_CONFIG_DLL(d3dx9_41)
2654 WINE_CONFIG_DLL(d3dx9_42)
2655 WINE_CONFIG_DLL(d3dx9_43)
2656 WINE_CONFIG_DLL(d3dxof,,[implib])
2657 WINE_CONFIG_TEST(dlls/d3dxof/tests)
2658 WINE_CONFIG_DLL(dbgeng,,[implib])
2659 WINE_CONFIG_DLL(dbghelp,,[implib])
2660 WINE_CONFIG_DLL(dciman32,,[implib])
2661 WINE_CONFIG_DLL(ddeml.dll16,enable_win16)
2662 WINE_CONFIG_DLL(ddraw,,[implib])
2663 WINE_CONFIG_TEST(dlls/ddraw/tests)
2664 WINE_CONFIG_DLL(ddrawex)
2665 WINE_CONFIG_TEST(dlls/ddrawex/tests)
2666 WINE_CONFIG_DLL(devenum,,[po])
2667 WINE_CONFIG_TEST(dlls/devenum/tests)
2668 WINE_CONFIG_DLL(dhcpcsvc)
2669 WINE_CONFIG_DLL(dinput,,[implib,po,staticimplib])
2670 WINE_CONFIG_TEST(dlls/dinput/tests)
2671 WINE_CONFIG_DLL(dinput8,,[implib])
2672 WINE_CONFIG_TEST(dlls/dinput8/tests)
2673 WINE_CONFIG_DLL(dispdib.dll16,enable_win16)
2674 WINE_CONFIG_DLL(dispex)
2675 WINE_CONFIG_TEST(dlls/dispex/tests)
2676 WINE_CONFIG_DLL(display.drv16,enable_win16)
2677 WINE_CONFIG_DLL(dmband)
2678 WINE_CONFIG_TEST(dlls/dmband/tests)
2679 WINE_CONFIG_DLL(dmcompos)
2680 WINE_CONFIG_DLL(dmime)
2681 WINE_CONFIG_TEST(dlls/dmime/tests)
2682 WINE_CONFIG_DLL(dmloader)
2683 WINE_CONFIG_TEST(dlls/dmloader/tests)
2684 WINE_CONFIG_DLL(dmscript)
2685 WINE_CONFIG_DLL(dmstyle)
2686 WINE_CONFIG_DLL(dmsynth)
2687 WINE_CONFIG_TEST(dlls/dmsynth/tests)
2688 WINE_CONFIG_DLL(dmusic)
2689 WINE_CONFIG_TEST(dlls/dmusic/tests)
2690 WINE_CONFIG_DLL(dmusic32,,[implib])
2691 WINE_CONFIG_DLL(dnsapi,,[implib])
2692 WINE_CONFIG_TEST(dlls/dnsapi/tests)
2693 WINE_CONFIG_DLL(dplay,,[implib])
2694 WINE_CONFIG_DLL(dplayx,,[implib])
2695 WINE_CONFIG_TEST(dlls/dplayx/tests)
2696 WINE_CONFIG_DLL(dpnaddr)
2697 WINE_CONFIG_DLL(dpnet,,[implib])
2698 WINE_CONFIG_TEST(dlls/dpnet/tests)
2699 WINE_CONFIG_DLL(dpnhpast)
2700 WINE_CONFIG_DLL(dpnlobby)
2701 WINE_CONFIG_DLL(dpwsockx)
2702 WINE_CONFIG_DLL(drmclien)
2703 WINE_CONFIG_DLL(dsound,,[implib])
2704 WINE_CONFIG_TEST(dlls/dsound/tests)
2705 WINE_CONFIG_DLL(dssenh)
2706 WINE_CONFIG_TEST(dlls/dssenh/tests)
2707 WINE_CONFIG_DLL(dswave)
2708 WINE_CONFIG_DLL(dwmapi,,[implib])
2709 WINE_CONFIG_DLL(dwrite,,[implib])
2710 WINE_CONFIG_TEST(dlls/dwrite/tests)
2711 WINE_CONFIG_DLL(dxdiagn,,[po])
2712 WINE_CONFIG_TEST(dlls/dxdiagn/tests)
2713 WINE_CONFIG_LIB(dxerr8)
2714 WINE_CONFIG_LIB(dxerr9)
2715 WINE_CONFIG_DLL(dxgi,,[implib])
2716 WINE_CONFIG_TEST(dlls/dxgi/tests)
2717 WINE_CONFIG_LIB(dxguid)
2718 WINE_CONFIG_DLL(explorerframe)
2719 WINE_CONFIG_TEST(dlls/explorerframe/tests)
2720 WINE_CONFIG_DLL(faultrep,,[implib])
2721 WINE_CONFIG_TEST(dlls/faultrep/tests)
2722 WINE_CONFIG_DLL(fltlib)
2723 WINE_CONFIG_DLL(fusion)
2724 WINE_CONFIG_TEST(dlls/fusion/tests)
2725 WINE_CONFIG_DLL(fwpuclnt)
2726 WINE_CONFIG_DLL(gameux)
2727 WINE_CONFIG_TEST(dlls/gameux/tests)
2728 WINE_CONFIG_DLL(gdi.exe16,enable_win16)
2729 WINE_CONFIG_DLL(gdi32,,[implib,po])
2730 WINE_CONFIG_TEST(dlls/gdi32/tests)
2731 WINE_CONFIG_DLL(gdiplus,,[implib])
2732 WINE_CONFIG_TEST(dlls/gdiplus/tests)
2733 WINE_CONFIG_DLL(glu32,,[implib])
2734 WINE_CONFIG_DLL(gphoto2.ds,,[po])
2735 WINE_CONFIG_DLL(gpkcsp)
2736 WINE_CONFIG_DLL(hal)
2737 WINE_CONFIG_DLL(hhctrl.ocx,,[implib,po],[htmlhelp])
2738 WINE_CONFIG_DLL(hid,,[implib])
2739 WINE_CONFIG_DLL(hlink,,[implib])
2740 WINE_CONFIG_TEST(dlls/hlink/tests)
2741 WINE_CONFIG_DLL(hnetcfg)
2742 WINE_CONFIG_DLL(httpapi)
2743 WINE_CONFIG_DLL(iccvid,,[po])
2744 WINE_CONFIG_DLL(icmp)
2745 WINE_CONFIG_DLL(ieframe,,[implib,po])
2746 WINE_CONFIG_TEST(dlls/ieframe/tests)
2747 WINE_CONFIG_DLL(ifsmgr.vxd,enable_win16)
2748 WINE_CONFIG_DLL(imaadp32.acm)
2749 WINE_CONFIG_DLL(imagehlp,,[implib])
2750 WINE_CONFIG_TEST(dlls/imagehlp/tests)
2751 WINE_CONFIG_DLL(imm.dll16,enable_win16)
2752 WINE_CONFIG_DLL(imm32,,[implib])
2753 WINE_CONFIG_TEST(dlls/imm32/tests)
2754 WINE_CONFIG_DLL(inetcomm,,[implib])
2755 WINE_CONFIG_TEST(dlls/inetcomm/tests)
2756 WINE_CONFIG_DLL(inetcpl.cpl,,[po])
2757 WINE_CONFIG_DLL(inetmib1)
2758 WINE_CONFIG_TEST(dlls/inetmib1/tests)
2759 WINE_CONFIG_DLL(infosoft)
2760 WINE_CONFIG_TEST(dlls/infosoft/tests)
2761 WINE_CONFIG_DLL(initpki)
2762 WINE_CONFIG_DLL(inkobj)
2763 WINE_CONFIG_DLL(inseng)
2764 WINE_CONFIG_DLL(iphlpapi,,[implib])
2765 WINE_CONFIG_TEST(dlls/iphlpapi/tests)
2766 WINE_CONFIG_DLL(itircl)
2767 WINE_CONFIG_DLL(itss)
2768 WINE_CONFIG_TEST(dlls/itss/tests)
2769 WINE_CONFIG_DLL(joy.cpl,,[po])
2770 WINE_CONFIG_DLL(jscript,,[po])
2771 WINE_CONFIG_TEST(dlls/jscript/tests)
2772 WINE_CONFIG_DLL(kernel32,,[implib,mc])
2773 WINE_CONFIG_TEST(dlls/kernel32/tests)
2774 WINE_CONFIG_DLL(keyboard.drv16,enable_win16)
2775 WINE_CONFIG_DLL(krnl386.exe16,enable_win16,[implib],[kernel])
2776 WINE_CONFIG_DLL(ktmw32)
2777 WINE_CONFIG_DLL(loadperf,,[implib])
2778 WINE_CONFIG_DLL(localspl,,[po])
2779 WINE_CONFIG_TEST(dlls/localspl/tests)
2780 WINE_CONFIG_DLL(localui,,[po])
2781 WINE_CONFIG_TEST(dlls/localui/tests)
2782 WINE_CONFIG_DLL(lz32,,[implib])
2783 WINE_CONFIG_TEST(dlls/lz32/tests)
2784 WINE_CONFIG_DLL(lzexpand.dll16,enable_win16)
2785 WINE_CONFIG_DLL(mapi32,,[implib,po])
2786 WINE_CONFIG_TEST(dlls/mapi32/tests)
2787 WINE_CONFIG_DLL(mapistub)
2788 WINE_CONFIG_DLL(mciavi32)
2789 WINE_CONFIG_DLL(mcicda)
2790 WINE_CONFIG_DLL(mciqtz32)
2791 WINE_CONFIG_DLL(mciseq)
2792 WINE_CONFIG_DLL(mciwave)
2793 WINE_CONFIG_DLL(mgmtapi)
2794 WINE_CONFIG_DLL(midimap)
2795 WINE_CONFIG_DLL(mlang,,[implib])
2796 WINE_CONFIG_TEST(dlls/mlang/tests)
2797 WINE_CONFIG_DLL(mmcndmgr)
2798 WINE_CONFIG_TEST(dlls/mmcndmgr/tests)
2799 WINE_CONFIG_DLL(mmdevapi)
2800 WINE_CONFIG_TEST(dlls/mmdevapi/tests)
2801 WINE_CONFIG_DLL(mmdevldr.vxd,enable_win16)
2802 WINE_CONFIG_DLL(mmsystem.dll16,enable_win16)
2803 WINE_CONFIG_DLL(monodebg.vxd,enable_win16)
2804 WINE_CONFIG_DLL(mountmgr.sys)
2805 WINE_CONFIG_DLL(mouse.drv16,enable_win16)
2806 WINE_CONFIG_DLL(mpr,,[implib,po])
2807 WINE_CONFIG_TEST(dlls/mpr/tests)
2808 WINE_CONFIG_DLL(mprapi,,[implib])
2809 WINE_CONFIG_DLL(msacm.dll16,enable_win16)
2810 WINE_CONFIG_DLL(msacm32.drv)
2811 WINE_CONFIG_DLL(msacm32,,[implib,po])
2812 WINE_CONFIG_TEST(dlls/msacm32/tests)
2813 WINE_CONFIG_DLL(msadp32.acm)
2814 WINE_CONFIG_DLL(mscat32)
2815 WINE_CONFIG_DLL(mscms,,[implib])
2816 WINE_CONFIG_TEST(dlls/mscms/tests)
2817 WINE_CONFIG_DLL(mscoree)
2818 WINE_CONFIG_TEST(dlls/mscoree/tests)
2819 WINE_CONFIG_DLL(msctf)
2820 WINE_CONFIG_TEST(dlls/msctf/tests)
2821 WINE_CONFIG_DLL(msdaps)
2822 WINE_CONFIG_DLL(msdmo,,[implib])
2823 WINE_CONFIG_DLL(msftedit)
2824 WINE_CONFIG_DLL(msg711.acm)
2825 WINE_CONFIG_DLL(msgsm32.acm)
2826 WINE_CONFIG_DLL(mshtml.tlb)
2827 WINE_CONFIG_DLL(mshtml,,[implib,po])
2828 WINE_CONFIG_TEST(dlls/mshtml/tests)
2829 WINE_CONFIG_DLL(msi,,[implib,po])
2830 WINE_CONFIG_TEST(dlls/msi/tests)
2831 WINE_CONFIG_DLL(msident)
2832 WINE_CONFIG_DLL(msimg32,,[implib])
2833 WINE_CONFIG_DLL(msimsg)
2834 WINE_CONFIG_DLL(msimtf)
2835 WINE_CONFIG_DLL(msisip)
2836 WINE_CONFIG_DLL(msisys.ocx)
2837 WINE_CONFIG_DLL(msls31)
2838 WINE_CONFIG_DLL(msnet32)
2839 WINE_CONFIG_DLL(mspatcha)
2840 WINE_CONFIG_DLL(msrle32,,[po])
2841 WINE_CONFIG_DLL(mssign32)
2842 WINE_CONFIG_DLL(mssip32)
2843 WINE_CONFIG_DLL(mstask)
2844 WINE_CONFIG_TEST(dlls/mstask/tests)
2845 WINE_CONFIG_DLL(msvcirt)
2846 WINE_CONFIG_DLL(msvcm80)
2847 WINE_CONFIG_DLL(msvcm90)
2848 WINE_CONFIG_DLL(msvcp100)
2849 WINE_CONFIG_TEST(dlls/msvcp100/tests)
2850 WINE_CONFIG_DLL(msvcp60)
2851 WINE_CONFIG_TEST(dlls/msvcp60/tests)
2852 WINE_CONFIG_DLL(msvcp70)
2853 WINE_CONFIG_DLL(msvcp71)
2854 WINE_CONFIG_DLL(msvcp80)
2855 WINE_CONFIG_DLL(msvcp90)
2856 WINE_CONFIG_TEST(dlls/msvcp90/tests)
2857 WINE_CONFIG_DLL(msvcr100)
2858 WINE_CONFIG_TEST(dlls/msvcr100/tests)
2859 WINE_CONFIG_DLL(msvcr70,,[implib])
2860 WINE_CONFIG_DLL(msvcr71,,[implib])
2861 WINE_CONFIG_DLL(msvcr80)
2862 WINE_CONFIG_DLL(msvcr90)
2863 WINE_CONFIG_TEST(dlls/msvcr90/tests)
2864 WINE_CONFIG_DLL(msvcrt,,[implib])
2865 WINE_CONFIG_TEST(dlls/msvcrt/tests)
2866 WINE_CONFIG_DLL(msvcrt20,,[implib])
2867 WINE_CONFIG_DLL(msvcrt40,,[implib])
2868 WINE_CONFIG_DLL(msvcrtd,,[implib])
2869 WINE_CONFIG_TEST(dlls/msvcrtd/tests)
2870 WINE_CONFIG_DLL(msvfw32,,[implib,po])
2871 WINE_CONFIG_TEST(dlls/msvfw32/tests)
2872 WINE_CONFIG_DLL(msvidc32,,[po])
2873 WINE_CONFIG_DLL(msvideo.dll16,enable_win16)
2874 WINE_CONFIG_DLL(mswsock,,[implib])
2875 WINE_CONFIG_DLL(msxml)
2876 WINE_CONFIG_DLL(msxml2)
2877 WINE_CONFIG_DLL(msxml3)
2878 WINE_CONFIG_TEST(dlls/msxml3/tests)
2879 WINE_CONFIG_DLL(msxml4)
2880 WINE_CONFIG_DLL(msxml6)
2881 WINE_CONFIG_DLL(nddeapi,,[implib])
2882 WINE_CONFIG_DLL(netapi32,,[implib])
2883 WINE_CONFIG_TEST(dlls/netapi32/tests)
2884 WINE_CONFIG_DLL(newdev,,[implib])
2885 WINE_CONFIG_DLL(normaliz,,[implib])
2886 WINE_CONFIG_DLL(npmshtml)
2887 WINE_CONFIG_DLL(ntdll,,[implib])
2888 WINE_CONFIG_TEST(dlls/ntdll/tests)
2889 WINE_CONFIG_DLL(ntdsapi,,[implib])
2890 WINE_CONFIG_TEST(dlls/ntdsapi/tests)
2891 WINE_CONFIG_DLL(ntoskrnl.exe,,[implib])
2892 WINE_CONFIG_DLL(ntprint)
2893 WINE_CONFIG_TEST(dlls/ntprint/tests)
2894 WINE_CONFIG_DLL(objsel)
2895 WINE_CONFIG_DLL(odbc32,,[implib])
2896 WINE_CONFIG_DLL(odbccp32,,[implib])
2897 WINE_CONFIG_TEST(dlls/odbccp32/tests)
2898 WINE_CONFIG_DLL(odbccu32)
2899 WINE_CONFIG_DLL(ole2.dll16,enable_win16)
2900 WINE_CONFIG_DLL(ole2conv.dll16,enable_win16)
2901 WINE_CONFIG_DLL(ole2disp.dll16,enable_win16)
2902 WINE_CONFIG_DLL(ole2nls.dll16,enable_win16)
2903 WINE_CONFIG_DLL(ole2prox.dll16,enable_win16)
2904 WINE_CONFIG_DLL(ole2thk.dll16,enable_win16)
2905 WINE_CONFIG_DLL(ole32,,[implib])
2906 WINE_CONFIG_TEST(dlls/ole32/tests)
2907 WINE_CONFIG_DLL(oleacc,,[implib,po])
2908 WINE_CONFIG_TEST(dlls/oleacc/tests)
2909 WINE_CONFIG_DLL(oleaut32,,[implib,po])
2910 WINE_CONFIG_TEST(dlls/oleaut32/tests)
2911 WINE_CONFIG_DLL(olecli.dll16,enable_win16)
2912 WINE_CONFIG_DLL(olecli32,,[implib])
2913 WINE_CONFIG_DLL(oledb32)
2914 WINE_CONFIG_TEST(dlls/oledb32/tests)
2915 WINE_CONFIG_DLL(oledlg,,[implib,po])
2916 WINE_CONFIG_DLL(olepro32,,[implib])
2917 WINE_CONFIG_DLL(olesvr.dll16,enable_win16)
2918 WINE_CONFIG_DLL(olesvr32,,[implib])
2919 WINE_CONFIG_DLL(olethk32)
2920 WINE_CONFIG_DLL(openal32)
2921 WINE_CONFIG_DLL(opencl)
2922 WINE_CONFIG_DLL(opengl32,,[implib])
2923 WINE_CONFIG_TEST(dlls/opengl32/tests)
2924 WINE_CONFIG_DLL(pdh,,[implib])
2925 WINE_CONFIG_TEST(dlls/pdh/tests)
2926 WINE_CONFIG_DLL(photometadatahandler)
2927 WINE_CONFIG_DLL(pidgen)
2928 WINE_CONFIG_DLL(powrprof,,[implib])
2929 WINE_CONFIG_DLL(printui)
2930 WINE_CONFIG_DLL(propsys,,[implib])
2931 WINE_CONFIG_TEST(dlls/propsys/tests)
2932 WINE_CONFIG_DLL(psapi,,[implib])
2933 WINE_CONFIG_TEST(dlls/psapi/tests)
2934 WINE_CONFIG_DLL(pstorec)
2935 WINE_CONFIG_DLL(qcap)
2936 WINE_CONFIG_DLL(qedit)
2937 WINE_CONFIG_TEST(dlls/qedit/tests)
2938 WINE_CONFIG_DLL(qmgr)
2939 WINE_CONFIG_TEST(dlls/qmgr/tests)
2940 WINE_CONFIG_DLL(qmgrprxy)
2941 WINE_CONFIG_DLL(quartz,,[implib])
2942 WINE_CONFIG_TEST(dlls/quartz/tests)
2943 WINE_CONFIG_DLL(query)
2944 WINE_CONFIG_DLL(rasapi16.dll16,enable_win16)
2945 WINE_CONFIG_DLL(rasapi32,,[implib])
2946 WINE_CONFIG_TEST(dlls/rasapi32/tests)
2947 WINE_CONFIG_DLL(rasdlg,,[implib])
2948 WINE_CONFIG_DLL(regapi)
2949 WINE_CONFIG_DLL(resutils,,[implib])
2950 WINE_CONFIG_DLL(riched20,,[implib])
2951 WINE_CONFIG_TEST(dlls/riched20/tests)
2952 WINE_CONFIG_DLL(riched32)
2953 WINE_CONFIG_TEST(dlls/riched32/tests)
2954 WINE_CONFIG_DLL(rpcrt4,,[implib])
2955 WINE_CONFIG_TEST(dlls/rpcrt4/tests)
2956 WINE_CONFIG_DLL(rsabase)
2957 WINE_CONFIG_DLL(rsaenh,,[implib])
2958 WINE_CONFIG_TEST(dlls/rsaenh/tests)
2959 WINE_CONFIG_DLL(rstrtmgr)
2960 WINE_CONFIG_DLL(rtutils,,[implib])
2961 WINE_CONFIG_DLL(samlib)
2962 WINE_CONFIG_DLL(sane.ds,,[po])
2963 WINE_CONFIG_DLL(scarddlg)
2964 WINE_CONFIG_DLL(sccbase)
2965 WINE_CONFIG_DLL(schannel)
2966 WINE_CONFIG_TEST(dlls/schannel/tests)
2967 WINE_CONFIG_DLL(scrrun)
2968 WINE_CONFIG_TEST(dlls/scrrun/tests)
2969 WINE_CONFIG_DLL(scsiport.sys)
2970 WINE_CONFIG_DLL(secur32,,[implib])
2971 WINE_CONFIG_TEST(dlls/secur32/tests)
2972 WINE_CONFIG_DLL(security)
2973 WINE_CONFIG_DLL(sensapi,,[implib])
2974 WINE_CONFIG_DLL(serialui,,[implib,po])
2975 WINE_CONFIG_TEST(dlls/serialui/tests)
2976 WINE_CONFIG_DLL(setupapi,,[implib,po])
2977 WINE_CONFIG_TEST(dlls/setupapi/tests)
2978 WINE_CONFIG_DLL(setupx.dll16,enable_win16)
2979 WINE_CONFIG_DLL(sfc,,[implib])
2980 WINE_CONFIG_DLL(sfc_os,,[implib])
2981 WINE_CONFIG_DLL(shdoclc,,[po])
2982 WINE_CONFIG_DLL(shdocvw,,[implib])
2983 WINE_CONFIG_TEST(dlls/shdocvw/tests)
2984 WINE_CONFIG_DLL(shell.dll16,enable_win16)
2985 WINE_CONFIG_DLL(shell32,,[implib,po])
2986 WINE_CONFIG_TEST(dlls/shell32/tests)
2987 WINE_CONFIG_DLL(shfolder,,[implib])
2988 WINE_CONFIG_DLL(shlwapi,,[implib,po])
2989 WINE_CONFIG_TEST(dlls/shlwapi/tests)
2990 WINE_CONFIG_DLL(slbcsp)
2991 WINE_CONFIG_DLL(slc,,[implib])
2992 WINE_CONFIG_DLL(snmpapi,,[implib])
2993 WINE_CONFIG_TEST(dlls/snmpapi/tests)
2994 WINE_CONFIG_DLL(softpub)
2995 WINE_CONFIG_DLL(sound.drv16,enable_win16)
2996 WINE_CONFIG_DLL(spoolss,,[implib])
2997 WINE_CONFIG_TEST(dlls/spoolss/tests)
2998 WINE_CONFIG_DLL(stdole2.tlb)
2999 WINE_CONFIG_DLL(stdole32.tlb)
3000 WINE_CONFIG_DLL(sti,,[implib])
3001 WINE_CONFIG_TEST(dlls/sti/tests)
3002 WINE_CONFIG_DLL(storage.dll16,enable_win16)
3003 WINE_CONFIG_DLL(stress.dll16,enable_win16)
3004 WINE_CONFIG_LIB(strmbase)
3005 WINE_CONFIG_LIB(strmiids)
3006 WINE_CONFIG_DLL(svrapi)
3007 WINE_CONFIG_DLL(sxs,,[implib])
3008 WINE_CONFIG_TEST(dlls/sxs/tests)
3009 WINE_CONFIG_DLL(system.drv16,enable_win16)
3010 WINE_CONFIG_DLL(t2embed)
3011 WINE_CONFIG_DLL(tapi32,,[implib])
3012 WINE_CONFIG_DLL(toolhelp.dll16,enable_win16)
3013 WINE_CONFIG_DLL(traffic)
3014 WINE_CONFIG_DLL(twain.dll16,enable_win16)
3015 WINE_CONFIG_DLL(twain_32)
3016 WINE_CONFIG_TEST(dlls/twain_32/tests)
3017 WINE_CONFIG_DLL(typelib.dll16,enable_win16)
3018 WINE_CONFIG_DLL(unicows,,[implib])
3019 WINE_CONFIG_DLL(updspapi)
3020 WINE_CONFIG_DLL(url,,[implib])
3021 WINE_CONFIG_DLL(urlmon,,[implib,po])
3022 WINE_CONFIG_TEST(dlls/urlmon/tests)
3023 WINE_CONFIG_DLL(usbd.sys,,[implib])
3024 WINE_CONFIG_DLL(user.exe16,enable_win16)
3025 WINE_CONFIG_DLL(user32,,[implib,po])
3026 WINE_CONFIG_TEST(dlls/user32/tests)
3027 WINE_CONFIG_DLL(userenv,,[implib])
3028 WINE_CONFIG_TEST(dlls/userenv/tests)
3029 WINE_CONFIG_DLL(usp10,,[implib])
3030 WINE_CONFIG_TEST(dlls/usp10/tests)
3031 WINE_CONFIG_LIB(uuid)
3032 WINE_CONFIG_DLL(uxtheme,,[implib])
3033 WINE_CONFIG_TEST(dlls/uxtheme/tests)
3034 WINE_CONFIG_DLL(vbscript)
3035 WINE_CONFIG_TEST(dlls/vbscript/tests)
3036 WINE_CONFIG_DLL(vcomp)
3037 WINE_CONFIG_DLL(vcomp100)
3038 WINE_CONFIG_DLL(vcomp90)
3039 WINE_CONFIG_DLL(vdhcp.vxd,enable_win16)
3040 WINE_CONFIG_DLL(vdmdbg,,[implib])
3041 WINE_CONFIG_DLL(ver.dll16,enable_win16)
3042 WINE_CONFIG_DLL(version,,[implib])
3043 WINE_CONFIG_TEST(dlls/version/tests)
3044 WINE_CONFIG_DLL(vmm.vxd,enable_win16)
3045 WINE_CONFIG_DLL(vnbt.vxd,enable_win16)
3046 WINE_CONFIG_DLL(vnetbios.vxd,enable_win16)
3047 WINE_CONFIG_DLL(vtdapi.vxd,enable_win16)
3048 WINE_CONFIG_DLL(vwin32.vxd,enable_win16)
3049 WINE_CONFIG_DLL(w32skrnl,enable_win16)
3050 WINE_CONFIG_DLL(w32sys.dll16,enable_win16)
3051 WINE_CONFIG_DLL(wbemprox)
3052 WINE_CONFIG_TEST(dlls/wbemprox/tests)
3053 WINE_CONFIG_DLL(wer,,[implib])
3054 WINE_CONFIG_TEST(dlls/wer/tests)
3055 WINE_CONFIG_DLL(wevtapi)
3056 WINE_CONFIG_DLL(wiaservc)
3057 WINE_CONFIG_DLL(win32s16.dll16,enable_win16)
3058 WINE_CONFIG_DLL(win87em.dll16,enable_win16)
3059 WINE_CONFIG_DLL(winaspi.dll16,enable_win16)
3060 WINE_CONFIG_DLL(windebug.dll16,enable_win16)
3061 WINE_CONFIG_DLL(windowscodecs,,[implib])
3062 WINE_CONFIG_TEST(dlls/windowscodecs/tests)
3063 WINE_CONFIG_DLL(winealsa.drv)
3064 WINE_CONFIG_DLL(winecoreaudio.drv)
3065 WINE_CONFIG_LIB(winecrt0)
3066 WINE_CONFIG_DLL(wined3d,,[implib])
3067 WINE_CONFIG_DLL(winegstreamer)
3068 WINE_CONFIG_DLL(winejoystick.drv)
3069 WINE_CONFIG_DLL(winemac.drv)
3070 WINE_CONFIG_DLL(winemapi)
3071 WINE_CONFIG_DLL(winemp3.acm)
3072 WINE_CONFIG_DLL(wineoss.drv)
3073 WINE_CONFIG_DLL(wineps.drv,,[install-lib,po])
3074 WINE_CONFIG_DLL(wineps16.drv16,enable_win16)
3075 WINE_CONFIG_DLL(wineqtdecoder)
3076 WINE_CONFIG_DLL(winex11.drv)
3077 WINE_CONFIG_DLL(wing.dll16,enable_win16)
3078 WINE_CONFIG_DLL(wing32)
3079 WINE_CONFIG_DLL(winhttp,,[implib])
3080 WINE_CONFIG_TEST(dlls/winhttp/tests)
3081 WINE_CONFIG_DLL(wininet,,[implib,po])
3082 WINE_CONFIG_TEST(dlls/wininet/tests)
3083 WINE_CONFIG_DLL(winmm,,[implib,po])
3084 WINE_CONFIG_TEST(dlls/winmm/tests)
3085 WINE_CONFIG_DLL(winnls.dll16,enable_win16)
3086 WINE_CONFIG_DLL(winnls32,,[implib])
3087 WINE_CONFIG_DLL(winscard,,[implib])
3088 WINE_CONFIG_DLL(winsock.dll16,enable_win16)
3089 WINE_CONFIG_DLL(winspool.drv,,[implib,po],[winspool])
3090 WINE_CONFIG_TEST(dlls/winspool.drv/tests)
3091 WINE_CONFIG_DLL(winsta)
3092 WINE_CONFIG_DLL(wintab.dll16,enable_win16)
3093 WINE_CONFIG_DLL(wintab32,,[implib])
3094 WINE_CONFIG_TEST(dlls/wintab32/tests)
3095 WINE_CONFIG_DLL(wintrust,,[implib])
3096 WINE_CONFIG_TEST(dlls/wintrust/tests)
3097 WINE_CONFIG_DLL(wlanapi)
3098 WINE_CONFIG_DLL(wldap32,,[implib,po])
3099 WINE_CONFIG_TEST(dlls/wldap32/tests)
3100 WINE_CONFIG_DLL(wmi)
3101 WINE_CONFIG_DLL(wmiutils)
3102 WINE_CONFIG_TEST(dlls/wmiutils/tests)
3103 WINE_CONFIG_DLL(wmvcore)
3104 WINE_CONFIG_DLL(wnaspi32,,[implib])
3105 WINE_CONFIG_DLL(wow32,enable_win16,[implib])
3106 WINE_CONFIG_DLL(ws2_32,,[implib])
3107 WINE_CONFIG_TEST(dlls/ws2_32/tests)
3108 WINE_CONFIG_DLL(wshom.ocx)
3109 WINE_CONFIG_TEST(dlls/wshom.ocx/tests)
3110 WINE_CONFIG_DLL(wsnmp32)
3111 WINE_CONFIG_DLL(wsock32,,[implib])
3112 WINE_CONFIG_DLL(wtsapi32,,[implib])
3113 WINE_CONFIG_DLL(wuapi)
3114 WINE_CONFIG_DLL(wuaueng)
3115 WINE_CONFIG_DLL(xapofx1_1)
3116 WINE_CONFIG_DLL(xinput1_1)
3117 WINE_CONFIG_DLL(xinput1_2)
3118 WINE_CONFIG_DLL(xinput1_3,,[implib],[xinput])
3119 WINE_CONFIG_TEST(dlls/xinput1_3/tests)
3120 WINE_CONFIG_DLL(xinput9_1_0)
3121 WINE_CONFIG_DLL(xmllite)
3122 WINE_CONFIG_TEST(dlls/xmllite/tests)
3123 WINE_CONFIG_DLL(xolehlp)
3124 WINE_CONFIG_DLL(xpsprint)
3125 WINE_CONFIG_DLL(xpssvcs)
3126 WINE_CONFIG_MAKEFILE([documentation])
3127 WINE_CONFIG_MAKEFILE([fonts],,[install-lib])
3128 WINE_CONFIG_MAKEFILE([include],,[install-dev])
3129 WINE_CONFIG_MAKEFILE([libs/port])
3130 WINE_CONFIG_MAKEFILE([libs/wine],,[install-dev,install-lib])
3131 WINE_CONFIG_MAKEFILE([libs/wpp])
3132 WINE_CONFIG_MAKEFILE([loader],,[install-lib,manpage])
3133 WINE_CONFIG_PROGRAM(aspnet_regiis,,[install])
3134 WINE_CONFIG_PROGRAM(attrib,,[install,po])
3135 WINE_CONFIG_PROGRAM(cabarc,,[install])
3136 WINE_CONFIG_PROGRAM(cacls,,[install])
3137 WINE_CONFIG_PROGRAM(clock,,[install,po])
3138 WINE_CONFIG_PROGRAM(cmd,,[install,po])
3139 WINE_CONFIG_TEST(programs/cmd/tests)
3140 WINE_CONFIG_PROGRAM(conhost,,[install])
3141 WINE_CONFIG_PROGRAM(control,,[install])
3142 WINE_CONFIG_PROGRAM(cscript,,[install])
3143 WINE_CONFIG_PROGRAM(dxdiag,,[install,po])
3144 WINE_CONFIG_PROGRAM(eject,,[install])
3145 WINE_CONFIG_PROGRAM(expand,,[install])
3146 WINE_CONFIG_PROGRAM(explorer,,[install,po])
3147 WINE_CONFIG_PROGRAM(extrac32,,[install])
3148 WINE_CONFIG_PROGRAM(findstr,,[install])
3149 WINE_CONFIG_PROGRAM(hh,,[install])
3150 WINE_CONFIG_PROGRAM(hostname,,[install,po])
3151 WINE_CONFIG_PROGRAM(icinfo,,[install])
3152 WINE_CONFIG_PROGRAM(iexplore,,[install])
3153 WINE_CONFIG_PROGRAM(ipconfig,,[install,po])
3154 WINE_CONFIG_PROGRAM(lodctr,,[install])
3155 WINE_CONFIG_PROGRAM(mofcomp,,[install])
3156 WINE_CONFIG_PROGRAM(mshta,,[install])
3157 WINE_CONFIG_PROGRAM(msiexec,,[install,installbin,manpage])
3158 WINE_CONFIG_PROGRAM(net,,[install,po])
3159 WINE_CONFIG_PROGRAM(netsh,,[install])
3160 WINE_CONFIG_PROGRAM(netstat,,[install,po])
3161 WINE_CONFIG_PROGRAM(ngen,,[install])
3162 WINE_CONFIG_PROGRAM(notepad,,[install,installbin,manpage,po])
3163 WINE_CONFIG_PROGRAM(oleview,,[install,po])
3164 WINE_CONFIG_PROGRAM(ping,,[install])
3165 WINE_CONFIG_PROGRAM(plugplay,,[install])
3166 WINE_CONFIG_PROGRAM(presentationfontcache,,[install])
3167 WINE_CONFIG_PROGRAM(progman,,[install,po])
3168 WINE_CONFIG_PROGRAM(reg,,[install,po])
3169 WINE_CONFIG_PROGRAM(regasm,,[install])
3170 WINE_CONFIG_PROGRAM(regedit,,[install,installbin,manpage,po])
3171 WINE_CONFIG_TEST(programs/regedit/tests)
3172 WINE_CONFIG_PROGRAM(regsvcs,,[install])
3173 WINE_CONFIG_PROGRAM(regsvr32,,[install,installbin,manpage])
3174 WINE_CONFIG_PROGRAM(rpcss,,[install])
3175 WINE_CONFIG_PROGRAM(rundll.exe16,enable_win16,[install])
3176 WINE_CONFIG_PROGRAM(rundll32,,[install])
3177 WINE_CONFIG_PROGRAM(sc,,[install])
3178 WINE_CONFIG_PROGRAM(schtasks,,[install])
3179 WINE_CONFIG_PROGRAM(secedit,,[install])
3180 WINE_CONFIG_PROGRAM(servicemodelreg,,[install])
3181 WINE_CONFIG_PROGRAM(services,,[install])
3182 WINE_CONFIG_TEST(programs/services/tests)
3183 WINE_CONFIG_PROGRAM(spoolsv,,[install])
3184 WINE_CONFIG_PROGRAM(start,,[install,po])
3185 WINE_CONFIG_PROGRAM(svchost,,[install])
3186 WINE_CONFIG_PROGRAM(taskkill,,[install,po])
3187 WINE_CONFIG_PROGRAM(taskmgr,,[install,po])
3188 WINE_CONFIG_PROGRAM(termsv,,[install])
3189 WINE_CONFIG_PROGRAM(uninstaller,,[install,po])
3190 WINE_CONFIG_PROGRAM(unlodctr,,[install])
3191 WINE_CONFIG_PROGRAM(view,,[install,po])
3192 WINE_CONFIG_PROGRAM(wineboot,,[install,installbin,manpage,po])
3193 WINE_CONFIG_PROGRAM(winebrowser,,[install])
3194 WINE_CONFIG_PROGRAM(winecfg,,[install,installbin,manpage,po])
3195 WINE_CONFIG_PROGRAM(wineconsole,,[install,installbin,manpage,po])
3196 WINE_CONFIG_PROGRAM(winedbg,,[install,installbin,manpage,po])
3197 WINE_CONFIG_PROGRAM(winedevice,,[install])
3198 WINE_CONFIG_PROGRAM(winefile,,[install,installbin,manpage,po])
3199 WINE_CONFIG_PROGRAM(winemenubuilder,,[install])
3200 WINE_CONFIG_PROGRAM(winemine,,[install,installbin,manpage,po])
3201 WINE_CONFIG_PROGRAM(winemsibuilder,,[install])
3202 WINE_CONFIG_PROGRAM(winepath,,[install,installbin,manpage])
3203 WINE_CONFIG_PROGRAM(winetest)
3204 WINE_CONFIG_PROGRAM(winevdm,enable_win16,[install])
3205 WINE_CONFIG_PROGRAM(winhelp.exe16,enable_win16,[install])
3206 WINE_CONFIG_PROGRAM(winhlp32,,[install,po])
3207 WINE_CONFIG_PROGRAM(winoldap.mod16,enable_win16,[install])
3208 WINE_CONFIG_PROGRAM(winver,,[install])
3209 WINE_CONFIG_PROGRAM(wmic,,[install,po])
3210 WINE_CONFIG_PROGRAM(wordpad,,[install,po])
3211 WINE_CONFIG_PROGRAM(write,,[install,po])
3212 WINE_CONFIG_PROGRAM(wscript,,[install])
3213 WINE_CONFIG_TEST(programs/wscript/tests)
3214 WINE_CONFIG_PROGRAM(wusa,,[install])
3215 WINE_CONFIG_PROGRAM(xcopy,,[install,po])
3216 WINE_CONFIG_MAKEFILE([server],,[install-lib,manpage])
3217 WINE_CONFIG_TOOL(tools,[install-dev,install-lib,manpage])
3218 WINE_CONFIG_TOOL(tools/widl,[install-dev,manpage])
3219 WINE_CONFIG_TOOL(tools/winebuild,[install-dev,manpage])
3220 WINE_CONFIG_TOOL(tools/winedump,[install-dev,manpage])
3221 WINE_CONFIG_TOOL(tools/winegcc,[install-dev,manpage])
3222 WINE_CONFIG_TOOL(tools/wmc,[install-dev,manpage])
3223 WINE_CONFIG_TOOL(tools/wrc,[install-dev,manpage])
3224
3225 AC_SUBST([LINGUAS],["\
3226 ar \
3227 bg \
3228 ca \
3229 cs \
3230 da \
3231 de \
3232 el \
3233 en \
3234 en_US \
3235 eo \
3236 es \
3237 fa \
3238 fi \
3239 fr \
3240 he \
3241 hi \
3242 hu \
3243 it \
3244 ja \
3245 ko \
3246 lt \
3247 ml \
3248 nb_NO \
3249 nl \
3250 or \
3251 pa \
3252 pl \
3253 pt_BR \
3254 pt_PT \
3255 rm \
3256 ro \
3257 ru \
3258 sk \
3259 sl \
3260 sr_RS@cyrillic \
3261 sr_RS@latin \
3262 sv \
3263 te \
3264 th \
3265 tr \
3266 uk \
3267 wa \
3268 zh_CN \
3269 zh_TW"])
3270
3271 dnl End of auto-generated output commands
3272
3273 AC_CONFIG_COMMANDS([Makefile], [wine_fn_output_makefile Makefile],
3274 [wine_fn_output_makefile ()
3275 {
3276     cat Make.tmp - <<\_WINE_EOF >\$tmp/makefile && mv -f \$tmp/makefile \$[]1 && rm -f Make.tmp && return
3277 $ALL_MAKEFILE_DEPENDS
3278 _WINE_EOF
3279     AS_ERROR([could not create Makefile])
3280 }])
3281
3282 AC_CONFIG_FILES([Make.tmp:Make.vars.in:Makefile.in])
3283
3284 dnl Some final makefile rules
3285
3286 if test "x$enable_maintainer_mode" = xyes
3287 then
3288     WINE_APPEND_RULE([ALL_MAKEFILE_DEPENDS],
3289 [\$(srcdir)/configure: configure.ac aclocal.m4
3290         cd \$(srcdir) && autoconf --warnings=all
3291 \$(srcdir)/include/config.h.in: include/stamp-h.in
3292 \$(srcdir)/include/stamp-h.in: configure.ac aclocal.m4
3293         cd \$(srcdir) && autoheader --warnings=all
3294         @echo timestamp > \$[@]])
3295 fi
3296
3297 if test "x$with_gettextpo" = xyes
3298 then
3299     test "$srcdir" = . || AC_MSG_ERROR([Rebuilding po files is not supported for out of tree builds.])
3300     WINE_APPEND_RULE([ALL_MAKEFILE_DEPENDS],
3301 [ALL_POT_FILES =$ALL_POT_FILES
3302 \$(LINGUAS:%=po/%.po): \$(srcdir)/po/wine.pot
3303         msgmerge --previous -q \$[@] \$(srcdir)/po/wine.pot | msgattrib --no-obsolete -o \$[@].new && mv \$[@].new \$[@]
3304 \$(srcdir)/po/wine.pot: \$(ALL_POT_FILES)
3305         msgcat -o \$[@] \$(ALL_POT_FILES)])
3306 fi
3307
3308 if test "$MSGFMT" != false
3309 then
3310     AC_SUBST([PORCFLAGS],["--po-dir=\$(top_builddir)/po"])
3311     WINE_APPEND_RULE([ALL_MAKEFILE_DEPENDS],[__builddeps__: \$(ALL_MO_FILES)])
3312 else
3313     LINGUAS=
3314 fi
3315
3316 if test "x$enable_tools" != xno
3317 then
3318     WINE_APPEND_RULE([ALL_MAKEFILE_DEPENDS],
3319 [\$(MAKEDEP): tools/Makefile
3320 clean:: __clean__
3321         \$(RM) tools/makedep\$(EXEEXT)])
3322 fi
3323
3324 if test -n "$with_wine64"
3325 then
3326 WINE_APPEND_RULE([ALL_MAKEFILE_DEPENDS],
3327 [all: fonts server tools $with_wine64/loader/wine $with_wine64/loader/wine-preloader
3328 fonts server tools:
3329         \$(RM) \$[@] && \$(LN_S) $with_wine64/\$[@] \$[@]
3330 $with_wine64/loader/wine:
3331         \$(RM) \$[@] && \$(LN_S) $ac_pwd/loader/wine \$[@]
3332 $with_wine64/loader/wine-preloader:
3333         \$(RM) \$[@] && \$(LN_S) $ac_pwd/loader/wine-preloader \$[@]
3334 clean::
3335         \$(RM) fonts server tools $with_wine64/loader/wine $with_wine64/loader/wine-preloader])
3336 fi
3337
3338 AC_OUTPUT
3339
3340 if test "$no_create" = "yes"
3341 then
3342   exit 0
3343 fi
3344
3345 WINE_PRINT_MESSAGES
3346
3347 echo "
3348 $as_me: Finished.  Do '${ac_make}' to compile Wine.
3349 " >&AS_MESSAGE_FD
3350
3351 dnl Local Variables:
3352 dnl comment-start: "dnl "
3353 dnl comment-end: ""
3354 dnl comment-start-skip: "\\bdnl\\b\\s *"
3355 dnl compile-command: "autoreconf --warnings=all"
3356 dnl End: