git.oblomov.eu Git - wine/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Original author: Michael Patra
   3 dnl See ChangeLog file for detailed change history.
   4
   5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
   6
   7 AC_PREREQ(2.53)
   8 AC_INIT([Wine],WINE_VERSION,[wine-devel@winehq.org])
   9 AC_CONFIG_SRCDIR(server/atom.c)
  10 AC_CONFIG_HEADERS(include/config.h)
  11 AC_CONFIG_AUX_DIR(tools)
  12
  13 dnl **** Command-line arguments ****
  14
  15 AC_ARG_ENABLE(win16, AC_HELP_STRING([--disable-win16],[do not include Win16 support]))
  16 AC_ARG_ENABLE(debug, AC_HELP_STRING([--disable-debug],[compile out all debugging messages]))
  17 AC_ARG_ENABLE(trace, AC_HELP_STRING([--disable-trace],[compile out TRACE messages]))
  18 AC_ARG_ENABLE(win64, AC_HELP_STRING([--enable-win64], [build a Win64 emulator on AMD64 (won't run Win32 binaries)]))
  19
  20 AC_ARG_WITH(opengl,    AC_HELP_STRING([--without-opengl],[do not use OpenGL]))
  21 AC_ARG_WITH(curses,    AC_HELP_STRING([--without-curses],[do not use curses]))
  22 AC_ARG_WITH(wine-tools,AC_HELP_STRING([--with-wine-tools=<dir>],[use Wine tools from directory <dir>]))
  23
  24 AC_SUBST(WIN16_FILES,"\$(WIN16_FILES)")
  25 AC_SUBST(WIN16_INSTALL,"\$(WIN16_INSTALL)")
  26 if test "x$enable_win16" = "xno"
  27 then
  28   WIN16_FILES=""
  29   WIN16_INSTALL=""
  30 fi
  31
  32 AC_SUBST(DLLDEFS,"")
  33 if test "x$enable_debug" = "xno"
  34 then
  35   DLLDEFS="$DLLDEFS -DWINE_NO_DEBUG_MSGS"
  36 fi
  37 if test "x$enable_trace" = "xno" -o "x$enable_debug" = "xno"
  38 then
  39   DLLDEFS="$DLLDEFS -DWINE_NO_TRACE_MSGS"
  40 fi
  41
  42 dnl **** Check for some programs ****
  43
  44 AC_CANONICAL_HOST
  45 case $host in
  46   x86_64*linux*)
  47     if test "x$enable_win64" != "xyes"
  48     then
  49       test -n "$CC" || CC="gcc -m32"
  50       test -n "$LD" || LD="ld -m elf_i386"
  51       test -n "$AS" || AS="as --32"
  52     fi
  53     ;;
  54 esac
  55
  56 AC_PROG_MAKE_SET
  57 AC_PROG_CC
  58 AC_PROG_CXX
  59 dnl We can't use AC_PROG_CPP for winegcc, it uses by default $(CC) -E
  60 AC_CHECK_TOOL(CPPBIN,cpp,cpp)
  61
  62 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
  63   [if test -z "$with_wine_tools"; then
  64      if test "$cross_compiling" = "yes"; then
  65        AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
  66      else
  67        wine_cv_toolsdir="\$(TOPOBJDIR)"
  68      fi
  69    elif test -d "$with_wine_tools/tools/winebuild"; then
  70      case $with_wine_tools in
  71        /*) wine_cv_toolsdir="$with_wine_tools" ;;
  72        *)  wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
  73      esac
  74    else
  75      AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
  76    fi])
  77 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
  78
  79 AC_PATH_XTRA
  80 AC_PROG_LEX
  81
  82 dnl **** Just additional warning checks, since AC_PROG just sets 'lex' even
  83 dnl **** without one present.
  84 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
  85 if test "$XLEX" = "none"
  86 then
  87   AC_MSG_ERROR([no suitable lex found. Please install the 'flex' package.])
  88 fi
  89
  90 dnl Check for bison
  91 AC_CHECK_PROGS(BISON,bison,none)
  92 if test "$BISON" = "none"
  93 then
  94   AC_MSG_ERROR([no suitable bison found. Please install the 'bison' package.])
  95 fi
  96
  97 AC_CHECK_TOOLS(AS,[gas as],as)
  98 AC_CHECK_TOOL(LD,ld,ld)
  99 AC_CHECK_TOOL(AR,ar,ar)
 100 AC_PROG_RANLIB
 101 AC_CHECK_TOOL(STRIP,strip,strip)
 102 AC_CHECK_TOOL(WINDRES,windres,false)
 103 AC_PROG_LN_S
 104 WINE_PROG_LN
 105 AC_PROG_EGREP
 106 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
 107 AC_PROG_INSTALL
 108 dnl Prepend src dir to install path dir if it's a relative path
 109 case "$INSTALL" in
 110   [[\\/$]]* | ?:[[\\/]]* ) ;;
 111   *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
 112 esac
 113
 114 dnl Check for lint
 115 AC_CHECK_PROGS(LINT, lclint lint)
 116 if test "$LINT" = "lint"
 117 then
 118   LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
 119   dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
 120 fi
 121 AC_SUBST(LINT)
 122 AC_SUBST(LINTFLAGS)
 123
 124 dnl Check for various programs
 125 AC_CHECK_PROGS(DB2HTML, docbook2html db2html, false)
 126 AC_CHECK_PROGS(DB2PDF, docbook2pdf db2pdf, false)
 127 AC_CHECK_PROGS(DB2PS, docbook2ps db2ps, false)
 128 AC_CHECK_PROGS(DB2TXT, docbook2txt db2txt, false)
 129 AC_CHECK_PROGS(FONTFORGE, fontforge, false)
 130
 131 dnl **** Check for some libraries ****
 132
 133 dnl Check for -li386 for NetBSD and OpenBSD
 134 AC_CHECK_LIB(i386,i386_set_ldt)
 135 dnl Check for -lossaudio for NetBSD
 136 AC_CHECK_LIB(ossaudio,_oss_ioctl)
 137 dnl Check for -lw for Solaris
 138 AC_CHECK_FUNCS(iswalnum,,AC_CHECK_LIB(w,iswalnum))
 139 dnl Check for -lnsl for Solaris
 140 AC_CHECK_FUNCS(gethostbyname,,AC_CHECK_LIB(nsl,gethostbyname))
 141 dnl Check for -lsocket for Solaris
 142 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
 143 dnl Check for -lresolv for Solaris
 144 AC_CHECK_FUNCS(inet_aton,,AC_CHECK_LIB(resolv,inet_aton))
 145 dnl Check for -lxpg4 for FreeBSD
 146 AC_CHECK_LIB(xpg4,_xpg4_setrunelocale)
 147 dnl Check for -lpoll for Mac OS X/Darwin
 148 AC_CHECK_LIB(poll,poll)
 149 dnl Check for -lresolv for Mac OS X/Darwin
 150 AC_CHECK_LIB(resolv,res_9_init)
 151 dnl Check for -lpthread
 152 AC_CHECK_LIB(pthread,pthread_create,AC_SUBST(LIBPTHREAD,"-lpthread"))
 153
 154 AC_SUBST(XLIB)
 155 AC_SUBST(XFILES)
 156 XFILES=""
 157 AC_SUBST(OPENGLFILES)
 158 OPENGLFILES=""
 159 AC_SUBST(GLU32FILES)
 160 GLU32FILES=""
 161 AC_SUBST(OPENGL_LIBS)
 162 OPENGL_LIBS=""
 163
 164 dnl **** Check for header files ****
 165
 166 AC_CHECK_HEADERS(\
 167         arpa/inet.h \
 168         arpa/nameser.h \
 169         cups/cups.h \
 170         direct.h \
 171         elf.h \
 172         float.h \
 173         fontconfig/fontconfig.h \
 174         getopt.h \
 175         gif_lib.h \
 176         ieeefp.h \
 177         io.h \
 178         jack/jack.h \
 179         jpeglib.h \
 180         lcms/lcms.h \
 181         lcms.h \
 182         link.h \
 183         linux/cdrom.h \
 184         linux/compiler.h \
 185         linux/hdreg.h \
 186         linux/input.h \
 187         linux/ioctl.h \
 188         linux/joystick.h \
 189         linux/major.h \
 190         linux/param.h \
 191         linux/serial.h \
 192         linux/ucdrom.h \
 193         machine/cpu.h \
 194         mntent.h \
 195         netdb.h \
 196         netinet/in.h \
 197         netinet/in_systm.h \
 198         netinet/tcp.h \
 199         netinet/tcp_fsm.h \
 200         openssl/ssl.h \
 201         process.h \
 202         pthread.h \
 203         pwd.h \
 204         regex.h \
 205         sched.h \
 206         scsi/sg.h \
 207         scsi/scsi.h \
 208         scsi/scsi_ioctl.h \
 209         stdint.h \
 210         strings.h \
 211         sys/cdio.h \
 212         sys/elf32.h \
 213         sys/errno.h \
 214         sys/epoll.h \
 215         sys/exec_elf.h \
 216         sys/filio.h \
 217         sys/ioctl.h \
 218         sys/ipc.h \
 219         sys/link.h \
 220         sys/lwp.h \
 221         sys/mman.h \
 222         sys/modem.h \
 223         sys/msg.h \
 224         sys/param.h \
 225         sys/poll.h \
 226         sys/ptrace.h \
 227         sys/reg.h \
 228         sys/scsiio.h \
 229         sys/shm.h \
 230         sys/signal.h \
 231         sys/socket.h \
 232         sys/sockio.h \
 233         sys/statfs.h \
 234         sys/statvfs.h \
 235         sys/strtio.h \
 236         sys/syscall.h \
 237         sys/sysctl.h \
 238         sys/time.h \
 239         sys/times.h \
 240         sys/uio.h \
 241         sys/un.h \
 242         sys/vfs.h \
 243         sys/vm86.h \
 244         sys/wait.h \
 245         syscall.h \
 246         termios.h \
 247         unistd.h \
 248         utime.h \
 249         valgrind/memcheck.h
 250 )
 251 AC_HEADER_STAT()
 252
 253 dnl **** Check for X11 ****
 254
 255 if test "$have_x" = "yes"
 256 then
 257     XLIB="-lXext -lX11"
 258     ac_save_CPPFLAGS="$CPPFLAGS"
 259     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 260
 261     dnl *** All of the following tests require X11/Xlib.h
 262     AC_CHECK_HEADERS(X11/Xlib.h,
 263       [
 264         AC_CHECK_HEADERS([X11/XKBlib.h \
 265                           X11/Xutil.h \
 266                           X11/extensions/shape.h \
 267                           X11/extensions/XInput.h \
 268                           X11/extensions/XShm.h \
 269                           X11/extensions/Xrandr.h \
 270                           X11/extensions/Xrender.h \
 271                           X11/extensions/xf86dga.h \
 272                           X11/extensions/xf86vmode.h],,,
 273                          [#include <X11/Xlib.h>
 274                           #ifdef HAVE_X11_XUTIL_H
 275                           # include <X11/Xutil.h>
 276                           #endif])
 277
 278         dnl *** Check for X keyboard extension
 279         if test "$ac_cv_header_X11_XKBlib_h" = "yes"
 280         then
 281               AC_CHECK_LIB(X11, XkbQueryExtension,
 282               AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
 283               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 284         fi
 285
 286         dnl *** Check for X Shm extension
 287         if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
 288         then
 289               AC_CHECK_LIB(Xext, XShmQueryExtension,
 290               AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
 291               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 292         fi
 293
 294         dnl *** Check for X shape extension
 295         if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
 296         then
 297               AC_CHECK_LIB(Xext,XShapeQueryExtension,
 298               AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
 299               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 300         fi
 301
 302         dnl *** Check for XFree86 DGA / DGA 2.0 extension
 303         if test "$ac_cv_header_X11_extensions_xf86dga_h" = "yes"
 304         then
 305               AC_CHECK_LIB(Xxf86dga, XDGAQueryExtension,
 306                 [ AC_DEFINE(HAVE_LIBXXF86DGA2, 1,
 307                             [Define if you have the Xxf86dga library version 2])
 308                   X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
 309                 ],,
 310                 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 311         fi
 312
 313         dnl *** Check for XFree86 VMODE extension
 314         if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
 315         then
 316                 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
 317                   [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
 318                      X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
 319                   ],,
 320                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 321         fi
 322
 323         dnl *** Check for X RandR extension
 324         if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes"
 325         then
 326                 AC_TRY_COMPILE([#include <X11/Xlib.h>
 327 #include <X11/extensions/Xrandr.h>],[static typeof(XRRSetScreenConfigAndRate) * func;],
 328                   [AC_DEFINE(HAVE_LIBXRANDR, 1, [Define if you have the Xrandr library])])
 329         fi
 330
 331         dnl *** Check for Transform functions in Xrender
 332         if test "$ac_cv_header_X11_extensions_Xrender_h" = "yes"
 333         then
 334               AC_CHECK_LIB(Xrender, XRenderSetPictureTransform,
 335                 [AC_DEFINE(HAVE_XRENDERSETPICTURETRANSFORM, 1,
 336                  [Define if Xrender has the XRenderSetPictureTransform function])],,
 337                 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 338         fi
 339       ]
 340     ) dnl *** End of X11/Xlib.h check
 341
 342     dnl Check for the presence of OpenGL
 343     if test "x$with_opengl" != "xno"
 344     then
 345         if test -f /usr/X11R6/lib/libGL.a -a ! -f /usr/X11R6/lib/libGL.so
 346         then
 347             AC_MSG_ERROR([/usr/X11R6/lib/libGL.a is present on your system.
 348 This prevents linking to OpenGL. Delete the file and restart configure.])
 349         fi
 350
 351         AC_CHECK_HEADERS(GL/gl.h GL/glx.h)
 352         if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
 353         then
 354             AC_CHECK_HEADERS(GL/glext.h,,,[#include <GL/glx.h>])
 355             dnl Check for some problems due to old Mesa versions
 356             AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_version_OK,
 357               AC_TRY_COMPILE(
 358                 [#include <GL/gl.h>],
 359                 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
 360                 [wine_cv_opengl_version_OK="yes"],
 361                 [wine_cv_opengl_version_OK="no"]
 362               )
 363             )
 364
 365             if test "$wine_cv_opengl_version_OK" = "yes"
 366             then
 367                 dnl Check for the presence of the library
 368                 AC_CHECK_LIB(GL,glXCreateContext,
 369                              OPENGL_LIBS="-lGL"
 370                              ,,
 371                              $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 372
 373                 if test "$ac_cv_lib_GL_glXCreateContext" = "yes"
 374                 then
 375                         OPENGLFILES='$(OPENGLFILES)'
 376                         AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])
 377                 fi
 378                 dnl Check for GLU32 library.
 379                 AC_CHECK_LIB(GLU,gluLookAt,
 380                              [OPENGL_LIBS="$OPENGL_LIBS -lGLU"
 381                              GLU32FILES='$(GLU32FILES)']
 382                              ,,
 383                              $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS
 384                 )
 385              fi
 386
 387              dnl Check for glut32 library.
 388              AC_CHECK_LIB(glut,glutMainLoop,
 389                        [AC_SUBST(GLUT_LIBS,"-lglut -lXmu -lXi")
 390                         AC_SUBST(GLUT32FILES,'$(GLUT32FILES)')],,
 391                         $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXmu -lXi -lX11 $X_EXTRA_LIBS)
 392          fi
 393     fi
 394
 395     dnl **** Check for NAS ****
 396     AC_SUBST(NASLIBS,"")
 397     AC_CHECK_HEADERS(audio/audiolib.h,
 398          [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
 399           AC_CHECK_LIB(audio,AuCreateFlow,
 400                        [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
 401                         NASLIBS="-laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],,
 402                        [-lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
 403
 404     CPPFLAGS="$ac_save_CPPFLAGS"
 405     XFILES='$(XFILES)'
 406 else
 407     XLIB=""
 408     X_CFLAGS=""
 409     X_LIBS=""
 410 fi
 411
 412 dnl **** Check which curses lib to use ***
 413 CURSESLIBS=""
 414 if test "x$with_curses" != "xno"
 415 then
 416     AC_CHECK_HEADERS(ncurses.h,
 417         [AC_CHECK_LIB(ncurses,waddch,
 418             [AC_DEFINE(HAVE_LIBNCURSES, 1, [Define if you have the ncurses library (-lncurses)])
 419              CURSESLIBS="-lncurses"],
 420              [AC_CHECK_HEADERS(curses.h,
 421                  [AC_CHECK_LIB(curses,waddch,
 422                      [AC_DEFINE(HAVE_LIBCURSES, 1, [Define if you have the curses library (-lcurses)])
 423                       CURSESLIBS="-lcurses"])])])])
 424 fi
 425 AC_SUBST(CURSESLIBS)
 426
 427 dnl **** Check for SANE ****
 428 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
 429 if test "$sane_devel" = "no"
 430 then
 431     SANELIBS=""
 432     SANEINCL=""
 433 else
 434     SANELIBS="`$sane_devel --libs`"
 435     SANEINCL="`$sane_devel --cflags`"
 436     ac_save_CPPFLAGS="$CPPFLAGS"
 437     ac_save_LIBS="$LIBS"
 438     CPPFLAGS="$CPPFLAGS $SANEINCL"
 439     LIBS="$LIBS $SANELIBS"
 440     AC_CHECK_HEADER(sane/sane.h,
 441                     [AC_CHECK_LIB(sane,sane_open,
 442                                   [AC_DEFINE(HAVE_SANE, 1, [Define if we have SANE development environment])],
 443                                   [SANELIBS=""
 444                                   SANEINCL=""])],
 445                     [SANELIBS=""
 446                     SANEINCL=""])
 447     LIBS="$ac_save_LIBS"
 448     CPPFLAGS="$ac_save_CPPFLAGS"
 449 fi
 450 AC_SUBST(SANELIBS)
 451 AC_SUBST(SANEINCL)
 452
 453 dnl **** Check for the ICU library ****
 454 AC_CHECK_HEADERS(unicode/ubidi.h)
 455 if test "$ac_cv_header_unicode_ubidi_h" = "yes"
 456 then
 457     saved_libs="$LIBS"
 458     ICU_LIB_DIR="${ICU_LIB_DIR-/usr/lib}"
 459     ICUUC_LIB="${ICUUC_LIB-$ICU_LIB_DIR/libsicuuc.a}"
 460     ICUDATA_LIB="${ICUDATA_LIB-$ICU_LIB_DIR/libsicudata.a}"
 461     AC_MSG_CHECKING(whether can link with ICU libraries $ICUUC_LIB and $ICUDATA_LIB)
 462     LIBS="$LIBS $ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s"
 463     AC_TRY_LINK([#include <unicode/ubidi.h>],[ubidi_open()],
 464                 [AC_DEFINE(HAVE_ICU,1,[Define to 1 if the ICU libraries are installed])
 465                  AC_SUBST(ICULIBS,"$ICUUC_LIB $ICUDATA_LIB -lstdc++ -lgcc_s")
 466                  AC_MSG_RESULT(yes)],
 467                 [AC_MSG_RESULT(no)])
 468     LIBS="$saved_libs"
 469 fi
 470
 471 dnl **** Check for FreeType 2 ****
 472 AC_CHECK_LIB(freetype,FT_Init_FreeType,ft_lib=yes,ft_lib=no,$X_LIBS)
 473 if test "$ft_lib" = "no"
 474 then
 475     FREETYPELIBS=""
 476     FREETYPEINCL=""
 477     wine_cv_msg_freetype=no
 478 else
 479     AC_CHECK_PROG(ft_devel,freetype-config,freetype-config,no)
 480     if test "$ft_devel" = "no"
 481     then
 482         AC_CHECK_PROG(ft_devel2,freetype2-config,freetype2-config,no)
 483         if test "$ft_devel2" = "freetype2-config"
 484         then
 485                 ft_devel=$ft_devel2
 486         fi
 487     fi
 488     if test "$ft_devel" = "no"
 489     then
 490         FREETYPELIBS=""
 491         FREETYPEINCL=""
 492         wine_cv_msg_freetype=yes
 493     else
 494         FREETYPELIBS=`$ft_devel --libs`
 495         FREETYPEINCL=`$ft_devel --cflags`
 496         ac_save_CPPFLAGS="$CPPFLAGS"
 497         CPPFLAGS="$FREETYPEINCL $CPPFLAGS"
 498         AC_CHECK_HEADERS(ft2build.h \
 499                          freetype/freetype.h \
 500                          freetype/ftglyph.h \
 501                          freetype/tttables.h \
 502                          freetype/ftnames.h \
 503                          freetype/ftsnames.h \
 504                          freetype/ttnameid.h \
 505                          freetype/ftoutln.h \
 506                          freetype/ftwinfnt.h \
 507                          freetype/internal/sfnt.h,,,
 508                          [#if HAVE_FT2BUILD_H
 509                           #include <ft2build.h>
 510                           #endif])
 511         AC_TRY_CPP([#include <ft2build.h>
 512                     #include <freetype/fttrigon.h>],
 513                     [AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
 514           [Define if you have the <freetype/fttrigon.h> header file.])
 515                     wine_cv_fttrigon=yes],
 516                     wine_cv_fttrigon=no)
 517         CPPFLAGS="$ac_save_CPPFLAGS"
 518         dnl Check that we have at least freetype/freetype.h
 519         if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
 520         then
 521             AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
 522             wine_cv_msg_freetype=no
 523         else
 524             FREETYPELIBS=""
 525             FREETYPEINCL=""
 526             wine_cv_msg_freetype=yes
 527         fi
 528     fi
 529 fi
 530 AC_SUBST(FREETYPELIBS)
 531 AC_SUBST(FREETYPEINCL)
 532
 533 dnl Only build the fonts dir if we have both freetype and fontforge
 534 if test "$FONTFORGE" != "false" -a -n "$FREETYPELIBS"
 535 then
 536   AC_SUBST(FONTSSUBDIRS,"fonts")
 537 fi
 538
 539 dnl **** Check for parport (currently Linux only) ****
 540 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
 541  AC_TRY_COMPILE(
 542    [#include <linux/ppdev.h>],
 543    [ioctl (1,PPCLAIM,0)],
 544    [ac_cv_c_ppdev="yes"],
 545    [ac_cv_c_ppdev="no"])
 546  )
 547 if test "$ac_cv_c_ppdev" = "yes"
 548 then
 549     AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
 550 fi
 551
 552 dnl **** Check for va_copy ****
 553 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
 554  AC_TRY_LINK(
 555    [#include <stdarg.h>],
 556    [va_list ap1, ap2;
 557     va_copy(ap1,ap2);
 558    ],
 559    [ac_cv_c_va_copy="yes"],
 560    [ac_cv_c_va_copy="no"])
 561  )
 562 if test "$ac_cv_c_va_copy" = "yes"
 563 then
 564     AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
 565 fi
 566 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
 567  AC_TRY_LINK(
 568    [#include <stdarg.h>],
 569    [va_list ap1, ap2;
 570     __va_copy(ap1,ap2);
 571    ],
 572    [ac_cv_c___va_copy="yes"],
 573    [ac_cv_c___va_copy="no"])
 574  )
 575 if test "$ac_cv_c___va_copy" = "yes"
 576 then
 577     AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
 578 fi
 579
 580 dnl **** Check for sigsetjmp ****
 581 AC_CACHE_CHECK([for sigsetjmp], ac_cv_c_sigsetjmp,
 582  AC_TRY_LINK(
 583    [#include <setjmp.h>],
 584    [sigjmp_buf buf;
 585     sigsetjmp( buf, 1 );
 586     siglongjmp( buf, 1 );],
 587    [ac_cv_c_sigsetjmp="yes"],
 588    [ac_cv_c_sigsetjmp="no"])
 589  )
 590 if test "$ac_cv_c_sigsetjmp" = "yes"
 591 then
 592     AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have the sigsetjmp (and siglongjmp) function])
 593 fi
 594
 595 dnl **** Check for pthread_rwlock_t ****
 596 AC_CHECK_TYPES([pthread_rwlock_t, pthread_rwlockattr_t],,,[#define _GNU_SOURCE
 597 #include <pthread.h>])
 598
 599 dnl **** Check for pthread functions ****
 600 ac_save_LIBS="$LIBS"
 601 LIBS="$LIBS $LIBPTHREAD"
 602 AC_CHECK_FUNCS(\
 603         pthread_getattr_np \
 604         pthread_get_stackaddr_np \
 605         pthread_get_stacksize_np \
 606 )
 607 LIBS="$ac_save_LIBS"
 608
 609 dnl **** Check for Open Sound System ****
 610 AC_CHECK_HEADERS(sys/soundcard.h machine/soundcard.h soundcard.h, break)
 611
 612 AC_CACHE_CHECK([for Open Sound System],
 613         ac_cv_c_opensoundsystem,
 614         AC_TRY_COMPILE([
 615         #if defined(HAVE_SYS_SOUNDCARD_H)
 616                 #include <sys/soundcard.h>
 617         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 618                 #include <machine/soundcard.h>
 619         #elif defined(HAVE_SOUNDCARD_H)
 620                 #include <soundcard.h>
 621         #endif
 622         ],[
 623
 624 /* check for one of the Open Sound System specific SNDCTL_ defines */
 625 #if !defined(SNDCTL_DSP_STEREO)
 626 #error No open sound system
 627 #endif
 628 ],ac_cv_c_opensoundsystem="yes",ac_cv_c_opensoundsystem="no"))
 629
 630 if test "$ac_cv_c_opensoundsystem" = "yes"
 631 then
 632     AC_DEFINE(HAVE_OSS, 1, [Define if you have the Open Sound system])
 633 fi
 634
 635 AC_CACHE_CHECK([for Open Sound System/MIDI interface],
 636         ac_cv_c_opensoundsystem_midi,
 637         AC_TRY_COMPILE([
 638         #if defined(HAVE_SYS_SOUNDCARD_H)
 639                 #include <sys/soundcard.h>
 640         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 641                 #include <machine/soundcard.h>
 642         #elif defined(HAVE_SOUNDCARD_H)
 643                 #include <soundcard.h>
 644         #endif
 645         ],[
 646
 647 /* check for one of the Open Sound System specific SNDCTL_SEQ defines */
 648 #if !defined(SNDCTL_SEQ_SYNC)
 649 #error No open sound system MIDI interface
 650 #endif
 651 ],ac_cv_c_opensoundsystem_midi="yes",ac_cv_c_opensoundsystem_midi="no"))
 652
 653 if test "$ac_cv_c_opensoundsystem_midi" = "yes"
 654 then
 655     AC_DEFINE(HAVE_OSS_MIDI, 1, [Define if you have the Open Sound system (MIDI interface)])
 656 fi
 657
 658 dnl **** Check for aRts Sound Server ****
 659 AC_PATH_PROG(ARTSCCONFIG, artsc-config)
 660 if test x$ARTSCCONFIG != x -a x$ARTSCCONFIG != x'"$ARTSCCONFIG"';
 661 then
 662     ARTSC_CFLAGS=""
 663     for i in `$ARTSCCONFIG --cflags`
 664     do
 665       case "$i" in
 666         -I*) ARTSC_CFLAGS="$ARTSC_CFLAGS $i";;
 667       esac
 668     done
 669     ARTSC_LIBS=`$ARTSCCONFIG --libs`
 670     save_CFLAGS="$CFLAGS"
 671     CFLAGS="$CFLAGS $ARTSC_CFLAGS"
 672     AC_TRY_COMPILE([#include <artsc.h>],[arts_stream_t stream;],
 673         [AC_SUBST(ARTSLIBS, $ARTSC_LIBS)
 674          AC_SUBST(ARTSINCL, $ARTSC_CFLAGS)
 675          AC_DEFINE(HAVE_ARTS, 1, [Define if you have ARTS sound server])])
 676     CFLAGS="$save_CFLAGS"
 677 fi
 678
 679 dnl **** Check for ALSA 1.x ****
 680 AC_SUBST(ALSALIBS,"")
 681 AC_CHECK_HEADERS(alsa/asoundlib.h sys/asoundlib.h, break)
 682 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
 683 then
 684     AC_CHECK_LIB(asound,snd_pcm_hw_params_get_access,
 685         [AC_TRY_COMPILE([#ifdef HAVE_ALSA_ASOUNDLIB_H
 686 #include <alsa/asoundlib.h>
 687 #elif defined(HAVE_SYS_ASOUNDLIB_H)
 688 #include <sys/asoundlib.h>
 689 #endif],
 690                         [int ret = snd_pcm_hw_params_get_access(NULL, NULL)],
 691                         [AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA 1.x including devel headers])
 692                          ALSALIBS="-lasound"])])
 693 fi
 694
 695 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
 696
 697 AC_SUBST(AUDIOIOLIBS,"")
 698 AC_CHECK_HEADERS(libaudioio.h,
 699     [AC_CHECK_LIB(audioio,AudioIOGetVersion,
 700                   [AUDIOIOLIBS="-laudioio"
 701                    AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])])
 702
 703 dnl **** Check for capi4linux ****
 704
 705 AC_CHECK_HEADERS(capi20.h,[
 706         AC_CHECK_HEADERS(linux/capi.h,[
 707                 AC_CHECK_LIB(capi20,capi20_register,[
 708                         AC_DEFINE(HAVE_CAPI4LINUX,1,[Define if you have capi4linux libs and headers])
 709                 ])
 710         ])
 711 ])
 712
 713 dnl **** Check for broken glibc mmap64 ****
 714
 715 AC_CACHE_CHECK( [whether mmap64 works defined as mmap], ac_cv_mmap64_works,
 716         AC_TRY_RUN([
 717                 #define _FILE_OFFSET_BITS 64
 718                 #include <stdio.h>
 719                 #include <unistd.h>
 720                 #include <fcntl.h>
 721                 #include <sys/mman.h>
 722                 #include <errno.h>
 723
 724                 int main(int argc,char **argv) {
 725                         int fd = open("conftest.map",O_CREAT|O_RDWR,0600);
 726                         if (fd == -1) exit(1);
 727
 728                         unlink("conftest.map");
 729
 730                         write(fd,"test",4);
 731
 732                         if ((-1 == mmap(0,4,PROT_READ|PROT_WRITE,MAP_SHARED,fd,0)) &&
 733                             (errno == EINVAL)
 734                         ) {
 735                                 exit(1);
 736                         }
 737                         close(fd);
 738                         fprintf(stderr,"success!\n");
 739                         exit(0);
 740                 }
 741
 742         ],
 743     ac_cv_mmap64_works="yes",
 744     ac_cv_mmap64_works="no",
 745     ac_cv_mmap64_works="no") )
 746
 747 if test "$ac_cv_mmap64_works" = "yes"
 748 then
 749     AC_DEFINE(_FILE_OFFSET_BITS, 64, [Set this to 64 to enable 64-bit file support on Linux])
 750 fi
 751
 752 dnl **** Check for gcc specific options ****
 753
 754 AC_SUBST(EXTRACFLAGS,"")
 755 if test "x${GCC}" = "xyes"
 756 then
 757   EXTRACFLAGS="-Wall -pipe"
 758
 759   dnl Check for strength-reduce bug
 760   AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
 761                   AC_TRY_RUN([
 762 int     L[[4]] = {0,1,2,3};
 763 int main(void) {
 764   static int Array[[3]];
 765   unsigned int B = 3;
 766   int i;
 767   for(i=0; i<B; i++) Array[[i]] = i - 3;
 768   for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
 769   L[[i]] = 4;
 770
 771   exit( Array[[1]] != -2 || L[[2]] != 3);
 772 }],
 773     ac_cv_c_gcc_strength_bug="no",
 774     ac_cv_c_gcc_strength_bug="yes",
 775     ac_cv_c_gcc_strength_bug="yes") )
 776   if test "$ac_cv_c_gcc_strength_bug" = "yes"
 777   then
 778     EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
 779   fi
 780
 781   dnl Check for -fshort-wchar
 782   AC_CACHE_CHECK([for gcc -fshort-wchar support], ac_cv_c_gcc_fshort_wchar,
 783       [WINE_TRY_CFLAGS([-fshort-wchar],
 784                       ac_cv_c_gcc_fshort_wchar="yes",ac_cv_c_gcc_fshort_wchar="no")])
 785   if test "$ac_cv_c_gcc_fshort_wchar" = "yes"
 786   then
 787       AC_DEFINE(CC_FLAG_SHORT_WCHAR, "-fshort-wchar", [Specifies the compiler flag that forces a short wchar_t])
 788   fi
 789
 790   dnl Check for -mpreferred-stack-boundary
 791   AC_CACHE_CHECK([for gcc -mpreferred-stack-boundary=2 support], ac_cv_c_gcc_stack_boundary,
 792       [WINE_TRY_CFLAGS([-mpreferred-stack-boundary=2],
 793                       ac_cv_c_gcc_stack_boundary="yes",ac_cv_c_gcc_stack_boundary="no")])
 794   if test "$ac_cv_c_gcc_stack_boundary" = "yes"
 795   then
 796     EXTRACFLAGS="$EXTRACFLAGS -mpreferred-stack-boundary=2"
 797   fi
 798
 799   dnl Check for -fno-strict-aliasing
 800   AC_CACHE_CHECK([for gcc -fno-strict-aliasing support], ac_cv_c_gcc_no_strict_aliasing,
 801       [WINE_TRY_CFLAGS([-fno-strict-aliasing],
 802                       ac_cv_c_gcc_no_strict_aliasing="yes",ac_cv_c_gcc_no_strict_aliasing="no")])
 803   if test "$ac_cv_c_gcc_no_strict_aliasing" = "yes"
 804   then
 805     EXTRACFLAGS="$EXTRACFLAGS -fno-strict-aliasing"
 806   fi
 807
 808   dnl Check for -gstabs+ option
 809   AC_CACHE_CHECK([for gcc -gstabs+ support], ac_cv_c_gcc_gstabs,
 810       [WINE_TRY_CFLAGS([-gstabs+],ac_cv_c_gcc_gstabs="yes", ac_cv_c_gcc_gstabs="no")])
 811   if test "$ac_cv_c_gcc_gstabs" = "yes"
 812   then
 813     EXTRACFLAGS="$EXTRACFLAGS -gstabs+"
 814   fi
 815
 816   dnl Check for noisy string.h
 817   saved_CFLAGS="$CFLAGS"
 818   CFLAGS="$CFLAGS -Wpointer-arith -Werror"
 819   AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
 820       AC_TRY_COMPILE([#include <string.h>],[],
 821                      [ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
 822   CFLAGS="$saved_CFLAGS"
 823   if test "$ac_cv_c_string_h_warnings" = "no"
 824   then
 825     EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
 826   fi
 827 fi
 828
 829 dnl **** Check how to define a function in assembly code ****
 830
 831 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
 832   WINE_TRY_ASM_LINK(
 833       ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
 834       ac_cv_asm_func_def=".def",
 835     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
 836       ac_cv_asm_func_def=".type @function",
 837     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
 838       ac_cv_asm_func_def=".type 2",
 839       ac_cv_asm_func_def="unknown")])]))
 840
 841 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
 842 case "$ac_cv_asm_func_def" in
 843   ".def")
 844      AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
 845   ".type @function")
 846      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
 847   ".type 2")
 848      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
 849   *)
 850      AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
 851 esac
 852
 853 dnl **** Check for underscore on external symbols ****
 854
 855 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
 856     WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
 857                       [extern int ac_test;],
 858                       [if (ac_test) return 1],
 859                       ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
 860
 861 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
 862 if test "$ac_cv_c_extern_prefix" = "yes"
 863 then
 864   AC_DEFINE([__ASM_NAME(name)], ["_" name])
 865 else
 866   AC_DEFINE([__ASM_NAME(name)], [name])
 867 fi
 868
 869 dnl **** Check how to do strings in assembler ****
 870
 871 AC_CACHE_CHECK([for assembler keyword for ASCII strings], ac_cv_c_asm_string,
 872     WINE_TRY_ASM_LINK([".data\\n\\t.string \\"test\\"\\n\\t.text"],,,ac_cv_c_asm_string=".string",
 873       WINE_TRY_ASM_LINK([".data\\n\\t.asciz \\"test\\"\\n\\t.text"],,,ac_cv_c_asm_string=".asciz",
 874         WINE_TRY_ASM_LINK([".data\\n\\t.ascii \\"test\\"\\n\\t.text"],,,ac_cv_c_asm_string=".ascii",
 875           AC_MSG_ERROR([could not discover how to produce C strings with assembler.])))))
 876
 877 AC_DEFINE_UNQUOTED(__ASM_STRING, ["$ac_cv_c_asm_string"],
 878                    [Define to the assembler keyword used to specify an ASCII string])
 879
 880 dnl **** Check for .short in assembler ****
 881
 882 AC_CACHE_CHECK([for assembler keyword for word values], ac_cv_c_asm_short,
 883     WINE_TRY_ASM_LINK([".data\\n\\t.short 1\\n\\t.text"],,,ac_cv_c_asm_short=".short",
 884       WINE_TRY_ASM_LINK([".data\\n\\t.half 1\\n\\t.text"],,,ac_cv_c_asm_short=".half",
 885         AC_MSG_ERROR([could not discover how to specify word values with assembler.]))))
 886
 887 AC_DEFINE_UNQUOTED(__ASM_SHORT, ["$ac_cv_c_asm_short"],
 888                    [Define to the assembler keyword used to specify a word value])
 889
 890 dnl **** Check for .size in assembler ****
 891
 892 AC_CACHE_CHECK([for .size in assembler], ac_cv_c_asm_size,
 893     WINE_TRY_ASM_LINK([".globl _ac_test\n.size _ac_test, . - _ac_test"],,,
 894                       ac_cv_c_asm_size="yes",ac_cv_c_asm_size="no"))
 895
 896 if test "$ac_cv_c_asm_size" = "yes"
 897 then
 898   AC_DEFINE(HAVE_ASM_DOT_SIZE, 1, [Define if the assembler keyword .size is accepted])
 899 fi
 900
 901 dnl **** Check for working dll ****
 902
 903 AC_SUBST(DLLEXT,"")
 904 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
 905 AC_SUBST(DLLIBS,"")
 906 AC_SUBST(LDSHARED,"")
 907 AC_SUBST(LDDLLFLAGS,"")
 908 AC_SUBST(LIBEXT,"so")
 909 AC_SUBST(IMPLIBEXT,"def")
 910
 911 case $host_os in
 912   cygwin*|mingw32*)
 913     AC_CHECK_TOOL(DLLTOOL,dlltool,false)
 914     AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
 915     if test "$DLLWRAP" = "false"; then
 916       LIBEXT="a"
 917     else
 918       dnl FIXME - check whether dllwrap works correctly...
 919       LIBEXT="dll"
 920     fi
 921     IMPLIBEXT="a"
 922     dnl We can't build 16-bit NE dlls
 923     WIN16_FILES=""
 924     WIN16_INSTALL=""
 925     ;;
 926   *)
 927     AC_CHECK_HEADERS(dlfcn.h,
 928         [AC_CHECK_FUNCS(dlopen,,
 929             [AC_CHECK_LIB(dl,dlopen,
 930                          [AC_DEFINE(HAVE_DLOPEN,1,[Define if you have dlopen])
 931                           DLLIBS="-ldl"],
 932                          [LIBEXT="a"])])],
 933         [LIBEXT="a"])
 934
 935     if test "$LIBEXT" = "so"
 936     then
 937       DLLFLAGS="$DLLFLAGS -fPIC"
 938       DLLEXT=".so"
 939       AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
 940           [WINE_TRY_SHLIB_FLAGS([-fPIC -shared -Wl,-soname,conftest.so.1.0,-Bsymbolic],
 941                                 ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
 942       if test "$ac_cv_c_dll_gnuelf" = "yes"
 943       then
 944         LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"
 945         LDDLLFLAGS="-shared -Wl,-Bsymbolic"
 946         AC_CACHE_CHECK([whether the linker accepts -z defs], ac_cv_c_dll_zdefs,
 947           [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs],
 948                            ac_cv_c_dll_zdefs="yes",ac_cv_c_dll_zdefs="no")])
 949         if test "$ac_cv_c_dll_zdefs" = "yes"
 950         then
 951           LDDLLFLAGS="$LDDLLFLAGS,-z,defs"
 952         fi
 953
 954         AC_CACHE_CHECK([whether the linker accepts -init and -fini], ac_cv_c_dll_init_fini,
 955           [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-init,__wine_spec_init,-fini,__wine_spec_fini],
 956                            ac_cv_c_dll_init_fini="yes",ac_cv_c_dll_init_fini="no")])
 957         if test "$ac_cv_c_dll_init_fini" = "yes"
 958         then
 959           LDDLLFLAGS="$LDDLLFLAGS,-init,__wine_spec_init,-fini,__wine_spec_fini"
 960         fi
 961
 962         AC_CACHE_CHECK([whether the linker accepts version scripts], ac_cv_c_ld_version_scripts,
 963           [echo '{ global: *; };' >conftest.map
 964            WINE_TRY_CFLAGS([-fPIC -shared -Wl,--version-script=conftest.map],
 965                            ac_cv_c_ld_version_scripts="yes",ac_cv_c_ld_version_scripts="no")
 966            rm -f conftest.map])
 967         if test "$ac_cv_c_ld_version_scripts" = "yes"
 968         then
 969           LDSHARED="$LDSHARED \$(VERSCRIPT:%=-Wl,--version-script=%)"
 970         fi
 971
 972         AC_CACHE_CHECK([whether the linker accepts --export-dynamic], ac_cv_c_export_dynamic,
 973           [WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
 974                            ac_cv_c_export_dynamic="yes",ac_cv_c_export_dynamic="no")])
 975         if test "$ac_cv_c_export_dynamic" = "yes"
 976         then
 977           AC_SUBST(LDEXECFLAGS,["-Wl,--export-dynamic"])
 978         fi
 979
 980         case $host_cpu in
 981           *i[[3456789]]86*)
 982             AC_CACHE_CHECK([whether we can relocate the executable to 0x77f00000], ac_cv_ld_reloc_exec,
 983               [WINE_TRY_CFLAGS([-Wl,--section-start,.interp=0x77f00400],
 984                                ac_cv_ld_reloc_exec="yes", ac_cv_ld_reloc_exec="no")])
 985             if test "$ac_cv_ld_reloc_exec" = "yes"
 986             then
 987               LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x77f00400"
 988             fi
 989             ;;
 990         esac
 991
 992       else
 993         AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
 994             [WINE_TRY_SHLIB_FLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
 995                                   ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
 996         if test "$ac_cv_c_dll_unixware" = "yes"
 997         then
 998           LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
 999           LDDLLFLAGS="-Wl,-G,-B,symbolic"
1000
1001         else
1002           AC_CACHE_CHECK(whether we can build a Mach-O (Mac OS X/Darwin) dll, ac_cv_c_dll_macho,
1003             [WINE_TRY_SHLIB_FLAGS([-bundle], ac_cv_c_dll_macho="yes", ac_cv_c_dll_macho="no")])
1004           if test "$ac_cv_c_dll_macho" = "yes"
1005           then
1006             LIBEXT="dylib"
1007             LDDLLFLAGS="-bundle -flat_namespace -undefined suppress"
1008             LDSHARED="\$(CC) -dynamiclib"
1009             CFLAGS="$CFLAGS -ffixed-r13 -no-cpp-precomp"
1010             STRIP="$STRIP -u -r"
1011             dnl Relocate wine executable
1012             AC_SUBST(LDEXECFLAGS,"-seg1addr 0x120000")
1013             dnl Relocate libwine.dyld too
1014             AC_SUBST(LDLIBWINEFLAGS,"-seg1addr 0x140000")
1015             dnl declare needed frameworks
1016             AC_SUBST(COREFOUNDATIONLIB,"-framework CoreFoundation")
1017             AC_SUBST(IOKITLIB,"-framework IOKit")
1018             dnl using IOKit imply we use CoreFoundation too
1019             IOKITLIB = "$IOKITLIB $COREFOUNDATIONLIB"
1020           else
1021             AC_CACHE_CHECK(whether we can build an HP-UX dll, ac_cv_c_dll_hpux,
1022               [WINE_TRY_SHLIB_FLAGS([-shared], ac_cv_c_dll_hpux="yes", ac_cv_c_dll_hpux="no")])
1023             if test "$ac_cv_c_dll_hpux" = "yes"
1024             then
1025               LIBEXT="sl"
1026               DLLEXT=".sl"
1027               LDDLLFLAGS="-shared -fPIC"
1028               LDSHARED="\$(CC) -shared"
1029             fi
1030           fi
1031         fi
1032       fi
1033     fi
1034
1035     dnl Check for cross compiler to build test programs
1036     AC_SUBST(CROSSTEST,"")
1037     if test "$cross_compiling" = "no"
1038     then
1039       AC_CHECK_PROGS(CROSSCC,i586-mingw32msvc-gcc i386-mingw32msvc-gcc i386-mingw32-gcc mingw-gcc,false)
1040       AC_CHECK_PROGS(DLLTOOL,i586-mingw32msvc-dlltool i386-mingw32msvc-dlltool i386-mingw32-dlltool mingw-dlltool,false)
1041       AC_CHECK_PROGS(CROSSWINDRES,i586-mingw32msvc-windres i386-mingw32msvc-windres i386-mingw32-windres mingw-windres,false)
1042       if test "$CROSSCC" != "false"; then CROSSTEST="\$(CROSSTEST)"; fi
1043     fi
1044     ;;
1045 esac
1046
1047 if test "$LIBEXT" = "a"; then
1048   AC_MSG_ERROR(
1049 [could not find a way to build shared libraries.
1050 It is currently not possible to build Wine without shared library
1051 (.so) support to allow transparent switch between .so and .dll files.
1052 If you are using Linux, you will need a newer binutils.]
1053 )
1054 fi
1055
1056 case $build_os in
1057   cygwin*|mingw32*)
1058     AC_SUBST(LDPATH,"PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$PATH\"") ;;
1059   darwin*|macosx*)
1060     AC_SUBST(LDPATH,"DYLD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$DYLD_LIBRARY_PATH\"") ;;
1061   *)
1062     AC_SUBST(LDPATH,"LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/unicode:\$\$LD_LIBRARY_PATH\"") ;;
1063 esac
1064
1065 dnl Mingw needs explicit msvcrt for linking libwine and winsock for wininet
1066 case $host_os in
1067   mingw32*)
1068     AC_SUBST(CRTLIBS,"-lmsvcrt")
1069     AC_SUBST(SOCKETLIBS,"-lws2_32")
1070     ;;
1071 esac
1072
1073 case $host_os in
1074   linux*)
1075     case $host_cpu in
1076       *i[[3456789]]86*) AC_SUBST(WINE_BINARIES,"wine-glibc wine-kthread wine-pthread wine-preloader") ;;
1077       *) AC_SUBST(WINE_BINARIES,"wine-glibc wine-kthread wine-pthread") ;;
1078     esac
1079     AC_SUBST(MAIN_BINARY,"wine-glibc")
1080     ;;
1081   darwin*)
1082     AC_SUBST(WINE_BINARIES,"wine-pthread")
1083     AC_SUBST(MAIN_BINARY,"wine-pthread")
1084     ;;
1085   *)
1086     AC_SUBST(WINE_BINARIES,"wine-kthread")
1087     AC_SUBST(MAIN_BINARY,"wine-kthread")
1088     ;;
1089 esac
1090
1091 dnl **** Get the soname for libraries that we load dynamically ****
1092
1093 if test "$LIBEXT" = "so" -o "$LIBEXT" = "dylib"
1094 then
1095   WINE_GET_SONAME(X11,XCreateWindow,[$X_LIBS $X_EXTRA_LIBS])
1096   WINE_GET_SONAME(Xext,XextCreateExtension,[$X_LIBS -lX11 $X_EXTRA_LIBS])
1097   WINE_GET_SONAME(Xi,XOpenDevice,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1098   WINE_GET_SONAME(Xrender,XRenderQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1099   WINE_GET_SONAME(Xrandr,XRRQueryExtension,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
1100   WINE_GET_SONAME(freetype,FT_Init_FreeType,[$X_LIBS])
1101   WINE_GET_SONAME(GL,glXQueryExtension,[$X_LIBS $X_EXTRA_LIBS])
1102   WINE_GET_SONAME(txc_dxtn,fetch_2d_texel_rgba_dxt1)
1103   WINE_GET_SONAME(cups,cupsGetDefault)
1104   WINE_GET_SONAME(jack,jack_client_new)
1105   WINE_GET_SONAME(fontconfig,FcInit)
1106   WINE_GET_SONAME(ssl,SSL_library_init)
1107   WINE_GET_SONAME(crypto,BIO_new_socket)
1108   WINE_GET_SONAME(ncurses,waddch)
1109   WINE_GET_SONAME(curses,waddch)
1110   WINE_GET_SONAME(jpeg,jpeg_start_decompress)
1111   WINE_GET_SONAME(ungif,DGifOpen)
1112   WINE_GET_SONAME(gif,DGifOpen)
1113   WINE_GET_SONAME(lcms,cmsOpenProfileFromFile)
1114   WINE_GET_SONAME(capi20,capi20_isinstalled)
1115 fi
1116
1117
1118 dnl **** Check for functions ****
1119
1120 AC_FUNC_ALLOCA()
1121 AC_CHECK_FUNCS(\
1122         _lwp_create \
1123         _lwp_self \
1124         _pclose \
1125         _popen \
1126         _snprintf \
1127         _spawnvp \
1128         _stricmp \
1129         _strnicmp \
1130         _vsnprintf \
1131         chsize \
1132         clone \
1133         epoll_create \
1134         ffs \
1135         finite \
1136         fork \
1137         fpclass \
1138         fstatfs \
1139         fstatvfs \
1140         ftruncate \
1141         futimes \
1142         getnetbyname \
1143         getopt_long \
1144         getpagesize \
1145         getprotobyname \
1146         getprotobynumber \
1147         getpwuid \
1148         getservbyport \
1149         gettid \
1150         gettimeofday \
1151         getuid \
1152         inet_network \
1153         lstat \
1154         memmove \
1155         mmap \
1156         pclose \
1157         popen \
1158         pread \
1159         pwrite \
1160         readlink \
1161         rfork \
1162         sched_yield \
1163         select \
1164         sendmsg \
1165         settimeofday \
1166         sigaltstack \
1167         sigprocmask \
1168         snprintf \
1169         spawnvp \
1170         statfs \
1171         statvfs \
1172         strcasecmp \
1173         strerror \
1174         strncasecmp \
1175         tcgetattr \
1176         timegm \
1177         usleep \
1178         vsnprintf \
1179         wait4 \
1180         waitpid \
1181 )
1182
1183 dnl **** Checks for headers that depend on other ones ****
1184
1185 AC_CHECK_HEADERS(sys/mount.h sys/user.h,,,
1186     [#include <sys/types.h>
1187      #if HAVE_SYS_PARAM_H
1188      # include <sys/param.h>
1189      #endif])
1190
1191 AC_CHECK_HEADERS([net/if.h net/if_arp.h net/if_dl.h net/if_types.h net/route.h],,,
1192     [#include <sys/types.h>
1193      #if HAVE_SYS_SOCKET_H
1194      # include <sys/socket.h>
1195      #endif])
1196
1197 AC_CHECK_HEADERS([resolv.h],,,
1198     [#include <sys/types.h>
1199      #if HAVE_SYS_SOCKET_H
1200      # include <sys/socket.h>
1201      #endif
1202      #if HAVE_NETINET_IN_H
1203      # include <netinet/in.h>
1204      #endif
1205      #if HAVE_ARPA_NAMESER_H
1206      # include <arpa/nameser.h>
1207      #endif])
1208
1209 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
1210
1211 dnl **** Check for IPX headers (currently Linux only) ****
1212
1213 AC_CACHE_CHECK([for GNU style IPX support], ac_cv_c_ipx_gnu,
1214  AC_TRY_COMPILE(
1215    [#include <sys/types.h>
1216     #ifdef HAVE_SYS_SOCKET_H
1217     # include <sys/socket.h>
1218     #endif
1219     #include <netipx/ipx.h>],
1220    [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
1221    [ac_cv_c_ipx_gnu="yes"],
1222    [ac_cv_c_ipx_gnu="no"])
1223  )
1224 if test "$ac_cv_c_ipx_gnu" = "yes"
1225 then
1226     AC_DEFINE(HAVE_IPX_GNU, 1, [Define if IPX should use netipx/ipx.h from libc])
1227 fi
1228
1229 if test "$ac_cv_c_ipx_gnu" = "no"
1230 then
1231  AC_CACHE_CHECK([for linux style IPX support], ac_cv_c_ipx_linux,
1232   AC_TRY_COMPILE(
1233     [#include <sys/types.h>
1234      #ifdef HAVE_SYS_SOCKET_H
1235      # include <sys/socket.h>
1236      #endif
1237      #include <asm/types.h>
1238      #include <linux/ipx.h>],
1239     [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
1240     [ac_cv_c_ipx_linux="yes"],
1241     [ac_cv_c_ipx_linux="no"])
1242   )
1243   if test "$ac_cv_c_ipx_linux" = "yes"
1244   then
1245       AC_DEFINE(HAVE_IPX_LINUX, 1, [Define if IPX includes are taken from Linux kernel])
1246   fi
1247 fi
1248
1249 dnl **** Check for types ****
1250
1251 AC_C_CONST
1252 AC_C_INLINE
1253 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t, long long, fsblkcnt_t, fsfilcnt_t])
1254 AC_CHECK_TYPES([sigset_t],,,[#include <signal.h>])
1255
1256 AC_CACHE_CHECK([whether linux/input.h is for real],
1257         wine_cv_linux_input_h,
1258         AC_TRY_COMPILE([
1259             #include <linux/input.h>
1260         ] , [
1261             int foo = EVIOCGBIT(EV_ABS,42);
1262             int bar = BTN_PINKIE;
1263             int fortytwo = 42;
1264         ],
1265         wine_cv_linux_input_h=yes,
1266         wine_cv_linux_input_h=no,
1267         no
1268         )
1269     )
1270     if test "$wine_cv_linux_input_h" = "yes"
1271     then
1272         AC_DEFINE(HAVE_CORRECT_LINUXINPUT_H, 1,
1273                   [Define if we have linux/input.h AND it contains the INPUT event API])
1274     fi
1275
1276 AC_CACHE_CHECK([for sigaddset],wine_cv_have_sigaddset,
1277                AC_TRY_LINK([#include <signal.h>],[sigset_t set; sigaddset(&set,SIGTERM);],
1278                            wine_cv_have_sigaddset=yes,wine_cv_have_sigaddset=no))
1279 if test "$wine_cv_have_sigaddset" = "yes"
1280 then
1281   AC_DEFINE(HAVE_SIGADDSET, 1, [Define if sigaddset is supported])
1282 fi
1283
1284
1285 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1286         wine_cv_linux_gethostbyname_r_6,
1287         AC_TRY_LINK([
1288 #include <netdb.h>
1289         ], [
1290     char *name=NULL;
1291     struct hostent he;
1292     struct hostent *result;
1293     char *buf=NULL;
1294     int bufsize=0;
1295     int res,errnr;
1296     char *addr=NULL;
1297     int addrlen=0;
1298     int addrtype=0;
1299     res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1300     res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1301     ],
1302         wine_cv_linux_gethostbyname_r_6=yes,
1303         wine_cv_linux_gethostbyname_r_6=no
1304         )
1305    )
1306    if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1307    then
1308       AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1309                 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1310    fi
1311
1312 if test "$ac_cv_header_linux_joystick_h" = "yes"
1313 then
1314    AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1315         wine_cv_linux_joystick_22_api,
1316         AC_TRY_COMPILE([
1317         #include <sys/ioctl.h>
1318         #include <linux/joystick.h>
1319
1320         struct js_event blub;
1321         #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1322         #error "no 2.2 header"
1323         #endif
1324         ],/*empty*/,
1325         wine_cv_linux_joystick_22_api=yes,
1326         wine_cv_linux_joystick_22_api=no,
1327         wine_cv_linux_joystick_22_api=no
1328         )
1329    )
1330    if test "$wine_cv_linux_joystick_22_api" = "yes"
1331    then
1332       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1333                 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1334    fi
1335 fi
1336
1337 dnl **** statfs checks ****
1338
1339 if test "$ac_cv_header_sys_vfs_h" = "yes"
1340 then
1341     AC_CACHE_CHECK( [whether sys/vfs.h defines statfs],
1342                     wine_cv_sys_vfs_has_statfs,
1343         AC_TRY_COMPILE([
1344         #include <sys/types.h>
1345         #ifdef HAVE_SYS_PARAM_H
1346         # include <sys/param.h>
1347         #endif
1348         #include <sys/vfs.h>
1349         ],[
1350                 struct statfs stfs;
1351
1352                 memset(&stfs,0,sizeof(stfs));
1353         ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
1354         )
1355     )
1356     if test "$wine_cv_sys_vfs_has_statfs" = "yes"
1357     then
1358       AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS, 1,
1359                 [Define if the struct statfs is defined by <sys/vfs.h>])
1360     fi
1361 fi
1362
1363 if test "$ac_cv_header_sys_statfs_h" = "yes"
1364 then
1365     AC_CACHE_CHECK( [whether sys/statfs.h defines statfs],
1366                     wine_cv_sys_statfs_has_statfs,
1367         AC_TRY_COMPILE([
1368         #include <sys/types.h>
1369         #ifdef HAVE_SYS_PARAM_H
1370         # include <sys/param.h>
1371         #endif
1372         #include <sys/statfs.h>
1373         ],[
1374                 struct statfs stfs;
1375         ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
1376         )
1377     )
1378     if test "$wine_cv_sys_statfs_has_statfs" = "yes"
1379     then
1380       AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS, 1,
1381                 [Define if the struct statfs is defined by <sys/statfs.h>])
1382     fi
1383 fi
1384
1385 if test "$ac_cv_header_sys_mount_h" = "yes"
1386 then
1387     AC_CACHE_CHECK( [whether sys/mount.h defines statfs],
1388                     wine_cv_sys_mount_has_statfs,
1389         AC_TRY_COMPILE([
1390         #include <sys/types.h>
1391         #ifdef HAVE_SYS_PARAM_H
1392         # include <sys/param.h>
1393         #endif
1394         #include <sys/mount.h>
1395         ],[
1396                 struct statfs stfs;
1397         ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
1398         )
1399     )
1400     if test "$wine_cv_sys_mount_has_statfs" = "yes"
1401     then
1402       AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT, 1,
1403                 [Define if the struct statfs is defined by <sys/mount.h>])
1404     fi
1405 fi
1406
1407 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1408
1409 dnl Check for statfs members
1410 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail, struct statfs.f_frsize, struct statfs.f_ffree, struct statfs.f_favail, struct statfs.f_namelen],,,
1411 [#include <sys/types.h>
1412 #ifdef HAVE_SYS_PARAM_H
1413 # include <sys/param.h>
1414 #endif
1415 #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1416 # include <sys/mount.h>
1417 #else
1418 # ifdef STATFS_DEFINED_BY_SYS_VFS
1419 #  include <sys/vfs.h>
1420 # else
1421 #  ifdef STATFS_DEFINED_BY_SYS_STATFS
1422 #   include <sys/statfs.h>
1423 #  endif
1424 # endif
1425 #endif])
1426
1427 AC_CHECK_MEMBERS([struct statvfs.f_blocks],,,
1428 [#ifdef HAVE_SYS_STATVFS_H
1429 #include <sys/statvfs.h>
1430 #endif])
1431
1432 dnl Check for socket structure members
1433 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
1434 [#include <sys/types.h>
1435 #ifdef HAVE_SYS_SOCKET_H
1436 # include <sys/socket.h>
1437 #endif
1438 #ifdef HAVE_SYS_UN_H
1439 # include <sys/un.h>
1440 #endif])
1441
1442 dnl Check for siginfo_t members
1443 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
1444
1445 dnl Check for struct option
1446 AC_CHECK_MEMBERS([struct option.name],,,
1447 [#ifdef HAVE_GETOPT_H
1448 #include <getopt.h>
1449 #endif])
1450
1451 dnl Check for stat.st_blocks
1452 AC_CHECK_MEMBERS([struct stat.st_blocks])
1453
1454 dnl *** check for the need to define platform-specific symbols
1455
1456 case $host_cpu in
1457   *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
1458   *alpha*)          WINE_CHECK_DEFINE([__ALPHA__]) ;;
1459   *sparc*)          WINE_CHECK_DEFINE([__sparc__]) ;;
1460   *powerpc*)        WINE_CHECK_DEFINE([__powerpc__]) ;;
1461 esac
1462
1463 case $host_vendor in
1464   *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
1465 esac
1466
1467 dnl **** Generate output files ****
1468
1469 AH_TOP([#define __WINE_CONFIG_H])
1470
1471 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/d3ddevice)
1472 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dclipper)
1473 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/ddraw)
1474 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/direct3d)
1475 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dpalette)
1476 WINE_CONFIG_EXTRA_DIR(dlls/ddraw/dsurface)
1477 WINE_CONFIG_EXTRA_DIR(dlls/gdi/enhmfdrv)
1478 WINE_CONFIG_EXTRA_DIR(dlls/gdi/mfdrv)
1479 WINE_CONFIG_EXTRA_DIR(dlls/kernel/messages)
1480 WINE_CONFIG_EXTRA_DIR(dlls/user/dde)
1481 WINE_CONFIG_EXTRA_DIR(dlls/user/resources)
1482 WINE_CONFIG_EXTRA_DIR(dlls/wineps/data)
1483 WINE_CONFIG_EXTRA_DIR(include/wine)
1484 WINE_CONFIG_EXTRA_DIR(misc)
1485 WINE_CONFIG_EXTRA_DIR(programs/regedit/tests)
1486 WINE_CONFIG_EXTRA_DIR(windows)
1487
1488 MAKE_RULES=Make.rules
1489 AC_SUBST_FILE(MAKE_RULES)
1490
1491 MAKE_DLL_RULES=dlls/Makedll.rules
1492 AC_SUBST_FILE(MAKE_DLL_RULES)
1493
1494 MAKE_TEST_RULES=dlls/Maketest.rules
1495 AC_SUBST_FILE(MAKE_TEST_RULES)
1496
1497 MAKE_LIB_RULES=libs/Makelib.rules
1498 AC_SUBST_FILE(MAKE_LIB_RULES)
1499
1500 MAKE_PROG_RULES=programs/Makeprog.rules
1501 AC_SUBST_FILE(MAKE_PROG_RULES)
1502
1503 AC_CONFIG_FILES([
1504 Make.rules
1505 dlls/Makedll.rules
1506 dlls/Maketest.rules
1507 libs/Makelib.rules
1508 programs/Makeprog.rules
1509 Makefile
1510 dlls/Makefile
1511 dlls/advapi32/Makefile
1512 dlls/advapi32/tests/Makefile
1513 dlls/advpack/Makefile
1514 dlls/amstream/Makefile
1515 dlls/atl/Makefile
1516 dlls/avicap32/Makefile
1517 dlls/avifil32/Makefile
1518 dlls/cabinet/Makefile
1519 dlls/capi2032/Makefile
1520 dlls/cards/Makefile
1521 dlls/cfgmgr32/Makefile
1522 dlls/comcat/Makefile
1523 dlls/comctl32/Makefile
1524 dlls/comctl32/tests/Makefile
1525 dlls/commdlg/Makefile
1526 dlls/crtdll/Makefile
1527 dlls/crypt32/Makefile
1528 dlls/ctl3d/Makefile
1529 dlls/d3d8/Makefile
1530 dlls/d3d9/Makefile
1531 dlls/d3dim/Makefile
1532 dlls/d3drm/Makefile
1533 dlls/d3dx8/Makefile
1534 dlls/d3dxof/Makefile
1535 dlls/dbghelp/Makefile
1536 dlls/dciman32/Makefile
1537 dlls/ddraw/Makefile
1538 dlls/ddraw/tests/Makefile
1539 dlls/devenum/Makefile
1540 dlls/dinput/Makefile
1541 dlls/dinput8/Makefile
1542 dlls/dmband/Makefile
1543 dlls/dmcompos/Makefile
1544 dlls/dmime/Makefile
1545 dlls/dmloader/Makefile
1546 dlls/dmscript/Makefile
1547 dlls/dmstyle/Makefile
1548 dlls/dmsynth/Makefile
1549 dlls/dmusic/Makefile
1550 dlls/dmusic32/Makefile
1551 dlls/dplay/Makefile
1552 dlls/dplayx/Makefile
1553 dlls/dpnet/Makefile
1554 dlls/dpnhpast/Makefile
1555 dlls/dsound/Makefile
1556 dlls/dsound/tests/Makefile
1557 dlls/dswave/Makefile
1558 dlls/dxdiagn/Makefile
1559 dlls/dxerr8/Makefile
1560 dlls/dxerr9/Makefile
1561 dlls/dxguid/Makefile
1562 dlls/gdi/Makefile
1563 dlls/gdi/tests/Makefile
1564 dlls/glu32/Makefile
1565 dlls/glut32/Makefile
1566 dlls/hhctrl.ocx/Makefile
1567 dlls/iccvid/Makefile
1568 dlls/icmp/Makefile
1569 dlls/ifsmgr.vxd/Makefile
1570 dlls/imagehlp/Makefile
1571 dlls/imm32/Makefile
1572 dlls/iphlpapi/Makefile
1573 dlls/iphlpapi/tests/Makefile
1574 dlls/itss/Makefile
1575 dlls/kernel/Makefile
1576 dlls/kernel/tests/Makefile
1577 dlls/lzexpand/Makefile
1578 dlls/lzexpand/tests/Makefile
1579 dlls/mapi32/Makefile
1580 dlls/mapi32/tests/Makefile
1581 dlls/mlang/Makefile
1582 dlls/mlang/tests/Makefile
1583 dlls/mmdevldr.vxd/Makefile
1584 dlls/monodebg.vxd/Makefile
1585 dlls/mpr/Makefile
1586 dlls/msacm/Makefile
1587 dlls/msacm/imaadp32/Makefile
1588 dlls/msacm/msadp32/Makefile
1589 dlls/msacm/msg711/Makefile
1590 dlls/msacm/winemp3/Makefile
1591 dlls/msacm/tests/Makefile
1592 dlls/mscms/Makefile
1593 dlls/mscms/tests/Makefile
1594 dlls/msdmo/Makefile
1595 dlls/mshtml/Makefile
1596 dlls/msi/Makefile
1597 dlls/msi/tests/Makefile
1598 dlls/msimg32/Makefile
1599 dlls/msisys/Makefile
1600 dlls/msnet32/Makefile
1601 dlls/msrle32/Makefile
1602 dlls/msvcrt/Makefile
1603 dlls/msvcrt/tests/Makefile
1604 dlls/msvcrt20/Makefile
1605 dlls/msvcrt40/Makefile
1606 dlls/msvcrtd/Makefile
1607 dlls/msvcrtd/tests/Makefile
1608 dlls/msvidc32/Makefile
1609 dlls/msvideo/Makefile
1610 dlls/mswsock/Makefile
1611 dlls/netapi32/Makefile
1612 dlls/netapi32/tests/Makefile
1613 dlls/newdev/Makefile
1614 dlls/ntdll/Makefile
1615 dlls/ntdll/tests/Makefile
1616 dlls/odbc32/Makefile
1617 dlls/ole32/Makefile
1618 dlls/ole32/tests/Makefile
1619 dlls/oleacc/Makefile
1620 dlls/oleaut32/Makefile
1621 dlls/oleaut32/tests/Makefile
1622 dlls/olecli/Makefile
1623 dlls/oledlg/Makefile
1624 dlls/olepro32/Makefile
1625 dlls/olesvr/Makefile
1626 dlls/opengl32/Makefile
1627 dlls/psapi/Makefile
1628 dlls/psapi/tests/Makefile
1629 dlls/qcap/Makefile
1630 dlls/quartz/Makefile
1631 dlls/quartz/tests/Makefile
1632 dlls/rasapi32/Makefile
1633 dlls/richedit/Makefile
1634 dlls/rpcrt4/Makefile
1635 dlls/rpcrt4/tests/Makefile
1636 dlls/rsabase/Makefile
1637 dlls/rsabase/tests/Makefile
1638 dlls/rsaenh/Makefile
1639 dlls/rsaenh/tests/Makefile
1640 dlls/secur32/Makefile
1641 dlls/serialui/Makefile
1642 dlls/setupapi/Makefile
1643 dlls/shdocvw/Makefile
1644 dlls/shell32/Makefile
1645 dlls/shell32/tests/Makefile
1646 dlls/shfolder/Makefile
1647 dlls/shlwapi/Makefile
1648 dlls/shlwapi/tests/Makefile
1649 dlls/snmpapi/Makefile
1650 dlls/sti/Makefile
1651 dlls/strmiids/Makefile
1652 dlls/tapi32/Makefile
1653 dlls/ttydrv/Makefile
1654 dlls/twain/Makefile
1655 dlls/unicows/Makefile
1656 dlls/url/Makefile
1657 dlls/urlmon/Makefile
1658 dlls/urlmon/tests/Makefile
1659 dlls/user/Makefile
1660 dlls/user/tests/Makefile
1661 dlls/uuid/Makefile
1662 dlls/uxtheme/Makefile
1663 dlls/vdhcp.vxd/Makefile
1664 dlls/vdmdbg/Makefile
1665 dlls/version/Makefile
1666 dlls/version/tests/Makefile
1667 dlls/vmm.vxd/Makefile
1668 dlls/vnbt.vxd/Makefile
1669 dlls/vnetbios.vxd/Makefile
1670 dlls/vtdapi.vxd/Makefile
1671 dlls/vwin32.vxd/Makefile
1672 dlls/win32s/Makefile
1673 dlls/winaspi/Makefile
1674 dlls/wined3d/Makefile
1675 dlls/winedos/Makefile
1676 dlls/wineps/Makefile
1677 dlls/wininet/Makefile
1678 dlls/wininet/tests/Makefile
1679 dlls/winmm/Makefile
1680 dlls/winmm/joystick/Makefile
1681 dlls/winmm/mcianim/Makefile
1682 dlls/winmm/mciavi/Makefile
1683 dlls/winmm/mcicda/Makefile
1684 dlls/winmm/mciseq/Makefile
1685 dlls/winmm/mciwave/Makefile
1686 dlls/winmm/midimap/Makefile
1687 dlls/winmm/tests/Makefile
1688 dlls/winmm/wavemap/Makefile
1689 dlls/winmm/winealsa/Makefile
1690 dlls/winmm/winearts/Makefile
1691 dlls/winmm/wineaudioio/Makefile
1692 dlls/winmm/winejack/Makefile
1693 dlls/winmm/winenas/Makefile
1694 dlls/winmm/wineoss/Makefile
1695 dlls/winnls/Makefile
1696 dlls/winsock/Makefile
1697 dlls/winsock/tests/Makefile
1698 dlls/winspool/Makefile
1699 dlls/winspool/tests/Makefile
1700 dlls/wintab32/Makefile
1701 dlls/wintrust/Makefile
1702 dlls/wow32/Makefile
1703 dlls/wsock32/Makefile
1704 dlls/x11drv/Makefile
1705 documentation/Makefile
1706 fonts/Makefile
1707 include/Makefile
1708 libs/Makefile
1709 libs/port/Makefile
1710 libs/unicode/Makefile
1711 libs/wine/Makefile
1712 libs/wpp/Makefile
1713 loader/Makefile
1714 programs/Makefile
1715 programs/avitools/Makefile
1716 programs/clock/Makefile
1717 programs/cmdlgtst/Makefile
1718 programs/control/Makefile
1719 programs/expand/Makefile
1720 programs/msiexec/Makefile
1721 programs/notepad/Makefile
1722 programs/progman/Makefile
1723 programs/regedit/Makefile
1724 programs/regsvr32/Makefile
1725 programs/rpcss/Makefile
1726 programs/rundll32/Makefile
1727 programs/start/Makefile
1728 programs/taskmgr/Makefile
1729 programs/uninstaller/Makefile
1730 programs/view/Makefile
1731 programs/wcmd/Makefile
1732 programs/wineboot/Makefile
1733 programs/winebrowser/Makefile
1734 programs/winecfg/Makefile
1735 programs/wineconsole/Makefile
1736 programs/winedbg/Makefile
1737 programs/winefile/Makefile
1738 programs/winemenubuilder/Makefile
1739 programs/winemine/Makefile
1740 programs/winepath/Makefile
1741 programs/winetest/Makefile
1742 programs/winevdm/Makefile
1743 programs/winhelp/Makefile
1744 programs/winver/Makefile
1745 server/Makefile
1746 tools/Makefile
1747 tools/widl/Makefile
1748 tools/winapi/Makefile
1749 tools/winebuild/Makefile
1750 tools/winedump/Makefile
1751 tools/winegcc/Makefile
1752 tools/wmc/Makefile
1753 tools/wrc/Makefile])
1754
1755 AC_OUTPUT
1756
1757 if test "$have_x" = "no"
1758 then
1759   echo
1760   echo "*** Warning: X development files not found. Wine will be built without"
1761   echo "*** X support, which currently does not work, and would probably not be"
1762   echo "*** what you want anyway. You will need to install devel packages of"
1763   echo "*** Xlib/Xfree86 at the very least."
1764 fi
1765
1766 if test "$wine_cv_opengl_version_OK" = "no"
1767 then
1768   echo
1769   echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
1770   echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)."
1771 fi
1772
1773 if test "$wine_cv_msg_freetype" = "yes"
1774 then
1775   echo
1776   echo "*** Note: Your system appears to have the FreeType 2 runtime libraries"
1777   echo "*** installed, but 'freetype-config' is not in your PATH. Install the"
1778   echo "*** freetype-devel package (or its equivalent on your distribution) to"
1779   echo "*** enable Wine to use TrueType fonts."
1780 fi
1781
1782 echo
1783 echo "Configure finished.  Do '${ac_make} depend && ${ac_make}' to compile Wine."
1784 echo
1785
1786 dnl Local Variables:
1787 dnl comment-start: "dnl "
1788 dnl comment-end: ""
1789 dnl comment-start-skip: "\\bdnl\\b\\s *"
1790 dnl compile-command: "autoconf"
1791 dnl End: