git.oblomov.eu Git - wine/blob - configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Author: Michael Patra   <micky@marie.physik.tu-berlin.de>
   3 dnl                         <patra@itp1.physik.tu-berlin.de>
   4 AC_REVISION([configure.in 1.00])
   5 AC_INIT(controls/edit.c)
   6 AC_CONFIG_HEADER(include/config.h)
   7 AC_CONFIG_AUX_DIR(tools)
   8
   9 dnl **** Command-line arguments ****
  10
  11 dnl Default values
  12 LIBEXT=so       # library type .so or .a
  13 TRACE_MSGS=yes  # the TRACE() macro
  14 DEBUG_MSGS=yes  # the TRACE(), WARN(), and FIXME() macros.
  15 CURSES=yes
  16 OPENGL=normal
  17
  18 AC_ARG_ENABLE(debug,
  19 [  --disable-debug         compile out all debugging messages],
  20 [if test "$enableval" = "no"; then DEBUG_MSGS="no"; fi])
  21
  22 AC_ARG_ENABLE(opengl,
  23 [  --enable-opengl         force usage of OpenGL even if the latter is thread-safe],
  24 [if test "$enableval" = "no"; then OPENGL="no"; elif test "$enableval" = "yes"; then OPENGL="yes"; fi])
  25
  26 AC_ARG_ENABLE(trace,
  27 [  --disable-trace         compile out TRACE messages],
  28 [if test "$enableval" = "no"; then TRACE_MSGS="no"; fi])
  29
  30 AC_ARG_WITH(curses,
  31 [  --without-curses        do not use curses],
  32 [if test "$withval" = "no"; then CURSES="no"; fi])
  33
  34 AC_ARG_WITH(reentrant-x,
  35 [  --without-reentrant-x   compile for use with non-reentrant X libraries])
  36
  37 AC_SUBST(OPTIONS)
  38
  39 if test "$DEBUG_MSGS" = "no"
  40 then
  41     AC_DEFINE(NO_DEBUG_MSGS)
  42     AC_DEFINE(NO_TRACE_MSGS)
  43 else
  44     if test "$TRACE_MSGS" = "no"
  45     then
  46         AC_DEFINE(NO_TRACE_MSGS)
  47     fi
  48 fi
  49
  50 dnl **** Check for some programs ****
  51
  52 AC_PROG_MAKE_SET
  53 AC_PROG_CC
  54 AC_PROG_CPP
  55 AC_PATH_XTRA
  56 AC_PROG_YACC
  57 AC_PROG_LEX
  58 AC_CHECK_PROGS(XLEX,$LEX flex lex,none)
  59 if test "$XLEX" = "none"
  60 then
  61         echo "*** Error: No suitable lex found. ***"
  62         echo "    Please install the 'flex' package."
  63         exit 1
  64 fi
  65 AC_DECL_YYTEXT
  66 AC_PROG_RANLIB
  67 AC_PROG_INSTALL
  68 AC_PROG_LN_S
  69 AC_CHECK_PROG(C2MAN,c2man,c2man,\$(TOPSRCDIR)/tools/c2man.pl)
  70 AC_PATH_PROG(LDCONFIG, ldconfig, true, /sbin:/usr/sbin:$PATH)
  71 AC_CYGWIN
  72 AC_CHECK_PROG(DLLWRAP,dllwrap,dllwrap,false)
  73
  74 dnl Check for lint
  75 AC_CHECK_PROGS(LINT, lclint lint)
  76 if test "$LINT" = "lint"
  77 then
  78   LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
  79   dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
  80 fi
  81 AC_SUBST(LINT)
  82 AC_SUBST(LINTFLAGS)
  83
  84 if test "$CYGWIN" = "yes"
  85 then
  86     LDCOMBINE="ld -r --enable-stdcall-fixup"
  87 else
  88     LDCOMBINE="ld -r"
  89 fi
  90 AC_SUBST(LDCOMBINE)
  91
  92 dnl **** Check for some libraries ****
  93
  94 dnl Check for -lm for BeOS
  95 AC_CHECK_LIB(m,sqrt)
  96 dnl Check for -li386 for NetBSD and OpenBSD
  97 AC_CHECK_LIB(i386,i386_set_ldt)
  98 dnl Check for -lossaudio for NetBSD
  99 AC_CHECK_LIB(ossaudio,_oss_ioctl)
 100 dnl Check for -lw for Solaris
 101 AC_CHECK_LIB(w,iswalnum)
 102 dnl Check for -lnsl for Solaris
 103 AC_CHECK_FUNCS(gethostbyname,, AC_CHECK_LIB(nsl, gethostbyname, X_EXTRA_LIBS="$X_EXTRA_LIBS -lnsl", AC_CHECK_LIB(socket, gethostbyname, X_EXTRA_LIBS="$X_EXTRA_LIBS -lnsl", , -lnsl), -lsocket))
 104 dnl Check for -lsocket for Solaris
 105 AC_CHECK_FUNCS(connect,,AC_CHECK_LIB(socket,connect))
 106 dnl Check for -lxpg4 for FreeBSD
 107 AC_CHECK_LIB(xpg4,setrunelocale)
 108 dnl Check for -lmmap for OS/2
 109 AC_CHECK_LIB(mmap,mmap)
 110 dnl Check for openpty
 111 AC_CHECK_FUNCS(openpty,,
 112         AC_CHECK_LIB(util,openpty,
 113                 AC_DEFINE(HAVE_OPENPTY)
 114                 LIBS="$LIBS -lutil"
 115         ))
 116
 117 AC_CHECK_HEADERS(dlfcn.h,
 118         AC_CHECK_FUNCS(dlopen,
 119                 AC_DEFINE(HAVE_DL_API),
 120                 AC_CHECK_LIB(dl,dlopen,
 121                         AC_DEFINE(HAVE_DL_API)
 122                         LIBS="$LIBS -ldl",
 123                         LIBEXT="a"
 124                 )
 125         ),
 126         LIBEXT="a"
 127 )
 128 AC_SUBST(XLIB)
 129 AC_SUBST(X_DLLS)
 130 X_DLLS=""
 131 AC_SUBST(XFILES)
 132 XFILES=""
 133 AC_SUBST(OPENGLFILES)
 134 OPENGLFILES=""
 135 AC_SUBST(OPENGL32_DLL)
 136 OPENGL32_DLL=""
 137 AC_SUBST(DGA_SRCS)
 138 DGA_SRCS=""
 139 AC_SUBST(DGA2_SRCS)
 140 DGA2_SRCS=""
 141 AC_SUBST(MESA_SRCS)
 142 MESA_SRCS=""
 143 if test "$have_x" = "yes"
 144 then
 145     XLIB="-lXext -lX11"
 146     ac_save_CPPFLAGS="$CPPFLAGS"
 147     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 148
 149     dnl *** Check for -lXpm
 150     AC_CHECK_HEADERS(X11/xpm.h,
 151       [ dnl *** If X11/xpm.h exists...
 152         AC_CHECK_LIB(Xpm, XpmCreatePixmapFromData,
 153           [ AC_DEFINE(HAVE_LIBXXPM) X_PRE_LIBS="$X_PRE_LIBS -lXpm"],,
 154           $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 155         )
 156       ],
 157       [ dnl *** If X11/xpm.h does not exist...
 158         dnl NOTE: autoconf does not allow commas inside the third
 159         dnl       parameter to AC_CHECK_HEADERS, due to some quoting
 160         dnl       magic it does.
 161         echo "Redhat            :       xpm xpm-devel"
 162         echo "Caldera OpenLinux :       xpm xpm-devel xpm-devel-static"
 163         echo "SuSE              :       xpm"
 164         echo "Debian/Corel Linux:       xpm4g xpm4g-dev"
 165         echo
 166         echo "Or get the sources from ftp.x.org and all its mirror sites from "
 167         echo "the directory /contrib/libraries."
 168         echo
 169         exit 1
 170       ]
 171     )
 172
 173     dnl *** All three of the following tests require X11/Xlib.h
 174     AC_CHECK_HEADERS(X11/Xlib.h,
 175       [
 176         dnl *** Check for X Shm extension
 177         AC_CHECK_HEADERS(X11/extensions/XShm.h,
 178             [ dnl *** If X11/extensions/XShm.h exists...
 179               AC_CHECK_LIB(Xext, XShmQueryExtension,
 180               AC_DEFINE(HAVE_LIBXXSHM),,
 181               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 182             ],
 183             AC_MSG_WARN([Xshm extension not found!!])
 184         )
 185
 186         dnl *** Check for X shape extension
 187         AC_CHECK_HEADERS(X11/Xlib.h X11/extensions/shape.h,
 188             [ dnl *** If X11/extensions/shape.h exists...
 189               AC_CHECK_LIB(Xext,XShapeQueryExtension,
 190               AC_DEFINE(HAVE_LIBXSHAPE),,
 191               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 192             ],
 193             AC_MSG_WARN([XShape extension found!!])
 194         )
 195
 196         dnl *** Check for XFree86 DGA / DGA 2.0 extension
 197         AC_CHECK_HEADERS(X11/extensions/xf86dga.h,
 198             [ dnl *** If X11/extensions/xf86dga.h exists, check
 199               dnl *** for XDGAQueryExtension()...
 200               AC_CHECK_LIB(Xxf86dga, XDGAQueryExtension,
 201                 [ dnl *** If found...
 202                   AC_DEFINE(HAVE_LIBXXF86DGA2)
 203                   AC_DEFINE(HAVE_LIBXXF86DGA)
 204                   X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
 205                   DGA_SRCS='$(DGA_SRCS)'
 206                   DGA2_SRCS='$(DGA2_SRCS)'
 207                ],
 208                 [ dnl *** If not found, look for XF86DGAQueryExtension()
 209                   dnl *** instead (DGA 2.0 not found)...
 210                   AC_CHECK_LIB(Xxf86dga, XF86DGAQueryExtension,
 211                     [ AC_DEFINE(HAVE_LIBXXF86DGA)
 212                       X_PRE_LIBS="$X_PRE_LIBS -lXxf86dga"
 213                       DGA_SRCS='$(DGA_SRCS)'
 214                     ],,
 215                     $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 216                   )
 217                 ],
 218                 $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 219               )
 220             ],
 221             AC_MSG_WARN([DGA extension not found!!])
 222         )
 223
 224         dnl *** Check for XFree86 VMODE extension
 225         AC_CHECK_HEADERS(X11/extensions/xf86vmode.h,
 226             [ dnl *** If X11/extensions/xf86vmode.h exists...
 227                 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
 228                   [ AC_DEFINE(HAVE_LIBXXF86VM)
 229                      X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
 230                   ],,
 231                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 232                 )
 233             ],
 234             AC_MSG_WARN([XFree86 VMODE extension not found!!])
 235         )
 236
 237         dnl *** Check for XVideo extension supporting XvImages
 238         AC_CHECK_HEADERS(X11/extensions/Xvlib.h,
 239             [ dnl *** If X11/extensions/Xvlib.h exists...
 240                 AC_CHECK_LIB(Xv, XvShmCreateImage,
 241                   [ AC_DEFINE(HAVE_XVIDEO)
 242                      X_PRE_LIBS="$X_PRE_LIBS -lXv"
 243                   ],,
 244                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS
 245                 )
 246             ],
 247             AC_MSG_WARN([XVideo extension not found !!])
 248         )
 249
 250       ]
 251     ) dnl *** End of X11/Xlib.h check
 252
 253     dnl Check for the presence of OpenGL
 254     if test $OPENGL = "yes" -o $OPENGL = "normal"
 255     then
 256         AC_CHECK_HEADERS(GL/gl.h GL/glx.h GL/glext.h)
 257         if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
 258         then
 259             dnl Check for some problems due to old Mesa versions
 260             AC_CACHE_CHECK("for up-to-date OpenGL version", wine_cv_opengl_version_OK,
 261               AC_TRY_COMPILE(
 262                 [#include <GL/gl.h>],
 263                 [GLenum test = GL_UNSIGNED_SHORT_5_6_5;],
 264                 [wine_cv_opengl_version_OK="yes"],
 265                 [wine_cv_opengl_version_OK="no"]
 266               )
 267             )
 268
 269             dnl Check for the thread-safety of the OpenGL library
 270             AC_CACHE_CHECK("for thread-safe OpenGL version",
 271                            wine_cv_opengl_version_threadsafe,
 272               [saved_libs=$LIBS
 273                LIBS="$X_LIBS -lGL"
 274                AC_TRY_LINK([],[pthread_getspecific();],
 275                               [wine_cv_opengl_version_threadsafe="yes"],
 276                               [wine_cv_opengl_version_threadsafe="no"])
 277                LIBS=$saved_libs]
 278             )
 279
 280             if test "$wine_cv_opengl_version_OK" = "yes" -a \( "$wine_cv_opengl_version_threadsafe" = "no" -o $OPENGL = "yes" \)
 281             then
 282                 dnl Check for the presence of the library
 283                 AC_CHECK_LIB(GL,glXCreateContext,
 284                              X_PRE_LIBS="$X_PRE_LIBS -lGL"
 285                              MESA_SRCS='$(MESA_SRCS)'
 286                              ,,
 287                              $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 288
 289                 if test $ac_cv_lib_GL_glXCreateContext = "yes"
 290                 then
 291
 292                         OPENGLFILES='$(OPENGLFILES)'
 293                         AC_DEFINE(HAVE_OPENGL)
 294
 295                         AC_CHECK_LIB(GL,glXGetProcAddressARB,AC_DEFINE(HAVE_GLX_GETPROCADDRESS),,$X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 296
 297                         if test $ac_cv_lib_GL_glXGetProcAddressARB = "yes"
 298                         then
 299                                AC_CACHE_CHECK("for OpenGL extension functions prototypes", wine_cv_extension_prototypes,
 300                                   AC_TRY_COMPILE([#include <GL/gl.h>
 301                                                   #ifdef HAVE_GL_GLEXT_H
 302                                                   # include <GL/glext.h>
 303                                                   #endif
 304                                                   ],
 305                                                  [PFNGLCOLORTABLEEXTPROC test_proc;],
 306                                                  [wine_cv_extension_prototypes="yes"],
 307                                                  [wine_cv_extension_prototypes="no"]
 308                                   )
 309                                 )
 310                                 if test $wine_cv_extension_prototypes = "yes"
 311                                 then
 312                                         AC_DEFINE(HAVE_GLEXT_PROTOTYPES)
 313                                 fi
 314
 315                                 OPENGL32_DLL=opengl32
 316                         fi
 317                 fi
 318              fi
 319          fi
 320     fi
 321
 322     CPPFLAGS="$ac_save_CPPFLAGS"
 323     X_DLLS='$(X_DLLS)'
 324     XFILES='$(XFILES)'
 325 else
 326     XLIB=""
 327     X_CFLAGS=""
 328     X_LIBS=""
 329 fi
 330
 331 dnl **** Check which curses lib to use ***
 332 if test "$CURSES" = "yes"
 333 then
 334     AC_CHECK_HEADERS(ncurses.h)
 335     if test "$ac_cv_header_ncurses_h" = "yes"
 336     then
 337         AC_CHECK_LIB(ncurses,waddch)
 338     fi
 339     if test "$ac_cv_lib_ncurses_waddch" = "yes"
 340     then
 341         AC_CHECK_LIB(ncurses,resizeterm,AC_DEFINE(HAVE_RESIZETERM))
 342         AC_CHECK_LIB(ncurses,getbkgd,AC_DEFINE(HAVE_GETBKGD))
 343     else
 344         AC_CHECK_HEADERS(curses.h)
 345         if test "$ac_cv_header_curses_h" = "yes"
 346         then
 347             AC_CHECK_LIB(curses,waddch)
 348             if test "$ac_cv_lib_curses_waddch" = "yes"
 349             then
 350                 AC_CHECK_LIB(curses,resizeterm,AC_DEFINE(HAVE_RESIZETERM))
 351                 AC_CHECK_LIB(curses,getbkgd,AC_DEFINE(HAVE_GETBKGD))
 352             fi
 353         fi
 354     fi
 355 fi
 356
 357 dnl **** Check for IPX (currently Linux only) ****
 358 AC_CACHE_CHECK("for GNU style IPX support", ac_cv_c_ipx_gnu,
 359  AC_TRY_COMPILE(
 360    [#include <sys/socket.h>
 361     #include <netipx/ipx.h>],
 362    [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
 363    [ac_cv_c_ipx_gnu="yes"],
 364    [ac_cv_c_ipx_gnu="no"])
 365  )
 366 if test "$ac_cv_c_ipx_gnu" = "yes"
 367 then
 368     AC_DEFINE(HAVE_IPX_GNU)
 369 fi
 370
 371 if test "$ac_cv_c_ipx_gnu" = "no"
 372 then
 373  AC_CACHE_CHECK("for linux style IPX support", ac_cv_c_ipx_linux,
 374   AC_TRY_COMPILE(
 375     [#include <sys/socket.h>
 376      #include <asm/types.h>
 377      #include <linux/ipx.h>],
 378     [((struct sockaddr_ipx *)0)->sipx_family == AF_IPX],
 379     [ac_cv_c_ipx_linux="yes"],
 380     [ac_cv_c_ipx_linux="no"])
 381   )
 382   if test "$ac_cv_c_ipx_linux" = "yes"
 383   then
 384       AC_DEFINE(HAVE_IPX_LINUX)
 385   fi
 386 fi
 387
 388 dnl **** Check for Open Sound System ****
 389 AC_CHECK_HEADERS(sys/soundcard.h machine/soundcard.h soundcard.h, break)
 390
 391 AC_CACHE_CHECK("for Open Sound System",
 392         ac_cv_c_opensoundsystem,
 393         AC_TRY_COMPILE([
 394         #if defined(HAVE_SYS_SOUNDCARD_H)
 395                 #include <sys/soundcard.h>
 396         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 397                 #include <machine/soundcard.h>
 398         #elif defined(HAVE_SOUNDCARD_H)
 399                 #include <soundcard.h>
 400         #endif
 401         ],[
 402
 403 /* check for one of the Open Sound System specific SNDCTL_ defines */
 404 #if !defined(SNDCTL_DSP_STEREO)
 405 #error No open sound system
 406 #endif
 407 ],ac_cv_c_opensoundsystem="yes",ac_cv_c_opensoundsystem="no"))
 408
 409 if test "$ac_cv_c_opensoundsystem" = "yes"
 410 then
 411     AC_DEFINE(HAVE_OSS)
 412 fi
 413
 414 AC_CACHE_CHECK("for Open Sound System/MIDI interface",
 415         ac_cv_c_opensoundsystem_midi,
 416         AC_TRY_COMPILE([
 417         #if defined(HAVE_SYS_SOUNDCARD_H)
 418                 #include <sys/soundcard.h>
 419         #elif defined(HAVE_MACHINE_SOUNDCARD_H)
 420                 #include <machine/soundcard.h>
 421         #elif defined(HAVE_SOUNDCARD_H)
 422                 #include <soundcard.h>
 423         #endif
 424         ],[
 425
 426 /* check for one of the Open Sound System specific SNDCTL_SEQ defines */
 427 #if !defined(SNDCTL_SEQ_SYNC)
 428 #error No open sound system MIDI interface
 429 #endif
 430 ],ac_cv_c_opensoundsystem_midi="yes",ac_cv_c_opensoundsystem_midi="no"))
 431
 432 if test "$ac_cv_c_opensoundsystem_midi" = "yes"
 433 then
 434     AC_DEFINE(HAVE_OSS_MIDI)
 435 fi
 436
 437 dnl **** If ln -s doesn't work, use cp instead ****
 438 if test "$ac_cv_prog_LN_S" = "ln -s"; then : ; else LN_S=cp ; fi
 439
 440 dnl **** Check for gcc strength-reduce bug ****
 441
 442 if test "x${GCC}" = "xyes"
 443 then
 444   CFLAGS="$CFLAGS -Wall"
 445   AC_CACHE_CHECK( "for gcc strength-reduce bug", ac_cv_c_gcc_strength_bug,
 446                   AC_TRY_RUN([
 447 int     L[[4]] = {0,1,2,3};
 448 int main(void) {
 449   static int Array[[3]];
 450   unsigned int B = 3;
 451   int i;
 452   for(i=0; i<B; i++) Array[[i]] = i - 3;
 453   for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
 454   L[[i]] = 4;
 455
 456   exit( Array[[1]] != -2 || L[[2]] != 3);
 457 }],
 458     ac_cv_c_gcc_strength_bug="no",
 459     ac_cv_c_gcc_strength_bug="yes",
 460     ac_cv_c_gcc_strength_bug="yes") )
 461   if test "$ac_cv_c_gcc_strength_bug" = "yes"
 462   then
 463     CFLAGS="$CFLAGS -fno-strength-reduce"
 464   fi
 465
 466   dnl Check for -mpreferred-stack-boundary
 467   AC_CACHE_CHECK("for gcc -mpreferred-stack-boundary=2 support",
 468                  ac_cv_c_gcc_stack_boundary,
 469   [saved_cflags=$CFLAGS
 470   CFLAGS="$CFLAGS -mpreferred-stack-boundary=2"
 471   AC_TRY_COMPILE(,[return 0],ac_cv_c_gcc_stack_boundary="yes",ac_cv_c_gcc_stack_boundary="no")
 472   CFLAGS=$saved_cflags
 473   ])
 474   if test "$ac_cv_c_gcc_stack_boundary" = "yes"
 475   then
 476     CFLAGS="$CFLAGS -mpreferred-stack-boundary=2"
 477   fi
 478 fi
 479
 480 dnl **** Check if we need to place .type inside a .def directive ****
 481
 482 AC_CACHE_CHECK("whether .type must sit inside a .def directive",
 483                ac_cv_c_type_in_def,
 484 [saved_libs=$LIBS
 485 LIBS="conftest_asm.s $LIBS"
 486 cat > conftest_asm.s <<EOF
 487         .globl _ac_test
 488         .def _ac_test; .scl 2; .type 32; .endef
 489 _ac_test:
 490         .long 0
 491 EOF
 492 AC_TRY_LINK(,,ac_cv_c_type_in_def="yes",ac_cv_c_type_in_def="no")
 493 LIBS=$saved_libs])
 494 if test "$ac_cv_c_type_in_def" = "yes"
 495 then
 496   AC_DEFINE(NEED_TYPE_IN_DEF)
 497 fi
 498
 499 dnl **** Check for underscore on external symbols ****
 500
 501 AC_CACHE_CHECK("whether external symbols need an underscore prefix",
 502                ac_cv_c_extern_prefix,
 503 [saved_libs=$LIBS
 504 LIBS="conftest_asm.s $LIBS"
 505 cat > conftest_asm.s <<EOF
 506         .globl _ac_test
 507 _ac_test:
 508         .long 0
 509 EOF
 510 AC_TRY_LINK([extern int ac_test;],[if (ac_test) return 1],
 511             ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no")
 512 LIBS=$saved_libs])
 513 if test "$ac_cv_c_extern_prefix" = "yes"
 514 then
 515   AC_DEFINE(NEED_UNDERSCORE_PREFIX)
 516 fi
 517
 518 dnl **** Check for .string in assembler ****
 519
 520 AC_CACHE_CHECK("whether assembler accepts .string",
 521                ac_cv_c_asm_string,
 522 [saved_libs=$LIBS
 523 LIBS="conftest_asm.s $LIBS"
 524 cat > conftest_asm.s <<EOF
 525         .string "test"
 526 EOF
 527 AC_TRY_LINK(,,ac_cv_c_asm_string="yes",ac_cv_c_asm_string="no")
 528 LIBS=$saved_libs])
 529 if test "$ac_cv_c_asm_string" = "yes"
 530 then
 531   AC_DEFINE(HAVE_ASM_STRING)
 532 fi
 533
 534 dnl **** Check for working dll ****
 535
 536 LDSHARED=""
 537 LDDLLFLAGS=""
 538 if test "$LIBEXT" = "so"
 539 then
 540   AC_CACHE_CHECK("whether we can build a Linux dll",
 541                  ac_cv_c_dll_linux,
 542   [saved_cflags=$CFLAGS
 543   CFLAGS="$CFLAGS -fPIC -shared -Wl,-soname,conftest.so.1.0,-Bsymbolic"
 544   AC_TRY_LINK(,[return 1],ac_cv_c_dll_linux="yes",ac_cv_c_dll_linux="no")
 545   CFLAGS=$saved_cflags
 546   ])
 547   if test "$ac_cv_c_dll_linux" = "yes"
 548   then
 549     LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%) -Wl,-rpath,\$(libdir)"
 550     LDDLLFLAGS="-Wl,-Bsymbolic"
 551   else
 552     AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll,
 553                  ac_cv_c_dll_unixware,
 554     [saved_cflags=$CFLAGS
 555     CFLAGS="$CFLAGS -fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic"
 556     AC_TRY_LINK(,[return 1],ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")
 557     CFLAGS=$saved_cflags
 558     ])
 559     if test "$ac_cv_c_dll_unixware" = "yes"
 560     then
 561       LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,\$(libdir)/%)"
 562       LDDLLFLAGS="-Wl,-B,symbolic"
 563     else
 564       AC_CACHE_CHECK("whether we can build a NetBSD dll",
 565                    ac_cv_c_dll_netbsd,
 566       [saved_cflags=$CFLAGS
 567       CFLAGS="$CFLAGS -fPIC -Wl,-Bshareable,-Bforcearchive"
 568       AC_TRY_LINK(,[return 1],ac_cv_c_dll_netbsd="yes",ac_cv_c_dll_netbsd="no")
 569       CFLAGS=$saved_cflags
 570       ])
 571       if test "$ac_cv_c_dll_netbsd" = "yes"
 572       then
 573         LDSHARED="\$(CC) -Wl,-Bshareable,-Bforcearchive"
 574         LDDLLFLAGS="" #FIXME
 575       fi
 576     fi
 577   fi
 578   if test "$ac_cv_c_dll_linux" = "no" -a "$ac_cv_c_dll_unixware" = "no" -a "$ac_cv_c_dll_netbsd" = "no"
 579   then
 580     LIBEXT="a"
 581     if test "$DLLWRAP" = "dllwrap"; then
 582       dnl FIXME - check whether dllwrap works correctly...
 583       if test "$CYGWIN" = "yes"; then
 584         echo "*** use dllwrap for building shared library."
 585         LIBEXT="dll"
 586       fi
 587     fi
 588   fi
 589 fi
 590
 591 if test "$LIBEXT" = "a"; then
 592   echo "*** It is currently not possible to build WINE without shared"
 593   echo "*** library (.so) support to allow transparent switch between .so"
 594   echo "*** and .dll files."
 595   echo "*** If you are using Linux, you will need a newer binutils."
 596   exit 1
 597 fi
 598
 599 DLLFLAGS=""
 600 LDPATH=""
 601
 602 if test "$LIBEXT" = "so"; then
 603     DLLFLAGS="-fPIC"
 604     DLL_LINK="-L\$(DLLDIR) \$(IMPORTS:%=-l%) \$(LIBWINE) \$(LIBUNICODE)"
 605     LDPATH="LD_LIBRARY_PATH=\"\$(TOPOBJDIR)/unicode:\$\$LD_LIBRARY_PATH\""
 606 elif test "$LIBEXT" = "dll"; then
 607     #DLLFLAGS="-fPIC" # -fPIC doesn't work(at least in cygwin-b20) - FIXME
 608     DLL_LINK="-L\$(DLLDIR) \$(IMPORTS:%=-l%) \$(LIBWINE) \$(LIBUNICODE)"
 609     LDPATH="PATH=\"\$(TOPOBJDIR)/unicode:\$\$PATH\""
 610 else
 611     DLL_LINK="-L\$(DLLDIR) \$(DLLS:%=-l%) \$(LIBWINE) \$(LIBUNICODE) \$(X_LIBS) \$(XLIB)"
 612     AC_CACHE_CHECK([whether the linker supports --[[no]]-whole-archive (Linux)],
 613                    ac_cv_c_whole_archive,
 614             [saved_cflags=$CFLAGS
 615             CFLAGS="$CFLAGS -Wl,--whole-archive -Wl,--no-whole-archive"
 616             AC_TRY_LINK(,[return 1],ac_cv_c_whole_archive="yes",ac_cv_c_whole_archive="no")
 617             CFLAGS=$saved_cflags
 618             ])
 619     if test "$ac_cv_c_whole_archive" = "yes"
 620     then
 621         DLL_LINK="-Wl,--whole-archive $DLL_LINK -Wl,--no-whole-archive"
 622     else
 623         AC_CACHE_CHECK([whether the linker supports -z {all,default}extract (Linux)],
 624                        ac_cv_c_allextract,
 625                 [saved_cflags=$CFLAGS
 626                 CFLAGS="$CFLAGS -Wl,-z,allextract -Wl,-z,defaultextract"
 627                 AC_TRY_LINK(,[return 1],ac_cv_c_allextract="yes",ac_cv_c_allextract="no")
 628                 CFLAGS=$saved_cflags
 629                 ])
 630         if test "$ac_cv_c_allextract" = "yes"
 631         then
 632             DLL_LINK="-Wl,-z,allextract $DLL_LINK -Wl,-z,defaultextract"
 633         fi
 634     fi
 635 fi
 636
 637 AC_SUBST(DLL_LINK)
 638 AC_SUBST(DLLFLAGS)
 639 AC_SUBST(LDSHARED)
 640 AC_SUBST(LDDLLFLAGS)
 641 AC_SUBST(LIBEXT)
 642 AC_SUBST(LDPATH)
 643
 644 dnl **** Check for reentrant libc ****
 645 dnl
 646 dnl For cross-compiling we blindly assume that libc is reentrant. This is
 647 dnl ok since non-reentrant libc is quite rare (mostly old libc5 versions).
 648
 649 wine_cv_libc_reentrant=no
 650 dnl
 651 dnl Linux style errno location
 652 dnl
 653 AC_CACHE_CHECK("for reentrant libc: __errno_location", wine_cv_libc_r__errno_location,
 654   [AC_TRY_RUN([int myerrno = 0;
 655 char buf[256];
 656 int *__errno_location(){return &myerrno;}
 657 main(){connect(0,buf,255); exit(!myerrno);}],
 658   wine_cv_libc_r__errno_location=yes, wine_cv_libc_r__errno_location=no,
 659   wine_cv_libc_r__errno_location=yes )
 660 ])
 661 if test "$wine_cv_libc_r__errno_location" = "yes"
 662 then
 663     AC_DEFINE(HAVE__ERRNO_LOCATION)
 664     wine_cv_libc_reentrant=__errno_location
 665 fi
 666 dnl
 667 dnl FreeBSD style errno location
 668 dnl
 669 AC_CACHE_CHECK("for reentrant libc: __error", wine_cv_libc_r__error,
 670   [AC_TRY_RUN([int myerrno = 0;
 671 char buf[256];
 672 int *__error(){return &myerrno;}
 673 main(){connect(0,buf,255); exit(!myerrno);}],
 674     wine_cv_libc_r__error=yes, wine_cv_libc_r__error=no,
 675     wine_cv_libc_r__error=yes )
 676 ])
 677 if test "$wine_cv_libc_r__error" = "yes"
 678 then
 679     AC_DEFINE(HAVE__ERROR)
 680     wine_cv_libc_reentrant=__error
 681 fi
 682 dnl
 683 dnl Solaris style errno location
 684 dnl
 685 AC_CACHE_CHECK("for reentrant libc: ___errno", wine_cv_libc_r___errno,
 686   [AC_TRY_RUN([int myerrno = 0;
 687 char buf[256];
 688 int *___errno(){return &myerrno;}
 689 main(){connect(0,buf,255); exit(!myerrno);}],
 690     wine_cv_libc_r___errno=yes, wine_cv_libc_r___errno=no,
 691     wine_cv_libc_r___errno=yes )
 692 ])
 693 if test "$wine_cv_libc_r___errno" = "yes"
 694 then
 695     AC_DEFINE(HAVE___ERRNO)
 696     wine_cv_libc_reentrant=___errno
 697 fi
 698 dnl
 699 dnl UnixWare style errno location
 700 dnl
 701 AC_CACHE_CHECK("for reentrant libc: __thr_errno", wine_cv_libc_r__thr_errno,
 702   [AC_TRY_RUN([int myerrno = 0;
 703 char buf[256];
 704 int *__thr_errno(){return &myerrno;}
 705 main(){connect(0,buf,255); exit(!myerrno);}],
 706     wine_cv_libc_r__thr_errno=yes, wine_cv_libc_r__thr_errno=no,
 707     wine_cv_libc_r__thr_errno=yes )
 708 ])
 709 if test "$wine_cv_libc_r__thr_errno" = "yes"
 710 then
 711     AC_DEFINE(HAVE__THR_ERRNO)
 712     wine_cv_libc_reentrant=__thr_errno
 713 fi
 714 if test "$wine_cv_libc_reentrant" = "no"
 715 then
 716   AC_DEFINE(NO_REENTRANT_LIBC)
 717 fi
 718
 719 dnl **** Check for reentrant X libraries ****
 720 dnl
 721 dnl This may fail to determine whether X libraries are reentrant if
 722 dnl AC_PATH_XTRA does not set x_libraries. In this case manual configuration
 723 dnl is possible with the --without-reentrant-x option.
 724
 725 if test "$have_x" = "yes" -a "$wine_cv_libc_reentrant" != "no"
 726 then
 727 AC_CACHE_CHECK( "for reentrant X libraries", wine_cv_x_reentrant,
 728   [ if test "x$with_reentrant_x" = "xno"
 729     then
 730         wine_cv_x_reentrant=no
 731     else
 732         libX11_check=none
 733         for dir in "$x_libraries" /usr/lib /usr/local/lib /lib; do
 734             if test -r $dir/libX11.so; then
 735                 libX11_check="-D $dir/libX11.so"
 736                 break 1
 737             fi
 738             if test -r $dir/libX11.a; then
 739                 libX11_check="$dir/libX11.a"
 740                 break 1
 741             fi
 742         done
 743         if test "$libX11_check" != "none"; then
 744             if nm $libX11_check | grep $wine_cv_libc_reentrant >/dev/null 2>&1
 745             then
 746                 wine_cv_x_reentrant=yes
 747             else
 748                 wine_cv_x_reentrant=no
 749             fi
 750         else
 751             wine_cv_x_reentrant=unknown
 752         fi
 753     fi ] )
 754 else
 755     wine_cv_x_reentrant=no
 756 fi
 757 if test "$wine_cv_x_reentrant" = "no"
 758 then
 759   AC_DEFINE(NO_REENTRANT_X11)
 760 fi
 761
 762 dnl **** Check for endianness ****
 763
 764 AC_C_BIGENDIAN
 765
 766 AC_CACHE_CHECK( "whether bitfields are bigendian", wine_cv_bitfields_bigendian,
 767   [AC_TRY_RUN([
 768 union
 769 {
 770   int word;
 771   struct
 772   {
 773       int bit0 : 1;
 774       int rest : sizeof(int)*8 - 1;
 775   } bitfield;
 776 } u;
 777 main() { u.word = 0; u.bitfield.bit0 = 1; exit( u.word == 1 ); } ],
 778     wine_cv_bitfields_bigendian=yes, wine_cv_bitfields_bigendian=no,
 779     wine_cv_bitfields_bigendian=no ) ])
 780 if test "$wine_cv_bitfields_bigendian" = "yes"
 781 then
 782   AC_DEFINE(BITFIELDS_BIGENDIAN)
 783 fi
 784
 785
 786 dnl **** Check for functions ****
 787
 788 AC_FUNC_ALLOCA()
 789 AC_CHECK_FUNCS(\
 790         __libc_fork \
 791         _lwp_create \
 792         clone \
 793         finite \
 794         fpclass \
 795         getnetbyaddr \
 796         getnetbyname \
 797         getpagesize \
 798         getprotobyname \
 799         getprotobynumber \
 800         getrlimit \
 801         getservbyport \
 802         getsockopt \
 803         inet_network \
 804         lstat \
 805         memmove \
 806         mmap \
 807         rfork \
 808         select \
 809         sendmsg \
 810         settimeofday \
 811         sigaltstack \
 812         statfs \
 813         strcasecmp \
 814         strerror \
 815         strncasecmp \
 816         tcgetattr \
 817         timegm \
 818         usleep \
 819         vfscanf \
 820         wait4 \
 821         waitpid \
 822 )
 823
 824 dnl **** Check for header files ****
 825
 826 AC_CHECK_HEADERS(\
 827         arpa/inet.h \
 828         arpa/nameser.h \
 829         elf.h \
 830         float.h \
 831         libio.h \
 832         libutil.h \
 833         link.h \
 834         linux/cdrom.h \
 835         linux/input.h \
 836         linux/joystick.h \
 837         linux/ucdrom.h \
 838         net/if.h \
 839         netdb.h \
 840         netinet/in.h \
 841         netinet/in_systm.h \
 842         netinet/ip.h \
 843         netinet/tcp.h \
 844         pty.h \
 845         resolv.h \
 846         sched.h \
 847         socket.h \
 848         strings.h \
 849         sys/cdio.h \
 850         sys/errno.h \
 851         sys/file.h \
 852         sys/filio.h \
 853         sys/ipc.h \
 854         sys/lwp.h \
 855         sys/mman.h \
 856         sys/modem.h \
 857         sys/mount.h \
 858         sys/msg.h \
 859         sys/param.h \
 860         sys/ptrace.h \
 861         sys/reg.h \
 862         sys/signal.h \
 863         sys/shm.h \
 864         sys/socket.h \
 865         sys/sockio.h \
 866         sys/statfs.h \
 867         sys/strtio.h \
 868         sys/syscall.h \
 869         sys/user.h \
 870         sys/wait.h \
 871         sys/v86.h \
 872         sys/v86intr.h \
 873         sys/vfs.h \
 874         sys/vm86.h \
 875         syscall.h \
 876         ucontext.h \
 877 )
 878 AC_HEADER_STAT()
 879
 880 dnl **** Check for types ****
 881
 882 AC_C_CONST()
 883 AC_C_INLINE()
 884 AC_TYPE_SIZE_T()
 885 AC_CHECK_SIZEOF(long long,0)
 886
 887
 888 AC_CACHE_CHECK("whether we can use re-entrant gethostbyname_r Linux style",
 889         wine_cv_linux_gethostbyname_r_6,
 890         AC_TRY_COMPILE([
 891 #include <netdb.h>
 892         ], [
 893     char *name=NULL;
 894     struct hostent he;
 895     struct hostent *result;
 896     char *buf=NULL;
 897     int bufsize=0;
 898     int res,errnr;
 899     char *addr=NULL;
 900     int addrlen=0;
 901     int addrtype=0;
 902     res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
 903     res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
 904     ],
 905         wine_cv_linux_gethostbyname_r_6=yes,
 906         wine_cv_linux_gethostbyname_r_6=no
 907         )
 908    )
 909    if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
 910    then
 911       AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6)
 912    fi
 913
 914 if test "$ac_cv_header_linux_joystick_h" = "yes"
 915 then
 916    AC_CACHE_CHECK("whether linux/joystick.h uses the Linux 2.2+ API",
 917         wine_cv_linux_joystick_22_api,
 918         AC_TRY_COMPILE([
 919         #include <sys/ioctl.h>
 920         #include <linux/joystick.h>
 921
 922         struct js_event blub;
 923         #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
 924         #error "no 2.2 header"
 925         #endif
 926         ],/*empty*/,
 927         wine_cv_linux_joystick_22_api=yes,
 928         wine_cv_linux_joystick_22_api=no,
 929         wine_cv_linux_joystick_22_api=no
 930         )
 931    )
 932    if test "$wine_cv_linux_joystick_22_api" = "yes"
 933    then
 934       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API)
 935    fi
 936 fi
 937
 938 dnl **** statfs checks ****
 939
 940 if test "$ac_cv_header_sys_vfs_h" = "yes"
 941 then
 942     AC_CACHE_CHECK( "whether sys/vfs.h defines statfs",
 943                     wine_cv_sys_vfs_has_statfs,
 944         AC_TRY_COMPILE([
 945         #include <sys/types.h>
 946         #ifdef HAVE_SYS_PARAM_H
 947         # include <sys/param.h>
 948         #endif
 949         #include <sys/vfs.h>
 950         ],[
 951                 struct statfs stfs;
 952
 953                 memset(&stfs,0,sizeof(stfs));
 954         ],wine_cv_sys_vfs_has_statfs=yes,wine_cv_sys_vfs_has_statfs=no
 955         )
 956     )
 957     if test "$wine_cv_sys_vfs_has_statfs" = "yes"
 958     then
 959       AC_DEFINE(STATFS_DEFINED_BY_SYS_VFS)
 960     fi
 961 fi
 962
 963 if test "$ac_cv_header_sys_statfs_h" = "yes"
 964 then
 965     AC_CACHE_CHECK( "whether sys/statfs.h defines statfs",
 966                     wine_cv_sys_statfs_has_statfs,
 967         AC_TRY_COMPILE([
 968         #include <sys/types.h>
 969         #ifdef HAVE_SYS_PARAM_H
 970         # include <sys/param.h>
 971         #endif
 972         #include <sys/statfs.h>
 973         ],[
 974                 struct statfs stfs;
 975         ],wine_cv_sys_statfs_has_statfs=yes,wine_cv_sys_statfs_has_statfs=no
 976         )
 977     )
 978     if test "$wine_cv_sys_statfs_has_statfs" = "yes"
 979     then
 980       AC_DEFINE(STATFS_DEFINED_BY_SYS_STATFS)
 981     fi
 982 fi
 983
 984 if test "$ac_cv_header_sys_mount_h" = "yes"
 985 then
 986     AC_CACHE_CHECK( "whether sys/mount.h defines statfs",
 987                     wine_cv_sys_mount_has_statfs,
 988         AC_TRY_COMPILE([
 989         #include <sys/types.h>
 990         #ifdef HAVE_SYS_PARAM_H
 991         # include <sys/param.h>
 992         #endif
 993         #include <sys/mount.h>
 994         ],[
 995                 struct statfs stfs;
 996         ],wine_cv_sys_mount_has_statfs=yes,wine_cv_sys_mount_has_statfs=no
 997         )
 998     )
 999     if test "$wine_cv_sys_mount_has_statfs" = "yes"
1000     then
1001       AC_DEFINE(STATFS_DEFINED_BY_SYS_MOUNT)
1002     fi
1003 fi
1004
1005 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1006
1007 AC_CACHE_CHECK( "for statfs.f_bfree", wine_cv_statfs_bfree,
1008   [ if test "x$statfs_bfree" = "xno"
1009     then
1010         wine_cv_statfs_bfree=no
1011     else
1012         AC_TRY_COMPILE([
1013         #include <sys/types.h>
1014         #ifdef HAVE_SYS_PARAM_H
1015         # include <sys/param.h>
1016         #endif
1017         #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1018         # include <sys/mount.h>
1019         #else
1020         # ifdef STATFS_DEFINED_BY_SYS_VFS
1021         #  include <sys/vfs.h>
1022         # else
1023         #  ifdef STATFS_DEFINED_BY_SYS_STATFS
1024         #   include <sys/statfs.h>
1025         #  endif
1026         # endif
1027         #endif
1028         ],[
1029                 struct statfs stfs;
1030
1031                 stfs.f_bfree++;
1032         ],wine_cv_statfs_bfree=yes,wine_cv_statfs_bfree=no
1033         )
1034     fi ] )
1035 if test "$wine_cv_statfs_bfree" = "yes"
1036 then
1037   AC_DEFINE(STATFS_HAS_BFREE)
1038 fi
1039
1040 AC_CACHE_CHECK( "for statfs.f_bavail", wine_cv_statfs_bavail,
1041   [ if test "x$statfs_bavail" = "xno"
1042     then
1043         wine_cv_statfs_bavail=no
1044     else
1045         AC_TRY_COMPILE([
1046         #include <sys/types.h>
1047         #ifdef HAVE_SYS_PARAM_H
1048         # include <sys/param.h>
1049         #endif
1050         #ifdef STATFS_DEFINED_BY_SYS_MOUNT
1051         # include <sys/mount.h>
1052         #else
1053         # ifdef STATFS_DEFINED_BY_SYS_VFS
1054         #  include <sys/vfs.h>
1055         # else
1056         #  ifdef STATFS_DEFINED_BY_SYS_STATFS
1057         #   include <sys/statfs.h>
1058         #  endif
1059         # endif
1060         #endif
1061         ],[
1062                 struct statfs stfs;
1063
1064                 stfs.f_bavail++;
1065         ],wine_cv_statfs_bavail=yes,wine_cv_statfs_bavail=no
1066         )
1067     fi ] )
1068 if test "$wine_cv_statfs_bavail" = "yes"
1069 then
1070   AC_DEFINE(STATFS_HAS_BAVAIL)
1071 fi
1072
1073 dnl *** check for file descriptor passing with msg_accrights
1074
1075 AC_CACHE_CHECK("for msg_accrights in struct msghdr", ac_cv_c_msg_accrights,
1076  AC_TRY_COMPILE([#include <sys/types.h>
1077 #include <sys/socket.h>],[struct msghdr hdr; hdr.msg_accrights=0],
1078                 ac_cv_c_msg_accrights="yes", ac_cv_c_msg_accrights="no"))
1079 if test "$ac_cv_c_msg_accrights" = "yes"
1080 then
1081     AC_DEFINE(HAVE_MSGHDR_ACCRIGHTS)
1082 fi
1083
1084 dnl *** Check for the sun_len member in struct sockaddr_un
1085
1086 AC_CACHE_CHECK("for sun_len in struct sockaddr_un", ac_cv_c_sun_len,
1087  AC_TRY_COMPILE([#include <sys/types.h>
1088 #include <sys/socket.h>
1089 #include <sys/un.h>], [static struct sockaddr_un addr; addr.sun_len = 1],
1090                 ac_cv_c_sun_len="yes", ac_cv_c_sun_len="no"))
1091 if test "$ac_cv_c_sun_len" = "yes"
1092 then
1093     AC_DEFINE(HAVE_SOCKADDR_SUN_LEN)
1094 fi
1095
1096 dnl *** check for the need to define __i386__
1097
1098 AC_CACHE_CHECK("whether we need to define __i386__",ac_cv_cpp_def_i386,
1099  AC_EGREP_CPP(yes,[#if (defined(i386) || defined(__i386)) && !defined(__i386__)
1100 yes
1101 #endif],
1102  ac_cv_cpp_def_i386="yes", ac_cv_cpp_def_i386="no"))
1103 if test "$ac_cv_cpp_def_i386" = "yes"
1104 then
1105     CFLAGS="$CFLAGS -D__i386__"
1106     LINTFLAGS="$LINTFLAGS -D__i386__"
1107 fi
1108
1109 dnl $GCC is set by autoconf
1110 GCC_NO_BUILTIN=""
1111 if test "$GCC" = "yes"
1112 then
1113     GCC_NO_BUILTIN="-fno-builtin"
1114 fi
1115 AC_SUBST(GCC_NO_BUILTIN)
1116
1117 dnl **** Generate output files ****
1118
1119 AC_OUTPUT_COMMANDS([
1120 extra_subdirs="\
1121 dlls/ddraw/d3ddevice \
1122 dlls/ddraw/dclipper \
1123 dlls/ddraw/ddraw \
1124 dlls/ddraw/direct3d \
1125 dlls/ddraw/dpalette \
1126 dlls/ddraw/dsurface \
1127 dlls/dinput/joystick \
1128 dlls/dinput/keyboard \
1129 dlls/dinput/mouse \
1130 dlls/kernel/messages \
1131 dlls/user/resources \
1132 "
1133 for i in $extra_subdirs; do [ -d $i ] || (echo "creating $i" && mkdir $i); done ])
1134
1135 MAKE_RULES=Make.rules
1136 AC_SUBST_FILE(MAKE_RULES)
1137
1138 MAKE_DLL_RULES=dlls/Makedll.rules
1139 AC_SUBST_FILE(MAKE_DLL_RULES)
1140
1141 MAKE_PROG_RULES=programs/Makeprog.rules
1142 AC_SUBST_FILE(MAKE_PROG_RULES)
1143
1144 AC_OUTPUT([
1145 Make.rules
1146 dlls/Makedll.rules
1147 programs/Makeprog.rules
1148 Makefile
1149 console/Makefile
1150 controls/Makefile
1151 debugger/Makefile
1152 dlls/Makefile
1153 dlls/advapi32/Makefile
1154 dlls/avifil32/Makefile
1155 dlls/comctl32/Makefile
1156 dlls/commdlg/Makefile
1157 dlls/crtdll/Makefile
1158 dlls/dciman32/Makefile
1159 dlls/ddraw/Makefile
1160 dlls/dinput/Makefile
1161 dlls/dplay/Makefile
1162 dlls/dplayx/Makefile
1163 dlls/dsound/Makefile
1164 dlls/gdi/Makefile
1165 dlls/icmp/Makefile
1166 dlls/imagehlp/Makefile
1167 dlls/imm32/Makefile
1168 dlls/kernel/Makefile
1169 dlls/lzexpand/Makefile
1170 dlls/mpr/Makefile
1171 dlls/msacm/Makefile
1172 dlls/msnet32/Makefile
1173 dlls/msvideo/Makefile
1174 dlls/ntdll/Makefile
1175 dlls/odbc32/Makefile
1176 dlls/ole32/Makefile
1177 dlls/oleaut32/Makefile
1178 dlls/olecli/Makefile
1179 dlls/oledlg/Makefile
1180 dlls/olepro32/Makefile
1181 dlls/olesvr/Makefile
1182 dlls/opengl32/Makefile
1183 dlls/psapi/Makefile
1184 dlls/rasapi32/Makefile
1185 dlls/richedit/Makefile
1186 dlls/rpcrt4/Makefile
1187 dlls/serialui/Makefile
1188 dlls/setupapi/Makefile
1189 dlls/shell32/Makefile
1190 dlls/shfolder/Makefile
1191 dlls/shlwapi/Makefile
1192 dlls/tapi32/Makefile
1193 dlls/ttydrv/Makefile
1194 dlls/urlmon/Makefile
1195 dlls/user/Makefile
1196 dlls/version/Makefile
1197 dlls/win32s/Makefile
1198 dlls/winaspi/Makefile
1199 dlls/wineps/Makefile
1200 dlls/wininet/Makefile
1201 dlls/winmm/Makefile
1202 dlls/winmm/joystick/Makefile
1203 dlls/winmm/mcianim/Makefile
1204 dlls/winmm/mciavi/Makefile
1205 dlls/winmm/mcicda/Makefile
1206 dlls/winmm/mciseq/Makefile
1207 dlls/winmm/mciwave/Makefile
1208 dlls/winmm/midimap/Makefile
1209 dlls/winmm/wavemap/Makefile
1210 dlls/winmm/wineoss/Makefile
1211 dlls/winnls/Makefile
1212 dlls/winsock/Makefile
1213 dlls/winspool/Makefile
1214 dlls/wow32/Makefile
1215 dlls/wsock32/Makefile
1216 dlls/x11drv/Makefile
1217 documentation/Makefile
1218 documentation/wine.conf.man
1219 documentation/wine.man
1220 files/Makefile
1221 graphics/Makefile
1222 graphics/enhmetafiledrv/Makefile
1223 graphics/metafiledrv/Makefile
1224 graphics/win16drv/Makefile
1225 graphics/x11drv/Makefile
1226 if1632/Makefile
1227 include/Makefile
1228 library/Makefile
1229 libtest/Makefile
1230 loader/Makefile
1231 loader/dos/Makefile
1232 loader/ne/Makefile
1233 memory/Makefile
1234 misc/Makefile
1235 miscemu/Makefile
1236 msdos/Makefile
1237 objects/Makefile
1238 ole/Makefile
1239 programs/Makefile
1240 programs/avitools/Makefile
1241 programs/clock/Makefile
1242 programs/cmdlgtst/Makefile
1243 programs/control/Makefile
1244 programs/notepad/Makefile
1245 programs/osversioncheck/Makefile
1246 programs/progman/Makefile
1247 programs/regapi/Makefile
1248 programs/regtest/Makefile
1249 programs/uninstaller/Makefile
1250 programs/view/Makefile
1251 programs/wcmd/Makefile
1252 programs/winemine/Makefile
1253 programs/winhelp/Makefile
1254 programs/winver/Makefile
1255 relay32/Makefile
1256 scheduler/Makefile
1257 server/Makefile
1258 tools/Makefile
1259 tools/cvdump/Makefile
1260 tools/winebuild/Makefile
1261 tools/winelauncher
1262 tools/wmc/Makefile
1263 tools/wrc/Makefile
1264 tsx11/Makefile
1265 unicode/Makefile
1266 win32/Makefile
1267 windows/Makefile
1268 windows/x11drv/Makefile ])
1269
1270 if test "$have_x" = "no"
1271 then
1272   echo
1273   echo "*** Warning: X development files not found. Wine will be built without"
1274   echo "*** X support, which currently does not work, and would probably not be"
1275   echo "*** what you want anyway. You will need to install devel packages of"
1276   echo "*** Xlib/Xfree86 and Xpm at the very least."
1277 elif test "$ac_cv_lib_Xpm_XpmCreatePixmapFromData" = "no"
1278 then
1279   echo
1280   echo "*** Warning: Xpm development files not found. Wine will be built without"
1281   echo "*** Xpm support, which currently does not work. You will need to install"
1282   echo "*** devel packages of Xpm."
1283 fi
1284
1285 if test "$ac_cv_lib_ncurses_resizeterm" = "no" -a "$ac_cv_lib_ncurses_waddch" = "yes"
1286 then
1287   echo
1288   echo "*** Warning: resizeterm not found in ncurses. Wine will be built without"
1289   echo "*** terminal resize support. Consider upgrading ncurses."
1290 fi
1291
1292 if test "$wine_cv_libc_reentrant" = "no"
1293 then
1294   echo
1295   echo "*** Warning: non-reentrant libc detected. Wine will be build without"
1296   echo "*** thread support. Consider upgrading libc to a more recent"
1297   echo "*** reentrant version of libc."
1298 fi
1299
1300 if test "$wine_cv_opengl_version_OK" = "no"
1301 then
1302   echo
1303   echo "*** Warning: old Mesa headers detected. Wine will be built without Direct3D"
1304   echo "*** support. Consider upgrading your Mesa libraries (http://www.mesa3d.org/)."
1305 fi
1306
1307 if test "$wine_cv_opengl_version_threadsafe" = "yes" -a $OPENGL = "normal"
1308 then
1309   echo
1310   echo "*** Warning: the OpenGL version you have installed relies on libpthread for"
1311   echo "*** thread-safety. To prevent crashes, OpenGL support has been removed."
1312   echo "*** A fix for glibc 2.1.3 that seem to work is included in this version of Wine,"
1313   echo "*** start configure with '--enable-opengl' to force OpenGL support."
1314 fi
1315
1316 if test "$wine_cv_opengl_version_threadsafe" = "yes" -a $OPENGL = "yes"
1317 then
1318   echo
1319   echo "*** Warning: you explicitely linked in a thread-safe OpenGL version. If you"
1320   echo "*** experience unusual crashes on DirectDraw games, try first to disable OpenGL"
1321   echo "*** support before reporting bugs."
1322 fi
1323
1324
1325 echo
1326 echo "Configure finished.  Do 'make depend && make' to compile Wine."
1327 echo
1328
1329 dnl Local Variables:
1330 dnl comment-start: "dnl "
1331 dnl comment-end: ""
1332 dnl comment-start-skip: "\\bdnl\\b\\s *"
1333 dnl compile-command: "autoconf"
1334 dnl End: