git.oblomov.eu Git - wine/blob - configure.ac

   1 dnl Process this file with autoconf to produce a configure script.
   2 dnl Original author: Michael Patra
   3 dnl See ChangeLog file for detailed change history.
   4
   5 m4_define(WINE_VERSION,regexp(m4_include(VERSION),[version \([-.0-9A-Za-z]+\)],[\1]))
   6
   7 AC_PREREQ(2.53b)
   8 AC_INIT([Wine],[WINE_VERSION],[wine-devel@winehq.org])
   9 AC_CONFIG_SRCDIR(server/atom.c)
  10 AC_CONFIG_HEADERS(include/config.h)
  11 AC_CONFIG_AUX_DIR(tools)
  12
  13 dnl **** Command-line arguments ****
  14
  15 AC_ARG_ENABLE(win16, AS_HELP_STRING([--disable-win16],[do not include Win16 support]))
  16 AC_ARG_ENABLE(win64, AS_HELP_STRING([--enable-win64],[build a Win64 emulator on AMD64 (won't run Win32 binaries)]))
  17 AC_ARG_ENABLE(maintainer-mode, AS_HELP_STRING([--enable-maintainer-mode],[enable maintainer-specific build rules]),
  18                                ,[AC_SUBST([MAINTAINER_MODE],[\#])])
  19
  20 AC_ARG_WITH(alsa,      AS_HELP_STRING([--without-alsa],[do not use the Alsa sound support]),
  21             [if test "x$withval" = "xno"; then ac_cv_header_sys_asoundlib_h=no; ac_cv_header_alsa_asoundlib_h=no; fi])
  22 AC_ARG_WITH(audioio,   AS_HELP_STRING([--without-audioio],[do not use the AudioIO sound support]),
  23             [if test "x$withval" = "xno"; then ac_cv_header_libaudioio_h=no; fi])
  24 AC_ARG_WITH(capi,      AS_HELP_STRING([--without-capi],[do not use CAPI (ISDN support)]),
  25             [if test "x$withval" = "xno"; then ac_cv_header_capi20_h=no; ac_cv_header_linux_capi_h=no; fi])
  26 AC_ARG_WITH(cms,       AS_HELP_STRING([--without-cms],[do not use CMS (color management support)]),
  27             [if test "x$withval" = "xno"; then ac_cv_header_lcms_h=no; ac_cv_header_lcms_lcms_h=no; fi])
  28 AC_ARG_WITH(coreaudio, AS_HELP_STRING([--without-coreaudio],[do not use the CoreAudio sound support]),
  29             [if test "x$withval" = "xno"; then ac_cv_header_CoreAudio_CoreAudio_h=no; fi])
  30 AC_ARG_WITH(cups,      AS_HELP_STRING([--without-cups],[do not use CUPS]),
  31             [if test "x$withval" = "xno"; then ac_cv_header_cups_cups_h=no; fi])
  32 AC_ARG_WITH(curses,    AS_HELP_STRING([--without-curses],[do not use (n)curses]),
  33             [if test "x$withval" = "xno"; then ac_cv_header_ncurses_h=no; ac_cv_header_curses_h=no; fi])
  34 AC_ARG_WITH(esd,       AS_HELP_STRING([--without-esd],[do not use the EsounD sound support]))
  35 AC_ARG_WITH(fontconfig,AS_HELP_STRING([--without-fontconfig],[do not use fontconfig]),
  36             [if test "x$withval" = "xno"; then ac_cv_header_fontconfig_fontconfig_h=no; fi])
  37 AC_ARG_WITH(gphoto,    AS_HELP_STRING([--without-gphoto],[do not use gphoto (Digital Camera support)]))
  38 AC_ARG_WITH(hal,       AS_HELP_STRING([--without-hal],[do not use HAL (dynamic device support)]))
  39 AC_ARG_WITH(jack,      AS_HELP_STRING([--without-jack],[do not use the Jack sound support]),
  40             [if test "x$withval" = "xno"; then ac_cv_header_jack_jack_h=no; fi])
  41 AC_ARG_WITH(jpeg,      AS_HELP_STRING([--without-jpeg],[do not use JPEG]),
  42             [if test "x$withval" = "xno"; then ac_cv_header_jpeglib_h=no; fi])
  43 AC_ARG_WITH(ldap,      AS_HELP_STRING([--without-ldap],[do not use LDAP]),
  44             [if test "x$withval" = "xno"; then ac_cv_header_ldap_h=no; ac_cv_header_lber_h=no; fi])
  45 AC_ARG_WITH(nas,       AS_HELP_STRING([--without-nas],[do not use the NAS sound support]),
  46             [if test "x$withval" = "xno"; then ac_cv_header_audio_audiolib_h=no; fi])
  47 AC_ARG_WITH(opengl,    AS_HELP_STRING([--without-opengl],[do not use OpenGL]))
  48 AC_ARG_WITH(openssl,   AS_HELP_STRING([--without-openssl],[do not use OpenSSL]),
  49             [if test "x$withval" = "xno"; then ac_cv_header_openssl_err_h=no; ac_cv_header_openssl_ssl_h=no; fi])
  50 AC_ARG_WITH(oss,       AS_HELP_STRING([--without-oss],[do not use the OSS sound support]),
  51             [if test "x$withval" = "xno"; then ac_cv_header_soundcard_h=no; ac_cv_header_sys_soundcard_h=no; ac_cv_header_machine_soundcard_h=no; fi])
  52 AC_ARG_WITH(png,       AS_HELP_STRING([--without-png],[do not use PNG]),
  53             [if test "x$withval" = "xno"; then ac_cv_header_png_h=no; fi])
  54 AC_ARG_WITH(sane,      AS_HELP_STRING([--without-sane],[do not use SANE (scanner support)]))
  55 AC_ARG_WITH(xcomposite,AS_HELP_STRING([--without-xcomposite],[do not use the Xcomposite extension]),
  56             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_Xcomposite_h=no; fi])
  57 AC_ARG_WITH(xcursor,   AS_HELP_STRING([--without-xcursor],[do not use the Xcursor extension]),
  58             [if test "x$withval" = "xno"; then ac_cv_header_X11_Xcursor_Xcursor_h=no; fi])
  59 AC_ARG_WITH(xinerama,  AS_HELP_STRING([--without-xinerama],[do not use Xinerama (multi-monitor support)]),
  60             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_Xinerama_h=no; fi])
  61 AC_ARG_WITH(xinput,    AS_HELP_STRING([--without-xinput],[do not use the Xinput extension]),
  62             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_XInput_h=no; fi])
  63 AC_ARG_WITH(xml,       AS_HELP_STRING([--without-xml],[do not use XML]))
  64 AC_ARG_WITH(xrandr,    AS_HELP_STRING([--without-xrandr],[do not use Xrandr (resolution changes)]),
  65             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_Xrandr_h=no; fi])
  66 AC_ARG_WITH(xrender,   AS_HELP_STRING([--without-xrender],[do not use the Xrender extension]),
  67             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_Xrender_h=no; fi])
  68 AC_ARG_WITH(xshape,    AS_HELP_STRING([--without-xshape],[do not use the Xshape extension]),
  69             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_shape_h=no; fi])
  70 AC_ARG_WITH(xshm,      AS_HELP_STRING([--without-xshm],[do not use XShm (shared memory extension)]),
  71             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_XShm_h=no; fi])
  72 AC_ARG_WITH(xslt,      AS_HELP_STRING([--without-xslt],[do not use XSLT]))
  73 AC_ARG_WITH(xvidmode,  AS_HELP_STRING([--without-xvidmode],[do not use XFree video mode extension]),
  74             [if test "x$withval" = "xno"; then ac_cv_header_X11_extensions_xf86vmode_h=no; fi])
  75
  76 AC_ARG_WITH(wine-tools,AS_HELP_STRING([--with-wine-tools=DIR],[use Wine tools from directory DIR]))
  77
  78 AC_CANONICAL_HOST
  79 case $host in
  80   x86_64*linux*)
  81     if test "x$enable_win64" != "xyes"
  82     then
  83       test -n "$CC" || CC="gcc -m32"
  84       test -n "$CXX"|| CXX="g++ -m32"
  85       test -n "$LD" || LD="ld -m elf_i386"
  86       test -n "$AS" || AS="as --32"
  87       host_cpu="i386"
  88     fi
  89     ;;
  90 esac
  91
  92 dnl enable_win16 defaults to yes on x86, to no on other CPUs
  93 case $host_cpu in
  94   *i[[3456789]]86*)
  95     if test "x$enable_win16" != "xno"
  96     then
  97       enable_win16="yes"
  98     fi
  99     ;;
 100 esac
 101
 102 AC_SUBST(WIN16_FILES,"\$(WIN16_FILES)")
 103 AC_SUBST(WIN16_INSTALL,"\$(WIN16_INSTALL)")
 104 if test "x$enable_win16" != "xyes"
 105 then
 106   WIN16_FILES=""
 107   WIN16_INSTALL=""
 108 fi
 109
 110 dnl check for out of tree build with unclean source tree
 111 case "$srcdir" in
 112  .) ;;
 113  *) if test -f "$srcdir/Makefile" -o -f "$srcdir/include/config.h"; then
 114       AC_MSG_ERROR([you are building out of the source tree, but the source tree contains object files.
 115 You need to run 'make distclean' in the source tree first.])
 116     fi ;;
 117 esac
 118
 119 dnl **** Check for some programs ****
 120
 121 AC_PROG_MAKE_SET
 122 AC_PROG_CC
 123 AC_PROG_CXX
 124 dnl We can't use AC_PROG_CPP for winegcc, it uses by default $(CC) -E
 125 AC_CHECK_TOOL(CPPBIN,cpp,cpp)
 126
 127 AC_CACHE_CHECK([for the directory containing the Wine tools], wine_cv_toolsdir,
 128   [if test -z "$with_wine_tools"; then
 129      if test "$cross_compiling" = "yes"; then
 130        AC_MSG_ERROR([you must use the --with-wine-tools option when cross-compiling.])
 131      else
 132        wine_cv_toolsdir="\$(TOPOBJDIR)"
 133      fi
 134    elif test -d "$with_wine_tools/tools/winebuild"; then
 135      case $with_wine_tools in
 136        /*) wine_cv_toolsdir="$with_wine_tools" ;;
 137        *)  wine_cv_toolsdir="\$(TOPOBJDIR)/$with_wine_tools" ;;
 138      esac
 139    else
 140      AC_MSG_ERROR([could not find Wine tools in $with_wine_tools.])
 141    fi])
 142 AC_SUBST(TOOLSDIR,$wine_cv_toolsdir)
 143
 144 AC_PATH_XTRA
 145
 146 dnl Check for flex
 147 AC_CHECK_PROGS(FLEX,flex,none)
 148 if test "$FLEX" = "none"
 149 then
 150   AC_MSG_ERROR([no suitable flex found. Please install the 'flex' package.])
 151 fi
 152
 153 dnl Check for bison
 154 AC_CHECK_PROGS(BISON,bison,none)
 155 if test "$BISON" = "none"
 156 then
 157   AC_MSG_ERROR([no suitable bison found. Please install the 'bison' package.])
 158 fi
 159
 160 AC_CHECK_TOOLS(AS,[gas as],as)
 161 AC_CHECK_TOOL(LD,ld,ld)
 162 AC_CHECK_TOOL(AR,ar,ar)
 163 AC_SUBST(ARFLAGS,rc)
 164 AC_PROG_RANLIB
 165 AC_CHECK_TOOL(STRIP,strip,strip)
 166 AC_CHECK_TOOL(WINDRES,windres,false)
 167 AC_PROG_LN_S
 168 WINE_PROG_LN
 169 AC_PROG_EGREP
 170 AC_PATH_PROG(LDCONFIG, ldconfig, true, [/sbin /usr/sbin $PATH])
 171 AC_PROG_INSTALL
 172 dnl Prepend src dir to install path dir if it's a relative path
 173 case "$INSTALL" in
 174   [[\\/$]]* | ?:[[\\/]]* ) ;;
 175   *)  INSTALL="\\\$(TOPSRCDIR)/$INSTALL" ;;
 176 esac
 177
 178 dnl Check for lint
 179 AC_CHECK_PROGS(LINT, lclint lint)
 180 if test "$LINT" = "lint"
 181 then
 182   LINTFLAGS="$LINTFLAGS -errchk=%all,no%longptr64 -errhdr=%user -Ncheck=macro -Nlevel=4"
 183   dnl LINTFLAGS='-D_SIZE_T "-Dsize_t=unsigned long" -errchk=longptr64'
 184 fi
 185 AC_SUBST(LINT)
 186 AC_SUBST(LINTFLAGS)
 187
 188 dnl Check for various programs
 189 AC_CHECK_PROGS(FONTFORGE, fontforge, false)
 190 AC_CHECK_PROGS(PKG_CONFIG, pkg-config, false)
 191 AC_CHECK_PROGS(RSVG, rsvg, false)
 192 AC_CHECK_PROGS(ICOTOOL, icotool, false)
 193
 194 if test "${enable_maintainer_mode+set}" = set
 195 then
 196   if test "$FONTFORGE" = "false"; then WINE_WARNING([fontforge is missing, fonts can't be rebuilt.]); fi
 197   if test "$RSVG" = "false"; then WINE_WARNING([rsvg is missing, icons can't be rebuilt.]); fi
 198   if test "$ICOTOOL" = "false"; then WINE_WARNING([icotool is missing, icons can't be rebuilt.]); fi
 199 fi
 200
 201 case $host_cpu in
 202   *i[[3456789]]86*)
 203     AC_PATH_PROG(PRELINK, prelink, false, [/sbin /usr/sbin $PATH])
 204     ;;
 205 esac
 206
 207 dnl **** Check for some libraries ****
 208
 209 dnl Check for -li386 for NetBSD and OpenBSD
 210 AC_CHECK_LIB(i386,i386_set_ldt)
 211 dnl Check for -lossaudio for NetBSD
 212 AC_CHECK_LIB(ossaudio,_oss_ioctl)
 213 dnl Check for -lpthread
 214 AC_CHECK_LIB(pthread,pthread_create,AC_SUBST(LIBPTHREAD,"-lpthread"))
 215
 216 AC_SUBST(XLIB,"")
 217 AC_SUBST(XFILES,"")
 218 AC_SUBST(OPENGLFILES,"")
 219 AC_SUBST(GLU32FILES,"")
 220 AC_SUBST(OPENGL_LIBS,"")
 221 AC_SUBST(QUARTZFILES,"")
 222
 223 dnl **** Check for header files ****
 224
 225 AC_CHECK_HEADERS(\
 226         AudioUnit/AudioUnit.h \
 227         Carbon/Carbon.h \
 228         CoreAudio/CoreAudio.h \
 229         DiskArbitration/DiskArbitration.h \
 230         IOKit/IOKitLib.h \
 231         alsa/asoundlib.h \
 232         arpa/inet.h \
 233         arpa/nameser.h \
 234         asm/types.h \
 235         capi20.h \
 236         cups/cups.h \
 237         curses.h \
 238         direct.h \
 239         dlfcn.h \
 240         elf.h \
 241         float.h \
 242         fontconfig/fontconfig.h \
 243         getopt.h \
 244         ieeefp.h \
 245         io.h \
 246         jack/jack.h \
 247         jpeglib.h \
 248         lber.h \
 249         lcms.h \
 250         lcms/lcms.h \
 251         ldap.h \
 252         libaudioio.h \
 253         link.h \
 254         linux/cdrom.h \
 255         linux/compiler.h \
 256         linux/hdreg.h \
 257         linux/input.h \
 258         linux/ioctl.h \
 259         linux/joystick.h \
 260         linux/major.h \
 261         linux/param.h \
 262         linux/serial.h \
 263         linux/ucdrom.h \
 264         mach/mach.h \
 265         mach/machine.h \
 266         machine/cpu.h \
 267         machine/limits.h \
 268         machine/soundcard.h \
 269         mntent.h \
 270         ncurses.h \
 271         netdb.h \
 272         netinet/in.h \
 273         netinet/in_systm.h \
 274         netinet/tcp.h \
 275         netinet/tcp_fsm.h \
 276         openssl/err.h \
 277         openssl/ssl.h \
 278         png.h \
 279         poll.h \
 280         process.h \
 281         pthread.h \
 282         pwd.h \
 283         regex.h \
 284         sched.h \
 285         scsi/scsi.h \
 286         scsi/scsi_ioctl.h \
 287         scsi/sg.h \
 288         soundcard.h \
 289         stdint.h \
 290         strings.h \
 291         sys/asoundlib.h \
 292         sys/cdio.h \
 293         sys/elf32.h \
 294         sys/epoll.h \
 295         sys/errno.h \
 296         sys/event.h \
 297         sys/exec_elf.h \
 298         sys/filio.h \
 299         sys/ioctl.h \
 300         sys/ipc.h \
 301         sys/limits.h \
 302         sys/link.h \
 303         sys/lwp.h \
 304         sys/mman.h \
 305         sys/modem.h \
 306         sys/msg.h \
 307         sys/mtio.h \
 308         sys/param.h \
 309         sys/poll.h \
 310         sys/prctl.h \
 311         sys/ptrace.h \
 312         sys/reg.h \
 313         sys/resource.h \
 314         sys/scsiio.h \
 315         sys/shm.h \
 316         sys/signal.h \
 317         sys/socket.h \
 318         sys/socketvar.h \
 319         sys/sockio.h \
 320         sys/soundcard.h \
 321         sys/statvfs.h \
 322         sys/strtio.h \
 323         sys/syscall.h \
 324         sys/sysctl.h \
 325         sys/time.h \
 326         sys/times.h \
 327         sys/uio.h \
 328         sys/un.h \
 329         sys/vm86.h \
 330         sys/wait.h \
 331         syscall.h \
 332         termios.h \
 333         unistd.h \
 334         utime.h \
 335         valgrind/memcheck.h
 336 )
 337 AC_HEADER_STAT()
 338
 339 dnl **** Checks for headers that depend on other ones ****
 340
 341 AC_CHECK_HEADERS([sys/mount.h sys/statfs.h sys/user.h sys/vfs.h],,,
 342     [#include <sys/types.h>
 343      #ifdef HAVE_SYS_PARAM_H
 344      # include <sys/param.h>
 345      #endif])
 346
 347 AC_CHECK_HEADERS([netinet/in_pcb.h netinet/ip_var.h net/if.h net/if_arp.h net/if_dl.h net/if_types.h net/route.h netipx/ipx.h],,,
 348     [#include <sys/types.h>
 349      #ifdef HAVE_SYS_SOCKET_H
 350      # include <sys/socket.h>
 351      #endif
 352      #ifdef HAVE_SYS_SOCKETVAR_H
 353      # include <sys/socketvar.h>
 354      #endif
 355      #ifdef HAVE_NETINET_IN_H
 356      # include <netinet/in.h>
 357      #endif])
 358
 359 AC_CHECK_HEADERS([netinet/tcp_var.h],,,
 360     [#include <sys/types.h>
 361      #ifdef HAVE_SYS_SOCKET_H
 362      # include <sys/socket.h>
 363      #endif
 364      #ifdef HAVE_SYS_SOCKETVAR_H
 365      # include <sys/socketvar.h>
 366      #endif
 367      #ifdef HAVE_NETINET_IN_H
 368      # include <netinet/in.h>
 369      #endif
 370      #ifdef HAVE_NETINET_TCP_H
 371      # include <netinet/tcp.h>
 372      #endif])
 373
 374 AC_CHECK_HEADERS([linux/ipx.h],,,
 375     [#include <sys/types.h>
 376      #ifdef HAVE_ASM_TYPES_H
 377      # include <asm/types.h>
 378      #endif
 379      #ifdef HAVE_SYS_SOCKET_H
 380      # include <sys/socket.h>
 381      #endif])
 382
 383 AC_CHECK_HEADERS([resolv.h],,,
 384     [#include <sys/types.h>
 385      #ifdef HAVE_SYS_SOCKET_H
 386      # include <sys/socket.h>
 387      #endif
 388      #ifdef HAVE_NETINET_IN_H
 389      # include <netinet/in.h>
 390      #endif
 391      #ifdef HAVE_ARPA_NAMESER_H
 392      # include <arpa/nameser.h>
 393      #endif])
 394
 395 AC_CHECK_HEADERS(ucontext.h,,,[#include <signal.h>])
 396
 397 AC_CHECK_HEADERS([sys/thr.h],,,
 398 [#include <sys/types.h>
 399 #ifdef HAVE_UCONTEXT_H
 400 #include <ucontext.h>
 401 #endif])
 402
 403 AC_CHECK_HEADERS([pthread_np.h],,,
 404 [#ifdef HAVE_PTHREAD_H
 405 #include <pthread.h>
 406 #endif])
 407
 408 AC_CHECK_HEADERS([linux/videodev.h],,,
 409 [#ifdef HAVE_SYS_TIME_H
 410 #include <sys/time.h>
 411 #endif
 412 #include <sys/types.h>
 413 #ifdef HAVE_ASM_TYPES_H
 414 #include <asm/types.h>
 415 #endif])
 416
 417 dnl Check for broken kernel header that doesn't define __user
 418 AC_CHECK_HEADERS([linux/capi.h],,,[#define __user])
 419
 420 dnl **** Check for working dll ****
 421
 422 AC_SUBST(DLLEXT,"")
 423 AC_SUBST(DLLFLAGS,"-D_REENTRANT")
 424 AC_SUBST(LDSHARED,"")
 425 AC_SUBST(LDDLLFLAGS,"")
 426 AC_SUBST(LIBEXT,"so")
 427 AC_SUBST(IMPLIBEXT,"def")
 428 AC_SUBST(LDRPATH_INSTALL,"")
 429 AC_SUBST(LDRPATH_LOCAL,"")
 430 WINE_PATH_LDD
 431
 432 case $host_os in
 433   cygwin*|mingw32*)
 434     AC_CHECK_TOOL(DLLTOOL,dlltool,false)
 435     AC_CHECK_TOOL(DLLWRAP,dllwrap,false)
 436     AC_CHECK_TOOL(MINGWAR,ar,false)
 437     if test "$DLLWRAP" = "false"; then
 438       LIBEXT="a"
 439     else
 440       dnl FIXME - check whether dllwrap works correctly...
 441       LIBEXT="dll"
 442     fi
 443     IMPLIBEXT="a"
 444     dnl We can't build 16-bit NE dlls
 445     WIN16_FILES=""
 446     WIN16_INSTALL=""
 447     ;;
 448   darwin*|macosx*)
 449     DLLEXT=".so"
 450     LIBEXT="dylib"
 451     DLLFLAGS="$DLLFLAGS -fPIC"
 452     LDDLLFLAGS="-bundle -multiply_defined suppress"
 453     LIBWINE_LDFLAGS="-multiply_defined suppress"
 454     LDSHARED="\$(CC) -dynamiclib"
 455     STRIP="$STRIP -x"
 456     LDRPATH_LOCAL="&& install_name_tool -change @executable_path/\`\$(RELPATH) \$(bindir) \$(libdir)\`/libwine.1.dylib @executable_path/\$(TOPOBJDIR)/libs/wine/libwine.1.dylib \$@ || \$(RM) \$@"
 457     dnl declare needed frameworks
 458     AC_SUBST(SECURITYLIB,"-framework Security -framework CoreFoundation")
 459     AC_SUBST(COREFOUNDATIONLIB,"-framework CoreFoundation")
 460     AC_SUBST(IOKITLIB,"-framework IOKit -framework CoreFoundation")
 461     AC_SUBST(LDEXECFLAGS,["-image_base 0x7bf00000 -Wl,-segaddr,WINE_DOS,0x00000000,-segaddr,WINE_SHARED_HEAP,0x7f000000"])
 462     if test "$ac_cv_header_DiskArbitration_DiskArbitration_h" = "yes"
 463     then
 464         dnl DiskArbitration API is not public on Darwin < 8.0, use it only if header found
 465         AC_SUBST(DISKARBITRATIONLIB,"-framework DiskArbitration -framework CoreFoundation")
 466     fi
 467     if test "$ac_cv_header_CoreAudio_CoreAudio_h" = "yes" -a "$ac_cv_header_AudioUnit_AudioUnit_h" = "yes"
 468     then
 469         dnl CoreServices needed by AudioUnit
 470         AC_SUBST(COREAUDIO,"-framework CoreAudio -framework AudioUnit -framework CoreServices -framework AudioToolbox -framework CoreMIDI")
 471     fi
 472     case $host_cpu in
 473       *powerpc*)
 474         LDDLLFLAGS="$LDDLLFLAGS -read_only_relocs warning"  dnl FIXME
 475         ;;
 476     esac
 477     dnl Enable quartz driver on Mac OS X
 478     if test "$ac_cv_header_Carbon_Carbon_h" = "yes"
 479     then
 480         AC_SUBST(CARBONLIB,"-framework Carbon")
 481         QUARTZFILES='$(QUARTZFILES)'
 482     fi
 483     ;;
 484   *)
 485     DLLFLAGS="$DLLFLAGS -fPIC"
 486     DLLEXT=".so"
 487     AC_CACHE_CHECK([whether we can build a GNU style ELF dll], ac_cv_c_dll_gnuelf,
 488         [WINE_TRY_SHLIB_FLAGS([-fPIC -shared -Wl,-Bsymbolic],
 489                               ac_cv_c_dll_gnuelf="yes",ac_cv_c_dll_gnuelf="no")])
 490     if test "$ac_cv_c_dll_gnuelf" = "yes"
 491     then
 492       LDSHARED="\$(CC) -shared"
 493       LDDLLFLAGS="-shared -Wl,-Bsymbolic"
 494       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-soname,confest.so.1],
 495                       [LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-soname,%)"],
 496                       [WINE_TRY_CFLAGS([-fPIC -shared -Wl,-h,confest.so.1],
 497                                        [LDSHARED="\$(CC) -shared \$(SONAME:%=-Wl,-h,%)"])])
 498
 499       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-z,defs], [LDDLLFLAGS="$LDDLLFLAGS,-z,defs"])
 500
 501       WINE_TRY_CFLAGS([-fPIC -shared -Wl,-Bsymbolic,-init,__wine_spec_init,-fini,__wine_spec_fini],
 502                       [LDDLLFLAGS="$LDDLLFLAGS,-init,__wine_spec_init,-fini,__wine_spec_fini"])
 503
 504       echo '{ global: *; };' >conftest.map
 505       WINE_TRY_CFLAGS([-fPIC -shared -Wl,--version-script=conftest.map],
 506                       [LDSHARED="$LDSHARED \$(VERSCRIPT:%=-Wl,--version-script=%)"])
 507       rm -f conftest.map
 508
 509       WINE_TRY_CFLAGS([-fPIC -Wl,--export-dynamic],
 510                       [AC_SUBST(LDEXECFLAGS,["-Wl,--export-dynamic"])])
 511
 512       WINE_TRY_CFLAGS([-fPIC -Wl,--rpath,\$ORIGIN/../lib],
 513                       [LDRPATH_INSTALL="-Wl,--rpath,\\\$\$ORIGIN/\`\$(RELPATH) \$(bindir) \$(libdir)\`"
 514                        LDRPATH_LOCAL="-Wl,--rpath,\\\$\$ORIGIN/\$(TOPOBJDIR)/libs/wine"],
 515           [WINE_TRY_CFLAGS([-fPIC -Wl,-R,\$ORIGIN/../lib],
 516                            [LDRPATH_INSTALL="-Wl,-R,\\\$\$ORIGIN/\`\$(RELPATH) \$(bindir) \$(libdir)\`"
 517                             LDRPATH_LOCAL="-Wl,-R,\\\$\$ORIGIN/\$(TOPOBJDIR)/libs/wine"])])
 518
 519       WINE_TRY_CFLAGS([-Wl,--enable-new-dtags],
 520                       [LDRPATH_INSTALL="$LDRPATH_INSTALL -Wl,--enable-new-dtags"])
 521
 522       case $host_cpu in
 523         *i[[3456789]]86* | x86_64)
 524           WINE_TRY_CFLAGS([-Wl,--section-start,.interp=0x7bf00400],
 525                           [LDEXECFLAGS="$LDEXECFLAGS -Wl,--section-start,.interp=0x7bf00400"])
 526           ;;
 527       esac
 528
 529     else
 530       AC_CACHE_CHECK(whether we can build a UnixWare (Solaris) dll, ac_cv_c_dll_unixware,
 531           [WINE_TRY_SHLIB_FLAGS([-fPIC -Wl,-G,-h,conftest.so.1.0,-B,symbolic],
 532                                 ac_cv_c_dll_unixware="yes",ac_cv_c_dll_unixware="no")])
 533       if test "$ac_cv_c_dll_unixware" = "yes"
 534       then
 535         LDSHARED="\$(CC) -Wl,-G \$(SONAME:%=-Wl,-h,%)"
 536         LDDLLFLAGS="-Wl,-G,-B,symbolic"
 537
 538       else
 539         AC_CACHE_CHECK(whether we can build an HP-UX dll, ac_cv_c_dll_hpux,
 540           [WINE_TRY_SHLIB_FLAGS([-shared], ac_cv_c_dll_hpux="yes", ac_cv_c_dll_hpux="no")])
 541         if test "$ac_cv_c_dll_hpux" = "yes"
 542         then
 543           LIBEXT="sl"
 544           DLLEXT=".sl"
 545           LDDLLFLAGS="-shared -fPIC"
 546           LDSHARED="\$(CC) -shared"
 547         fi
 548       fi
 549     fi
 550
 551     dnl Check for cross compiler to build test programs
 552     AC_SUBST(CROSSTEST,"")
 553     if test "$cross_compiling" = "no"
 554     then
 555       WINE_CHECK_MINGW_PROG(CROSSCC,gcc,false)
 556       WINE_CHECK_MINGW_PROG(DLLTOOL,dlltool,false)
 557       WINE_CHECK_MINGW_PROG(CROSSWINDRES,windres,false)
 558       WINE_CHECK_MINGW_PROG(MINGWAR,ar,false)
 559       if test "$CROSSCC" != "false"; then CROSSTEST="\$(CROSSTEST)"; fi
 560     fi
 561     ;;
 562 esac
 563
 564 if test "$LIBEXT" = "a"; then
 565   AC_MSG_ERROR(
 566 [could not find a way to build shared libraries.
 567 It is currently not possible to build Wine without shared library
 568 (.so) support to allow transparent switch between .so and .dll files.
 569 If you are using Linux, you will need a newer binutils.]
 570 )
 571 fi
 572
 573 dnl **** Check for X11 ****
 574
 575 if test "$have_x" = "yes"
 576 then
 577     XLIB="-lXext -lX11"
 578     ac_save_CPPFLAGS="$CPPFLAGS"
 579     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 580
 581     WINE_CHECK_SONAME(X11,XCreateWindow,,,[$X_LIBS $X_EXTRA_LIBS])
 582     WINE_CHECK_SONAME(Xext,XextCreateExtension,,,[$X_LIBS -lX11 $X_EXTRA_LIBS])
 583
 584     dnl *** All of the following tests require X11/Xlib.h
 585     AC_CHECK_HEADERS([X11/Xlib.h \
 586                       X11/XKBlib.h \
 587                       X11/Xutil.h \
 588                       X11/Xcursor/Xcursor.h \
 589                       X11/extensions/shape.h \
 590                       X11/extensions/XInput.h \
 591                       X11/extensions/XShm.h \
 592                       X11/extensions/Xcomposite.h \
 593                       X11/extensions/Xinerama.h \
 594                       X11/extensions/Xrandr.h \
 595                       X11/extensions/Xrender.h \
 596                       X11/extensions/xf86vmode.h],,,
 597 [#ifdef HAVE_X11_XLIB_H
 598 # include <X11/Xlib.h>
 599 #endif
 600 #ifdef HAVE_X11_XUTIL_H
 601 # include <X11/Xutil.h>
 602 #endif])
 603
 604         dnl *** Check for X keyboard extension
 605         if test "$ac_cv_header_X11_XKBlib_h" = "yes"
 606         then
 607               AC_CHECK_LIB(X11, XkbQueryExtension,
 608               AC_DEFINE(HAVE_XKB, 1, [Define if you have the XKB extension]),,
 609               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 610         fi
 611
 612         dnl *** Check for X cursor
 613         if test "$ac_cv_header_X11_Xcursor_Xcursor_h" = "yes"
 614         then
 615             WINE_CHECK_SONAME(Xcursor,XcursorImageLoadCursor,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
 616         fi
 617         WINE_NOTICE_WITH(xcursor,[test "x$ac_cv_lib_soname_Xcursor" = "x"],
 618                          [libxcursor development files not found, the Xcursor extension won't be supported.])
 619
 620         dnl *** Check for X input extension
 621         if test "$ac_cv_header_X11_extensions_XInput_h" = "yes"
 622         then
 623             WINE_CHECK_SONAME(Xi,XOpenDevice,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
 624         fi
 625         WINE_NOTICE_WITH(xinput,[test "x$ac_cv_lib_soname_Xi" = "x"],
 626                          [libxi development files not found, the Xinput extension won't be supported.])
 627
 628         dnl *** Check for X Shm extension
 629         if test "$ac_cv_header_X11_extensions_XShm_h" = "yes"
 630         then
 631               AC_CHECK_LIB(Xext, XShmQueryExtension,
 632               AC_DEFINE(HAVE_LIBXXSHM, 1, [Define if you have the X Shm extension]),,
 633               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 634         fi
 635         WINE_NOTICE_WITH(xshm,[test "$ac_cv_lib_Xext_XShmQueryExtension" != "yes"],
 636                          [XShm development files not found, X Shared Memory won't be supported.])
 637
 638         dnl *** Check for X shape extension
 639         if test "$ac_cv_header_X11_extensions_shape_h" = "yes"
 640         then
 641               AC_CHECK_LIB(Xext,XShapeQueryExtension,
 642               AC_DEFINE(HAVE_LIBXSHAPE, 1, [Define if you have the X Shape extension]),,
 643               $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 644         fi
 645         WINE_NOTICE_WITH(xshape,[test "$ac_cv_lib_Xext_XShapeQueryExtension" != "yes"],
 646                          [XShape development files not found, XShape won't be supported.])
 647
 648         dnl *** Check for XFree86 VMODE extension
 649         if test "$ac_cv_header_X11_extensions_xf86vmode_h" = "yes"
 650         then
 651                 AC_CHECK_LIB(Xxf86vm, XF86VidModeQueryExtension,
 652                   [ AC_DEFINE(HAVE_LIBXXF86VM, 1, [Define if you have the Xxf86vm library])
 653                      X_PRE_LIBS="$X_PRE_LIBS -lXxf86vm"
 654                   ],,
 655                   $X_LIBS -lXext -lX11 $X_EXTRA_LIBS)
 656         fi
 657         WINE_NOTICE_WITH(xvidmode,[test "$ac_cv_lib_Xxf86vm_XF86VidModeQueryExtension" != "yes"],
 658                          [libXxf86vm development files not found, XFree86 Vidmode won't be supported.])
 659
 660         dnl *** Check for Transform functions in Xrender
 661         if test "$ac_cv_header_X11_extensions_Xrender_h" = "yes" -a "x$ac_cv_lib_soname_X11" != "x" -a "x$ac_cv_lib_soname_Xext" != "x"
 662         then
 663             WINE_CHECK_SONAME(Xrender,XRenderQueryExtension,
 664               [AC_CHECK_LIB(Xrender,XRenderSetPictureTransform,
 665                 [AC_DEFINE(HAVE_XRENDERSETPICTURETRANSFORM, 1,
 666                  [Define if Xrender has the XRenderSetPictureTransform function])],,
 667                 [$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])],,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
 668
 669         fi
 670         WINE_NOTICE_WITH(xrender,[test "x$ac_cv_lib_soname_Xrender" = "x"],
 671                          [libxrender development files not found, XRender won't be supported.])
 672
 673         dnl *** Check for X RandR extension
 674         if test "$ac_cv_header_X11_extensions_Xrandr_h" = "yes" -a "x$ac_cv_lib_soname_Xrender" != "x"
 675         then
 676                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
 677 #include <X11/extensions/Xrandr.h>]], [[static typeof(XRRSetScreenConfigAndRate) * func;]])],
 678                   [WINE_CHECK_SONAME(Xrandr,XRRQueryExtension,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
 679         fi
 680         WINE_NOTICE_WITH(xrandr,[test "x$ac_cv_lib_soname_Xrandr" = "x"],
 681                          [libxrandr development files not found, XRandr won't be supported.])
 682
 683         dnl *** Check for Xinerama extension
 684         if test "$ac_cv_header_X11_extensions_Xinerama_h" = "yes"
 685         then
 686                 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <X11/Xlib.h>
 687 #include <X11/extensions/Xinerama.h>]], [[static typeof(XineramaQueryScreens) * func;]])],
 688                   [WINE_CHECK_SONAME(Xinerama,XineramaQueryScreens,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
 689         fi
 690         WINE_NOTICE_WITH(xinerama,[test "x$ac_cv_lib_soname_Xinerama" = "x"],
 691                          [libxinerama development files not found, multi-monitor setups won't be supported.])
 692
 693         dnl *** Check for X Composite extension
 694         if test "$ac_cv_header_X11_extensions_Xcomposite_h" = "yes"
 695         then
 696             WINE_CHECK_SONAME(Xcomposite,XCompositeRedirectWindow,,,[$X_LIBS -lXext -lX11 $X_EXTRA_LIBS])
 697         fi
 698         WINE_NOTICE_WITH(xcomposite,[test "x$ac_cv_lib_soname_Xcomposite" = "x"],
 699                          [libxcomposite development files not found, Xcomposite won't be supported.])
 700
 701         dnl *** Check for XICCallback struct
 702         AC_CHECK_MEMBERS([XICCallback.callback],,,
 703 [#ifdef HAVE_X11_XLIB_H
 704 #include <X11/Xlib.h>
 705 #endif])
 706
 707     dnl *** End of X11/Xlib.h check
 708
 709     dnl Check for the presence of OpenGL
 710     opengl_msg=""
 711     if test "x$with_opengl" != "xno"
 712     then
 713         AC_CHECK_HEADERS(GL/gl.h GL/glx.h GL/glext.h GL/glu.h,,,
 714 [#ifdef HAVE_GL_GLX_H
 715 # include <GL/glx.h>
 716 #endif])
 717         if test "$ac_cv_header_GL_gl_h" = "yes" -a "$ac_cv_header_GL_glx_h" = "yes"
 718         then
 719             dnl Check for some problems due to old Mesa versions
 720             AC_CACHE_CHECK([for up-to-date OpenGL version], wine_cv_opengl_header_version_OK,
 721               AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <GL/gl.h>]], [[GLenum test = GL_UNSIGNED_SHORT_5_6_5;]])],
 722                 [wine_cv_opengl_header_version_OK="yes"],
 723                 [wine_cv_opengl_header_version_OK="no"]))
 724
 725             if test "$wine_cv_opengl_header_version_OK" = "yes"
 726             then
 727                 dnl Check for the presence of the library
 728                 WINE_CHECK_SONAME(GL,glXCreateContext,
 729                              [OPENGL_LIBS="-lGL"
 730                              OPENGLFILES='$(OPENGLFILES)'
 731                              AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])],
 732                              [WINE_CHECK_SONAME(GL,glXCreateContext,
 733                                     [OPENGL_LIBS="-Xlinker -dylib_file -Xlinker /System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib:/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib -lGL"
 734                                     OPENGLFILES='$(OPENGLFILES)'
 735                                     AC_DEFINE(HAVE_OPENGL, 1, [Define if OpenGL is present on the system])],
 736                                     [if test -f /usr/X11R6/lib/libGL.a
 737                                     then
 738                                         opengl_msg="/usr/X11R6/lib/libGL.a is present on your system.
 739 This probably prevents linking to OpenGL. Try deleting the file and restarting configure."
 740                                     else
 741                                         opengl_msg="No OpenGL library found on this system."
 742                                     fi],
 743                                     $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS -dylib_file /System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib:/System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib)],
 744                              $X_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 745
 746                 dnl Check for GLU32 library.
 747                 AC_CHECK_LIB(GLU,gluLookAt,
 748                              [OPENGL_LIBS="$OPENGL_LIBS -lGLU"
 749                              GLU32FILES='$(GLU32FILES)']
 750                              ,,
 751                              $OPENGL_LIBS $X_LIBS $X_PRE_LIBS -lXext -lX11 -lm $X_EXTRA_LIBS)
 752              else
 753                  opengl_msg="Old Mesa headers detected. Consider upgrading your Mesa libraries."
 754              fi
 755          else
 756              opengl_msg="OpenGL development headers not found."
 757          fi
 758     fi
 759     WINE_WARNING_WITH(opengl,[test -n "$opengl_msg"],[$opengl_msg
 760 OpenGL and Direct3D won't be supported.])
 761
 762     dnl **** Check for NAS ****
 763     AC_SUBST(NASLIBS,"")
 764     AC_CHECK_HEADERS(audio/audiolib.h,
 765          [AC_CHECK_HEADERS(audio/soundlib.h,,,[#include <audio/audiolib.h>])
 766           AC_CHECK_LIB(audio,AuCreateFlow,
 767                        [AC_DEFINE(HAVE_NAS,1,[Define if you have NAS including devel headers])
 768                         AC_CHECK_LIB(Xau,XauGetBestAuthByAddr,
 769                           [NASLIBS="-lXau -laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],
 770                           [NASLIBS="-laudio -lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS"],
 771                           [$X_LIBS])
 772                        ],,
 773                        [-lXt $X_LIBS -lXext -lX11 $X_EXTRA_LIBS])])
 774
 775     CPPFLAGS="$ac_save_CPPFLAGS"
 776     XFILES='$(XFILES)'
 777 else
 778     XLIB=""
 779     X_CFLAGS=""
 780     X_LIBS=""
 781 fi
 782 WINE_WARNING_WITH(x,[test "x$XLIB" = "x"],[X development files not found. Wine will be built
 783 without X support, which probably isn't what you want. You will need to install
 784 development packages of Xlib/Xfree86 at the very least.])
 785
 786 dnl **** Check for libxml2 ****
 787
 788 AC_SUBST(XML2LIBS,"")
 789 AC_SUBST(XML2INCL,"")
 790 AC_SUBST(XSLTLIBS,"")
 791 AC_SUBST(XSLTINCL,"")
 792 if test "x$with_xml" != "xno"
 793 then
 794     ac_save_CPPFLAGS="$CPPFLAGS"
 795     if test "$PKG_CONFIG" != "false"
 796     then
 797         ac_xml_libs="`$PKG_CONFIG --libs libxml-2.0 2>/dev/null`"
 798         ac_xml_cflags="`$PKG_CONFIG --cflags libxml-2.0 2>/dev/null`"
 799     else
 800         ac_xml_libs="`xml2-config --libs 2>/dev/null`"
 801         ac_xml_cflags="`xml2-config --cflags  2>/dev/null`"
 802     fi
 803     CPPFLAGS="$CPPFLAGS $ac_xml_cflags"
 804     AC_CHECK_HEADERS(libxml/parser.h,
 805             [AC_CHECK_LIB(xml2, xmlParseMemory,
 806                 [AC_DEFINE(HAVE_LIBXML2, 1, [Define if you have the libxml2 library])
 807                  XML2LIBS="$ac_xml_libs"
 808                  XML2INCL="$ac_xml_cflags"],,$ac_xml_libs)
 809              AC_CHECK_LIB(xml2, xmlReadMemory,
 810                 [AC_DEFINE(HAVE_XMLREADMEMORY,1,[Define if libxml2 has the xmlReadMemory function])],,$ac_xml_libs)
 811              AC_CHECK_LIB(xml2, xmlNewDocPI,
 812                 [AC_DEFINE(HAVE_XMLNEWDOCPI,1,[Define if libxml2 has the xmlNewDocPI function])],,$ac_xml_libs)
 813         ])
 814     CPPFLAGS="$ac_save_CPPFLAGS"
 815 fi
 816 WINE_NOTICE_WITH(xml,[test "$ac_cv_lib_xml2_xmlParseMemory" != "yes"],
 817                  [libxml2 development files not found, XML won't be supported.])
 818
 819 if test "x$with_xslt" != "xno"
 820 then
 821     if test "$PKG_CONFIG" != "false"
 822     then
 823         ac_xslt_libs="`$PKG_CONFIG --libs libxslt 2>/dev/null`"
 824         ac_xslt_cflags="`$PKG_CONFIG --cflags libxslt 2>/dev/null`"
 825     else
 826         ac_xslt_libs="`xslt-config --libs 2>/dev/null`"
 827         ac_xslt_cflags="`xslt-config --cflags 2>/dev/null`"
 828     fi
 829     ac_save_CPPFLAGS="$CPPFLAGS"
 830     CPPFLAGS="$CPPFLAGS $ac_xslt_cflags"
 831     AC_CHECK_HEADERS([libxslt/pattern.h libxslt/transform.h],,,
 832     [#ifdef HAVE_LIBXSLT_PATTERN_H
 833 # include <libxslt/pattern.h>
 834 #endif])
 835     CPPFLAGS="$ac_save_CPPFLAGS"
 836     if test "$ac_cv_header_libxslt_transform_h" = "yes"
 837     then
 838         AC_CHECK_LIB(xslt, xsltCompilePattern,
 839             [AC_DEFINE(HAVE_LIBXSLT, 1, [Define if you have the libxslt library])
 840              XSLTLIBS="$ac_xslt_libs"
 841              XSLTINCL="$ac_xslt_cflags"
 842              ac_save_LIBS="$LIBS"
 843              LIBS="$LIBS $ac_xslt_libs"
 844              AC_CHECK_FUNCS(xsltInit)
 845              LIBS="$ac_save_LIBS"],,$ac_xslt_libs)
 846     fi
 847 fi
 848 WINE_NOTICE_WITH(xslt,[test "$ac_cv_lib_xslt_xsltCompilePattern" != "yes"],
 849                  [libxslt development files not found, xslt won't be supported.])
 850
 851 dnl **** Check for libhal ****
 852 AC_SUBST(HALINCL,"")
 853 if test "x$with_hal" != "xno" -a "$PKG_CONFIG" != "false"
 854 then
 855     ac_save_CPPFLAGS="$CPPFLAGS"
 856     ac_hal_libs="`$PKG_CONFIG --libs hal 2>/dev/null`"
 857     ac_hal_cflags="`$PKG_CONFIG --cflags hal 2>/dev/null`"
 858     CPPFLAGS="$CPPFLAGS $ac_hal_cflags"
 859     AC_CHECK_HEADERS([dbus/dbus.h hal/libhal.h])
 860     if test "$ac_cv_header_dbus_dbus_h" = "yes" -a "$ac_cv_header_hal_libhal_h" = "yes"
 861     then
 862         AC_CHECK_LIB(dbus-1, dbus_connection_close,
 863           [WINE_CHECK_SONAME(hal, libhal_ctx_new,
 864             [HALINCL="$ac_hal_cflags"],,[$ac_hal_libs])],,[$ac_hal_libs])
 865     fi
 866     CPPFLAGS="$ac_save_CPPFLAGS"
 867 fi
 868 WINE_NOTICE_WITH(hal,[test "x$ac_cv_lib_soname_hal" = "x"],
 869                  [libhal development files not found, no dynamic device support.])
 870
 871 dnl **** Check which curses lib to use ***
 872 CURSESLIBS=""
 873 if test "$ac_cv_header_ncurses_h" = "yes"
 874 then
 875     WINE_CHECK_SONAME(ncurses,waddch,[CURSESLIBS="-lncurses"])
 876 elif test "$ac_cv_header_curses_h" = "yes"
 877 then
 878     WINE_CHECK_SONAME(curses,waddch,[CURSESLIBS="-lcurses"])
 879 fi
 880 ac_save_LIBS="$LIBS"
 881 LIBS="$LIBS $CURSESLIBS"
 882 AC_CHECK_FUNCS(mousemask)
 883 LIBS="$ac_save_LIBS"
 884 WINE_NOTICE_WITH(curses,[test "x$ac_cv_lib_soname_curses$ac_cv_lib_soname_ncurses" = "x"],
 885                  [lib(n)curses development files not found, curses won't be supported.])
 886
 887 dnl **** Check for SANE ****
 888 AC_CHECK_PROG(sane_devel,sane-config,sane-config,no)
 889 if test "$sane_devel" != "no" -a "x$with_sane" != "xno"
 890 then
 891     ac_sane_incl="`$sane_devel --cflags`"
 892     ac_save_CPPFLAGS="$CPPFLAGS"
 893     CPPFLAGS="$CPPFLAGS $ac_sane_incl"
 894     AC_CHECK_HEADER(sane/sane.h,
 895         [WINE_CHECK_SONAME(sane,sane_init,[AC_SUBST(SANEINCL,"$ac_sane_incl")])])
 896     CPPFLAGS="$ac_save_CPPFLAGS"
 897 fi
 898 WINE_NOTICE_WITH(sane,[test "x$ac_cv_lib_soname_sane" = "x"],
 899                  [libsane development files not found, scanners won't be supported.])
 900
 901 dnl **** Check for libgphoto2 ****
 902 AC_CHECK_PROG(gphoto2_devel,gphoto2-config,gphoto2-config,no)
 903 AC_CHECK_PROG(gphoto2port_devel,gphoto2-port-config,gphoto2-port-config,no)
 904 if test "$gphoto2_devel" != "no" -a "$gphoto2port_devel" != "no" -a "x$with_gphoto" != "xno"
 905 then
 906     ac_gphoto2_incl="`$gphoto2_devel --cflags` `$gphoto2port_devel --cflags`"
 907     ac_gphoto2_libs=""
 908     for i in `$gphoto2_devel --libs` `$gphoto2port_devel --libs`
 909     do
 910       case "$i" in
 911         -L/usr/lib|-L/usr/lib64) ;;
 912         -L*|-l*) ac_gphoto2_libs="$ac_gphoto2_libs $i";;
 913       esac
 914     done
 915     ac_save_CPPFLAGS="$CPPFLAGS"
 916     CPPFLAGS="$CPPFLAGS $ac_gphoto2_incl"
 917     AC_CHECK_HEADER(gphoto2-camera.h,
 918                     [AC_CHECK_LIB(gphoto2,gp_camera_new,
 919                                   [AC_DEFINE(HAVE_GPHOTO2, 1, [Define if we have libgphoto2 development environment])
 920                                    AC_SUBST(GPHOTO2LIBS,"$ac_gphoto2_libs")
 921                                    AC_SUBST(GPHOTO2INCL,"$ac_gphoto2_incl")],,
 922                                   [$GPHOTO2LIBS])])
 923     CPPFLAGS="$ac_save_CPPFLAGS"
 924 fi
 925 WINE_NOTICE_WITH(gphoto,[test "$ac_cv_lib_gphoto2_gp_camera_new" != "yes"],
 926                  [libgphoto2 development files not found, digital cameras won't be supported.])
 927
 928
 929 dnl **** Check for resolver library ***
 930 AC_SUBST(RESOLVLIBS,"")
 931 if test "$ac_cv_header_resolv_h" = "yes"
 932 then
 933     AC_CHECK_LIB(resolv, res_query,
 934         [AC_DEFINE(HAVE_RESOLV, 1, [Define if you have the resolver library and header])
 935          RESOLVLIBS="-lresolv"])
 936 fi
 937
 938 dnl **** Check for LittleCMS ***
 939 AC_SUBST(LCMSLIBS,"")
 940 if test "$ac_cv_header_lcms_h" = "yes" -o "$ac_cv_header_lcms_lcms_h" = "yes"
 941 then
 942     AC_CHECK_LIB(lcms, cmsOpenProfileFromFile,
 943         [AC_DEFINE(HAVE_LCMS, 1, [Define if you have the LittleCMS development environment])
 944          LCMSLIBS="-llcms"])
 945 fi
 946 WINE_NOTICE_WITH(cms,[test "$ac_cv_lib_lcms_cmsOpenProfileFromFile" != "yes"],
 947                  [liblcms development files not found, Color Management won't be supported.])
 948
 949 dnl **** Check for OpenLDAP ***
 950 AC_SUBST(LDAPLIBS,"")
 951 if test "$ac_cv_header_ldap_h" = "yes" -a "$ac_cv_header_lber_h" = "yes"
 952 then
 953     AC_CHECK_LIB(ldap_r, ldap_initialize,
 954         [AC_CHECK_LIB(lber, ber_init,
 955             [AC_DEFINE(HAVE_LDAP, 1, [Define if you have the OpenLDAP development environment])
 956              LDAPLIBS="-lldap_r -llber"],,
 957              [$LIBPTHREAD])],,
 958              [$LIBPTHREAD])
 959     WINE_CHECK_LIB_FUNCS(\
 960         ldap_count_references \
 961         ldap_first_reference \
 962         ldap_next_reference \
 963         ldap_parse_reference \
 964         ldap_parse_sort_control \
 965         ldap_parse_sortresponse_control \
 966         ldap_parse_vlv_control \
 967         ldap_parse_vlvresponse_control,
 968         [$LDAPLIBS $LIBPTHREAD])
 969 fi
 970 WINE_NOTICE_WITH(ldap,[test "x$LDAPLIBS" = "x"],
 971                  [libldap (OpenLDAP) development files not found, LDAP won't be supported.])
 972
 973 dnl **** Check for FreeType 2 ****
 974 AC_CHECK_PROGS(ft_devel,[freetype-config freetype2-config],false)
 975 if test "$ft_devel" != "false"
 976 then
 977     ac_freetype_libs=`$ft_devel --libs`
 978     ac_freetype_incl=`$ft_devel --cflags`
 979     WINE_CHECK_SONAME(freetype,FT_Init_FreeType,[ft_lib=yes],[ft_lib=no],[$ac_freetype_libs])
 980     if test "$ft_lib" = "yes"
 981     then
 982         ac_save_CPPFLAGS="$CPPFLAGS"
 983         CPPFLAGS="$ac_freetype_incl $CPPFLAGS"
 984         AC_CHECK_HEADERS(ft2build.h \
 985                          freetype/freetype.h \
 986                          freetype/ftglyph.h \
 987                          freetype/fttypes.h \
 988                          freetype/tttables.h \
 989                          freetype/ftnames.h \
 990                          freetype/ftsnames.h \
 991                          freetype/ttnameid.h \
 992                          freetype/ftoutln.h \
 993                          freetype/ftwinfnt.h \
 994                          freetype/ftmodapi.h \
 995                          freetype/internal/sfnt.h,,,
 996                          [#ifdef HAVE_FT2BUILD_H
 997                           # include <ft2build.h>
 998                           #endif])
 999         AC_PREPROC_IFELSE([AC_LANG_SOURCE([[#include <ft2build.h>
1000                     #include <freetype/fttrigon.h>]])],[AC_DEFINE(HAVE_FREETYPE_FTTRIGON_H, 1,
1001           [Define if you have the <freetype/fttrigon.h> header file.])
1002                     wine_cv_fttrigon=yes],[wine_cv_fttrigon=no])
1003         AC_CHECK_TYPES(FT_TrueTypeEngineType,,,[#include <freetype/ftmodapi.h>])
1004         ac_save_CFLAGS="$CFLAGS"
1005         CFLAGS="$CFLAGS $ac_freetype_libs"
1006         AC_CHECK_FUNCS(FT_Load_Sfnt_Table)
1007         CFLAGS="$ac_save_CFLAGS"
1008         CPPFLAGS="$ac_save_CPPFLAGS"
1009         dnl Check that we have at least freetype/freetype.h
1010         if test "$ac_cv_header_freetype_freetype_h" = "yes" -a "$wine_cv_fttrigon" = "yes"
1011         then
1012             AC_DEFINE(HAVE_FREETYPE, 1, [Define if FreeType 2 is installed])
1013             AC_SUBST(FREETYPELIBS,"$ac_freetype_libs")
1014             AC_SUBST(FREETYPEINCL,"$ac_freetype_incl")
1015         fi
1016     fi
1017 fi
1018
1019 dnl Only build the fonts dir if we have freetype
1020 if test "x$FREETYPELIBS" = "x"
1021 then
1022     WINE_WARNING([FreeType development files not found.
1023 Fonts will not be built. Dialog text may be invisible or unaligned.])
1024 else
1025   AC_SUBST(FONTSSUBDIRS,"fonts")
1026 fi
1027
1028 dnl **** Check for parport (currently Linux only) ****
1029 AC_CACHE_CHECK([for parport header/ppdev.h], ac_cv_c_ppdev,
1030  AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <linux/ppdev.h>]], [[ioctl (1,PPCLAIM,0)]])],
1031     [ac_cv_c_ppdev="yes"],[ac_cv_c_ppdev="no"]))
1032 if test "$ac_cv_c_ppdev" = "yes"
1033 then
1034     AC_DEFINE(HAVE_PPDEV, 1, [Define if we can use ppdev.h for parallel port access])
1035 fi
1036
1037 dnl **** Check for va_copy ****
1038 AC_CACHE_CHECK([for va_copy], ac_cv_c_va_copy,
1039  AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdarg.h>]], [[va_list ap1, ap2; va_copy(ap1,ap2);]])],
1040     [ac_cv_c_va_copy="yes"],[ac_cv_c_va_copy="no"])
1041  )
1042 if test "$ac_cv_c_va_copy" = "yes"
1043 then
1044     AC_DEFINE(HAVE_VA_COPY, 1, [Define if we have va_copy])
1045 fi
1046 AC_CACHE_CHECK([for __va_copy], ac_cv_c___va_copy,
1047  AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <stdarg.h>]], [[va_list ap1, ap2; __va_copy(ap1,ap2);]])],
1048     [ac_cv_c___va_copy="yes"],[ac_cv_c___va_copy="no"])
1049  )
1050 if test "$ac_cv_c___va_copy" = "yes"
1051 then
1052     AC_DEFINE(HAVE___VA_COPY, 1, [Define if we have __va_copy])
1053 fi
1054
1055 dnl **** Check for sigsetjmp ****
1056 AC_CACHE_CHECK([for sigsetjmp], ac_cv_c_sigsetjmp,
1057  AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <setjmp.h>]], [[sigjmp_buf buf;
1058     sigsetjmp( buf, 1 );
1059     siglongjmp( buf, 1 );]])],[ac_cv_c_sigsetjmp="yes"],[ac_cv_c_sigsetjmp="no"])
1060  )
1061 if test "$ac_cv_c_sigsetjmp" = "yes"
1062 then
1063     AC_DEFINE(HAVE_SIGSETJMP, 1, [Define to 1 if you have the sigsetjmp (and siglongjmp) function])
1064 fi
1065
1066 dnl **** Check for pthread_rwlock_t ****
1067 AC_CHECK_TYPES([pthread_rwlock_t, pthread_rwlockattr_t],,,[#define _GNU_SOURCE
1068 #include <pthread.h>])
1069
1070 dnl **** Check for pthread functions ****
1071 WINE_CHECK_LIB_FUNCS(\
1072         pthread_attr_get_np \
1073         pthread_getattr_np \
1074         pthread_get_stackaddr_np \
1075         pthread_get_stacksize_np,
1076         [$LIBPTHREAD])
1077
1078 dnl **** Check for EsounD ****
1079 AC_PATH_PROG(ESDCONFIG, esd-config)
1080 if test "x$with_esd" != xno -a "x$ESDCONFIG" != x -a "x$ESDCONFIG" != x'"$ESDCONFIG"';
1081 then
1082     ESD_CFLAGS=""
1083     for i in `$ESDCONFIG --cflags`
1084     do
1085       case "$i" in
1086         -I*) ESD_CFLAGS="$ESD_CFLAGS $i";;
1087       esac
1088     done
1089     ESD_LIBS=`$ESDCONFIG --libs`
1090     save_CFLAGS="$CFLAGS"
1091     CFLAGS="$CFLAGS $ESD_CFLAGS"
1092     AC_CHECK_LIB(esd,esd_open_sound,
1093         [AC_SUBST(ESDLIBS, $ESD_LIBS)
1094          AC_SUBST(ESDINCL, $ESD_CFLAGS)
1095          AC_DEFINE(HAVE_ESD, 1, [Define if you have EsounD sound server])])
1096     CFLAGS="$save_CFLAGS"
1097 fi
1098
1099 dnl **** Check for ALSA 1.x ****
1100 AC_SUBST(ALSALIBS,"")
1101 if test "$ac_cv_header_sys_asoundlib_h" = "yes" -o "$ac_cv_header_alsa_asoundlib_h" = "yes"
1102 then
1103     AC_CHECK_LIB(asound,snd_pcm_hw_params_get_access,
1104         [AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#ifdef HAVE_ALSA_ASOUNDLIB_H
1105 #include <alsa/asoundlib.h>
1106 #elif defined(HAVE_SYS_ASOUNDLIB_H)
1107 #include <sys/asoundlib.h>
1108 #endif]], [[int ret = snd_pcm_hw_params_get_access(NULL, NULL)]])],
1109                         [AC_DEFINE(HAVE_ALSA,1,[Define if you have ALSA 1.x including devel headers])
1110                          ALSALIBS="-lasound"],[])])
1111 fi
1112
1113 dnl **** Check for libaudioio (which can be used to get solaris audio support) ****
1114 AC_SUBST(AUDIOIOLIBS,"")
1115 if test "$ac_cv_header_libaudioio_h" = "yes"
1116 then
1117     AC_CHECK_LIB(audioio,AudioIOGetVersion,
1118                   [AUDIOIOLIBS="-laudioio"
1119                    AC_DEFINE(HAVE_LIBAUDIOIO, 1, [Define if you have libaudioIO])])
1120 fi
1121
1122 dnl **** Check for capi4linux ****
1123
1124 if test "$ac_cv_header_capi20_h" = "yes" -a "$ac_cv_header_linux_capi_h" = "yes"
1125 then
1126     WINE_CHECK_SONAME(capi20,capi20_register)
1127 fi
1128 WINE_NOTICE_WITH(capi,[test "x$ac_cv_lib_soname_capi20" = "x"],
1129                  [libcapi20 development files not found, ISDN won't be supported.])
1130
1131 dnl **** Check for cups ****
1132 if test "$ac_cv_header_cups_cups_h" = "yes"
1133 then
1134     WINE_CHECK_SONAME(cups,cupsGetDefault)
1135 fi
1136 WINE_NOTICE_WITH(cups,[test "x$ac_cv_lib_soname_cups" = "x"],
1137                  [libcups development files not found, CUPS won't be supported.])
1138
1139 dnl **** Check for jack ****
1140 if test "$ac_cv_header_jack_jack_h" = "yes"
1141 then
1142     WINE_CHECK_SONAME(jack,jack_client_new)
1143 fi
1144
1145 dnl **** Check for fontconfig ****
1146 if test "$ac_cv_header_fontconfig_fontconfig_h" = "yes"
1147 then
1148     WINE_CHECK_SONAME(fontconfig,FcInit)
1149 elif test -n "$X_CFLAGS" -a "x$with_fontconfig" != "xno"
1150 then
1151     dnl fontconfig is in the X directory on Mac OS X
1152     ac_save_CPPFLAGS="$CPPFLAGS"
1153     CPPFLAGS="$CPPFLAGS $X_CFLAGS"
1154     $as_unset ac_cv_header_fontconfig_fontconfig_h
1155     AC_CHECK_HEADERS([fontconfig/fontconfig.h])
1156     CPPFLAGS="$ac_save_CPPFLAGS"
1157     if test "$ac_cv_header_fontconfig_fontconfig_h" = "yes"
1158     then
1159         AC_SUBST(FONTCONFIGINCL,"$X_CFLAGS")
1160         WINE_CHECK_SONAME(fontconfig,FcInit,,,[$X_LIBS])
1161     fi
1162 fi
1163 WINE_NOTICE_WITH(fontconfig,[test "x$ac_cv_lib_soname_fontconfig" = "x"],
1164                  [fontconfig development files not found, fontconfig won't be supported.])
1165
1166 dnl **** Check for SSL ****
1167 if test "$ac_cv_header_openssl_err_h" = "yes" -a "$ac_cv_header_openssl_ssl_h" = "yes"
1168 then
1169     WINE_CHECK_SONAME(ssl,SSL_library_init)
1170     WINE_CHECK_SONAME(crypto,BIO_new_socket)
1171 fi
1172 WINE_NOTICE_WITH(openssl,[test "x$ac_cv_lib_soname_ssl" = "x"],
1173                  [OpenSSL development files not found, SSL won't be supported.])
1174
1175 dnl **** Check for libjpeg ****
1176 if test "$ac_cv_header_jpeglib_h" = "yes"
1177 then
1178     WINE_CHECK_SONAME(jpeg,jpeg_start_decompress)
1179 fi
1180 WINE_NOTICE_WITH(jpeg,[test "x$ac_cv_lib_soname_jpeg" = "x"],
1181                  [libjpeg development files not found, JPEG won't be supported.])
1182
1183 dnl **** Check for libpng ****
1184 if test "$ac_cv_header_png_h" = "yes"
1185 then
1186     WINE_CHECK_SONAME(png,png_create_read_struct,,,,[[libpng[[0-9]]*]])
1187 fi
1188 WINE_NOTICE_WITH(png,[test "x$ac_cv_lib_soname_png" = "x"],
1189                  [libpng development files not found, PNG won't be supported.])
1190
1191 dnl **** Check for libodbc ****
1192 WINE_CHECK_SONAME(odbc,SQLConnect,,[AC_DEFINE_UNQUOTED(SONAME_LIBODBC,["libodbc.$LIBEXT"])])
1193
1194 dnl **** Check for any sound system ****
1195 if test "x$ALSALIBS$AUDIOIOLIBS$COREAUDIO$NASLIBS$ESD_LIBS$ac_cv_lib_soname_jack" = "x" -a \
1196         "$ac_cv_header_sys_soundcard_h" != "yes" -a \
1197         "$ac_cv_header_machine_soundcard_h" != "yes" -a \
1198         "$ac_cv_header_soundcard_h" != "yes" -a \
1199         "x$with_alsa$with_audioio$with_coreaudio$with_nas$with_esd$with_jack$with_oss" != xnonononononono
1200 then
1201     WINE_WARNING([No sound system was found. Windows applications will be silent.])
1202 fi
1203
1204 dnl **** Check for gcc specific options ****
1205
1206 AC_SUBST(EXTRACFLAGS,"")
1207 if test "x${GCC}" = "xyes"
1208 then
1209   EXTRACFLAGS="-Wall -pipe"
1210
1211   dnl Check for strength-reduce bug
1212   AC_CACHE_CHECK( [for gcc strength-reduce bug], ac_cv_c_gcc_strength_bug,
1213                   AC_RUN_IFELSE([AC_LANG_PROGRAM([[int L[[4]] = {0,1,2,3};]],
1214 [[static int Array[[3]];
1215   unsigned int B = 3;
1216   int i;
1217   for(i=0; i<B; i++) Array[[i]] = i - 3;
1218   for(i=0; i<4 - 1; i++) L[[i]] = L[[i + 1]];
1219   L[[i]] = 4;
1220   exit( Array[[1]] != -2 || L[[2]] != 3)]])],
1221     [ac_cv_c_gcc_strength_bug="no"],[ac_cv_c_gcc_strength_bug="yes"],[ac_cv_c_gcc_strength_bug="yes"]) )
1222   if test "$ac_cv_c_gcc_strength_bug" = "yes"
1223   then
1224     EXTRACFLAGS="$EXTRACFLAGS -fno-strength-reduce"
1225   fi
1226
1227   dnl Check for some compiler flags
1228
1229   WINE_TRY_CFLAGS([-fshort-wchar],
1230                   [AC_DEFINE(CC_FLAG_SHORT_WCHAR, "-fshort-wchar",
1231                              [Specifies the compiler flag that forces a short wchar_t])])
1232   WINE_TRY_CFLAGS([-fno-strict-aliasing])
1233   WINE_TRY_CFLAGS([-Wdeclaration-after-statement])
1234   WINE_TRY_CFLAGS([-Wwrite-strings])
1235   WINE_TRY_CFLAGS([-Wtype-limits])
1236
1237   dnl Check for noisy string.h
1238   saved_CFLAGS="$CFLAGS"
1239   CFLAGS="$CFLAGS -Wpointer-arith -Werror"
1240   AC_CACHE_CHECK([for broken string.h that generates warnings], ac_cv_c_string_h_warnings,
1241       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[#include <string.h>]], [[]])],[ac_cv_c_string_h_warnings=no],[ac_cv_c_string_h_warnings=yes]))
1242   CFLAGS="$saved_CFLAGS"
1243   if test "$ac_cv_c_string_h_warnings" = "no"
1244   then
1245     EXTRACFLAGS="$EXTRACFLAGS -Wpointer-arith"
1246   fi
1247
1248   AC_SUBST(BUILTINFLAG,"")
1249   saved_CFLAGS="$CFLAGS"
1250   CFLAGS="$CFLAGS -Werror"
1251   AC_CACHE_CHECK([for builtin wchar inlines], ac_cv_c_builtin_wchar_ctype,
1252       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[]], [[int iswlower(unsigned short);]])],[ac_cv_c_builtin_wchar_ctype=no],[ac_cv_c_builtin_wchar_ctype=yes]))
1253   CFLAGS="$saved_CFLAGS"
1254   if test "$ac_cv_c_builtin_wchar_ctype" = "yes"
1255   then
1256     BUILTINFLAG="-fno-builtin"
1257   fi
1258 fi
1259
1260 dnl **** Check how to define a function in assembly code ****
1261
1262 AC_CACHE_CHECK([how to define a function in assembly code], ac_cv_asm_func_def,
1263   WINE_TRY_ASM_LINK(
1264       ["\t.globl _ac_test\n\t.def _ac_test; .scl 2; .type 32; .endef\n_ac_test:\t.long 0"],,,
1265       ac_cv_asm_func_def=".def",
1266     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,@function\n_ac_test:\t.long 0"],,,
1267       ac_cv_asm_func_def=".type @function",
1268     [WINE_TRY_ASM_LINK(["\t.globl _ac_test\n\t.type _ac_test,2\n_ac_test:\t.long 0"],,,
1269       ac_cv_asm_func_def=".type 2",
1270       ac_cv_asm_func_def="unknown")])]))
1271
1272 AH_TEMPLATE(__ASM_FUNC,[Define to a macro to generate an assembly function directive])
1273 case "$ac_cv_asm_func_def" in
1274   ".def")
1275      AC_DEFINE([__ASM_FUNC(name)], [".def " __ASM_NAME(name) "; .scl 2; .type 32; .endef"]) ;;
1276   ".type @function")
1277      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",@function"]) ;;
1278   ".type 2")
1279      AC_DEFINE([__ASM_FUNC(name)], [".type " __ASM_NAME(name) ",2"]) ;;
1280   *)
1281      AC_DEFINE([__ASM_FUNC(name)], [""]) ;;
1282 esac
1283
1284 dnl **** Check for underscore on external symbols ****
1285
1286 AC_CACHE_CHECK([whether external symbols need an underscore prefix], ac_cv_c_extern_prefix,
1287     WINE_TRY_ASM_LINK([".globl _ac_test\n_ac_test:\t.long 0"],
1288                       [extern int ac_test;],
1289                       [if (ac_test) return 1],
1290                       ac_cv_c_extern_prefix="yes",ac_cv_c_extern_prefix="no"))
1291
1292 AH_TEMPLATE(__ASM_NAME,[Define to a macro to generate an assembly name from a C symbol])
1293 if test "$ac_cv_c_extern_prefix" = "yes"
1294 then
1295   AC_DEFINE([__ASM_NAME(name)], ["_" name])
1296 else
1297   AC_DEFINE([__ASM_NAME(name)], [name])
1298 fi
1299
1300 dnl **** Platform-specific checks ****
1301
1302 AC_SUBST(LDPATH,"")
1303 case $build_os in
1304   cygwin*|mingw32*)
1305     LDPATH="PATH=\"\$(TOOLSDIR)/libs/wine:\$\$PATH\""
1306     ;;
1307   darwin*|macosx*)
1308     ;;
1309   linux*|solaris*)  dnl FIXME: What other platforms support $ORIGIN?
1310     if test -z "$LDRPATH_LOCAL"
1311     then
1312       LDPATH="LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/wine:\$\$LD_LIBRARY_PATH\""
1313     fi
1314     ;;
1315   *)
1316     LDPATH="LD_LIBRARY_PATH=\"\$(TOOLSDIR)/libs/wine:\$\$LD_LIBRARY_PATH\""
1317     ;;
1318 esac
1319
1320 dnl Mingw needs explicit msvcrt for linking libwine and winsock for wininet
1321 case $host_os in
1322   mingw32*)
1323     AC_SUBST(CRTLIBS,"-lmsvcrt")
1324     AC_SUBST(SOCKETLIBS,"-lws2_32")
1325     ;;
1326 esac
1327
1328 AC_SUBST(MAIN_BINARY,"wine-pthread")  dnl Default value
1329 case $host_cpu in
1330   *i[[3456789]]86*)
1331     case $host_os in
1332       linux* | k*bsd*-gnu)
1333         AC_SUBST(MAIN_BINARY,"wine-glibc")
1334         AC_SUBST(EXTRA_BINARIES,"wine-kthread wine-pthread wine-preloader") ;;
1335       freebsd*)
1336         AC_SUBST(MAIN_BINARY,"wine-freebsd")
1337         AC_SUBST(EXTRA_BINARIES,"wine-pthread") ;;
1338     esac
1339     ;;
1340 esac
1341
1342 dnl **** Check for functions ****
1343
1344 AC_CHECK_FUNCS(\
1345         _pclose \
1346         _popen \
1347         _snprintf \
1348         _spawnvp \
1349         _strdup \
1350         _stricmp \
1351         _strnicmp \
1352         _strtoi64 \
1353         _strtoui64 \
1354         _vsnprintf \
1355         asctime_r \
1356         chsize \
1357         clone \
1358         dlopen \
1359         epoll_create \
1360         ffs \
1361         finite \
1362         fork \
1363         fpclass \
1364         fstatfs \
1365         fstatvfs \
1366         ftruncate \
1367         futimes \
1368         futimesat \
1369         getdirentries \
1370         getopt_long \
1371         getpagesize \
1372         getpwuid \
1373         gettid \
1374         gettimeofday \
1375         getuid \
1376         inet_pton \
1377         kqueue \
1378         lstat \
1379         memmove \
1380         mmap \
1381         pclose \
1382         poll \
1383         popen \
1384         prctl \
1385         pread \
1386         pwrite \
1387         readlink \
1388         rfork \
1389         sched_yield \
1390         select \
1391         setproctitle \
1392         setrlimit \
1393         settimeofday \
1394         sigaltstack \
1395         sigprocmask \
1396         snprintf \
1397         spawnvp \
1398         statfs \
1399         statvfs \
1400         strcasecmp \
1401         strdup \
1402         strerror \
1403         strncasecmp \
1404         strtold \
1405         strtoll \
1406         strtoull \
1407         tcgetattr \
1408         thr_kill2 \
1409         timegm \
1410         usleep \
1411         vsnprintf \
1412         wait4 \
1413         waitpid \
1414 )
1415
1416 dnl Check for -ldl
1417 if test "$ac_cv_func_dlopen" = no
1418 then
1419     AC_CHECK_LIB(dl,dlopen,[AC_DEFINE(HAVE_DLOPEN,1) AC_SUBST(LIBDL,"-ldl")])
1420 fi
1421 WINE_CHECK_LIB_FUNCS(dladdr,[$LIBDL])
1422
1423 dnl Check for -lpoll for Mac OS X/Darwin
1424 if test "$ac_cv_func_poll" = no
1425 then
1426     AC_CHECK_LIB(poll,poll,[AC_DEFINE(HAVE_POLL,1) AC_SUBST(LIBPOLL,"-lpoll")])
1427 fi
1428
1429 dnl Check for -lnsl for Solaris
1430 AC_SEARCH_LIBS(gethostbyname, nsl)
1431
1432 dnl Check for -lsocket for Solaris
1433 AC_SEARCH_LIBS(connect, socket)
1434
1435 dnl Check for -lresolv for Solaris
1436 AC_SEARCH_LIBS(inet_aton, resolv)
1437
1438 dnl **** Check for functions which may rely on -lsocket on Solaris.
1439 AC_CHECK_FUNCS(\
1440         getaddrinfo \
1441         getnameinfo \
1442         getnetbyname \
1443         getprotobyname \
1444         getprotobynumber \
1445         getservbyport \
1446         inet_network \
1447         sendmsg \
1448 )
1449
1450 dnl **** Check for types ****
1451
1452 AC_C_CONST
1453 AC_C_INLINE
1454 AC_CHECK_TYPES([mode_t, off_t, pid_t, size_t, ssize_t, long long, fsblkcnt_t, fsfilcnt_t])
1455 AC_CHECK_TYPES([sigset_t],,,[#include <signal.h>])
1456 AC_CHECK_TYPES([request_sense],,,[#include <linux/cdrom.h>])
1457
1458 AC_CHECK_MEMBERS([struct ff_effect.direction],,,
1459 [#ifdef HAVE_LINUX_INPUT_H
1460 #include <linux/input.h>
1461 #endif])
1462
1463 AC_CACHE_CHECK([for sigaddset],wine_cv_have_sigaddset,
1464                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <signal.h>]], [[sigset_t set; sigaddset(&set,SIGTERM);]])],[wine_cv_have_sigaddset=yes],[wine_cv_have_sigaddset=no]))
1465 if test "$wine_cv_have_sigaddset" = "yes"
1466 then
1467   AC_DEFINE(HAVE_SIGADDSET, 1, [Define if sigaddset is supported])
1468 fi
1469
1470
1471 AC_CACHE_CHECK([whether we can use re-entrant gethostbyname_r Linux style],
1472         wine_cv_linux_gethostbyname_r_6,
1473         AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <netdb.h>]],[[
1474     char *name=0;
1475     struct hostent he;
1476     struct hostent *result;
1477     char *buf=0;
1478     int bufsize=0;
1479     int res,errnr;
1480     char *addr=0;
1481     int addrlen=0;
1482     int addrtype=0;
1483     res=gethostbyname_r(name,&he,buf,bufsize,&result,&errnr);
1484     res=gethostbyaddr_r(addr, addrlen, addrtype,&he,buf,bufsize,&result,&errnr);
1485     ]])],[wine_cv_linux_gethostbyname_r_6=yes],[wine_cv_linux_gethostbyname_r_6=no
1486         ])
1487    )
1488    if test "$wine_cv_linux_gethostbyname_r_6" = "yes"
1489    then
1490       AC_DEFINE(HAVE_LINUX_GETHOSTBYNAME_R_6, 1,
1491                 [Define if Linux-style gethostbyname_r and gethostbyaddr_r are available])
1492    fi
1493
1494 if test "$ac_cv_header_linux_joystick_h" = "yes"
1495 then
1496    AC_CACHE_CHECK([whether linux/joystick.h uses the Linux 2.2+ API],
1497         wine_cv_linux_joystick_22_api,
1498         AC_COMPILE_IFELSE([AC_LANG_PROGRAM([[
1499         #include <sys/ioctl.h>
1500         #include <sys/types.h>
1501         #include <linux/joystick.h>
1502
1503         struct js_event blub;
1504         #if !defined(JS_EVENT_AXIS) || !defined(JS_EVENT_BUTTON)
1505         #error "no 2.2 header"
1506         #endif
1507         ]], [[/*empty*/]])],[wine_cv_linux_joystick_22_api=yes],[wine_cv_linux_joystick_22_api=no])
1508    )
1509    if test "$wine_cv_linux_joystick_22_api" = "yes"
1510    then
1511       AC_DEFINE(HAVE_LINUX_22_JOYSTICK_API, 1,
1512                 [Define if <linux/joystick.h> defines the Linux 2.2 joystick API])
1513    fi
1514 fi
1515
1516 dnl **** FIXME: what about mixed cases, where we need two of them? ***
1517
1518 dnl Check for statfs members
1519 AC_CHECK_MEMBERS([struct statfs.f_bfree, struct statfs.f_bavail, struct statfs.f_frsize, struct statfs.f_ffree, struct statfs.f_favail, struct statfs.f_namelen],,,
1520 [#include <sys/types.h>
1521 #ifdef HAVE_SYS_PARAM_H
1522 # include <sys/param.h>
1523 #endif
1524 #ifdef HAVE_SYS_MOUNT_H
1525 # include <sys/mount.h>
1526 #endif
1527 #ifdef HAVE_SYS_VFS_H
1528 # include <sys/vfs.h>
1529 #endif
1530 #ifdef HAVE_SYS_STATFS_H
1531 # include <sys/statfs.h>
1532 #endif])
1533
1534 AC_CHECK_MEMBERS([struct statvfs.f_blocks],,,
1535 [#ifdef HAVE_SYS_STATVFS_H
1536 #include <sys/statvfs.h>
1537 #endif])
1538
1539 dnl Check for socket structure members
1540 AC_CHECK_MEMBERS([struct msghdr.msg_accrights, struct sockaddr.sa_len, struct sockaddr_un.sun_len],,,
1541 [#include <sys/types.h>
1542 #ifdef HAVE_SYS_SOCKET_H
1543 # include <sys/socket.h>
1544 #endif
1545 #ifdef HAVE_SYS_UN_H
1546 # include <sys/un.h>
1547 #endif])
1548
1549 dnl Check for scsireq_t and sg_io_hdr_t members
1550 AC_CHECK_MEMBERS([scsireq_t.cmd, sg_io_hdr_t.interface_id],,,
1551 [#include <sys/types.h>
1552 #ifdef HAVE_SCSI_SG_H
1553 #include <scsi/sg.h>
1554 #endif])
1555
1556 dnl Check for siginfo_t members
1557 AC_CHECK_MEMBERS([siginfo_t.si_fd],,,[#include <signal.h>])
1558
1559 dnl Check for struct mtget members
1560 AC_CHECK_MEMBERS([struct mtget.mt_blksiz, struct mtget.mt_gstat, struct mtget.mt_blkno],,,
1561 [#include <sys/types.h>
1562 #ifdef HAVE_SYS_MTIO_H
1563 #include <sys/mtio.h>
1564 #endif])
1565
1566 dnl Check for struct option
1567 AC_CHECK_MEMBERS([struct option.name],,,
1568 [#ifdef HAVE_GETOPT_H
1569 #include <getopt.h>
1570 #endif])
1571
1572 dnl Check for stat.st_blocks
1573 AC_CHECK_MEMBERS([struct stat.st_blocks])
1574
1575 dnl Check for sin6_scope_id
1576 AC_CHECK_MEMBERS([struct sockaddr_in6.sin6_scope_id],,,
1577 [#ifdef HAVE_SYS_TYPES_H
1578 #include <sys/types.h>
1579 #endif
1580 #ifdef HAVE_NETINET_IN_H
1581 #include <netinet/in.h>
1582 #endif])
1583
1584 dnl Check for ns_msg ptr member
1585 AC_CHECK_MEMBERS([ns_msg._msg_ptr],,,
1586 [#ifdef HAVE_SYS_TYPES_H
1587 #include <sys/types.h>
1588 #endif
1589 #ifdef HAVE_NETINET_IN_H
1590 # include <netinet/in.h>
1591 #endif
1592 #ifdef HAVE_ARPA_NAMESER_H
1593 # include <arpa/nameser.h>
1594 #endif])
1595
1596 dnl Check for the external timezone variables timezone and daylight
1597 AC_CACHE_CHECK([for timezone variable], ac_cv_have_timezone,
1598                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[timezone = 1]])],[ac_cv_have_timezone="yes"],[ac_cv_have_timezone="no"]))
1599 if test "$ac_cv_have_timezone" = "yes"
1600 then
1601     AC_DEFINE(HAVE_TIMEZONE, 1, [Define if you have the timezone variable])
1602 fi
1603 AC_CACHE_CHECK([for daylight variable], ac_cv_have_daylight,
1604                AC_LINK_IFELSE([AC_LANG_PROGRAM([[#include <time.h>]], [[daylight = 1]])],[ac_cv_have_daylight="yes"],[ac_cv_have_daylight="no"]))
1605 if test "$ac_cv_have_daylight" = "yes"
1606 then
1607     AC_DEFINE(HAVE_DAYLIGHT, 1, [Define if you have the daylight variable])
1608 fi
1609
1610 dnl *** check for the need to define platform-specific symbols
1611
1612 case $host_cpu in
1613   *i[[3456789]]86*) WINE_CHECK_DEFINE([__i386__]) ;;
1614   *x86_64*)         WINE_CHECK_DEFINE([__x86_64__]) ;;
1615   *alpha*)          WINE_CHECK_DEFINE([__ALPHA__]) ;;
1616   *sparc*)          WINE_CHECK_DEFINE([__sparc__]) ;;
1617   *powerpc*)        WINE_CHECK_DEFINE([__powerpc__]) ;;
1618 esac
1619
1620 case $host_vendor in
1621   *sun*) WINE_CHECK_DEFINE([__sun__]) ;;
1622 esac
1623
1624 dnl **** Generate output files ****
1625
1626 dnl autoconf versions before 2.59d need backslashes to escape newlines in subst variables
1627 AC_SUBST(DEPENDENCIES,m4_if(m4_version_compare(m4_defn([m4_PACKAGE_VERSION]), [2.59d]), -1,
1628 ["### Dependencies:\\
1629 \\
1630 .INIT: Makefile\\
1631 .BEGIN: Makefile\\
1632 Makefile: dummy\\
1633         -\$(MAKEDEP) -C\$(SRCDIR) -S\$(TOPSRCDIR) -T\$(TOPOBJDIR) \$(EXTRAINCL) \$(DEPEND_SRCS)\\
1634 \\
1635 \$(OBJS): \$(IDL_GEN_HEADERS)\\
1636 \$(IDL_GEN_C_SRCS:.c=.o): \$(IDL_GEN_C_SRCS)\\
1637 \$(LEX_SRCS:.l=.yy.o): \$(LEX_SRCS:.l=.yy.c)\\
1638 \$(BISON_SRCS:.y=.tab.o): \$(BISON_SRCS:.y=.tab.c)"],
1639 ["### Dependencies:
1640
1641 .INIT: Makefile
1642 .BEGIN: Makefile
1643 Makefile: dummy
1644         -\$(MAKEDEP) -C\$(SRCDIR) -S\$(TOPSRCDIR) -T\$(TOPOBJDIR) \$(EXTRAINCL) \$(DEPEND_SRCS)
1645
1646 \$(OBJS): \$(IDL_GEN_HEADERS)
1647 \$(IDL_GEN_C_SRCS:.c=.o): \$(IDL_GEN_C_SRCS)
1648 \$(LEX_SRCS:.l=.yy.o): \$(LEX_SRCS:.l=.yy.c)
1649 \$(BISON_SRCS:.y=.tab.o): \$(BISON_SRCS:.y=.tab.c)"]))
1650
1651 AH_TOP([#define __WINE_CONFIG_H])
1652
1653 AC_CONFIG_COMMANDS([include/stamp-h], [echo timestamp > include/stamp-h])
1654
1655 WINE_CONFIG_EXTRA_DIR(dlls/gdi32/enhmfdrv)
1656 WINE_CONFIG_EXTRA_DIR(dlls/gdi32/mfdrv)
1657 WINE_CONFIG_EXTRA_DIR(dlls/kernel32/nls)
1658 WINE_CONFIG_EXTRA_DIR(dlls/user32/resources)
1659 WINE_CONFIG_EXTRA_DIR(dlls/wineps.drv/data)
1660 WINE_CONFIG_EXTRA_DIR(include/wine)
1661
1662 MAKE_RULES=Make.rules
1663 AC_SUBST_FILE(MAKE_RULES)
1664
1665 MAKE_DLL_RULES=dlls/Makedll.rules
1666 AC_SUBST_FILE(MAKE_DLL_RULES)
1667
1668 MAKE_IMPLIB_RULES=dlls/Makeimplib.rules
1669 AC_SUBST_FILE(MAKE_IMPLIB_RULES)
1670
1671 MAKE_TEST_RULES=dlls/Maketest.rules
1672 AC_SUBST_FILE(MAKE_TEST_RULES)
1673
1674 MAKE_PROG_RULES=programs/Makeprog.rules
1675 AC_SUBST_FILE(MAKE_PROG_RULES)
1676
1677 AC_CONFIG_FILES([Make.rules])
1678 AC_CONFIG_FILES([dlls/Makedll.rules])
1679 AC_CONFIG_FILES([dlls/Makeimplib.rules])
1680 AC_CONFIG_FILES([dlls/Maketest.rules])
1681 AC_CONFIG_FILES([programs/Makeprog.rules])
1682 AC_CONFIG_FILES([Makefile])
1683 AC_CONFIG_FILES([dlls/Makefile])
1684 AC_CONFIG_FILES([dlls/acledit/Makefile])
1685 AC_CONFIG_FILES([dlls/activeds/Makefile])
1686 AC_CONFIG_FILES([dlls/actxprxy/Makefile])
1687 AC_CONFIG_FILES([dlls/adsiid/Makefile])
1688 AC_CONFIG_FILES([dlls/advapi32/Makefile])
1689 AC_CONFIG_FILES([dlls/advapi32/tests/Makefile])
1690 AC_CONFIG_FILES([dlls/advpack/Makefile])
1691 AC_CONFIG_FILES([dlls/advpack/tests/Makefile])
1692 AC_CONFIG_FILES([dlls/amstream/Makefile])
1693 AC_CONFIG_FILES([dlls/atl/Makefile])
1694 AC_CONFIG_FILES([dlls/avicap32/Makefile])
1695 AC_CONFIG_FILES([dlls/avifil32/Makefile])
1696 AC_CONFIG_FILES([dlls/browseui/Makefile])
1697 AC_CONFIG_FILES([dlls/browseui/tests/Makefile])
1698 AC_CONFIG_FILES([dlls/cabinet/Makefile])
1699 AC_CONFIG_FILES([dlls/cabinet/tests/Makefile])
1700 AC_CONFIG_FILES([dlls/capi2032/Makefile])
1701 AC_CONFIG_FILES([dlls/cards/Makefile])
1702 AC_CONFIG_FILES([dlls/cfgmgr32/Makefile])
1703 AC_CONFIG_FILES([dlls/clusapi/Makefile])
1704 AC_CONFIG_FILES([dlls/comcat/Makefile])
1705 AC_CONFIG_FILES([dlls/comcat/tests/Makefile])
1706 AC_CONFIG_FILES([dlls/comctl32/Makefile])
1707 AC_CONFIG_FILES([dlls/comctl32/tests/Makefile])
1708 AC_CONFIG_FILES([dlls/comdlg32/Makefile])
1709 AC_CONFIG_FILES([dlls/comdlg32/tests/Makefile])
1710 AC_CONFIG_FILES([dlls/compstui/Makefile])
1711 AC_CONFIG_FILES([dlls/credui/Makefile])
1712 AC_CONFIG_FILES([dlls/credui/tests/Makefile])
1713 AC_CONFIG_FILES([dlls/crtdll/Makefile])
1714 AC_CONFIG_FILES([dlls/crypt32/Makefile])
1715 AC_CONFIG_FILES([dlls/crypt32/tests/Makefile])
1716 AC_CONFIG_FILES([dlls/cryptdlg/Makefile])
1717 AC_CONFIG_FILES([dlls/cryptdll/Makefile])
1718 AC_CONFIG_FILES([dlls/cryptnet/Makefile])
1719 AC_CONFIG_FILES([dlls/cryptnet/tests/Makefile])
1720 AC_CONFIG_FILES([dlls/cryptui/Makefile])
1721 AC_CONFIG_FILES([dlls/ctapi32/Makefile])
1722 AC_CONFIG_FILES([dlls/ctl3d32/Makefile])
1723 AC_CONFIG_FILES([dlls/d3d10/Makefile])
1724 AC_CONFIG_FILES([dlls/d3d8/Makefile])
1725 AC_CONFIG_FILES([dlls/d3d8/tests/Makefile])
1726 AC_CONFIG_FILES([dlls/d3d9/Makefile])
1727 AC_CONFIG_FILES([dlls/d3d9/tests/Makefile])
1728 AC_CONFIG_FILES([dlls/d3dim/Makefile])
1729 AC_CONFIG_FILES([dlls/d3drm/Makefile])
1730 AC_CONFIG_FILES([dlls/d3drm/tests/Makefile])
1731 AC_CONFIG_FILES([dlls/d3dx8/Makefile])
1732 AC_CONFIG_FILES([dlls/d3dx8/tests/Makefile])
1733 AC_CONFIG_FILES([dlls/d3dx9_24/Makefile])
1734 AC_CONFIG_FILES([dlls/d3dx9_25/Makefile])
1735 AC_CONFIG_FILES([dlls/d3dx9_26/Makefile])
1736 AC_CONFIG_FILES([dlls/d3dx9_27/Makefile])
1737 AC_CONFIG_FILES([dlls/d3dx9_28/Makefile])
1738 AC_CONFIG_FILES([dlls/d3dx9_29/Makefile])
1739 AC_CONFIG_FILES([dlls/d3dx9_30/Makefile])
1740 AC_CONFIG_FILES([dlls/d3dx9_31/Makefile])
1741 AC_CONFIG_FILES([dlls/d3dx9_32/Makefile])
1742 AC_CONFIG_FILES([dlls/d3dx9_33/Makefile])
1743 AC_CONFIG_FILES([dlls/d3dx9_34/Makefile])
1744 AC_CONFIG_FILES([dlls/d3dx9_35/Makefile])
1745 AC_CONFIG_FILES([dlls/d3dx9_36/Makefile])
1746 AC_CONFIG_FILES([dlls/d3dx9_36/tests/Makefile])
1747 AC_CONFIG_FILES([dlls/d3dx9_37/Makefile])
1748 AC_CONFIG_FILES([dlls/d3dxof/Makefile])
1749 AC_CONFIG_FILES([dlls/dbghelp/Makefile])
1750 AC_CONFIG_FILES([dlls/dciman32/Makefile])
1751 AC_CONFIG_FILES([dlls/ddraw/Makefile])
1752 AC_CONFIG_FILES([dlls/ddraw/tests/Makefile])
1753 AC_CONFIG_FILES([dlls/ddrawex/Makefile])
1754 AC_CONFIG_FILES([dlls/devenum/Makefile])
1755 AC_CONFIG_FILES([dlls/dinput/Makefile])
1756 AC_CONFIG_FILES([dlls/dinput/tests/Makefile])
1757 AC_CONFIG_FILES([dlls/dinput8/Makefile])
1758 AC_CONFIG_FILES([dlls/dmband/Makefile])
1759 AC_CONFIG_FILES([dlls/dmcompos/Makefile])
1760 AC_CONFIG_FILES([dlls/dmime/Makefile])
1761 AC_CONFIG_FILES([dlls/dmloader/Makefile])
1762 AC_CONFIG_FILES([dlls/dmscript/Makefile])
1763 AC_CONFIG_FILES([dlls/dmstyle/Makefile])
1764 AC_CONFIG_FILES([dlls/dmsynth/Makefile])
1765 AC_CONFIG_FILES([dlls/dmusic/Makefile])
1766 AC_CONFIG_FILES([dlls/dmusic32/Makefile])
1767 AC_CONFIG_FILES([dlls/dnsapi/Makefile])
1768 AC_CONFIG_FILES([dlls/dnsapi/tests/Makefile])
1769 AC_CONFIG_FILES([dlls/dplay/Makefile])
1770 AC_CONFIG_FILES([dlls/dplayx/Makefile])
1771 AC_CONFIG_FILES([dlls/dplayx/tests/Makefile])
1772 AC_CONFIG_FILES([dlls/dpnaddr/Makefile])
1773 AC_CONFIG_FILES([dlls/dpnet/Makefile])
1774 AC_CONFIG_FILES([dlls/dpnhpast/Makefile])
1775 AC_CONFIG_FILES([dlls/dpnlobby/Makefile])
1776 AC_CONFIG_FILES([dlls/dsound/Makefile])
1777 AC_CONFIG_FILES([dlls/dsound/tests/Makefile])
1778 AC_CONFIG_FILES([dlls/dssenh/Makefile])
1779 AC_CONFIG_FILES([dlls/dswave/Makefile])
1780 AC_CONFIG_FILES([dlls/dwmapi/Makefile])
1781 AC_CONFIG_FILES([dlls/dxdiagn/Makefile])
1782 AC_CONFIG_FILES([dlls/dxerr8/Makefile])
1783 AC_CONFIG_FILES([dlls/dxerr9/Makefile])
1784 AC_CONFIG_FILES([dlls/dxguid/Makefile])
1785 AC_CONFIG_FILES([dlls/faultrep/Makefile])
1786 AC_CONFIG_FILES([dlls/fusion/Makefile])
1787 AC_CONFIG_FILES([dlls/fusion/tests/Makefile])
1788 AC_CONFIG_FILES([dlls/gdi32/Makefile])
1789 AC_CONFIG_FILES([dlls/gdi32/tests/Makefile])
1790 AC_CONFIG_FILES([dlls/gdiplus/Makefile])
1791 AC_CONFIG_FILES([dlls/gdiplus/tests/Makefile])
1792 AC_CONFIG_FILES([dlls/glu32/Makefile])
1793 AC_CONFIG_FILES([dlls/gphoto2.ds/Makefile])
1794 AC_CONFIG_FILES([dlls/gpkcsp/Makefile])
1795 AC_CONFIG_FILES([dlls/hal/Makefile])
1796 AC_CONFIG_FILES([dlls/hhctrl.ocx/Makefile])
1797 AC_CONFIG_FILES([dlls/hid/Makefile])
1798 AC_CONFIG_FILES([dlls/hlink/Makefile])
1799 AC_CONFIG_FILES([dlls/hlink/tests/Makefile])
1800 AC_CONFIG_FILES([dlls/hnetcfg/Makefile])
1801 AC_CONFIG_FILES([dlls/iccvid/Makefile])
1802 AC_CONFIG_FILES([dlls/icmp/Makefile])
1803 AC_CONFIG_FILES([dlls/ifsmgr.vxd/Makefile])
1804 AC_CONFIG_FILES([dlls/imaadp32.acm/Makefile])
1805 AC_CONFIG_FILES([dlls/imagehlp/Makefile])
1806 AC_CONFIG_FILES([dlls/imm32/Makefile])
1807 AC_CONFIG_FILES([dlls/imm32/tests/Makefile])
1808 AC_CONFIG_FILES([dlls/inetcomm/Makefile])
1809 AC_CONFIG_FILES([dlls/inetcomm/tests/Makefile])
1810 AC_CONFIG_FILES([dlls/infosoft/Makefile])
1811 AC_CONFIG_FILES([dlls/infosoft/tests/Makefile])
1812 AC_CONFIG_FILES([dlls/initpki/Makefile])
1813 AC_CONFIG_FILES([dlls/inkobj/Makefile])
1814 AC_CONFIG_FILES([dlls/inseng/Makefile])
1815 AC_CONFIG_FILES([dlls/iphlpapi/Makefile])
1816 AC_CONFIG_FILES([dlls/iphlpapi/tests/Makefile])
1817 AC_CONFIG_FILES([dlls/itircl/Makefile])
1818 AC_CONFIG_FILES([dlls/itss/Makefile])
1819 AC_CONFIG_FILES([dlls/itss/tests/Makefile])
1820 AC_CONFIG_FILES([dlls/jscript/Makefile])
1821 AC_CONFIG_FILES([dlls/jscript/tests/Makefile])
1822 AC_CONFIG_FILES([dlls/kernel32/Makefile])
1823 AC_CONFIG_FILES([dlls/kernel32/tests/Makefile])
1824 AC_CONFIG_FILES([dlls/localspl/Makefile])
1825 AC_CONFIG_FILES([dlls/localspl/tests/Makefile])
1826 AC_CONFIG_FILES([dlls/localui/Makefile])
1827 AC_CONFIG_FILES([dlls/localui/tests/Makefile])
1828 AC_CONFIG_FILES([dlls/lz32/Makefile])
1829 AC_CONFIG_FILES([dlls/lz32/tests/Makefile])
1830 AC_CONFIG_FILES([dlls/mapi32/Makefile])
1831 AC_CONFIG_FILES([dlls/mapi32/tests/Makefile])
1832 AC_CONFIG_FILES([dlls/mciavi32/Makefile])
1833 AC_CONFIG_FILES([dlls/mcicda/Makefile])
1834 AC_CONFIG_FILES([dlls/mciseq/Makefile])
1835 AC_CONFIG_FILES([dlls/mciwave/Makefile])
1836 AC_CONFIG_FILES([dlls/midimap/Makefile])
1837 AC_CONFIG_FILES([dlls/mlang/Makefile])
1838 AC_CONFIG_FILES([dlls/mlang/tests/Makefile])
1839 AC_CONFIG_FILES([dlls/mmdevldr.vxd/Makefile])
1840 AC_CONFIG_FILES([dlls/monodebg.vxd/Makefile])
1841 AC_CONFIG_FILES([dlls/mountmgr.sys/Makefile])
1842 AC_CONFIG_FILES([dlls/mpr/Makefile])
1843 AC_CONFIG_FILES([dlls/mprapi/Makefile])
1844 AC_CONFIG_FILES([dlls/msacm32.drv/Makefile])
1845 AC_CONFIG_FILES([dlls/msacm32/Makefile])
1846 AC_CONFIG_FILES([dlls/msacm32/tests/Makefile])
1847 AC_CONFIG_FILES([dlls/msadp32.acm/Makefile])
1848 AC_CONFIG_FILES([dlls/mscat32/Makefile])
1849 AC_CONFIG_FILES([dlls/mscms/Makefile])
1850 AC_CONFIG_FILES([dlls/mscms/tests/Makefile])
1851 AC_CONFIG_FILES([dlls/mscoree/Makefile])
1852 AC_CONFIG_FILES([dlls/msdmo/Makefile])
1853 AC_CONFIG_FILES([dlls/msftedit/Makefile])
1854 AC_CONFIG_FILES([dlls/msg711.acm/Makefile])
1855 AC_CONFIG_FILES([dlls/mshtml.tlb/Makefile])
1856 AC_CONFIG_FILES([dlls/mshtml/Makefile])
1857 AC_CONFIG_FILES([dlls/mshtml/tests/Makefile])
1858 AC_CONFIG_FILES([dlls/msi/Makefile])
1859 AC_CONFIG_FILES([dlls/msi/tests/Makefile])
1860 AC_CONFIG_FILES([dlls/msimg32/Makefile])
1861 AC_CONFIG_FILES([dlls/msimtf/Makefile])
1862 AC_CONFIG_FILES([dlls/msisys.ocx/Makefile])
1863 AC_CONFIG_FILES([dlls/msnet32/Makefile])
1864 AC_CONFIG_FILES([dlls/msrle32/Makefile])
1865 AC_CONFIG_FILES([dlls/mssip32/Makefile])
1866 AC_CONFIG_FILES([dlls/msvcirt/Makefile])
1867 AC_CONFIG_FILES([dlls/msvcr71/Makefile])
1868 AC_CONFIG_FILES([dlls/msvcrt/Makefile])
1869 AC_CONFIG_FILES([dlls/msvcrt/tests/Makefile])
1870 AC_CONFIG_FILES([dlls/msvcrt20/Makefile])
1871 AC_CONFIG_FILES([dlls/msvcrt40/Makefile])
1872 AC_CONFIG_FILES([dlls/msvcrtd/Makefile])
1873 AC_CONFIG_FILES([dlls/msvcrtd/tests/Makefile])
1874 AC_CONFIG_FILES([dlls/msvfw32/Makefile])
1875 AC_CONFIG_FILES([dlls/msvidc32/Makefile])
1876 AC_CONFIG_FILES([dlls/mswsock/Makefile])
1877 AC_CONFIG_FILES([dlls/msxml3/Makefile])
1878 AC_CONFIG_FILES([dlls/msxml3/tests/Makefile])
1879 AC_CONFIG_FILES([dlls/nddeapi/Makefile])
1880 AC_CONFIG_FILES([dlls/netapi32/Makefile])
1881 AC_CONFIG_FILES([dlls/netapi32/tests/Makefile])
1882 AC_CONFIG_FILES([dlls/newdev/Makefile])
1883 AC_CONFIG_FILES([dlls/ntdll/Makefile])
1884 AC_CONFIG_FILES([dlls/ntdll/tests/Makefile])
1885 AC_CONFIG_FILES([dlls/ntdsapi/Makefile])
1886 AC_CONFIG_FILES([dlls/ntdsapi/tests/Makefile])
1887 AC_CONFIG_FILES([dlls/ntoskrnl.exe/Makefile])
1888 AC_CONFIG_FILES([dlls/ntprint/Makefile])
1889 AC_CONFIG_FILES([dlls/ntprint/tests/Makefile])
1890 AC_CONFIG_FILES([dlls/objsel/Makefile])
1891 AC_CONFIG_FILES([dlls/odbc32/Makefile])
1892 AC_CONFIG_FILES([dlls/odbccp32/Makefile])
1893 AC_CONFIG_FILES([dlls/odbccp32/tests/Makefile])
1894 AC_CONFIG_FILES([dlls/ole32/Makefile])
1895 AC_CONFIG_FILES([dlls/ole32/tests/Makefile])
1896 AC_CONFIG_FILES([dlls/oleacc/Makefile])
1897 AC_CONFIG_FILES([dlls/oleaut32/Makefile])
1898 AC_CONFIG_FILES([dlls/oleaut32/tests/Makefile])
1899 AC_CONFIG_FILES([dlls/olecli32/Makefile])
1900 AC_CONFIG_FILES([dlls/oledlg/Makefile])
1901 AC_CONFIG_FILES([dlls/olepro32/Makefile])
1902 AC_CONFIG_FILES([dlls/olesvr32/Makefile])
1903 AC_CONFIG_FILES([dlls/olethk32/Makefile])
1904 AC_CONFIG_FILES([dlls/opengl32/Makefile])
1905 AC_CONFIG_FILES([dlls/opengl32/tests/Makefile])
1906 AC_CONFIG_FILES([dlls/pdh/Makefile])
1907 AC_CONFIG_FILES([dlls/pdh/tests/Makefile])
1908 AC_CONFIG_FILES([dlls/powrprof/Makefile])
1909 AC_CONFIG_FILES([dlls/printui/Makefile])
1910 AC_CONFIG_FILES([dlls/propsys/Makefile])
1911 AC_CONFIG_FILES([dlls/psapi/Makefile])
1912 AC_CONFIG_FILES([dlls/psapi/tests/Makefile])
1913 AC_CONFIG_FILES([dlls/pstorec/Makefile])
1914 AC_CONFIG_FILES([dlls/qcap/Makefile])
1915 AC_CONFIG_FILES([dlls/qedit/Makefile])
1916 AC_CONFIG_FILES([dlls/qedit/tests/Makefile])
1917 AC_CONFIG_FILES([dlls/qmgr/Makefile])
1918 AC_CONFIG_FILES([dlls/qmgr/tests/Makefile])
1919 AC_CONFIG_FILES([dlls/qmgrprxy/Makefile])
1920 AC_CONFIG_FILES([dlls/quartz/Makefile])
1921 AC_CONFIG_FILES([dlls/quartz/tests/Makefile])
1922 AC_CONFIG_FILES([dlls/query/Makefile])
1923 AC_CONFIG_FILES([dlls/rasapi32/Makefile])
1924 AC_CONFIG_FILES([dlls/resutils/Makefile])
1925 AC_CONFIG_FILES([dlls/riched20/Makefile])
1926 AC_CONFIG_FILES([dlls/riched20/tests/Makefile])
1927 AC_CONFIG_FILES([dlls/riched32/Makefile])
1928 AC_CONFIG_FILES([dlls/riched32/tests/Makefile])
1929 AC_CONFIG_FILES([dlls/rpcrt4/Makefile])
1930 AC_CONFIG_FILES([dlls/rpcrt4/tests/Makefile])
1931 AC_CONFIG_FILES([dlls/rsabase/Makefile])
1932 AC_CONFIG_FILES([dlls/rsaenh/Makefile])
1933 AC_CONFIG_FILES([dlls/rsaenh/tests/Makefile])
1934 AC_CONFIG_FILES([dlls/sane.ds/Makefile])
1935 AC_CONFIG_FILES([dlls/sccbase/Makefile])
1936 AC_CONFIG_FILES([dlls/schannel/Makefile])
1937 AC_CONFIG_FILES([dlls/schannel/tests/Makefile])
1938 AC_CONFIG_FILES([dlls/secur32/Makefile])
1939 AC_CONFIG_FILES([dlls/secur32/tests/Makefile])
1940 AC_CONFIG_FILES([dlls/security/Makefile])
1941 AC_CONFIG_FILES([dlls/sensapi/Makefile])
1942 AC_CONFIG_FILES([dlls/serialui/Makefile])
1943 AC_CONFIG_FILES([dlls/serialui/tests/Makefile])
1944 AC_CONFIG_FILES([dlls/setupapi/Makefile])
1945 AC_CONFIG_FILES([dlls/setupapi/tests/Makefile])
1946 AC_CONFIG_FILES([dlls/sfc/Makefile])
1947 AC_CONFIG_FILES([dlls/sfc_os/Makefile])
1948 AC_CONFIG_FILES([dlls/shdoclc/Makefile])
1949 AC_CONFIG_FILES([dlls/shdocvw/Makefile])
1950 AC_CONFIG_FILES([dlls/shdocvw/tests/Makefile])
1951 AC_CONFIG_FILES([dlls/shell32/Makefile])
1952 AC_CONFIG_FILES([dlls/shell32/tests/Makefile])
1953 AC_CONFIG_FILES([dlls/shfolder/Makefile])
1954 AC_CONFIG_FILES([dlls/shlwapi/Makefile])
1955 AC_CONFIG_FILES([dlls/shlwapi/tests/Makefile])
1956 AC_CONFIG_FILES([dlls/slbcsp/Makefile])
1957 AC_CONFIG_FILES([dlls/slc/Makefile])
1958 AC_CONFIG_FILES([dlls/snmpapi/Makefile])
1959 AC_CONFIG_FILES([dlls/snmpapi/tests/Makefile])
1960 AC_CONFIG_FILES([dlls/softpub/Makefile])
1961 AC_CONFIG_FILES([dlls/spoolss/Makefile])
1962 AC_CONFIG_FILES([dlls/spoolss/tests/Makefile])
1963 AC_CONFIG_FILES([dlls/stdole2.tlb/Makefile])
1964 AC_CONFIG_FILES([dlls/stdole32.tlb/Makefile])
1965 AC_CONFIG_FILES([dlls/sti/Makefile])
1966 AC_CONFIG_FILES([dlls/strmiids/Makefile])
1967 AC_CONFIG_FILES([dlls/svrapi/Makefile])
1968 AC_CONFIG_FILES([dlls/sxs/Makefile])
1969 AC_CONFIG_FILES([dlls/tapi32/Makefile])
1970 AC_CONFIG_FILES([dlls/twain_32/Makefile])
1971 AC_CONFIG_FILES([dlls/unicows/Makefile])
1972 AC_CONFIG_FILES([dlls/url/Makefile])
1973 AC_CONFIG_FILES([dlls/urlmon/Makefile])
1974 AC_CONFIG_FILES([dlls/urlmon/tests/Makefile])
1975 AC_CONFIG_FILES([dlls/user32/Makefile])
1976 AC_CONFIG_FILES([dlls/user32/tests/Makefile])
1977 AC_CONFIG_FILES([dlls/userenv/Makefile])
1978 AC_CONFIG_FILES([dlls/usp10/Makefile])
1979 AC_CONFIG_FILES([dlls/usp10/tests/Makefile])
1980 AC_CONFIG_FILES([dlls/uuid/Makefile])
1981 AC_CONFIG_FILES([dlls/uxtheme/Makefile])
1982 AC_CONFIG_FILES([dlls/uxtheme/tests/Makefile])
1983 AC_CONFIG_FILES([dlls/vdhcp.vxd/Makefile])
1984 AC_CONFIG_FILES([dlls/vdmdbg/Makefile])
1985 AC_CONFIG_FILES([dlls/version/Makefile])
1986 AC_CONFIG_FILES([dlls/version/tests/Makefile])
1987 AC_CONFIG_FILES([dlls/vmm.vxd/Makefile])
1988 AC_CONFIG_FILES([dlls/vnbt.vxd/Makefile])
1989 AC_CONFIG_FILES([dlls/vnetbios.vxd/Makefile])
1990 AC_CONFIG_FILES([dlls/vtdapi.vxd/Makefile])
1991 AC_CONFIG_FILES([dlls/vwin32.vxd/Makefile])
1992 AC_CONFIG_FILES([dlls/w32skrnl/Makefile])
1993 AC_CONFIG_FILES([dlls/winealsa.drv/Makefile])
1994 AC_CONFIG_FILES([dlls/wineaudioio.drv/Makefile])
1995 AC_CONFIG_FILES([dlls/winecoreaudio.drv/Makefile])
1996 AC_CONFIG_FILES([dlls/winecrt0/Makefile])
1997 AC_CONFIG_FILES([dlls/wined3d/Makefile])
1998 AC_CONFIG_FILES([dlls/winedos/Makefile])
1999 AC_CONFIG_FILES([dlls/wineesd.drv/Makefile])
2000 AC_CONFIG_FILES([dlls/winejack.drv/Makefile])
2001 AC_CONFIG_FILES([dlls/winejoystick.drv/Makefile])
2002 AC_CONFIG_FILES([dlls/winemp3.acm/Makefile])
2003 AC_CONFIG_FILES([dlls/winenas.drv/Makefile])
2004 AC_CONFIG_FILES([dlls/wineoss.drv/Makefile])
2005 AC_CONFIG_FILES([dlls/wineps.drv/Makefile])
2006 AC_CONFIG_FILES([dlls/winequartz.drv/Makefile])
2007 AC_CONFIG_FILES([dlls/winex11.drv/Makefile])
2008 AC_CONFIG_FILES([dlls/wing32/Makefile])
2009 AC_CONFIG_FILES([dlls/winhttp/Makefile])
2010 AC_CONFIG_FILES([dlls/wininet/Makefile])
2011 AC_CONFIG_FILES([dlls/wininet/tests/Makefile])
2012 AC_CONFIG_FILES([dlls/winmm/Makefile])
2013 AC_CONFIG_FILES([dlls/winmm/tests/Makefile])
2014 AC_CONFIG_FILES([dlls/winnls32/Makefile])
2015 AC_CONFIG_FILES([dlls/winscard/Makefile])
2016 AC_CONFIG_FILES([dlls/winspool.drv/Makefile])
2017 AC_CONFIG_FILES([dlls/winspool.drv/tests/Makefile])
2018 AC_CONFIG_FILES([dlls/wintab32/Makefile])
2019 AC_CONFIG_FILES([dlls/wintrust/Makefile])
2020 AC_CONFIG_FILES([dlls/wintrust/tests/Makefile])
2021 AC_CONFIG_FILES([dlls/wldap32/Makefile])
2022 AC_CONFIG_FILES([dlls/wmi/Makefile])
2023 AC_CONFIG_FILES([dlls/wnaspi32/Makefile])
2024 AC_CONFIG_FILES([dlls/wow32/Makefile])
2025 AC_CONFIG_FILES([dlls/ws2_32/Makefile])
2026 AC_CONFIG_FILES([dlls/ws2_32/tests/Makefile])
2027 AC_CONFIG_FILES([dlls/wsock32/Makefile])
2028 AC_CONFIG_FILES([dlls/wtsapi32/Makefile])
2029 AC_CONFIG_FILES([documentation/Makefile])
2030 AC_CONFIG_FILES([fonts/Makefile])
2031 AC_CONFIG_FILES([include/Makefile])
2032 AC_CONFIG_FILES([libs/Makefile])
2033 AC_CONFIG_FILES([libs/port/Makefile])
2034 AC_CONFIG_FILES([libs/wine/Makefile])
2035 AC_CONFIG_FILES([libs/wpp/Makefile])
2036 AC_CONFIG_FILES([loader/Makefile])
2037 AC_CONFIG_FILES([programs/Makefile])
2038 AC_CONFIG_FILES([programs/clock/Makefile])
2039 AC_CONFIG_FILES([programs/cmd/Makefile])
2040 AC_CONFIG_FILES([programs/cmdlgtst/Makefile])
2041 AC_CONFIG_FILES([programs/control/Makefile])
2042 AC_CONFIG_FILES([programs/eject/Makefile])
2043 AC_CONFIG_FILES([programs/expand/Makefile])
2044 AC_CONFIG_FILES([programs/explorer/Makefile])
2045 AC_CONFIG_FILES([programs/hh/Makefile])
2046 AC_CONFIG_FILES([programs/icinfo/Makefile])
2047 AC_CONFIG_FILES([programs/iexplore/Makefile])
2048 AC_CONFIG_FILES([programs/msiexec/Makefile])
2049 AC_CONFIG_FILES([programs/net/Makefile])
2050 AC_CONFIG_FILES([programs/notepad/Makefile])
2051 AC_CONFIG_FILES([programs/oleview/Makefile])
2052 AC_CONFIG_FILES([programs/progman/Makefile])
2053 AC_CONFIG_FILES([programs/reg/Makefile])
2054 AC_CONFIG_FILES([programs/regedit/Makefile])
2055 AC_CONFIG_FILES([programs/regsvr32/Makefile])
2056 AC_CONFIG_FILES([programs/rpcss/Makefile])
2057 AC_CONFIG_FILES([programs/rundll32/Makefile])
2058 AC_CONFIG_FILES([programs/secedit/Makefile])
2059 AC_CONFIG_FILES([programs/services/Makefile])
2060 AC_CONFIG_FILES([programs/spoolsv/Makefile])
2061 AC_CONFIG_FILES([programs/start/Makefile])
2062 AC_CONFIG_FILES([programs/svchost/Makefile])
2063 AC_CONFIG_FILES([programs/taskmgr/Makefile])
2064 AC_CONFIG_FILES([programs/uninstaller/Makefile])
2065 AC_CONFIG_FILES([programs/view/Makefile])
2066 AC_CONFIG_FILES([programs/wineboot/Makefile])
2067 AC_CONFIG_FILES([programs/winebrowser/Makefile])
2068 AC_CONFIG_FILES([programs/winecfg/Makefile])
2069 AC_CONFIG_FILES([programs/wineconsole/Makefile])
2070 AC_CONFIG_FILES([programs/winedbg/Makefile])
2071 AC_CONFIG_FILES([programs/winedevice/Makefile])
2072 AC_CONFIG_FILES([programs/winefile/Makefile])
2073 AC_CONFIG_FILES([programs/winemenubuilder/Makefile])
2074 AC_CONFIG_FILES([programs/winemine/Makefile])
2075 AC_CONFIG_FILES([programs/winepath/Makefile])
2076 AC_CONFIG_FILES([programs/winetest/Makefile])
2077 AC_CONFIG_FILES([programs/winevdm/Makefile])
2078 AC_CONFIG_FILES([programs/winhelp/Makefile])
2079 AC_CONFIG_FILES([programs/winver/Makefile])
2080 AC_CONFIG_FILES([programs/wordpad/Makefile])
2081 AC_CONFIG_FILES([programs/write/Makefile])
2082 AC_CONFIG_FILES([programs/xcopy/Makefile])
2083 AC_CONFIG_FILES([server/Makefile])
2084 AC_CONFIG_FILES([tools/Makefile])
2085 AC_CONFIG_FILES([tools/widl/Makefile])
2086 AC_CONFIG_FILES([tools/winebuild/Makefile])
2087 AC_CONFIG_FILES([tools/winedump/Makefile])
2088 AC_CONFIG_FILES([tools/winegcc/Makefile])
2089 AC_CONFIG_FILES([tools/wmc/Makefile])
2090 AC_CONFIG_FILES([tools/wrc/Makefile])
2091
2092 AC_OUTPUT
2093
2094 if test "$no_create" = "yes"
2095 then
2096   exit 0
2097 fi
2098
2099 WINE_PRINT_MESSAGES
2100
2101 echo "
2102 $as_me: Finished.  Do '${ac_make} depend && ${ac_make}' to compile Wine.
2103 " >&AS_MESSAGE_FD
2104
2105 dnl Local Variables:
2106 dnl comment-start: "dnl "
2107 dnl comment-end: ""
2108 dnl comment-start-skip: "\\bdnl\\b\\s *"
2109 dnl compile-command: "autoreconf --warnings=all"
2110 dnl End: