git.oblomov.eu Git - ocl-icd/blob - configure.ac

   1 #                                               -*- Autoconf -*-
   2 # Process this file with autoconf to produce a configure script.
   3
   4 AC_PREREQ([2.68])
   5 AC_INIT([OpenCL ICD Loader], [1.5], [ocl-icd-devel@lists.forge.imag.fr], [ocl-icd])
   6 AC_CONFIG_SRCDIR([ocl_icd_loader.c])
   7 AC_CONFIG_AUX_DIR([build-aux])
   8 AC_CONFIG_HEADERS([config.h])
   9 AC_CONFIG_MACRO_DIR([m4])
  10 AM_INIT_AUTOMAKE([-Wall -Werror foreign 1.9 tar-pax check-news color-tests parallel-tests])
  11 AMX_SILENT_RULES([AM_DEFAULT_VERBOSITY=0])
  12 LT_INIT([disable-static])
  13
  14 OPENCL_VERSION="1.2"
  15 AC_SUBST([OPENCL_VERSION])
  16
  17 # Checks for programs.
  18 AC_PROG_CC_C89
  19 AC_PROG_INSTALL
  20 AC_PROG_LN_S
  21
  22 # Checks for libraries.
  23 AC_CHECK_LIB([dl], [dlopen])
  24
  25 # Checks for header files.
  26 AC_CHECK_HEADERS([stdlib.h string.h])
  27
  28 # Checks for typedefs, structures, and compiler characteristics.
  29 AC_C_INLINE
  30 AC_TYPE_SIZE_T
  31 AC_C_CONST
  32
  33 NO_DEPRECATED_DECLARATIONS_FLAGS=
  34 AX_CHECK_COMPILER_FLAGS([-Wno-deprecated-declarations],
  35   [NO_DEPRECATED_DECLARATIONS_FLAGS="-Wno-deprecated-declarations"])
  36 AC_SUBST([NO_DEPRECATED_DECLARATIONS_FLAGS])
  37
  38 # Checks for library functions.
  39 AC_FUNC_MALLOC
  40 AC_FUNC_REALLOC
  41 AC_CHECK_FUNCS([strstr])
  42
  43 # --enable-pthread-once
  44 AC_ARG_ENABLE([pthread-once],
  45   [AS_HELP_STRING([--enable-pthread-once],
  46                [use pthread_once() to ensure correct initialisation without polling])],
  47   [pthread_once=$enableval],
  48   [pthread_once=no])
  49
  50 if test "$pthread_once" = yes ; then
  51   AX_PTHREAD([
  52     AC_DEFINE([USE_PTHREAD], [1],
  53               [pthreads are available])
  54   ], [
  55     AC_MSG_ERROR([No pthread detected on this platform!])
  56   ])
  57 fi
  58
  59 # --disable-debug
  60 AC_ARG_ENABLE([debug],
  61   [AS_HELP_STRING([--disable-debug],
  62                [remove debug and additionnal checks (default is included)])],
  63   [use_debug=$enableval],
  64   [use_debug=yes])
  65 if  test "x$use_debug" != xno ; then
  66   AC_DEFINE([DEBUG_OCL_ICD], [1],
  67             [Add DEBUG additionnal code])
  68 fi
  69
  70 # --enable-update-database
  71 AC_ARG_ENABLE([update-database],
  72   [AS_HELP_STRING([--enable-update-database],
  73                [update the YAML database from the currently installed ICD Loader and OpenCL headers (root access required)])],
  74   [update_database=$enableval],
  75   [update_database=no])
  76 AM_CONDITIONAL([UPDATE_DATABASE], [test x"$update_database" != xno])
  77
  78 # always use versionned symbols (check required for MacOSX)
  79 AM_CONDITIONAL([USE_MAP], [true])
  80
  81 AC_CONFIG_FILES([
  82   Makefile
  83   OpenCL.pc
  84   ocl-icd.pc
  85 ])
  86 AC_OUTPUT