git.oblomov.eu Git - ohcount/blob - test/detect_files/foo.sci

   1 // Scilab ( http://www.scilab.org/ ) - This file is part of Scilab
   2 // Copyright (C) INRIA - Farid BELAHCENE
   3 //
   4 // This file must be used under the terms of the CeCILL.
   5 // This source file is licensed as described in the file COPYING, which
   6 // you should have received as part of this distribution.  The terms
   7 // are also available at
   8 // http://www.cecill.info/licences/Licence_CeCILL_V2-en.txt
   9
  10 function y=factorial(n)
  11
  12         // This function returns the factorial n. If n is a vector, matrix or hypermatrix it returns the element wise factorial
  13         // Input : n, a scalar/vector/matrix/hypermat of positives integers.
  14         // Output : y, a scalar/vector/matrix/hypermat
  15
  16         rhs = argn(2);
  17
  18         if rhs <> 1 then
  19                 error(msprintf(gettext("%s: Wrong number of input argument(s): %d expected.\n"),"factorial",1));
  20         end
  21
  22         if (type(n) <> 1 & (typeof(n)<>"hypermat" | type(n.entries)<>1)) | (~isempty(n) & (or((n-floor(n)<>0)) | or(n<0))) then
  23                 error(msprintf(gettext("%s: Wrong value for input argument #%d: Scalar/vector/matrix/hypermatrix of positive integers expected.\n"),"factorial",1));
  24         elseif isempty(n)
  25                 y=n
  26                 return
  27         else
  28                 n(n==0)=1
  29                 ntemp=cumprod(1:max(n))
  30                 y=matrix(ntemp(n(:)),size(n))
  31         end
  32
  33 endfunction